FS/FS/part_pkg/voip_cdr.pm

   1 package FS::part_pkg::voip_cdr;
   2
   3 use strict;
   4 use vars qw(@ISA $DEBUG %info);
   5 use Date::Format;
   6 use Tie::IxHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearchs qsearch);
   9 use FS::part_pkg::flat;
  10 use FS::cdr;
  11 #use FS::rate;
  12 #use FS::rate_prefix;
  13
  14 @ISA = qw(FS::part_pkg::flat);
  15
  16 $DEBUG = 1;
  17
  18 tie my %rating_method, 'Tie::IxHash',
  19   'prefix' => 'Rate calls by using destination prefix to look up a region and rate according to the internal prefix and rate tables',
  20   'upstream' => 'Rate calls based on upstream data: If the call type is "1", map the upstream rate ID directly to an internal rate (rate_detail), otherwise, pass the upstream price through directly.',
  21   'upstream_simple' => 'Simply pass through and charge the "upstream_price" amount.',
  22 ;
  23
  24 #tie my %cdr_location, 'Tie::IxHash',
  25 #  'internal' => 'Internal: CDR records imported into the internal CDR table',
  26 #  'external' => 'External: CDR records queried directly from an external '.
  27 #                'Asterisk (or other?) CDR table',
  28 #;
  29
  30 %info = (
  31   'name' => 'VoIP rating by plan of CDR records in an internal (or external) SQL table',
  32   'shortname' => 'VoIP/telco CDR rating (standard)',
  33   'fields' => {
  34     'setup_fee'     => { 'name' => 'Setup fee for this package',
  35                          'default' => 0,
  36                        },
  37     'recur_fee'     => { 'name' => 'Base recurring fee for this package',
  38                          'default' => 0,
  39                        },
  40     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
  41                                    ' of service at cancellation',
  42                          'type' => 'checkbox',
  43                        },
  44     'ratenum'   => { 'name' => 'Rate plan',
  45                      'type' => 'select',
  46                      'select_table' => 'rate',
  47                      'select_key'   => 'ratenum',
  48                      'select_label' => 'ratename',
  49                    },
  50     'rating_method' => { 'name' => 'Region rating method',
  51                          'type' => 'radio',
  52                          'options' => \%rating_method,
  53                        },
  54
  55     'default_prefix' => { 'name'    => 'Default prefix optionally prepended to customer DID numbers when searching for CDR records',
  56                           'default' => '+1',
  57                         },
  58
  59     'disable_src' => { 'name' => 'Disable rating of CDR records based on the "src" field in addition to "charged_party"',
  60                        'type' => 'checkbox'
  61                      },
  62
  63     'domestic_prefix' => { 'name'    => 'Destination prefix for domestic CDR records',
  64                            'default' => '1',
  65                          },
  66
  67 #    'domestic_prefix_required' => { 'name' => 'Require explicit destination prefix for domestic CDR records',
  68 #                                    'type' => 'checkbox',
  69 #                                  },
  70
  71     'international_prefix' => { 'name'    => 'Destination prefix for international CDR records',
  72                                 'default' => '011',
  73                               },
  74
  75     'use_amaflags' => { 'name' => 'Do not charge for CDRs where the amaflags field is not set to "2" ("BILL"/"BILLING").',
  76                         'type' => 'checkbox',
  77                       },
  78
  79     'use_disposition' => { 'name' => 'Do not charge for CDRs where the disposition flag is not set to "ANSWERED".',
  80                            'type' => 'checkbox',
  81                          },
  82
  83     'output_format' => { 'name' => 'Simple output format',
  84                          'type' => 'select',
  85                          'select_options' => { FS::cdr::invoice_formats() },
  86                        },
  87
  88     #XXX also have option for an external db
  89 #    'cdr_location' => { 'name' => 'CDR database location'
  90 #                        'type' => 'select',
  91 #                        'select_options' => \%cdr_location,
  92 #                        'select_callback' => {
  93 #                          'external' => {
  94 #                            'enable' => [ 'datasrc', 'username', 'password' ],
  95 #                          },
  96 #                          'internal' => {
  97 #                            'disable' => [ 'datasrc', 'username', 'password' ],
  98 #                          }
  99 #                        },
 100 #                      },
 101 #    'datasrc' => { 'name' => 'DBI data source for external CDR table',
 102 #                   'disabled' => 'Y',
 103 #                 },
 104 #    'username' => { 'name' => 'External database username',
 105 #                    'disabled' => 'Y',
 106 #                  },
 107 #    'password' => { 'name' => 'External database password',
 108 #                    'disabled' => 'Y',
 109 #                  },
 110
 111   },
 112   'fieldorder' => [qw(
 113                        setup_fee recur_fee unused_credit
 114                        rating_method ratenum
 115                        default_prefix
 116                        disable_src
 117                        domestic_prefix international_prefix
 118                        use_amaflags use_disposition output_format
 119                      )
 120                   ],
 121   'weight' => 40,
 122 );
 123
 124 sub calc_setup {
 125   my($self, $cust_pkg ) = @_;
 126   $self->option('setup_fee');
 127 }
 128
 129 #false laziness w/voip_sqlradacct... resolve it if that one ever gets used again
 130 sub calc_recur {
 131   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 132
 133   my $last_bill = $cust_pkg->last_bill;
 134
 135   my $ratenum = $cust_pkg->part_pkg->option('ratenum');
 136
 137   my $spool_cdr = $cust_pkg->cust_main->spool_cdr;
 138
 139   my %included_min = ();
 140
 141   my $charges = 0;
 142
 143   my $downstream_cdr = '';
 144
 145   my $output_format = $self->option('output_format', 'Hush!')
 146                       || 'voxlinesystems';
 147
 148   foreach my $cust_svc (
 149     grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc
 150   ) {
 151
 152     foreach my $cdr (
 153       $cust_svc->get_cdrs_for_update( 'disable_src'    => $self->option('disable_src'),
 154                                       'default_prefix' => $self->option('default_prefix'),
 155                                     )  # $last_bill, $$sdate )
 156     ) {
 157       if ( $DEBUG > 1 ) {
 158         warn "rating CDR $cdr\n".
 159              join('', map { "  $_ => ". $cdr->{$_}. "\n" } keys %$cdr );
 160       }
 161
 162       my $rate_detail;
 163       my( $rate_region, $regionnum );
 164       my $pretty_destnum;
 165       my $charge = '';
 166       my @call_details = ();
 167       if ( $self->option('rating_method') eq 'prefix'
 168            || ! $self->option('rating_method')
 169          )
 170       {
 171
 172         if ( $self->option('use_amaflags') && $cdr->amaflags != 2 ) {
 173
 174           warn "not charging for CDR (amaflags != 2)\n" if $DEBUG;
 175           $charge = 0;
 176
 177         } elsif ( $self->option('use_disposition')
 178                   && $cdr->disposition ne 'ANSWERED' ) {
 179
 180           warn "not charging for CDR (disposition != ANSWERED)\n" if $DEBUG;
 181           $charge = 0;
 182
 183         } else {
 184
 185           ###
 186           # look up rate details based on called station id
 187           # (or calling station id for toll free calls)
 188           ###
 189
 190           my( $to_or_from, $number );
 191           if ( $cdr->dst =~ /^(\+?1)?8([02-8])\1/ ) { #tollfree call
 192             $to_or_from = 'from';
 193             $number = $cdr->src;
 194           } else { #regular call
 195             $to_or_from = 'to';
 196             $number = $cdr->dst;
 197           }
 198
 199           #remove non-phone# stuff and whitespace
 200           $number =~ s/\s//g;
 201 #          my $proto = '';
 202 #          $dest =~ s/^(\w+):// and $proto = $1; #sip:
 203 #          my $siphost = '';
 204 #          $dest =~ s/\@(.*)$// and $siphost = $1; # @10.54.32.1, @sip.example.com
 205
 206           my $intl = $self->option('international_prefix') || '011';
 207
 208           #determine the country code
 209           my $countrycode;
 210           if (    $number =~ /^$intl(((\d)(\d))(\d))(\d+)$/
 211                || $number =~ /^\+(((\d)(\d))(\d))(\d+)$/
 212              )
 213           {
 214
 215             my( $three, $two, $one, $u1, $u2, $rest ) = ( $1,$2,$3,$4,$5,$6 );
 216             #first look for 1 digit country code
 217             if ( qsearch('rate_prefix', { 'countrycode' => $one } ) ) {
 218               $countrycode = $one;
 219               $number = $u1.$u2.$rest;
 220             } elsif ( qsearch('rate_prefix', { 'countrycode' => $two } ) ) { #or 2
 221               $countrycode = $two;
 222               $number = $u2.$rest;
 223             } else { #3 digit country code
 224               $countrycode = $three;
 225               $number = $rest;
 226             }
 227
 228           } else {
 229             $countrycode = $self->option('domestic_prefix') || '1';
 230             $number =~ s/^$countrycode//;# if length($number) > 10;
 231           }
 232
 233           warn "rating call $to_or_from +$countrycode $number\n" if $DEBUG;
 234           $pretty_destnum = "+$countrycode $number";
 235
 236           #find a rate prefix, first look at most specific (4 digits) then 3, etc.,
 237           # finally trying the country code only
 238           my $rate_prefix = '';
 239           for my $len ( reverse(1..6) ) {
 240             $rate_prefix = qsearchs('rate_prefix', {
 241               'countrycode' => $countrycode,
 242               #'npa'         => { op=> 'LIKE', value=> substr($number, 0, $len) }
 243               'npa'         => substr($number, 0, $len),
 244             } ) and last;
 245           }
 246           $rate_prefix ||= qsearchs('rate_prefix', {
 247             'countrycode' => $countrycode,
 248             'npa'         => '',
 249           });
 250
 251           #
 252           die "Can't find rate for call $to_or_from +$countrycode $number\n"
 253             unless $rate_prefix;
 254
 255           $regionnum = $rate_prefix->regionnum;
 256           $rate_detail = qsearchs('rate_detail', {
 257             'ratenum'        => $ratenum,
 258             'dest_regionnum' => $regionnum,
 259           } );
 260
 261           $rate_region = $rate_prefix->rate_region;
 262
 263           warn "  found rate for regionnum $regionnum ".
 264                "and rate detail $rate_detail\n"
 265             if $DEBUG;
 266
 267         }
 268
 269       } elsif ( $self->option('rating_method') eq 'upstream' ) {
 270
 271         if ( $cdr->cdrtypenum == 1 ) { #rate based on upstream rateid
 272
 273           $rate_detail = $cdr->cdr_upstream_rate->rate_detail;
 274
 275           $regionnum = $rate_detail->dest_regionnum;
 276           $rate_region = $rate_detail->dest_region;
 277
 278           $pretty_destnum = $cdr->dst;
 279
 280           warn "  found rate for regionnum $regionnum and ".
 281                "rate detail $rate_detail\n"
 282             if $DEBUG;
 283
 284         } else { #pass upstream price through
 285
 286           $charge = sprintf('%.2f', $cdr->upstream_price);
 287           $charges += $charge;
 288
 289           @call_details = (
 290             #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 291             time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 292             'N/A', #minutes...
 293             '$'.$charge,
 294             #$pretty_destnum,
 295             $cdr->description, #$rate_region->regionname,
 296           );
 297
 298         }
 299
 300       } elsif ( $self->option('rating_method') eq 'upstream_simple' ) {
 301
 302         #XXX $charge = sprintf('%.2f', $cdr->upstream_price);
 303         $charge = sprintf('%.3f', $cdr->upstream_price);
 304         $charges += $charge;
 305
 306         @call_details = ($cdr->downstream_csv( 'format' => $output_format ));
 307
 308       } else {
 309         die "don't know how to rate CDRs using method: ".
 310             $self->option('rating_method'). "\n";
 311       }
 312
 313       ###
 314       # find the price and add detail to the invoice
 315       ###
 316
 317       # if $rate_detail is not found, skip this CDR... i.e.
 318       # don't add it to invoice, don't set its status to NULL,
 319       # don't call downstream_csv or something on it...
 320       # but DO emit a warning...
 321       #if ( ! $rate_detail && ! scalar(@call_details) ) {
 322       if ( ! $rate_detail && $charge eq '' ) {
 323
 324         warn "no rate_detail found for CDR.acctid:  ". $cdr->acctid.
 325              "; skipping\n"
 326
 327       } else { # there *is* a rate_detail (or call_details), proceed...
 328
 329         unless ( @call_details || ( $charge ne '' && $charge == 0 ) ) {
 330
 331           $included_min{$regionnum} = $rate_detail->min_included
 332             unless exists $included_min{$regionnum};
 333
 334           my $granularity = $rate_detail->sec_granularity;
 335           my $seconds = $cdr->billsec; # length($cdr->billsec) ? $cdr->billsec : $cdr->duration;
 336           $seconds += $granularity - ( $seconds % $granularity )
 337             if $seconds      # don't granular-ize 0 billsec calls (bills them)
 338             && $granularity; # 0 is per call
 339           my $minutes = sprintf("%.1f", $seconds / 60);
 340           $minutes =~ s/\.0$// if $granularity == 60;
 341
 342           # per call rather than per minute
 343           $minutes = 1 unless $granularity;
 344
 345           $included_min{$regionnum} -= $minutes;
 346
 347           if ( $included_min{$regionnum} < 0 ) {
 348             my $charge_min = 0 - $included_min{$regionnum};
 349             $included_min{$regionnum} = 0;
 350             $charge = sprintf('%.2f', $rate_detail->min_charge * $charge_min );
 351             $charges += $charge;
 352           }
 353
 354           # this is why we need regionnum/rate_region....
 355           warn "  (rate region $rate_region)\n" if $DEBUG;
 356
 357           @call_details = (
 358             #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 359             time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 360             $granularity ? $minutes.'m' : $minutes.' call',
 361             '$'.$charge,
 362             $pretty_destnum,
 363             $rate_region->regionname,
 364           );
 365
 366         }
 367
 368         if ( $charge > 0 ) {
 369           my $call_details;
 370           if ( $self->option('rating_method') eq 'upstream_simple' ) {
 371             $call_details = [ 'C', $call_details[0] ];
 372           }else{
 373             $call_details = join(' - ', @call_details );
 374           }
 375           warn "  adding details on charge to invoice: $call_details"
 376             if ( $DEBUG && !ref($call_details) );
 377           warn "  adding details on charge to invoice: [ ".
 378               join(', ', @{$call_details} ). " ]"
 379             if ( $DEBUG && ref($call_details) );
 380           push @$details, $call_details; #\@call_details,
 381         }
 382
 383         # if the customer flag is on, call "downstream_csv" or something
 384         # like it to export the call downstream!
 385         # XXX price plan option to pick format, or something...
 386         $downstream_cdr .= $cdr->downstream_csv( 'format' => 'convergent' )
 387           if $spool_cdr;
 388
 389         my $error = $cdr->set_status_and_rated_price('done', $charge);
 390         die $error if $error;
 391
 392       }
 393
 394     } # $cdr
 395
 396     unshift @$details, [ 'C', FS::cdr::invoice_header( $output_format) ]
 397       if (@$details && $self->option('rating_method') eq 'upstream_simple' );
 398
 399   } # $cust_svc
 400
 401   if ( $spool_cdr && length($downstream_cdr) ) {
 402
 403     use FS::UID qw(datasrc);
 404     my $dir = '/usr/local/etc/freeside/export.'. datasrc. '/cdr';
 405     mkdir $dir, 0700 unless -d $dir;
 406     $dir .= '/'. $cust_pkg->custnum.
 407     mkdir $dir, 0700 unless -d $dir;
 408     my $filename = time2str("$dir/CDR%Y%m%d-spool.CSV", time); #XXX invoice date instead?  would require changing the order things are generated in cust_main::bill insert cust_bill first - with transactions it could be done though
 409
 410     push @{ $param->{'precommit_hooks'} },
 411          sub {
 412                #lock the downstream spool file and append the records
 413                use Fcntl qw(:flock);
 414                use IO::File;
 415                my $spool = new IO::File ">>$filename"
 416                  or die "can't open $filename: $!\n";
 417                flock( $spool, LOCK_EX)
 418                  or die "can't lock $filename: $!\n";
 419                seek($spool, 0, 2)
 420                  or die "can't seek to end of $filename: $!\n";
 421                print $spool $downstream_cdr;
 422                flock( $spool, LOCK_UN );
 423                close $spool;
 424              };
 425
 426   } #if ( $spool_cdr && length($downstream_cdr) )
 427
 428   $self->option('recur_fee') + $charges;
 429
 430 }
 431
 432 sub is_free {
 433   0;
 434 }
 435
 436 sub base_recur {
 437   my($self, $cust_pkg) = @_;
 438   $self->option('recur_fee');
 439 }
 440
 441 #  This equates svc_phone records; perhaps svc_phone should have a field
 442 #  to indicate it represents a line
 443 sub calc_units {
 444   my($self, $cust_pkg ) = @_;
 445   scalar(grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc);
 446 }
 447
 448 1;
 449