FS/FS/part_pkg/agent.pm

   1 package FS::part_pkg::agent;
   2
   3 use strict;
   4 use vars qw(@ISA $DEBUG $me %info);
   5 use Date::Format;
   6 use FS::Record qw( qsearch );
   7 use FS::agent;
   8 use FS::cust_main;
   9
  10 #use FS::part_pkg::recur_Common;;
  11 #@ISA = qw(FS::part_pkg::recur_Common);
  12 use FS::part_pkg::prorate;
  13 @ISA = qw(FS::part_pkg::prorate);
  14
  15 $DEBUG = 0;
  16
  17 $me = '[FS::part_pkg::agent]';
  18
  19 %info = (
  20   'name'      => 'Wholesale bulk billing, for master customers of an agent.',
  21   'shortname' => 'Wholesale bulk billing for agent.',
  22
  23   'fields' => {
  24     'setup_fee'     => { 'name' => 'Setup fee for this package',
  25                          'default' => 0,
  26                        },
  27     'recur_fee'     => { 'name' => 'Base recurring fee for this package',
  28                          'default' => 0,
  29                        },
  30
  31
  32     #'recur_method'  => { 'name' => 'Recurring fee method',
  33     #                     #'type' => 'radio',
  34     #                     #'options' => \%recur_method,
  35     #                     'type' => 'select',
  36     #                     'select_options' => \%recur_Common::recur_method,
  37     #                   },
  38     'cutoff_day'    => { 'name' => 'Billing Day (1 - 28)',
  39                          'default' => '1',
  40                        },
  41
  42     'no_pkg_prorate'   => { 'name' => 'Disable prorating bulk packages (charge full price for packages active only a portion of the month)',
  43                             'type' => 'checkbox',
  44                           },
  45
  46   },
  47
  48   #'fieldorder' => [qw( setup_fee recur_fee recur_method cutoff_day ) ],
  49   'fieldorder' => [qw( setup_fee recur_fee cutoff_day no_pkg_prorate ) ],
  50
  51   'weight' => 51,
  52
  53 );
  54
  55 #some false laziness-ish w/bulk.pm...  not a lot
  56 sub calc_recur {
  57   my $self = shift;
  58   my($cust_pkg, $sdate, $details, $param ) = @_;
  59
  60   my $last_bill = $cust_pkg->last_bill;
  61
  62   return sprintf("%.2f", $self->SUPER::calc_recur(@_) )
  63     unless $$sdate > $last_bill;
  64
  65   my $conf = new FS::Conf;
  66   my $money_char = $conf->config('money_char') || '$';
  67
  68   my $total_agent_charge = 0;
  69
  70   warn "$me billing for agent packages from ". time2str('%x', $last_bill).
  71                                        " to ". time2str('%x', $$sdate). "\n"
  72     if $DEBUG;
  73
  74   my $prorate_ratio =   ( $$sdate                     - $last_bill )
  75                       / ( $self->add_freq($last_bill) - $last_bill );
  76
  77   #almost always just one,
  78   #unless you have multiple agents with same master customer0
  79   my @agents = qsearch('agent', { 'agent_custnum' => $cust_pkg->custnum } );
  80
  81   foreach my $agent (@agents) {
  82
  83     warn "$me billing for agent ". $agent->agent. "\n"
  84       if $DEBUG;
  85
  86     #not the most efficient to load them all into memory,
  87     #but good enough for our current needs
  88     my @cust_main = qsearch('cust_main', { 'agentnum' => $agent->agentnum } );
  89
  90     foreach my $cust_main (@cust_main) {
  91
  92       warn "$me billing agent charges for ". $cust_main->name_short. "\n"
  93         if $DEBUG;
  94
  95       #make sure setup dates are filled in
  96       my $error = $cust_main->bill; #options don't propogate from freeside-daily
  97       die "Error pre-billing agent customer: $error" if $error;
  98
  99       my @cust_pkg = grep { my $setup  = $_->get('setup');
 100                             my $cancel = $_->get('cancel');
 101
 102                             $setup < $$sdate  # END
 103                             && ( ! $cancel || $cancel > $last_bill ) #START
 104                           }
 105                      $cust_main->all_pkgs;
 106
 107       foreach my $cust_pkg ( @cust_pkg ) {
 108
 109         warn "$me billing agent charges for pkgnum ". $cust_pkg->pkgnum. "\n"
 110           if $DEBUG;
 111
 112         my $pkg_details = $cust_main->name_short. ': '; #name?
 113         # + something to identify package... primary service probably
 114
 115         my $pkg_charge = 0;
 116
 117         my $part_pkg = $cust_pkg->part_pkg;
 118         #option to not fallback? via options above
 119         my $pkg_setup_fee  =
 120           $part_pkg->setup_cost || $part_pkg->option('setup_fee');
 121         my $pkg_base_recur =
 122           $part_pkg->recur_cost || $part_pkg->base_recur_permonth($cust_pkg);
 123
 124         my $pkg_start = $cust_pkg->get('setup');
 125         if ( $pkg_start < $last_bill ) {
 126           $pkg_start = $last_bill;
 127         } elsif ( $pkg_setup_fee ) {
 128           $pkg_charge += $pkg_setup_fee;
 129           $pkg_details .= $money_char. sprintf('%.2f setup, ', $pkg_setup_fee );
 130         }
 131
 132         my $pkg_end = $cust_pkg->get('cancel');
 133         $pkg_end = ( !$pkg_end || $pkg_end > $$sdate ) ? $$sdate : $pkg_end;
 134
 135
 136         my $pkg_recur_charge = $prorate_ratio * $pkg_base_recur;
 137         $pkg_recur_charge *= ( $pkg_end - $pkg_start )
 138                            / ( $$sdate  - $last_bill )
 139           unless $self->option('no_pkg_prorate');
 140
 141         my $recur_charge += $pkg_recur_charge;
 142
 143         $pkg_details .= $money_char. sprintf('%.2f', $recur_charge ).
 144                         ' ('.  time2str('%x', $pkg_start).
 145                         ' - '. time2str('%x', $pkg_end  ). ')'
 146           if $recur_charge;
 147
 148         $pkg_charge += $recur_charge;
 149
 150         push @$details, $pkg_details
 151           if $pkg_charge;
 152         $total_agent_charge += $pkg_charge;
 153
 154       } #foreach $cust_pkg
 155
 156     } #foreach $cust_main
 157
 158   } #foreach $agent;
 159
 160   my $charges = $total_agent_charge + $self->SUPER::calc_recur(@_); #prorate
 161
 162   sprintf('%.2f', $charges );
 163
 164 }
 165
 166 sub hide_svc_detail {
 167   1;
 168 }
 169
 170 sub is_free {
 171   0;
 172 }
 173
 174 1;
 175