FS/FS/part_pkg/voip_cdr.pm

   1 package FS::part_pkg::voip_cdr;
   2
   3 use strict;
   4 use vars qw(@ISA $DEBUG %info);
   5 use Date::Format;
   6 use Tie::IxHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearchs qsearch);
   9 use FS::part_pkg::recur_Common;
  10 use FS::cdr;
  11 use FS::rate;
  12 use FS::rate_prefix;
  13 use FS::rate_detail;
  14 use FS::part_pkg::recur_Common;
  15
  16 use List::Util qw(first min);
  17
  18 @ISA = qw(FS::part_pkg::recur_Common);
  19
  20 $DEBUG = 0;
  21
  22 tie my %cdr_svc_method, 'Tie::IxHash',
  23   'svc_phone.phonenum' => 'Phone numbers (svc_phone.phonenum)',
  24   'svc_pbx.title'      => 'PBX name (svc_pbx.title)',
  25   'svc_pbx.svcnum'     => 'Freeside service # (svc_pbx.svcnum)',
  26 ;
  27
  28 tie my %rating_method, 'Tie::IxHash',
  29   'prefix' => 'Rate calls by using destination prefix to look up a region and rate according to the internal prefix and rate tables',
  30 #  'upstream' => 'Rate calls based on upstream data: If the call type is "1", map the upstream rate ID directly to an internal rate (rate_detail), otherwise, pass the upstream price through directly.',
  31   'upstream_simple' => 'Simply pass through and charge the "upstream_price" amount.',
  32   'single_price' => 'A single price per minute for all calls.',
  33 ;
  34
  35 #tie my %cdr_location, 'Tie::IxHash',
  36 #  'internal' => 'Internal: CDR records imported into the internal CDR table',
  37 #  'external' => 'External: CDR records queried directly from an external '.
  38 #                'Asterisk (or other?) CDR table',
  39 #;
  40
  41 tie my %temporalities, 'Tie::IxHash',
  42   'upcoming'  => "Upcoming (future)",
  43   'preceding' => "Preceding (past)",
  44 ;
  45
  46 tie my %granularity, 'Tie::IxHash', FS::rate_detail::granularities();
  47
  48 %info = (
  49   'name' => 'VoIP rating by plan of CDR records in an internal (or external) SQL table',
  50   'shortname' => 'VoIP/telco CDR rating (standard)',
  51   'inherit_fields' => [ 'global_Mixin' ],
  52   'fields' => {
  53     #false laziness w/flat.pm
  54     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  55                              'type' => 'select',
  56                              'select_options' => \%temporalities,
  57                            },
  58
  59     'cutoff_day'    => { 'name' => 'Billing Day (1 - 28) for prorating or '.
  60                                    'subscription',
  61                          'default' => '1',
  62                        },
  63     'add_full_period'=> { 'name' => 'When prorating first month, also bill '.
  64                                     'for one full period after that',
  65                           'type' => 'checkbox',
  66                         },
  67     'recur_method'  => { 'name' => 'Recurring fee method',
  68                          #'type' => 'radio',
  69                          #'options' => \%recur_method,
  70                          'type' => 'select',
  71                          'select_options' => \%FS::part_pkg::recur_Common::recur_method,
  72                        },
  73
  74     'cdr_svc_method' => { 'name' => 'CDR service matching method',
  75                           'type' => 'radio',
  76                           'options' => \%cdr_svc_method,
  77                         },
  78
  79     'rating_method' => { 'name' => 'Rating method',
  80                          'type' => 'radio',
  81                          'options' => \%rating_method,
  82                        },
  83
  84     'ratenum'   => { 'name' => 'Rate plan',
  85                      'type' => 'select',
  86                      'select_table' => 'rate',
  87                      'select_key'   => 'ratenum',
  88                      'select_label' => 'ratename',
  89                    },
  90
  91     'min_included' => { 'name' => 'Minutes included when using "single price per minute" rating method',
  92                     },
  93
  94
  95     'min_charge' => { 'name' => 'Charge per minute when using "single price per minute" rating method',
  96                     },
  97
  98     'sec_granularity' => { 'name' => 'Granularity when using "single price per minute" rating method',
  99                            'type' => 'select',
 100                            'select_options' => \%granularity,
 101                          },
 102
 103     'ignore_unrateable' => { 'name' => 'Ignore calls without a rate in the rate tables.  By default, the system will throw a fatal error upon encountering unrateable calls.',
 104                              'type' => 'checkbox',
 105                            },
 106
 107     'default_prefix' => { 'name'    => 'Default prefix optionally prepended to customer DID numbers when searching for CDR records',
 108                           'default' => '+1',
 109                         },
 110
 111     'disable_src' => { 'name' => 'Disable rating of CDR records based on the "src" field in addition to "charged_party"',
 112                        'type' => 'checkbox'
 113                      },
 114
 115     'domestic_prefix' => { 'name'    => 'Destination prefix for domestic CDR records',
 116                            'default' => '1',
 117                          },
 118
 119 #    'domestic_prefix_required' => { 'name' => 'Require explicit destination prefix for domestic CDR records',
 120 #                                    'type' => 'checkbox',
 121 #                                  },
 122
 123     'international_prefix' => { 'name'    => 'Destination prefix for international CDR records',
 124                                 'default' => '011',
 125                               },
 126
 127     'disable_tollfree' => { 'name' => 'Disable automatic toll-free processing',
 128                             'type' => 'checkbox',
 129                           },
 130
 131     'use_amaflags' => { 'name' => 'Do not charge for CDRs where the amaflags field is not set to "2" ("BILL"/"BILLING").',
 132                         'type' => 'checkbox',
 133                       },
 134
 135     'use_disposition' => { 'name' => 'Do not charge for CDRs where the disposition flag is not set to "ANSWERED".',
 136                            'type' => 'checkbox',
 137                          },
 138
 139     'use_disposition_taqua' => { 'name' => 'Do not charge for CDRs where the disposition is not set to "100" (Taqua).',
 140                                  'type' => 'checkbox',
 141                                },
 142
 143     'use_carrierid' => { 'name' => 'Do not charge for CDRs where the Carrier ID is not set to: ',
 144                          },
 145
 146     'use_cdrtypenum' => { 'name' => 'Do not charge for CDRs where the CDR Type is not set to: ',
 147                          },
 148
 149     'skip_dst_prefix' => { 'name' => 'Do not charge for CDRs where the destination number starts with any of these values: ',
 150     },
 151
 152     'skip_dcontext' => { 'name' => 'Do not charge for CDRs where the dcontext is set to any of these (comma-separated) values: ',
 153                        },
 154
 155     'skip_dstchannel_prefix' => { 'name' => 'Do not charge for CDRs where the dstchannel starts with:',
 156                                 },
 157
 158     'skip_src_length_more' => { 'name' => 'Do not charge for CDRs where the source is more than this many digits:',
 159                               },
 160
 161     'noskip_src_length_accountcode_tollfree' => { 'name' => 'Do charge for CDRs where source is equal or greater than the specified digits, when accountcode is toll free',
 162                                                   'type' => 'checkbox',
 163                                                 },
 164
 165     'accountcode_tollfree_ratenum' => {
 166       'name' => 'Optional alternate rate plan when accountcode is toll free: ',
 167       'type' => 'select',
 168       'select_table'  => 'rate',
 169       'select_key'    => 'ratenum',
 170       'select_label'  => 'ratename',
 171       'disable_empty' => 0,
 172       'empty_label'   => '',
 173     },
 174
 175     'skip_dst_length_less' => { 'name' => 'Do not charge for CDRs where the destination is less than this many digits:',
 176                               },
 177
 178     'noskip_dst_length_accountcode_tollfree' => { 'name' => 'Do charge for CDRs where dst is less than the specified digits, when accountcode is toll free',
 179                                                   'type' => 'checkbox',
 180                                                 },
 181
 182     'skip_lastapp' => { 'name' => 'Do not charge for CDRs where the lastapp matches this value: ',
 183                       },
 184
 185     'skip_max_callers' => { 'name' => 'Do not charge for CDRs where max_callers is less than or equal to this value: ',
 186                           },
 187
 188     'use_duration'   => { 'name' => 'Calculate usage based on the duration field instead of the billsec field',
 189                           'type' => 'checkbox',
 190                         },
 191
 192     '411_rewrite' => { 'name' => 'Rewrite these (comma-separated) destination numbers to 411 for rating purposes (also ignore any carrierid check): ',
 193                       },
 194
 195     #false laziness w/cdr_termination.pm
 196     'output_format' => { 'name' => 'CDR invoice display format',
 197                          'type' => 'select',
 198                          'select_options' => { FS::cdr::invoice_formats() },
 199                          'default'        => 'default', #XXX test
 200                        },
 201
 202     'usage_section' => { 'name' => 'Section in which to place usage charges (whether separated or not): ',
 203                        },
 204
 205     'summarize_usage' => { 'name' => 'Include usage summary with recurring charges when usage is in separate section',
 206                           'type' => 'checkbox',
 207                         },
 208
 209     'usage_mandate' => { 'name' => 'Always put usage details in separate section',
 210                           'type' => 'checkbox',
 211                        },
 212     #eofalse
 213
 214     'bill_every_call' => { 'name' => 'Generate an invoice immediately for every call (as well any setup fee, upon first payment).  Useful for prepaid.',
 215                            'type' => 'checkbox',
 216                          },
 217
 218     'bill_inactive_svcs' => { 'name' => 'Bill for all phone numbers that were active during the billing period',
 219                               'type' => 'checkbox',
 220                             },
 221
 222     'count_available_phones' => { 'name' => 'Consider for tax purposes the number of lines to be svc_phones that may be provisioned rather than those that actually are.',
 223                            'type' => 'checkbox',
 224                          },
 225
 226     #XXX also have option for an external db
 227 #    'cdr_location' => { 'name' => 'CDR database location'
 228 #                        'type' => 'select',
 229 #                        'select_options' => \%cdr_location,
 230 #                        'select_callback' => {
 231 #                          'external' => {
 232 #                            'enable' => [ 'datasrc', 'username', 'password' ],
 233 #                          },
 234 #                          'internal' => {
 235 #                            'disable' => [ 'datasrc', 'username', 'password' ],
 236 #                          }
 237 #                        },
 238 #                      },
 239 #    'datasrc' => { 'name' => 'DBI data source for external CDR table',
 240 #                   'disabled' => 'Y',
 241 #                 },
 242 #    'username' => { 'name' => 'External database username',
 243 #                    'disabled' => 'Y',
 244 #                  },
 245 #    'password' => { 'name' => 'External database password',
 246 #                    'disabled' => 'Y',
 247 #                  },
 248
 249   },
 250   'fieldorder' => [qw(
 251                        recur_temporality
 252                        recur_method cutoff_day
 253                        add_full_period
 254                        cdr_svc_method
 255                        rating_method ratenum min_charge sec_granularity
 256                        ignore_unrateable
 257                        default_prefix
 258                        disable_src
 259                        domestic_prefix international_prefix
 260                        disable_tollfree
 261                        use_amaflags use_disposition
 262                        use_disposition_taqua use_carrierid use_cdrtypenum
 263                        skip_dcontext skip_dst_prefix
 264                        skip_dstchannel_prefix skip_src_length_more
 265                        noskip_src_length_accountcode_tollfree
 266                        accountcode_tollfree_ratenum
 267                        skip_dst_length_less
 268                        noskip_dst_length_accountcode_tollfree
 269                        skip_lastapp
 270                        skip_max_callers
 271                        use_duration
 272                        411_rewrite
 273                        output_format usage_mandate summarize_usage usage_section
 274                        bill_every_call bill_inactive_svcs
 275                        count_available_phones
 276                      )
 277                   ],
 278   'weight' => 40,
 279 );
 280
 281 sub calc_setup {
 282   my($self, $cust_pkg ) = @_;
 283   $self->option('setup_fee');
 284 }
 285
 286 sub calc_recur {
 287   my $self = shift;
 288   my($cust_pkg, $sdate, $details, $param ) = @_;
 289
 290   my $charges = 0;
 291
 292   $charges += $self->calc_usage(@_);
 293   $charges += $self->calc_recur_Common(@_);
 294
 295   $charges;
 296
 297 }
 298
 299 sub calc_cancel {
 300   my $self = shift;
 301   my($cust_pkg, $sdate, $details, $param ) = @_;
 302
 303   $self->calc_usage(@_);
 304 }
 305
 306 #false laziness w/voip_sqlradacct calc_recur resolve it if that one ever gets used again
 307
 308 sub calc_usage {
 309   my $self = shift;
 310   my($cust_pkg, $sdate, $details, $param ) = @_;
 311
 312   #my $last_bill = $cust_pkg->last_bill;
 313   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 314
 315   return 0
 316     if $self->option('recur_temporality', 1) eq 'preceding'
 317     && ( $last_bill eq '' || $last_bill == 0 );
 318
 319   my $ratenum = $cust_pkg->part_pkg->option('ratenum');
 320
 321   my $spool_cdr = $cust_pkg->cust_main->spool_cdr;
 322
 323   my %included_min = ();
 324
 325   my $charges = 0;
 326
 327 #  my $downstream_cdr = '';
 328
 329   my $cdr_svc_method    = $self->option('cdr_svc_method',1)||'svc_phone.phonenum';
 330   my $rating_method     = $self->option('rating_method') || 'prefix';
 331   my $intl              = $self->option('international_prefix') || '011';
 332   my $domestic_prefix   = $self->option('domestic_prefix');
 333   my $disable_tollfree  = $self->option('disable_tollfree');
 334   my $ignore_unrateable = $self->option('ignore_unrateable', 'Hush!');
 335   my $use_duration      = $self->option('use_duration');
 336
 337   my $output_format     = $self->option('output_format', 'Hush!')
 338                           || ( $rating_method eq 'upstream_simple'
 339                                  ? 'simple'
 340                                  : 'default'
 341                              );
 342
 343   my @dirass = ();
 344   if ( $self->option('411_rewrite') ) {
 345     my $dirass = $self->option('411_rewrite');
 346     $dirass =~ s/\s//g;
 347     @dirass = split(',', $dirass);
 348   }
 349
 350   my %interval_cache = (); # for timed rates
 351
 352   #for check_chargable, so we don't keep looking up options inside the loop
 353   my %opt_cache = ();
 354
 355   eval "use Text::CSV_XS;";
 356   die $@ if $@;
 357   my $csv = new Text::CSV_XS;
 358
 359   my($svc_table, $svc_field) = split('\.', $cdr_svc_method);
 360
 361   my @cust_svc;
 362   if( $self->option('bill_inactive_svcs',1) ) {
 363     #XXX in this mode do we need to restrict the set of CDRs by date also?
 364     @cust_svc = $cust_pkg->h_cust_svc($$sdate, $last_bill);
 365   }
 366   else {
 367     @cust_svc = $cust_pkg->cust_svc;
 368   }
 369   @cust_svc = grep { $_->part_svc->svcdb eq $svc_table } @cust_svc;
 370
 371   foreach my $cust_svc (@cust_svc) {
 372
 373     my $svc_x;
 374     if( $self->option('bill_inactive_svcs',1) ) {
 375       $svc_x = $cust_svc->h_svc_x($$sdate, $last_bill);
 376     }
 377     else {
 378       $svc_x = $cust_svc->svc_x;
 379     }
 380     my %options = (
 381         'disable_src'    => $self->option('disable_src'),
 382         'default_prefix' => $self->option('default_prefix'),
 383         'status'         => '',
 384         'for_update'     => 1,
 385       );  # $last_bill, $$sdate )
 386     $options{'by_svcnum'} = 1 if $svc_field eq 'svcnum';
 387
 388     my @invoice_details_sort;
 389
 390     foreach my $cdr (
 391       $svc_x->get_cdrs( %options )
 392     ) {
 393       if ( $DEBUG > 1 ) {
 394         warn "rating CDR $cdr\n".
 395              join('', map { "  $_ => ". $cdr->{$_}. "\n" } keys %$cdr );
 396       }
 397
 398       my $rate_detail;
 399       my( $rate_region, $regionnum );
 400       my $rate;
 401       my $pretty_destnum;
 402       my $charge = '';
 403       my $seconds = '';
 404       my $weektime = '';
 405       my $regionname = '';
 406       my $classnum = '';
 407       my $countrycode;
 408       my $number;
 409
 410       my @call_details = ();
 411       if ( $rating_method eq 'prefix' ) {
 412
 413         my $da_rewrote = 0;
 414         if ( length($cdr->dst) && grep { $cdr->dst eq $_ } @dirass ){
 415           $cdr->dst('411');
 416           $da_rewrote = 1;
 417         }
 418
 419         my $reason = $self->check_chargable( $cdr,
 420                                              'da_rewrote'   => $da_rewrote,
 421                                              'option_cache' => \%opt_cache,
 422                                            );
 423
 424         if ( $reason ) {
 425
 426           warn "not charging for CDR ($reason)\n" if $DEBUG;
 427           $charge = 0;
 428
 429         } else {
 430
 431           ###
 432           # look up rate details based on called station id
 433           # (or calling station id for toll free calls)
 434           ###
 435
 436           my( $to_or_from );
 437           if ( $cdr->is_tollfree && ! $disable_tollfree )
 438           { #tollfree call
 439             $to_or_from = 'from';
 440             $number = $cdr->src;
 441           } else { #regular call
 442             $to_or_from = 'to';
 443             $number = $cdr->dst;
 444           }
 445
 446           warn "parsing call $to_or_from $number\n" if $DEBUG;
 447
 448           #remove non-phone# stuff and whitespace
 449           $number =~ s/\s//g;
 450 #          my $proto = '';
 451 #          $dest =~ s/^(\w+):// and $proto = $1; #sip:
 452 #          my $siphost = '';
 453 #          $dest =~ s/\@(.*)$// and $siphost = $1; # @10.54.32.1, @sip.example.com
 454
 455           #determine the country code
 456           $countrycode = '';
 457           if (    $number =~ /^$intl(((\d)(\d))(\d))(\d+)$/
 458                || $number =~ /^\+(((\d)(\d))(\d))(\d+)$/
 459              )
 460           {
 461
 462             my( $three, $two, $one, $u1, $u2, $rest ) = ( $1,$2,$3,$4,$5,$6 );
 463             #first look for 1 digit country code
 464             if ( qsearch('rate_prefix', { 'countrycode' => $one } ) ) {
 465               $countrycode = $one;
 466               $number = $u1.$u2.$rest;
 467             } elsif ( qsearch('rate_prefix', { 'countrycode' => $two } ) ) { #or 2
 468               $countrycode = $two;
 469               $number = $u2.$rest;
 470             } else { #3 digit country code
 471               $countrycode = $three;
 472               $number = $rest;
 473             }
 474
 475           } else {
 476             $countrycode = length($domestic_prefix) ? $domestic_prefix : '1';
 477             $number =~ s/^$countrycode//;# if length($number) > 10;
 478           }
 479
 480           warn "rating call $to_or_from +$countrycode $number\n" if $DEBUG;
 481           $pretty_destnum = "+$countrycode $number";
 482           #asterisks here causes inserting the detail to barf, so:
 483           $pretty_destnum =~ s/\*//g;
 484
 485           my $eff_ratenum = $cdr->is_tollfree('accountcode')
 486             ? $cust_pkg->part_pkg->option('accountcode_tollfree_ratenum')
 487             : '';
 488           $eff_ratenum ||= $ratenum;
 489           $rate = qsearchs('rate', { 'ratenum' => $eff_ratenum })
 490             or die "ratenum $eff_ratenum not found!";
 491
 492           my @ltime = localtime($cdr->startdate);
 493           $weektime = $ltime[0] +
 494                       $ltime[1]*60 +   #minutes
 495                       $ltime[2]*3600 + #hours
 496                       $ltime[6]*86400; #days since sunday
 497           # if there's no timed rate_detail for this time/region combination,
 498           # dest_detail returns the default.  There may still be a timed rate
 499           # that applies after the starttime of the call, so be careful...
 500           $rate_detail = $rate->dest_detail({ 'countrycode' => $countrycode,
 501                                               'phonenum'    => $number,
 502                                               'weektime'    => $weektime,
 503                                             });
 504
 505           if ( $rate_detail ) {
 506
 507             $rate_region = $rate_detail->dest_region;
 508             $regionnum = $rate_region->regionnum;
 509             $regionname = $rate_region->regionname;
 510             warn "  found rate for regionnum $regionnum ".
 511                  "and rate detail $rate_detail\n"
 512               if $DEBUG;
 513
 514             if ( !exists($interval_cache{$regionnum}) ) {
 515               my @intervals = (
 516                 sort { $a->stime <=> $b->stime }
 517                 map { my $r = $_->rate_time; $r ? $r->intervals : () }
 518                 $rate->rate_detail
 519               );
 520               $interval_cache{$regionnum} = \@intervals;
 521               warn "  cached ".scalar(@intervals)." interval(s)\n"
 522                 if $DEBUG;
 523             }
 524
 525           } elsif ( $ignore_unrateable ) {
 526
 527             $rate_region = '';
 528             $regionnum = '';
 529             #code below will throw a warning & skip
 530
 531           } else {
 532
 533             die "FATAL: no rate_detail found in ".
 534                 $rate->ratenum. ":". $rate->ratename. " rate plan ".
 535                 "for +$countrycode $number (CDR acctid ". $cdr->acctid. "); ".
 536                 "add a rate or set ignore_unrateable flag on the package def\n";
 537           }
 538
 539         }
 540
 541       } elsif ( $rating_method eq 'upstream_simple' ) {
 542
 543         #XXX $charge = sprintf('%.2f', $cdr->upstream_price);
 544         $charge = sprintf('%.3f', $cdr->upstream_price);
 545         $charges += $charge;
 546         warn "Incrementing \$charges by $charge.  Now $charges\n" if $DEBUG;
 547
 548         @call_details = ($cdr->downstream_csv( 'format' => $output_format,
 549                                                'charge' => $charge,
 550                                              )
 551                         );
 552         $classnum = $cdr->calltypenum;
 553
 554       } elsif ( $rating_method eq 'single_price' ) {
 555
 556         # a little false laziness w/below
 557         # $rate_detail = new FS::rate_detail({sec_granularity => ... }) ?
 558
 559         my $granularity = length($self->option('sec_granularity'))
 560                             ? $self->option('sec_granularity')
 561                             : 60;
 562
 563         $seconds = $use_duration ? $cdr->duration : $cdr->billsec;
 564
 565         $seconds += $granularity - ( $seconds % $granularity )
 566           if $seconds      # don't granular-ize 0 billsec calls (bills them)
 567           && $granularity  # 0 is per call
 568           && $seconds % $granularity;
 569         my $minutes = $seconds / 60;
 570         # XXX config?
 571         #$charge = sprintf('%.2f', ( $self->option('min_charge') * $minutes )
 572                                   #+ 0.00000001 ); #so 1.005 rounds to 1.01
 573         $charge = sprintf('%.4f', ( $self->option('min_charge') * $minutes )
 574                                   + 0.0000000001 ); #so 1.00005 rounds to 1.0001
 575
 576         warn "Incrementing \$charges by $charge.  Now $charges\n" if $DEBUG;
 577         $charges += $charge;
 578
 579         @call_details = ($cdr->downstream_csv( 'format'  => $output_format,
 580                                                'charge'  => $charge,
 581                                                'seconds' => ($use_duration ?
 582                                                              $cdr->duration :
 583                                                              $cdr->billsec),
 584                                                'granularity' => $granularity,
 585                                              )
 586                         );
 587
 588       } else {
 589         die "don't know how to rate CDRs using method: $rating_method\n";
 590       }
 591
 592       ###
 593       # find the price and add detail to the invoice
 594       ###
 595
 596       # if $rate_detail is not found, skip this CDR... i.e.
 597       # don't add it to invoice, don't set its status to done,
 598       # don't call downstream_csv or something on it...
 599       # but DO emit a warning...
 600       #if ( ! $rate_detail && ! scalar(@call_details) ) {}
 601       if ( ! $rate_detail && $charge eq '' ) {
 602
 603         warn "no rate_detail found for CDR.acctid: ". $cdr->acctid.
 604              "; skipping\n"
 605
 606       } else { # there *is* a rate_detail (or call_details), proceed...
 607         # About this section:
 608         # We don't round _anything_ (except granularizing)
 609         # until the final $charge = sprintf("%.2f"...).
 610
 611         unless ( @call_details || ( $charge ne '' && $charge == 0 ) ) {
 612
 613           my $seconds_left = $use_duration ? $cdr->duration : $cdr->billsec;
 614           # charge for the first (conn_sec) seconds
 615           $seconds = min($seconds_left, $rate_detail->conn_sec);
 616           $seconds_left -= $seconds;
 617           $weektime     += $seconds;
 618           $charge = $rate_detail->conn_charge;
 619
 620           my $etime;
 621           while($seconds_left) {
 622             my $ratetimenum = $rate_detail->ratetimenum; # may be empty
 623
 624             # find the end of the current rate interval
 625             if(@{ $interval_cache{$regionnum} } == 0) {
 626               # There are no timed rates in this group, so just stay
 627               # in the default rate_detail for the entire duration.
 628               # Set an "end" of 1 past the end of the current call.
 629               $etime = $weektime + $seconds_left + 1;
 630             }
 631             elsif($ratetimenum) {
 632               # This is a timed rate, so go to the etime of this interval.
 633               # If it's followed by another timed rate, the stime of that
 634               # interval should match the etime of this one.
 635               my $interval = $rate_detail->rate_time->contains($weektime);
 636               $etime = $interval->etime;
 637             }
 638             else {
 639               # This is a default rate, so use the stime of the next
 640               # interval in the sequence.
 641               my $next_int = first { $_->stime > $weektime }
 642                               @{ $interval_cache{$regionnum} };
 643               if ($next_int) {
 644                 $etime = $next_int->stime;
 645               }
 646               else {
 647                 # weektime is near the end of the week, so decrement
 648                 # it by a full week and use the stime of the first
 649                 # interval.
 650                 $weektime -= (3600*24*7);
 651                 $etime = $interval_cache{$regionnum}->[0]->stime;
 652               }
 653             }
 654
 655             my $charge_sec = min($seconds_left, $etime - $weektime);
 656
 657             $seconds_left -= $charge_sec;
 658
 659             $included_min{$regionnum}{$ratetimenum} = $rate_detail->min_included
 660               unless exists $included_min{$regionnum}{$ratetimenum};
 661
 662             my $granularity = $rate_detail->sec_granularity;
 663
 664             my $minutes;
 665             if ( $granularity ) { # charge per minute
 666               # Round up to the nearest $granularity
 667               if ( $charge_sec and $charge_sec % $granularity ) {
 668                 $charge_sec += $granularity - ($charge_sec % $granularity);
 669               }
 670               $minutes = $charge_sec / 60; #don't round this
 671             }
 672             else { # per call
 673               $minutes = 1;
 674               $seconds_left = 0;
 675             }
 676
 677             $seconds += $charge_sec;
 678
 679             $included_min{$regionnum}{$ratetimenum} -= $minutes;
 680             if ( $included_min{$regionnum}{$ratetimenum} <= 0 ) {
 681               my $charge_min = 0 - $included_min{$regionnum}{$ratetimenum}; #XXX should preserve
 682                                                               #(display?) this
 683               $included_min{$regionnum}{$ratetimenum} = 0;
 684               $charge += ($rate_detail->min_charge * $charge_min); #still not rounded
 685             }
 686
 687             # choose next rate_detail
 688             $rate_detail = $rate->dest_detail({ 'countrycode' => $countrycode,
 689                                                 'phonenum'    => $number,
 690                                                 'weektime'    => $etime })
 691                     if($seconds_left);
 692             # we have now moved forward to $etime
 693             $weektime = $etime;
 694
 695           } #while $seconds_left
 696           # this is why we need regionnum/rate_region....
 697           warn "  (rate region $rate_region)\n" if $DEBUG;
 698
 699           $classnum = $rate_detail->classnum;
 700           $charge = sprintf('%.2f', $charge + 0.000001); # NOW round it.
 701           warn "Incrementing \$charges by $charge.  Now $charges\n" if $DEBUG;
 702           $charges += $charge;
 703
 704           @call_details = (
 705             $cdr->downstream_csv( 'format'         => $output_format,
 706                                   'granularity'    => $rate_detail->sec_granularity,
 707                                   'seconds'        => ($use_duration ?
 708                                                        $cdr->duration :
 709                                                        $cdr->billsec),
 710                                   'charge'         => $charge,
 711                                   'pretty_dst'     => $pretty_destnum,
 712                                   'dst_regionname' => $regionname,
 713                                 )
 714           );
 715         } #if(there is a rate_detail)
 716
 717
 718         if ( $charge > 0 ) {
 719           #just use FS::cust_bill_pkg_detail objects?
 720           my $call_details;
 721           my $phonenum = $svc_x->phonenum;
 722
 723           if ( scalar(@call_details) == 1 ) {
 724             $call_details =
 725               [ 'C',
 726                 $call_details[0],
 727                 $charge,
 728                 $classnum,
 729                 $phonenum,
 730                 $seconds,
 731                 $regionname,
 732               ];
 733           } else { #only used for $rating_method eq 'upstream' now
 734             $csv->combine(@call_details);
 735             $call_details =
 736               [ 'C',
 737                 $csv->string,
 738                 $charge,
 739                 $classnum,
 740                 $phonenum,
 741                 $seconds,
 742                 $regionname,
 743               ];
 744           }
 745           warn "  adding details on charge to invoice: [ ".
 746               join(', ', @{$call_details} ). " ]"
 747             if ( $DEBUG && ref($call_details) );
 748           push @invoice_details_sort, [ $call_details, $cdr->calldate_unix ];
 749         }
 750
 751         # if the customer flag is on, call "downstream_csv" or something
 752         # like it to export the call downstream!
 753         # XXX price plan option to pick format, or something...
 754         #$downstream_cdr .= $cdr->downstream_csv( 'format' => 'XXX format' )
 755         #  if $spool_cdr;
 756
 757         my $error = $cdr->set_status_and_rated_price( 'done',
 758                                                       $charge,
 759                                                       $cust_svc->svcnum,
 760                                                     );
 761         die $error if $error;
 762
 763       }
 764
 765     } # $cdr
 766
 767     my @sorted_invoice_details = sort { @{$a}[1] <=> @{$b}[1] } @invoice_details_sort;
 768     foreach my $sorted_call_detail ( @sorted_invoice_details ) {
 769         push @$details, @{$sorted_call_detail}[0];
 770     }
 771
 772   } # $cust_svc
 773
 774   unshift @$details, [ 'C',
 775                        FS::cdr::invoice_header($output_format),
 776                        '',
 777                        '',
 778                        '',
 779                        '',
 780                        '',
 781                      ]
 782     if @$details && $rating_method ne 'upstream';
 783
 784 #  if ( $spool_cdr && length($downstream_cdr) ) {
 785 #
 786 #    use FS::UID qw(datasrc);
 787 #    my $dir = '/usr/local/etc/freeside/export.'. datasrc. '/cdr';
 788 #    mkdir $dir, 0700 unless -d $dir;
 789 #    $dir .= '/'. $cust_pkg->custnum.
 790 #    mkdir $dir, 0700 unless -d $dir;
 791 #    my $filename = time2str("$dir/CDR%Y%m%d-spool.CSV", time); #XXX invoice date instead?  would require changing the order things are generated in cust_main::bill insert cust_bill first - with transactions it could be done though
 792 #
 793 #    push @{ $param->{'precommit_hooks'} },
 794 #         sub {
 795 #               #lock the downstream spool file and append the records
 796 #               use Fcntl qw(:flock);
 797 #               use IO::File;
 798 #               my $spool = new IO::File ">>$filename"
 799 #                 or die "can't open $filename: $!\n";
 800 #               flock( $spool, LOCK_EX)
 801 #                 or die "can't lock $filename: $!\n";
 802 #               seek($spool, 0, 2)
 803 #                 or die "can't seek to end of $filename: $!\n";
 804 #               print $spool $downstream_cdr;
 805 #               flock( $spool, LOCK_UN );
 806 #               close $spool;
 807 #             };
 808 #
 809 #  } #if ( $spool_cdr && length($downstream_cdr) )
 810
 811   $charges;
 812 }
 813
 814 #returns a reason why not to rate this CDR, or false if the CDR is chargeable
 815 sub check_chargable {
 816   my( $self, $cdr, %flags ) = @_;
 817
 818   #should have some better way of checking these options from a hash
 819   #or something
 820
 821   my @opt = qw(
 822     use_amaflags
 823     use_disposition
 824     use_disposition_taqua
 825     use_carrierid
 826     use_cdrtypenum
 827     skip_dst_prefix
 828     skip_dcontext
 829     skip_dstchannel_prefix
 830     skip_src_length_more noskip_src_length_accountcode_tollfree
 831     skip_dst_length_less noskip_dst_length_accountcode_tollfree
 832     skip_lastapp
 833     skip_max_callers
 834   );
 835   foreach my $opt (grep !exists($flags{option_cache}->{$_}), @opt ) {
 836     $flags{option_cache}->{$opt} = $self->option($opt, 1);
 837   }
 838   my %opt = %{ $flags{option_cache} };
 839
 840   return 'amaflags != 2'
 841     if $opt{'use_amaflags'} && $cdr->amaflags != 2;
 842
 843   return 'disposition != ANSWERED'
 844     if $opt{'use_disposition'} && $cdr->disposition ne 'ANSWERED';
 845
 846   return "disposition != 100"
 847     if $opt{'use_disposition_taqua'} && $cdr->disposition != 100;
 848
 849   return "carrierid != $opt{'use_carrierid'}"
 850     if length($opt{'use_carrierid'})
 851     && $cdr->carrierid ne $opt{'use_carrierid'} #ne otherwise 0 matches ''
 852     && ! $flags{'da_rewrote'};
 853
 854   return "cdrtypenum != $opt{'use_cdrtypenum'}"
 855     if length($opt{'use_cdrtypenum'})
 856     && $cdr->cdrtypenum ne $opt{'use_cdrtypenum'}; #ne otherwise 0 matches ''
 857
 858   foreach(split(',',$opt{'skip_dst_prefix'})) {
 859     return "dst starts with '$_'"
 860     if length($_) && substr($cdr->dst,0,length($_)) eq $_;
 861   }
 862
 863   return "dcontext IN ( $opt{'skip_dcontext'} )"
 864     if $opt{'skip_dcontext'} =~ /\S/
 865     && grep { $cdr->dcontext eq $_ } split(/\s*,\s*/, $opt{'skip_dcontext'});
 866
 867   my $len_prefix = length($opt{'skip_dstchannel_prefix'});
 868   return "dstchannel starts with $opt{'skip_dstchannel_prefix'}"
 869     if $len_prefix
 870     && substr($cdr->dstchannel,0,$len_prefix) eq $opt{'skip_dstchannel_prefix'};
 871
 872   my $dst_length = $opt{'skip_dst_length_less'};
 873   return "destination less than $dst_length digits"
 874     if $dst_length && length($cdr->dst) < $dst_length
 875     && ! ( $opt{'noskip_dst_length_accountcode_tollfree'}
 876             && $cdr->is_tollfree('accountcode')
 877          );
 878
 879   return "lastapp is $opt{'skip_lastapp'}"
 880     if length($opt{'skip_lastapp'}) && $cdr->lastapp eq $opt{'skip_lastapp'};
 881
 882   my $src_length = $opt{'skip_src_length_more'};
 883   if ( $src_length ) {
 884
 885     if ( $opt{'noskip_src_length_accountcode_tollfree'} ) {
 886
 887       if ( $cdr->is_tollfree('accountcode') ) {
 888         return "source less than or equal to $src_length digits"
 889           if length($cdr->src) <= $src_length;
 890       } else {
 891         return "source more than $src_length digits"
 892           if length($cdr->src) > $src_length;
 893       }
 894
 895     } else {
 896       return "source more than $src_length digits"
 897         if length($cdr->src) > $src_length;
 898     }
 899
 900   }
 901
 902   return "max_callers <= $opt{skip_max_callers}"
 903     if length($opt{'skip_max_callers'})
 904       and length($cdr->max_callers)
 905       and $cdr->max_callers <= $opt{'skip_max_callers'};
 906
 907   #all right then, rate it
 908   '';
 909 }
 910
 911 sub is_free {
 912   0;
 913 }
 914
 915 #  This equates svc_phone records; perhaps svc_phone should have a field
 916 #  to indicate it represents a line
 917 sub calc_units {
 918   my($self, $cust_pkg ) = @_;
 919   my $count = 0;
 920   if ( $self->option('count_available_phones', 1)) {
 921     map { $count += ( $_->quantity || 0 ) }
 922       grep { $_->part_svc->svcdb eq 'svc_phone' }
 923       $cust_pkg->part_pkg->pkg_svc;
 924   } else {
 925     $count =
 926       scalar(grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc);
 927   }
 928   $count;
 929 }
 930
 931 1;
 932