FS/FS/part_pkg.pm

   1 package FS::part_pkg;
   2
   3 use strict;
   4 use vars qw( @ISA %plans $DEBUG $setup_hack $skip_pkg_svc_hack );
   5 use Carp qw(carp cluck confess);
   6 use Scalar::Util qw( blessed );
   7 use Time::Local qw( timelocal_nocheck );
   8 use Tie::IxHash;
   9 use FS::Conf;
  10 use FS::Record qw( qsearch qsearchs dbh dbdef );
  11 use FS::pkg_svc;
  12 use FS::part_svc;
  13 use FS::cust_pkg;
  14 use FS::agent_type;
  15 use FS::type_pkgs;
  16 use FS::part_pkg_option;
  17 use FS::pkg_class;
  18 use FS::agent;
  19 use FS::part_pkg_taxoverride;
  20 use FS::part_pkg_taxproduct;
  21 use FS::part_pkg_link;
  22
  23 @ISA = qw( FS::m2m_Common FS::option_Common );
  24 $DEBUG = 0;
  25 $setup_hack = 0;
  26 $skip_pkg_svc_hack = 0;
  27
  28 =head1 NAME
  29
  30 FS::part_pkg - Object methods for part_pkg objects
  31
  32 =head1 SYNOPSIS
  33
  34   use FS::part_pkg;
  35
  36   $record = new FS::part_pkg \%hash
  37   $record = new FS::part_pkg { 'column' => 'value' };
  38
  39   $custom_record = $template_record->clone;
  40
  41   $error = $record->insert;
  42
  43   $error = $new_record->replace($old_record);
  44
  45   $error = $record->delete;
  46
  47   $error = $record->check;
  48
  49   @pkg_svc = $record->pkg_svc;
  50
  51   $svcnum = $record->svcpart;
  52   $svcnum = $record->svcpart( 'svc_acct' );
  53
  54 =head1 DESCRIPTION
  55
  56 An FS::part_pkg object represents a package definition.  FS::part_pkg
  57 inherits from FS::Record.  The following fields are currently supported:
  58
  59 =over 4
  60
  61 =item pkgpart - primary key (assigned automatically for new package definitions)
  62
  63 =item pkg - Text name of this package definition (customer-viewable)
  64
  65 =item comment - Text name of this package definition (non-customer-viewable)
  66
  67 =item classnum - Optional package class (see L<FS::pkg_class>)
  68
  69 =item promo_code - Promotional code
  70
  71 =item setup - Setup fee expression (deprecated)
  72
  73 =item freq - Frequency of recurring fee
  74
  75 =item recur - Recurring fee expression (deprecated)
  76
  77 =item setuptax - Setup fee tax exempt flag, empty or `Y'
  78
  79 =item recurtax - Recurring fee tax exempt flag, empty or `Y'
  80
  81 =item taxclass - Tax class
  82
  83 =item plan - Price plan
  84
  85 =item plandata - Price plan data (deprecated - see L<FS::part_pkg_option> instead)
  86
  87 =item disabled - Disabled flag, empty or `Y'
  88
  89 =item custom - Custom flag, empty or `Y'
  90
  91 =item setup_cost - for cost tracking
  92
  93 =item recur_cost - for cost tracking
  94
  95 =item pay_weight - Weight (relative to credit_weight and other package definitions) that controls payment application to specific line items.
  96
  97 =item credit_weight - Weight (relative to other package definitions) that controls credit application to specific line items.
  98
  99 =item agentnum - Optional agentnum (see L<FS::agent>)
 100
 101 =item fcc_ds0s - Optional DS0 equivalency number for FCC form 477
 102
 103 =back
 104
 105 =head1 METHODS
 106
 107 =over 4
 108
 109 =item new HASHREF
 110
 111 Creates a new package definition.  To add the package definition to
 112 the database, see L<"insert">.
 113
 114 =cut
 115
 116 sub table { 'part_pkg'; }
 117
 118 =item clone
 119
 120 An alternate constructor.  Creates a new package definition by duplicating
 121 an existing definition.  A new pkgpart is assigned and the custom flag is
 122 set to Y.  To add the package definition to the database, see L<"insert">.
 123
 124 =cut
 125
 126 sub clone {
 127   my $self = shift;
 128   my $class = ref($self);
 129   my %hash = $self->hash;
 130   $hash{'pkgpart'} = '';
 131   $hash{'custom'} = 'Y';
 132   #new FS::part_pkg ( \%hash ); # ?
 133   new $class ( \%hash ); # ?
 134 }
 135
 136 =item insert [ , OPTION => VALUE ... ]
 137
 138 Adds this package definition to the database.  If there is an error,
 139 returns the error, otherwise returns false.
 140
 141 Currently available options are: I<pkg_svc>, I<primary_svc>, I<cust_pkg>,
 142 I<custnum_ref> and I<options>.
 143
 144 If I<pkg_svc> is set to a hashref with svcparts as keys and quantities as
 145 values, appropriate FS::pkg_svc records will be inserted.
 146
 147 If I<primary_svc> is set to the svcpart of the primary service, the appropriate
 148 FS::pkg_svc record will be updated.
 149
 150 If I<cust_pkg> is set to a pkgnum of a FS::cust_pkg record (or the FS::cust_pkg
 151 record itself), the object will be updated to point to this package definition.
 152
 153 In conjunction with I<cust_pkg>, if I<custnum_ref> is set to a scalar reference,
 154 the scalar will be updated with the custnum value from the cust_pkg record.
 155
 156 If I<tax_overrides> is set to a hashref with usage classes as keys and comma
 157 separated tax class numbers as values, appropriate FS::part_pkg_taxoverride
 158 records will be inserted.
 159
 160 If I<options> is set to a hashref of options, appropriate FS::part_pkg_option
 161 records will be inserted.
 162
 163 =cut
 164
 165 sub insert {
 166   my $self = shift;
 167   my %options = @_;
 168   warn "FS::part_pkg::insert called on $self with options ".
 169        join(', ', map "$_=>$options{$_}", keys %options)
 170     if $DEBUG;
 171
 172   local $SIG{HUP} = 'IGNORE';
 173   local $SIG{INT} = 'IGNORE';
 174   local $SIG{QUIT} = 'IGNORE';
 175   local $SIG{TERM} = 'IGNORE';
 176   local $SIG{TSTP} = 'IGNORE';
 177   local $SIG{PIPE} = 'IGNORE';
 178
 179   my $oldAutoCommit = $FS::UID::AutoCommit;
 180   local $FS::UID::AutoCommit = 0;
 181   my $dbh = dbh;
 182
 183   warn "  inserting part_pkg record" if $DEBUG;
 184   my $error = $self->SUPER::insert( $options{options} );
 185   if ( $error ) {
 186     $dbh->rollback if $oldAutoCommit;
 187     return $error;
 188   }
 189
 190   my $conf = new FS::Conf;
 191   if ( $conf->exists('agent_defaultpkg') ) {
 192     warn "  agent_defaultpkg set; allowing all agents to purchase package"
 193       if $DEBUG;
 194     foreach my $agent_type ( qsearch('agent_type', {} ) ) {
 195       my $type_pkgs = new FS::type_pkgs({
 196         'typenum' => $agent_type->typenum,
 197         'pkgpart' => $self->pkgpart,
 198       });
 199       my $error = $type_pkgs->insert;
 200       if ( $error ) {
 201         $dbh->rollback if $oldAutoCommit;
 202         return $error;
 203       }
 204     }
 205   }
 206
 207   warn "  inserting part_pkg_taxoverride records" if $DEBUG;
 208   my %overrides = %{ $options{'tax_overrides'} || {} };
 209   foreach my $usage_class ( keys %overrides ) {
 210     my $override =
 211       ( exists($overrides{$usage_class}) && defined($overrides{$usage_class}) )
 212         ? $overrides{$usage_class}
 213         : '';
 214     my @overrides = (grep "$_", split(',', $override) );
 215     my $error = $self->process_m2m (
 216                   'link_table'   => 'part_pkg_taxoverride',
 217                   'target_table' => 'tax_class',
 218                   'hashref'      => { 'usage_class' => $usage_class },
 219                   'params'       => \@overrides,
 220                 );
 221     if ( $error ) {
 222       $dbh->rollback if $oldAutoCommit;
 223       return $error;
 224     }
 225   }
 226
 227   unless ( $skip_pkg_svc_hack ) {
 228
 229     warn "  inserting pkg_svc records" if $DEBUG;
 230     my $pkg_svc = $options{'pkg_svc'} || {};
 231     foreach my $part_svc ( qsearch('part_svc', {} ) ) {
 232       my $quantity = $pkg_svc->{$part_svc->svcpart} || 0;
 233       my $primary_svc =
 234         ( $options{'primary_svc'} && $options{'primary_svc'}==$part_svc->svcpart )
 235           ? 'Y'
 236           : '';
 237
 238       my $pkg_svc = new FS::pkg_svc( {
 239         'pkgpart'     => $self->pkgpart,
 240         'svcpart'     => $part_svc->svcpart,
 241         'quantity'    => $quantity,
 242         'primary_svc' => $primary_svc,
 243       } );
 244       my $error = $pkg_svc->insert;
 245       if ( $error ) {
 246         $dbh->rollback if $oldAutoCommit;
 247         return $error;
 248       }
 249     }
 250
 251   }
 252
 253   if ( $options{'cust_pkg'} ) {
 254     warn "  updating cust_pkg record " if $DEBUG;
 255     my $old_cust_pkg =
 256       ref($options{'cust_pkg'})
 257         ? $options{'cust_pkg'}
 258         : qsearchs('cust_pkg', { pkgnum => $options{'cust_pkg'} } );
 259     ${ $options{'custnum_ref'} } = $old_cust_pkg->custnum
 260       if $options{'custnum_ref'};
 261     my %hash = $old_cust_pkg->hash;
 262     $hash{'pkgpart'} = $self->pkgpart,
 263     my $new_cust_pkg = new FS::cust_pkg \%hash;
 264     local($FS::cust_pkg::disable_agentcheck) = 1;
 265     my $error = $new_cust_pkg->replace($old_cust_pkg);
 266     if ( $error ) {
 267       $dbh->rollback if $oldAutoCommit;
 268       return "Error modifying cust_pkg record: $error";
 269     }
 270   }
 271
 272   warn "  commiting transaction" if $DEBUG;
 273   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 274
 275   '';
 276 }
 277
 278 =item delete
 279
 280 Currently unimplemented.
 281
 282 =cut
 283
 284 sub delete {
 285   return "Can't (yet?) delete package definitions.";
 286 # check & make sure the pkgpart isn't in cust_pkg or type_pkgs?
 287 }
 288
 289 =item replace OLD_RECORD [ , OPTION => VALUE ... ]
 290
 291 Replaces OLD_RECORD with this one in the database.  If there is an error,
 292 returns the error, otherwise returns false.
 293
 294 Currently available options are: I<pkg_svc>, I<primary_svc> and I<options>
 295
 296 If I<pkg_svc> is set to a hashref with svcparts as keys and quantities as
 297 values, the appropriate FS::pkg_svc records will be replaced.
 298
 299 If I<primary_svc> is set to the svcpart of the primary service, the appropriate
 300 FS::pkg_svc record will be updated.
 301
 302 If I<options> is set to a hashref, the appropriate FS::part_pkg_option records
 303 will be replaced.
 304
 305 =cut
 306
 307 sub replace {
 308   my $new = shift;
 309
 310   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 311               ? shift
 312               : $new->replace_old;
 313
 314   my $options =
 315     ( ref($_[0]) eq 'HASH' )
 316       ? shift
 317       : { @_ };
 318
 319   $options->{options} = {} unless defined($options->{options});
 320
 321   warn "FS::part_pkg::replace called on $new to replace $old with options".
 322        join(', ', map "$_ => ". $options->{$_}, keys %$options)
 323     if $DEBUG;
 324
 325   local $SIG{HUP} = 'IGNORE';
 326   local $SIG{INT} = 'IGNORE';
 327   local $SIG{QUIT} = 'IGNORE';
 328   local $SIG{TERM} = 'IGNORE';
 329   local $SIG{TSTP} = 'IGNORE';
 330   local $SIG{PIPE} = 'IGNORE';
 331
 332   my $oldAutoCommit = $FS::UID::AutoCommit;
 333   local $FS::UID::AutoCommit = 0;
 334   my $dbh = dbh;
 335
 336   #plandata shit stays in replace for upgrades until after 2.0 (or edit
 337   #_upgrade_data)
 338   warn "  saving legacy plandata" if $DEBUG;
 339   my $plandata = $new->get('plandata');
 340   $new->set('plandata', '');
 341
 342   warn "  deleting old part_pkg_option records" if $DEBUG;
 343   foreach my $part_pkg_option ( $old->part_pkg_option ) {
 344     my $error = $part_pkg_option->delete;
 345     if ( $error ) {
 346       $dbh->rollback if $oldAutoCommit;
 347       return $error;
 348     }
 349   }
 350
 351   warn "  replacing part_pkg record" if $DEBUG;
 352   my $error = $new->SUPER::replace($old, $options->{options} );
 353   if ( $error ) {
 354     $dbh->rollback if $oldAutoCommit;
 355     return $error;
 356   }
 357
 358   warn "  inserting part_pkg_option records for plandata: $plandata|" if $DEBUG;
 359   foreach my $part_pkg_option (
 360     map { /^(\w+)=(.*)$/ or do { $dbh->rollback if $oldAutoCommit;
 361                                  return "illegal plandata: $plandata";
 362                                };
 363           new FS::part_pkg_option {
 364             'pkgpart'     => $new->pkgpart,
 365             'optionname'  => $1,
 366             'optionvalue' => $2,
 367           };
 368         }
 369     split("\n", $plandata)
 370   ) {
 371     my $error = $part_pkg_option->insert;
 372     if ( $error ) {
 373       $dbh->rollback if $oldAutoCommit;
 374       return $error;
 375     }
 376   }
 377
 378   warn "  replacing pkg_svc records" if $DEBUG;
 379   my $pkg_svc = $options->{'pkg_svc'} || {};
 380   foreach my $part_svc ( qsearch('part_svc', {} ) ) {
 381     my $quantity = $pkg_svc->{$part_svc->svcpart} || 0;
 382     my $primary_svc =
 383       ( defined($options->{'primary_svc'}) && $options->{'primary_svc'}
 384         && $options->{'primary_svc'} == $part_svc->svcpart
 385       )
 386         ? 'Y'
 387         : '';
 388
 389
 390     my $old_pkg_svc = qsearchs('pkg_svc', {
 391       'pkgpart' => $old->pkgpart,
 392       'svcpart' => $part_svc->svcpart,
 393     } );
 394     my $old_quantity = $old_pkg_svc ? $old_pkg_svc->quantity : 0;
 395     my $old_primary_svc =
 396       ( $old_pkg_svc && $old_pkg_svc->dbdef_table->column('primary_svc') )
 397         ? $old_pkg_svc->primary_svc
 398         : '';
 399     next unless $old_quantity != $quantity || $old_primary_svc ne $primary_svc;
 400
 401     my $new_pkg_svc = new FS::pkg_svc( {
 402       'pkgsvcnum'   => ( $old_pkg_svc ? $old_pkg_svc->pkgsvcnum : '' ),
 403       'pkgpart'     => $new->pkgpart,
 404       'svcpart'     => $part_svc->svcpart,
 405       'quantity'    => $quantity,
 406       'primary_svc' => $primary_svc,
 407     } );
 408     my $error = $old_pkg_svc
 409                   ? $new_pkg_svc->replace($old_pkg_svc)
 410                   : $new_pkg_svc->insert;
 411     if ( $error ) {
 412       $dbh->rollback if $oldAutoCommit;
 413       return $error;
 414     }
 415   }
 416
 417   warn "  commiting transaction" if $DEBUG;
 418   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 419   '';
 420 }
 421
 422 =item check
 423
 424 Checks all fields to make sure this is a valid package definition.  If
 425 there is an error, returns the error, otherwise returns false.  Called by the
 426 insert and replace methods.
 427
 428 =cut
 429
 430 sub check {
 431   my $self = shift;
 432   warn "FS::part_pkg::check called on $self" if $DEBUG;
 433
 434   for (qw(setup recur plandata)) {
 435     #$self->set($_=>0) if $self->get($_) =~ /^\s*$/; }
 436     return "Use of $_ field is deprecated; set a plan and options: ".
 437            $self->get($_)
 438       if length($self->get($_));
 439     $self->set($_, '');
 440   }
 441
 442   if ( $self->dbdef_table->column('freq')->type =~ /(int)/i ) {
 443     my $error = $self->ut_number('freq');
 444     return $error if $error;
 445   } else {
 446     $self->freq =~ /^(\d+[hdw]?)$/
 447       or return "Illegal or empty freq: ". $self->freq;
 448     $self->freq($1);
 449   }
 450
 451   my @null_agentnum_right = ( 'Edit global package definitions' );
 452   push @null_agentnum_right, 'One-time charge'
 453     if $self->freq =~ /^0/;
 454   push @null_agentnum_right, 'Customize customer package'
 455     if $self->disabled eq 'Y'; #good enough
 456
 457   my $error = $self->ut_numbern('pkgpart')
 458     || $self->ut_text('pkg')
 459     || $self->ut_text('comment')
 460     || $self->ut_textn('promo_code')
 461     || $self->ut_alphan('plan')
 462     || $self->ut_enum('setuptax', [ '', 'Y' ] )
 463     || $self->ut_enum('recurtax', [ '', 'Y' ] )
 464     || $self->ut_textn('taxclass')
 465     || $self->ut_enum('disabled', [ '', 'Y' ] )
 466     || $self->ut_enum('custom', [ '', 'Y' ] )
 467     #|| $self->ut_moneyn('setup_cost')
 468     #|| $self->ut_moneyn('recur_cost')
 469     || $self->ut_floatn('setup_cost')
 470     || $self->ut_floatn('recur_cost')
 471     || $self->ut_floatn('pay_weight')
 472     || $self->ut_floatn('credit_weight')
 473     || $self->ut_numbern('taxproductnum')
 474     || $self->ut_foreign_keyn('taxproductnum',
 475                               'part_pkg_taxproduct',
 476                               'taxproductnum'
 477                              )
 478     || ( $setup_hack
 479            ? $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum' )
 480            : $self->ut_agentnum_acl('agentnum', \@null_agentnum_right)
 481        )
 482     || $self->ut_numbern('fcc_ds0s')
 483     || $self->SUPER::check
 484   ;
 485   return $error if $error;
 486
 487   if ( $self->classnum !~ /^$/ ) {
 488     my $error = $self->ut_foreign_key('classnum', 'pkg_class', 'classnum');
 489     return $error if $error;
 490   } else {
 491     $self->classnum('');
 492   }
 493
 494   return 'Unknown plan '. $self->plan
 495     unless exists($plans{$self->plan});
 496
 497   my $conf = new FS::Conf;
 498   return 'Taxclass is required'
 499     if ! $self->taxclass && $conf->exists('require_taxclasses');
 500
 501   '';
 502 }
 503
 504 =item pkg_comment [ OPTION => VALUE... ]
 505
 506 Returns an (internal) string representing this package.  Currently,
 507 "pkgpart: pkg - comment", is returned.  "pkg - comment" may be returned in the
 508 future, omitting pkgpart.  The comment will have '(CUSTOM) ' prepended if
 509 custom is Y.
 510
 511 If the option nopkgpart is true then the "pkgpart: ' is omitted.
 512
 513 =cut
 514
 515 sub pkg_comment {
 516   my $self = shift;
 517   my %opt = @_;
 518
 519   #$self->pkg. ' - '. $self->comment;
 520   #$self->pkg. ' ('. $self->comment. ')';
 521   my $pre = $opt{nopkgpart} ? '' : $self->pkgpart. ': ';
 522   $pre. $self->pkg. ' - '. $self->custom_comment;
 523 }
 524
 525 sub custom_comment {
 526   my $self = shift;
 527   ( $self->custom ? '(CUSTOM) ' : '' ). $self->comment;
 528 }
 529
 530 =item pkg_class
 531
 532 Returns the package class, as an FS::pkg_class object, or the empty string
 533 if there is no package class.
 534
 535 =cut
 536
 537 sub pkg_class {
 538   my $self = shift;
 539   if ( $self->classnum ) {
 540     qsearchs('pkg_class', { 'classnum' => $self->classnum } );
 541   } else {
 542     return '';
 543   }
 544 }
 545
 546 =item categoryname
 547
 548 Returns the package category name, or the empty string if there is no package
 549 category.
 550
 551 =cut
 552
 553 sub categoryname {
 554   my $self = shift;
 555   my $pkg_class = $self->pkg_class;
 556   $pkg_class
 557     ? $pkg_class->categoryname
 558     : '';
 559 }
 560
 561 =item classname
 562
 563 Returns the package class name, or the empty string if there is no package
 564 class.
 565
 566 =cut
 567
 568 sub classname {
 569   my $self = shift;
 570   my $pkg_class = $self->pkg_class;
 571   $pkg_class
 572     ? $pkg_class->classname
 573     : '';
 574 }
 575
 576 =item agent
 577
 578 Returns the associated agent for this event, if any, as an FS::agent object.
 579
 580 =cut
 581
 582 sub agent {
 583   my $self = shift;
 584   qsearchs('agent', { 'agentnum' => $self->agentnum } );
 585 }
 586
 587 =item pkg_svc [ HASHREF | OPTION => VALUE ]
 588
 589 Returns all FS::pkg_svc objects (see L<FS::pkg_svc>) for this package
 590 definition (with non-zero quantity).
 591
 592 One option is available, I<disable_linked>.  If set true it will return the
 593 services for this package definition alone, omitting services from any add-on
 594 packages.
 595
 596 =cut
 597
 598 =item type_pkgs
 599
 600 Returns all FS::type_pkgs objects (see L<FS::type_pkgs>) for this package
 601 definition.
 602
 603 =cut
 604
 605 sub type_pkgs {
 606   my $self = shift;
 607   qsearch('type_pkgs', { 'pkgpart' => $self->pkgpart } );
 608 }
 609
 610 sub pkg_svc {
 611   my $self = shift;
 612
 613 #  #sort { $b->primary cmp $a->primary }
 614 #    grep { $_->quantity }
 615 #      qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
 616
 617   my $opt = ref($_[0]) ? $_[0] : { @_ };
 618   my %pkg_svc = map  { $_->svcpart => $_ }
 619                 grep { $_->quantity }
 620                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
 621
 622   unless ( $opt->{disable_linked} ) {
 623     foreach my $dst_pkg ( map $_->dst_pkg, $self->svc_part_pkg_link ) {
 624       my @pkg_svc = grep { $_->quantity }
 625                     qsearch( 'pkg_svc', { pkgpart=>$dst_pkg->pkgpart } );
 626       foreach my $pkg_svc ( @pkg_svc ) {
 627         if ( $pkg_svc{$pkg_svc->svcpart} ) {
 628           my $quantity = $pkg_svc{$pkg_svc->svcpart}->quantity;
 629           $pkg_svc{$pkg_svc->svcpart}->quantity($quantity + $pkg_svc->quantity);
 630         } else {
 631           $pkg_svc{$pkg_svc->svcpart} = $pkg_svc;
 632         }
 633       }
 634     }
 635   }
 636
 637   values(%pkg_svc);
 638
 639 }
 640
 641 =item svcpart [ SVCDB ]
 642
 643 Returns the svcpart of the primary service definition (see L<FS::part_svc>)
 644 associated with this package definition (see L<FS::pkg_svc>).  Returns
 645 false if there not a primary service definition or exactly one service
 646 definition with quantity 1, or if SVCDB is specified and does not match the
 647 svcdb of the service definition.  SVCDB can be specified as a scalar table
 648 name, such as 'svc_acct', or as an arrayref of possible table names.
 649
 650 =cut
 651
 652 sub svcpart {
 653   my $pkg_svc = shift->_primary_pkg_svc(@_);
 654   $pkg_svc ? $pkg_svc->svcpart : '';
 655 }
 656
 657 =item part_svc [ SVCDB ]
 658
 659 Like the B<svcpart> method, but returns the FS::part_svc object (see
 660 L<FS::part_svc>).
 661
 662 =cut
 663
 664 sub part_svc {
 665   my $pkg_svc = shift->_primary_pkg_svc(@_);
 666   $pkg_svc ? $pkg_svc->part_svc : '';
 667 }
 668
 669 sub _primary_pkg_svc {
 670   my $self = shift;
 671
 672   my $svcdb = scalar(@_) ? shift : [];
 673   $svcdb = ref($svcdb) ? $svcdb : [ $svcdb ];
 674   my %svcdb = map { $_=>1 } @$svcdb;
 675
 676   my @svcdb_pkg_svc =
 677     grep { !scalar(@$svcdb) || $svcdb{ $_->part_svc->svcdb } }
 678          $self->pkg_svc;
 679
 680   my @pkg_svc = grep { $_->primary_svc =~ /^Y/i } @svcdb_pkg_svc;
 681   @pkg_svc = grep {$_->quantity == 1 } @svcdb_pkg_svc
 682     unless @pkg_svc;
 683   return '' if scalar(@pkg_svc) != 1;
 684   $pkg_svc[0];
 685 }
 686
 687 =item svcpart_unique_svcdb SVCDB
 688
 689 Returns the svcpart of a service definition (see L<FS::part_svc>) matching
 690 SVCDB associated with this package definition (see L<FS::pkg_svc>).  Returns
 691 false if there not a primary service definition for SVCDB or there are multiple
 692 service definitions for SVCDB.
 693
 694 =cut
 695
 696 sub svcpart_unique_svcdb {
 697   my( $self, $svcdb ) = @_;
 698   my @svcdb_pkg_svc = grep { ( $svcdb eq $_->part_svc->svcdb ) } $self->pkg_svc;
 699   return '' if scalar(@svcdb_pkg_svc) != 1;
 700   $svcdb_pkg_svc[0]->svcpart;
 701 }
 702
 703 =item payby
 704
 705 Returns a list of the acceptable payment types for this package.  Eventually
 706 this should come out of a database table and be editable, but currently has the
 707 following logic instead:
 708
 709 If the package is free, the single item B<BILL> is
 710 returned, otherwise, the single item B<CARD> is returned.
 711
 712 (CHEK?  LEC?  Probably shouldn't accept those by default, prone to abuse)
 713
 714 =cut
 715
 716 sub payby {
 717   my $self = shift;
 718   if ( $self->is_free ) {
 719     ( 'BILL' );
 720   } else {
 721     ( 'CARD' );
 722   }
 723 }
 724
 725 =item is_free
 726
 727 Returns true if this package is free.
 728
 729 =cut
 730
 731 sub is_free {
 732   my $self = shift;
 733   unless ( $self->plan ) {
 734     $self->setup =~ /^\s*0+(\.0*)?\s*$/
 735       && $self->recur =~ /^\s*0+(\.0*)?\s*$/;
 736   } elsif ( $self->can('is_free_options') ) {
 737     not grep { $_ !~ /^\s*0*(\.0*)?\s*$/ }
 738          map { $self->option($_) }
 739              $self->is_free_options;
 740   } else {
 741     warn "FS::part_pkg::is_free: FS::part_pkg::". $self->plan. " subclass ".
 742          "provides neither is_free_options nor is_free method; returning false";
 743     0;
 744   }
 745 }
 746
 747
 748 sub freqs_href {
 749   # moved to FS::Misc to make this accessible to other packages
 750   # at initialization
 751   FS::Misc::pkg_freqs();
 752 }
 753
 754 =item freq_pretty
 755
 756 Returns an english representation of the I<freq> field, such as "monthly",
 757 "weekly", "semi-annually", etc.
 758
 759 =cut
 760
 761 sub freq_pretty {
 762   my $self = shift;
 763   my $freq = $self->freq;
 764
 765   #my $freqs_href = $self->freqs_href;
 766   my $freqs_href = freqs_href();
 767
 768   if ( exists($freqs_href->{$freq}) ) {
 769     $freqs_href->{$freq};
 770   } else {
 771     my $interval = 'month';
 772     if ( $freq =~ /^(\d+)([hdw])$/ ) {
 773       my %interval = ( 'h' => 'hour', 'd'=>'day', 'w'=>'week' );
 774       $interval = $interval{$2};
 775     }
 776     if ( $1 == 1 ) {
 777       "every $interval";
 778     } else {
 779       "every $freq ${interval}s";
 780     }
 781   }
 782 }
 783
 784 =item add_freq TIMESTAMP
 785
 786 Adds the frequency of this package to the provided timestamp and returns
 787 the resulting timestamp, or -1 if the frequency of this package could not be
 788 parsed (shouldn't happen).
 789
 790 =cut
 791
 792 sub add_freq {
 793   my( $self, $date ) = @_;
 794   my $freq = $self->freq;
 795
 796   #change this bit to use Date::Manip? CAREFUL with timezones (see
 797   # mailing list archive)
 798   my ($sec,$min,$hour,$mday,$mon,$year) = (localtime($date) )[0,1,2,3,4,5];
 799
 800   if ( $self->freq =~ /^\d+$/ ) {
 801     $mon += $self->freq;
 802     until ( $mon < 12 ) { $mon -= 12; $year++; }
 803   } elsif ( $self->freq =~ /^(\d+)w$/ ) {
 804     my $weeks = $1;
 805     $mday += $weeks * 7;
 806   } elsif ( $self->freq =~ /^(\d+)d$/ ) {
 807     my $days = $1;
 808     $mday += $days;
 809   } elsif ( $self->freq =~ /^(\d+)h$/ ) {
 810     my $hours = $1;
 811     $hour += $hours;
 812   } else {
 813     return -1;
 814   }
 815
 816   timelocal_nocheck($sec,$min,$hour,$mday,$mon,$year);
 817 }
 818
 819 =item plandata
 820
 821 For backwards compatibility, returns the plandata field as well as all options
 822 from FS::part_pkg_option.
 823
 824 =cut
 825
 826 sub plandata {
 827   my $self = shift;
 828   carp "plandata is deprecated";
 829   if ( @_ ) {
 830     $self->SUPER::plandata(@_);
 831   } else {
 832     my $plandata = $self->get('plandata');
 833     my %options = $self->options;
 834     $plandata .= join('', map { "$_=$options{$_}\n" } keys %options );
 835     $plandata;
 836   }
 837 }
 838
 839 =item part_pkg_option
 840
 841 Returns all options as FS::part_pkg_option objects (see
 842 L<FS::part_pkg_option>).
 843
 844 =cut
 845
 846 sub part_pkg_option {
 847   my $self = shift;
 848   qsearch('part_pkg_option', { 'pkgpart' => $self->pkgpart } );
 849 }
 850
 851 =item options
 852
 853 Returns a list of option names and values suitable for assigning to a hash.
 854
 855 =cut
 856
 857 sub options {
 858   my $self = shift;
 859   map { $_->optionname => $_->optionvalue } $self->part_pkg_option;
 860 }
 861
 862 =item option OPTIONNAME
 863
 864 Returns the option value for the given name, or the empty string.
 865
 866 =cut
 867
 868 sub option {
 869   my( $self, $opt, $ornull ) = @_;
 870   my $part_pkg_option =
 871     qsearchs('part_pkg_option', {
 872       pkgpart    => $self->pkgpart,
 873       optionname => $opt,
 874   } );
 875   return $part_pkg_option->optionvalue if $part_pkg_option;
 876   my %plandata = map { /^(\w+)=(.*)$/; ( $1 => $2 ); }
 877                      split("\n", $self->get('plandata') );
 878   return $plandata{$opt} if exists $plandata{$opt};
 879   cluck "WARNING: (pkgpart ". $self->pkgpart. ") Package def option $opt ".
 880         "not found in options or plandata!\n"
 881     unless $ornull;
 882   '';
 883 }
 884
 885 =item bill_part_pkg_link
 886
 887 Returns the associated part_pkg_link records (see L<FS::part_pkg_link>).
 888
 889 =cut
 890
 891 sub bill_part_pkg_link {
 892   shift->_part_pkg_link('bill', @_);
 893 }
 894
 895 =item svc_part_pkg_link
 896
 897 Returns the associated part_pkg_link records (see L<FS::part_pkg_link>).
 898
 899 =cut
 900
 901 sub svc_part_pkg_link {
 902   shift->_part_pkg_link('svc', @_);
 903 }
 904
 905 sub _part_pkg_link {
 906   my( $self, $type ) = @_;
 907   qsearch({ table    => 'part_pkg_link',
 908             hashref  => { 'src_pkgpart' => $self->pkgpart,
 909                           'link_type'   => $type,
 910                         },
 911             order_by => "ORDER BY hidden",
 912          });
 913 }
 914
 915 sub self_and_bill_linked {
 916   shift->_self_and_linked('bill', @_);
 917 }
 918
 919 sub _self_and_linked {
 920   my( $self, $type, $hidden ) = @_;
 921   $hidden ||= '';
 922
 923   my @result = ();
 924   foreach ( ( $self, map { $_->dst_pkg->_self_and_linked($type, $_->hidden) }
 925                      $self->_part_pkg_link($type) ) )
 926   {
 927     $_->hidden($hidden) if $hidden;
 928     push @result, $_;
 929   }
 930
 931   (@result);
 932 }
 933
 934 =item part_pkg_taxoverride [ CLASS ]
 935
 936 Returns all associated FS::part_pkg_taxoverride objects (see
 937 L<FS::part_pkg_taxoverride>).  Limits the returned set to those
 938 of class CLASS if defined.  Class may be one of 'setup', 'recur',
 939 the empty string (default), or a usage class number (see L<FS::usage_class>).
 940 When a class is specified, the empty string class (default) is returned
 941 if no more specific values exist.
 942
 943 =cut
 944
 945 sub part_pkg_taxoverride {
 946   my $self = shift;
 947   my $class = shift;
 948
 949   my $hashref = { 'pkgpart' => $self->pkgpart };
 950   $hashref->{'usage_class'} = $class if defined($class);
 951   my @overrides = qsearch('part_pkg_taxoverride', $hashref );
 952
 953   unless ( scalar(@overrides) || !defined($class) || !$class ){
 954     $hashref->{'usage_class'} = '';
 955     @overrides = qsearch('part_pkg_taxoverride', $hashref );
 956   }
 957
 958   @overrides;
 959 }
 960
 961 =item has_taxproduct
 962
 963 Returns true if this package has any taxproduct associated with it.
 964
 965 =cut
 966
 967 sub has_taxproduct {
 968   my $self = shift;
 969
 970   $self->taxproductnum ||
 971   scalar( grep { $_ =~/^usage_taxproductnum_/ && $self->option($_) }
 972           keys %{ {$self->options} }
 973   )
 974
 975 }
 976
 977
 978 =item taxproduct [ CLASS ]
 979
 980 Returns the associated tax product for this package definition (see
 981 L<FS::part_pkg_taxproduct>).  CLASS may be one of 'setup', 'recur' or
 982 the usage classnum (see L<FS::usage_class>).  Returns the default
 983 tax product for this record if the more specific CLASS value does
 984 not exist.
 985
 986 =cut
 987
 988 sub taxproduct {
 989   my $self = shift;
 990   my $class = shift;
 991
 992   my $part_pkg_taxproduct;
 993
 994   my $taxproductnum = $self->taxproductnum;
 995   if ($class) {
 996     my $class_taxproductnum = $self->option("usage_taxproductnum_$class", 1);
 997     $taxproductnum = $class_taxproductnum
 998       if $class_taxproductnum
 999   }
1000
1001   $part_pkg_taxproduct =
1002     qsearchs( 'part_pkg_taxproduct', { 'taxproductnum' => $taxproductnum } );
1003
1004   unless ($part_pkg_taxproduct || $taxproductnum eq $self->taxproductnum ) {
1005     $taxproductnum = $self->taxproductnum;
1006     $part_pkg_taxproduct =
1007       qsearchs( 'part_pkg_taxproduct', { 'taxproductnum' => $taxproductnum } );
1008   }
1009
1010   $part_pkg_taxproduct;
1011 }
1012
1013 =item taxproduct_description [ CLASS ]
1014
1015 Returns the description of the associated tax product for this package
1016 definition (see L<FS::part_pkg_taxproduct>).
1017
1018 =cut
1019
1020 sub taxproduct_description {
1021   my $self = shift;
1022   my $part_pkg_taxproduct = $self->taxproduct(@_);
1023   $part_pkg_taxproduct ? $part_pkg_taxproduct->description : '';
1024 }
1025
1026 =item part_pkg_taxrate DATA_PROVIDER, GEOCODE, [ CLASS ]
1027
1028 Returns the package to taxrate m2m records for this package in the location
1029 specified by GEOCODE (see L<FS::part_pkg_taxrate>) and usage class CLASS.
1030 CLASS may be one of 'setup', 'recur', or one of the usage classes numbers
1031 (see L<FS::usage_class>).
1032
1033 =cut
1034
1035 sub _expand_cch_taxproductnum {
1036   my $self = shift;
1037   my $class = shift;
1038   my $part_pkg_taxproduct = $self->taxproduct($class);
1039
1040   my ($a,$b,$c,$d) = ( $part_pkg_taxproduct
1041                          ? ( split ':', $part_pkg_taxproduct->taxproduct )
1042                          : ()
1043                      );
1044   $a = '' unless $a; $b = '' unless $b; $c = '' unless $c; $d = '' unless $d;
1045   my $extra_sql = "AND ( taxproduct = '$a:$b:$c:$d'
1046                       OR taxproduct = '$a:$b:$c:'
1047                       OR taxproduct = '$a:$b:".":$d'
1048                       OR taxproduct = '$a:$b:".":' )";
1049   map { $_->taxproductnum } qsearch( { 'table'     => 'part_pkg_taxproduct',
1050                                        'hashref'   => { 'data_vendor'=>'cch' },
1051                                        'extra_sql' => $extra_sql,
1052                                    } );
1053
1054 }
1055
1056 sub part_pkg_taxrate {
1057   my $self = shift;
1058   my ($data_vendor, $geocode, $class) = @_;
1059
1060   my $dbh = dbh;
1061   my $extra_sql = 'WHERE part_pkg_taxproduct.data_vendor = '.
1062                   dbh->quote($data_vendor);
1063
1064   # CCH oddness in m2m
1065   $extra_sql .= ' AND ('.
1066     join(' OR ', map{ 'geocode = '. $dbh->quote(substr($geocode, 0, $_)) }
1067                  qw(10 5 2)
1068         ).
1069     ')';
1070   # much more CCH oddness in m2m -- this is kludgy
1071   my @tpnums = $self->_expand_cch_taxproductnum($class);
1072   if (scalar(@tpnums)) {
1073     $extra_sql .= ' AND ('.
1074                             join(' OR ', map{ "taxproductnum = $_" } @tpnums ).
1075                        ')';
1076   } else {
1077     $extra_sql .= ' AND ( 0 = 1 )';
1078   }
1079
1080   my $addl_from = 'LEFT JOIN part_pkg_taxproduct USING ( taxproductnum )';
1081   my $order_by = 'ORDER BY taxclassnum, length(geocode) desc, length(taxproduct) desc';
1082   my $select   = 'DISTINCT ON(taxclassnum) *, taxproduct';
1083
1084   # should qsearch preface columns with the table to facilitate joins?
1085   qsearch( { 'table'     => 'part_pkg_taxrate',
1086              'select'    => $select,
1087              'hashref'   => { # 'data_vendor'   => $data_vendor,
1088                               # 'taxproductnum' => $self->taxproductnum,
1089                             },
1090              'addl_from' => $addl_from,
1091              'extra_sql' => $extra_sql,
1092              'order_by'  => $order_by,
1093          } );
1094 }
1095
1096 =item _rebless
1097
1098 Reblesses the object into the FS::part_pkg::PLAN class (if available), where
1099 PLAN is the object's I<plan> field.  There should be better docs
1100 on how to create new price plans, but until then, see L</NEW PLAN CLASSES>.
1101
1102 =cut
1103
1104 sub _rebless {
1105   my $self = shift;
1106   my $plan = $self->plan;
1107   unless ( $plan ) {
1108     cluck "no price plan found for pkgpart ". $self->pkgpart. "\n"
1109       if $DEBUG;
1110     return $self;
1111   }
1112   return $self if ref($self) =~ /::$plan$/; #already blessed into plan subclass
1113   my $class = ref($self). "::$plan";
1114   warn "reblessing $self into $class" if $DEBUG;
1115   eval "use $class;";
1116   die $@ if $@;
1117   bless($self, $class) unless $@;
1118   $self;
1119 }
1120
1121 #fallbacks that eval the setup and recur fields, for backwards compat
1122
1123 sub calc_setup {
1124   my $self = shift;
1125   warn 'no price plan class for '. $self->plan. ", eval-ing setup\n";
1126   $self->_calc_eval('setup', @_);
1127 }
1128
1129 sub calc_recur {
1130   my $self = shift;
1131   warn 'no price plan class for '. $self->plan. ", eval-ing recur\n";
1132   $self->_calc_eval('recur', @_);
1133 }
1134
1135 use vars qw( $sdate @details );
1136 sub _calc_eval {
1137   #my( $self, $field, $cust_pkg ) = @_;
1138   my( $self, $field, $cust_pkg, $sdateref, $detailsref ) = @_;
1139   *sdate = $sdateref;
1140   *details = $detailsref;
1141   $self->$field() =~ /^(.*)$/
1142     or die "Illegal $field (pkgpart ". $self->pkgpart. '): '.
1143             $self->$field(). "\n";
1144   my $prog = $1;
1145   return 0 if $prog =~ /^\s*$/;
1146   my $value = eval $prog;
1147   die $@ if $@;
1148   $value;
1149 }
1150
1151 #fallback that return 0 for old legacy packages with no plan
1152
1153 sub calc_remain { 0; }
1154 sub calc_cancel { 0; }
1155 sub calc_units  { 0; }
1156
1157 #fallback for everything except bulk.pm
1158 sub hide_svc_detail { 0; }
1159
1160 =item recur_cost_permonth CUST_PKG
1161
1162 recur_cost divided by freq (only supported for monthly and longer frequencies)
1163
1164 =cut
1165
1166 sub recur_cost_permonth {
1167   my($self, $cust_pkg) = @_;
1168   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
1169   sprintf('%.2f', $self->recur_cost / $self->freq );
1170 }
1171
1172 =item format OPTION DATA
1173
1174 Returns data formatted according to the function 'format' described
1175 in the plan info.  Returns DATA if no such function exists.
1176
1177 =cut
1178
1179 sub format {
1180   my ($self, $option, $data) = (shift, shift, shift);
1181   if (exists($plans{$self->plan}->{fields}->{$option}{format})) {
1182     &{$plans{$self->plan}->{fields}->{$option}{format}}($data);
1183   }else{
1184     $data;
1185   }
1186 }
1187
1188 =item parse OPTION DATA
1189
1190 Returns data parsed according to the function 'parse' described
1191 in the plan info.  Returns DATA if no such function exists.
1192
1193 =cut
1194
1195 sub parse {
1196   my ($self, $option, $data) = (shift, shift, shift);
1197   if (exists($plans{$self->plan}->{fields}->{$option}{parse})) {
1198     &{$plans{$self->plan}->{fields}->{$option}{parse}}($data);
1199   }else{
1200     $data;
1201   }
1202 }
1203
1204 =back
1205
1206 =cut
1207
1208 =head1 CLASS METHODS
1209
1210 =over 4
1211
1212 =cut
1213
1214 # _upgrade_data
1215 #
1216 # Used by FS::Upgrade to migrate to a new database.
1217
1218 sub _upgrade_data { # class method
1219   my($class, %opts) = @_;
1220
1221   warn "[FS::part_pkg] upgrading $class\n" if $DEBUG;
1222
1223   my @part_pkg = qsearch({
1224     'table'     => 'part_pkg',
1225     'extra_sql' => "WHERE ". join(' OR ',
1226                      ( map "($_ IS NOT NULL AND $_ != '' )",
1227                            qw( plandata setup recur ) ),
1228                      'plan IS NULL', "plan = '' ",
1229                    ),
1230   });
1231
1232   foreach my $part_pkg (@part_pkg) {
1233
1234     unless ( $part_pkg->plan ) {
1235       $part_pkg->plan('flat');
1236     }
1237
1238     if ( length($part_pkg->option('setup_fee')) == 0
1239          && $part_pkg->setup =~ /^\s*([\d\.]+)\s*$/ ) {
1240
1241       my $opt = new FS::part_pkg_option {
1242         'pkgpart'     => $part_pkg->pkgpart,
1243         'optionname'  => 'setup_fee',
1244         'optionvalue' => $1,
1245       };
1246       my $error = $opt->insert;
1247       die $error if $error;
1248
1249
1250       #} else {
1251       #  die "Can't parse part_pkg.setup for fee; convert pkgnum ".
1252       #      $part_pkg->pkgnum. " manually: ". $part_pkg->setup. "\n";
1253     }
1254     $part_pkg->setup('');
1255
1256     if ( length($part_pkg->option('recur_fee')) == 0
1257          && $part_pkg->recur =~ /^\s*([\d\.]+)\s*$/ ) {
1258
1259         my $opt = new FS::part_pkg_option {
1260           'pkgpart'     => $part_pkg->pkgpart,
1261           'optionname'  => 'recur_fee',
1262           'optionvalue' => $1,
1263         };
1264         my $error = $opt->insert;
1265         die $error if $error;
1266
1267
1268       #} else {
1269       #  die "Can't parse part_pkg.setup for fee; convert pkgnum ".
1270       #      $part_pkg->pkgnum. " manually: ". $part_pkg->setup. "\n";
1271     }
1272     $part_pkg->recur('');
1273
1274     $part_pkg->replace; #this should take care of plandata, right?
1275
1276   }
1277
1278   # now upgrade to the explicit custom flag
1279
1280   @part_pkg = qsearch({
1281     'table'     => 'part_pkg',
1282     'hashref'   => { disabled => 'Y', custom => '' },
1283     'extra_sql' => "AND comment LIKE '(CUSTOM) %'",
1284   });
1285
1286   foreach my $part_pkg (@part_pkg) {
1287     my $new = new FS::part_pkg { $part_pkg->hash };
1288     $new->custom('Y');
1289     my $comment = $part_pkg->comment;
1290     $comment =~ s/^\(CUSTOM\) //;
1291     $comment = '(none)' unless $comment =~ /\S/;
1292     $new->comment($comment);
1293
1294     my $pkg_svc = { map { $_->svcpart => $_->quantity } $part_pkg->pkg_svc };
1295     my $primary = $part_pkg->svcpart;
1296     my $options = { $part_pkg->options };
1297
1298     my $error = $new->replace( $part_pkg,
1299                                'pkg_svc'     => $pkg_svc,
1300                                'primary_svc' => $primary,
1301                                'options'     => $options,
1302                              );
1303     die $error if $error;
1304   }
1305
1306 }
1307
1308 =item curuser_pkgs_sql
1309
1310 Returns an SQL fragment for searching for packages the current user can
1311 use, either via part_pkg.agentnum directly, or via agent type (see
1312 L<FS::type_pkgs>).
1313
1314 =cut
1315
1316 sub curuser_pkgs_sql {
1317   my $class = shift;
1318
1319   $class->_pkgs_sql( $FS::CurrentUser::CurrentUser->agentnums );
1320
1321 }
1322
1323 =item agent_pkgs_sql AGENT | AGENTNUM, ...
1324
1325 Returns an SQL fragment for searching for packages the provided agent or agents
1326 can use, either via part_pkg.agentnum directly, or via agent type (see
1327 L<FS::type_pkgs>).
1328
1329 =cut
1330
1331 sub agent_pkgs_sql {
1332   my $class = shift;  #i'm a class method, not a sub (the question is... why??)
1333   my @agentnums = map { ref($_) ? $_->agentnum : $_ } @_;
1334
1335   $class->_pkgs_sql(@agentnums); #is this why
1336
1337 }
1338
1339 sub _pkgs_sql {
1340   my( $class, @agentnums ) = @_;
1341   my $agentnums = join(',', @agentnums);
1342
1343   "
1344     (
1345       ( agentnum IS NOT NULL AND agentnum IN ($agentnums) )
1346       OR ( agentnum IS NULL
1347            AND EXISTS ( SELECT 1
1348                           FROM type_pkgs
1349                             LEFT JOIN agent_type USING ( typenum )
1350                             LEFT JOIN agent AS typeagent USING ( typenum )
1351                           WHERE type_pkgs.pkgpart = part_pkg.pkgpart
1352                             AND typeagent.agentnum IN ($agentnums)
1353                       )
1354          )
1355     )
1356   ";
1357
1358 }
1359
1360 =back
1361
1362 =head1 SUBROUTINES
1363
1364 =over 4
1365
1366 =item plan_info
1367
1368 =cut
1369
1370 #false laziness w/part_export & cdr
1371 my %info;
1372 foreach my $INC ( @INC ) {
1373   warn "globbing $INC/FS/part_pkg/*.pm\n" if $DEBUG;
1374   foreach my $file ( glob("$INC/FS/part_pkg/*.pm") ) {
1375     warn "attempting to load plan info from $file\n" if $DEBUG;
1376     $file =~ /\/(\w+)\.pm$/ or do {
1377       warn "unrecognized file in $INC/FS/part_pkg/: $file\n";
1378       next;
1379     };
1380     my $mod = $1;
1381     my $info = eval "use FS::part_pkg::$mod; ".
1382                     "\\%FS::part_pkg::$mod\::info;";
1383     if ( $@ ) {
1384       die "error using FS::part_pkg::$mod (skipping): $@\n" if $@;
1385       next;
1386     }
1387     unless ( keys %$info ) {
1388       warn "no %info hash found in FS::part_pkg::$mod, skipping\n";
1389       next;
1390     }
1391     warn "got plan info from FS::part_pkg::$mod: $info\n" if $DEBUG;
1392     if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
1393       warn "skipping disabled plan FS::part_pkg::$mod" if $DEBUG;
1394       next;
1395     }
1396     $info{$mod} = $info;
1397   }
1398 }
1399
1400 tie %plans, 'Tie::IxHash',
1401   map  { $_ => $info{$_} }
1402   sort { $info{$a}->{'weight'} <=> $info{$b}->{'weight'} }
1403   keys %info;
1404
1405 sub plan_info {
1406   \%plans;
1407 }
1408
1409
1410 =back
1411
1412 =head1 NEW PLAN CLASSES
1413
1414 A module should be added in FS/FS/part_pkg/  Eventually, an example may be
1415 found in eg/plan_template.pm.  Until then, it is suggested that you use the
1416 other modules in FS/FS/part_pkg/ as a guide.
1417
1418 =head1 BUGS
1419
1420 The delete method is unimplemented.
1421
1422 setup and recur semantics are not yet defined (and are implemented in
1423 FS::cust_bill.  hmm.).  now they're deprecated and need to go.
1424
1425 plandata should go
1426
1427 part_pkg_taxrate is Pg specific
1428
1429 replace should be smarter about managing the related tables (options, pkg_svc)
1430
1431 =head1 SEE ALSO
1432
1433 L<FS::Record>, L<FS::cust_pkg>, L<FS::type_pkgs>, L<FS::pkg_svc>, L<Safe>.
1434 schema.html from the base documentation.
1435
1436 =cut
1437
1438 1;
1439