FS/FS/pay_batch.pm

   1 package FS::pay_batch;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG %import_info %export_info $conf );
   5 use Time::Local;
   6 use Text::CSV_XS;
   7 use FS::Record qw( dbh qsearch qsearchs );
   8 use FS::cust_pay;
   9 use FS::Conf;
  10
  11 @ISA = qw(FS::Record);
  12
  13 =head1 NAME
  14
  15 FS::pay_batch - Object methods for pay_batch records
  16
  17 =head1 SYNOPSIS
  18
  19   use FS::pay_batch;
  20
  21   $record = new FS::pay_batch \%hash;
  22   $record = new FS::pay_batch { 'column' => 'value' };
  23
  24   $error = $record->insert;
  25
  26   $error = $new_record->replace($old_record);
  27
  28   $error = $record->delete;
  29
  30   $error = $record->check;
  31
  32 =head1 DESCRIPTION
  33
  34 An FS::pay_batch object represents an payment batch.  FS::pay_batch inherits
  35 from FS::Record.  The following fields are currently supported:
  36
  37 =over 4
  38
  39 =item batchnum - primary key
  40
  41 =item payby - CARD or CHEK
  42
  43 =item status - O (Open), I (In-transit), or R (Resolved)
  44
  45 =item download -
  46
  47 =item upload -
  48
  49
  50 =back
  51
  52 =head1 METHODS
  53
  54 =over 4
  55
  56 =item new HASHREF
  57
  58 Creates a new batch.  To add the batch to the database, see L<"insert">.
  59
  60 Note that this stores the hash reference, not a distinct copy of the hash it
  61 points to.  You can ask the object for a copy with the I<hash> method.
  62
  63 =cut
  64
  65 # the new method can be inherited from FS::Record, if a table method is defined
  66
  67 sub table { 'pay_batch'; }
  68
  69 =item insert
  70
  71 Adds this record to the database.  If there is an error, returns the error,
  72 otherwise returns false.
  73
  74 =cut
  75
  76 # the insert method can be inherited from FS::Record
  77
  78 =item delete
  79
  80 Delete this record from the database.
  81
  82 =cut
  83
  84 # the delete method can be inherited from FS::Record
  85
  86 =item replace OLD_RECORD
  87
  88 Replaces the OLD_RECORD with this one in the database.  If there is an error,
  89 returns the error, otherwise returns false.
  90
  91 =cut
  92
  93 # the replace method can be inherited from FS::Record
  94
  95 =item check
  96
  97 Checks all fields to make sure this is a valid batch.  If there is
  98 an error, returns the error, otherwise returns false.  Called by the insert
  99 and replace methods.
 100
 101 =cut
 102
 103 # the check method should currently be supplied - FS::Record contains some
 104 # data checking routines
 105
 106 sub check {
 107   my $self = shift;
 108
 109   my $error =
 110     $self->ut_numbern('batchnum')
 111     || $self->ut_enum('payby', [ 'CARD', 'CHEK' ])
 112     || $self->ut_enum('status', [ 'O', 'I', 'R' ])
 113   ;
 114   return $error if $error;
 115
 116   $self->SUPER::check;
 117 }
 118
 119 =item rebalance
 120
 121 =cut
 122
 123 sub rebalance {
 124   my $self = shift;
 125 }
 126
 127 =item set_status
 128
 129 =cut
 130
 131 sub set_status {
 132   my $self = shift;
 133   $self->status(shift);
 134   $self->download(time)
 135     if $self->status eq 'I' && ! $self->download;
 136   $self->upload(time)
 137     if $self->status eq 'R' && ! $self->upload;
 138   $self->replace();
 139 }
 140
 141 # further false laziness
 142
 143 %import_info = %export_info = ();
 144 foreach my $INC (@INC) {
 145   warn "globbing $INC/FS/pay_batch/*.pm\n" if $DEBUG;
 146   foreach my $file ( glob("$INC/FS/pay_batch/*.pm")) {
 147     warn "attempting to load batch format from $file\n" if $DEBUG;
 148     $file =~ /\/(\w+)\.pm$/;
 149     next if !$1;
 150     my $mod = $1;
 151     my ($import, $export, $name) =
 152       eval "use FS::pay_batch::$mod;
 153            ( \\%FS::pay_batch::$mod\::import_info,
 154              \\%FS::pay_batch::$mod\::export_info,
 155              \$FS::pay_batch::$mod\::name)";
 156     $name ||= $mod; # in case it's not defined
 157     if( $@) {
 158       # in FS::cdr this is a die, not a warn.  That's probably a bug.
 159       warn "error using FS::pay_batch::$mod (skipping): $@\n";
 160       next;
 161     }
 162     if(!keys(%$import)) {
 163       warn "no \%import_info found in FS::pay_batch::$mod (skipping)\n";
 164     }
 165     else {
 166       $import_info{$name} = $import;
 167     }
 168     if(!keys(%$export)) {
 169       warn "no \%export_info found in FS::pay_batch::$mod (skipping)\n";
 170     }
 171     else {
 172       $export_info{$name} = $export;
 173     }
 174   }
 175 }
 176
 177 =item import_results OPTION => VALUE, ...
 178
 179 Import batch results.
 180
 181 Options are:
 182
 183 I<filehandle> - open filehandle of results file.
 184
 185 I<format> - "csv-td_canada_trust-merchant_pc_batch", "csv-chase_canada-E-xactBatch", "ach-spiritone", or "PAP"
 186
 187 =cut
 188
 189 sub import_results {
 190   my $self = shift;
 191
 192   my $param = ref($_[0]) ? shift : { @_ };
 193   my $fh = $param->{'filehandle'};
 194   my $format = $param->{'format'};
 195   my $info = $import_info{$format}
 196     or die "unknown format $format";
 197
 198   my $filetype            = $info->{'filetype'};      # CSV or fixed
 199   my @fields              = @{ $info->{'fields'} };
 200   my $formatre            = $info->{'formatre'};      # for fixed
 201   my @all_values;
 202   my $begin_condition     = $info->{'begin_condition'};
 203   my $end_condition       = $info->{'end_condition'};
 204   my $end_hook            = $info->{'end_hook'};
 205   my $hook                = $info->{'hook'};
 206   my $approved_condition  = $info->{'approved'};
 207   my $declined_condition  = $info->{'declined'};
 208
 209   my $csv = new Text::CSV_XS;
 210
 211   local $SIG{HUP} = 'IGNORE';
 212   local $SIG{INT} = 'IGNORE';
 213   local $SIG{QUIT} = 'IGNORE';
 214   local $SIG{TERM} = 'IGNORE';
 215   local $SIG{TSTP} = 'IGNORE';
 216   local $SIG{PIPE} = 'IGNORE';
 217
 218   my $oldAutoCommit = $FS::UID::AutoCommit;
 219   local $FS::UID::AutoCommit = 0;
 220   my $dbh = dbh;
 221
 222   my $reself = $self->select_for_update;
 223
 224   unless ( $reself->status eq 'I' ) {
 225     $dbh->rollback if $oldAutoCommit;
 226     return "batchnum ". $self->batchnum. "no longer in transit";
 227   }
 228
 229   my $error = $self->set_status('R');
 230   if ( $error ) {
 231     $dbh->rollback if $oldAutoCommit;
 232     return $error;
 233   }
 234
 235   my $total = 0;
 236   my $line;
 237
 238   # Order of operations has been changed here.
 239   # We now slurp everything into @all_values, then
 240   # process one line at a time.
 241
 242   if ($filetype eq 'XML') {
 243     eval "use XML::Simple";
 244     die $@ if $@;
 245     my @xmlkeys = @{ $info->{'xmlkeys'} };  # for XML
 246     my $xmlrow  = $info->{'xmlrow'};        # also for XML
 247
 248     # Do everything differently.
 249     my $data = XML::Simple::XMLin($fh, KeepRoot => 1);
 250     my $rows = $data;
 251     # $xmlrow = [ RootKey, FirstLevelKey, SecondLevelKey... ]
 252     $rows = $rows->{$_} foreach( @$xmlrow );
 253     if(!defined($rows)) {
 254       $dbh->rollback if $oldAutoCommit;
 255       return "can't find rows in XML file";
 256     }
 257     $rows = [ $rows ] if ref($rows) ne 'ARRAY';
 258     foreach my $row (@$rows) {
 259       push @all_values, [ @{$row}{@xmlkeys} ];
 260     }
 261   }
 262   else {
 263     while ( defined($line=<$fh>) ) {
 264
 265       next if $line =~ /^\s*$/; #skip blank lines
 266
 267       if ($filetype eq "CSV") {
 268         $csv->parse($line) or do {
 269           $dbh->rollback if $oldAutoCommit;
 270           return "can't parse: ". $csv->error_input();
 271         };
 272         push @all_values, [ $csv->fields() ];
 273       }elsif ($filetype eq 'fixed'){
 274         my @values = $line =~ /$formatre/;
 275         unless (@values) {
 276           $dbh->rollback if $oldAutoCommit;
 277           return "can't parse: ". $line;
 278         };
 279         push @all_values, \@values;
 280       }else{
 281         $dbh->rollback if $oldAutoCommit;
 282         return "Unknown file type $filetype";
 283       }
 284     }
 285   }
 286
 287   foreach (@all_values) {
 288     my @values = @$_;
 289
 290     my %hash;
 291     foreach my $field ( @fields ) {
 292       my $value = shift @values;
 293       next unless $field;
 294       $hash{$field} = $value;
 295     }
 296
 297     if ( defined($end_condition) and &{$end_condition}(\%hash) ) {
 298       my $error;
 299       $error = &{$end_hook}(\%hash, $total) if defined($end_hook);
 300       if ( $error ) {
 301         $dbh->rollback if $oldAutoCommit;
 302         return $error;
 303       }
 304       last;
 305     }
 306
 307     my $cust_pay_batch =
 308       qsearchs('cust_pay_batch', { 'paybatchnum' => $hash{'paybatchnum'}+0 } );
 309     unless ( $cust_pay_batch ) {
 310       return "unknown paybatchnum $hash{'paybatchnum'}\n";
 311     }
 312     my $custnum = $cust_pay_batch->custnum,
 313     my $payby = $cust_pay_batch->payby,
 314
 315     my $new_cust_pay_batch = new FS::cust_pay_batch { $cust_pay_batch->hash };
 316
 317     &{$hook}(\%hash, $cust_pay_batch->hashref);
 318
 319     if ( &{$approved_condition}(\%hash) ) {
 320
 321       $new_cust_pay_batch->status('Approved');
 322
 323     } elsif ( &{$declined_condition}(\%hash) ) {
 324
 325       $new_cust_pay_batch->status('Declined');
 326
 327     }
 328
 329     my $error = $new_cust_pay_batch->replace($cust_pay_batch);
 330     if ( $error ) {
 331       $dbh->rollback if $oldAutoCommit;
 332       return "error updating status of paybatchnum $hash{'paybatchnum'}: $error\n";
 333     }
 334
 335     if ( $new_cust_pay_batch->status =~ /Approved/i ) {
 336
 337       my $cust_pay = new FS::cust_pay ( {
 338         'custnum'  => $custnum,
 339         'payby'    => $payby,
 340         'paybatch' => $self->batchnum,
 341         map { $_ => $hash{$_} } (qw( paid _date payinfo )),
 342       } );
 343       $error = $cust_pay->insert;
 344       if ( $error ) {
 345         $dbh->rollback if $oldAutoCommit;
 346         return "error adding payment paybatchnum $hash{'paybatchnum'}: $error\n";
 347       }
 348       $total += $hash{'paid'};
 349
 350       $cust_pay->cust_main->apply_payments;
 351
 352     } elsif ( $new_cust_pay_batch->status =~ /Declined/i ) {
 353
 354       #false laziness w/cust_main::collect
 355
 356       my $due_cust_event = $new_cust_pay_batch->cust_main->due_cust_event(
 357         #'check_freq' => '1d', #?
 358         'eventtable' => 'cust_pay_batch',
 359         'objects'    => [ $new_cust_pay_batch ],
 360       );
 361       unless( ref($due_cust_event) ) {
 362         $dbh->rollback if $oldAutoCommit;
 363         return $due_cust_event;
 364       }
 365
 366       foreach my $cust_event ( @$due_cust_event ) {
 367
 368         #XXX lock event
 369
 370         #re-eval event conditions (a previous event could have changed things)
 371         next unless $cust_event->test_conditions;
 372
 373         if ( my $error = $cust_event->do_event() ) {
 374           # gah, even with transactions.
 375           #$dbh->commit if $oldAutoCommit; #well.
 376           $dbh->rollback if $oldAutoCommit;
 377           return $error;
 378         }
 379
 380       }
 381
 382     }
 383
 384   }
 385
 386   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 387   '';
 388
 389 }
 390
 391 sub export_batch {
 392 # Formerly httemplate/misc/download-batch.cgi
 393   my $self = shift;
 394   my $conf = new FS::Conf;
 395   my $format = shift || $conf->config('batch-default_format')
 396                or die "No batch format configured\n";
 397   my $info = $export_info{$format} or die "Format not found: '$format'\n";
 398   &{$info->{'init'}}($conf) if exists($info->{'init'});
 399
 400   my $oldAutoCommit = $FS::UID::AutoCommit;
 401   local $FS::UID::AutoCommit = 0;
 402   my $dbh = dbh;
 403
 404   my $error;
 405
 406   my $first_download;
 407   if($self->status eq 'O') {
 408     $first_download = 1;
 409   }
 410   elsif($self->status eq 'I' and
 411         $FS::CurrentUser::CurrentUser->access_right('Reprocess batches')) {
 412     $first_download = 0;
 413   }
 414   else {
 415     die "No pending batch.\n"
 416   }
 417
 418   $error = $self->set_status('I');
 419   die "error updating pay_batch status: $error\n" if $error;
 420
 421   my $batch = '';
 422   my $batchtotal = 0;
 423   my $batchcount = 0;
 424
 425   my @cust_pay_batch = sort { $a->paybatchnum <=> $b->paybatchnum }
 426                       qsearch('cust_pay_batch', { batchnum => $self->batchnum } );
 427
 428   my $h = $info->{'header'};
 429   if(ref($h) eq 'CODE') {
 430     $batch .= &$h($self, \@cust_pay_batch) . "\n";
 431   }
 432   else {
 433     $batch .= $h . "\n";
 434   }
 435   foreach my $cust_pay_batch (@cust_pay_batch) {
 436     if($first_download) {
 437       my $balance = $cust_pay_batch->cust_main->balance;
 438       $error = '';
 439       if($balance <= 0) { # then don't charge this customer
 440         $error = $cust_pay_batch->delete;
 441         undef $cust_pay_batch;
 442       }
 443       elsif($balance < $cust_pay_batch->amount) { # then reduce the charge to the remaining balance
 444         $cust_pay_batch->amount($balance);
 445         $error = $cust_pay_batch->replace;
 446       }
 447       # else $balance >= $cust_pay_batch->amount
 448       if($error) {
 449         $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 450         die $error;
 451       }
 452     }
 453     if($cust_pay_batch) { # that is, it wasn't deleted
 454       $batchcount++;
 455       $batchtotal += $cust_pay_batch->amount;
 456       $batch .= &{$info->{'row'}}($cust_pay_batch, $self) . "\n";
 457     }
 458   }
 459   my $f = $info->{'footer'};
 460   if(ref($f) eq 'CODE') {
 461     $batch .= &$f($self, $batchcount, $batchtotal) . "\n";
 462   }
 463   else {
 464     $batch .= $f . "\n";
 465   }
 466
 467   if ($info->{'autopost'}) {
 468     $error = &{$info->{'autopost'}}($self, $batch);
 469     if($error) {
 470       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 471       die $error;
 472     }
 473   }
 474
 475   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 476   return $batch;
 477 }
 478
 479 =back
 480
 481 =head1 BUGS
 482
 483 status is somewhat redundant now that download and upload exist
 484
 485 =head1 SEE ALSO
 486
 487 L<FS::Record>, schema.html from the base documentation.
 488
 489 =cut
 490
 491 1;
 492