FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use base qw( FS::part_pkg
   5              FS::part_pkg::prorate_Mixin
   6              FS::part_pkg::discount_Mixin
   7            );
   8 use vars qw( %info %usage_recharge_fields @usage_recharge_fieldorder );
   9 use Tie::IxHash;
  10 use List::Util qw(min); # max);
  11 #use FS::Record qw(qsearch);
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14
  15 tie my %temporalities, 'Tie::IxHash',
  16   'upcoming'  => "Upcoming (future)",
  17   'preceding' => "Preceding (past)",
  18 ;
  19
  20 tie my %contract_years, 'Tie::IxHash', (
  21   '' => '(none)',
  22   map { $_*12 => $_ } (1..5),
  23 );
  24
  25 %info = (
  26   'name' => 'Flat rate (anniversary billing)',
  27   'shortname' => 'Anniversary',
  28   'inherit_fields' => [ 'usage_Mixin', 'global_Mixin' ],
  29   'fields' => {
  30     #false laziness w/voip_cdr.pm
  31     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  32                              'type' => 'select',
  33                              'select_options' => \%temporalities,
  34                            },
  35
  36     #used in cust_pkg.pm so could add to any price plan
  37     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
  38                        },
  39     'adjourn_months'=> { 'name' => 'Auto-add a suspension date this number of months out',
  40                        },
  41     'contract_end_months'=> {
  42                         'name' => 'Auto-add a contract end date this number of years out',
  43                         'type' => 'select',
  44                         'select_options' => \%contract_years,
  45                       },
  46     #used in cust_pkg.pm so could add to any price plan where it made sense
  47     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
  48                          'type' => 'checkbox',
  49                        },
  50     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
  51                                     'with the customer\'s other packages',
  52                           'type' => 'checkbox',
  53                         },
  54     'suspend_bill' => { 'name' => 'Continue recurring billing while suspended',
  55                         'type' => 'checkbox',
  56                       },
  57     'unsuspend_adjust_bill' =>
  58                         { 'name' => 'Adjust next bill date forward when '.
  59                                     'unsuspending',
  60                           'type' => 'checkbox',
  61                         },
  62
  63     'externalid' => { 'name'   => 'Optional External ID',
  64                       'default' => '',
  65                     },
  66   },
  67   'fieldorder' => [ qw( recur_temporality
  68                         expire_months adjourn_months
  69                         contract_end_months
  70                         start_1st sync_bill_date
  71                         suspend_bill unsuspend_adjust_bill
  72                         externalid ),
  73                   ],
  74   'weight' => 10,
  75 );
  76
  77 sub price_info {
  78     my $self = shift;
  79     my $conf = new FS::Conf;
  80     my $money_char = $conf->config('money_char') || '$';
  81     my $setup = $self->option('setup_fee') || 0;
  82     my $recur = $self->option('recur_fee', 1) || 0;
  83     my $str = '';
  84     $str = $money_char . $setup . ' one-time' if $setup;
  85     $str .= ', ' if ($setup && $recur);
  86     $str .= $money_char . $recur . ' recurring ' if $recur;
  87     $str;
  88 }
  89
  90 sub calc_setup {
  91   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
  92
  93   my $i = 0;
  94   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
  95   while ($i < $count) {
  96     push @$details, $self->option( 'additional_info' . $i++ );
  97   }
  98
  99   my $quantity = $cust_pkg->quantity || 1;
 100
 101   my $charge = $quantity * $self->unit_setup($cust_pkg, $sdate, $details);
 102
 103   my $discount = 0;
 104   if ( $charge > 0 ) {
 105       $param->{'setup_charge'} = $charge;
 106       $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 107       delete $param->{'setup_charge'};
 108   }
 109
 110   sprintf('%.2f', $charge - $discount);
 111 }
 112
 113 sub unit_setup {
 114   my($self, $cust_pkg, $sdate, $details ) = @_;
 115
 116   $self->option('setup_fee') || 0;
 117 }
 118
 119 sub calc_recur {
 120   my $self = shift;
 121   my($cust_pkg, $sdate, $details, $param ) = @_;
 122
 123   #my $last_bill = $cust_pkg->last_bill;
 124   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 125
 126   return 0
 127     if $self->option('recur_temporality', 1) eq 'preceding' && $last_bill == 0;
 128
 129   my $charge = $self->base_recur($cust_pkg, $sdate);
 130   if ( $self->option('sync_bill_date',1) ) {
 131     my $next_bill = $cust_pkg->cust_main->next_bill_date;
 132     if ( defined($next_bill) ) {
 133       my $cutoff_day = (localtime($next_bill))[3];
 134       $charge = $self->calc_prorate(@_, $cutoff_day);
 135     }
 136   }
 137   elsif ( $param->{freq_override} ) {
 138     # XXX not sure if this should be mutually exclusive with sync_bill_date.
 139     # Given the very specific problem that freq_override is meant to 'solve',
 140     # it probably should.
 141     $charge *= $param->{freq_override} if $param->{freq_override};
 142   }
 143
 144   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 145   return sprintf('%.2f', $charge - $discount);
 146 }
 147
 148 sub base_recur {
 149   my($self, $cust_pkg, $sdate) = @_;
 150   $self->option('recur_fee', 1) || 0;
 151 }
 152
 153 sub base_recur_permonth {
 154   my($self, $cust_pkg) = @_;
 155
 156   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 157
 158   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 159 }
 160
 161 sub calc_remain {
 162   my ($self, $cust_pkg, %options) = @_;
 163
 164   my $time;
 165   if ($options{'time'}) {
 166     $time = $options{'time'};
 167   } else {
 168     $time = time;
 169   }
 170
 171   my $next_bill = $cust_pkg->getfield('bill') || 0;
 172
 173   return 0 if    ! $self->base_recur($cust_pkg, \$time)
 174               || ! $next_bill
 175               || $next_bill < $time;
 176
 177   my %sec = (
 178     'h' =>    3600, # 60 * 60
 179     'd' =>   86400, # 60 * 60 * 24
 180     'w' =>  604800, # 60 * 60 * 24 * 7
 181     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 182   );
 183
 184   $self->freq =~ /^(\d+)([hdwm]?)$/
 185     or die 'unparsable frequency: '. $self->freq;
 186   my $freq_sec = $1 * $sec{$2||'m'};
 187   return 0 unless $freq_sec;
 188
 189   sprintf("%.2f", $self->base_recur($cust_pkg, \$time) * ( $next_bill - $time ) / $freq_sec );
 190
 191 }
 192
 193 sub is_free_options {
 194   qw( setup_fee recur_fee );
 195 }
 196
 197 sub is_prepaid { 0; } #no, we're postpaid
 198
 199 sub can_start_date { ! shift->option('start_1st', 1) }
 200
 201 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 202 sub can_discount {
 203   my $self = shift;
 204   $self->freq =~ /^\d+$/ && $self->freq > 0;
 205 }
 206
 207 sub usage_valuehash {
 208   my $self = shift;
 209   map { $_, $self->option($_) }
 210     grep { $self->option($_, 'hush') }
 211     qw(seconds upbytes downbytes totalbytes);
 212 }
 213
 214 sub reset_usage {
 215   my($self, $cust_pkg, %opt) = @_;
 216   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 217   my %values = $self->usage_valuehash;
 218   if ($self->option('usage_rollover', 1)) {
 219     $cust_pkg->recharge(\%values);
 220   }else{
 221     $cust_pkg->set_usage(\%values, %opt);
 222   }
 223 }
 224
 225 1;