FS/FS/part_export/netsapiens.pm

   1 package FS::part_export::netsapiens;
   2
   3 use vars qw(@ISA %info);
   4 use URI;
   5 use MIME::Base64;
   6 use Tie::IxHash;
   7 use FS::part_export;
   8
   9 @ISA = qw(FS::part_export);
  10
  11 tie my %options, 'Tie::IxHash',
  12   'login'         => { label=>'NetSapiens tac2 API username' },
  13   'password'      => { label=>'NetSapiens tac2 API password' },
  14   'url'           => { label=>'NetSapiens tac2 URL' },
  15   'domain'        => { label=>'NetSapiens Domain' },
  16 ;
  17
  18 %info = (
  19   'svc'      => 'svc_phone',
  20   'desc'     => 'Provision phone numbers to NetSapiens',
  21   'options'  => \%options,
  22   'notes'    => <<'END'
  23 Requires installation of
  24 <a href="http://search.cpan.org/dist/REST-Client">REST::Client</a>
  25 from CPAN.
  26 END
  27 );
  28
  29 sub rebless { shift; }
  30
  31 sub ns_command {
  32   my( $self, $method, $command ) = splice(@_,0,3);
  33
  34   eval 'use REST::Client';
  35   die $@ if $@;
  36
  37   my $ns = new REST::Client 'host'=>$self->option('url');
  38
  39   my @args = ( $command );
  40
  41   if ( $method eq 'PUT' ) {
  42     my $content = $ns->buildQuery( { @_ } );
  43     $content =~ s/^\?//;
  44     push @args, $content;
  45   } elsif ( $method eq 'GET' ) {
  46     $args[0] .= $ns->buildQuery( { @_ } );
  47   }
  48
  49   my $auth =
  50     encode_base64( $self->option('login'). ':'. $self->option('password') );
  51   push @args, { 'Authorization' => "Basic $auth" };
  52
  53   $ns->$method( @args );
  54   $ns;
  55 }
  56
  57 sub ns_subscriber {
  58   my($self, $svc_phone) = (shift, shift);
  59
  60   my $domain = $self->option('domain');
  61   my $phonenum = $svc_phone->phonenum;
  62
  63   "/domains_config/$domain/subscriber_config/$phonenum";
  64 }
  65
  66 sub ns_create_or_update {
  67   my($self, $svc_phone, $dial_policy) = (shift, shift, shift);
  68
  69   my $domain = $self->option('domain');
  70   my $phonenum = $svc_phone->phonenum;
  71
  72   my( $firstname, $lastname );
  73   if ( $svc_phone->phone_name =~ /^\s*(\S+)\s+(\S.*\S)\s*$/ ) {
  74     $firstname = $1;
  75     $lastname  = $2;
  76   } else {
  77     #deal w/unaudited netsapiens services?
  78     my $cust_main = $svc_phone->cust_svc->cust_pkg->cust_main;
  79     $firstname = $cust_main->get('first');
  80     $lastname  = $cust_main->get('last');
  81   }
  82
  83   my $ns = $self->ns_command( 'PUT', $self->ns_subscriber($svc_phone),
  84                                 'subscriber_login' => $phonenum.'@'.$domain,
  85                                 'firstname'        => $firstname,
  86                                 'lastname'         => $lastname,
  87                                 'subscriber_pin'   => $svc_phone->pin,
  88                                 'dial_plan'        => 'Default', #config?
  89                                 'dial_policy'      => $dial_policy,
  90                             );
  91
  92   if ( $ns->responseCode !~ /^2/ ) {
  93      return $ns->responseCode. ' '.
  94             join(', ', $self->ns_parse_response( $ns->responseContent ) );
  95   }
  96
  97   '';
  98 }
  99
 100 sub ns_delete {
 101   my($self, $svc_phone) = (shift, shift);
 102
 103   my $ns = $self->ns_command( 'DELETE', $self->ns_subscriber($svc_phone) );
 104
 105   if ( $ns->responseCode !~ /^2/ ) {
 106      return $ns->responseCode. ' '.
 107             join(', ', $self->ns_parse_response( $ns->responseContent ) );
 108   }
 109
 110   '';
 111
 112 }
 113
 114 sub ns_parse_response {
 115   my( $self, $content ) = ( shift, shift );
 116
 117   #try to screen-scrape something useful
 118   tie my %hash, Tie::IxHash;
 119   while ( $content =~ s/^.*?<p>\s*<b>(.+?)<\/b>\s*(.+?)\s*<\/p>//is ) {
 120     ( $hash{$1} = $2 ) =~ s/^\s*<(\w+)>(.+?)<\/\1>/$2/is;
 121   }
 122
 123   %hash;
 124 }
 125
 126 sub _export_insert {
 127   my($self, $svc_phone) = (shift, shift);
 128   $self->ns_create_or_update($svc_phone, 'Permit All');
 129 }
 130
 131 sub _export_replace {
 132   my( $self, $new, $old ) = (shift, shift, shift);
 133   return "can't change phonenum with NetSapiens (unprovision and reprovision?)"
 134     if $old->phonenum ne $new->phonenum;
 135   $self->_export_insert($new);
 136 }
 137
 138 sub _export_delete {
 139   my( $self, $svc_phone ) = (shift, shift);
 140
 141   $self->ns_delete($svc_phone);
 142 }
 143
 144 sub _export_suspend {
 145   my( $self, $svc_phone ) = (shift, shift);
 146   $self->ns_create_or_udpate($svc_phone, 'Deny');
 147 }
 148
 149 sub _export_unsuspend {
 150   my( $self, $svc_phone ) = (shift, shift);
 151   #$self->ns_create_or_update($svc_phone, 'Permit All');
 152   $self->_export_insert($svc_phone);
 153 }
 154
 155 sub export_links {
 156   my($self, $svc_phone, $arrayref) = (shift, shift, shift);
 157   #push @$arrayref, qq!<A HREF="http://example.com/~!. $svc_phone->username.
 158   #                 qq!">!. $svc_phone->username. qq!</A>!;
 159   '';
 160 }
 161
 162 1;