FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::cust_pkg::Search FS::cust_pkg::API
   3              FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   4              FS::contact_Mixin FS::location_Mixin
   5              FS::m2m_Common FS::option_Common
   6            );
   7
   8 use strict;
   9 use Carp qw(cluck);
  10 use Scalar::Util qw( blessed );
  11 use List::Util qw(min max);
  12 use Tie::IxHash;
  13 use Time::Local qw( timelocal timelocal_nocheck );
  14 use MIME::Entity;
  15 use FS::UID qw( dbh driver_name );
  16 use FS::Misc qw( send_email );
  17 use FS::Record qw( qsearch qsearchs fields );
  18 use FS::CurrentUser;
  19 use FS::cust_svc;
  20 use FS::part_pkg;
  21 use FS::cust_main;
  22 use FS::contact;
  23 use FS::cust_location;
  24 use FS::pkg_svc;
  25 use FS::cust_bill_pkg;
  26 use FS::cust_pkg_detail;
  27 use FS::cust_pkg_usage;
  28 use FS::cdr_cust_pkg_usage;
  29 use FS::cust_event;
  30 use FS::h_cust_svc;
  31 use FS::reg_code;
  32 use FS::part_svc;
  33 use FS::cust_pkg_reason;
  34 use FS::reason;
  35 use FS::cust_pkg_usageprice;
  36 use FS::cust_pkg_discount;
  37 use FS::discount;
  38 use FS::sales;
  39 # for modify_charge
  40 use FS::cust_credit;
  41
  42 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  43 # setup }
  44 # because they load configuration by setting FS::UID::callback (see TODO)
  45 use FS::svc_acct;
  46 use FS::svc_domain;
  47 use FS::svc_www;
  48 use FS::svc_forward;
  49
  50 # for sending cancel emails in sub cancel
  51 use FS::Conf;
  52
  53 our ($disable_agentcheck, $DEBUG, $me, $import) = (0, 0, '[FS::cust_pkg]', 0);
  54
  55 our $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  56
  57 sub _cache {
  58   my $self = shift;
  59   my ( $hashref, $cache ) = @_;
  60   #if ( $hashref->{'pkgpart'} ) {
  61   if ( $hashref->{'pkg'} ) {
  62     # #@{ $self->{'_pkgnum'} } = ();
  63     # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  64     # $self->{'_pkgpart'} = $subcache;
  65     # #push @{ $self->{'_pkgnum'} },
  66     #   FS::part_pkg->new_or_cached($hashref, $subcache);
  67     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  68   }
  69   if ( exists $hashref->{'svcnum'} ) {
  70     #@{ $self->{'_pkgnum'} } = ();
  71     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  72     $self->{'_svcnum'} = $subcache;
  73     #push @{ $self->{'_pkgnum'} },
  74     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  75   }
  76 }
  77
  78 =head1 NAME
  79
  80 FS::cust_pkg - Object methods for cust_pkg objects
  81
  82 =head1 SYNOPSIS
  83
  84   use FS::cust_pkg;
  85
  86   $record = new FS::cust_pkg \%hash;
  87   $record = new FS::cust_pkg { 'column' => 'value' };
  88
  89   $error = $record->insert;
  90
  91   $error = $new_record->replace($old_record);
  92
  93   $error = $record->delete;
  94
  95   $error = $record->check;
  96
  97   $error = $record->cancel;
  98
  99   $error = $record->suspend;
 100
 101   $error = $record->unsuspend;
 102
 103   $part_pkg = $record->part_pkg;
 104
 105   @labels = $record->labels;
 106
 107   $seconds = $record->seconds_since($timestamp);
 108
 109   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 110   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 111   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 112   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 113
 114 =head1 DESCRIPTION
 115
 116 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 117 inherits from FS::Record.  The following fields are currently supported:
 118
 119 =over 4
 120
 121 =item pkgnum
 122
 123 Primary key (assigned automatically for new billing items)
 124
 125 =item custnum
 126
 127 Customer (see L<FS::cust_main>)
 128
 129 =item pkgpart
 130
 131 Billing item definition (see L<FS::part_pkg>)
 132
 133 =item locationnum
 134
 135 Optional link to package location (see L<FS::location>)
 136
 137 =item order_date
 138
 139 date package was ordered (also remains same on changes)
 140
 141 =item start_date
 142
 143 date
 144
 145 =item setup
 146
 147 date
 148
 149 =item bill
 150
 151 date (next bill date)
 152
 153 =item last_bill
 154
 155 last bill date
 156
 157 =item adjourn
 158
 159 date
 160
 161 =item susp
 162
 163 date
 164
 165 =item expire
 166
 167 date
 168
 169 =item contract_end
 170
 171 date
 172
 173 =item cancel
 174
 175 date
 176
 177 =item usernum
 178
 179 order taker (see L<FS::access_user>)
 180
 181 =item manual_flag
 182
 183 If this field is set to 1, disables the automatic
 184 unsuspension of this package when using the B<unsuspendauto> config option.
 185
 186 =item quantity
 187
 188 If not set, defaults to 1
 189
 190 =item change_date
 191
 192 Date of change from previous package
 193
 194 =item change_pkgnum
 195
 196 Previous pkgnum
 197
 198 =item change_pkgpart
 199
 200 Previous pkgpart
 201
 202 =item change_locationnum
 203
 204 Previous locationnum
 205
 206 =item waive_setup
 207
 208 =item main_pkgnum
 209
 210 The pkgnum of the package that this package is supplemental to, if any.
 211
 212 =item pkglinknum
 213
 214 The package link (L<FS::part_pkg_link>) that defines this supplemental
 215 package, if it is one.
 216
 217 =item change_to_pkgnum
 218
 219 The pkgnum of the package this one will be "changed to" in the future
 220 (on its expiration date).
 221
 222 =back
 223
 224 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 225 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 226 L<Time::Local> and L<Date::Parse> for conversion functions.
 227
 228 =head1 METHODS
 229
 230 =over 4
 231
 232 =item new HASHREF
 233
 234 Create a new billing item.  To add the item to the database, see L<"insert">.
 235
 236 =cut
 237
 238 sub table { 'cust_pkg'; }
 239 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 240 sub cust_unlinked_msg {
 241   my $self = shift;
 242   "WARNING: can't find cust_main.custnum ". $self->custnum.
 243   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 244 }
 245
 246 =item set_initial_timers
 247
 248 If required by the package definition, sets any automatic expire, adjourn,
 249 or contract_end timers to some number of months after the start date
 250 (or setup date, if the package has already been setup). If the package has
 251 a delayed setup fee after a period of "free days", will also set the
 252 start date to the end of that period.
 253
 254 =cut
 255
 256 sub set_initial_timers {
 257   my $self = shift;
 258   my $part_pkg = $self->part_pkg;
 259   foreach my $action ( qw(expire adjourn contract_end) ) {
 260     my $months = $part_pkg->option("${action}_months",1);
 261     if($months and !$self->get($action)) {
 262       my $start = $self->start_date || $self->setup || time;
 263       $self->set($action, $part_pkg->add_freq($start, $months) );
 264     }
 265   }
 266
 267   # if this package has "free days" and delayed setup fee, then
 268   # set start date that many days in the future.
 269   # (this should have been set in the UI, but enforce it here)
 270   if ( $part_pkg->option('free_days',1)
 271        && $part_pkg->option('delay_setup',1)
 272      )
 273   {
 274     $self->start_date( $part_pkg->default_start_date );
 275   }
 276   '';
 277 }
 278
 279 =item insert [ OPTION => VALUE ... ]
 280
 281 Adds this billing item to the database ("Orders" the item).  If there is an
 282 error, returns the error, otherwise returns false.
 283
 284 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 285 will be used to look up the package definition and agent restrictions will be
 286 ignored.
 287
 288 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 289 be created and inserted.  Multiple FS::pkg_referral records can be created by
 290 setting I<refnum> to an array reference of refnums or a hash reference with
 291 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 292 record will be created corresponding to cust_main.refnum.
 293
 294 If the additional field I<cust_pkg_usageprice> is defined, it will be treated
 295 as an arrayref of FS::cust_pkg_usageprice objects, which will be inserted.
 296 (Note that this field cannot be set with a usual ->cust_pkg_usageprice method.
 297 It can be set as part of the hash when creating the object, or with the B<set>
 298 method.)
 299
 300 The following options are available:
 301
 302 =over 4
 303
 304 =item change
 305
 306 If set true, supresses actions that should only be taken for new package
 307 orders.  (Currently this includes: intro periods when delay_setup is on,
 308 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 309
 310 =item options
 311
 312 cust_pkg_option records will be created
 313
 314 =item ticket_subject
 315
 316 a ticket will be added to this customer with this subject
 317
 318 =item ticket_queue
 319
 320 an optional queue name for ticket additions
 321
 322 =item allow_pkgpart
 323
 324 Don't check the legality of the package definition.  This should be used
 325 when performing a package change that doesn't change the pkgpart (i.e.
 326 a location change).
 327
 328 =back
 329
 330 =cut
 331
 332 sub insert {
 333   my( $self, %options ) = @_;
 334
 335   my $error;
 336   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 337   return $error if $error;
 338
 339   my $part_pkg = $self->part_pkg;
 340
 341   if ( ! $import && ! $options{'change'} ) {
 342
 343     # set order date to now
 344     $self->order_date(time) unless ($import && $self->order_date);
 345
 346     # if the package def says to start only on the first of the month:
 347     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 348       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 349       $mon += 1 unless $mday == 1;
 350       until ( $mon < 12 ) { $mon -= 12; $year++; }
 351       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 352     }
 353
 354     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 355       # if the package was ordered on hold:
 356       # - suspend it
 357       # - don't set the start date (it will be started manually)
 358       $self->set('susp', $self->order_date);
 359       $self->set('start_date', '');
 360     } else {
 361       # set expire/adjourn/contract_end timers, and free days, if appropriate
 362       $self->set_initial_timers;
 363     }
 364   } # else this is a package change, and shouldn't have "new package" behavior
 365
 366   my $oldAutoCommit = $FS::UID::AutoCommit;
 367   local $FS::UID::AutoCommit = 0;
 368   my $dbh = dbh;
 369
 370   $error = $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 371   if ( $error ) {
 372     $dbh->rollback if $oldAutoCommit;
 373     return $error;
 374   }
 375
 376   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 377   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 378   $self->process_m2m( 'link_table'   => 'pkg_referral',
 379                       'target_table' => 'part_referral',
 380                       'params'       => $self->refnum,
 381                     );
 382
 383   if ( $self->hashref->{cust_pkg_usageprice} ) {
 384     for my $cust_pkg_usageprice ( @{ $self->hashref->{cust_pkg_usageprice} } ) {
 385       $cust_pkg_usageprice->pkgnum( $self->pkgnum );
 386       my $error = $cust_pkg_usageprice->insert;
 387       if ( $error ) {
 388         $dbh->rollback if $oldAutoCommit;
 389         return $error;
 390       }
 391     }
 392   }
 393
 394   if ( $self->discountnum ) {
 395     my $error = $self->insert_discount();
 396     if ( $error ) {
 397       $dbh->rollback if $oldAutoCommit;
 398       return $error;
 399     }
 400   }
 401
 402   my $conf = new FS::Conf;
 403
 404   if ( ! $import && $conf->config('ticket_system') && $options{ticket_subject} ) {
 405
 406     #this init stuff is still inefficient, but at least its limited to
 407     # the small number (any?) folks using ticket emailing on pkg order
 408
 409     #eval '
 410     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 411     #  use RT;
 412     #';
 413     #die $@ if $@;
 414     #
 415     #RT::LoadConfig();
 416     #RT::Init();
 417     use FS::TicketSystem;
 418     FS::TicketSystem->init();
 419
 420     my $q = new RT::Queue($RT::SystemUser);
 421     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 422     my $t = new RT::Ticket($RT::SystemUser);
 423     my $mime = new MIME::Entity;
 424     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 425     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 426                 Subject => $options{ticket_subject},
 427                 MIMEObj => $mime,
 428               );
 429     $t->AddLink( Type   => 'MemberOf',
 430                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 431                );
 432   }
 433
 434   if (! $import && $conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 435     my $queue = new FS::queue {
 436       'job'     => 'FS::cust_main::queueable_print',
 437     };
 438     $error = $queue->insert(
 439       'custnum'  => $self->custnum,
 440       'template' => 'welcome_letter',
 441     );
 442
 443     if ($error) {
 444       warn "can't send welcome letter: $error";
 445     }
 446
 447   }
 448
 449   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 450   '';
 451
 452 }
 453
 454 =item delete
 455
 456 This method now works but you probably shouldn't use it.
 457
 458 You don't want to delete packages, because there would then be no record
 459 the customer ever purchased the package.  Instead, see the cancel method and
 460 hide cancelled packages.
 461
 462 =cut
 463
 464 sub delete {
 465   my $self = shift;
 466
 467   my $oldAutoCommit = $FS::UID::AutoCommit;
 468   local $FS::UID::AutoCommit = 0;
 469   my $dbh = dbh;
 470
 471   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 472     my $error = $cust_pkg_discount->delete;
 473     if ( $error ) {
 474       $dbh->rollback if $oldAutoCommit;
 475       return $error;
 476     }
 477   }
 478   #cust_bill_pkg_discount?
 479
 480   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 481     my $error = $cust_pkg_detail->delete;
 482     if ( $error ) {
 483       $dbh->rollback if $oldAutoCommit;
 484       return $error;
 485     }
 486   }
 487
 488   foreach my $cust_pkg_reason (
 489     qsearchs( {
 490                 'table' => 'cust_pkg_reason',
 491                 'hashref' => { 'pkgnum' => $self->pkgnum },
 492               }
 493             )
 494   ) {
 495     my $error = $cust_pkg_reason->delete;
 496     if ( $error ) {
 497       $dbh->rollback if $oldAutoCommit;
 498       return $error;
 499     }
 500   }
 501
 502   #pkg_referral?
 503
 504   my $error = $self->SUPER::delete(@_);
 505   if ( $error ) {
 506     $dbh->rollback if $oldAutoCommit;
 507     return $error;
 508   }
 509
 510   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 511
 512   '';
 513
 514 }
 515
 516 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 517
 518 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 519 returns the error, otherwise returns false.
 520
 521 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 522
 523 Changing pkgpart may have disasterous effects.  See the order subroutine.
 524
 525 setup and bill are normally updated by calling the bill method of a customer
 526 object (see L<FS::cust_main>).
 527
 528 suspend is normally updated by the suspend and unsuspend methods.
 529
 530 cancel is normally updated by the cancel method (and also the order subroutine
 531 in some cases).
 532
 533 Available options are:
 534
 535 =over 4
 536
 537 =item reason
 538
 539 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 540
 541 =item reason_otaker
 542
 543 the access_user (see L<FS::access_user>) providing the reason
 544
 545 =item options
 546
 547 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 548
 549 =back
 550
 551 =cut
 552
 553 sub replace {
 554   my $new = shift;
 555
 556   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 557               ? shift
 558               : $new->replace_old;
 559
 560   my $options =
 561     ( ref($_[0]) eq 'HASH' )
 562       ? shift
 563       : { @_ };
 564
 565   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 566   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 567
 568   #allow this *sigh*
 569   #return "Can't change setup once it exists!"
 570   #  if $old->getfield('setup') &&
 571   #     $old->getfield('setup') != $new->getfield('setup');
 572
 573   #some logic for bill, susp, cancel?
 574
 575   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 576
 577   my $oldAutoCommit = $FS::UID::AutoCommit;
 578   local $FS::UID::AutoCommit = 0;
 579   my $dbh = dbh;
 580
 581   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 582     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 583       my $error = $new->insert_reason(
 584         'reason'        => $options->{'reason'},
 585         'date'          => $new->$method,
 586         'action'        => $method,
 587         'reason_otaker' => $options->{'reason_otaker'},
 588       );
 589       if ( $error ) {
 590         dbh->rollback if $oldAutoCommit;
 591         return "Error inserting cust_pkg_reason: $error";
 592       }
 593     }
 594   }
 595
 596   #save off and freeze RADIUS attributes for any associated svc_acct records
 597   my @svc_acct = ();
 598   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 599
 600                 #also check for specific exports?
 601                 # to avoid spurious modify export events
 602     @svc_acct = map  { $_->svc_x }
 603                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 604                      $old->cust_svc;
 605
 606     $_->snapshot foreach @svc_acct;
 607
 608   }
 609
 610   my $error =  $new->export_pkg_change($old)
 611             || $new->SUPER::replace( $old,
 612                                      $options->{options}
 613                                        ? $options->{options}
 614                                        : ()
 615                                    );
 616   if ( $error ) {
 617     $dbh->rollback if $oldAutoCommit;
 618     return $error;
 619   }
 620
 621   #for prepaid packages,
 622   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 623   foreach my $old_svc_acct ( @svc_acct ) {
 624     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 625     my $s_error =
 626       $new_svc_acct->replace( $old_svc_acct,
 627                               'depend_jobnum' => $options->{depend_jobnum},
 628                             );
 629     if ( $s_error ) {
 630       $dbh->rollback if $oldAutoCommit;
 631       return $s_error;
 632     }
 633   }
 634
 635   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 636   '';
 637
 638 }
 639
 640 =item check
 641
 642 Checks all fields to make sure this is a valid billing item.  If there is an
 643 error, returns the error, otherwise returns false.  Called by the insert and
 644 replace methods.
 645
 646 =cut
 647
 648 sub check {
 649   my $self = shift;
 650
 651   if ( !$self->locationnum or $self->locationnum == -1 ) {
 652     $self->set('locationnum', $self->cust_main->ship_locationnum);
 653   }
 654
 655   my $error =
 656     $self->ut_numbern('pkgnum')
 657     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 658     || $self->ut_numbern('pkgpart')
 659     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 660     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 661     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 662     || $self->ut_numbern('quantity')
 663     || $self->ut_numbern('start_date')
 664     || $self->ut_numbern('setup')
 665     || $self->ut_numbern('bill')
 666     || $self->ut_numbern('susp')
 667     || $self->ut_numbern('cancel')
 668     || $self->ut_numbern('adjourn')
 669     || $self->ut_numbern('resume')
 670     || $self->ut_numbern('expire')
 671     || $self->ut_numbern('dundate')
 672     || $self->ut_flag('no_auto', [ '', 'Y' ])
 673     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 674     || $self->ut_flag('separate_bill')
 675     || $self->ut_textn('agent_pkgid')
 676     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 677     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 678     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 679     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 680     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 681   ;
 682   return $error if $error;
 683
 684   return "A package with both start date (future start) and setup date (already started) will never bill"
 685     if $self->start_date && $self->setup && ! $upgrade;
 686
 687   return "A future unsuspend date can only be set for a package with a suspend date"
 688     if $self->resume and !$self->susp and !$self->adjourn;
 689
 690   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 691
 692   if ( $self->dbdef_table->column('manual_flag') ) {
 693     $self->manual_flag('') if $self->manual_flag eq ' ';
 694     $self->manual_flag =~ /^([01]?)$/
 695       or return "Illegal manual_flag ". $self->manual_flag;
 696     $self->manual_flag($1);
 697   }
 698
 699   $self->SUPER::check;
 700 }
 701
 702 =item check_pkgpart
 703
 704 Check the pkgpart to make sure it's allowed with the reg_code and/or
 705 promo_code of the package (if present) and with the customer's agent.
 706 Called from C<insert>, unless we are doing a package change that doesn't
 707 affect pkgpart.
 708
 709 =cut
 710
 711 sub check_pkgpart {
 712   my $self = shift;
 713
 714   # my $error = $self->ut_numbern('pkgpart'); # already done
 715
 716   my $error;
 717   if ( $self->reg_code ) {
 718
 719     unless ( grep { $self->pkgpart == $_->pkgpart }
 720              map  { $_->reg_code_pkg }
 721              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 722                                      'agentnum' => $self->cust_main->agentnum })
 723            ) {
 724       return "Unknown registration code";
 725     }
 726
 727   } elsif ( $self->promo_code ) {
 728
 729     my $promo_part_pkg =
 730       qsearchs('part_pkg', {
 731         'pkgpart'    => $self->pkgpart,
 732         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 733       } );
 734     return 'Unknown promotional code' unless $promo_part_pkg;
 735
 736   } else {
 737
 738     unless ( $disable_agentcheck ) {
 739       my $agent =
 740         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 741       return "agent ". $agent->agentnum. ':'. $agent->agent.
 742              " can't purchase pkgpart ". $self->pkgpart
 743         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 744             || $agent->agentnum == $self->part_pkg->agentnum;
 745     }
 746
 747     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 748     return $error if $error;
 749
 750   }
 751
 752   '';
 753
 754 }
 755
 756 =item cancel [ OPTION => VALUE ... ]
 757
 758 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 759 in this package, then cancels the package itself (sets the cancel field to
 760 now).
 761
 762 Available options are:
 763
 764 =over 4
 765
 766 =item quiet - can be set true to supress email cancellation notices.
 767
 768 =item time -  can be set to cancel the package based on a specific future or
 769 historical date.  Using time ensures that the remaining amount is calculated
 770 correctly.  Note however that this is an immediate cancel and just changes
 771 the date.  You are PROBABLY looking to expire the account instead of using
 772 this.
 773
 774 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 775 either a reasonnum of an existing reason, or passing a hashref will create
 776 a new reason.  The hashref should have the following keys: typenum - Reason
 777 type (see L<FS::reason_type>, reason - Text of the new reason.
 778
 779 =item date - can be set to a unix style timestamp to specify when to
 780 cancel (expire)
 781
 782 =item nobill - can be set true to skip billing if it might otherwise be done.
 783
 784 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 785 not credit it.  This must be set (by change()) when changing the package
 786 to a different pkgpart or location, and probably shouldn't be in any other
 787 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 788 be used.
 789
 790 =item no_delay_cancel - prevents delay_cancel behavior
 791 no matter what other options say, for use when changing packages (or any
 792 other time you're really sure you want an immediate cancel)
 793
 794 =back
 795
 796 If there is an error, returns the error, otherwise returns false.
 797
 798 =cut
 799
 800 #NOT DOCUMENTING - this should only be used when calling recursively
 801 #=item delay_cancel - for internal use, to allow proper handling of
 802 #supplemental packages when the main package is flagged to suspend
 803 #before cancelling, probably shouldn't be used otherwise (set the
 804 #corresponding package option instead)
 805
 806 sub cancel {
 807   my( $self, %options ) = @_;
 808   my $error;
 809
 810   # pass all suspend/cancel actions to the main package
 811   # (unless the pkglinknum has been removed, then the link is defunct and
 812   # this package can be canceled on its own)
 813   if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 814     return $self->main_pkg->cancel(%options);
 815   }
 816
 817   my $conf = new FS::Conf;
 818
 819   warn "cust_pkg::cancel called with options".
 820        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 821     if $DEBUG;
 822
 823   my $oldAutoCommit = $FS::UID::AutoCommit;
 824   local $FS::UID::AutoCommit = 0;
 825   my $dbh = dbh;
 826
 827   my $old = $self->select_for_update;
 828
 829   if ( $old->get('cancel') || $self->get('cancel') ) {
 830     dbh->rollback if $oldAutoCommit;
 831     return "";  # no error
 832   }
 833
 834   # XXX possibly set cancel_time to the expire date?
 835   my $cancel_time = $options{'time'} || time;
 836   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 837   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 838
 839   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 840   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 841        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 842        && !$options{'no_delay_cancel'}
 843   ) {
 844     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 845     my $expsecs = 60*60*24*$expdays;
 846     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 847     $expsecs = $expsecs - $suspfor if $suspfor;
 848     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 849       $delay_cancel = 1;
 850       $date = $cancel_time + $expsecs;
 851     }
 852   }
 853
 854   #race condition: usage could be ongoing until unprovisioned
 855   #resolved by performing a change package instead (which unprovisions) and
 856   #later cancelling
 857   if ( !$options{nobill} && !$date ) {
 858     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 859       my $copy = $self->new({$self->hash});
 860       my $error =
 861         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 862                                 'cancel'   => 1,
 863                                 'time'     => $cancel_time );
 864       warn "Error billing during cancel, custnum ".
 865         #$self->cust_main->custnum. ": $error"
 866         ": $error"
 867         if $error;
 868   }
 869
 870   if ( $options{'reason'} ) {
 871     $error = $self->insert_reason( 'reason' => $options{'reason'},
 872                                    'action' => $date ? 'expire' : 'cancel',
 873                                    'date'   => $date ? $date : $cancel_time,
 874                                    'reason_otaker' => $options{'reason_otaker'},
 875                                  );
 876     if ( $error ) {
 877       dbh->rollback if $oldAutoCommit;
 878       return "Error inserting cust_pkg_reason: $error";
 879     }
 880   }
 881
 882   my %svc_cancel_opt = ();
 883   $svc_cancel_opt{'date'} = $date if $date;
 884   foreach my $cust_svc (
 885     #schwartz
 886     map  { $_->[0] }
 887     sort { $a->[1] <=> $b->[1] }
 888     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 889     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 890   ) {
 891     my $part_svc = $cust_svc->part_svc;
 892     next if ( defined($part_svc) and $part_svc->preserve );
 893     my $error = $cust_svc->cancel( %svc_cancel_opt );
 894
 895     if ( $error ) {
 896       $dbh->rollback if $oldAutoCommit;
 897       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 898              " cust_svc: $error";
 899     }
 900   }
 901
 902   unless ($date) {
 903     # credit remaining time if appropriate
 904     my $do_credit;
 905     if ( exists($options{'unused_credit'}) ) {
 906       $do_credit = $options{'unused_credit'};
 907     }
 908     else {
 909       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
 910     }
 911     if ( $do_credit ) {
 912       my $error = $self->credit_remaining('cancel', $cancel_time);
 913       if ($error) {
 914         $dbh->rollback if $oldAutoCommit;
 915         return $error;
 916       }
 917     }
 918   } #unless $date
 919
 920   my %hash = $self->hash;
 921   if ( $date ) {
 922     $hash{'expire'} = $date;
 923     if ($delay_cancel) {
 924       # just to be sure these are clear
 925       $hash{'adjourn'} = undef;
 926       $hash{'resume'} = undef;
 927     }
 928   } else {
 929     $hash{'cancel'} = $cancel_time;
 930   }
 931   $hash{'change_custnum'} = $options{'change_custnum'};
 932
 933   # if this is a supplemental package that's lost its part_pkg_link, and it's
 934   # being canceled for real, unlink it completely
 935   if ( !$date and ! $self->pkglinknum ) {
 936     $hash{main_pkgnum} = '';
 937   }
 938
 939   my $new = new FS::cust_pkg ( \%hash );
 940   $error = $new->replace( $self, options => { $self->options } );
 941   if ( $self->change_to_pkgnum ) {
 942     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
 943     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
 944   }
 945   if ( $error ) {
 946     $dbh->rollback if $oldAutoCommit;
 947     return $error;
 948   }
 949
 950   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
 951     $error = $supp_pkg->cancel(%options,
 952       'from_main' => 1,
 953       'date' => $date, #in case it got changed by delay_cancel
 954       'delay_cancel' => $delay_cancel,
 955     );
 956     if ( $error ) {
 957       $dbh->rollback if $oldAutoCommit;
 958       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
 959     }
 960   }
 961
 962   if ($delay_cancel && !$options{'from_main'}) {
 963     $error = $new->suspend(
 964       'from_cancel' => 1,
 965       'time'        => $cancel_time
 966     );
 967   }
 968
 969   unless ($date) {
 970     foreach my $usage ( $self->cust_pkg_usage ) {
 971       $error = $usage->delete;
 972       if ( $error ) {
 973         $dbh->rollback if $oldAutoCommit;
 974         return "deleting usage pools: $error";
 975       }
 976     }
 977   }
 978
 979   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 980   return '' if $date; #no errors
 981
 982   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
 983   if ( !$options{'quiet'} &&
 984         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
 985         @invoicing_list ) {
 986     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
 987     my $error = '';
 988     if ( $msgnum ) {
 989       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
 990       $error = $msg_template->send( 'cust_main' => $self->cust_main,
 991                                     'object'    => $self );
 992     }
 993     else {
 994       $error = send_email(
 995         'from'    => $conf->invoice_from_full( $self->cust_main->agentnum ),
 996         'to'      => \@invoicing_list,
 997         'subject' => ( $conf->config('cancelsubject') || 'Cancellation Notice' ),
 998         'body'    => [ map "$_\n", $conf->config('cancelmessage') ],
 999         'custnum' => $self->custnum,
1000         'msgtype' => '', #admin?
1001       );
1002     }
1003     #should this do something on errors?
1004   }
1005
1006   ''; #no errors
1007
1008 }
1009
1010 =item cancel_if_expired [ NOW_TIMESTAMP ]
1011
1012 Cancels this package if its expire date has been reached.
1013
1014 =cut
1015
1016 sub cancel_if_expired {
1017   my $self = shift;
1018   my $time = shift || time;
1019   return '' unless $self->expire && $self->expire <= $time;
1020   my $error = $self->cancel;
1021   if ( $error ) {
1022     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1023            $self->custnum. ": $error";
1024   }
1025   '';
1026 }
1027
1028 =item uncancel
1029
1030 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1031 locationnum, (other fields?).  Attempts to re-provision cancelled services
1032 using history information (errors at this stage are not fatal).
1033
1034 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1035
1036 svc_fatal: service provisioning errors are fatal
1037
1038 svc_errors: pass an array reference, will be filled in with any provisioning errors
1039
1040 main_pkgnum: link the package as a supplemental package of this one.  For
1041 internal use only.
1042
1043 =cut
1044
1045 sub uncancel {
1046   my( $self, %options ) = @_;
1047
1048   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1049   return '' unless $self->get('cancel');
1050
1051   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1052     return $self->main_pkg->uncancel(%options);
1053   }
1054
1055   ##
1056   # Transaction-alize
1057   ##
1058
1059   my $oldAutoCommit = $FS::UID::AutoCommit;
1060   local $FS::UID::AutoCommit = 0;
1061   my $dbh = dbh;
1062
1063   ##
1064   # insert the new package
1065   ##
1066
1067   my $cust_pkg = new FS::cust_pkg {
1068     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1069     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1070     uncancel        => time,
1071     uncancel_pkgnum => $self->pkgnum,
1072     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1073     map { $_ => $self->get($_) } qw(
1074       custnum pkgpart locationnum
1075       setup
1076       susp adjourn resume expire start_date contract_end dundate
1077       change_date change_pkgpart change_locationnum
1078       manual_flag no_auto separate_bill quantity agent_pkgid
1079       recur_show_zero setup_show_zero
1080     ),
1081   };
1082
1083   my $error = $cust_pkg->insert(
1084     'change' => 1, #supresses any referral credit to a referring customer
1085     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1086   );
1087   if ($error) {
1088     $dbh->rollback if $oldAutoCommit;
1089     return $error;
1090   }
1091
1092   ##
1093   # insert services
1094   ##
1095
1096   #find historical services within this timeframe before the package cancel
1097   # (incompatible with "time" option to cust_pkg->cancel?)
1098   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1099                      #            too little? (unprovisioing export delay?)
1100   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1101   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1102
1103   my @svc_errors;
1104   foreach my $h_cust_svc (@h_cust_svc) {
1105     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1106     #next unless $h_svc_x; #should this happen?
1107     (my $table = $h_svc_x->table) =~ s/^h_//;
1108     require "FS/$table.pm";
1109     my $class = "FS::$table";
1110     my $svc_x = $class->new( {
1111       'pkgnum'  => $cust_pkg->pkgnum,
1112       'svcpart' => $h_cust_svc->svcpart,
1113       map { $_ => $h_svc_x->get($_) } fields($table)
1114     } );
1115
1116     # radius_usergroup
1117     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1118       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1119     }
1120
1121     my $svc_error = $svc_x->insert;
1122     if ( $svc_error ) {
1123       if ( $options{svc_fatal} ) {
1124         $dbh->rollback if $oldAutoCommit;
1125         return $svc_error;
1126       } else {
1127         # if we've failed to insert the svc_x object, svc_Common->insert
1128         # will have removed the cust_svc already.  if not, then both records
1129         # were inserted but we failed for some other reason (export, most
1130         # likely).  in that case, report the error and delete the records.
1131         push @svc_errors, $svc_error;
1132         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1133         if ( $cust_svc ) {
1134           # except if export_insert failed, export_delete probably won't be
1135           # much better
1136           local $FS::svc_Common::noexport_hack = 1;
1137           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1138           if ( $cleanup_error ) { # and if THAT fails, then run away
1139             $dbh->rollback if $oldAutoCommit;
1140             return $cleanup_error;
1141           }
1142         }
1143       } # svc_fatal
1144     } # svc_error
1145   } #foreach $h_cust_svc
1146
1147   #these are pretty rare, but should handle them
1148   # - dsl_device (mac addresses)
1149   # - phone_device (mac addresses)
1150   # - dsl_note (ikano notes)
1151   # - domain_record (i.e. restore DNS information w/domains)
1152   # - inventory_item(?) (inventory w/un-cancelling service?)
1153   # - nas (svc_broaband nas stuff)
1154   #this stuff is unused in the wild afaik
1155   # - mailinglistmember
1156   # - router.svcnum?
1157   # - svc_domain.parent_svcnum?
1158   # - acct_snarf (ancient mail fetching config)
1159   # - cgp_rule (communigate)
1160   # - cust_svc_option (used by our Tron stuff)
1161   # - acct_rt_transaction (used by our time worked stuff)
1162
1163   ##
1164   # also move over any services that didn't unprovision at cancellation
1165   ##
1166
1167   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1168     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1169     my $error = $cust_svc->replace;
1170     if ( $error ) {
1171       $dbh->rollback if $oldAutoCommit;
1172       return $error;
1173     }
1174   }
1175
1176   ##
1177   # Uncancel any supplemental packages, and make them supplemental to the
1178   # new one.
1179   ##
1180
1181   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1182     my $new_pkg;
1183     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1184     if ( $error ) {
1185       $dbh->rollback if $oldAutoCommit;
1186       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1187     }
1188   }
1189
1190   ##
1191   # Finish
1192   ##
1193
1194   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1195
1196   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1197   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1198
1199   '';
1200 }
1201
1202 =item unexpire
1203
1204 Cancels any pending expiration (sets the expire field to null).
1205
1206 If there is an error, returns the error, otherwise returns false.
1207
1208 =cut
1209
1210 sub unexpire {
1211   my( $self, %options ) = @_;
1212   my $error;
1213
1214   my $oldAutoCommit = $FS::UID::AutoCommit;
1215   local $FS::UID::AutoCommit = 0;
1216   my $dbh = dbh;
1217
1218   my $old = $self->select_for_update;
1219
1220   my $pkgnum = $old->pkgnum;
1221   if ( $old->get('cancel') || $self->get('cancel') ) {
1222     dbh->rollback if $oldAutoCommit;
1223     return "Can't unexpire cancelled package $pkgnum";
1224     # or at least it's pointless
1225   }
1226
1227   unless ( $old->get('expire') && $self->get('expire') ) {
1228     dbh->rollback if $oldAutoCommit;
1229     return "";  # no error
1230   }
1231
1232   my %hash = $self->hash;
1233   $hash{'expire'} = '';
1234   my $new = new FS::cust_pkg ( \%hash );
1235   $error = $new->replace( $self, options => { $self->options } );
1236   if ( $error ) {
1237     $dbh->rollback if $oldAutoCommit;
1238     return $error;
1239   }
1240
1241   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1242
1243   ''; #no errors
1244
1245 }
1246
1247 =item suspend [ OPTION => VALUE ... ]
1248
1249 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1250 package, then suspends the package itself (sets the susp field to now).
1251
1252 Available options are:
1253
1254 =over 4
1255
1256 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1257 either a reasonnum of an existing reason, or passing a hashref will create
1258 a new reason.  The hashref should have the following keys:
1259 - typenum - Reason type (see L<FS::reason_type>
1260 - reason - Text of the new reason.
1261
1262 =item date - can be set to a unix style timestamp to specify when to
1263 suspend (adjourn)
1264
1265 =item time - can be set to override the current time, for calculation
1266 of final invoices or unused-time credits
1267
1268 =item resume_date - can be set to a time when the package should be
1269 unsuspended.  This may be more convenient than calling C<unsuspend()>
1270 separately.
1271
1272 =item from_main - allows a supplemental package to be suspended, rather
1273 than redirecting the method call to its main package.  For internal use.
1274
1275 =item from_cancel - used when suspending from the cancel method, forces
1276 this to skip everything besides basic suspension.  For internal use.
1277
1278 =back
1279
1280 If there is an error, returns the error, otherwise returns false.
1281
1282 =cut
1283
1284 sub suspend {
1285   my( $self, %options ) = @_;
1286   my $error;
1287
1288   # pass all suspend/cancel actions to the main package
1289   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1290     return $self->main_pkg->suspend(%options);
1291   }
1292
1293   my $oldAutoCommit = $FS::UID::AutoCommit;
1294   local $FS::UID::AutoCommit = 0;
1295   my $dbh = dbh;
1296
1297   my $old = $self->select_for_update;
1298
1299   my $pkgnum = $old->pkgnum;
1300   if ( $old->get('cancel') || $self->get('cancel') ) {
1301     dbh->rollback if $oldAutoCommit;
1302     return "Can't suspend cancelled package $pkgnum";
1303   }
1304
1305   if ( $old->get('susp') || $self->get('susp') ) {
1306     dbh->rollback if $oldAutoCommit;
1307     return "";  # no error                     # complain on adjourn?
1308   }
1309
1310   my $suspend_time = $options{'time'} || time;
1311   my $date = $options{date} if $options{date}; # adjourn/suspend later
1312   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1313
1314   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1315     dbh->rollback if $oldAutoCommit;
1316     return "Package $pkgnum expires before it would be suspended.";
1317   }
1318
1319   # some false laziness with sub cancel
1320   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1321        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1322     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1323     # make the entire cust_main->bill path recognize 'suspend' and
1324     # 'cancel' separately.
1325     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1326     my $copy = $self->new({$self->hash});
1327     my $error =
1328       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1329                               'cancel'   => 1,
1330                               'time'     => $suspend_time );
1331     warn "Error billing during suspend, custnum ".
1332       #$self->cust_main->custnum. ": $error"
1333       ": $error"
1334       if $error;
1335   }
1336
1337   my $cust_pkg_reason;
1338   if ( $options{'reason'} ) {
1339     $error = $self->insert_reason( 'reason' => $options{'reason'},
1340                                    'action' => $date ? 'adjourn' : 'suspend',
1341                                    'date'   => $date ? $date : $suspend_time,
1342                                    'reason_otaker' => $options{'reason_otaker'},
1343                                  );
1344     if ( $error ) {
1345       dbh->rollback if $oldAutoCommit;
1346       return "Error inserting cust_pkg_reason: $error";
1347     }
1348     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1349         'date'    => $date ? $date : $suspend_time,
1350         'action'  => $date ? 'A' : 'S',
1351         'pkgnum'  => $self->pkgnum,
1352     });
1353   }
1354
1355   # if a reasonnum was passed, get the actual reason object so we can check
1356   # unused_credit
1357   # (passing a reason hashref is still allowed, but it can't be used with
1358   # the fancy behavioral options.)
1359
1360   my $reason;
1361   if ($options{'reason'} =~ /^\d+$/) {
1362     $reason = FS::reason->by_key($options{'reason'});
1363   }
1364
1365   my %hash = $self->hash;
1366   if ( $date ) {
1367     $hash{'adjourn'} = $date;
1368   } else {
1369     $hash{'susp'} = $suspend_time;
1370   }
1371
1372   my $resume_date = $options{'resume_date'} || 0;
1373   if ( $resume_date > ($date || $suspend_time) ) {
1374     $hash{'resume'} = $resume_date;
1375   }
1376
1377   $options{options} ||= {};
1378
1379   my $new = new FS::cust_pkg ( \%hash );
1380   $error = $new->replace( $self, options => { $self->options,
1381                                               %{ $options{options} },
1382                                             }
1383                         );
1384   if ( $error ) {
1385     $dbh->rollback if $oldAutoCommit;
1386     return $error;
1387   }
1388
1389   unless ( $date ) { # then we are suspending now
1390
1391     unless ($options{'from_cancel'}) {
1392       # credit remaining time if appropriate
1393       # (if required by the package def, or the suspend reason)
1394       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1395                           || ( defined($reason) && $reason->unused_credit );
1396
1397       if ( $unused_credit ) {
1398         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1399         my $error = $self->credit_remaining('suspend', $suspend_time);
1400         if ($error) {
1401           $dbh->rollback if $oldAutoCommit;
1402           return $error;
1403         }
1404       }
1405     }
1406
1407     my @labels = ();
1408
1409     foreach my $cust_svc (
1410       qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
1411     ) {
1412       my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1413
1414       $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1415         $dbh->rollback if $oldAutoCommit;
1416         return "Illegal svcdb value in part_svc!";
1417       };
1418       my $svcdb = $1;
1419       require "FS/$svcdb.pm";
1420
1421       my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1422       if ($svc) {
1423         $error = $svc->suspend;
1424         if ( $error ) {
1425           $dbh->rollback if $oldAutoCommit;
1426           return $error;
1427         }
1428         my( $label, $value ) = $cust_svc->label;
1429         push @labels, "$label: $value";
1430       }
1431     }
1432
1433     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1434     # and this is not a suspend-before-cancel
1435     if ( $cust_pkg_reason ) {
1436       my $reason_obj = $cust_pkg_reason->reason;
1437       if ( $reason_obj->feepart and
1438            ! $reason_obj->fee_on_unsuspend and
1439            ! $options{'from_cancel'} ) {
1440
1441         # register the need to charge a fee, cust_main->bill will do the rest
1442         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1443           if $DEBUG;
1444         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1445             'pkgreasonnum'  => $cust_pkg_reason->num,
1446             'pkgnum'        => $self->pkgnum,
1447             'feepart'       => $reason->feepart,
1448             'nextbill'      => $reason->fee_hold,
1449         });
1450         $error ||= $cust_pkg_reason_fee->insert;
1451       }
1452     }
1453
1454     my $conf = new FS::Conf;
1455     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1456
1457       my $error = send_email(
1458         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1459                                    #invoice_from ??? well as good as any
1460         'to'      => $conf->config('suspend_email_admin'),
1461         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1462         'body'    => [
1463           "This is an automatic message from your Freeside installation\n",
1464           "informing you that the following customer package has been suspended:\n",
1465           "\n",
1466           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1467           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1468           ( map { "Service : $_\n" } @labels ),
1469         ],
1470         'custnum' => $self->custnum,
1471         'msgtype' => 'admin'
1472       );
1473
1474       if ( $error ) {
1475         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1476              "$error\n";
1477       }
1478
1479     }
1480
1481   }
1482
1483   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1484     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1485     if ( $error ) {
1486       $dbh->rollback if $oldAutoCommit;
1487       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1488     }
1489   }
1490
1491   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1492
1493   ''; #no errors
1494 }
1495
1496 =item credit_remaining MODE TIME
1497
1498 Generate a credit for this package for the time remaining in the current
1499 billing period.  MODE is either "suspend" or "cancel" (determines the
1500 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1501 are mandatory.
1502
1503 =cut
1504
1505 # Implementation note:
1506 #
1507 # If you pkgpart-change a package that has been billed, and it's set to give
1508 # credit on package change, then this method gets called and then the new
1509 # package will have no last_bill date. Therefore the customer will be credited
1510 # only once (per billing period) even if there are multiple package changes.
1511 #
1512 # If you location-change a package that has been billed, this method will NOT
1513 # be called and the new package WILL have the last bill date of the old
1514 # package.
1515 #
1516 # If the new package is then canceled within the same billing cycle,
1517 # credit_remaining needs to run calc_remain on the OLD package to determine
1518 # the amount of unused time to credit.
1519
1520 sub credit_remaining {
1521   # Add a credit for remaining service
1522   my ($self, $mode, $time) = @_;
1523   die 'credit_remaining requires suspend or cancel'
1524     unless $mode eq 'suspend' or $mode eq 'cancel';
1525   die 'no suspend/cancel time' unless $time > 0;
1526
1527   my $conf = FS::Conf->new;
1528   my $reason_type = $conf->config($mode.'_credit_type');
1529
1530   my $last_bill = $self->getfield('last_bill') || 0;
1531   my $next_bill = $self->getfield('bill') || 0;
1532   if ( $last_bill > 0         # the package has been billed
1533       and $next_bill > 0      # the package has a next bill date
1534       and $next_bill >= $time # which is in the future
1535   ) {
1536     my @cust_credit_source_bill_pkg = ();
1537     my $remaining_value = 0;
1538
1539     my $remain_pkg = $self;
1540     $remaining_value = $remain_pkg->calc_remain(
1541       'time' => $time,
1542       'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1543     );
1544
1545     # we may have to walk back past some package changes to get to the
1546     # one that actually has unused time
1547     while ( $remaining_value == 0 ) {
1548       if ( $remain_pkg->change_pkgnum ) {
1549         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1550       } else {
1551         # the package has really never been billed
1552         return;
1553       }
1554       $remaining_value = $remain_pkg->calc_remain(
1555         'time' => $time,
1556         'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1557       );
1558     }
1559
1560     if ( $remaining_value > 0 ) {
1561       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1562         if $DEBUG;
1563       my $error = $self->cust_main->credit(
1564         $remaining_value,
1565         'Credit for unused time on '. $self->part_pkg->pkg,
1566         'reason_type' => $reason_type,
1567         'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1568       );
1569       return "Error crediting customer \$$remaining_value for unused time".
1570         " on ". $self->part_pkg->pkg. ": $error"
1571         if $error;
1572     } #if $remaining_value
1573   } #if $last_bill, etc.
1574   '';
1575 }
1576
1577 =item unsuspend [ OPTION => VALUE ... ]
1578
1579 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1580 package, then unsuspends the package itself (clears the susp field and the
1581 adjourn field if it is in the past).  If the suspend reason includes an
1582 unsuspension package, that package will be ordered.
1583
1584 Available options are:
1585
1586 =over 4
1587
1588 =item date
1589
1590 Can be set to a date to unsuspend the package in the future (the 'resume'
1591 field).
1592
1593 =item adjust_next_bill
1594
1595 Can be set true to adjust the next bill date forward by
1596 the amount of time the account was inactive.  This was set true by default
1597 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1598 explicitly requested with this option or in the price plan.
1599
1600 =back
1601
1602 If there is an error, returns the error, otherwise returns false.
1603
1604 =cut
1605
1606 sub unsuspend {
1607   my( $self, %opt ) = @_;
1608   my $error;
1609
1610   # pass all suspend/cancel actions to the main package
1611   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1612     return $self->main_pkg->unsuspend(%opt);
1613   }
1614
1615   my $oldAutoCommit = $FS::UID::AutoCommit;
1616   local $FS::UID::AutoCommit = 0;
1617   my $dbh = dbh;
1618
1619   my $old = $self->select_for_update;
1620
1621   my $pkgnum = $old->pkgnum;
1622   if ( $old->get('cancel') || $self->get('cancel') ) {
1623     $dbh->rollback if $oldAutoCommit;
1624     return "Can't unsuspend cancelled package $pkgnum";
1625   }
1626
1627   unless ( $old->get('susp') && $self->get('susp') ) {
1628     $dbh->rollback if $oldAutoCommit;
1629     return "";  # no error                     # complain instead?
1630   }
1631
1632   # handle the case of setting a future unsuspend (resume) date
1633   # and do not continue to actually unsuspend the package
1634   my $date = $opt{'date'};
1635   if ( $date and $date > time ) { # return an error if $date <= time?
1636
1637     if ( $old->get('expire') && $old->get('expire') < $date ) {
1638       $dbh->rollback if $oldAutoCommit;
1639       return "Package $pkgnum expires before it would be unsuspended.";
1640     }
1641
1642     my $new = new FS::cust_pkg { $self->hash };
1643     $new->set('resume', $date);
1644     $error = $new->replace($self, options => $self->options);
1645
1646     if ( $error ) {
1647       $dbh->rollback if $oldAutoCommit;
1648       return $error;
1649     }
1650     else {
1651       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1652       return '';
1653     }
1654
1655   } #if $date
1656
1657   if (!$self->setup) {
1658     # then this package is being released from on-hold status
1659     $self->set_initial_timers;
1660   }
1661
1662   my @labels = ();
1663
1664   foreach my $cust_svc (
1665     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1666   ) {
1667     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1668
1669     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1670       $dbh->rollback if $oldAutoCommit;
1671       return "Illegal svcdb value in part_svc!";
1672     };
1673     my $svcdb = $1;
1674     require "FS/$svcdb.pm";
1675
1676     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1677     if ($svc) {
1678       $error = $svc->unsuspend;
1679       if ( $error ) {
1680         $dbh->rollback if $oldAutoCommit;
1681         return $error;
1682       }
1683       my( $label, $value ) = $cust_svc->label;
1684       push @labels, "$label: $value";
1685     }
1686
1687   }
1688
1689   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1690   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1691
1692   my %hash = $self->hash;
1693   my $inactive = time - $hash{'susp'};
1694
1695   my $conf = new FS::Conf;
1696
1697   #adjust the next bill date forward
1698   # increment next bill date if certain conditions are met:
1699   # - it was due to be billed at some point
1700   # - either the global or local config says to do this
1701   my $adjust_bill = 0;
1702   if (
1703        $inactive > 0
1704     && ( $hash{'bill'} || $hash{'setup'} )
1705     && (    $opt{'adjust_next_bill'}
1706          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1707          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1708        )
1709   ) {
1710     $adjust_bill = 1;
1711   }
1712
1713   # but not if:
1714   # - the package billed during suspension
1715   # - or it was ordered on hold
1716   # - or the customer was credited for the unused time
1717
1718   if ( $self->option('suspend_bill',1)
1719       or ( $self->part_pkg->option('suspend_bill',1)
1720            and ! $self->option('no_suspend_bill',1)
1721          )
1722       or $hash{'order_date'} == $hash{'susp'}
1723   ) {
1724     $adjust_bill = 0;
1725   }
1726
1727   if ( $adjust_bill ) {
1728     if (    $self->part_pkg->option('unused_credit_suspend')
1729          or ( ref($reason) and $reason->unused_credit ) ) {
1730       # then the customer was credited for the unused time before suspending,
1731       # so their next bill should be immediate
1732       $hash{'bill'} = time;
1733     } else {
1734       # add the length of time suspended to the bill date
1735       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1736     }
1737   }
1738
1739   $hash{'susp'} = '';
1740   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1741   $hash{'resume'} = '' if !$hash{'adjourn'};
1742   my $new = new FS::cust_pkg ( \%hash );
1743   $error = $new->replace( $self, options => { $self->options } );
1744   if ( $error ) {
1745     $dbh->rollback if $oldAutoCommit;
1746     return $error;
1747   }
1748
1749   my $unsusp_pkg;
1750
1751   if ( $reason ) {
1752     if ( $reason->unsuspend_pkgpart ) {
1753       warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n";
1754       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1755         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
1756                     " not found.";
1757       my $start_date = $self->cust_main->next_bill_date
1758         if $reason->unsuspend_hold;
1759
1760       if ( $part_pkg ) {
1761         $unsusp_pkg = FS::cust_pkg->new({
1762             'custnum'     => $self->custnum,
1763             'pkgpart'     => $reason->unsuspend_pkgpart,
1764             'start_date'  => $start_date,
1765             'locationnum' => $self->locationnum,
1766             # discount? probably not...
1767         });
1768
1769         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
1770       }
1771     }
1772     # new way, using fees
1773     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
1774       # register the need to charge a fee, cust_main->bill will do the rest
1775       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1776         if $DEBUG;
1777       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1778           'pkgreasonnum'  => $cust_pkg_reason->num,
1779           'pkgnum'        => $self->pkgnum,
1780           'feepart'       => $reason->feepart,
1781           'nextbill'      => $reason->fee_hold,
1782       });
1783       $error ||= $cust_pkg_reason_fee->insert;
1784     }
1785
1786     if ( $error ) {
1787       $dbh->rollback if $oldAutoCommit;
1788       return $error;
1789     }
1790   }
1791
1792   if ( $conf->config('unsuspend_email_admin') ) {
1793
1794     my $error = send_email(
1795       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1796                                  #invoice_from ??? well as good as any
1797       'to'      => $conf->config('unsuspend_email_admin'),
1798       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
1799         "This is an automatic message from your Freeside installation\n",
1800         "informing you that the following customer package has been unsuspended:\n",
1801         "\n",
1802         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1803         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1804         ( map { "Service : $_\n" } @labels ),
1805         ($unsusp_pkg ?
1806           "An unsuspension fee was charged: ".
1807             $unsusp_pkg->part_pkg->pkg_comment."\n"
1808           : ''
1809         ),
1810       ],
1811       'custnum' => $self->custnum,
1812       'msgtype' => 'admin',
1813     );
1814
1815     if ( $error ) {
1816       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
1817            "$error\n";
1818     }
1819
1820   }
1821
1822   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1823     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
1824     if ( $error ) {
1825       $dbh->rollback if $oldAutoCommit;
1826       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1827     }
1828   }
1829
1830   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1831
1832   ''; #no errors
1833 }
1834
1835 =item unadjourn
1836
1837 Cancels any pending suspension (sets the adjourn field to null).
1838
1839 If there is an error, returns the error, otherwise returns false.
1840
1841 =cut
1842
1843 sub unadjourn {
1844   my( $self, %options ) = @_;
1845   my $error;
1846
1847   my $oldAutoCommit = $FS::UID::AutoCommit;
1848   local $FS::UID::AutoCommit = 0;
1849   my $dbh = dbh;
1850
1851   my $old = $self->select_for_update;
1852
1853   my $pkgnum = $old->pkgnum;
1854   if ( $old->get('cancel') || $self->get('cancel') ) {
1855     dbh->rollback if $oldAutoCommit;
1856     return "Can't unadjourn cancelled package $pkgnum";
1857     # or at least it's pointless
1858   }
1859
1860   if ( $old->get('susp') || $self->get('susp') ) {
1861     dbh->rollback if $oldAutoCommit;
1862     return "Can't unadjourn suspended package $pkgnum";
1863     # perhaps this is arbitrary
1864   }
1865
1866   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
1867     dbh->rollback if $oldAutoCommit;
1868     return "";  # no error
1869   }
1870
1871   my %hash = $self->hash;
1872   $hash{'adjourn'} = '';
1873   $hash{'resume'}  = '';
1874   my $new = new FS::cust_pkg ( \%hash );
1875   $error = $new->replace( $self, options => { $self->options } );
1876   if ( $error ) {
1877     $dbh->rollback if $oldAutoCommit;
1878     return $error;
1879   }
1880
1881   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1882
1883   ''; #no errors
1884
1885 }
1886
1887
1888 =item change HASHREF | OPTION => VALUE ...
1889
1890 Changes this package: cancels it and creates a new one, with a different
1891 pkgpart or locationnum or both.  All services are transferred to the new
1892 package (no change will be made if this is not possible).
1893
1894 Options may be passed as a list of key/value pairs or as a hash reference.
1895 Options are:
1896
1897 =over 4
1898
1899 =item locationnum
1900
1901 New locationnum, to change the location for this package.
1902
1903 =item cust_location
1904
1905 New FS::cust_location object, to create a new location and assign it
1906 to this package.
1907
1908 =item cust_main
1909
1910 New FS::cust_main object, to create a new customer and assign the new package
1911 to it.
1912
1913 =item pkgpart
1914
1915 New pkgpart (see L<FS::part_pkg>).
1916
1917 =item refnum
1918
1919 New refnum (see L<FS::part_referral>).
1920
1921 =item quantity
1922
1923 New quantity; if unspecified, the new package will have the same quantity
1924 as the old.
1925
1926 =item cust_pkg
1927
1928 "New" (existing) FS::cust_pkg object.  The package's services and other
1929 attributes will be transferred to this package.
1930
1931 =item keep_dates
1932
1933 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
1934 susp, adjourn, cancel, expire, and contract_end) to the new package.
1935
1936 =item unprotect_svcs
1937
1938 Normally, change() will rollback and return an error if some services
1939 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
1940 If unprotect_svcs is true, this method will transfer as many services as
1941 it can and then unconditionally cancel the old package.
1942
1943 =back
1944
1945 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
1946 cust_pkg must be specified (otherwise, what's the point?)
1947
1948 Returns either the new FS::cust_pkg object or a scalar error.
1949
1950 For example:
1951
1952   my $err_or_new_cust_pkg = $old_cust_pkg->change
1953
1954 =cut
1955
1956 #some false laziness w/order
1957 sub change {
1958   my $self = shift;
1959   my $opt = ref($_[0]) ? shift : { @_ };
1960
1961   my $conf = new FS::Conf;
1962
1963   # Transactionize this whole mess
1964   my $oldAutoCommit = $FS::UID::AutoCommit;
1965   local $FS::UID::AutoCommit = 0;
1966   my $dbh = dbh;
1967
1968   my $error;
1969
1970   my %hash = ();
1971
1972   my $time = time;
1973
1974   $hash{'setup'} = $time if $self->setup;
1975
1976   $hash{'change_date'} = $time;
1977   $hash{"change_$_"}  = $self->$_()
1978     foreach qw( pkgnum pkgpart locationnum );
1979
1980   if ( $opt->{'cust_location'} ) {
1981     $error = $opt->{'cust_location'}->find_or_insert;
1982     if ( $error ) {
1983       $dbh->rollback if $oldAutoCommit;
1984       return "creating location record: $error";
1985     }
1986     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
1987   }
1988
1989   if ( $opt->{'cust_pkg'} ) {
1990     # treat changing to a package with a different pkgpart as a
1991     # pkgpart change (because it is)
1992     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
1993   }
1994
1995   # whether to override pkgpart checking on the new package
1996   my $same_pkgpart = 1;
1997   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
1998     $same_pkgpart = 0;
1999   }
2000
2001   my $unused_credit = 0;
2002   my $keep_dates = $opt->{'keep_dates'};
2003   # Special case.  If the pkgpart is changing, and the customer is
2004   # going to be credited for remaining time, don't keep setup, bill,
2005   # or last_bill dates, and DO pass the flag to cancel() to credit
2006   # the customer.
2007   if ( $opt->{'pkgpart'}
2008        and $opt->{'pkgpart'} != $self->pkgpart
2009        and $self->part_pkg->option('unused_credit_change', 1) ) {
2010     $unused_credit = 1;
2011     $keep_dates = 0;
2012     $hash{$_} = '' foreach qw(setup bill last_bill);
2013   }
2014
2015   if ( $keep_dates ) {
2016     foreach my $date ( qw(setup bill last_bill susp adjourn cancel expire
2017                           resume start_date contract_end ) ) {
2018       $hash{$date} = $self->getfield($date);
2019     }
2020   }
2021   # always keep this date, regardless of anything
2022   # (the date of the package change is in a different field)
2023   $hash{'order_date'} = $self->getfield('order_date');
2024
2025   # allow $opt->{'locationnum'} = '' to specifically set it to null
2026   # (i.e. customer default location)
2027   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2028
2029   # usually this doesn't matter.  the two cases where it does are:
2030   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2031   # and
2032   # 2. (more importantly) changing a package before it's billed
2033   $hash{'waive_setup'} = $self->waive_setup;
2034
2035   my $custnum = $self->custnum;
2036   if ( $opt->{cust_main} ) {
2037     my $cust_main = $opt->{cust_main};
2038     unless ( $cust_main->custnum ) {
2039       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2040       if ( $error ) {
2041         $dbh->rollback if $oldAutoCommit;
2042         return "inserting customer record: $error";
2043       }
2044     }
2045     $custnum = $cust_main->custnum;
2046   }
2047
2048   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2049
2050   my $cust_pkg;
2051   if ( $opt->{'cust_pkg'} ) {
2052     # The target package already exists; update it to show that it was
2053     # changed from this package.
2054     $cust_pkg = $opt->{'cust_pkg'};
2055
2056     foreach ( qw( pkgnum pkgpart locationnum ) ) {
2057       $cust_pkg->set("change_$_", $self->get($_));
2058     }
2059     $cust_pkg->set('change_date', $time);
2060     $error = $cust_pkg->replace;
2061
2062   } else {
2063     # Create the new package.
2064     $cust_pkg = new FS::cust_pkg {
2065       custnum     => $custnum,
2066       locationnum => $opt->{'locationnum'},
2067       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2068           qw( pkgpart quantity refnum salesnum )
2069       ),
2070       %hash,
2071     };
2072     $error = $cust_pkg->insert( 'change' => 1,
2073                                 'allow_pkgpart' => $same_pkgpart );
2074   }
2075   if ($error) {
2076     $dbh->rollback if $oldAutoCommit;
2077     return "inserting new package: $error";
2078   }
2079
2080   # Transfer services and cancel old package.
2081   # Enforce service limits only if this is a pkgpart change.
2082   local $FS::cust_svc::ignore_quantity;
2083   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2084   $error = $self->transfer($cust_pkg);
2085   if ($error and $error == 0) {
2086     # $old_pkg->transfer failed.
2087     $dbh->rollback if $oldAutoCommit;
2088     return "transferring $error";
2089   }
2090
2091   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2092     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2093     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2094     if ($error and $error == 0) {
2095       # $old_pkg->transfer failed.
2096       $dbh->rollback if $oldAutoCommit;
2097       return "converting $error";
2098     }
2099   }
2100
2101   # We set unprotect_svcs when executing a "future package change".  It's
2102   # not a user-interactive operation, so returning an error means the
2103   # package change will just fail.  Rather than have that happen, we'll
2104   # let leftover services be deleted.
2105   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2106     # Transfers were successful, but we still had services left on the old
2107     # package.  We can't change the package under this circumstances, so abort.
2108     $dbh->rollback if $oldAutoCommit;
2109     return "unable to transfer all services";
2110   }
2111
2112   #reset usage if changing pkgpart
2113   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2114   if ($self->pkgpart != $cust_pkg->pkgpart) {
2115     my $part_pkg = $cust_pkg->part_pkg;
2116     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2117                                                  ? ()
2118                                                  : ( 'null' => 1 )
2119                                    )
2120       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2121
2122     if ($error) {
2123       $dbh->rollback if $oldAutoCommit;
2124       return "setting usage values: $error";
2125     }
2126   } else {
2127     # if NOT changing pkgpart, transfer any usage pools over
2128     foreach my $usage ($self->cust_pkg_usage) {
2129       $usage->set('pkgnum', $cust_pkg->pkgnum);
2130       $error = $usage->replace;
2131       if ( $error ) {
2132         $dbh->rollback if $oldAutoCommit;
2133         return "transferring usage pools: $error";
2134       }
2135     }
2136   }
2137
2138   # transfer usage pricing add-ons, if we're not changing pkgpart
2139   if ( $same_pkgpart ) {
2140     foreach my $old_cust_pkg_usageprice ($self->cust_pkg_usageprice) {
2141       my $new_cust_pkg_usageprice = new FS::cust_pkg_usageprice {
2142         'pkgnum'         => $cust_pkg->pkgnum,
2143         'usagepricepart' => $old_cust_pkg_usageprice->usagepricepart,
2144         'quantity'       => $old_cust_pkg_usageprice->quantity,
2145       };
2146       $error = $new_cust_pkg_usageprice->insert;
2147       if ( $error ) {
2148         $dbh->rollback if $oldAutoCommit;
2149         return "Error transferring usage pricing add-on: $error";
2150       }
2151     }
2152   }
2153
2154   # transfer discounts, if we're not changing pkgpart
2155   if ( $same_pkgpart ) {
2156     foreach my $old_discount ($self->cust_pkg_discount_active) {
2157       # don't remove the old discount, we may still need to bill that package.
2158       my $new_discount = new FS::cust_pkg_discount {
2159         'pkgnum'      => $cust_pkg->pkgnum,
2160         'discountnum' => $old_discount->discountnum,
2161         'months_used' => $old_discount->months_used,
2162       };
2163       $error = $new_discount->insert;
2164       if ( $error ) {
2165         $dbh->rollback if $oldAutoCommit;
2166         return "transferring discounts: $error";
2167       }
2168     }
2169   }
2170
2171   # transfer (copy) invoice details
2172   foreach my $detail ($self->cust_pkg_detail) {
2173     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2174     $new_detail->set('pkgdetailnum', '');
2175     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2176     $error = $new_detail->insert;
2177     if ( $error ) {
2178       $dbh->rollback if $oldAutoCommit;
2179       return "transferring package notes: $error";
2180     }
2181   }
2182
2183   my @new_supp_pkgs;
2184
2185   if ( !$opt->{'cust_pkg'} ) {
2186     # Order any supplemental packages.
2187     my $part_pkg = $cust_pkg->part_pkg;
2188     my @old_supp_pkgs = $self->supplemental_pkgs;
2189     foreach my $link ($part_pkg->supp_part_pkg_link) {
2190       my $old;
2191       foreach (@old_supp_pkgs) {
2192         if ($_->pkgpart == $link->dst_pkgpart) {
2193           $old = $_;
2194           $_->pkgpart(0); # so that it can't match more than once
2195         }
2196         last if $old;
2197       }
2198       # false laziness with FS::cust_main::Packages::order_pkg
2199       my $new = FS::cust_pkg->new({
2200           pkgpart       => $link->dst_pkgpart,
2201           pkglinknum    => $link->pkglinknum,
2202           custnum       => $custnum,
2203           main_pkgnum   => $cust_pkg->pkgnum,
2204           locationnum   => $cust_pkg->locationnum,
2205           start_date    => $cust_pkg->start_date,
2206           order_date    => $cust_pkg->order_date,
2207           expire        => $cust_pkg->expire,
2208           adjourn       => $cust_pkg->adjourn,
2209           contract_end  => $cust_pkg->contract_end,
2210           refnum        => $cust_pkg->refnum,
2211           discountnum   => $cust_pkg->discountnum,
2212           waive_setup   => $cust_pkg->waive_setup,
2213       });
2214       if ( $old and $opt->{'keep_dates'} ) {
2215         foreach (qw(setup bill last_bill)) {
2216           $new->set($_, $old->get($_));
2217         }
2218       }
2219       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2220       # transfer services
2221       if ( $old ) {
2222         $error ||= $old->transfer($new);
2223       }
2224       if ( $error and $error > 0 ) {
2225         # no reason why this should ever fail, but still...
2226         $error = "Unable to transfer all services from supplemental package ".
2227           $old->pkgnum;
2228       }
2229       if ( $error ) {
2230         $dbh->rollback if $oldAutoCommit;
2231         return $error;
2232       }
2233       push @new_supp_pkgs, $new;
2234     }
2235   } # if !$opt->{'cust_pkg'}
2236     # because if there is one, then supplemental packages would already
2237     # have been created for it.
2238
2239   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2240   #remaining time.
2241   #Don't allow billing the package (preceding period packages and/or
2242   #outstanding usage) if we are keeping dates (i.e. location changing),
2243   #because the new package will be billed for the same date range.
2244   #Supplemental packages are also canceled here.
2245
2246   # during scheduled changes, avoid canceling the package we just
2247   # changed to (duh)
2248   $self->set('change_to_pkgnum' => '');
2249
2250   $error = $self->cancel(
2251     quiet          => 1,
2252     unused_credit  => $unused_credit,
2253     nobill         => $keep_dates,
2254     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2255     no_delay_cancel => 1,
2256   );
2257   if ($error) {
2258     $dbh->rollback if $oldAutoCommit;
2259     return "canceling old package: $error";
2260   }
2261
2262   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2263     #$self->cust_main
2264     my $error = $cust_pkg->cust_main->bill(
2265       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2266     );
2267     if ( $error ) {
2268       $dbh->rollback if $oldAutoCommit;
2269       return "billing new package: $error";
2270     }
2271   }
2272
2273   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2274
2275   $cust_pkg;
2276
2277 }
2278
2279 =item change_later OPTION => VALUE...
2280
2281 Schedule a package change for a later date.  This actually orders the new
2282 package immediately, but sets its start date for a future date, and sets
2283 the current package to expire on the same date.
2284
2285 If the package is already scheduled for a change, this can be called with
2286 'start_date' to change the scheduled date, or with pkgpart and/or
2287 locationnum to modify the package change.  To cancel the scheduled change
2288 entirely, see C<abort_change>.
2289
2290 Options include:
2291
2292 =over 4
2293
2294 =item start_date
2295
2296 The date for the package change.  Required, and must be in the future.
2297
2298 =item pkgpart
2299
2300 =item locationnum
2301
2302 =item quantity
2303
2304 The pkgpart. locationnum, and quantity of the new package, with the same
2305 meaning as in C<change>.
2306
2307 =back
2308
2309 =cut
2310
2311 sub change_later {
2312   my $self = shift;
2313   my $opt = ref($_[0]) ? shift : { @_ };
2314
2315   my $oldAutoCommit = $FS::UID::AutoCommit;
2316   local $FS::UID::AutoCommit = 0;
2317   my $dbh = dbh;
2318
2319   my $cust_main = $self->cust_main;
2320
2321   my $date = delete $opt->{'start_date'} or return 'start_date required';
2322
2323   if ( $date <= time ) {
2324     $dbh->rollback if $oldAutoCommit;
2325     return "start_date $date is in the past";
2326   }
2327
2328   my $error;
2329
2330   if ( $self->change_to_pkgnum ) {
2331     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2332     my $new_pkgpart = $opt->{'pkgpart'}
2333         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2334     my $new_locationnum = $opt->{'locationnum'}
2335         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2336     my $new_quantity = $opt->{'quantity'}
2337         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2338     if ( $new_pkgpart or $new_locationnum or $new_quantity ) {
2339       # it hasn't been billed yet, so in principle we could just edit
2340       # it in place (w/o a package change), but that's bad form.
2341       # So change the package according to the new options...
2342       my $err_or_pkg = $change_to->change(%$opt);
2343       if ( ref $err_or_pkg ) {
2344         # Then set that package up for a future start.
2345         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2346         $self->set('expire', $date); # in case it's different
2347         $err_or_pkg->set('start_date', $date);
2348         $err_or_pkg->set('change_date', '');
2349         $err_or_pkg->set('change_pkgnum', '');
2350
2351         $error = $self->replace       ||
2352                  $err_or_pkg->replace ||
2353                  $change_to->cancel('no_delay_cancel' => 1) ||
2354                  $change_to->delete;
2355       } else {
2356         $error = $err_or_pkg;
2357       }
2358     } else { # change the start date only.
2359       $self->set('expire', $date);
2360       $change_to->set('start_date', $date);
2361       $error = $self->replace || $change_to->replace;
2362     }
2363     if ( $error ) {
2364       $dbh->rollback if $oldAutoCommit;
2365       return $error;
2366     } else {
2367       $dbh->commit if $oldAutoCommit;
2368       return '';
2369     }
2370   } # if $self->change_to_pkgnum
2371
2372   my $new_pkgpart = $opt->{'pkgpart'}
2373       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2374   my $new_locationnum = $opt->{'locationnum'}
2375       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2376   my $new_quantity = $opt->{'quantity'}
2377       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2378
2379   return '' unless $new_pkgpart or $new_locationnum or $new_quantity; # wouldn't do anything
2380
2381   # allow $opt->{'locationnum'} = '' to specifically set it to null
2382   # (i.e. customer default location)
2383   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2384
2385   my $new = FS::cust_pkg->new( {
2386     custnum     => $self->custnum,
2387     locationnum => $opt->{'locationnum'},
2388     start_date  => $date,
2389     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2390       qw( pkgpart quantity refnum salesnum )
2391   } );
2392   $error = $new->insert('change' => 1,
2393                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2394   if ( !$error ) {
2395     $self->set('change_to_pkgnum', $new->pkgnum);
2396     $self->set('expire', $date);
2397     $error = $self->replace;
2398   }
2399   if ( $error ) {
2400     $dbh->rollback if $oldAutoCommit;
2401   } else {
2402     $dbh->commit if $oldAutoCommit;
2403   }
2404
2405   $error;
2406 }
2407
2408 =item abort_change
2409
2410 Cancels a future package change scheduled by C<change_later>.
2411
2412 =cut
2413
2414 sub abort_change {
2415   my $self = shift;
2416   my $pkgnum = $self->change_to_pkgnum;
2417   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2418   my $error;
2419   if ( $change_to ) {
2420     $error = $change_to->cancel || $change_to->delete;
2421     return $error if $error;
2422   }
2423   $self->set('change_to_pkgnum', '');
2424   $self->set('expire', '');
2425   $self->replace;
2426 }
2427
2428 =item set_quantity QUANTITY
2429
2430 Change the package's quantity field.  This is one of the few package properties
2431 that can safely be changed without canceling and reordering the package
2432 (because it doesn't affect tax eligibility).  Returns an error or an
2433 empty string.
2434
2435 =cut
2436
2437 sub set_quantity {
2438   my $self = shift;
2439   $self = $self->replace_old; # just to make sure
2440   $self->quantity(shift);
2441   $self->replace;
2442 }
2443
2444 =item set_salesnum SALESNUM
2445
2446 Change the package's salesnum (sales person) field.  This is one of the few
2447 package properties that can safely be changed without canceling and reordering
2448 the package (because it doesn't affect tax eligibility).  Returns an error or
2449 an empty string.
2450
2451 =cut
2452
2453 sub set_salesnum {
2454   my $self = shift;
2455   $self = $self->replace_old; # just to make sure
2456   $self->salesnum(shift);
2457   $self->replace;
2458   # XXX this should probably reassign any credit that's already been given
2459 }
2460
2461 =item modify_charge OPTIONS
2462
2463 Change the properties of a one-time charge.  The following properties can
2464 be changed this way:
2465 - pkg: the package description
2466 - classnum: the package class
2467 - additional: arrayref of additional invoice details to add to this package
2468
2469 and, I<if the charge has not yet been billed>:
2470 - start_date: the date when it will be billed
2471 - amount: the setup fee to be charged
2472 - quantity: the multiplier for the setup fee
2473 - separate_bill: whether to put the charge on a separate invoice
2474
2475 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2476 commission credits linked to this charge, they will be recalculated.
2477
2478 =cut
2479
2480 sub modify_charge {
2481   my $self = shift;
2482   my %opt = @_;
2483   my $part_pkg = $self->part_pkg;
2484   my $pkgnum = $self->pkgnum;
2485
2486   my $dbh = dbh;
2487   my $oldAutoCommit = $FS::UID::AutoCommit;
2488   local $FS::UID::AutoCommit = 0;
2489
2490   return "Can't use modify_charge except on one-time charges"
2491     unless $part_pkg->freq eq '0';
2492
2493   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2494     $part_pkg->set('pkg', $opt{'pkg'});
2495   }
2496
2497   my %pkg_opt = $part_pkg->options;
2498   my $pkg_opt_modified = 0;
2499
2500   $opt{'additional'} ||= [];
2501   my $i;
2502   my @old_additional;
2503   foreach (grep /^additional/, keys %pkg_opt) {
2504     ($i) = ($_ =~ /^additional_info(\d+)$/);
2505     $old_additional[$i] = $pkg_opt{$_} if $i;
2506     delete $pkg_opt{$_};
2507   }
2508
2509   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2510     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2511     if (!exists($old_additional[$i])
2512         or $old_additional[$i] ne $opt{'additional'}->[$i])
2513     {
2514       $pkg_opt_modified = 1;
2515     }
2516   }
2517   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2518   $pkg_opt{'additional_count'} = $i if $i > 0;
2519
2520   my $old_classnum;
2521   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2522   {
2523     # remember it
2524     $old_classnum = $part_pkg->classnum;
2525     $part_pkg->set('classnum', $opt{'classnum'});
2526   }
2527
2528   if ( !$self->get('setup') ) {
2529     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2530     # and separate_bill
2531
2532     if ( exists($opt{'amount'})
2533           and $part_pkg->option('setup_fee') != $opt{'amount'}
2534           and $opt{'amount'} > 0 ) {
2535
2536       $pkg_opt{'setup_fee'} = $opt{'amount'};
2537       $pkg_opt_modified = 1;
2538     }
2539
2540     if ( exists($opt{'setup_cost'})
2541           and $part_pkg->setup_cost != $opt{'setup_cost'}
2542           and $opt{'setup_cost'} > 0 ) {
2543
2544       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2545     }
2546
2547     if ( exists($opt{'quantity'})
2548           and $opt{'quantity'} != $self->quantity
2549           and $opt{'quantity'} > 0 ) {
2550
2551       $self->set('quantity', $opt{'quantity'});
2552     }
2553
2554     if ( exists($opt{'start_date'})
2555           and $opt{'start_date'} != $self->start_date ) {
2556
2557       $self->set('start_date', $opt{'start_date'});
2558     }
2559
2560     if ( exists($opt{'separate_bill'})
2561           and $opt{'separate_bill'} ne $self->separate_bill ) {
2562
2563       $self->set('separate_bill', $opt{'separate_bill'});
2564     }
2565
2566
2567   } # else simply ignore them; the UI shouldn't allow editing the fields
2568
2569
2570   if ( exists($opt{'taxclass'})
2571           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2572
2573       $part_pkg->set('taxclass', $opt{'taxclass'});
2574   }
2575
2576   my $error;
2577   if ( $part_pkg->modified or $pkg_opt_modified ) {
2578     # can we safely modify the package def?
2579     # Yes, if it's not available for purchase, and this is the only instance
2580     # of it.
2581     if ( $part_pkg->disabled
2582          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2583          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2584        ) {
2585       $error = $part_pkg->replace( options => \%pkg_opt );
2586     } else {
2587       # clone it
2588       $part_pkg = $part_pkg->clone;
2589       $part_pkg->set('disabled' => 'Y');
2590       $error = $part_pkg->insert( options => \%pkg_opt );
2591       # and associate this as yet-unbilled package to the new package def
2592       $self->set('pkgpart' => $part_pkg->pkgpart);
2593     }
2594     if ( $error ) {
2595       $dbh->rollback if $oldAutoCommit;
2596       return $error;
2597     }
2598   }
2599
2600   if ($self->modified) { # for quantity or start_date change, or if we had
2601                          # to clone the existing package def
2602     my $error = $self->replace;
2603     return $error if $error;
2604   }
2605   if (defined $old_classnum) {
2606     # fix invoice grouping records
2607     my $old_catname = $old_classnum
2608                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2609                       : '';
2610     my $new_catname = $opt{'classnum'}
2611                       ? $part_pkg->pkg_class->categoryname
2612                       : '';
2613     if ( $old_catname ne $new_catname ) {
2614       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2615         # (there should only be one...)
2616         my @display = qsearch( 'cust_bill_pkg_display', {
2617             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2618             'section'     => $old_catname,
2619         });
2620         foreach (@display) {
2621           $_->set('section', $new_catname);
2622           $error = $_->replace;
2623           if ( $error ) {
2624             $dbh->rollback if $oldAutoCommit;
2625             return $error;
2626           }
2627         }
2628       } # foreach $cust_bill_pkg
2629     }
2630
2631     if ( $opt{'adjust_commission'} ) {
2632       # fix commission credits...tricky.
2633       foreach my $cust_event ($self->cust_event) {
2634         my $part_event = $cust_event->part_event;
2635         foreach my $table (qw(sales agent)) {
2636           my $class =
2637             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
2638           my $credit = qsearchs('cust_credit', {
2639               'eventnum' => $cust_event->eventnum,
2640           });
2641           if ( $part_event->isa($class) ) {
2642             # Yes, this results in current commission rates being applied
2643             # retroactively to a one-time charge.  For accounting purposes
2644             # there ought to be some kind of time limit on doing this.
2645             my $amount = $part_event->_calc_credit($self);
2646             if ( $credit and $credit->amount ne $amount ) {
2647               # Void the old credit.
2648               $error = $credit->void('Package class changed');
2649               if ( $error ) {
2650                 $dbh->rollback if $oldAutoCommit;
2651                 return "$error (adjusting commission credit)";
2652               }
2653             }
2654             # redo the event action to recreate the credit.
2655             local $@ = '';
2656             eval { $part_event->do_action( $self, $cust_event ) };
2657             if ( $@ ) {
2658               $dbh->rollback if $oldAutoCommit;
2659               return $@;
2660             }
2661           } # if $part_event->isa($class)
2662         } # foreach $table
2663       } # foreach $cust_event
2664     } # if $opt{'adjust_commission'}
2665   } # if defined $old_classnum
2666
2667   $dbh->commit if $oldAutoCommit;
2668   '';
2669 }
2670
2671
2672
2673 use Data::Dumper;
2674 sub process_bulk_cust_pkg {
2675   my $job = shift;
2676   my $param = shift;
2677   warn Dumper($param) if $DEBUG;
2678
2679   my $old_part_pkg = qsearchs('part_pkg',
2680                               { pkgpart => $param->{'old_pkgpart'} });
2681   my $new_part_pkg = qsearchs('part_pkg',
2682                               { pkgpart => $param->{'new_pkgpart'} });
2683   die "Must select a new package type\n" unless $new_part_pkg;
2684   #my $keep_dates = $param->{'keep_dates'} || 0;
2685   my $keep_dates = 1; # there is no good reason to turn this off
2686
2687   my $oldAutoCommit = $FS::UID::AutoCommit;
2688   local $FS::UID::AutoCommit = 0;
2689   my $dbh = dbh;
2690
2691   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
2692
2693   my $i = 0;
2694   foreach my $old_cust_pkg ( @cust_pkgs ) {
2695     $i++;
2696     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
2697     if ( $old_cust_pkg->getfield('cancel') ) {
2698       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
2699         $old_cust_pkg->pkgnum."\n"
2700         if $DEBUG;
2701       next;
2702     }
2703     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
2704       if $DEBUG;
2705     my $error = $old_cust_pkg->change(
2706       'pkgpart'     => $param->{'new_pkgpart'},
2707       'keep_dates'  => $keep_dates
2708     );
2709     if ( !ref($error) ) { # change returns the cust_pkg on success
2710       $dbh->rollback;
2711       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
2712     }
2713   }
2714   $dbh->commit if $oldAutoCommit;
2715   return;
2716 }
2717
2718 =item last_bill
2719
2720 Returns the last bill date, or if there is no last bill date, the setup date.
2721 Useful for billing metered services.
2722
2723 =cut
2724
2725 sub last_bill {
2726   my $self = shift;
2727   return $self->setfield('last_bill', $_[0]) if @_;
2728   return $self->getfield('last_bill') if $self->getfield('last_bill');
2729   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
2730                                                   'edate'  => $self->bill,  } );
2731   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
2732 }
2733
2734 =item last_cust_pkg_reason ACTION
2735
2736 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
2737 Returns false if there is no reason or the package is not currenly ACTION'd
2738 ACTION is one of adjourn, susp, cancel, or expire.
2739
2740 =cut
2741
2742 sub last_cust_pkg_reason {
2743   my ( $self, $action ) = ( shift, shift );
2744   my $date = $self->get($action);
2745   qsearchs( {
2746               'table' => 'cust_pkg_reason',
2747               'hashref' => { 'pkgnum' => $self->pkgnum,
2748                              'action' => substr(uc($action), 0, 1),
2749                              'date'   => $date,
2750                            },
2751               'order_by' => 'ORDER BY num DESC LIMIT 1',
2752            } );
2753 }
2754
2755 =item last_reason ACTION
2756
2757 Returns the most recent ACTION FS::reason associated with the package.
2758 Returns false if there is no reason or the package is not currenly ACTION'd
2759 ACTION is one of adjourn, susp, cancel, or expire.
2760
2761 =cut
2762
2763 sub last_reason {
2764   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
2765   $cust_pkg_reason->reason
2766     if $cust_pkg_reason;
2767 }
2768
2769 =item part_pkg
2770
2771 Returns the definition for this billing item, as an FS::part_pkg object (see
2772 L<FS::part_pkg>).
2773
2774 =cut
2775
2776 sub part_pkg {
2777   my $self = shift;
2778   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
2779   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
2780   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
2781 }
2782
2783 =item old_cust_pkg
2784
2785 Returns the cancelled package this package was changed from, if any.
2786
2787 =cut
2788
2789 sub old_cust_pkg {
2790   my $self = shift;
2791   return '' unless $self->change_pkgnum;
2792   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
2793 }
2794
2795 =item change_cust_main
2796
2797 Returns the customter this package was detached to, if any.
2798
2799 =cut
2800
2801 sub change_cust_main {
2802   my $self = shift;
2803   return '' unless $self->change_custnum;
2804   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
2805 }
2806
2807 =item calc_setup
2808
2809 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
2810 item.
2811
2812 =cut
2813
2814 sub calc_setup {
2815   my $self = shift;
2816   $self->part_pkg->calc_setup($self, @_);
2817 }
2818
2819 =item calc_recur
2820
2821 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
2822 item.
2823
2824 =cut
2825
2826 sub calc_recur {
2827   my $self = shift;
2828   $self->part_pkg->calc_recur($self, @_);
2829 }
2830
2831 =item base_setup
2832
2833 Calls the I<base_setup> of the FS::part_pkg object associated with this billing
2834 item.
2835
2836 =cut
2837
2838 sub base_setup {
2839   my $self = shift;
2840   $self->part_pkg->base_setup($self, @_);
2841 }
2842
2843 =item base_recur
2844
2845 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
2846 item.
2847
2848 =cut
2849
2850 sub base_recur {
2851   my $self = shift;
2852   $self->part_pkg->base_recur($self, @_);
2853 }
2854
2855 =item calc_remain
2856
2857 Calls the I<calc_remain> of the FS::part_pkg object associated with this
2858 billing item.
2859
2860 =cut
2861
2862 sub calc_remain {
2863   my $self = shift;
2864   $self->part_pkg->calc_remain($self, @_);
2865 }
2866
2867 =item calc_cancel
2868
2869 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
2870 billing item.
2871
2872 =cut
2873
2874 sub calc_cancel {
2875   my $self = shift;
2876   $self->part_pkg->calc_cancel($self, @_);
2877 }
2878
2879 =item cust_bill_pkg
2880
2881 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
2882
2883 =cut
2884
2885 sub cust_bill_pkg {
2886   my $self = shift;
2887   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
2888 }
2889
2890 =item cust_pkg_detail [ DETAILTYPE ]
2891
2892 Returns any customer package details for this package (see
2893 L<FS::cust_pkg_detail>).
2894
2895 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2896
2897 =cut
2898
2899 sub cust_pkg_detail {
2900   my $self = shift;
2901   my %hash = ( 'pkgnum' => $self->pkgnum );
2902   $hash{detailtype} = shift if @_;
2903   qsearch({
2904     'table'    => 'cust_pkg_detail',
2905     'hashref'  => \%hash,
2906     'order_by' => 'ORDER BY weight, pkgdetailnum',
2907   });
2908 }
2909
2910 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
2911
2912 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
2913
2914 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2915
2916 If there is an error, returns the error, otherwise returns false.
2917
2918 =cut
2919
2920 sub set_cust_pkg_detail {
2921   my( $self, $detailtype, @details ) = @_;
2922
2923   my $oldAutoCommit = $FS::UID::AutoCommit;
2924   local $FS::UID::AutoCommit = 0;
2925   my $dbh = dbh;
2926
2927   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
2928     my $error = $current->delete;
2929     if ( $error ) {
2930       $dbh->rollback if $oldAutoCommit;
2931       return "error removing old detail: $error";
2932     }
2933   }
2934
2935   foreach my $detail ( @details ) {
2936     my $cust_pkg_detail = new FS::cust_pkg_detail {
2937       'pkgnum'     => $self->pkgnum,
2938       'detailtype' => $detailtype,
2939       'detail'     => $detail,
2940     };
2941     my $error = $cust_pkg_detail->insert;
2942     if ( $error ) {
2943       $dbh->rollback if $oldAutoCommit;
2944       return "error adding new detail: $error";
2945     }
2946
2947   }
2948
2949   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2950   '';
2951
2952 }
2953
2954 =item cust_event
2955
2956 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
2957
2958 =cut
2959
2960 #false laziness w/cust_bill.pm
2961 sub cust_event {
2962   my $self = shift;
2963   qsearch({
2964     'table'     => 'cust_event',
2965     'addl_from' => 'JOIN part_event USING ( eventpart )',
2966     'hashref'   => { 'tablenum' => $self->pkgnum },
2967     'extra_sql' => " AND eventtable = 'cust_pkg' ",
2968   });
2969 }
2970
2971 =item num_cust_event
2972
2973 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
2974
2975 =cut
2976
2977 #false laziness w/cust_bill.pm
2978 sub num_cust_event {
2979   my $self = shift;
2980   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
2981   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
2982 }
2983
2984 =item exists_cust_event
2985
2986 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
2987
2988 =cut
2989
2990 sub exists_cust_event {
2991   my $self = shift;
2992   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
2993   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
2994   $row ? $row->[0] : '';
2995 }
2996
2997 sub _from_cust_event_where {
2998   #my $self = shift;
2999   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3000   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3001 }
3002
3003 sub _prep_ex {
3004   my( $self, $sql, @args ) = @_;
3005   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3006   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3007   $sth;
3008 }
3009
3010 =item part_pkg_currency_option OPTIONNAME
3011
3012 Returns a two item list consisting of the currency of this customer, if any,
3013 and a value for the provided option.  If the customer has a currency, the value
3014 is the option value the given name and the currency (see
3015 L<FS::part_pkg_currency>).  Otherwise, if the customer has no currency, is the
3016 regular option value for the given name (see L<FS::part_pkg_option>).
3017
3018 =cut
3019
3020 sub part_pkg_currency_option {
3021   my( $self, $optionname ) = @_;
3022   my $part_pkg = $self->part_pkg;
3023   if ( my $currency = $self->cust_main->currency ) {
3024     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
3025   } else {
3026     ('', $part_pkg->option($optionname) );
3027   }
3028 }
3029
3030 =item cust_svc [ SVCPART ] (old, deprecated usage)
3031
3032 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3033
3034 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3035
3036 Returns the services for this package, as FS::cust_svc objects (see
3037 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3038 spcififed, returns only the matching services.
3039
3040 As an optimization, use the cust_svc_unsorted version if you are not displaying
3041 the results.
3042
3043 =cut
3044
3045 sub cust_svc {
3046   my $self = shift;
3047   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3048   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3049 }
3050
3051 sub cust_svc_unsorted {
3052   my $self = shift;
3053   @{ $self->cust_svc_unsorted_arrayref(@_) };
3054 }
3055
3056 sub cust_svc_unsorted_arrayref {
3057   my $self = shift;
3058
3059   return [] unless $self->num_cust_svc(@_);
3060
3061   my %opt = ();
3062   if ( @_ && $_[0] =~ /^\d+/ ) {
3063     $opt{svcpart} = shift;
3064   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3065     %opt = %{ $_[0] };
3066   } elsif ( @_ ) {
3067     %opt = @_;
3068   }
3069
3070   my %search = (
3071     'table'   => 'cust_svc',
3072     'hashref' => { 'pkgnum' => $self->pkgnum },
3073   );
3074   if ( $opt{svcpart} ) {
3075     $search{hashref}->{svcpart} = $opt{'svcpart'};
3076   }
3077   if ( $opt{'svcdb'} ) {
3078     $search{addl_from} = ' LEFT JOIN part_svc USING ( svcpart ) ';
3079     $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{'svcdb'} );
3080   }
3081
3082   [ qsearch(\%search) ];
3083
3084 }
3085
3086 =item overlimit [ SVCPART ]
3087
3088 Returns the services for this package which have exceeded their
3089 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3090 is specified, return only the matching services.
3091
3092 =cut
3093
3094 sub overlimit {
3095   my $self = shift;
3096   return () unless $self->num_cust_svc(@_);
3097   grep { $_->overlimit } $self->cust_svc(@_);
3098 }
3099
3100 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3101
3102 Returns historical services for this package created before END TIMESTAMP and
3103 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3104 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3105 I<pkg_svc.hidden> flag will be omitted.
3106
3107 =cut
3108
3109 sub h_cust_svc {
3110   my $self = shift;
3111   warn "$me _h_cust_svc called on $self\n"
3112     if $DEBUG;
3113
3114   my ($end, $start, $mode) = @_;
3115
3116   local($FS::Record::qsearch_qualify_columns) = 0;
3117
3118   my @cust_svc = $self->_sort_cust_svc(
3119     [ qsearch( 'h_cust_svc',
3120       { 'pkgnum' => $self->pkgnum, },
3121       FS::h_cust_svc->sql_h_search(@_),
3122     ) ]
3123   );
3124
3125   if ( defined($mode) && $mode eq 'I' ) {
3126     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3127     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3128   } else {
3129     return @cust_svc;
3130   }
3131 }
3132
3133 sub _sort_cust_svc {
3134   my( $self, $arrayref ) = @_;
3135
3136   my $sort =
3137     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3138
3139   my %pkg_svc = map { $_->svcpart => $_ }
3140                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3141
3142   map  { $_->[0] }
3143   sort $sort
3144   map {
3145         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3146         [ $_,
3147           $pkg_svc ? $pkg_svc->primary_svc : '',
3148           $pkg_svc ? $pkg_svc->quantity : 0,
3149         ];
3150       }
3151   @$arrayref;
3152
3153 }
3154
3155 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3156
3157 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3158
3159 Returns the number of services for this package.  Available options are svcpart
3160 and svcdb.  If either is spcififed, returns only the matching services.
3161
3162 =cut
3163
3164 sub num_cust_svc {
3165   my $self = shift;
3166
3167   return $self->{'_num_cust_svc'}
3168     if !scalar(@_)
3169        && exists($self->{'_num_cust_svc'})
3170        && $self->{'_num_cust_svc'} =~ /\d/;
3171
3172   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3173     if $DEBUG > 2;
3174
3175   my %opt = ();
3176   if ( @_ && $_[0] =~ /^\d+/ ) {
3177     $opt{svcpart} = shift;
3178   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3179     %opt = %{ $_[0] };
3180   } elsif ( @_ ) {
3181     %opt = @_;
3182   }
3183
3184   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3185   my $where = ' WHERE pkgnum = ? ';
3186   my @param = ($self->pkgnum);
3187
3188   if ( $opt{'svcpart'} ) {
3189     $where .= ' AND svcpart = ? ';
3190     push @param, $opt{'svcpart'};
3191   }
3192   if ( $opt{'svcdb'} ) {
3193     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3194     $where .= ' AND svcdb = ? ';
3195     push @param, $opt{'svcdb'};
3196   }
3197
3198   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3199   $sth->execute(@param) or die $sth->errstr;
3200   $sth->fetchrow_arrayref->[0];
3201 }
3202
3203 =item available_part_svc
3204
3205 Returns a list of FS::part_svc objects representing services included in this
3206 package but not yet provisioned.  Each FS::part_svc object also has an extra
3207 field, I<num_avail>, which specifies the number of available services.
3208
3209 =cut
3210
3211 sub available_part_svc {
3212   my $self = shift;
3213
3214   my $pkg_quantity = $self->quantity || 1;
3215
3216   grep { $_->num_avail > 0 }
3217     map {
3218           my $part_svc = $_->part_svc;
3219           $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3220             $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3221
3222           # more evil encapsulation breakage
3223           if($part_svc->{'Hash'}{'num_avail'} > 0) {
3224             my @exports = $part_svc->part_export_did;
3225             $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3226           }
3227
3228           $part_svc;
3229         }
3230       $self->part_pkg->pkg_svc;
3231 }
3232
3233 =item part_svc [ OPTION => VALUE ... ]
3234
3235 Returns a list of FS::part_svc objects representing provisioned and available
3236 services included in this package.  Each FS::part_svc object also has the
3237 following extra fields:
3238
3239 =over 4
3240
3241 =item num_cust_svc
3242
3243 (count)
3244
3245 =item num_avail
3246
3247 (quantity - count)
3248
3249 =item cust_pkg_svc
3250
3251 (services) - array reference containing the provisioned services, as cust_svc objects
3252
3253 =back
3254
3255 Accepts two options:
3256
3257 =over 4
3258
3259 =item summarize_size
3260
3261 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3262 is this size or greater.
3263
3264 =item hide_discontinued
3265
3266 If true, will omit looking for services that are no longer avaialble in the
3267 package definition.
3268
3269 =back
3270
3271 =cut
3272
3273 #svcnum
3274 #label -> ($cust_svc->label)[1]
3275
3276 sub part_svc {
3277   my $self = shift;
3278   my %opt = @_;
3279
3280   my $pkg_quantity = $self->quantity || 1;
3281
3282   #XXX some sort of sort order besides numeric by svcpart...
3283   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3284     my $pkg_svc = $_;
3285     my $part_svc = $pkg_svc->part_svc;
3286     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3287     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3288     $part_svc->{'Hash'}{'num_avail'}    =
3289       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3290     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3291         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3292       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3293           && $num_cust_svc >= $opt{summarize_size};
3294     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3295     $part_svc;
3296   } $self->part_pkg->pkg_svc;
3297
3298   unless ( $opt{hide_discontinued} ) {
3299     #extras
3300     push @part_svc, map {
3301       my $part_svc = $_;
3302       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3303       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3304       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3305       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3306         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3307       $part_svc;
3308     } $self->extra_part_svc;
3309   }
3310
3311   @part_svc;
3312
3313 }
3314
3315 =item extra_part_svc
3316
3317 Returns a list of FS::part_svc objects corresponding to services in this
3318 package which are still provisioned but not (any longer) available in the
3319 package definition.
3320
3321 =cut
3322
3323 sub extra_part_svc {
3324   my $self = shift;
3325
3326   my $pkgnum  = $self->pkgnum;
3327   #my $pkgpart = $self->pkgpart;
3328
3329 #  qsearch( {
3330 #    'table'     => 'part_svc',
3331 #    'hashref'   => {},
3332 #    'extra_sql' =>
3333 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3334 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3335 #                       AND pkg_svc.pkgpart = ?
3336 #                       AND quantity > 0
3337 #                 )
3338 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3339 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3340 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3341 #                       AND pkgnum = ?
3342 #                 )",
3343 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3344 #  } );
3345
3346 #seems to benchmark slightly faster... (or did?)
3347
3348   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3349   my $pkgparts = join(',', @pkgparts);
3350
3351   qsearch( {
3352     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3353     #MySQL doesn't grok DISINCT ON
3354     'select'      => 'DISTINCT part_svc.*',
3355     'table'       => 'part_svc',
3356     'addl_from'   =>
3357       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3358                                AND pkg_svc.pkgpart IN ($pkgparts)
3359                                AND quantity > 0
3360                              )
3361        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3362        LEFT JOIN cust_pkg USING ( pkgnum )
3363       ",
3364     'hashref'     => {},
3365     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3366     'extra_param' => [ [$self->pkgnum=>'int'] ],
3367   } );
3368 }
3369
3370 =item status
3371
3372 Returns a short status string for this package, currently:
3373
3374 =over 4
3375
3376 =item on hold
3377
3378 =item not yet billed
3379
3380 =item one-time charge
3381
3382 =item active
3383
3384 =item suspended
3385
3386 =item cancelled
3387
3388 =back
3389
3390 =cut
3391
3392 sub status {
3393   my $self = shift;
3394
3395   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3396
3397   return 'cancelled' if $self->get('cancel');
3398   return 'on hold' if $self->susp && ! $self->setup;
3399   return 'suspended' if $self->susp;
3400   return 'not yet billed' unless $self->setup;
3401   return 'one-time charge' if $freq =~ /^(0|$)/;
3402   return 'active';
3403 }
3404
3405 =item ucfirst_status
3406
3407 Returns the status with the first character capitalized.
3408
3409 =cut
3410
3411 sub ucfirst_status {
3412   ucfirst(shift->status);
3413 }
3414
3415 =item statuses
3416
3417 Class method that returns the list of possible status strings for packages
3418 (see L<the status method|/status>).  For example:
3419
3420   @statuses = FS::cust_pkg->statuses();
3421
3422 =cut
3423
3424 tie my %statuscolor, 'Tie::IxHash',
3425   'on hold'         => 'FF00F5', #brighter purple!
3426   'not yet billed'  => '009999', #teal? cyan?
3427   'one-time charge' => '0000CC', #blue  #'000000',
3428   'active'          => '00CC00',
3429   'suspended'       => 'FF9900',
3430   'cancelled'       => 'FF0000',
3431 ;
3432
3433 sub statuses {
3434   my $self = shift; #could be class...
3435   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3436   #                                    # mayble split btw one-time vs. recur
3437     keys %statuscolor;
3438 }
3439
3440 sub statuscolors {
3441   #my $self = shift;
3442   \%statuscolor;
3443 }
3444
3445 =item statuscolor
3446
3447 Returns a hex triplet color string for this package's status.
3448
3449 =cut
3450
3451 sub statuscolor {
3452   my $self = shift;
3453   $statuscolor{$self->status};
3454 }
3455
3456 =item is_status_delay_cancel
3457
3458 Returns true if part_pkg has option delay_cancel,
3459 cust_pkg status is 'suspended' and expire is set
3460 to cancel package within the next day (or however
3461 many days are set in global config part_pkg-delay_cancel-days.
3462
3463 This is not a real status, this only meant for hacking display
3464 values, because otherwise treating the package as suspended is
3465 really the whole point of the delay_cancel option.
3466
3467 =cut
3468
3469 sub is_status_delay_cancel {
3470   my ($self) = @_;
3471   if ( $self->main_pkgnum and $self->pkglinknum ) {
3472     return $self->main_pkg->is_status_delay_cancel;
3473   }
3474   return 0 unless $self->part_pkg->option('delay_cancel',1);
3475   return 0 unless $self->status eq 'suspended';
3476   return 0 unless $self->expire;
3477   my $conf = new FS::Conf;
3478   my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3479   my $expsecs = 60*60*24*$expdays;
3480   return 0 unless $self->expire < time + $expsecs;
3481   return 1;
3482 }
3483
3484 =item pkg_label
3485
3486 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3487 "pkg - comment" depending on user preference).
3488
3489 =cut
3490
3491 sub pkg_label {
3492   my $self = shift;
3493   my $label = $self->part_pkg->pkg_comment( cust_pkg=>$self, nopkgpart=>1 );
3494   $label = $self->pkgnum. ": $label"
3495     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3496   $label;
3497 }
3498
3499 =item pkg_label_long
3500
3501 Returns a long label for this package, adding the primary service's label to
3502 pkg_label.
3503
3504 =cut
3505
3506 sub pkg_label_long {
3507   my $self = shift;
3508   my $label = $self->pkg_label;
3509   my $cust_svc = $self->primary_cust_svc;
3510   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3511   $label;
3512 }
3513
3514 =item pkg_locale
3515
3516 Returns a customer-localized label for this package.
3517
3518 =cut
3519
3520 sub pkg_locale {
3521   my $self = shift;
3522   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3523 }
3524
3525 =item primary_cust_svc
3526
3527 Returns a primary service (as FS::cust_svc object) if one can be identified.
3528
3529 =cut
3530
3531 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3532
3533 sub primary_cust_svc {
3534   my $self = shift;
3535
3536   my @cust_svc = $self->cust_svc;
3537
3538   return '' unless @cust_svc; #no serivces - irrelevant then
3539
3540   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3541
3542   # primary service as specified in the package definition
3543   # or exactly one service definition with quantity one
3544   my $svcpart = $self->part_pkg->svcpart;
3545   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3546   return $cust_svc[0] if scalar(@cust_svc) == 1;
3547
3548   #couldn't identify one thing..
3549   return '';
3550 }
3551
3552 =item labels
3553
3554 Returns a list of lists, calling the label method for all services
3555 (see L<FS::cust_svc>) of this billing item.
3556
3557 =cut
3558
3559 sub labels {
3560   my $self = shift;
3561   map { [ $_->label ] } $self->cust_svc;
3562 }
3563
3564 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3565
3566 Like the labels method, but returns historical information on services that
3567 were active as of END_TIMESTAMP and (optionally) not cancelled before
3568 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3569 I<pkg_svc.hidden> flag will be omitted.
3570
3571 Returns a list of lists, calling the label method for all (historical) services
3572 (see L<FS::h_cust_svc>) of this billing item.
3573
3574 =cut
3575
3576 sub h_labels {
3577   my $self = shift;
3578   warn "$me _h_labels called on $self\n"
3579     if $DEBUG;
3580   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3581 }
3582
3583 =item labels_short
3584
3585 Like labels, except returns a simple flat list, and shortens long
3586 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3587 identical services to one line that lists the service label and the number of
3588 individual services rather than individual items.
3589
3590 =cut
3591
3592 sub labels_short {
3593   shift->_labels_short( 'labels', @_ );
3594 }
3595
3596 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3597
3598 Like h_labels, except returns a simple flat list, and shortens long
3599 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3600 identical services to one line that lists the service label and the number of
3601 individual services rather than individual items.
3602
3603 =cut
3604
3605 sub h_labels_short {
3606   shift->_labels_short( 'h_labels', @_ );
3607 }
3608
3609 sub _labels_short {
3610   my( $self, $method ) = ( shift, shift );
3611
3612   warn "$me _labels_short called on $self with $method method\n"
3613     if $DEBUG;
3614
3615   my $conf = new FS::Conf;
3616   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
3617
3618   warn "$me _labels_short populating \%labels\n"
3619     if $DEBUG;
3620
3621   my %labels;
3622   #tie %labels, 'Tie::IxHash';
3623   push @{ $labels{$_->[0]} }, $_->[1]
3624     foreach $self->$method(@_);
3625
3626   warn "$me _labels_short populating \@labels\n"
3627     if $DEBUG;
3628
3629   my @labels;
3630   foreach my $label ( keys %labels ) {
3631     my %seen = ();
3632     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
3633     my $num = scalar(@values);
3634     warn "$me _labels_short $num items for $label\n"
3635       if $DEBUG;
3636
3637     if ( $num > $max_same_services ) {
3638       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
3639         if $DEBUG;
3640       push @labels, "$label ($num)";
3641     } else {
3642       if ( $conf->exists('cust_bill-consolidate_services') ) {
3643         warn "$me _labels_short   consolidating services\n"
3644           if $DEBUG;
3645         # push @labels, "$label: ". join(', ', @values);
3646         while ( @values ) {
3647           my $detail = "$label: ";
3648           $detail .= shift(@values). ', '
3649             while @values
3650                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
3651           $detail =~ s/, $//;
3652           push @labels, $detail;
3653         }
3654         warn "$me _labels_short   done consolidating services\n"
3655           if $DEBUG;
3656       } else {
3657         warn "$me _labels_short   adding service data\n"
3658           if $DEBUG;
3659         push @labels, map { "$label: $_" } @values;
3660       }
3661     }
3662   }
3663
3664  @labels;
3665
3666 }
3667
3668 =item cust_main
3669
3670 Returns the parent customer object (see L<FS::cust_main>).
3671
3672 =item balance
3673
3674 Returns the balance for this specific package, when using
3675 experimental package balance.
3676
3677 =cut
3678
3679 sub balance {
3680   my $self = shift;
3681   $self->cust_main->balance_pkgnum( $self->pkgnum );
3682 }
3683
3684 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
3685
3686 =item cust_location
3687
3688 Returns the location object, if any (see L<FS::cust_location>).
3689
3690 =item cust_location_or_main
3691
3692 If this package is associated with a location, returns the locaiton (see
3693 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
3694
3695 =item location_label [ OPTION => VALUE ... ]
3696
3697 Returns the label of the location object (see L<FS::cust_location>).
3698
3699 =cut
3700
3701 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
3702
3703 =item tax_locationnum
3704
3705 Returns the foreign key to a L<FS::cust_location> object for calculating
3706 tax on this package, as determined by the C<tax-pkg_address> and
3707 C<tax-ship_address> configuration flags.
3708
3709 =cut
3710
3711 sub tax_locationnum {
3712   my $self = shift;
3713   my $conf = FS::Conf->new;
3714   if ( $conf->exists('tax-pkg_address') ) {
3715     return $self->locationnum;
3716   }
3717   elsif ( $conf->exists('tax-ship_address') ) {
3718     return $self->cust_main->ship_locationnum;
3719   }
3720   else {
3721     return $self->cust_main->bill_locationnum;
3722   }
3723 }
3724
3725 =item tax_location
3726
3727 Returns the L<FS::cust_location> object for tax_locationnum.
3728
3729 =cut
3730
3731 sub tax_location {
3732   my $self = shift;
3733   my $conf = FS::Conf->new;
3734   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
3735     return FS::cust_location->by_key($self->locationnum);
3736   }
3737   elsif ( $conf->exists('tax-ship_address') ) {
3738     return $self->cust_main->ship_location;
3739   }
3740   else {
3741     return $self->cust_main->bill_location;
3742   }
3743 }
3744
3745 =item seconds_since TIMESTAMP
3746
3747 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
3748 package have been online since TIMESTAMP, according to the session monitor.
3749
3750 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
3751 L<Time::Local> and L<Date::Parse> for conversion functions.
3752
3753 =cut
3754
3755 sub seconds_since {
3756   my($self, $since) = @_;
3757   my $seconds = 0;
3758
3759   foreach my $cust_svc (
3760     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
3761   ) {
3762     $seconds += $cust_svc->seconds_since($since);
3763   }
3764
3765   $seconds;
3766
3767 }
3768
3769 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
3770
3771 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
3772 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
3773 (exclusive).
3774
3775 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3776 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3777 functions.
3778
3779
3780 =cut
3781
3782 sub seconds_since_sqlradacct {
3783   my($self, $start, $end) = @_;
3784
3785   my $seconds = 0;
3786
3787   foreach my $cust_svc (
3788     grep {
3789       my $part_svc = $_->part_svc;
3790       $part_svc->svcdb eq 'svc_acct'
3791         && scalar($part_svc->part_export_usage);
3792     } $self->cust_svc
3793   ) {
3794     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
3795   }
3796
3797   $seconds;
3798
3799 }
3800
3801 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
3802
3803 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
3804 in this package for sessions ending between TIMESTAMP_START (inclusive) and
3805 TIMESTAMP_END
3806 (exclusive).
3807
3808 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3809 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3810 functions.
3811
3812 =cut
3813
3814 sub attribute_since_sqlradacct {
3815   my($self, $start, $end, $attrib) = @_;
3816
3817   my $sum = 0;
3818
3819   foreach my $cust_svc (
3820     grep {
3821       my $part_svc = $_->part_svc;
3822       scalar($part_svc->part_export_usage);
3823     } $self->cust_svc
3824   ) {
3825     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
3826   }
3827
3828   $sum;
3829
3830 }
3831
3832 =item quantity
3833
3834 =cut
3835
3836 sub quantity {
3837   my( $self, $value ) = @_;
3838   if ( defined($value) ) {
3839     $self->setfield('quantity', $value);
3840   }
3841   $self->getfield('quantity') || 1;
3842 }
3843
3844 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
3845
3846 Transfers as many services as possible from this package to another package.
3847
3848 The destination package can be specified by pkgnum by passing an FS::cust_pkg
3849 object.  The destination package must already exist.
3850
3851 Services are moved only if the destination allows services with the correct
3852 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
3853 this option with caution!  No provision is made for export differences
3854 between the old and new service definitions.  Probably only should be used
3855 when your exports for all service definitions of a given svcdb are identical.
3856 (attempt a transfer without it first, to move all possible svcpart-matching
3857 services)
3858
3859 Any services that can't be moved remain in the original package.
3860
3861 Returns an error, if there is one; otherwise, returns the number of services
3862 that couldn't be moved.
3863
3864 =cut
3865
3866 sub transfer {
3867   my ($self, $dest_pkgnum, %opt) = @_;
3868
3869   my $remaining = 0;
3870   my $dest;
3871   my %target;
3872
3873   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
3874     $dest = $dest_pkgnum;
3875     $dest_pkgnum = $dest->pkgnum;
3876   } else {
3877     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
3878   }
3879
3880   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
3881
3882   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
3883     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
3884   }
3885
3886   foreach my $cust_svc ($dest->cust_svc) {
3887     $target{$cust_svc->svcpart}--;
3888   }
3889
3890   my %svcpart2svcparts = ();
3891   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3892     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
3893     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
3894       next if exists $svcpart2svcparts{$svcpart};
3895       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
3896       $svcpart2svcparts{$svcpart} = [
3897         map  { $_->[0] }
3898         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
3899         map {
3900               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
3901                                                    'svcpart' => $_          } );
3902               [ $_,
3903                 $pkg_svc ? $pkg_svc->primary_svc : '',
3904                 $pkg_svc ? $pkg_svc->quantity : 0,
3905               ];
3906             }
3907
3908         grep { $_ != $svcpart }
3909         map  { $_->svcpart }
3910         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
3911       ];
3912       warn "alternates for svcpart $svcpart: ".
3913            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
3914         if $DEBUG;
3915     }
3916   }
3917
3918   my $error;
3919   foreach my $cust_svc ($self->cust_svc) {
3920     my $svcnum = $cust_svc->svcnum;
3921     if($target{$cust_svc->svcpart} > 0
3922        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
3923       $target{$cust_svc->svcpart}--;
3924       my $new = new FS::cust_svc { $cust_svc->hash };
3925       $new->pkgnum($dest_pkgnum);
3926       $error = $new->replace($cust_svc);
3927     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3928       if ( $DEBUG ) {
3929         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
3930         warn "alternates to consider: ".
3931              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
3932       }
3933       my @alternate = grep {
3934                              warn "considering alternate svcpart $_: ".
3935                                   "$target{$_} available in new package\n"
3936                                if $DEBUG;
3937                              $target{$_} > 0;
3938                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
3939       if ( @alternate ) {
3940         warn "alternate(s) found\n" if $DEBUG;
3941         my $change_svcpart = $alternate[0];
3942         $target{$change_svcpart}--;
3943         my $new = new FS::cust_svc { $cust_svc->hash };
3944         $new->svcpart($change_svcpart);
3945         $new->pkgnum($dest_pkgnum);
3946         $error = $new->replace($cust_svc);
3947       } else {
3948         $remaining++;
3949       }
3950     } else {
3951       $remaining++
3952     }
3953     if ( $error ) {
3954       my @label = $cust_svc->label;
3955       return "$label[0] $label[1]: $error";
3956     }
3957   }
3958   return $remaining;
3959 }
3960
3961 =item grab_svcnums SVCNUM, SVCNUM ...
3962
3963 Change the pkgnum for the provided services to this packages.  If there is an
3964 error, returns the error, otherwise returns false.
3965
3966 =cut
3967
3968 sub grab_svcnums {
3969   my $self = shift;
3970   my @svcnum = @_;
3971
3972   my $oldAutoCommit = $FS::UID::AutoCommit;
3973   local $FS::UID::AutoCommit = 0;
3974   my $dbh = dbh;
3975
3976   foreach my $svcnum (@svcnum) {
3977     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
3978       $dbh->rollback if $oldAutoCommit;
3979       return "unknown svcnum $svcnum";
3980     };
3981     $cust_svc->pkgnum( $self->pkgnum );
3982     my $error = $cust_svc->replace;
3983     if ( $error ) {
3984       $dbh->rollback if $oldAutoCommit;
3985       return $error;
3986     }
3987   }
3988
3989   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3990   '';
3991
3992 }
3993
3994 =item reexport
3995
3996 This method is deprecated.  See the I<depend_jobnum> option to the insert and
3997 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
3998
3999 =cut
4000
4001 #looks like this is still used by the order_pkg and change_pkg methods in
4002 # ClientAPI/MyAccount, need to look into those before removing
4003 sub reexport {
4004   my $self = shift;
4005
4006   my $oldAutoCommit = $FS::UID::AutoCommit;
4007   local $FS::UID::AutoCommit = 0;
4008   my $dbh = dbh;
4009
4010   foreach my $cust_svc ( $self->cust_svc ) {
4011     #false laziness w/svc_Common::insert
4012     my $svc_x = $cust_svc->svc_x;
4013     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4014       my $error = $part_export->export_insert($svc_x);
4015       if ( $error ) {
4016         $dbh->rollback if $oldAutoCommit;
4017         return $error;
4018       }
4019     }
4020   }
4021
4022   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4023   '';
4024
4025 }
4026
4027 =item export_pkg_change OLD_CUST_PKG
4028
4029 Calls the "pkg_change" export action for all services attached to this package.
4030
4031 =cut
4032
4033 sub export_pkg_change {
4034   my( $self, $old )  = ( shift, shift );
4035
4036   my $oldAutoCommit = $FS::UID::AutoCommit;
4037   local $FS::UID::AutoCommit = 0;
4038   my $dbh = dbh;
4039
4040   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4041     my $error = $svc_x->export('pkg_change', $self, $old);
4042     if ( $error ) {
4043       $dbh->rollback if $oldAutoCommit;
4044       return $error;
4045     }
4046   }
4047
4048   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4049   '';
4050
4051 }
4052
4053 =item insert_reason
4054
4055 Associates this package with a (suspension or cancellation) reason (see
4056 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4057 L<FS::reason>).
4058
4059 Available options are:
4060
4061 =over 4
4062
4063 =item reason
4064
4065 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4066
4067 =item reason_otaker
4068
4069 the access_user (see L<FS::access_user>) providing the reason
4070
4071 =item date
4072
4073 a unix timestamp
4074
4075 =item action
4076
4077 the action (cancel, susp, adjourn, expire) associated with the reason
4078
4079 =back
4080
4081 If there is an error, returns the error, otherwise returns false.
4082
4083 =cut
4084
4085 sub insert_reason {
4086   my ($self, %options) = @_;
4087
4088   my $otaker = $options{reason_otaker} ||
4089                $FS::CurrentUser::CurrentUser->username;
4090
4091   my $reasonnum;
4092   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4093
4094     $reasonnum = $1;
4095
4096   } elsif ( ref($options{'reason'}) ) {
4097
4098     return 'Enter a new reason (or select an existing one)'
4099       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4100
4101     my $reason = new FS::reason({
4102       'reason_type' => $options{'reason'}->{'typenum'},
4103       'reason'      => $options{'reason'}->{'reason'},
4104     });
4105     my $error = $reason->insert;
4106     return $error if $error;
4107
4108     $reasonnum = $reason->reasonnum;
4109
4110   } else {
4111     return "Unparseable reason: ". $options{'reason'};
4112   }
4113
4114   my $cust_pkg_reason =
4115     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4116                               'reasonnum' => $reasonnum,
4117                               'otaker'    => $otaker,
4118                               'action'    => substr(uc($options{'action'}),0,1),
4119                               'date'      => $options{'date'}
4120                                                ? $options{'date'}
4121                                                : time,
4122                             });
4123
4124   $cust_pkg_reason->insert;
4125 }
4126
4127 =item insert_discount
4128
4129 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4130 inserting a new discount on the fly (see L<FS::discount>).
4131
4132 Available options are:
4133
4134 =over 4
4135
4136 =item discountnum
4137
4138 =back
4139
4140 If there is an error, returns the error, otherwise returns false.
4141
4142 =cut
4143
4144 sub insert_discount {
4145   #my ($self, %options) = @_;
4146   my $self = shift;
4147
4148   my $cust_pkg_discount = new FS::cust_pkg_discount {
4149     'pkgnum'      => $self->pkgnum,
4150     'discountnum' => $self->discountnum,
4151     'months_used' => 0,
4152     'end_date'    => '', #XXX
4153     #for the create a new discount case
4154     '_type'       => $self->discountnum__type,
4155     'amount'      => $self->discountnum_amount,
4156     'percent'     => $self->discountnum_percent,
4157     'months'      => $self->discountnum_months,
4158     'setup'      => $self->discountnum_setup,
4159     #'disabled'    => $self->discountnum_disabled,
4160   };
4161
4162   $cust_pkg_discount->insert;
4163 }
4164
4165 =item set_usage USAGE_VALUE_HASHREF
4166
4167 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4168 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4169 upbytes, downbytes, and totalbytes are appropriate keys.
4170
4171 All svc_accts which are part of this package have their values reset.
4172
4173 =cut
4174
4175 sub set_usage {
4176   my ($self, $valueref, %opt) = @_;
4177
4178   #only svc_acct can set_usage for now
4179   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4180     my $svc_x = $cust_svc->svc_x;
4181     $svc_x->set_usage($valueref, %opt)
4182       if $svc_x->can("set_usage");
4183   }
4184 }
4185
4186 =item recharge USAGE_VALUE_HASHREF
4187
4188 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4189 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4190 upbytes, downbytes, and totalbytes are appropriate keys.
4191
4192 All svc_accts which are part of this package have their values incremented.
4193
4194 =cut
4195
4196 sub recharge {
4197   my ($self, $valueref) = @_;
4198
4199   #only svc_acct can set_usage for now
4200   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4201     my $svc_x = $cust_svc->svc_x;
4202     $svc_x->recharge($valueref)
4203       if $svc_x->can("recharge");
4204   }
4205 }
4206
4207 =item apply_usageprice
4208
4209 =cut
4210
4211 sub apply_usageprice {
4212   my $self = shift;
4213
4214   my $oldAutoCommit = $FS::UID::AutoCommit;
4215   local $FS::UID::AutoCommit = 0;
4216   my $dbh = dbh;
4217
4218   my $error = '';
4219
4220   foreach my $cust_pkg_usageprice ( $self->cust_pkg_usageprice ) {
4221     $error ||= $cust_pkg_usageprice->apply;
4222   }
4223
4224   if ( $error ) {
4225     $dbh->rollback if $oldAutoCommit;
4226     die "error applying part_pkg_usageprice add-ons, pkgnum ". $self->pkgnum.
4227         ": $error\n";
4228   } else {
4229     $dbh->commit if $oldAutoCommit;
4230   }
4231
4232
4233 }
4234
4235 =item cust_pkg_discount
4236
4237 =item cust_pkg_discount_active
4238
4239 =cut
4240
4241 sub cust_pkg_discount_active {
4242   my $self = shift;
4243   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4244 }
4245
4246 =item cust_pkg_usage
4247
4248 Returns a list of all voice usage counters attached to this package.
4249
4250 =item apply_usage OPTIONS
4251
4252 Takes the following options:
4253 - cdr: a call detail record (L<FS::cdr>)
4254 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4255 - minutes: the maximum number of minutes to be charged
4256
4257 Finds available usage minutes for a call of this class, and subtracts
4258 up to that many minutes from the usage pool.  If the usage pool is empty,
4259 and the C<cdr-minutes_priority> global config option is set, minutes may
4260 be taken from other calls as well.  Either way, an allocation record will
4261 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4262 number of minutes of usage applied to the call.
4263
4264 =cut
4265
4266 sub apply_usage {
4267   my ($self, %opt) = @_;
4268   my $cdr = $opt{cdr};
4269   my $rate_detail = $opt{rate_detail};
4270   my $minutes = $opt{minutes};
4271   my $classnum = $rate_detail->classnum;
4272   my $pkgnum = $self->pkgnum;
4273   my $custnum = $self->custnum;
4274
4275   my $oldAutoCommit = $FS::UID::AutoCommit;
4276   local $FS::UID::AutoCommit = 0;
4277   my $dbh = dbh;
4278
4279   my $order = FS::Conf->new->config('cdr-minutes_priority');
4280
4281   my $is_classnum;
4282   if ( $classnum ) {
4283     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4284   } else {
4285     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4286   }
4287   my @usage_recs = qsearch({
4288       'table'     => 'cust_pkg_usage',
4289       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4290                      ' JOIN cust_pkg             USING (pkgnum)'.
4291                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4292       'select'    => 'cust_pkg_usage.*',
4293       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4294                      " ( cust_pkg.custnum = $custnum AND ".
4295                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4296                      $is_classnum . ' AND '.
4297                      " cust_pkg_usage.minutes > 0",
4298       'order_by'  => " ORDER BY priority ASC",
4299   });
4300
4301   my $orig_minutes = $minutes;
4302   my $error;
4303   while (!$error and $minutes > 0 and @usage_recs) {
4304     my $cust_pkg_usage = shift @usage_recs;
4305     $cust_pkg_usage->select_for_update;
4306     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4307         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4308         acctid      => $cdr->acctid,
4309         minutes     => min($cust_pkg_usage->minutes, $minutes),
4310     });
4311     $cust_pkg_usage->set('minutes',
4312       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4313     );
4314     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4315     $minutes -= $cdr_cust_pkg_usage->minutes;
4316   }
4317   if ( $order and $minutes > 0 and !$error ) {
4318     # then try to steal minutes from another call
4319     my %search = (
4320         'table'     => 'cdr_cust_pkg_usage',
4321         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4322                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4323                        ' JOIN cust_pkg              USING (pkgnum)'.
4324                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4325                        ' JOIN cdr                   USING (acctid)',
4326         'select'    => 'cdr_cust_pkg_usage.*',
4327         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4328                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4329                        " ( cust_pkg.custnum = $custnum AND ".
4330                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4331                        " part_pkg_usage_class.classnum = $classnum",
4332         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4333     );
4334     if ( $order eq 'time' ) {
4335       # find CDRs that are using minutes, but have a later startdate
4336       # than this call
4337       my $startdate = $cdr->startdate;
4338       if ($startdate !~ /^\d+$/) {
4339         die "bad cdr startdate '$startdate'";
4340       }
4341       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4342       # minimize needless reshuffling
4343       $search{'order_by'} .= ', cdr.startdate DESC';
4344     } else {
4345       # XXX may not work correctly with rate_time schedules.  Could
4346       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4347       # think...
4348       $search{'addl_from'} .=
4349         ' JOIN rate_detail'.
4350         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4351       if ( $order eq 'rate_high' ) {
4352         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4353                                 $rate_detail->min_charge;
4354         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4355       } elsif ( $order eq 'rate_low' ) {
4356         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4357                                 $rate_detail->min_charge;
4358         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4359       } else {
4360         #  this should really never happen
4361         die "invalid cdr-minutes_priority value '$order'\n";
4362       }
4363     }
4364     my @cdr_usage_recs = qsearch(\%search);
4365     my %reproc_cdrs;
4366     while (!$error and @cdr_usage_recs and $minutes > 0) {
4367       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4368       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4369       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4370       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4371       $cdr_cust_pkg_usage->select_for_update;
4372       $old_cdr->select_for_update;
4373       $cust_pkg_usage->select_for_update;
4374       # in case someone else stole the usage from this CDR
4375       # while waiting for the lock...
4376       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4377       # steal the usage allocation and flag the old CDR for reprocessing
4378       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4379       # if the allocation is more minutes than we need, adjust it...
4380       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4381       if ( $delta > 0 ) {
4382         $cdr_cust_pkg_usage->set('minutes', $minutes);
4383         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4384         $error = $cust_pkg_usage->replace;
4385       }
4386       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4387       $error ||= $cdr_cust_pkg_usage->replace;
4388       # deduct the stolen minutes
4389       $minutes -= $cdr_cust_pkg_usage->minutes;
4390     }
4391     # after all minute-stealing is done, reset the affected CDRs
4392     foreach (values %reproc_cdrs) {
4393       $error ||= $_->set_status('');
4394       # XXX or should we just call $cdr->rate right here?
4395       # it's not like we can create a loop this way, since the min_charge
4396       # or call time has to go monotonically in one direction.
4397       # we COULD get some very deep recursions going, though...
4398     }
4399   } # if $order and $minutes
4400   if ( $error ) {
4401     $dbh->rollback;
4402     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4403   } else {
4404     $dbh->commit if $oldAutoCommit;
4405     return $orig_minutes - $minutes;
4406   }
4407 }
4408
4409 =item supplemental_pkgs
4410
4411 Returns a list of all packages supplemental to this one.
4412
4413 =cut
4414
4415 sub supplemental_pkgs {
4416   my $self = shift;
4417   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4418 }
4419
4420 =item main_pkg
4421
4422 Returns the package that this one is supplemental to, if any.
4423
4424 =cut
4425
4426 sub main_pkg {
4427   my $self = shift;
4428   if ( $self->main_pkgnum ) {
4429     return FS::cust_pkg->by_key($self->main_pkgnum);
4430   }
4431   return;
4432 }
4433
4434 =back
4435
4436 =head1 CLASS METHODS
4437
4438 =over 4
4439
4440 =item recurring_sql
4441
4442 Returns an SQL expression identifying recurring packages.
4443
4444 =cut
4445
4446 sub recurring_sql { "
4447   '0' != ( select freq from part_pkg
4448              where cust_pkg.pkgpart = part_pkg.pkgpart )
4449 "; }
4450
4451 =item onetime_sql
4452
4453 Returns an SQL expression identifying one-time packages.
4454
4455 =cut
4456
4457 sub onetime_sql { "
4458   '0' = ( select freq from part_pkg
4459             where cust_pkg.pkgpart = part_pkg.pkgpart )
4460 "; }
4461
4462 =item ordered_sql
4463
4464 Returns an SQL expression identifying ordered packages (recurring packages not
4465 yet billed).
4466
4467 =cut
4468
4469 sub ordered_sql {
4470    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4471 }
4472
4473 =item active_sql
4474
4475 Returns an SQL expression identifying active packages.
4476
4477 =cut
4478
4479 sub active_sql {
4480   $_[0]->recurring_sql. "
4481   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4482   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4483   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4484 "; }
4485
4486 =item not_yet_billed_sql
4487
4488 Returns an SQL expression identifying packages which have not yet been billed.
4489
4490 =cut
4491
4492 sub not_yet_billed_sql { "
4493       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4494   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4495   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4496 "; }
4497
4498 =item inactive_sql
4499
4500 Returns an SQL expression identifying inactive packages (one-time packages
4501 that are otherwise unsuspended/uncancelled).
4502
4503 =cut
4504
4505 sub inactive_sql { "
4506   ". $_[0]->onetime_sql(). "
4507   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4508   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4509   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4510 "; }
4511
4512 =item on_hold_sql
4513
4514 Returns an SQL expression identifying on-hold packages.
4515
4516 =cut
4517
4518 sub on_hold_sql {
4519   #$_[0]->recurring_sql(). ' AND '.
4520   "
4521         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4522     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4523     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4524   ";
4525 }
4526
4527 =item susp_sql
4528 =item suspended_sql
4529
4530 Returns an SQL expression identifying suspended packages.
4531
4532 =cut
4533
4534 sub suspended_sql { susp_sql(@_); }
4535 sub susp_sql {
4536   #$_[0]->recurring_sql(). ' AND '.
4537   "
4538         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4539     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4540     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4541   ";
4542 }
4543
4544 =item cancel_sql
4545 =item cancelled_sql
4546
4547 Returns an SQL exprression identifying cancelled packages.
4548
4549 =cut
4550
4551 sub cancelled_sql { cancel_sql(@_); }
4552 sub cancel_sql {
4553   #$_[0]->recurring_sql(). ' AND '.
4554   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4555 }
4556
4557 =item status_sql
4558
4559 Returns an SQL expression to give the package status as a string.
4560
4561 =cut
4562
4563 sub status_sql {
4564 "CASE
4565   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4566   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4567   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4568   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4569   WHEN ".onetime_sql()." THEN 'one-time charge'
4570   ELSE 'active'
4571 END"
4572 }
4573
4574 =item fcc_477_count
4575
4576 Returns a list of two package counts.  The first is a count of packages
4577 based on the supplied criteria and the second is the count of residential
4578 packages with those same criteria.  Criteria are specified as in the search
4579 method.
4580
4581 =cut
4582
4583 sub fcc_477_count {
4584   my ($class, $params) = @_;
4585
4586   my $sql_query = $class->search( $params );
4587
4588   my $count_sql = delete($sql_query->{'count_query'});
4589   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
4590     or die "couldn't parse count_sql";
4591
4592   my $count_sth = dbh->prepare($count_sql)
4593     or die "Error preparing $count_sql: ". dbh->errstr;
4594   $count_sth->execute
4595     or die "Error executing $count_sql: ". $count_sth->errstr;
4596   my $count_arrayref = $count_sth->fetchrow_arrayref;
4597
4598   return ( @$count_arrayref );
4599
4600 }
4601
4602 =item tax_locationnum_sql
4603
4604 Returns an SQL expression for the tax location for a package, based
4605 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
4606
4607 =cut
4608
4609 sub tax_locationnum_sql {
4610   my $conf = FS::Conf->new;
4611   if ( $conf->exists('tax-pkg_address') ) {
4612     'cust_pkg.locationnum';
4613   }
4614   elsif ( $conf->exists('tax-ship_address') ) {
4615     'cust_main.ship_locationnum';
4616   }
4617   else {
4618     'cust_main.bill_locationnum';
4619   }
4620 }
4621
4622 =item location_sql
4623
4624 Returns a list: the first item is an SQL fragment identifying matching
4625 packages/customers via location (taking into account shipping and package
4626 address taxation, if enabled), and subsequent items are the parameters to
4627 substitute for the placeholders in that fragment.
4628
4629 =cut
4630
4631 sub location_sql {
4632   my($class, %opt) = @_;
4633   my $ornull = $opt{'ornull'};
4634
4635   my $conf = new FS::Conf;
4636
4637   # '?' placeholders in _location_sql_where
4638   my $x = $ornull ? 3 : 2;
4639   my @bill_param = (
4640     ('district')x3,
4641     ('city')x3,
4642     ('county')x$x,
4643     ('state')x$x,
4644     'country'
4645   );
4646
4647   my $main_where;
4648   my @main_param;
4649   if ( $conf->exists('tax-ship_address') ) {
4650
4651     $main_where = "(
4652          (     ( ship_last IS NULL     OR  ship_last  = '' )
4653            AND ". _location_sql_where('cust_main', '', $ornull ). "
4654          )
4655       OR (       ship_last IS NOT NULL AND ship_last != ''
4656            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
4657          )
4658     )";
4659     #    AND payby != 'COMP'
4660
4661     @main_param = ( @bill_param, @bill_param );
4662
4663   } else {
4664
4665     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
4666     @main_param = @bill_param;
4667
4668   }
4669
4670   my $where;
4671   my @param;
4672   if ( $conf->exists('tax-pkg_address') ) {
4673
4674     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
4675
4676     $where = " (
4677                     ( cust_pkg.locationnum IS     NULL AND $main_where )
4678                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
4679                )
4680              ";
4681     @param = ( @main_param, @bill_param );
4682
4683   } else {
4684
4685     $where = $main_where;
4686     @param = @main_param;
4687
4688   }
4689
4690   ( $where, @param );
4691
4692 }
4693
4694 #subroutine, helper for location_sql
4695 sub _location_sql_where {
4696   my $table  = shift;
4697   my $prefix = @_ ? shift : '';
4698   my $ornull = @_ ? shift : '';
4699
4700 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
4701
4702   $ornull = $ornull ? ' OR ? IS NULL ' : '';
4703
4704   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
4705   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
4706   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
4707
4708   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
4709
4710 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
4711   "
4712         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
4713     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
4714     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
4715     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
4716     AND   $table.${prefix}country  = ?
4717   ";
4718 }
4719
4720 sub _X_show_zero {
4721   my( $self, $what ) = @_;
4722
4723   my $what_show_zero = $what. '_show_zero';
4724   length($self->$what_show_zero())
4725     ? ($self->$what_show_zero() eq 'Y')
4726     : $self->part_pkg->$what_show_zero();
4727 }
4728
4729 =head1 SUBROUTINES
4730
4731 =over 4
4732
4733 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
4734
4735 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
4736 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
4737
4738 CUSTNUM is a customer (see L<FS::cust_main>)
4739
4740 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
4741 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
4742 permitted.
4743
4744 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
4745 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
4746 new billing items.  An error is returned if this is not possible (see
4747 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
4748 parameter.
4749
4750 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
4751 newly-created cust_pkg objects.
4752
4753 REFNUM, if specified, will specify the FS::pkg_referral record to be created
4754 and inserted.  Multiple FS::pkg_referral records can be created by
4755 setting I<refnum> to an array reference of refnums or a hash reference with
4756 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
4757 record will be created corresponding to cust_main.refnum.
4758
4759 =cut
4760
4761 sub order {
4762   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
4763
4764   my $conf = new FS::Conf;
4765
4766   # Transactionize this whole mess
4767   my $oldAutoCommit = $FS::UID::AutoCommit;
4768   local $FS::UID::AutoCommit = 0;
4769   my $dbh = dbh;
4770
4771   my $error;
4772 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
4773 #  return "Customer not found: $custnum" unless $cust_main;
4774
4775   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
4776     if $DEBUG;
4777
4778   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
4779                          @$remove_pkgnum;
4780
4781   my $change = scalar(@old_cust_pkg) != 0;
4782
4783   my %hash = ();
4784   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
4785
4786     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
4787          " to pkgpart ". $pkgparts->[0]. "\n"
4788       if $DEBUG;
4789
4790     my $err_or_cust_pkg =
4791       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
4792                                 'refnum'  => $refnum,
4793                               );
4794
4795     unless (ref($err_or_cust_pkg)) {
4796       $dbh->rollback if $oldAutoCommit;
4797       return $err_or_cust_pkg;
4798     }
4799
4800     push @$return_cust_pkg, $err_or_cust_pkg;
4801     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4802     return '';
4803
4804   }
4805
4806   # Create the new packages.
4807   foreach my $pkgpart (@$pkgparts) {
4808
4809     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
4810
4811     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
4812                                       pkgpart => $pkgpart,
4813                                       refnum  => $refnum,
4814                                       %hash,
4815                                     };
4816     $error = $cust_pkg->insert( 'change' => $change );
4817     push @$return_cust_pkg, $cust_pkg;
4818
4819     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
4820       my $supp_pkg = FS::cust_pkg->new({
4821           custnum => $custnum,
4822           pkgpart => $link->dst_pkgpart,
4823           refnum  => $refnum,
4824           main_pkgnum => $cust_pkg->pkgnum,
4825           %hash,
4826       });
4827       $error ||= $supp_pkg->insert( 'change' => $change );
4828       push @$return_cust_pkg, $supp_pkg;
4829     }
4830
4831     if ($error) {
4832       $dbh->rollback if $oldAutoCommit;
4833       return $error;
4834     }
4835
4836   }
4837   # $return_cust_pkg now contains refs to all of the newly
4838   # created packages.
4839
4840   # Transfer services and cancel old packages.
4841   foreach my $old_pkg (@old_cust_pkg) {
4842
4843     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
4844       if $DEBUG;
4845
4846     foreach my $new_pkg (@$return_cust_pkg) {
4847       $error = $old_pkg->transfer($new_pkg);
4848       if ($error and $error == 0) {
4849         # $old_pkg->transfer failed.
4850         $dbh->rollback if $oldAutoCommit;
4851         return $error;
4852       }
4853     }
4854
4855     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
4856       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
4857       foreach my $new_pkg (@$return_cust_pkg) {
4858         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
4859         if ($error and $error == 0) {
4860           # $old_pkg->transfer failed.
4861         $dbh->rollback if $oldAutoCommit;
4862         return $error;
4863         }
4864       }
4865     }
4866
4867     if ($error > 0) {
4868       # Transfers were successful, but we went through all of the
4869       # new packages and still had services left on the old package.
4870       # We can't cancel the package under the circumstances, so abort.
4871       $dbh->rollback if $oldAutoCommit;
4872       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
4873     }
4874     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
4875     if ($error) {
4876       $dbh->rollback;
4877       return $error;
4878     }
4879   }
4880   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4881   '';
4882 }
4883
4884 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
4885
4886 A bulk change method to change packages for multiple customers.
4887
4888 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
4889 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
4890 permitted.
4891
4892 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
4893 replace.  The services (see L<FS::cust_svc>) are moved to the
4894 new billing items.  An error is returned if this is not possible (see
4895 L<FS::pkg_svc>).
4896
4897 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
4898 newly-created cust_pkg objects.
4899
4900 =cut
4901
4902 sub bulk_change {
4903   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
4904
4905   # Transactionize this whole mess
4906   my $oldAutoCommit = $FS::UID::AutoCommit;
4907   local $FS::UID::AutoCommit = 0;
4908   my $dbh = dbh;
4909
4910   my @errors;
4911   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
4912                          @$remove_pkgnum;
4913
4914   while(scalar(@old_cust_pkg)) {
4915     my @return = ();
4916     my $custnum = $old_cust_pkg[0]->custnum;
4917     my (@remove) = map { $_->pkgnum }
4918                    grep { $_->custnum == $custnum } @old_cust_pkg;
4919     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
4920
4921     my $error = order $custnum, $pkgparts, \@remove, \@return;
4922
4923     push @errors, $error
4924       if $error;
4925     push @$return_cust_pkg, @return;
4926   }
4927
4928   if (scalar(@errors)) {
4929     $dbh->rollback if $oldAutoCommit;
4930     return join(' / ', @errors);
4931   }
4932
4933   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4934   '';
4935 }
4936
4937 # Used by FS::Upgrade to migrate to a new database.
4938 sub _upgrade_data {  # class method
4939   my ($class, %opts) = @_;
4940   $class->_upgrade_otaker(%opts);
4941   my @statements = (
4942     # RT#10139, bug resulting in contract_end being set when it shouldn't
4943   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
4944     # RT#10830, bad calculation of prorate date near end of year
4945     # the date range for bill is December 2009, and we move it forward
4946     # one year if it's before the previous bill date (which it should
4947     # never be)
4948   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
4949   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
4950   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
4951     # RT6628, add order_date to cust_pkg
4952     'update cust_pkg set order_date = (select history_date from h_cust_pkg
4953         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
4954         history_action = \'insert\') where order_date is null',
4955   );
4956   foreach my $sql (@statements) {
4957     my $sth = dbh->prepare($sql);
4958     $sth->execute or die $sth->errstr;
4959   }
4960
4961   # RT31194: supplemental package links that are deleted don't clean up
4962   # linked records
4963   my @pkglinknums = qsearch({
4964       'select'    => 'DISTINCT cust_pkg.pkglinknum',
4965       'table'     => 'cust_pkg',
4966       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
4967       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
4968                         AND part_pkg_link.pkglinknum IS NULL',
4969   });
4970   foreach (@pkglinknums) {
4971     my $pkglinknum = $_->pkglinknum;
4972     warn "cleaning part_pkg_link #$pkglinknum\n";
4973     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
4974     my $error = $part_pkg_link->remove_linked;
4975     die $error if $error;
4976   }
4977 }
4978
4979 =back
4980
4981 =head1 BUGS
4982
4983 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
4984
4985 In sub order, the @pkgparts array (passed by reference) is clobbered.
4986
4987 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
4988 method to pass dates to the recur_prog expression, it should do so.
4989
4990 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
4991 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
4992 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
4993 configuration values.  Probably need a subroutine which decides what to do
4994 based on whether or not we've fetched the user yet, rather than a hash.  See
4995 FS::UID and the TODO.
4996
4997 Now that things are transactional should the check in the insert method be
4998 moved to check ?
4999
5000 =head1 SEE ALSO
5001
5002 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5003 L<FS::pkg_svc>, schema.html from the base documentation
5004
5005 =cut
5006
5007 1;
5008