FS/FS/part_pkg/voip_cdr.pm

   1 package FS::part_pkg::voip_cdr;
   2
   3 use strict;
   4 use vars qw(@ISA $DEBUG %info);
   5 use Date::Format;
   6 use Tie::IxHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearchs qsearch);
   9 use FS::part_pkg::flat;
  10 use FS::cdr;
  11 use FS::rate;
  12 use FS::rate_prefix;
  13 use FS::rate_detail;
  14
  15 @ISA = qw(FS::part_pkg::prorate);
  16
  17 $DEBUG = 0;
  18
  19 tie my %rating_method, 'Tie::IxHash',
  20   'prefix' => 'Rate calls by using destination prefix to look up a region and rate according to the internal prefix and rate tables',
  21   'upstream' => 'Rate calls based on upstream data: If the call type is "1", map the upstream rate ID directly to an internal rate (rate_detail), otherwise, pass the upstream price through directly.',
  22   'upstream_simple' => 'Simply pass through and charge the "upstream_price" amount.',
  23 ;
  24
  25 #tie my %cdr_location, 'Tie::IxHash',
  26 #  'internal' => 'Internal: CDR records imported into the internal CDR table',
  27 #  'external' => 'External: CDR records queried directly from an external '.
  28 #                'Asterisk (or other?) CDR table',
  29 #;
  30
  31 tie my %temporalities, 'Tie::IxHash',
  32   'upcoming'  => "Upcoming (future)",
  33   'preceding' => "Preceding (past)",
  34 ;
  35
  36 %info = (
  37   'name' => 'VoIP rating by plan of CDR records in an internal (or external) SQL table',
  38   'shortname' => 'VoIP/telco CDR rating (standard)',
  39   'fields' => {
  40     'setup_fee'     => { 'name' => 'Setup fee for this package',
  41                          'default' => 0,
  42                        },
  43     'recur_fee'     => { 'name' => 'Base recurring fee for this package',
  44                          'default' => 0,
  45                        },
  46
  47     #false laziness w/flat.pm
  48     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  49                              'type' => 'select',
  50                              'select_options' => \%temporalities,
  51                            },
  52
  53     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
  54                                    ' of service at cancellation',
  55                          'type' => 'checkbox',
  56                        },
  57
  58     'enable_prorate' => { 'name' => 'Enable prorating of the first month',
  59                           'type' => 'checkbox',
  60                         },
  61
  62     'cutoff_day'    => { 'name' => 'Billing Day (1 - 28) for prorating ',
  63                          'default' => '1',
  64                        },
  65
  66     'rating_method' => { 'name' => 'Region rating method',
  67                          'type' => 'radio',
  68                          'options' => \%rating_method,
  69                        },
  70
  71     'ratenum'   => { 'name' => 'Rate plan',
  72                      'type' => 'select',
  73                      'select_table' => 'rate',
  74                      'select_key'   => 'ratenum',
  75                      'select_label' => 'ratename',
  76                    },
  77
  78     'ignore_unrateable' => { 'name' => 'Ignore calls without a rate in the rate tables.  By default, the system will throw a fatal error upon encountering unrateable calls.',
  79                              'type' => 'checkbox',
  80                            },
  81
  82     'default_prefix' => { 'name'    => 'Default prefix optionally prepended to customer DID numbers when searching for CDR records',
  83                           'default' => '+1',
  84                         },
  85
  86     'disable_src' => { 'name' => 'Disable rating of CDR records based on the "src" field in addition to "charged_party"',
  87                        'type' => 'checkbox'
  88                      },
  89
  90     'domestic_prefix' => { 'name'    => 'Destination prefix for domestic CDR records',
  91                            'default' => '1',
  92                          },
  93
  94 #    'domestic_prefix_required' => { 'name' => 'Require explicit destination prefix for domestic CDR records',
  95 #                                    'type' => 'checkbox',
  96 #                                  },
  97
  98     'international_prefix' => { 'name'    => 'Destination prefix for international CDR records',
  99                                 'default' => '011',
 100                               },
 101
 102     'disable_tollfree' => { 'name' => 'Disable automatic toll-free processing',
 103                             'type' => 'checkbox',
 104                           },
 105
 106     'use_amaflags' => { 'name' => 'Do not charge for CDRs where the amaflags field is not set to "2" ("BILL"/"BILLING").',
 107                         'type' => 'checkbox',
 108                       },
 109
 110     'use_disposition' => { 'name' => 'Do not charge for CDRs where the disposition flag is not set to "ANSWERED".',
 111                            'type' => 'checkbox',
 112                          },
 113
 114     'use_disposition_taqua' => { 'name' => 'Do not charge for CDRs where the disposition is not set to "100" (Taqua).',
 115                                  'type' => 'checkbox',
 116                                },
 117
 118     'use_carrierid' => { 'name' => 'Do not charge for CDRs where the Carrier ID is not set to: ',
 119                          },
 120
 121     'use_cdrtypenum' => { 'name' => 'Do not charge for CDRs where the CDR Type is not set to: ',
 122                          },
 123
 124     'skip_dcontext' => { 'name' => 'Do not charge for CDRs where the dcontext is set to any of these (comma-separated) values:',
 125                        },
 126
 127     'skip_dstchannel_prefix' => { 'name' => 'Do not charge for CDRs where the dstchannel starts with:',
 128                                 },
 129
 130     'skip_dst_length_less' => { 'name' => 'Do not charge for CDRs where the destination is less than this many digits:',
 131                               },
 132
 133     'skip_lastapp' => { 'name' => 'Do not charge for CDRs where the lastapp matches this value',
 134                       },
 135
 136     'use_duration'   => { 'name' => 'Calculate usage based on the duration field instead of the billsec field',
 137                           'type' => 'checkbox',
 138                         },
 139
 140     '411_rewrite' => { 'name' => 'Rewrite these (comma-separated) destination numbers to 411 for rating purposes (also ignore any carrierid check): ',
 141                       },
 142
 143     'output_format' => { 'name' => 'CDR invoice display format',
 144                          'type' => 'select',
 145                          'select_options' => { FS::cdr::invoice_formats() },
 146                          'default'        => 'default', #XXX test
 147                        },
 148
 149     'usage_section' => { 'name' => 'Section in which to place separate usage charges',
 150                        },
 151
 152     'summarize_usage' => { 'name' => 'Include usage summary with recurring charges when usage is in separate section',
 153                           'type' => 'checkbox',
 154                         },
 155
 156     'bill_every_call' => { 'name' => 'Generate an invoice immediately for every call.  Useful for prepaid.',
 157                            'type' => 'checkbox',
 158                          },
 159
 160     #XXX also have option for an external db
 161 #    'cdr_location' => { 'name' => 'CDR database location'
 162 #                        'type' => 'select',
 163 #                        'select_options' => \%cdr_location,
 164 #                        'select_callback' => {
 165 #                          'external' => {
 166 #                            'enable' => [ 'datasrc', 'username', 'password' ],
 167 #                          },
 168 #                          'internal' => {
 169 #                            'disable' => [ 'datasrc', 'username', 'password' ],
 170 #                          }
 171 #                        },
 172 #                      },
 173 #    'datasrc' => { 'name' => 'DBI data source for external CDR table',
 174 #                   'disabled' => 'Y',
 175 #                 },
 176 #    'username' => { 'name' => 'External database username',
 177 #                    'disabled' => 'Y',
 178 #                  },
 179 #    'password' => { 'name' => 'External database password',
 180 #                    'disabled' => 'Y',
 181 #                  },
 182
 183   },
 184   'fieldorder' => [qw(
 185                        setup_fee recur_fee recur_temporality unused_credit
 186                        enable_prorate cutoff_day
 187                        rating_method ratenum ignore_unrateable
 188                        default_prefix
 189                        disable_src
 190                        domestic_prefix international_prefix
 191                        disable_tollfree
 192                        use_amaflags use_disposition
 193                        use_disposition_taqua use_carrierid use_cdrtypenum
 194                        skip_dcontext skip_dstchannel_prefix
 195                        skip_dst_length_less skip_lastapp
 196                        use_duration
 197                        411_rewrite
 198                        output_format summarize_usage usage_section
 199                        bill_every_call
 200                      )
 201                   ],
 202   'weight' => 40,
 203 );
 204
 205 sub calc_setup {
 206   my($self, $cust_pkg ) = @_;
 207   $self->option('setup_fee');
 208 }
 209
 210 #false laziness w/voip_sqlradacct calc_recur resolve it if that one ever gets used again
 211 sub calc_recur {
 212   my $self = shift;
 213   my($cust_pkg, $sdate, $details, $param ) = @_;
 214
 215   #my $last_bill = $cust_pkg->last_bill;
 216   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 217
 218   return 0
 219     if $self->option('recur_temporality', 1) eq 'preceding'
 220     && ( $last_bill eq '' || $last_bill == 0 );
 221
 222   my $ratenum = $cust_pkg->part_pkg->option('ratenum');
 223
 224   my $spool_cdr = $cust_pkg->cust_main->spool_cdr;
 225
 226   my %included_min = ();
 227
 228   my $charges = 0;
 229
 230   my $downstream_cdr = '';
 231
 232   my $rating_method     = $self->option('rating_method') || 'prefix';
 233   my $intl              = $self->option('international_prefix') || '011';
 234   my $domestic_prefix   = $self->option('domestic_prefix');
 235   my $disable_tollfree  = $self->option('disable_tollfree');
 236   my $ignore_unrateable = $self->option('ignore_unrateable', 'Hush!');
 237   my $use_duration      = $self->option('use_duration');
 238
 239   my $output_format     = $self->option('output_format', 'Hush!')
 240                           || ( $rating_method eq 'upstream_simple'
 241                                  ? 'simple'
 242                                  : 'default'
 243                              );
 244
 245   my @dirass = ();
 246   if ( $self->option('411_rewrite') ) {
 247     my $dirass = $self->option('411_rewrite');
 248     $dirass =~ s/\s//g;
 249     @dirass = split(',', $dirass);
 250   }
 251
 252   #for check_chargable, so we don't keep looking up options inside the loop
 253   my %opt_cache = ();
 254
 255   eval "use Text::CSV_XS;";
 256   die $@ if $@;
 257   my $csv = new Text::CSV_XS;
 258
 259   foreach my $cust_svc (
 260     grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc
 261   ) {
 262
 263     foreach my $cdr (
 264       $cust_svc->get_cdrs_for_update(
 265         'disable_src'    => $self->option('disable_src'),
 266         'default_prefix' => $self->option('default_prefix'),
 267       )  # $last_bill, $$sdate )
 268     ) {
 269       if ( $DEBUG > 1 ) {
 270         warn "rating CDR $cdr\n".
 271              join('', map { "  $_ => ". $cdr->{$_}. "\n" } keys %$cdr );
 272       }
 273
 274       my $rate_detail;
 275       my( $rate_region, $regionnum );
 276       my $pretty_destnum;
 277       my $charge = '';
 278       my $classnum = '';
 279       my @call_details = ();
 280       if ( $rating_method eq 'prefix' ) {
 281
 282         my $da_rewrote = 0;
 283         if ( length($cdr->dst) && grep { $cdr->dst eq $_ } @dirass ){
 284           $cdr->dst('411');
 285           $da_rewrote = 1;
 286         }
 287
 288         my $reason = $self->check_chargable( $cdr,
 289                                              'da_rewrote'   => $da_rewrote,
 290                                              'option_cache' => \%opt_cache,
 291                                            );
 292
 293         if ( $reason ) {
 294
 295           warn "not charging for CDR ($reason)\n" if $DEBUG;
 296           $charge = 0;
 297
 298         } else {
 299
 300           ###
 301           # look up rate details based on called station id
 302           # (or calling station id for toll free calls)
 303           ###
 304
 305           my( $to_or_from, $number );
 306           if ( $cdr->dst =~ /^(\+?1)?8([02-8])\1/
 307                && ! $disable_tollfree
 308               )
 309           { #tollfree call
 310             $to_or_from = 'from';
 311             $number = $cdr->src;
 312           } else { #regular call
 313             $to_or_from = 'to';
 314             $number = $cdr->dst;
 315           }
 316
 317           warn "parsing call $to_or_from $number\n" if $DEBUG;
 318
 319           #remove non-phone# stuff and whitespace
 320           $number =~ s/\s//g;
 321 #          my $proto = '';
 322 #          $dest =~ s/^(\w+):// and $proto = $1; #sip:
 323 #          my $siphost = '';
 324 #          $dest =~ s/\@(.*)$// and $siphost = $1; # @10.54.32.1, @sip.example.com
 325
 326           #determine the country code
 327           my $countrycode;
 328           if (    $number =~ /^$intl(((\d)(\d))(\d))(\d+)$/
 329                || $number =~ /^\+(((\d)(\d))(\d))(\d+)$/
 330              )
 331           {
 332
 333             my( $three, $two, $one, $u1, $u2, $rest ) = ( $1,$2,$3,$4,$5,$6 );
 334             #first look for 1 digit country code
 335             if ( qsearch('rate_prefix', { 'countrycode' => $one } ) ) {
 336               $countrycode = $one;
 337               $number = $u1.$u2.$rest;
 338             } elsif ( qsearch('rate_prefix', { 'countrycode' => $two } ) ) { #or 2
 339               $countrycode = $two;
 340               $number = $u2.$rest;
 341             } else { #3 digit country code
 342               $countrycode = $three;
 343               $number = $rest;
 344             }
 345
 346           } else {
 347             $countrycode = $domestic_prefix || '1';
 348             $number =~ s/^$countrycode//;# if length($number) > 10;
 349           }
 350
 351           warn "rating call $to_or_from +$countrycode $number\n" if $DEBUG;
 352           $pretty_destnum = "+$countrycode $number";
 353
 354           my $rate = qsearchs('rate', { 'ratenum' => $ratenum })
 355             or die "ratenum $ratenum not found!";
 356
 357           $rate_detail = $rate->dest_detail({ 'countrycode' => $countrycode,
 358                                               'phonenum'    => $number,
 359                                             });
 360
 361           if ( $rate_detail ) {
 362
 363             $rate_region = $rate_detail->dest_region;
 364             $regionnum = $rate_region->regionnum;
 365             warn "  found rate for regionnum $regionnum ".
 366                  "and rate detail $rate_detail\n"
 367               if $DEBUG;
 368
 369           } elsif ( $ignore_unrateable ) {
 370
 371             $rate_region = '';
 372             $regionnum = '';
 373             #code below will throw a warning & skip
 374
 375           } else {
 376
 377             die "FATAL: no rate_detail found in ".
 378                 $rate->ratenum. ":". $rate->ratename. " rate plan ".
 379                 "for +$countrycode $number (CDR acctid ". $cdr->acctid. "); ".
 380                 "add a rate or set ignore_unrateable flag on the package def\n";
 381           }
 382
 383         }
 384
 385       } elsif ( $rating_method eq 'upstream' ) { #XXX this was convergent, not currently used.  very much becoming the odd one out. remove?
 386
 387         if ( $cdr->cdrtypenum == 1 ) { #rate based on upstream rateid
 388
 389           $rate_detail = $cdr->cdr_upstream_rate->rate_detail;
 390
 391           $regionnum = $rate_detail->dest_regionnum;
 392           $rate_region = $rate_detail->dest_region;
 393
 394           $pretty_destnum = $cdr->dst;
 395
 396           warn "  found rate for regionnum $regionnum and ".
 397                "rate detail $rate_detail\n"
 398             if $DEBUG;
 399
 400         } else { #pass upstream price through
 401
 402           $charge = sprintf('%.2f', $cdr->upstream_price);
 403           $charges += $charge;
 404
 405           @call_details = (
 406             #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 407             time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 408             'N/A', #minutes...
 409             '$'.$charge,
 410             #$pretty_destnum,
 411             $cdr->description, #$rate_region->regionname,
 412           );
 413
 414         }
 415
 416       } elsif ( $rating_method eq 'upstream_simple' ) {
 417
 418         #XXX $charge = sprintf('%.2f', $cdr->upstream_price);
 419         $charge = sprintf('%.3f', $cdr->upstream_price);
 420         $charges += $charge;
 421
 422         @call_details = ($cdr->downstream_csv( 'format' => $output_format,
 423                                                'charge' => $charge,
 424                                              )
 425                         );
 426         $classnum = $cdr->calltypenum;
 427
 428       } else {
 429         die "don't know how to rate CDRs using method: $rating_method\n";
 430       }
 431
 432       ###
 433       # find the price and add detail to the invoice
 434       ###
 435
 436       # if $rate_detail is not found, skip this CDR... i.e.
 437       # don't add it to invoice, don't set its status to done,
 438       # don't call downstream_csv or something on it...
 439       # but DO emit a warning...
 440       #if ( ! $rate_detail && ! scalar(@call_details) ) {}
 441       if ( ! $rate_detail && $charge eq '' ) {
 442
 443         warn "no rate_detail found for CDR.acctid: ". $cdr->acctid.
 444              "; skipping\n"
 445
 446       } else { # there *is* a rate_detail (or call_details), proceed...
 447
 448         unless ( @call_details || ( $charge ne '' && $charge == 0 ) ) {
 449
 450           $included_min{$regionnum} = $rate_detail->min_included
 451             unless exists $included_min{$regionnum};
 452
 453           my $granularity = $rate_detail->sec_granularity;
 454
 455                       # length($cdr->billsec) ? $cdr->billsec : $cdr->duration;
 456           my $seconds = $use_duration ? $cdr->duration : $cdr->billsec;
 457
 458           $seconds += $granularity - ( $seconds % $granularity )
 459             if $seconds      # don't granular-ize 0 billsec calls (bills them)
 460             && $granularity; # 0 is per call
 461           my $minutes = sprintf("%.1f", $seconds / 60);
 462           $minutes =~ s/\.0$// if $granularity == 60;
 463
 464           # per call rather than per minute
 465           $minutes = 1 unless $granularity;
 466
 467           $included_min{$regionnum} -= $minutes;
 468
 469           if ( $included_min{$regionnum} < 0 ) {
 470             my $charge_min = 0 - $included_min{$regionnum}; #XXX should preserve
 471                                                             #(display?) this
 472             $included_min{$regionnum} = 0;
 473             $charge = sprintf('%.2f', ( $rate_detail->min_charge * $charge_min )
 474                                       + 0.00000001 ); #so 1.005 rounds to 1.01
 475             $charges += $charge;
 476           }
 477
 478           # this is why we need regionnum/rate_region....
 479           warn "  (rate region $rate_region)\n" if $DEBUG;
 480
 481           @call_details = (
 482            $cdr->downstream_csv( 'format'         => $output_format,
 483                                  'granularity'    => $granularity,
 484                                  'minutes'        => $minutes,
 485                                  'charge'         => $charge,
 486                                  'pretty_dst'     => $pretty_destnum,
 487                                  'dst_regionname' => $rate_region->regionname,
 488                                )
 489           );
 490
 491           $classnum = $rate_detail->classnum;
 492
 493         }
 494
 495         if ( $charge > 0 ) {
 496           #just use FS::cust_bill_pkg_detail objects?
 497           my $call_details;
 498
 499           #if ( $self->option('rating_method') eq 'upstream_simple' ) {
 500           if ( scalar(@call_details) == 1 ) {
 501             $call_details = [ 'C', $call_details[0], $charge, $classnum ];
 502           } else { #only used for $rating_method eq 'upstream' now
 503             $csv->combine(@call_details);
 504             $call_details = [ 'C', $csv->string, $charge, $classnum ];
 505           }
 506           warn "  adding details on charge to invoice: [ ".
 507               join(', ', @{$call_details} ). " ]"
 508             if ( $DEBUG && ref($call_details) );
 509           push @$details, $call_details; #\@call_details,
 510         }
 511
 512         # if the customer flag is on, call "downstream_csv" or something
 513         # like it to export the call downstream!
 514         # XXX price plan option to pick format, or something...
 515         $downstream_cdr .= $cdr->downstream_csv( 'format' => 'convergent' )
 516           if $spool_cdr;
 517
 518         my $error = $cdr->set_status_and_rated_price('done', $charge);
 519         die $error if $error;
 520
 521       }
 522
 523     } # $cdr
 524
 525   } # $cust_svc
 526
 527   unshift @$details, [ 'C', FS::cdr::invoice_header($output_format) ]
 528     if @$details && $rating_method ne 'upstream';
 529
 530   if ( $spool_cdr && length($downstream_cdr) ) {
 531
 532     use FS::UID qw(datasrc);
 533     my $dir = '/usr/local/etc/freeside/export.'. datasrc. '/cdr';
 534     mkdir $dir, 0700 unless -d $dir;
 535     $dir .= '/'. $cust_pkg->custnum.
 536     mkdir $dir, 0700 unless -d $dir;
 537     my $filename = time2str("$dir/CDR%Y%m%d-spool.CSV", time); #XXX invoice date instead?  would require changing the order things are generated in cust_main::bill insert cust_bill first - with transactions it could be done though
 538
 539     push @{ $param->{'precommit_hooks'} },
 540          sub {
 541                #lock the downstream spool file and append the records
 542                use Fcntl qw(:flock);
 543                use IO::File;
 544                my $spool = new IO::File ">>$filename"
 545                  or die "can't open $filename: $!\n";
 546                flock( $spool, LOCK_EX)
 547                  or die "can't lock $filename: $!\n";
 548                seek($spool, 0, 2)
 549                  or die "can't seek to end of $filename: $!\n";
 550                print $spool $downstream_cdr;
 551                flock( $spool, LOCK_UN );
 552                close $spool;
 553              };
 554
 555   } #if ( $spool_cdr && length($downstream_cdr) )
 556
 557   if ($param->{'increment_next_bill'}) {
 558     if ( $self->option('enable_prorate', 1) ) {
 559       $charges += $self->SUPER::calc_recur(@_);
 560     } else {
 561       $charges += $self->option('recur_fee')
 562     }
 563   }
 564
 565   $charges;
 566 }
 567
 568 #returns a reason why not to rate this CDR, or false if the CDR is chargeable
 569 sub check_chargable {
 570   my( $self, $cdr, %flags ) = @_;
 571
 572   #should have some better way of checking these options from a hash
 573   #or something
 574
 575   my @opt = qw(
 576     use_amaflags
 577     use_disposition
 578     use_disposition_taqua
 579     use_carrierid
 580     use_cdrtypenum
 581     skip_dcontext
 582     skip_dstchannel_prefix
 583     skip_dst_length_less
 584     skip_lastapp
 585   );
 586   foreach my $opt (grep !exists($flags{option_cache}->{$_}), @opt ) {
 587     $flags{option_cache}->{$opt} = $self->option($opt);
 588   }
 589   my %opt = %{ $flags{option_cache} };
 590
 591   return 'amaflags != 2'
 592     if $opt{'use_amaflags'} && $cdr->amaflags != 2;
 593
 594   return 'disposition != ANSWERED'
 595     if $opt{'use_disposition'} && $cdr->disposition ne 'ANSWERED';
 596
 597   return "disposition != 100"
 598     if $opt{'use_disposition_taqua'} && $cdr->disposition != 100;
 599
 600   return "carrierid != $opt{'use_carrierid'}"
 601     if length($opt{'use_carrierid'})
 602     && $cdr->carrierid ne $opt{'use_carrierid'} #ne otherwise 0 matches ''
 603     && ! $flags{'da_rewrote'};
 604
 605   return "cdrtypenum != $opt{'use_cdrtypenum'}"
 606     if length($opt{'use_cdrtypenum'})
 607     && $cdr->cdrtypenum ne $opt{'use_cdrtypenum'}; #ne otherwise 0 matches ''
 608
 609   return "dcontext IN ( $opt{'skip_dcontext'} )"
 610     if $opt{'skip_dcontext'} =~ /\S/
 611     && grep { $cdr->dcontext eq $_ } split(/\s*,\s*/, $opt{'skip_dcontext'});
 612
 613   my $len_prefix = length($opt{'skip_dstchannel_prefix'});
 614   return "dstchannel starts with $opt{'skip_dstchannel_prefix'}"
 615     if $len_prefix
 616     && substr($cdr->dstchannel,0,$len_prefix) eq $opt{'skip_dstchannel_prefix'};
 617
 618   my $dst_length = $opt{'skip_dst_length_less'};
 619   return "destination less than $dst_length digits"
 620     if $dst_length && length($cdr->dst) < $dst_length;
 621
 622   return "lastapp is $opt{'skip_lastapp'}"
 623     if length($opt{'skip_lastapp'}) && $cdr->lastapp eq $opt{'skip_lastapp'};
 624
 625   #all right then, rate it
 626   '';
 627 }
 628
 629 sub is_free {
 630   0;
 631 }
 632
 633 sub base_recur {
 634   my($self, $cust_pkg) = @_;
 635   $self->option('recur_fee');
 636 }
 637
 638 #  This equates svc_phone records; perhaps svc_phone should have a field
 639 #  to indicate it represents a line
 640 sub calc_units {
 641   my($self, $cust_pkg ) = @_;
 642   scalar(grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc);
 643 }
 644
 645 1;
 646