FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2 use base qw( FS::part_pkg::prorate_Mixin
   3              FS::part_pkg::discount_Mixin
   4              FS::part_pkg
   5            );
   6
   7 use strict;
   8 use vars qw( %info %usage_recharge_fields @usage_recharge_fieldorder );
   9 use FS::Record qw( qsearch );
  10 use Tie::IxHash;
  11 use List::Util qw( min );
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14
  15 tie my %temporalities, 'Tie::IxHash',
  16   'upcoming'  => "Upcoming (future)",
  17   'preceding' => "Preceding (past)",
  18 ;
  19
  20 tie my %contract_years, 'Tie::IxHash', (
  21   '' => '(none)',
  22   map { $_*12 => $_ } (1..5),
  23 );
  24
  25 %info = (
  26   'name' => 'Flat rate (anniversary billing)',
  27   'shortname' => 'Anniversary',
  28   'inherit_fields' => [ 'prorate_Mixin', 'usage_Mixin', 'global_Mixin' ],
  29   'fields' => {
  30     #false laziness w/voip_cdr.pm
  31     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  32                              'type' => 'select',
  33                              'select_options' => \%temporalities,
  34                            },
  35
  36     #used in cust_pkg.pm so could add to any price plan
  37     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
  38                        },
  39     'adjourn_months'=> { 'name' => 'Auto-add a suspension date this number of months out',
  40                        },
  41     'contract_end_months'=> {
  42                         'name' => 'Auto-add a contract end date this number of years out',
  43                         'type' => 'select',
  44                         'select_options' => \%contract_years,
  45                       },
  46     #used in cust_pkg.pm so could add to any price plan where it made sense
  47     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
  48                          'type' => 'checkbox',
  49                        },
  50     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
  51                                     'with the customer\'s other packages',
  52                           'type' => 'checkbox',
  53                         },
  54     'prorate_defer_bill' => {
  55                           'name' => 'When synchronizing, defer the bill until '.
  56                                     'the customer\'s next bill date',
  57                           'type' => 'checkbox',
  58                         },
  59     'prorate_round_day' => {
  60                           'name' => 'When synchronizing, round the prorated '.
  61                                     'period to the nearest full day',
  62                           'type' => 'checkbox',
  63                         },
  64     'add_full_period' => { 'disabled' => 1 }, # doesn't make sense with sync?
  65
  66     'suspend_bill' => { 'name' => 'Continue recurring billing while suspended',
  67                         'type' => 'checkbox',
  68                       },
  69     'unsuspend_adjust_bill' =>
  70                         { 'name' => 'Adjust next bill date forward when '.
  71                                     'unsuspending',
  72                           'type' => 'checkbox',
  73                         },
  74     'bill_recur_on_cancel' => {
  75                         'name' => 'Bill the last period on cancellation',
  76                         'type' => 'checkbox',
  77                         },
  78     'bill_suspend_as_cancel' => {
  79                         'name' => 'Bill immediately upon suspension', #desc?
  80                         'type' => 'checkbox',
  81                         },
  82     'externalid' => { 'name'   => 'Optional External ID',
  83                       'default' => '',
  84                     },
  85   },
  86   'fieldorder' => [ qw( recur_temporality
  87                         expire_months adjourn_months
  88                         contract_end_months
  89                         start_1st
  90                         sync_bill_date prorate_defer_bill prorate_round_day
  91                         suspend_bill unsuspend_adjust_bill
  92                         bill_recur_on_cancel
  93                         bill_suspend_as_cancel
  94                         externalid ),
  95                   ],
  96   'weight' => 10,
  97 );
  98
  99 sub price_info {
 100     my $self = shift;
 101     my $conf = new FS::Conf;
 102     my $money_char = $conf->config('money_char') || '$';
 103     my $setup = $self->option('setup_fee') || 0;
 104     my $recur = $self->option('recur_fee', 1) || 0;
 105     my $str = '';
 106     $str = $money_char . $setup . ($recur ? ' setup ' : ' one-time') if $setup;
 107     $str .= ', ' if ($setup && $recur);
 108     $str .= $money_char. $recur. '/'. $self->freq_pretty if $recur;
 109     $str;
 110 }
 111
 112 sub calc_setup {
 113   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 114
 115   return 0 if $self->prorate_setup($cust_pkg, $sdate);
 116
 117   my $i = 0;
 118   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 119   while ($i < $count) {
 120     push @$details, $self->option( 'additional_info' . $i++ );
 121   }
 122
 123   my $charge = $self->base_setup($cust_pkg, $sdate, $details);
 124
 125   my $discount = 0;
 126   if ( $charge > 0 ) {
 127       $param->{'setup_charge'} = $charge;
 128       $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 129       delete $param->{'setup_charge'};
 130   }
 131
 132   sprintf( '%.2f', ($cust_pkg->quantity || 1) * ($charge - $discount) );
 133 }
 134
 135 sub base_setup {
 136   my($self, $cust_pkg, $sdate, $details ) = @_;
 137
 138   $self->option('setup_fee') || 0;
 139 }
 140
 141 sub calc_recur {
 142   my $self = shift;
 143   my($cust_pkg, $sdate, $details, $param ) = @_;
 144
 145   #my $last_bill = $cust_pkg->last_bill;
 146   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 147
 148   return 0
 149     if $self->recur_temporality eq 'preceding' && !$last_bill;
 150
 151   my $charge = $self->base_recur($cust_pkg, $sdate);
 152   # always treat cutoff_day as a list
 153   if ( my @cutoff_day = $self->cutoff_day($cust_pkg) ) {
 154     $charge = $self->calc_prorate(@_, @cutoff_day);
 155   }
 156   elsif ( $param->{freq_override} ) {
 157     # XXX not sure if this should be mutually exclusive with sync_bill_date.
 158     # Given the very specific problem that freq_override is meant to 'solve',
 159     # it probably should.
 160     $charge *= $param->{freq_override} if $param->{freq_override};
 161   }
 162
 163   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 164
 165   sprintf( '%.2f', ($cust_pkg->quantity || 1) * ($charge - $discount) );
 166 }
 167
 168 sub cutoff_day {
 169   my $self = shift;
 170   my $cust_pkg = shift;
 171   if ( $self->option('sync_bill_date',1) ) {
 172     my $next_bill = $cust_pkg->cust_main->next_bill_date;
 173     if ( defined($next_bill) ) {
 174       return (localtime($next_bill))[3];
 175     }
 176   }
 177   return ();
 178 }
 179
 180 sub base_recur {
 181   my($self, $cust_pkg, $sdate) = @_;
 182   $self->option('recur_fee', 1) || 0;
 183 }
 184
 185 sub base_recur_permonth {
 186   my($self, $cust_pkg) = @_;
 187
 188   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 189
 190   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 191 }
 192
 193 sub calc_cancel {
 194   my $self = shift;
 195   my $conf = new FS::Conf;
 196   if ( $self->recur_temporality eq 'preceding'
 197        and $self->option('bill_recur_on_cancel', 1) ) {
 198     # run another recurring cycle
 199     return $self->calc_recur(@_);
 200   }
 201   elsif ( $conf->exists('bill_usage_on_cancel') # should be a package option?
 202           and $self->can('calc_usage') ) {
 203     # bill for outstanding usage
 204     return $self->calc_usage(@_);
 205   }
 206   0;
 207 }
 208
 209 sub calc_remain {
 210   my ($self, $cust_pkg, %options) = @_;
 211
 212   my $time;
 213   if ($options{'time'}) {
 214     $time = $options{'time'};
 215   } else {
 216     $time = time;
 217   }
 218
 219   my $next_bill = $cust_pkg->getfield('bill') || 0;
 220
 221   return 0 if    ! $self->base_recur($cust_pkg, \$time)
 222               || ! $next_bill
 223               || $next_bill < $time;
 224
 225   # Use actual charge for this period, not base_recur (for discounts).
 226   # Use sdate < $time and edate >= $time because when billing on
 227   # cancellation, edate = $time.
 228   my $credit = 0;
 229   foreach my $item (
 230     qsearch('cust_bill_pkg', {
 231       pkgnum => $cust_pkg->pkgnum,
 232       sdate => {op => '<' , value => $time},
 233       edate => {op => '>=', value => $time},
 234       recur => {op => '>' , value => 0},
 235     })
 236   ) {
 237     # hack to deal with the weird behavior of edate on package cancellation
 238     my $edate = $item->edate;
 239     if ( $self->recur_temporality eq 'preceding' ) {
 240       $edate = $self->add_freq($item->sdate);
 241     }
 242     $credit += ($item->recur - $item->usage) *
 243                ($edate - $time) / ($edate - $item->sdate);
 244   }
 245   sprintf('%.2f', $credit);
 246   #sprintf("%.2f", $self->base_recur($cust_pkg, \$time) * ( $next_bill - $time ) / $freq_sec );
 247
 248 }
 249
 250 sub is_free_options {
 251   qw( setup_fee recur_fee );
 252 }
 253
 254 sub is_prepaid { 0; } #no, we're postpaid
 255
 256 sub can_start_date { ! shift->option('start_1st', 1) }
 257
 258 sub can_discount { 1; }
 259
 260 sub recur_temporality {
 261   my $self = shift;
 262   $self->option('recur_temporality', 1);
 263 }
 264
 265 sub usage_valuehash {
 266   my $self = shift;
 267   map { $_, $self->option($_) }
 268     grep { $self->option($_, 'hush') }
 269     qw(seconds upbytes downbytes totalbytes);
 270 }
 271
 272 sub reset_usage {
 273   my($self, $cust_pkg, %opt) = @_;
 274   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 275   my %values = $self->usage_valuehash;
 276   if ($self->option('usage_rollover', 1)) {
 277     $cust_pkg->recharge(\%values);
 278   }else{
 279     $cust_pkg->set_usage(\%values, %opt);
 280   }
 281 }
 282
 283 1;