FS/FS/part_event_condition.pm

   1 package FS::part_event_condition;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG @SKIP_CONDITION_SQL );
   5 use FS::UID qw(dbh);
   6 use FS::Record qw( qsearch qsearchs );
   7 use FS::option_Common;
   8 use FS::part_event; #for order_conditions_sql...
   9
  10 @ISA = qw( FS::option_Common ); # FS::Record );
  11 $DEBUG = 0;
  12
  13 @SKIP_CONDITION_SQL = ();
  14
  15 =head1 NAME
  16
  17 FS::part_event_condition - Object methods for part_event_condition records
  18
  19 =head1 SYNOPSIS
  20
  21   use FS::part_event_condition;
  22
  23   $record = new FS::part_event_condition \%hash;
  24   $record = new FS::part_event_condition { 'column' => 'value' };
  25
  26   $error = $record->insert;
  27
  28   $error = $new_record->replace($old_record);
  29
  30   $error = $record->delete;
  31
  32   $error = $record->check;
  33
  34 =head1 DESCRIPTION
  35
  36 An FS::part_event_condition object represents an event condition.
  37 FS::part_event_condition inherits from FS::Record.  The following fields are
  38 currently supported:
  39
  40 =over 4
  41
  42 =item eventconditionnum - primary key
  43
  44 =item eventpart - Event definition (see L<FS::part_event>)
  45
  46 =item conditionname - Condition name - defines which FS::part_event::Condition::I<conditionname> evaluates this condition
  47
  48 =back
  49
  50 =head1 METHODS
  51
  52 =over 4
  53
  54 =item new HASHREF
  55
  56 Creates a new event.  To add the example to the database, see L<"insert">.
  57
  58 Note that this stores the hash reference, not a distinct copy of the hash it
  59 points to.  You can ask the object for a copy with the I<hash> method.
  60
  61 =cut
  62
  63 # the new method can be inherited from FS::Record, if a table method is defined
  64
  65 sub table { 'part_event_condition'; }
  66
  67 =item insert [ HASHREF | OPTION => VALUE ... ]
  68
  69 Adds this record to the database.  If there is an error, returns the error,
  70 otherwise returns false.
  71
  72 If a list or hash reference of options is supplied, part_event_condition_option
  73 records are created (see L<FS::part_event_condition_option>).
  74
  75 =cut
  76
  77 # the insert method can be inherited from FS::Record
  78
  79 =item delete
  80
  81 Delete this record from the database.
  82
  83 =cut
  84
  85 # the delete method can be inherited from FS::Record
  86
  87 =item replace OLD_RECORD [ HASHREF | OPTION => VALUE ... ]
  88
  89 Replaces the OLD_RECORD with this one in the database.  If there is an error,
  90 returns the error, otherwise returns false.
  91
  92 If a list or hash reference of options is supplied, part_event_condition_option
  93 records are created or modified (see L<FS::part_event_condition_option>).
  94
  95 =cut
  96
  97 # the replace method can be inherited from FS::Record
  98
  99 =item check
 100
 101 Checks all fields to make sure this is a valid example.  If there is
 102 an error, returns the error, otherwise returns false.  Called by the insert
 103 and replace methods.
 104
 105 =cut
 106
 107 # the check method should currently be supplied - FS::Record contains some
 108 # data checking routines
 109
 110 sub check {
 111   my $self = shift;
 112
 113   my $error =
 114     $self->ut_numbern('eventconditionnum')
 115     || $self->ut_foreign_key('eventpart', 'part_event', 'eventpart')
 116     || $self->ut_alpha('conditionname')
 117   ;
 118   return $error if $error;
 119
 120   #XXX check conditionname to make sure a module exists?
 121   # well it'll die in _rebless...
 122
 123   $self->SUPER::check;
 124 }
 125
 126
 127 =item _rebless
 128
 129 Reblesses the object into the FS::part_event::Condition::CONDITIONNAME class,
 130 where CONDITIONNAME is the object's I<conditionname> field.
 131
 132 =cut
 133
 134 sub _rebless {
 135   my $self = shift;
 136   my $conditionname = $self->conditionname;
 137   #my $class = ref($self). "::$conditionname";
 138   my $class = "FS::part_event::Condition::$conditionname";
 139   eval "use $class";
 140   die $@ if $@;
 141   bless($self, $class); #unless $@;
 142   $self;
 143 }
 144
 145 =back
 146
 147 =head1 CLASS METHODS
 148
 149 =over 4
 150
 151 =item conditions [ EVENTTABLE ]
 152
 153 Return information about the available conditions.  If an eventtable is
 154 specified, only return information about conditions available for that
 155 eventtable.
 156
 157 Information is returned as key-value pairs.  Keys are condition names.  Values
 158 are hashrefs with the following keys:
 159
 160 =over 4
 161
 162 =item description
 163
 164 =item option_fields
 165
 166 # =item default_weight
 167
 168 # =item deprecated
 169
 170 =back
 171
 172 See L<FS::part_event::Condition> for more information.
 173
 174 =cut
 175
 176 #false laziness w/part_event.pm
 177 #some false laziness w/part_export & part_pkg
 178 my %conditions;
 179 foreach my $INC ( @INC ) {
 180   foreach my $file ( glob("$INC/FS/part_event/Condition/*.pm") ) {
 181     warn "attempting to load Condition from $file\n" if $DEBUG;
 182     $file =~ /\/(\w+)\.pm$/ or do {
 183       warn "unrecognized file in $INC/FS/part_event/Condition/: $file\n";
 184       next;
 185     };
 186     my $mod = $1;
 187     my $fullmod = "FS::part_event::Condition::$mod";
 188     eval "use $fullmod;";
 189     if ( $@ ) {
 190       die "error using $fullmod (skipping): $@\n" if $@;
 191       #warn "error using $fullmod (skipping): $@\n" if $@;
 192       #next;
 193     }
 194     #my $full_condition_sql = $fullmod. '::condition_sql';
 195     my $condition_sql_coderef = sub { $fullmod->condition_sql(@_) };
 196     my $order_sql_coderef = $fullmod->can('order_sql')
 197                               ? sub { $fullmod->order_sql(@_) }
 198                               : '';
 199     $conditions{$mod} = {
 200       ( map { $_ => $fullmod->$_() }
 201             qw( description eventtable_hashref
 202                 implicit_flag remove_warning
 203                 order_sql_weight
 204               )
 205             # deprecated
 206             #option_fields_hashref
 207       ),
 208       'option_fields' => [ $fullmod->option_fields() ],
 209       'condition_sql' => $condition_sql_coderef,
 210       'order_sql'     => $order_sql_coderef,
 211     };
 212   }
 213 }
 214
 215 sub conditions {
 216   my( $class, $eventtable ) = @_;
 217   (
 218     map  { $_ => $conditions{$_} }
 219 #    sort { $conditions{$a}->{'default_weight'}<=>$conditions{$b}->{'default_weight'} }
 220 #    sort by ?
 221     $class->all_conditionnames( $eventtable )
 222   );
 223
 224 }
 225
 226 =item all_conditionnames [ EVENTTABLE ]
 227
 228 Returns a list of just the condition names
 229
 230 =cut
 231
 232 sub all_conditionnames {
 233   my ( $class, $eventtable ) = @_;
 234
 235   grep { !$eventtable || $conditions{$_}->{'eventtable_hashref'}{$eventtable} }
 236        keys %conditions
 237 }
 238
 239 =item join_conditions_sql [ EVENTTABLE ]
 240
 241 Returns an SQL fragment selecting joining all condition options for an event as
 242 tables titled "cond_I<conditionname>".  Typically used in conjunction with
 243 B<where_conditions_sql>.
 244
 245 =cut
 246
 247 sub join_conditions_sql {
 248   my ( $class, $eventtable ) = @_;
 249   my %conditions = $class->conditions( $eventtable );
 250
 251   join(' ',
 252     map {
 253           "LEFT JOIN part_event_condition AS cond_$_".
 254           "  ON ( part_event.eventpart = cond_$_.eventpart".
 255           "       AND cond_$_.conditionname = ". dbh->quote($_).
 256           "     )";
 257         }
 258         keys %conditions
 259   );
 260
 261 }
 262
 263 =item where_conditions_sql [ EVENTTABLE [ , OPTION => VALUE, ... ] ]
 264
 265 Returns an SQL fragment to select events which have unsatisfied conditions.
 266 Must be used in conjunction with B<join_conditions_sql>.
 267
 268 The only current option is "time", the current time (or "pretend" current time
 269 as passed to freeside-daily), as a UNIX timestamp.
 270
 271 =cut
 272
 273 sub where_conditions_sql {
 274   my ( $class, $eventtable, %options ) = @_;
 275
 276   my $time = $options{'time'};
 277
 278   my %conditions = $class->conditions( $eventtable );
 279
 280   my $where = join(' AND ',
 281     map {
 282           my $conditionname = $_;
 283           my $coderef = $conditions{$conditionname}->{condition_sql};
 284           my $sql = &$coderef( $eventtable, 'time'=>$time );
 285           die "$coderef is not a CODEREF" unless ref($coderef) eq 'CODE';
 286           "( cond_$conditionname.conditionname IS NULL OR $sql )";
 287         }
 288         grep { my $cond = $_;
 289                ! grep { $_ eq $cond } @SKIP_CONDITION_SQL
 290              }
 291              keys %conditions
 292   );
 293
 294   $where;
 295 }
 296
 297 =item order_conditions_sql [ EVENTTABLE ]
 298
 299 Returns an SQL fragment to order selected events.  Must be used in conjunction
 300 with B<join_conditions_sql>.
 301
 302 =cut
 303
 304 sub order_conditions_sql {
 305   my( $class, $eventtable ) = @_;
 306
 307   my %conditions = $class->conditions( $eventtable );
 308
 309   my $eventtables = join(' ', FS::part_event->eventtables_runorder);
 310
 311   my $order_by = join(', ',
 312     "position( part_event.eventtable in ' $eventtables ')",
 313     ( map  {
 314              my $conditionname = $_;
 315              my $coderef = $conditions{$conditionname}->{order_sql};
 316              my $sql = &$coderef( $eventtable );
 317              "CASE WHEN cond_$conditionname.conditionname IS NULL
 318                  THEN -1
 319                  ELSE $sql
 320               END
 321              ";
 322            }
 323       sort {     $conditions{$a}->{order_sql_weight}
 324              <=> $conditions{$b}->{order_sql_weight}
 325            }
 326       grep { $conditions{$_}->{order_sql} }
 327            keys %conditions
 328     ),
 329     'part_event.weight'
 330   );
 331
 332   "ORDER BY $order_by";
 333
 334 }
 335
 336 =back
 337
 338 =head1 BUGS
 339
 340 =head1 SEE ALSO
 341
 342 L<FS::part_event::Condition>, L<FS::part_event>, L<FS::Record>, schema.html from
 343 the base documentation.
 344
 345 =cut
 346
 347 1;
 348