FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use base qw( FS::part_pkg
   5              FS::part_pkg::prorate_Mixin
   6              FS::part_pkg::discount_Mixin
   7            );
   8 use vars qw( %info %usage_recharge_fields @usage_recharge_fieldorder );
   9 use Tie::IxHash;
  10 use List::Util qw(min); # max);
  11 #use FS::Record qw(qsearch);
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14
  15 tie my %temporalities, 'Tie::IxHash',
  16   'upcoming'  => "Upcoming (future)",
  17   'preceding' => "Preceding (past)",
  18 ;
  19
  20 tie my %contract_years, 'Tie::IxHash', (
  21   '' => '(none)',
  22   map { $_*12 => $_ } (1..5),
  23 );
  24
  25 %info = (
  26   'name' => 'Flat rate (anniversary billing)',
  27   'shortname' => 'Anniversary',
  28   'inherit_fields' => [ 'prorate_Mixin', 'usage_Mixin', 'global_Mixin' ],
  29   'fields' => {
  30     #false laziness w/voip_cdr.pm
  31     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  32                              'type' => 'select',
  33                              'select_options' => \%temporalities,
  34                            },
  35
  36     #used in cust_pkg.pm so could add to any price plan
  37     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
  38                        },
  39     'adjourn_months'=> { 'name' => 'Auto-add a suspension date this number of months out',
  40                        },
  41     'contract_end_months'=> {
  42                         'name' => 'Auto-add a contract end date this number of years out',
  43                         'type' => 'select',
  44                         'select_options' => \%contract_years,
  45                       },
  46     #used in cust_pkg.pm so could add to any price plan where it made sense
  47     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
  48                          'type' => 'checkbox',
  49                        },
  50     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
  51                                     'with the customer\'s other packages',
  52                           'type' => 'checkbox',
  53                         },
  54     'prorate_defer_bill' => {
  55                           'name' => 'When synchronizing, defer the bill until '.
  56                                     'the customer\'s next bill date',
  57                           'type' => 'checkbox',
  58                         },
  59     'prorate_round_day' => {
  60                           'name' => 'When synchronizing, round the prorated '.
  61                                     'period to the nearest full day',
  62                           'type' => 'checkbox',
  63                         },
  64     'add_full_period' => { 'disabled' => 1 }, # doesn't make sense with sync?
  65
  66     'suspend_bill' => { 'name' => 'Continue recurring billing while suspended',
  67                         'type' => 'checkbox',
  68                       },
  69     'unsuspend_adjust_bill' =>
  70                         { 'name' => 'Adjust next bill date forward when '.
  71                                     'unsuspending',
  72                           'type' => 'checkbox',
  73                         },
  74
  75     'externalid' => { 'name'   => 'Optional External ID',
  76                       'default' => '',
  77                     },
  78   },
  79   'fieldorder' => [ qw( recur_temporality
  80                         expire_months adjourn_months
  81                         contract_end_months
  82                         start_1st
  83                         sync_bill_date prorate_defer_bill prorate_round_day
  84                         suspend_bill unsuspend_adjust_bill
  85                         externalid ),
  86                   ],
  87   'weight' => 10,
  88 );
  89
  90 sub price_info {
  91     my $self = shift;
  92     my $conf = new FS::Conf;
  93     my $money_char = $conf->config('money_char') || '$';
  94     my $setup = $self->option('setup_fee') || 0;
  95     my $recur = $self->option('recur_fee', 1) || 0;
  96     my $str = '';
  97     $str = $money_char . $setup . ' one-time' if $setup;
  98     $str .= ', ' if ($setup && $recur);
  99     $str .= $money_char . $recur . ' recurring ' if $recur;
 100     $str;
 101 }
 102
 103 sub calc_setup {
 104   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 105
 106   return 0 if $self->prorate_setup($cust_pkg, $sdate);
 107
 108   my $i = 0;
 109   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 110   while ($i < $count) {
 111     push @$details, $self->option( 'additional_info' . $i++ );
 112   }
 113
 114   my $quantity = $cust_pkg->quantity || 1;
 115
 116   my $charge = $quantity * $self->unit_setup($cust_pkg, $sdate, $details);
 117
 118   my $discount = 0;
 119   if ( $charge > 0 ) {
 120       $param->{'setup_charge'} = $charge;
 121       $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 122       delete $param->{'setup_charge'};
 123   }
 124
 125   sprintf('%.2f', $charge - $discount);
 126 }
 127
 128 sub unit_setup {
 129   my($self, $cust_pkg, $sdate, $details ) = @_;
 130
 131   $self->option('setup_fee') || 0;
 132 }
 133
 134 sub calc_recur {
 135   my $self = shift;
 136   my($cust_pkg, $sdate, $details, $param ) = @_;
 137
 138   #my $last_bill = $cust_pkg->last_bill;
 139   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 140
 141   return 0
 142     if $self->recur_temporality eq 'preceding' && $last_bill == 0;
 143
 144   my $charge = $self->base_recur($cust_pkg, $sdate);
 145   if ( my $cutoff_day = $self->cutoff_day($cust_pkg) ) {
 146     $charge = $self->calc_prorate(@_, $cutoff_day);
 147   }
 148   elsif ( $param->{freq_override} ) {
 149     # XXX not sure if this should be mutually exclusive with sync_bill_date.
 150     # Given the very specific problem that freq_override is meant to 'solve',
 151     # it probably should.
 152     $charge *= $param->{freq_override} if $param->{freq_override};
 153   }
 154
 155   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 156   return sprintf('%.2f', $charge - $discount);
 157 }
 158
 159 sub cutoff_day {
 160   my $self = shift;
 161   my $cust_pkg = shift;
 162   if ( $self->option('sync_bill_date',1) ) {
 163     my $next_bill = $cust_pkg->cust_main->next_bill_date;
 164     if ( defined($next_bill) ) {
 165       return (localtime($next_bill))[3];
 166     }
 167   }
 168   return 0;
 169 }
 170
 171 sub base_recur {
 172   my($self, $cust_pkg, $sdate) = @_;
 173   $self->option('recur_fee', 1) || 0;
 174 }
 175
 176 sub base_recur_permonth {
 177   my($self, $cust_pkg) = @_;
 178
 179   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 180
 181   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 182 }
 183
 184 sub calc_remain {
 185   my ($self, $cust_pkg, %options) = @_;
 186
 187   my $time;
 188   if ($options{'time'}) {
 189     $time = $options{'time'};
 190   } else {
 191     $time = time;
 192   }
 193
 194   my $next_bill = $cust_pkg->getfield('bill') || 0;
 195
 196   return 0 if    ! $self->base_recur($cust_pkg, \$time)
 197               || ! $next_bill
 198               || $next_bill < $time;
 199
 200   my %sec = (
 201     'h' =>    3600, # 60 * 60
 202     'd' =>   86400, # 60 * 60 * 24
 203     'w' =>  604800, # 60 * 60 * 24 * 7
 204     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 205   );
 206
 207   $self->freq =~ /^(\d+)([hdwm]?)$/
 208     or die 'unparsable frequency: '. $self->freq;
 209   my $freq_sec = $1 * $sec{$2||'m'};
 210   return 0 unless $freq_sec;
 211
 212   sprintf("%.2f", $self->base_recur($cust_pkg, \$time) * ( $next_bill - $time ) / $freq_sec );
 213
 214 }
 215
 216 sub is_free_options {
 217   qw( setup_fee recur_fee );
 218 }
 219
 220 sub is_prepaid { 0; } #no, we're postpaid
 221
 222 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 223 sub can_discount {
 224   my $self = shift;
 225   $self->freq =~ /^\d+$/ && $self->freq > 0;
 226 }
 227
 228 sub recur_temporality {
 229   my $self = shift;
 230   $self->option('recur_temporality', 1);
 231 }
 232
 233 sub usage_valuehash {
 234   my $self = shift;
 235   map { $_, $self->option($_) }
 236     grep { $self->option($_, 'hush') }
 237     qw(seconds upbytes downbytes totalbytes);
 238 }
 239
 240 sub reset_usage {
 241   my($self, $cust_pkg, %opt) = @_;
 242   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 243   my %values = $self->usage_valuehash;
 244   if ($self->option('usage_rollover', 1)) {
 245     $cust_pkg->recharge(\%values);
 246   }else{
 247     $cust_pkg->set_usage(\%values, %opt);
 248   }
 249 }
 250
 251 1;