FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use vars qw( @ISA %info
   5              %usage_fields %usage_recharge_fields
   6              @usage_fieldorder @usage_recharge_fieldorder
   7            );
   8 use Tie::IxHash;
   9 use List::Util qw(min); # max);
  10 #use FS::Record qw(qsearch);
  11 use FS::UI::bytecount;
  12 use FS::Conf;
  13 use FS::part_pkg;
  14 use FS::cust_bill_pkg_discount;
  15
  16 @ISA = qw(FS::part_pkg FS::part_pkg::prorate_Mixin);
  17
  18 tie my %temporalities, 'Tie::IxHash',
  19   'upcoming'  => "Upcoming (future)",
  20   'preceding' => "Preceding (past)",
  21 ;
  22
  23 %usage_fields = (
  24
  25     'seconds'       => { 'name' => 'Time limit for this package',
  26                          'default' => '',
  27                          'check' => sub { shift =~ /^\d*$/ },
  28                        },
  29     'upbytes'       => { 'name' => 'Upload limit for this package',
  30                          'default' => '',
  31                          'check' => sub { shift =~ /^\d*$/ },
  32                          'format' => \&FS::UI::bytecount::display_bytecount,
  33                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  34                        },
  35     'downbytes'     => { 'name' => 'Download limit for this package',
  36                          'default' => '',
  37                          'check' => sub { shift =~ /^\d*$/ },
  38                          'format' => \&FS::UI::bytecount::display_bytecount,
  39                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  40                        },
  41     'totalbytes'    => { 'name' => 'Transfer limit for this package',
  42                          'default' => '',
  43                          'check' => sub { shift =~ /^\d*$/ },
  44                          'format' => \&FS::UI::bytecount::display_bytecount,
  45                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  46                        },
  47 );
  48
  49 %usage_recharge_fields = (
  50
  51     'recharge_amount'       => { 'name' => 'Cost of recharge for this package',
  52                          'default' => '',
  53                          'check' => sub { shift =~ /^\d*(\.\d{2})?$/ },
  54                        },
  55     'recharge_seconds'      => { 'name' => 'Recharge time for this package',
  56                          'default' => '',
  57                          'check' => sub { shift =~ /^\d*$/ },
  58                        },
  59     'recharge_upbytes'      => { 'name' => 'Recharge upload for this package',
  60                          'default' => '',
  61                          'check' => sub { shift =~ /^\d*$/ },
  62                          'format' => \&FS::UI::bytecount::display_bytecount,
  63                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  64                        },
  65     'recharge_downbytes'    => { 'name' => 'Recharge download for this package',
  66                          'default' => '',
  67                          'check' => sub { shift =~ /^\d*$/ },
  68                          'format' => \&FS::UI::bytecount::display_bytecount,
  69                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  70                        },
  71     'recharge_totalbytes'   => { 'name' => 'Recharge transfer for this package',
  72                          'default' => '',
  73                          'check' => sub { shift =~ /^\d*$/ },
  74                          'format' => \&FS::UI::bytecount::display_bytecount,
  75                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  76                        },
  77     'usage_rollover' => { 'name' => 'Allow usage from previous period to roll '.
  78                                     ' over into current period',
  79                           'type' => 'checkbox',
  80                         },
  81     'recharge_reset' => { 'name' => 'Reset usage to these values on manual '.
  82                                     'package recharge',
  83                           'type' => 'checkbox',
  84                         },
  85 );
  86
  87 @usage_fieldorder = qw( seconds upbytes downbytes totalbytes );
  88 @usage_recharge_fieldorder = qw(
  89   recharge_amount recharge_seconds recharge_upbytes
  90   recharge_downbytes recharge_totalbytes
  91   usage_rollover recharge_reset
  92 );
  93
  94 %info = (
  95   'name' => 'Flat rate (anniversary billing)',
  96   'shortname' => 'Anniversary',
  97   'fields' => {
  98     'setup_fee'     => { 'name' => 'Setup fee for this package',
  99                          'default' => 0,
 100                        },
 101     'recur_fee'     => { 'name' => 'Recurring fee for this package',
 102                          'default' => 0,
 103                        },
 104
 105     #false laziness w/voip_cdr.pm
 106     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
 107                              'type' => 'select',
 108                              'select_options' => \%temporalities,
 109                            },
 110     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
 111                                    ' of service at cancellation',
 112                          'type' => 'checkbox',
 113                        },
 114
 115     #used in cust_pkg.pm so could add to any price plan
 116     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
 117                        },
 118     'adjourn_months'=> { 'name' => 'Auto-add a suspension date this number of months out',
 119                        },
 120     #used in cust_pkg.pm so could add to any price plan where it made sense
 121     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
 122                          'type' => 'checkbox',
 123                        },
 124     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
 125                                     'with the customer\'s other packages',
 126                           'type' => 'checkbox',
 127                         },
 128     'unsuspend_adjust_bill' =>
 129                         { 'name' => 'Adjust next bill date forward when '.
 130                                     'unsuspending',
 131                           'type' => 'checkbox',
 132                         },
 133
 134     %usage_fields,
 135     %usage_recharge_fields,
 136
 137     'externalid' => { 'name'   => 'Optional External ID',
 138                       'default' => '',
 139                     },
 140   },
 141   'fieldorder' => [ qw( setup_fee recur_fee
 142                         recur_temporality unused_credit
 143                         expire_months adjourn_months
 144                         start_1st sync_bill_date
 145                         unsuspend_adjust_bill
 146                       ),
 147                     @usage_fieldorder, @usage_recharge_fieldorder,
 148                     qw( externalid ),
 149                   ],
 150   'weight' => 10,
 151 );
 152
 153 sub calc_setup {
 154   my($self, $cust_pkg, $sdate, $details ) = @_;
 155
 156   my $i = 0;
 157   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 158   while ($i < $count) {
 159     push @$details, $self->option( 'additional_info' . $i++ );
 160   }
 161
 162   my $quantity = $cust_pkg->quantity || 1;
 163
 164   sprintf("%.2f", $quantity * $self->unit_setup($cust_pkg, $sdate, $details) );
 165 }
 166
 167 sub unit_setup {
 168   my($self, $cust_pkg, $sdate, $details ) = @_;
 169
 170   $self->option('setup_fee') || 0;
 171 }
 172
 173 sub calc_recur {
 174   my $self = shift;
 175   my($cust_pkg, $sdate, $details, $param ) = @_;
 176
 177   #my $last_bill = $cust_pkg->last_bill;
 178   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 179
 180   return 0
 181     if $self->option('recur_temporality', 1) eq 'preceding' && $last_bill == 0;
 182
 183   if( $self->option('sync_bill_date',1) ) {
 184     return $self->calc_prorate(@_);
 185   }
 186   else {
 187     my $charge = $self->base_recur($cust_pkg);
 188     my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 189
 190     return sprintf('%.2f', $charge - $discount);
 191   }
 192 }
 193
 194 sub calc_discount {
 195   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 196
 197   my $br = $self->base_recur($cust_pkg);
 198
 199   my $tot_discount = 0;
 200   #UI enforces just 1 for now, will need ordering when they can be stacked
 201   my @cust_pkg_discount = $cust_pkg->cust_pkg_discount_active;
 202   foreach my $cust_pkg_discount ( @cust_pkg_discount ) {
 203      my $discount = $cust_pkg_discount->discount;
 204      #UI enforces one or the other (for now?  probably for good)
 205      my $amount = 0;
 206      $amount += $discount->amount
 207        if $cust_pkg->pkgpart == $param->{real_pkgpart};
 208      $amount += sprintf('%.2f', $discount->percent * $br / 100 );
 209
 210      my $chg_months = $param->{'months'} || $cust_pkg->part_pkg->freq;
 211
 212      my $months = $discount->months
 213                     ? min( $chg_months,
 214                            $discount->months - $cust_pkg_discount->months_used )
 215                     : $chg_months;
 216
 217      my $error = $cust_pkg_discount->increment_months_used($months);
 218      die "error discounting: $error" if $error;
 219
 220      $amount *= $months;
 221      $amount = sprintf('%.2f', $amount);
 222
 223      next unless $amount > 0;
 224
 225      #record details in cust_bill_pkg_discount
 226      my $cust_bill_pkg_discount = new FS::cust_bill_pkg_discount {
 227        'pkgdiscountnum' => $cust_pkg_discount->pkgdiscountnum,
 228        'amount'         => $amount,
 229        'months'         => $months,
 230      };
 231      push @{ $param->{'discounts'} }, $cust_bill_pkg_discount;
 232
 233      #add details on discount to invoice
 234      my $conf = new FS::Conf;
 235      my $money_char = $conf->config('money_char') || '$';
 236      $months = sprintf('%.2f', $months) if $months =~ /\./;
 237
 238      my $d = 'Includes ';
 239      $d .= $discount->name. ' ' if $discount->name;
 240      $d .= 'discount of '. $discount->description_short;
 241      $d .= " for $months month". ( $months!=1 ? 's' : '' );
 242      $d .= ": $money_char$amount" if $months != 1 || $discount->percent;
 243      push @$details, $d;
 244
 245      $tot_discount += $amount;
 246   }
 247
 248   sprintf('%.2f', $tot_discount);
 249 }
 250
 251 sub base_recur {
 252   my($self, $cust_pkg) = @_;
 253   $self->option('recur_fee', 1) || 0;
 254 }
 255
 256 sub base_recur_permonth {
 257   my($self, $cust_pkg) = @_;
 258
 259   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 260
 261   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 262 }
 263
 264 sub calc_remain {
 265   my ($self, $cust_pkg, %options) = @_;
 266
 267   my $time;
 268   if ($options{'time'}) {
 269     $time = $options{'time'};
 270   } else {
 271     $time = time;
 272   }
 273
 274   my $next_bill = $cust_pkg->getfield('bill') || 0;
 275
 276   #my $last_bill = $cust_pkg->last_bill || 0;
 277   my $last_bill = $cust_pkg->get('last_bill') || 0; #->last_bill falls back to setup
 278
 279   return 0 if    ! $self->base_recur($cust_pkg)
 280               || ! $self->option('unused_credit', 1)
 281               || ! $last_bill
 282               || ! $next_bill
 283               || $next_bill < $time;
 284
 285   my %sec = (
 286     'h' =>    3600, # 60 * 60
 287     'd' =>   86400, # 60 * 60 * 24
 288     'w' =>  604800, # 60 * 60 * 24 * 7
 289     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 290   );
 291
 292   $self->freq =~ /^(\d+)([hdwm]?)$/
 293     or die 'unparsable frequency: '. $self->freq;
 294   my $freq_sec = $1 * $sec{$2||'m'};
 295   return 0 unless $freq_sec;
 296
 297   sprintf("%.2f", $self->base_recur($cust_pkg) * ( $next_bill - $time ) / $freq_sec );
 298
 299 }
 300
 301 sub is_free_options {
 302   qw( setup_fee recur_fee );
 303 }
 304
 305 sub is_prepaid { 0; } #no, we're postpaid
 306
 307 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 308 sub can_discount {
 309   my $self = shift;
 310   $self->freq =~ /^\d+$/ && $self->freq > 0;
 311 }
 312
 313 sub usage_valuehash {
 314   my $self = shift;
 315   map { $_, $self->option($_) }
 316     grep { $self->option($_, 'hush') }
 317     qw(seconds upbytes downbytes totalbytes);
 318 }
 319
 320 sub reset_usage {
 321   my($self, $cust_pkg, %opt) = @_;
 322   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 323   my %values = $self->usage_valuehash;
 324   if ($self->option('usage_rollover', 1)) {
 325     $cust_pkg->recharge(\%values);
 326   }else{
 327     $cust_pkg->set_usage(\%values, %opt);
 328   }
 329 }
 330
 331 1;