FS/FS/part_event/Condition/signupdate_day.pm

   1 package FS::part_event::Condition::signupdate_day;
   2
   3 use strict;
   4 use Tie::IxHash;
   5
   6 use base qw( FS::part_event::Condition );
   7
   8 sub description {
   9   "Customer signed up on the same day of month as today";
  10 }
  11
  12 sub option_fields {
  13   (
  14     'delay' => { label  => 'Delay additional days',
  15                  type   => 'text',
  16                  value  => '0',
  17                },
  18   );
  19 }
  20
  21 sub condition {
  22   my( $self, $object, %opt ) = @_;
  23
  24   my $cust_main = $self->cust_main($object);
  25
  26   my ($today) = (localtime($opt{'time'}))[3];
  27
  28   my $delay = $self->option('delay') || 0;
  29   my $signupday = ((localtime($cust_main->signupdate + $delay * 86400))[3] - 1)
  30                    % 28 + 1;
  31
  32   $today == $signupday;
  33 }
  34
  35 sub condition_sql {
  36   my( $class, $table, %opt ) = @_;
  37   my $mday;
  38   if ( $opt{'driver_name'} eq 'Pg' ) {
  39     $mday = sub{ "EXTRACT( DAY FROM TO_TIMESTAMP($_[0]) )::INTEGER" };
  40   }
  41   elsif ( $opt{'driver_name'} eq 'mysql' ) {
  42     $mday = sub{ "DAY( FROM_UNIXTIME($_[0]) )" };
  43   }
  44   else {
  45     return 'true';
  46   }
  47
  48   my $delay = $class->condition_sql_option_integer('delay',
  49     $opt{'driver_name'}); # returns 0 for null
  50   $mday->($opt{'time'}) . ' = '.
  51     '(' . $mday->("cust_main.signupdate + $delay * 86400") . ' - 1) % 28 + 1';
  52 }
  53
  54 1;