FS/FS/part_pkg/discount_Mixin.pm

   1 package FS::part_pkg::discount_Mixin;
   2
   3 use strict;
   4 use vars qw( %info );
   5 use Time::Local qw( timelocal );
   6 use List::Util  qw( min );
   7 use FS::Record qw( qsearchs );
   8 use FS::cust_pkg;
   9 use FS::cust_bill_pkg_discount;
  10
  11 %info = ( 'disabled' => 1 );
  12
  13 =head1 NAME
  14
  15 FS::part_pkg::discount_Mixin - Mixin class for part_pkg:: classes that
  16 can be discounted.
  17
  18 =head1 SYNOPSIS
  19
  20 package FS::part_pkg::...;
  21 use base qw( FS::part_pkg::discount_Mixin );
  22
  23 sub calc_recur {
  24   ...
  25   my $discount = $self->calc_discount($cust_pkg, $$sdate, $details, $param);
  26   $charge -= $discount;
  27   ...
  28 }
  29
  30 =head METHODS
  31
  32 =item calc_discount CUST_PKG, SDATE, DETAILS_ARRAYREF, PARAM_HASHREF
  33
  34 Takes all the arguments of calc_recur.  Calculates and returns the amount
  35 by which to reduce the charge; also increments months used on the discount.
  36
  37 If there is a setup fee, this will be called once with 'setup_charge' => the
  38 setup fee amount (and should return the discount to be applied to the setup
  39 charge, if any), and again without it (for the recurring fee discount).
  40 PARAM_HASHREF carries over between the two invocations.
  41
  42 =cut
  43
  44 sub calc_discount {
  45   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
  46   my $conf = new FS::Conf;
  47
  48   my $br = $self->base_recur($cust_pkg, $sdate);
  49
  50   ## can not multiply non monthly recurring frequency so skip.
  51   unless ($cust_pkg->part_pkg->freq !~ /^\d+$/) {
  52     $br += $param->{'override_charges'} * ($cust_pkg->part_pkg->freq || 0) if $param->{'override_charges'};
  53   }
  54
  55   my $tot_discount = 0;
  56   #UI enforces just 1 for now, will need ordering when they can be stacked
  57
  58   # discount setup/recur splitting DOES NOT TOUCH THIS YET.
  59   # we need some kind of monitoring to see who if anyone still uses term
  60   # discounts.
  61   if ( $param->{freq_override} ) {
  62     # When a customer pays for more than one month at a time to receive a
  63     # term discount, freq_override is set to the number of months.
  64     my $real_part_pkg = new FS::part_pkg { $self->hash };
  65     $real_part_pkg->pkgpart($param->{real_pkgpart} || $self->pkgpart);
  66     # Find a discount with that duration...
  67     my @discount = grep { $_->months == $param->{freq_override} }
  68                     map { $_->discount } $real_part_pkg->part_pkg_discount;
  69     my $discount = shift @discount;
  70     # and default to bill that many months at once.
  71     $param->{months} = $param->{freq_override} unless $param->{months};
  72     my $error;
  73     if ($discount) {
  74       # Then set the cust_pkg discount.
  75       if ($discount->months == $param->{months}) {
  76         $cust_pkg->discountnum($discount->discountnum);
  77         $error = $cust_pkg->insert_discount;
  78       } else {
  79         $cust_pkg->discountnum(-1);
  80         foreach ( qw( amount percent months ) ) {
  81           my $method = "discountnum_$_";
  82           $cust_pkg->$method($discount->$_);
  83         }
  84         $error = $cust_pkg->insert_discount;
  85       }
  86       die "error discounting using part_pkg_discount: $error" if $error;
  87     }
  88   }
  89
  90   my @cust_pkg_discount = $cust_pkg->cust_pkg_discount_active;
  91
  92   if ( defined $param->{'setup_charge'} ) {
  93     @cust_pkg_discount = grep { $_->setuprecur eq 'setup' } @cust_pkg_discount;
  94   } else {
  95     @cust_pkg_discount = grep { $_->setuprecur eq 'recur' } @cust_pkg_discount;
  96   }
  97
  98   foreach my $cust_pkg_discount ( @cust_pkg_discount ) {
  99     my $discount_left;
 100     my $discount = $cust_pkg_discount->discount;
 101     #UI enforces one or the other (for now?  probably for good)
 102     # $chg_months: the number of months we are charging recur for
 103     # $months: $chg_months or the months left on the discount, whchever is less
 104
 105     my $chg_months = 1;
 106     unless ($cust_pkg->part_pkg->freq !~ /^\d+$/) {
 107       $chg_months = $cust_pkg->part_pkg->freq || 1;
 108     }
 109     if ( defined($param->{'months'}) ) { # then override
 110       $chg_months = $param->{'months'};
 111     }
 112
 113     my $months = $chg_months;
 114     if ( $discount->months ) {
 115       $months = min( $chg_months,
 116                      $discount->months - $cust_pkg_discount->months_used );
 117     }
 118
 119     # $amount is now the (estimated) discount amount on the recurring charge.
 120     # if it's a percent discount, that's base recur * percentage.
 121
 122     my $amount = 0;
 123
 124     if (defined $param->{'setup_charge'}) {
 125
 126         # we are calculating the setup discount.
 127         # if this discount doesn't apply to setup fees, skip it.
 128         # if it's a percent discount, set $amount = percent * setup_charge.
 129         # if it's a flat amount discount for one month:
 130         # - if the discount amount > setup_charge, then set it to setup_charge,
 131         #   and set 'discount_left_recur' to the difference.
 132         # - otherwise set it to just the discount amount.
 133         # if it's a flat amount discount for other than one month:
 134         # - skip the discount. unsure, leaving it alone for now.
 135
 136         $months = 0; # never count a setup discount as a month of discount
 137                      # (the recur discount in the same month should do it)
 138
 139         if ( $discount->percent > 0 ) {
 140             $amount = $discount->percent * $param->{'setup_charge'} / 100;
 141         } elsif ( $discount->amount > 0 ) {
 142             # apply the discount amount, up to a maximum of the setup charge
 143             $amount = min($discount->amount, $param->{'setup_charge'});
 144             $discount_left = sprintf('%.2f', $discount->amount - $amount);
 145             # transfer remainder of discount, if any, to recur
 146             $param->{'discount_left_recur'}{$discount->discountnum} = $discount_left;
 147         }
 148
 149     } else {
 150
 151       # we are calculating a recurring fee discount. estimate the recurring
 152       # fee. Note we use $months here rather than $chg_months so that if the
 153       # remaining discount amount is for less time than the package period,
 154       # the "estimated recurring fee" is only for as long as the discount
 155       # lasts.
 156
 157       # can not multiply non monthly recurring frequency so skip.
 158       next if $self->freq !~ /^\d+$/;
 159
 160       my $recur_charge = $br * $months / $self->freq;
 161       # round this, because the real recur charge is rounded
 162       $recur_charge = sprintf('%.2f', $recur_charge);
 163
 164       # if it's a percentage discount, calculate it based on that estimate.
 165       # otherwise use the flat amount.
 166
 167       if ( $discount->percent > 0 ) {
 168         $amount = $recur_charge * $discount->percent / 100;
 169       } elsif ( $discount->amount > 0
 170                 and $cust_pkg->pkgpart == $param->{'real_pkgpart'} ) {
 171         $amount = $discount->amount * $months;
 172       }
 173
 174       if ( exists $param->{'discount_left_recur'}{$discount->discountnum} ) {
 175         # there is a discount_left_recur entry for this discountnum, so this
 176         # is the second (recur) pass on the discount.  use up transferred
 177         # remainder of discount from setup.
 178         #
 179         # note that discount_left_recur can now be zero.
 180         $amount = $param->{'discount_left_recur'}{$discount->discountnum};
 181         $param->{'discount_left_recur'}{$discount->discountnum} = 0;
 182         $months = 1; # XXX really? not $chg_months?
 183       }
 184       #elsif (    $discount->setup
 185       #          && ($discount->months || 0) == 1
 186       #          && $discount->amount > 0
 187       #        ) {
 188       #    next;
 189       #
 190       #    RT #11512: bugfix to prevent applying flat discount to both setup
 191       #    and recur. The original implementation ignored discount_left_recur
 192       #    if it was zero, so if the setup fee used up the entire flat
 193       #    discount, the recurring charge would get to use the entire flat
 194       #    discount also. This bugfix was a kludge. Instead, we now allow
 195       #    discount_left_recur to be zero in that case, and then the available
 196       #    recur discount is zero.
 197       #}
 198
 199       # Transfer remainder of discount, if any, to setup
 200       # This is used when the recur phase wants to add a setup fee
 201       # (prorate_defer_bill): the "discount_left_setup" amount will
 202       # be subtracted in _make_lines.
 203       if ( $discount->amount > 0 && ($discount->months || 0) != 1 )
 204       {
 205         # make sure there is a setup discount with this discountnum
 206         # on the same package.
 207         if ( qsearchs('cust_pkg_discount', {
 208               pkgnum      => $cust_pkg->pkgnum,
 209               discountnum => $discount->discountnum,
 210               setuprecur  => 'setup'
 211             }) )
 212         {
 213           # $amount is no longer permonth at this point! correct. very good.
 214           $discount_left = $amount - $recur_charge; # backward, as above
 215           if ( $discount_left > 0 ) {
 216             $amount = $recur_charge;
 217             $param->{'discount_left_setup'}{$discount->discountnum} =
 218               0 - $discount_left;
 219           }
 220         }
 221       }
 222
 223       # cap the discount amount at the recur charge
 224       $amount = min($amount, $recur_charge);
 225
 226       # if this is the base pkgpart, schedule increment_months_used to run at
 227       # the end of billing. (addon packages haven't been calculated yet, so
 228       # don't let the discount expire during the billing process. RT#17045.)
 229       if ( $cust_pkg->pkgpart == $param->{'real_pkgpart'} ) {
 230         push @{ $param->{precommit_hooks} }, sub {
 231           my $error = $cust_pkg_discount->increment_months_used($months);
 232           die "error discounting: $error" if $error;
 233         };
 234       }
 235
 236     } # else not 'setup_charge'
 237
 238     $amount = sprintf('%.2f', $amount + 0.00000001 ); #so 1.005 rounds to 1.01
 239
 240     next unless $amount > 0;
 241
 242     #record details in cust_bill_pkg_discount
 243     my $cust_bill_pkg_discount = new FS::cust_bill_pkg_discount {
 244       'pkgdiscountnum' => $cust_pkg_discount->pkgdiscountnum,
 245       'amount'         => $amount,
 246       'months'         => $months,
 247     };
 248     push @{ $param->{'discounts'} }, $cust_bill_pkg_discount;
 249     $tot_discount += $amount;
 250
 251   }
 252
 253   sprintf('%.2f', $tot_discount);
 254 }
 255
 256 1;