FS/FS/detail_format/sum_duration_prefix.pm

   1 package FS::detail_format::sum_duration_prefix;
   2
   3 use strict;
   4 use vars qw( $DEBUG );
   5 use base qw(FS::detail_format);
   6 use List::Util qw(sum);
   7
   8 $DEBUG = 0;
   9
  10 my $me = '[sum_duration_prefix]';
  11
  12 sub name { 'Summary, one line per destination prefix' };
  13 # and also..."rate group"?  what do you call the interstate/intrastate rate
  14 # distinction?
  15
  16 sub header_detail {
  17   'Destination NPA-NXX,Interstate Calls,Duration,Intrastate Calls,Duration,Price';
  18 }
  19
  20 my $prefix_length = 6;
  21 # possibly should use rate_prefix for this, but interstate/intrastate uses
  22 # them in a strange way and we are following along
  23
  24 sub append {
  25   my $self = shift;
  26   my $prefixes = ($self->{prefixes} ||= {});
  27   foreach my $cdr (@_) {
  28     my $phonenum = $self->{inbound} ? $cdr->src : $cdr->dst;
  29     $phonenum =~ /^(\d{$prefix_length})/;
  30     my $prefix = $1 || 'other';
  31     warn "$me appending ".$cdr->dst." to $prefix\n" if $DEBUG;
  32
  33     # XXX hardcoded ratenames, not the worst of evils
  34     $prefixes->{$prefix} ||= {
  35       Interstate => { count => 0, duration => 0, amount => 0 },
  36       Intrastate => { count => 0, duration => 0, amount => 0 },
  37     };
  38     my $object = $self->{inbound} ? $cdr->cdr_termination(1) : $cdr;
  39     # XXX using $cdr's rated_ratename instead of $object because
  40     # cdr_termination doesn't have one...
  41     # but interstate-ness should be symmetric, yes?  if A places an
  42     # interstate call to B, then B receives an interstate call from A.
  43     my $subtotal = $prefixes->{$prefix}{$cdr->rated_ratename}
  44       or die "unknown rated_ratename '" .$cdr->rated_ratename.
  45              "' in CDR #".$cdr->acctid."\n";
  46     $subtotal->{count}++;
  47     $subtotal->{duration} += $object->rated_seconds;
  48     $subtotal->{amount} += $object->rated_price;
  49   }
  50 }
  51
  52 sub finish {
  53   my $self = shift;
  54   my $prefixes = $self->{prefixes};
  55   foreach my $prefix (sort { $a cmp $b } keys %$prefixes) {
  56
  57     warn "processing $prefix\n" if $DEBUG;
  58
  59     my $ratenames = $prefixes->{$prefix};
  60     my @subtotals = ($ratenames->{'Interstate'}, $ratenames->{'Intrastate'});
  61     my $total_amount   = sum( map { $_->{'amount'} } @subtotals );
  62     my $total_duration = sum( map { $_->{'duration'} } @subtotals );
  63     $prefix =~ s/(...)(...)/$1 - $2/;
  64
  65     next if $total_amount < 0.01;
  66
  67     $self->csv->combine(
  68       $prefix,
  69       map({
  70           $_->{count},
  71           (int($_->{duration}/60) . ' min'),
  72         } @subtotals ),
  73       $self->money_char . sprintf('%.02f',$total_amount),
  74     );
  75
  76     warn "adding detail: ".$self->csv->string."\n" if $DEBUG;
  77
  78     push @{ $self->{buffer} }, FS::cust_bill_pkg_detail->new({
  79         amount      => $total_amount,
  80         format      => 'C',
  81         classnum    => '', #ignored in this format
  82         duration    => $total_duration,
  83         phonenum    => '', # not divided up per service
  84         accountcode => '', #ignored in this format
  85         startdate   => '', #could use the earliest startdate in the bunch?
  86         regionname  => '', #no, we're using prefix instead
  87         detail      => $self->csv->string,
  88     });
  89   } #foreach $prefix
  90 }
  91
  92 1;