FS/FS/part_pkg/voip_tiered.pm

   1 package FS::part_pkg::voip_tiered;
   2 use base qw( FS::part_pkg::voip_cdr );
   3
   4 use strict;
   5 use vars qw( $DEBUG %info );
   6 use Tie::IxHash;
   7 use Date::Format;
   8 use Text::CSV_XS;
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs); # qsearch);
  11 use FS::cdr;
  12 use FS::rate_tier;
  13 use FS::rate_detail;
  14
  15 use Data::Dumper;
  16
  17 $DEBUG = 0;
  18
  19 tie my %cdr_inout, 'Tie::IxHash',
  20   'outbound'         => 'Outbound',
  21   'inbound'          => 'Inbound',
  22   'outbound_inbound' => 'Outbound and Inbound',
  23 ;
  24
  25 tie my %granularity, 'Tie::IxHash', FS::rate_detail::granularities();
  26
  27 %info = (
  28   'name' => 'VoIP tiered rate pricing of CDRs',
  29   'shortname' => 'VoIP/telco CDR tiered rating',
  30   'inherit_fields' => [ 'voip_cdr', 'prorate_Mixin', 'global_Mixin' ],
  31   'fields' => {
  32     'tiernum' => { 'name' => 'Tier plan',
  33                    'type' => 'select',
  34                    'select_table' => 'rate_tier',
  35                    'select_key'   => 'tiernum',
  36                    'select_label' => 'tiername',
  37                  },
  38     'cdr_inout' => { 'name'=> 'Call direction when using phone number matching',
  39                      'type'=> 'select',
  40                      'select_options' => \%cdr_inout,
  41                    },
  42     'min_included' => { 'name' => 'Minutes included',
  43                     },
  44     'sec_granularity' => { 'name' => 'Granularity',
  45                            'type' => 'select',
  46                            'select_options' => \%granularity,
  47                          },
  48     'rating_method'                          => { 'disabled' => 1 },
  49     'ratenum'                                => { 'disabled' => 1 },
  50     'intrastate_ratenum'                     => { 'disabled' => 1 },
  51     'min_charge'                             => { 'disabled' => 1 },
  52     'ignore_unrateable'                      => { 'disabled' => 1 },
  53     'domestic_prefix'                        => { 'disabled' => 1 },
  54     'international_prefix'                   => { 'disabled' => 1 },
  55     'disable_tollfree'                       => { 'disabled' => 1 },
  56     'noskip_src_length_accountcode_tollfree' => { 'disabled' => 1 },
  57     'accountcode_tollfree_ratenum'           => { 'disabled' => 1 },
  58     'noskip_dst_length_accountcode_tollfree' => { 'disabled' => 1 },
  59   },
  60   'fieldorder' => [qw(
  61                        recur_temporality
  62                        recur_method cutoff_day ),
  63                        FS::part_pkg::prorate_Mixin::fieldorder,
  64                    qw(
  65                        cdr_svc_method cdr_inout
  66                        tiernum
  67                      )
  68                   ],
  69   'weight' => 44,
  70 );
  71
  72 sub calc_usage {
  73   my $self = shift;
  74   my($cust_pkg, $sdate, $details, $param ) = @_;
  75
  76   #my $last_bill = $cust_pkg->last_bill;
  77   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
  78
  79   return 0
  80     if $self->recur_temporality eq 'preceding'
  81     && ( $last_bill eq '' || $last_bill == 0 );
  82
  83   my $included_min    = $self->option('min_included', 1) || 0;
  84   my $cdr_svc_method  = $self->option('cdr_svc_method',1)||'svc_phone.phonenum';
  85   my $cdr_inout       = ($cdr_svc_method eq 'svc_phone.phonenum')
  86                           && $self->option('cdr_inout',1)
  87                           || 'outbound';
  88   my $use_duration    = $self->option('use_duration');
  89   my $granularity     = length($self->option('sec_granularity'))
  90                           ? $self->option('sec_granularity')
  91                           : 60;
  92
  93   #for check_chargable, so we don't keep looking up options inside the loop
  94   my %opt_cache = ();
  95
  96   my($svc_table, $svc_field) = split('\.', $cdr_svc_method);
  97
  98   my %options = (
  99     'disable_src'    => $self->option('disable_src'),
 100     'default_prefix' => $self->option('default_prefix'),
 101     'cdrtypenum'     => $self->option('use_cdrtypenum'),
 102     'status'         => '',
 103     'for_update'     => 1,
 104   );  # $last_bill, $$sdate )
 105   $options{'by_svcnum'} = 1 if $svc_field eq 'svcnum';
 106
 107   ###
 108   # pass one: find the total minutes/calls and store the CDRs
 109   ###
 110   my $total = 0;
 111
 112   my @cust_svc;
 113   if( $self->option('bill_inactive_svcs',1) ) {
 114     #XXX in this mode do we need to restrict the set of CDRs by date also?
 115     @cust_svc = $cust_pkg->h_cust_svc($$sdate, $last_bill);
 116   } else {
 117     @cust_svc = $cust_pkg->cust_svc;
 118   }
 119   @cust_svc = grep { $_->part_svc->svcdb eq $svc_table } @cust_svc;
 120
 121   foreach my $cust_svc (@cust_svc) {
 122
 123     my $svc_x;
 124     if( $self->option('bill_inactive_svcs',1) ) {
 125       $svc_x = $cust_svc->h_svc_x($$sdate, $last_bill);
 126     }
 127     else {
 128       $svc_x = $cust_svc->svc_x;
 129     }
 130
 131     foreach my $pass (split('_', $cdr_inout)) {
 132
 133       $options{'inbound'} = ( $pass eq 'inbound' );
 134
 135       my $cdr_search = $svc_x->psearch_cdrs(%options);
 136       $cdr_search->limit(1000);
 137       $cdr_search->increment(0);
 138       while ( my $cdr = $cdr_search->fetch ) {
 139
 140         if ( $DEBUG > 1 ) {
 141           warn "rating CDR $cdr\n".
 142                join('', map { "  $_ => ". $cdr->{$_}. "\n" } keys %$cdr );
 143         }
 144
 145         my $charge = '';
 146         my $seconds = '';
 147
 148         $seconds = $use_duration ? $cdr->duration : $cdr->billsec;
 149
 150         $seconds += $granularity - ( $seconds % $granularity )
 151           if $seconds      # don't granular-ize 0 billsec calls (bills them)
 152           && $granularity  # 0 is per call
 153           && $seconds % $granularity;
 154         my $minutes = $granularity ? ($seconds / 60) : 1;
 155
 156         my $charge_min = $minutes;
 157
 158         $included_min -= $minutes;
 159         if ( $included_min > 0 ) {
 160           $charge_min = 0;
 161         } else {
 162            $charge_min = 0 - $included_min;
 163            $included_min = 0;
 164         }
 165
 166         my $error = $cdr->set_status_and_rated_price(
 167           'processing-tiered',
 168           '', #charge,
 169           $cust_svc->svcnum,
 170           'inbound'       => ($pass eq 'inbound'),
 171           'rated_minutes' => $charge_min,
 172           'rated_seconds' => $seconds,
 173         );
 174         die $error if $error;
 175
 176         $total += $charge_min;
 177
 178         $cdr_search->adjust(1) if $cdr->freesidestatus eq '';
 179
 180       } # $cdr
 181
 182     } # $pass
 183
 184   } # $cust_svc
 185
 186   ###
 187   # pass two: find a tiered rate and do the rest
 188   ###
 189
 190   my $rate_tier = qsearchs('rate_tier', { tiernum=>$self->option('tiernum') } )
 191     or die "unknown tiernum ". $self->option('tiernum');
 192   my $rate_tier_detail = $rate_tier->rate_tier_detail( $total )
 193     or die "no base rate for tier? ($total)";
 194   my $min_charge = $rate_tier_detail->min_charge;
 195
 196   my $output_format = $self->option('output_format', 'Hush!') || 'default';
 197
 198   my $formatter = FS::detail_format->new($output_format, buffer => $details);
 199
 200   my $charges = 0;
 201
 202   $options{'status'} = 'processing-tiered';
 203
 204   foreach my $cust_svc (@cust_svc) {
 205
 206     my $svc_x;
 207     if( $self->option('bill_inactive_svcs',1) ) {
 208       $svc_x = $cust_svc->h_svc_x($$sdate, $last_bill);
 209     }
 210     else {
 211       $svc_x = $cust_svc->svc_x;
 212     }
 213
 214     foreach my $pass (split('_', $cdr_inout)) {
 215
 216       $options{'inbound'} = ( $pass eq 'inbound' );
 217       # tell the formatter what we're sending it
 218       $formatter->inbound($options{'inbound'});
 219
 220       my $cdr_search = $svc_x->psearch_cdrs(%options);
 221       $cdr_search->limit(1000);
 222       $cdr_search->increment(0);
 223       while ( my $cdr = $cdr_search->fetch ) {
 224
 225         my $object = $options{'inbound'}
 226                        ? $cdr->cdr_termination( 1 ) #1: inbound
 227                        : $cdr;
 228
 229         my $charge_min = $object->rated_minutes;
 230
 231         my $charge = sprintf('%.4f', ( $min_charge * $charge_min )
 232                                      + 0.0000000001 ); #so 1.00005 rounds to 1.0001
 233
 234         if ( $charge > 0 ) {
 235           $charges += $charge;
 236         }
 237
 238         my $error = $cdr->set_status_and_rated_price(
 239           'done',
 240           $charge,
 241           $cust_svc->svcnum,
 242           'inbound'       => $options{'inbound'},
 243           'rated_minutes' => $charge_min,
 244           'rated_seconds' => $object->rated_seconds,
 245         );
 246         die $error if $error;
 247
 248         $formatter->append($cdr);
 249
 250         $cdr_search->adjust(1) if $cdr->freesidestatus eq 'processing-tiered';
 251
 252       } # $cdr
 253
 254     } # $pass
 255
 256   } # $cust_svc
 257
 258   $formatter->finish;
 259   unshift @$details, $formatter->header if @$details;
 260
 261   $charges;
 262 }
 263
 264 1;
 265