FS/FS/part_pkg/bulk.pm

   1 package FS::part_pkg::bulk;
   2
   3 use strict;
   4 use vars qw(@ISA $DEBUG $me %info);
   5 use Date::Format;
   6 use FS::part_pkg::flat;
   7
   8 @ISA = qw(FS::part_pkg::flat);
   9
  10 $DEBUG = 0;
  11 $me = '[FS::part_pkg::bulk]';
  12
  13 %info = (
  14   'name' => 'Bulk billing based on number of active services',
  15   'fields' => {
  16     'setup_fee' => { 'name'    => 'Setup fee for the entire bulk package',
  17                      'default' => 0,
  18                    },
  19     'recur_fee' => { 'name'    => 'Recurring fee for the entire bulk package',
  20                      'default' => 0,
  21                    },
  22     'svc_setup_fee' => { 'name'    => 'Setup fee for each new service',
  23                          'default' => 0,
  24                        },
  25     'svc_recur_fee' => { 'name'    => 'Recurring fee for each service',
  26                          'default' => 0,
  27                        },
  28     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
  29                                    ' of service at cancellation',
  30                          'type' => 'checkbox',
  31                        },
  32     'summarize_svcs'=> { 'name' => 'Show a count of services on the invoice, '.
  33                                    'instead of a detailed list',
  34                          'type' => 'checkbox',
  35                        },
  36     'no_prorate'    => { 'name' => 'Don\'t prorate recurring fees on services '.
  37                                    'active for a partial month',
  38                          'type' => 'checkbox',
  39                        },
  40   },
  41   'fieldorder' => [ 'setup_fee', 'recur_fee', 'svc_setup_fee', 'svc_recur_fee',
  42                     'unused_credit', 'summarize_svcs', 'no_prorate' ],
  43   'weight' => 50,
  44 );
  45
  46 #some false laziness-ish w/agent.pm...  not a lot
  47 sub calc_recur {
  48   my($self, $cust_pkg, $sdate, $details ) = @_;
  49
  50   my $conf = new FS::Conf;
  51   my $money_char = $conf->config('money_char') || '$';
  52
  53   my $svc_setup_fee = $self->option('svc_setup_fee');
  54
  55   my $last_bill = $cust_pkg->last_bill;
  56
  57   return sprintf("%.2f", $self->base_recur($cust_pkg) )
  58     unless $$sdate > $last_bill;
  59
  60   my $total_svc_charge = 0;
  61   my %n_setup = ();
  62   my %n_recur = ();
  63   my %part_svc_label = ();
  64
  65   my $summarize = $self->option('summarize_svcs',1);
  66
  67   warn "$me billing for bulk services from ". time2str('%x', $last_bill).
  68                                       " to ". time2str('%x', $$sdate). "\n"
  69     if $DEBUG;
  70
  71                                            #   END      START
  72   foreach my $h_cust_svc ( $cust_pkg->h_cust_svc( $$sdate, $last_bill ) ) {
  73
  74     my @label = $h_cust_svc->label_long( $$sdate, $last_bill );
  75     die "fatal: no historical label found, wtf?" unless scalar(@label); #?
  76     my $svc_details = $label[0]. ': '. $label[1]. ': ';
  77     $part_svc_label{$h_cust_svc->svcpart} ||= $label[0];
  78
  79     my $svc_charge = 0;
  80
  81     my $svc_start = $h_cust_svc->date_inserted;
  82     if ( $svc_start < $last_bill ) {
  83       $svc_start = $last_bill;
  84     } elsif ( $svc_setup_fee ) {
  85       $svc_charge += $svc_setup_fee;
  86       $svc_details .= $money_char. sprintf('%.2f setup, ', $svc_setup_fee);
  87       $n_setup{$h_cust_svc->svcpart}++;
  88     }
  89
  90     my $svc_end = $h_cust_svc->date_deleted;
  91     $svc_end = ( !$svc_end || $svc_end > $$sdate ) ? $$sdate : $svc_end;
  92
  93     my $recur_charge;
  94     if ( $self->option('no_prorate',1) ) {
  95       $recur_charge = $self->option('svc_recur_fee');
  96     }
  97     else {
  98       $recur_charge = $self->option('svc_recur_fee')
  99                                      * ( $svc_end - $svc_start )
 100                                      / ( $$sdate  - $last_bill );
 101     }
 102
 103     $svc_details .= $money_char. sprintf('%.2f', $recur_charge ).
 104                     ' ('.  time2str('%x', $svc_start).
 105                     ' - '. time2str('%x', $svc_end  ). ')'
 106       if $recur_charge;
 107
 108     $svc_charge += $recur_charge;
 109     $n_recur{$h_cust_svc->svcpart}++;
 110     push @$details, $svc_details if !$summarize;
 111     $total_svc_charge += $svc_charge;
 112
 113   }
 114   if ( $summarize ) {
 115     foreach my $svcpart (keys %part_svc_label) {
 116       push @$details, sprintf('Setup fee: %d @ '.$money_char.'%.2f',
 117         $n_setup{$svcpart}, $svc_setup_fee )
 118         if $svc_setup_fee and $n_setup{$svcpart};
 119       push @$details, sprintf('%d services @ '.$money_char.'%.2f',
 120         $n_recur{$svcpart}, $self->option('svc_recur_fee') )
 121         if $n_recur{$svcpart};
 122     }
 123   }
 124
 125   sprintf('%.2f', $self->base_recur($cust_pkg) + $total_svc_charge );
 126 }
 127
 128 sub can_discount { 0; }
 129
 130 sub hide_svc_detail {
 131   1;
 132 }
 133
 134 sub is_free_options {
 135   qw( setup_fee recur_fee svc_setup_fee svc_recur_fee );
 136 }
 137
 138 1;
 139