FS/FS/msg_template.pm

   1 package FS::msg_template;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use Text::Template;
   6 use FS::Misc qw( generate_email send_email );
   7 use FS::Conf;
   8 use FS::Record qw( qsearch qsearchs );
   9
  10 use Date::Format qw( time2str );
  11 use HTML::Entities qw( decode_entities encode_entities ) ;
  12 use HTML::FormatText;
  13 use HTML::TreeBuilder;
  14 use vars '$DEBUG';
  15
  16 $DEBUG=0;
  17
  18 =head1 NAME
  19
  20 FS::msg_template - Object methods for msg_template records
  21
  22 =head1 SYNOPSIS
  23
  24   use FS::msg_template;
  25
  26   $record = new FS::msg_template \%hash;
  27   $record = new FS::msg_template { 'column' => 'value' };
  28
  29   $error = $record->insert;
  30
  31   $error = $new_record->replace($old_record);
  32
  33   $error = $record->delete;
  34
  35   $error = $record->check;
  36
  37 =head1 DESCRIPTION
  38
  39 An FS::msg_template object represents a customer message template.
  40 FS::msg_template inherits from FS::Record.  The following fields are currently
  41 supported:
  42
  43 =over 4
  44
  45 =item msgnum
  46
  47 primary key
  48
  49 =item msgname
  50
  51 Template name.
  52
  53 =item agentnum
  54
  55 Agent associated with this template.  Can be NULL for a global template.
  56
  57 =item mime_type
  58
  59 MIME type.  Defaults to text/html.
  60
  61 =item from_addr
  62
  63 Source email address.
  64
  65 =item subject
  66
  67 The message subject line, in L<Text::Template> format.
  68
  69 =item body
  70
  71 The message body, as plain text or HTML, in L<Text::Template> format.
  72
  73 =item disabled
  74
  75 disabled
  76
  77 =back
  78
  79 =head1 METHODS
  80
  81 =over 4
  82
  83 =item new HASHREF
  84
  85 Creates a new template.  To add the template to the database, see L<"insert">.
  86
  87 Note that this stores the hash reference, not a distinct copy of the hash it
  88 points to.  You can ask the object for a copy with the I<hash> method.
  89
  90 =cut
  91
  92 # the new method can be inherited from FS::Record, if a table method is defined
  93
  94 sub table { 'msg_template'; }
  95
  96 =item insert
  97
  98 Adds this record to the database.  If there is an error, returns the error,
  99 otherwise returns false.
 100
 101 =cut
 102
 103 # the insert method can be inherited from FS::Record
 104
 105 =item delete
 106
 107 Delete this record from the database.
 108
 109 =cut
 110
 111 # the delete method can be inherited from FS::Record
 112
 113 =item replace OLD_RECORD
 114
 115 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 116 returns the error, otherwise returns false.
 117
 118 =cut
 119
 120 # the replace method can be inherited from FS::Record
 121
 122 =item check
 123
 124 Checks all fields to make sure this is a valid template.  If there is
 125 an error, returns the error, otherwise returns false.  Called by the insert
 126 and replace methods.
 127
 128 =cut
 129
 130 # the check method should currently be supplied - FS::Record contains some
 131 # data checking routines
 132
 133 sub check {
 134   my $self = shift;
 135
 136   my $error =
 137     $self->ut_numbern('msgnum')
 138     || $self->ut_text('msgname')
 139     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 140     || $self->ut_textn('mime_type')
 141     || $self->ut_anything('subject')
 142     || $self->ut_anything('body')
 143     || $self->ut_enum('disabled', [ '', 'Y' ] )
 144     || $self->ut_textn('from_addr')
 145   ;
 146   return $error if $error;
 147
 148   $self->mime_type('text/html') unless $self->mime_type;
 149
 150   $self->SUPER::check;
 151 }
 152
 153 =item prepare OPTION => VALUE
 154
 155 Fills in the template and returns a hash of the 'from' address, 'to'
 156 addresses, subject line, and body.
 157
 158 Options are passed as a list of name/value pairs:
 159
 160 =over 4
 161
 162 =item cust_main
 163
 164 Customer object (required).
 165
 166 =item object
 167
 168 Additional context object (currently, can be a cust_main, cust_pkg,
 169 cust_bill, svc_acct, cust_pay, or cust_pay_pending object).
 170
 171 =back
 172
 173 =cut
 174
 175 sub prepare {
 176   my( $self, %opt ) = @_;
 177
 178   my $cust_main = $opt{'cust_main'};
 179   my $object = $opt{'object'};
 180   warn "preparing template '".$self->msgname."' to cust#".$cust_main->custnum."\n"
 181     if($DEBUG);
 182
 183   my $subs = $self->substitutions;
 184
 185   ###
 186   # create substitution table
 187   ###
 188   my %hash;
 189   foreach my $obj ($cust_main, $object || ()) {
 190     foreach my $name (@{ $subs->{$obj->table} }) {
 191       if(!ref($name)) {
 192         # simple case
 193         $hash{$name} = $obj->$name();
 194       }
 195       elsif( ref($name) eq 'ARRAY' ) {
 196         # [ foo => sub { ... } ]
 197         $hash{$name->[0]} = $name->[1]->($obj);
 198       }
 199       else {
 200         warn "bad msg_template substitution: '$name'\n";
 201         #skip it?
 202       }
 203     }
 204   }
 205   $_ = encode_entities($_) foreach values(%hash);
 206
 207
 208   ###
 209   # clean up template
 210   ###
 211   my $subject_tmpl = new Text::Template (
 212     TYPE   => 'STRING',
 213     SOURCE => $self->subject,
 214   );
 215   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 216
 217   my $body = $self->body;
 218   my ($skin, $guts) = eviscerate($body);
 219   @$guts = map {
 220     $_ = decode_entities($_); # turn all punctuation back into itself
 221     s/\r//gs;           # remove \r's
 222     s/<br[^>]*>/\n/gsi; # and <br /> tags
 223     s/<p>/\n/gsi;       # and <p>
 224     s/<\/p>//gsi;       # and </p>
 225     s/\240/ /gs;        # and &nbsp;
 226     $_
 227   } @$guts;
 228
 229   $body = '';
 230   while(@$skin || @$guts) {
 231     $body .= shift(@$skin) || '';
 232     $body .= shift(@$guts) || '';
 233   }
 234
 235   ###
 236   # fill-in
 237   ###
 238
 239   my $body_tmpl = new Text::Template (
 240     TYPE          => 'STRING',
 241     SOURCE        => $body,
 242   );
 243
 244   $body = $body_tmpl->fill_in( HASH => \%hash );
 245
 246   ###
 247   # and email
 248   ###
 249
 250   my @to = $cust_main->invoicing_list_emailonly;
 251   warn "prepared msg_template with no email destination (custnum ".
 252     $cust_main->custnum.")\n"
 253     if !@to;
 254
 255   my $conf = new FS::Conf;
 256
 257   (
 258     'from' => $self->from_addr ||
 259               scalar( $conf->config('invoice_from', $cust_main->agentnum) ),
 260     'to'   => \@to,
 261     'bcc'  => $self->bcc_addr || undef,
 262     'subject'   => $subject,
 263     'html_body' => $body,
 264     'text_body' => HTML::FormatText->new(leftmargin => 0, rightmargin => 70
 265                     )->format( HTML::TreeBuilder->new_from_content($body) ),
 266   );
 267
 268 }
 269
 270 =item send OPTION => VALUE
 271
 272 Fills in the template and sends it to the customer.  Options are as for
 273 'prepare'.
 274
 275 =cut
 276
 277 # broken out from prepare() in case we want to queue the sending,
 278 # preview it, etc.
 279 sub send {
 280   my $self = shift;
 281   send_email(generate_email($self->prepare(@_)));
 282 }
 283
 284 # helper sub for package dates
 285 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 286
 287 # needed for some things
 288 my $conf = new FS::Conf;
 289
 290 #return contexts and fill-in values
 291 # If you add anything, be sure to add a description in
 292 # httemplate/edit/msg_template.html.
 293 sub substitutions {
 294   { 'cust_main' => [qw(
 295       display_custnum agentnum agent_name
 296
 297       last first company
 298       name name_short contact contact_firstlast
 299       address1 address2 city county state zip
 300       country
 301       daytime night fax
 302
 303       has_ship_address
 304       ship_last ship_first ship_company
 305       ship_name ship_name_short ship_contact ship_contact_firstlast
 306       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 307       ship_country
 308       ship_daytime ship_night ship_fax
 309
 310       paymask payname paytype payip
 311       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 312       classname categoryname
 313       balance
 314       invoicing_list_emailonly
 315       cust_status ucfirst_cust_status cust_statuscolor
 316
 317       signupdate dundate
 318       ),
 319       [ signupdate_ymd    => sub { time2str('%Y-%m-%d', shift->signupdate) } ],
 320       [ dundate_ymd       => sub { time2str('%Y-%m-%d', shift->dundate) } ],
 321       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 322       [ otaker_first      => sub { shift->access_user->first } ],
 323       [ otaker_last       => sub { shift->access_user->last } ],
 324       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 325       [ company_name      => sub {
 326           $conf->config('company_name', shift->agentnum)
 327         } ],
 328       [ company_address   => sub {
 329           $conf->config('company_address', shift->agentnum)
 330         } ],
 331     ],
 332     # next_bill_date
 333     'cust_pkg'  => [qw(
 334       pkgnum pkg_label pkg_label_long
 335       location_label
 336       status statuscolor
 337
 338       start_date setup bill last_bill
 339       adjourn susp expire
 340       labels_short
 341       ),
 342       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 343       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 344       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 345       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 346       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 347       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 348       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 349       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 350       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 351     ],
 352     'cust_bill' => [qw(
 353       invnum
 354       _date
 355     )],
 356     #XXX not really thinking about cust_bill substitutions quite yet
 357
 358     # for welcome and limit warning messages
 359     'svc_acct' => [qw(
 360       username
 361       ),
 362       [ password          => sub { shift->getfield('_password') } ],
 363     ],
 364     # for payment receipts
 365     'cust_pay' => [qw(
 366       paynum
 367       _date
 368       ),
 369       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 370       # overrides the one in cust_main in cases where a cust_pay is passed
 371       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 372       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 373       [ payinfo           => sub {
 374           my $cust_pay = shift;
 375           ($cust_pay->payby eq 'CARD' || $cust_pay->payby eq 'CHEK') ?
 376             $cust_pay->paymask : $cust_pay->decrypt($cust_pay->payinfo)
 377         } ],
 378     ],
 379     # for payment decline messages
 380     # try to support all cust_pay fields
 381     # 'error' is a special case, it contains the raw error from the gateway
 382     'cust_pay_pending' => [qw(
 383       _date
 384       error
 385       ),
 386       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 387       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 388       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 389       [ payinfo           => sub {
 390           my $pending = shift;
 391           ($pending->payby eq 'CARD' || $pending->payby eq 'CHEK') ?
 392             $pending->paymask : $pending->decrypt($pending->payinfo)
 393         } ],
 394     ],
 395   };
 396 }
 397
 398 sub _upgrade_data {
 399   my ($self, %opts) = @_;
 400
 401   my @fixes = (
 402     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 403     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 404     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 405     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 406     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 407     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 408     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 409   );
 410
 411   my $conf = new FS::Conf;
 412   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 413   foreach my $agentnum (@agentnums) {
 414     foreach (@fixes) {
 415       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 416       if ($conf->exists($oldname, $agentnum)) {
 417         my $new = new FS::msg_template({
 418            'msgname'   => $oldname,
 419            'agentnum'  => $agentnum,
 420            'from_addr' => ($from && $conf->config($from, $agentnum)) ||
 421                           $conf->config('invoice_from', $agentnum),
 422            'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 423            'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 424            'mime_type' => 'text/html',
 425            'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 426         });
 427         my $error = $new->insert;
 428         die $error if $error;
 429         $conf->set($newname, $new->msgnum, $agentnum);
 430         $conf->delete($oldname, $agentnum);
 431         $conf->delete($from, $agentnum) if $from;
 432         $conf->delete($subject, $agentnum) if $subject;
 433       }
 434     }
 435   }
 436 }
 437
 438 sub eviscerate {
 439   # Every bit as pleasant as it sounds.
 440   #
 441   # We do this because Text::Template::Preprocess doesn't
 442   # actually work.  It runs the entire template through
 443   # the preprocessor, instead of the code segments.  Which
 444   # is a shame, because Text::Template already contains
 445   # the code to do this operation.
 446   my $body = shift;
 447   my (@outside, @inside);
 448   my $depth = 0;
 449   my $chunk = '';
 450   while($body || $chunk) {
 451     my ($first, $delim, $rest);
 452     # put all leading non-delimiters into $first
 453     ($first, $rest) =
 454         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 455     $chunk .= $first;
 456     # put a leading delimiter into $delim if there is one
 457     ($delim, $rest) =
 458       ($rest =~ /^([{}]?)(.*)$/s);
 459
 460     if( $delim eq '{' ) {
 461       $chunk .= '{';
 462       if( $depth == 0 ) {
 463         push @outside, $chunk;
 464         $chunk = '';
 465       }
 466       $depth++;
 467     }
 468     elsif( $delim eq '}' ) {
 469       $depth--;
 470       if( $depth == 0 ) {
 471         push @inside, $chunk;
 472         $chunk = '';
 473       }
 474       $chunk .= '}';
 475     }
 476     else {
 477       # no more delimiters
 478       if( $depth == 0 ) {
 479         push @outside, $chunk . $rest;
 480       } # else ? something wrong
 481       last;
 482     }
 483     $body = $rest;
 484   }
 485   (\@outside, \@inside);
 486 }
 487
 488 =back
 489
 490 =head1 BUGS
 491
 492 =head1 SEE ALSO
 493
 494 L<FS::Record>, schema.html from the base documentation.
 495
 496 =cut
 497
 498 1;
 499