FS/FS/cust_svc.pm

   1 package FS::cust_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $ignore_quantity );
   5 use Carp qw( carp cluck );
   6 use FS::Conf;
   7 use FS::Record qw( qsearch qsearchs dbh );
   8 use FS::cust_pkg;
   9 use FS::part_pkg;
  10 use FS::part_svc;
  11 use FS::pkg_svc;
  12 use FS::svc_acct;
  13 use FS::svc_domain;
  14 use FS::svc_forward;
  15 use FS::svc_broadband;
  16 use FS::svc_external;
  17 use FS::domain_record;
  18 use FS::part_export;
  19
  20 @ISA = qw( FS::Record );
  21
  22 $DEBUG = 0;
  23
  24 $ignore_quantity = 0;
  25
  26 sub _cache {
  27   my $self = shift;
  28   my ( $hashref, $cache ) = @_;
  29   if ( $hashref->{'username'} ) {
  30     $self->{'_svc_acct'} = FS::svc_acct->new($hashref, '');
  31   }
  32   if ( $hashref->{'svc'} ) {
  33     $self->{'_svcpart'} = FS::part_svc->new($hashref);
  34   }
  35 }
  36
  37 =head1 NAME
  38
  39 FS::cust_svc - Object method for cust_svc objects
  40
  41 =head1 SYNOPSIS
  42
  43   use FS::cust_svc;
  44
  45   $record = new FS::cust_svc \%hash
  46   $record = new FS::cust_svc { 'column' => 'value' };
  47
  48   $error = $record->insert;
  49
  50   $error = $new_record->replace($old_record);
  51
  52   $error = $record->delete;
  53
  54   $error = $record->check;
  55
  56   ($label, $value) = $record->label;
  57
  58 =head1 DESCRIPTION
  59
  60 An FS::cust_svc represents a service.  FS::cust_svc inherits from FS::Record.
  61 The following fields are currently supported:
  62
  63 =over 4
  64
  65 =item svcnum - primary key (assigned automatically for new services)
  66
  67 =item pkgnum - Package (see L<FS::cust_pkg>)
  68
  69 =item svcpart - Service definition (see L<FS::part_svc>)
  70
  71 =back
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item new HASHREF
  78
  79 Creates a new service.  To add the refund to the database, see L<"insert">.
  80 Services are normally created by creating FS::svc_ objects (see
  81 L<FS::svc_acct>, L<FS::svc_domain>, and L<FS::svc_forward>, among others).
  82
  83 =cut
  84
  85 sub table { 'cust_svc'; }
  86
  87 =item insert
  88
  89 Adds this service to the database.  If there is an error, returns the error,
  90 otherwise returns false.
  91
  92 =item delete
  93
  94 Deletes this service from the database.  If there is an error, returns the
  95 error, otherwise returns false.  Note that this only removes the cust_svc
  96 record - you should probably use the B<cancel> method instead.
  97
  98 =item cancel
  99
 100 Cancels the relevant service by calling the B<cancel> method of the associated
 101 FS::svc_XXX object (i.e. an FS::svc_acct object or FS::svc_domain object),
 102 deleting the FS::svc_XXX record and then deleting this record.
 103
 104 If there is an error, returns the error, otherwise returns false.
 105
 106 =cut
 107
 108 sub cancel {
 109   my $self = shift;
 110
 111   local $SIG{HUP} = 'IGNORE';
 112   local $SIG{INT} = 'IGNORE';
 113   local $SIG{QUIT} = 'IGNORE';
 114   local $SIG{TERM} = 'IGNORE';
 115   local $SIG{TSTP} = 'IGNORE';
 116   local $SIG{PIPE} = 'IGNORE';
 117
 118   my $oldAutoCommit = $FS::UID::AutoCommit;
 119   local $FS::UID::AutoCommit = 0;
 120   my $dbh = dbh;
 121
 122   my $part_svc = $self->part_svc;
 123
 124   $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
 125     $dbh->rollback if $oldAutoCommit;
 126     return "Illegal svcdb value in part_svc!";
 127   };
 128   my $svcdb = $1;
 129   require "FS/$svcdb.pm";
 130
 131   my $svc = $self->svc_x;
 132   if ($svc) {
 133     my $error = $svc->cancel;
 134     if ( $error ) {
 135       $dbh->rollback if $oldAutoCommit;
 136       return "Error canceling service: $error";
 137     }
 138     $error = $svc->delete;
 139     if ( $error ) {
 140       $dbh->rollback if $oldAutoCommit;
 141       return "Error deleting service: $error";
 142     }
 143   }
 144
 145   my $error = $self->delete;
 146   if ( $error ) {
 147     $dbh->rollback if $oldAutoCommit;
 148     return "Error deleting cust_svc: $error";
 149   }
 150
 151   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 152
 153   ''; #no errors
 154
 155 }
 156
 157 =item replace OLD_RECORD
 158
 159 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 160 returns the error, otherwise returns false.
 161
 162 =cut
 163
 164 sub replace {
 165   my ( $new, $old ) = ( shift, shift );
 166
 167   local $SIG{HUP} = 'IGNORE';
 168   local $SIG{INT} = 'IGNORE';
 169   local $SIG{QUIT} = 'IGNORE';
 170   local $SIG{TERM} = 'IGNORE';
 171   local $SIG{TSTP} = 'IGNORE';
 172   local $SIG{PIPE} = 'IGNORE';
 173
 174   my $oldAutoCommit = $FS::UID::AutoCommit;
 175   local $FS::UID::AutoCommit = 0;
 176   my $dbh = dbh;
 177
 178   if ( $new->svcpart != $old->svcpart ) {
 179     my $svc_x = $new->svc_x;
 180     my $new_svc_x = ref($svc_x)->new({$svc_x->hash, svcpart=>$new->svcpart });
 181     local($FS::Record::nowarn_identical) = 1;
 182     my $error = $new_svc_x->replace($svc_x);
 183     if ( $error ) {
 184       $dbh->rollback if $oldAutoCommit;
 185       return $error if $error;
 186     }
 187   }
 188
 189   my $error = $new->SUPER::replace($old);
 190   if ( $error ) {
 191     $dbh->rollback if $oldAutoCommit;
 192     return $error if $error;
 193   }
 194
 195   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 196   ''; #no error
 197
 198 }
 199
 200 =item check
 201
 202 Checks all fields to make sure this is a valid service.  If there is an error,
 203 returns the error, otehrwise returns false.  Called by the insert and
 204 replace methods.
 205
 206 =cut
 207
 208 sub check {
 209   my $self = shift;
 210
 211   my $error =
 212     $self->ut_numbern('svcnum')
 213     || $self->ut_numbern('pkgnum')
 214     || $self->ut_number('svcpart')
 215   ;
 216   return $error if $error;
 217
 218   my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 219   return "Unknown svcpart" unless $part_svc;
 220
 221   if ( $self->pkgnum ) {
 222     my $cust_pkg = qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 223     return "Unknown pkgnum" unless $cust_pkg;
 224     my $pkg_svc = qsearchs( 'pkg_svc', {
 225       'pkgpart' => $cust_pkg->pkgpart,
 226       'svcpart' => $self->svcpart,
 227     });
 228     # or new FS::pkg_svc ( { 'pkgpart'  => $cust_pkg->pkgpart,
 229     #                        'svcpart'  => $self->svcpart,
 230     #                        'quantity' => 0                   } );
 231     my $quantity = $pkg_svc ? $pkg_svc->quantity : 0;
 232
 233     my @cust_svc = qsearch('cust_svc', {
 234       'pkgnum'  => $self->pkgnum,
 235       'svcpart' => $self->svcpart,
 236     });
 237     return "Already ". scalar(@cust_svc). " ". $part_svc->svc.
 238            " services for pkgnum ". $self->pkgnum
 239       if scalar(@cust_svc) >= $quantity && !$ignore_quantity;
 240   }
 241
 242   $self->SUPER::check;
 243 }
 244
 245 =item part_svc
 246
 247 Returns the definition for this service, as a FS::part_svc object (see
 248 L<FS::part_svc>).
 249
 250 =cut
 251
 252 sub part_svc {
 253   my $self = shift;
 254   $self->{'_svcpart'}
 255     ? $self->{'_svcpart'}
 256     : qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 257 }
 258
 259 =item cust_pkg
 260
 261 Returns the package this service belongs to, as a FS::cust_pkg object (see
 262 L<FS::cust_pkg>).
 263
 264 =cut
 265
 266 sub cust_pkg {
 267   my $self = shift;
 268   qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 269 }
 270
 271 =item label
 272
 273 Returns a list consisting of:
 274 - The name of this service (from part_svc)
 275 - A meaningful identifier (username, domain, or mail alias)
 276 - The table name (i.e. svc_domain) for this service
 277 - svcnum
 278
 279 =cut
 280
 281 sub label {
 282   my $self = shift;
 283   carp "FS::cust_svc::label called on $self" if $DEBUG;
 284   my $svc_x = $self->svc_x
 285     or die "can't find ". $self->part_svc->svcdb. '.svcnum '. $self->svcnum;
 286   $self->_svc_label($svc_x);
 287 }
 288
 289 sub _svc_label {
 290   my( $self, $svc_x ) = ( shift, shift );
 291   my $svcdb = $self->part_svc->svcdb;
 292
 293   my $tag;
 294   if ( $svcdb eq 'svc_acct' ) {
 295     $tag = $svc_x->email(@_);
 296   } elsif ( $svcdb eq 'svc_forward' ) {
 297     if ( $svc_x->srcsvc ) {
 298       my $svc_acct = $svc_x->srcsvc_acct(@_);
 299       $tag = $svc_acct->email(@_);
 300     } else {
 301       $tag = $svc_x->src;
 302     }
 303     $tag .= '->';
 304     if ( $svc_x->dstsvc ) {
 305       my $svc_acct = $svc_x->dstsvc_acct(@_);
 306       $tag .= $svc_acct->email(@_);
 307     } else {
 308       $tag .= $svc_x->dst;
 309     }
 310   } elsif ( $svcdb eq 'svc_domain' ) {
 311     $tag = $svc_x->getfield('domain');
 312   } elsif ( $svcdb eq 'svc_www' ) {
 313     my $domain_record = $svc_x->domain_record(@_);
 314     $tag = $domain_record->zone;
 315   } elsif ( $svcdb eq 'svc_broadband' ) {
 316     $tag = $svc_x->ip_addr;
 317   } elsif ( $svcdb eq 'svc_external' ) {
 318     my $conf = new FS::Conf;
 319     if ( $conf->config('svc_external-display_type') eq 'artera_turbo' ) {
 320       $tag = sprintf('%010d', $svc_x->id). '-'.
 321              substr('0000000000'.uc($svc_x->title), -10);
 322     } else {
 323       $tag = $svc_x->id. ': '. $svc_x->title;
 324     }
 325   } else {
 326     cluck "warning: asked for label of unsupported svcdb; using svcnum";
 327     $tag = $svc_x->getfield('svcnum');
 328   }
 329
 330   $self->part_svc->svc, $tag, $svcdb, $self->svcnum;
 331
 332 }
 333
 334 =item svc_x
 335
 336 Returns the FS::svc_XXX object for this service (i.e. an FS::svc_acct object or
 337 FS::svc_domain object, etc.)
 338
 339 =cut
 340
 341 sub svc_x {
 342   my $self = shift;
 343   my $svcdb = $self->part_svc->svcdb;
 344   if ( $svcdb eq 'svc_acct' && $self->{'_svc_acct'} ) {
 345     $self->{'_svc_acct'};
 346   } else {
 347     #require "FS/$svcdb.pm";
 348     qsearchs( $svcdb, { 'svcnum' => $self->svcnum } );
 349   }
 350 }
 351
 352 =item seconds_since TIMESTAMP
 353
 354 See L<FS::svc_acct/seconds_since>.  Equivalent to
 355 $cust_svc->svc_x->seconds_since, but more efficient.  Meaningless for records
 356 where B<svcdb> is not "svc_acct".
 357
 358 =cut
 359
 360 #note: implementation here, POD in FS::svc_acct
 361 sub seconds_since {
 362   my($self, $since) = @_;
 363   my $dbh = dbh;
 364   my $sth = $dbh->prepare(' SELECT SUM(logout-login) FROM session
 365                               WHERE svcnum = ?
 366                                 AND login >= ?
 367                                 AND logout IS NOT NULL'
 368   ) or die $dbh->errstr;
 369   $sth->execute($self->svcnum, $since) or die $sth->errstr;
 370   $sth->fetchrow_arrayref->[0];
 371 }
 372
 373 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
 374
 375 See L<FS::svc_acct/seconds_since_sqlradacct>.  Equivalent to
 376 $cust_svc->svc_x->seconds_since_sqlradacct, but more efficient.  Meaningless
 377 for records where B<svcdb> is not "svc_acct".
 378
 379 =cut
 380
 381 #note: implementation here, POD in FS::svc_acct
 382 sub seconds_since_sqlradacct {
 383   my($self, $start, $end) = @_;
 384
 385   my $svc_x = $self->svc_x;
 386
 387   my @part_export = $self->part_svc->part_export('sqlradius');
 388   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 389   die "no sqlradius or sqlradius_withdomain export configured for this".
 390       "service type"
 391     unless @part_export;
 392     #or return undef;
 393
 394   my $seconds = 0;
 395   foreach my $part_export ( @part_export ) {
 396
 397     next if $part_export->option('ignore_accounting');
 398
 399     my $dbh = DBI->connect( map { $part_export->option($_) }
 400                             qw(datasrc username password)    )
 401       or die "can't connect to sqlradius database: ". $DBI::errstr;
 402
 403     #select a unix time conversion function based on database type
 404     my $str2time;
 405     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 406       $str2time = 'UNIX_TIMESTAMP(';
 407     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 408       $str2time = 'EXTRACT( EPOCH FROM ';
 409     } else {
 410       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 411            "; guessing how to convert to UNIX timestamps";
 412       $str2time = 'extract(epoch from ';
 413     }
 414
 415     my $username;
 416     if ( $part_export->exporttype eq 'sqlradius' ) {
 417       $username = $svc_x->username;
 418     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 419       $username = $svc_x->email;
 420     } else {
 421       die 'unknown exporttype '. $part_export->exporttype;
 422     }
 423
 424     my $query;
 425
 426     #find closed sessions completely within the given range
 427     my $sth = $dbh->prepare("SELECT SUM(acctsessiontime)
 428                                FROM radacct
 429                                WHERE UserName = ?
 430                                  AND $str2time AcctStartTime) >= ?
 431                                  AND $str2time AcctStopTime ) <  ?
 432                                  AND $str2time AcctStopTime ) > 0
 433                                  AND AcctStopTime IS NOT NULL"
 434     ) or die $dbh->errstr;
 435     $sth->execute($username, $start, $end) or die $sth->errstr;
 436     my $regular = $sth->fetchrow_arrayref->[0];
 437
 438     #find open sessions which start in the range, count session start->range end
 439     $query = "SELECT SUM( ? - $str2time AcctStartTime ) )
 440                 FROM radacct
 441                 WHERE UserName = ?
 442                   AND $str2time AcctStartTime ) >= ?
 443                   AND $str2time AcctStartTime ) <  ?
 444                   AND ( ? - $str2time AcctStartTime ) ) < 86400
 445                   AND (    $str2time AcctStopTime ) = 0
 446                                     OR AcctStopTime IS NULL )";
 447     $sth = $dbh->prepare($query) or die $dbh->errstr;
 448     $sth->execute($end, $username, $start, $end, $end)
 449       or die $sth->errstr. " executing query $query";
 450     my $start_during = $sth->fetchrow_arrayref->[0];
 451
 452     #find closed sessions which start before the range but stop during,
 453     #count range start->session end
 454     $sth = $dbh->prepare("SELECT SUM( $str2time AcctStopTime ) - ? )
 455                             FROM radacct
 456                             WHERE UserName = ?
 457                               AND $str2time AcctStartTime ) < ?
 458                               AND $str2time AcctStopTime  ) >= ?
 459                               AND $str2time AcctStopTime  ) <  ?
 460                               AND $str2time AcctStopTime ) > 0
 461                               AND AcctStopTime IS NOT NULL"
 462     ) or die $dbh->errstr;
 463     $sth->execute($start, $username, $start, $start, $end ) or die $sth->errstr;
 464     my $end_during = $sth->fetchrow_arrayref->[0];
 465
 466     #find closed (not anymore - or open) sessions which start before the range
 467     # but stop after, or are still open, count range start->range end
 468     # don't count open sessions (probably missing stop record)
 469     $sth = $dbh->prepare("SELECT COUNT(*)
 470                             FROM radacct
 471                             WHERE UserName = ?
 472                               AND $str2time AcctStartTime ) < ?
 473                               AND ( $str2time AcctStopTime ) >= ?
 474                                                                   )"
 475                               #      OR AcctStopTime =  0
 476                               #      OR AcctStopTime IS NULL       )"
 477     ) or die $dbh->errstr;
 478     $sth->execute($username, $start, $end ) or die $sth->errstr;
 479     my $entire_range = ($end-$start) * $sth->fetchrow_arrayref->[0];
 480
 481     $seconds += $regular + $end_during + $start_during + $entire_range;
 482
 483   }
 484
 485   $seconds;
 486
 487 }
 488
 489 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
 490
 491 See L<FS::svc_acct/attribute_since_sqlradacct>.  Equivalent to
 492 $cust_svc->svc_x->attribute_since_sqlradacct, but more efficient.  Meaningless
 493 for records where B<svcdb> is not "svc_acct".
 494
 495 =cut
 496
 497 #note: implementation here, POD in FS::svc_acct
 498 #(false laziness w/seconds_since_sqlradacct above)
 499 sub attribute_since_sqlradacct {
 500   my($self, $start, $end, $attrib) = @_;
 501
 502   my $svc_x = $self->svc_x;
 503
 504   my @part_export = $self->part_svc->part_export('sqlradius');
 505   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 506   die "no sqlradius or sqlradius_withdomain export configured for this".
 507       "service type"
 508     unless @part_export;
 509     #or return undef;
 510
 511   my $sum = 0;
 512
 513   foreach my $part_export ( @part_export ) {
 514
 515     next if $part_export->option('ignore_accounting');
 516
 517     my $dbh = DBI->connect( map { $part_export->option($_) }
 518                             qw(datasrc username password)    )
 519       or die "can't connect to sqlradius database: ". $DBI::errstr;
 520
 521     #select a unix time conversion function based on database type
 522     my $str2time;
 523     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 524       $str2time = 'UNIX_TIMESTAMP(';
 525     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 526       $str2time = 'EXTRACT( EPOCH FROM ';
 527     } else {
 528       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 529            "; guessing how to convert to UNIX timestamps";
 530       $str2time = 'extract(epoch from ';
 531     }
 532
 533     my $username;
 534     if ( $part_export->exporttype eq 'sqlradius' ) {
 535       $username = $svc_x->username;
 536     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 537       $username = $svc_x->email;
 538     } else {
 539       die 'unknown exporttype '. $part_export->exporttype;
 540     }
 541
 542     my $sth = $dbh->prepare("SELECT SUM($attrib)
 543                                FROM radacct
 544                                WHERE UserName = ?
 545                                  AND $str2time AcctStopTime ) >= ?
 546                                  AND $str2time AcctStopTime ) <  ?
 547                                  AND AcctStopTime IS NOT NULL"
 548     ) or die $dbh->errstr;
 549     $sth->execute($username, $start, $end) or die $sth->errstr;
 550
 551     $sum += $sth->fetchrow_arrayref->[0];
 552
 553   }
 554
 555   $sum;
 556
 557 }
 558
 559 =item get_session_history TIMESTAMP_START TIMESTAMP_END
 560
 561 See L<FS::svc_acct/get_session_history>.  Equivalent to
 562 $cust_svc->svc_x->get_session_history, but more efficient.  Meaningless for
 563 records where B<svcdb> is not "svc_acct".
 564
 565 =cut
 566
 567 sub get_session_history {
 568   my($self, $start, $end, $attrib) = @_;
 569
 570   #$attrib ???
 571
 572   #my @part_export = $cust_svc->part_svc->part_export->can('usage_sessions');
 573   my @part_export = $self->part_svc->part_export('sqlradius');
 574   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 575   die "no sqlradius or sqlradius_withdomain export configured for this".
 576       "service type"
 577     unless @part_export;
 578     #or return undef;
 579
 580   my @sessions = ();
 581
 582   foreach my $part_export ( @part_export ) {
 583     push @sessions,
 584       @{ $part_export->usage_sessions( $start, $end, $self->svc_x ) };
 585   }
 586
 587   @sessions;
 588
 589 }
 590
 591 =item pkg_svc
 592
 593 Returns the pkg_svc record for for this service, if applicable.
 594
 595 =cut
 596
 597 sub pkg_svc {
 598   my $self = shift;
 599   my $cust_pkg = $self->cust_pkg;
 600   return undef unless $cust_pkg;
 601
 602   qsearchs( 'pkg_svc', { 'svcpart' => $self->svcpart,
 603                          'pkgpart' => $cust_pkg->pkgpart,
 604                        }
 605           );
 606 }
 607
 608 =back
 609
 610 =head1 BUGS
 611
 612 Behaviour of changing the svcpart of cust_svc records is undefined and should
 613 possibly be prohibited, and pkg_svc records are not checked.
 614
 615 pkg_svc records are not checked in general (here).
 616
 617 Deleting this record doesn't check or delete the svc_* record associated
 618 with this record.
 619
 620 In seconds_since_sqlradacct, specifying a DATASRC/USERNAME/PASSWORD instead of
 621 a DBI database handle is not yet implemented.
 622
 623 =head1 SEE ALSO
 624
 625 L<FS::Record>, L<FS::cust_pkg>, L<FS::part_svc>, L<FS::pkg_svc>,
 626 schema.html from the base documentation
 627
 628 =cut
 629
 630 1;
 631