FS/FS/pay_batch.pm

   1 package FS::pay_batch;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG %import_info %export_info $conf );
   5 use Time::Local;
   6 use Text::CSV_XS;
   7 use FS::Record qw( dbh qsearch qsearchs );
   8 use FS::cust_pay;
   9 use FS::Conf;
  10
  11 @ISA = qw(FS::Record);
  12
  13 =head1 NAME
  14
  15 FS::pay_batch - Object methods for pay_batch records
  16
  17 =head1 SYNOPSIS
  18
  19   use FS::pay_batch;
  20
  21   $record = new FS::pay_batch \%hash;
  22   $record = new FS::pay_batch { 'column' => 'value' };
  23
  24   $error = $record->insert;
  25
  26   $error = $new_record->replace($old_record);
  27
  28   $error = $record->delete;
  29
  30   $error = $record->check;
  31
  32 =head1 DESCRIPTION
  33
  34 An FS::pay_batch object represents an payment batch.  FS::pay_batch inherits
  35 from FS::Record.  The following fields are currently supported:
  36
  37 =over 4
  38
  39 =item batchnum - primary key
  40
  41 =item payby - CARD or CHEK
  42
  43 =item status - O (Open), I (In-transit), or R (Resolved)
  44
  45 =item download -
  46
  47 =item upload -
  48
  49
  50 =back
  51
  52 =head1 METHODS
  53
  54 =over 4
  55
  56 =item new HASHREF
  57
  58 Creates a new batch.  To add the batch to the database, see L<"insert">.
  59
  60 Note that this stores the hash reference, not a distinct copy of the hash it
  61 points to.  You can ask the object for a copy with the I<hash> method.
  62
  63 =cut
  64
  65 # the new method can be inherited from FS::Record, if a table method is defined
  66
  67 sub table { 'pay_batch'; }
  68
  69 =item insert
  70
  71 Adds this record to the database.  If there is an error, returns the error,
  72 otherwise returns false.
  73
  74 =cut
  75
  76 # the insert method can be inherited from FS::Record
  77
  78 =item delete
  79
  80 Delete this record from the database.
  81
  82 =cut
  83
  84 # the delete method can be inherited from FS::Record
  85
  86 =item replace OLD_RECORD
  87
  88 Replaces the OLD_RECORD with this one in the database.  If there is an error,
  89 returns the error, otherwise returns false.
  90
  91 =cut
  92
  93 # the replace method can be inherited from FS::Record
  94
  95 =item check
  96
  97 Checks all fields to make sure this is a valid batch.  If there is
  98 an error, returns the error, otherwise returns false.  Called by the insert
  99 and replace methods.
 100
 101 =cut
 102
 103 # the check method should currently be supplied - FS::Record contains some
 104 # data checking routines
 105
 106 sub check {
 107   my $self = shift;
 108
 109   my $error =
 110     $self->ut_numbern('batchnum')
 111     || $self->ut_enum('payby', [ 'CARD', 'CHEK' ])
 112     || $self->ut_enum('status', [ 'O', 'I', 'R' ])
 113   ;
 114   return $error if $error;
 115
 116   $self->SUPER::check;
 117 }
 118
 119 =item rebalance
 120
 121 =cut
 122
 123 sub rebalance {
 124   my $self = shift;
 125 }
 126
 127 =item set_status
 128
 129 =cut
 130
 131 sub set_status {
 132   my $self = shift;
 133   $self->status(shift);
 134   $self->download(time)
 135     if $self->status eq 'I' && ! $self->download;
 136   $self->upload(time)
 137     if $self->status eq 'R' && ! $self->upload;
 138   $self->replace();
 139 }
 140
 141 # further false laziness
 142
 143 %import_info = %export_info = ();
 144 foreach my $INC (@INC) {
 145   warn "globbing $INC/FS/pay_batch/*.pm\n" if $DEBUG;
 146   foreach my $file ( glob("$INC/FS/pay_batch/*.pm")) {
 147     warn "attempting to load batch format from $file\n" if $DEBUG;
 148     $file =~ /\/(\w+)\.pm$/;
 149     next if !$1;
 150     my $mod = $1;
 151     my ($import, $export, $name) =
 152       eval "use FS::pay_batch::$mod;
 153            ( \\%FS::pay_batch::$mod\::import_info,
 154              \\%FS::pay_batch::$mod\::export_info,
 155              \$FS::pay_batch::$mod\::name)";
 156     $name ||= $mod; # in case it's not defined
 157     if( $@) {
 158       # in FS::cdr this is a die, not a warn.  That's probably a bug.
 159       warn "error using FS::pay_batch::$mod (skipping): $@\n";
 160       next;
 161     }
 162     if(!keys(%$import)) {
 163       warn "no \%import_info found in FS::pay_batch::$mod (skipping)\n";
 164     }
 165     else {
 166       $import_info{$name} = $import;
 167     }
 168     if(!keys(%$export)) {
 169       warn "no \%export_info found in FS::pay_batch::$mod (skipping)\n";
 170     }
 171     else {
 172       $export_info{$name} = $export;
 173     }
 174   }
 175 }
 176
 177 =item import_results OPTION => VALUE, ...
 178
 179 Import batch results.
 180
 181 Options are:
 182
 183 I<filehandle> - open filehandle of results file.
 184
 185 I<format> - "csv-td_canada_trust-merchant_pc_batch", "csv-chase_canada-E-xactBatch", "ach-spiritone", or "PAP"
 186
 187 =cut
 188
 189 sub import_results {
 190   my $self = shift;
 191
 192   my $param = ref($_[0]) ? shift : { @_ };
 193   my $fh = $param->{'filehandle'};
 194   my $format = $param->{'format'};
 195   my $info = $import_info{$format}
 196     or die "unknown format $format";
 197
 198   my $filetype            = $info->{'filetype'};      # CSV or fixed
 199   my @fields              = @{ $info->{'fields'}};
 200   my $formatre            = $info->{'formatre'};      # for fixed
 201   my @all_values;
 202   my $begin_condition     = $info->{'begin_condition'};
 203   my $end_condition       = $info->{'end_condition'};
 204   my $end_hook            = $info->{'end_hook'};
 205   my $hook                = $info->{'hook'};
 206   my $approved_condition  = $info->{'approved'};
 207   my $declined_condition  = $info->{'declined'};
 208
 209   my $csv = new Text::CSV_XS;
 210
 211   local $SIG{HUP} = 'IGNORE';
 212   local $SIG{INT} = 'IGNORE';
 213   local $SIG{QUIT} = 'IGNORE';
 214   local $SIG{TERM} = 'IGNORE';
 215   local $SIG{TSTP} = 'IGNORE';
 216   local $SIG{PIPE} = 'IGNORE';
 217
 218   my $oldAutoCommit = $FS::UID::AutoCommit;
 219   local $FS::UID::AutoCommit = 0;
 220   my $dbh = dbh;
 221
 222   my $reself = $self->select_for_update;
 223
 224   unless ( $reself->status eq 'I' ) {
 225     $dbh->rollback if $oldAutoCommit;
 226     return "batchnum ". $self->batchnum. "no longer in transit";
 227   }
 228
 229   my $error = $self->set_status('R');
 230   if ( $error ) {
 231     $dbh->rollback if $oldAutoCommit;
 232     return $error;
 233   }
 234
 235   my $total = 0;
 236   my $line;
 237
 238   # Order of operations has been changed here.
 239   # We now slurp everything into @all_values, then
 240   # process one line at a time.
 241
 242   if ($filetype eq 'XML') {
 243     eval "use XML::Simple";
 244     die $@ if $@;
 245     my @xmlkeys = @{ $info->{'xmlkeys'} };  # for XML
 246     my $xmlrow  = $info->{'xmlrow'};        # also for XML
 247
 248     # Do everything differently.
 249     my $data = XML::Simple::XMLin($fh, KeepRoot => 1);
 250     my $rows = $data;
 251     # $xmlrow = [ RootKey, FirstLevelKey, SecondLevelKey... ]
 252     $rows = $rows->{$_} foreach( @$xmlrow );
 253     if(!defined($rows)) {
 254       $dbh->rollback if $oldAutoCommit;
 255       return "can't find rows in XML file";
 256     }
 257     $rows = [ $rows ] if ref($rows) ne 'ARRAY';
 258     foreach my $row (@$rows) {
 259       push @all_values, [ @{$row}{@xmlkeys}, $row ];
 260     }
 261   }
 262   else {
 263     while ( defined($line=<$fh>) ) {
 264
 265       next if $line =~ /^\s*$/; #skip blank lines
 266
 267       if ($filetype eq "CSV") {
 268         $csv->parse($line) or do {
 269           $dbh->rollback if $oldAutoCommit;
 270           return "can't parse: ". $csv->error_input();
 271         };
 272         push @all_values, [ $csv->fields(), $line ];
 273       }elsif ($filetype eq 'fixed'){
 274         my @values = ( $line =~ /$formatre/, $line );
 275         unless (@values) {
 276           $dbh->rollback if $oldAutoCommit;
 277           return "can't parse: ". $line;
 278         };
 279         push @all_values, \@values;
 280       }else{
 281         $dbh->rollback if $oldAutoCommit;
 282         return "Unknown file type $filetype";
 283       }
 284     }
 285   }
 286
 287   foreach (@all_values) {
 288     my @values = @$_;
 289
 290     my %hash;
 291     my $line = pop @values;
 292     foreach my $field ( @fields ) {
 293       my $value = shift @values;
 294       next unless $field;
 295       $hash{$field} = $value;
 296     }
 297
 298     if ( defined($begin_condition) and &{$begin_condition}(\%hash, $line)) {
 299       undef $begin_condition;
 300     }
 301
 302     if ( defined($end_condition) and &{$end_condition}(\%hash, $line) ) {
 303       my $error;
 304       $error = &{$end_hook}(\%hash, $total, $line) if defined($end_hook);
 305       if ( $error ) {
 306         $dbh->rollback if $oldAutoCommit;
 307         return $error;
 308       }
 309       last;
 310     }
 311
 312     my $cust_pay_batch =
 313       qsearchs('cust_pay_batch', { 'paybatchnum' => $hash{'paybatchnum'}+0 } );
 314     unless ( $cust_pay_batch ) {
 315       return "unknown paybatchnum $hash{'paybatchnum'}\n";
 316     }
 317     my $custnum = $cust_pay_batch->custnum,
 318     my $payby = $cust_pay_batch->payby,
 319
 320     my $new_cust_pay_batch = new FS::cust_pay_batch { $cust_pay_batch->hash };
 321
 322     &{$hook}(\%hash, $cust_pay_batch->hashref);
 323
 324     if ( &{$approved_condition}(\%hash) ) {
 325
 326       $new_cust_pay_batch->status('Approved');
 327
 328     } elsif ( &{$declined_condition}(\%hash) ) {
 329
 330       $new_cust_pay_batch->status('Declined');
 331
 332     }
 333
 334     my $error = $new_cust_pay_batch->replace($cust_pay_batch);
 335     if ( $error ) {
 336       $dbh->rollback if $oldAutoCommit;
 337       return "error updating status of paybatchnum $hash{'paybatchnum'}: $error\n";
 338     }
 339
 340     if ( $new_cust_pay_batch->status =~ /Approved/i ) {
 341
 342       my $cust_pay = new FS::cust_pay ( {
 343         'custnum'  => $custnum,
 344         'payby'    => $payby,
 345         'paybatch' => $self->batchnum,
 346         map { $_ => $hash{$_} } (qw( paid _date payinfo )),
 347       } );
 348       $error = $cust_pay->insert;
 349       if ( $error ) {
 350         $dbh->rollback if $oldAutoCommit;
 351         return "error adding payment paybatchnum $hash{'paybatchnum'}: $error\n";
 352       }
 353       $total += $hash{'paid'};
 354
 355       $cust_pay->cust_main->apply_payments;
 356
 357     } elsif ( $new_cust_pay_batch->status =~ /Declined/i ) {
 358
 359       #false laziness w/cust_main::collect
 360
 361       my $due_cust_event = $new_cust_pay_batch->cust_main->due_cust_event(
 362         #'check_freq' => '1d', #?
 363         'eventtable' => 'cust_pay_batch',
 364         'objects'    => [ $new_cust_pay_batch ],
 365       );
 366       unless( ref($due_cust_event) ) {
 367         $dbh->rollback if $oldAutoCommit;
 368         return $due_cust_event;
 369       }
 370
 371       foreach my $cust_event ( @$due_cust_event ) {
 372
 373         #XXX lock event
 374
 375         #re-eval event conditions (a previous event could have changed things)
 376         next unless $cust_event->test_conditions;
 377
 378         if ( my $error = $cust_event->do_event() ) {
 379           # gah, even with transactions.
 380           #$dbh->commit if $oldAutoCommit; #well.
 381           $dbh->rollback if $oldAutoCommit;
 382           return $error;
 383         }
 384
 385       }
 386
 387     }
 388
 389   }
 390
 391   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 392   '';
 393
 394 }
 395
 396 # Formerly httemplate/misc/download-batch.cgi
 397 sub export_batch {
 398   my $self = shift;
 399   my $conf = new FS::Conf;
 400   my $format = shift || $conf->config('batch-default_format')
 401                or die "No batch format configured\n";
 402   my $info = $export_info{$format} or die "Format not found: '$format'\n";
 403   &{$info->{'init'}}($conf) if exists($info->{'init'});
 404
 405   my $curuser = $FS::CurrentUser::CurrentUser;
 406
 407   my $oldAutoCommit = $FS::UID::AutoCommit;
 408   local $FS::UID::AutoCommit = 0;
 409   my $dbh = dbh;
 410
 411   my $first_download;
 412   my $status = $self->status;
 413   if ($status eq 'O') {
 414     $first_download = 1;
 415     my $error = $self->set_status('I');
 416     die "error updating pay_batch status: $error\n" if $error;
 417   } elsif ($status eq 'I' && $curuser->access_right('Reprocess batches')) {
 418     $first_download = 0;
 419   } else {
 420     die "No pending batch.\n";
 421   }
 422
 423   my $batch = '';
 424   my $batchtotal = 0;
 425   my $batchcount = 0;
 426
 427   my @cust_pay_batch = sort { $a->paybatchnum <=> $b->paybatchnum }
 428                       qsearch('cust_pay_batch', { batchnum => $self->batchnum } );
 429
 430   my $h = $info->{'header'};
 431   if(ref($h) eq 'CODE') {
 432     $batch .= &$h($self, \@cust_pay_batch) . "\n";
 433   }
 434   else {
 435     $batch .= $h . "\n";
 436   }
 437   foreach my $cust_pay_batch (@cust_pay_batch) {
 438     if($first_download) {
 439       my $balance = $cust_pay_batch->cust_main->balance;
 440       my $error = '';
 441       if($balance <= 0) { # then don't charge this customer
 442         $error = $cust_pay_batch->delete;
 443         undef $cust_pay_batch;
 444       }
 445       elsif($balance < $cust_pay_batch->amount) { # then reduce the charge to the remaining balance
 446         $cust_pay_batch->amount($balance);
 447         $error = $cust_pay_batch->replace;
 448       }
 449       # else $balance >= $cust_pay_batch->amount
 450       if($error) {
 451         $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 452         die $error;
 453       }
 454     }
 455     if($cust_pay_batch) { # that is, it wasn't deleted
 456       $batchcount++;
 457       $batchtotal += $cust_pay_batch->amount;
 458       $batch .= &{$info->{'row'}}($cust_pay_batch, $self) . "\n";
 459     }
 460   }
 461   my $f = $info->{'footer'};
 462   if(ref($f) eq 'CODE') {
 463     $batch .= &$f($self, $batchcount, $batchtotal) . "\n";
 464   }
 465   else {
 466     $batch .= $f . "\n";
 467   }
 468
 469   if ($info->{'autopost'}) {
 470     my $error = &{$info->{'autopost'}}($self, $batch);
 471     if($error) {
 472       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 473       die $error;
 474     }
 475   }
 476
 477   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 478   return $batch;
 479 }
 480
 481 =back
 482
 483 =head1 BUGS
 484
 485 status is somewhat redundant now that download and upload exist
 486
 487 =head1 SEE ALSO
 488
 489 L<FS::Record>, schema.html from the base documentation.
 490
 491 =cut
 492
 493 1;
 494