FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::cust_pkg::Search FS::cust_pkg::API
   3              FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   4              FS::contact_Mixin FS::location_Mixin
   5              FS::m2m_Common FS::option_Common
   6            );
   7
   8 use strict;
   9 use Carp qw(cluck);
  10 use Scalar::Util qw( blessed );
  11 use List::Util qw(min max sum);
  12 use Tie::IxHash;
  13 use Time::Local qw( timelocal timelocal_nocheck );
  14 use MIME::Entity;
  15 use FS::UID qw( dbh driver_name );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_usageprice;
  35 use FS::cust_pkg_discount;
  36 use FS::discount;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 use Data::Dumper;
  42
  43 # temporary fix; remove this once (un)suspend admin notices are cleaned up
  44 use FS::Misc qw(send_email);
  45
  46 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  47 # setup }
  48 # because they load configuration by setting FS::UID::callback (see TODO)
  49 use FS::svc_acct;
  50 use FS::svc_domain;
  51 use FS::svc_www;
  52 use FS::svc_forward;
  53
  54 # for sending cancel emails in sub cancel
  55 use FS::Conf;
  56
  57 our ($disable_agentcheck, $DEBUG, $me, $import) = (0, 0, '[FS::cust_pkg]', 0);
  58
  59 our $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  60
  61 our $cache_enabled = 0;
  62
  63 sub _simplecache {
  64   my( $self, $hashref ) = @_;
  65   if ( $cache_enabled && $hashref->{'pkg'} && $hashref->{'plan'} ) {
  66     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  67   }
  68 }
  69
  70 sub _cache {
  71   my $self = shift;
  72   my ( $hashref, $cache ) = @_;
  73 #  #if ( $hashref->{'pkgpart'} ) {
  74 #  if ( $hashref->{'pkg'} ) {
  75 #    # #@{ $self->{'_pkgnum'} } = ();
  76 #    # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  77 #    # $self->{'_pkgpart'} = $subcache;
  78 #    # #push @{ $self->{'_pkgnum'} },
  79 #    #   FS::part_pkg->new_or_cached($hashref, $subcache);
  80 #    $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  81 #  }
  82   if ( exists $hashref->{'svcnum'} ) {
  83     #@{ $self->{'_pkgnum'} } = ();
  84     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  85     $self->{'_svcnum'} = $subcache;
  86     #push @{ $self->{'_pkgnum'} },
  87     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  88   }
  89 }
  90
  91 =head1 NAME
  92
  93 FS::cust_pkg - Object methods for cust_pkg objects
  94
  95 =head1 SYNOPSIS
  96
  97   use FS::cust_pkg;
  98
  99   $record = new FS::cust_pkg \%hash;
 100   $record = new FS::cust_pkg { 'column' => 'value' };
 101
 102   $error = $record->insert;
 103
 104   $error = $new_record->replace($old_record);
 105
 106   $error = $record->delete;
 107
 108   $error = $record->check;
 109
 110   $error = $record->cancel;
 111
 112   $error = $record->suspend;
 113
 114   $error = $record->unsuspend;
 115
 116   $part_pkg = $record->part_pkg;
 117
 118   @labels = $record->labels;
 119
 120   $seconds = $record->seconds_since($timestamp);
 121
 122   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 123   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 124   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 125   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 126
 127 =head1 DESCRIPTION
 128
 129 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 130 inherits from FS::Record.  The following fields are currently supported:
 131
 132 =over 4
 133
 134 =item pkgnum
 135
 136 Primary key (assigned automatically for new billing items)
 137
 138 =item custnum
 139
 140 Customer (see L<FS::cust_main>)
 141
 142 =item pkgpart
 143
 144 Billing item definition (see L<FS::part_pkg>)
 145
 146 =item locationnum
 147
 148 Optional link to package location (see L<FS::location>)
 149
 150 =item order_date
 151
 152 date package was ordered (also remains same on changes)
 153
 154 =item start_date
 155
 156 date
 157
 158 =item setup
 159
 160 date
 161
 162 =item bill
 163
 164 date (next bill date)
 165
 166 =item last_bill
 167
 168 last bill date
 169
 170 =item adjourn
 171
 172 date
 173
 174 =item susp
 175
 176 date
 177
 178 =item expire
 179
 180 date
 181
 182 =item contract_end
 183
 184 date
 185
 186 =item cancel
 187
 188 date
 189
 190 =item usernum
 191
 192 order taker (see L<FS::access_user>)
 193
 194 =item quantity
 195
 196 If not set, defaults to 1
 197
 198 =item change_date
 199
 200 Date of change from previous package
 201
 202 =item change_pkgnum
 203
 204 Previous pkgnum
 205
 206 =item change_pkgpart
 207
 208 Previous pkgpart
 209
 210 =item change_locationnum
 211
 212 Previous locationnum
 213
 214 =item waive_setup
 215
 216 =item main_pkgnum
 217
 218 The pkgnum of the package that this package is supplemental to, if any.
 219
 220 =item pkglinknum
 221
 222 The package link (L<FS::part_pkg_link>) that defines this supplemental
 223 package, if it is one.
 224
 225 =item change_to_pkgnum
 226
 227 The pkgnum of the package this one will be "changed to" in the future
 228 (on its expiration date).
 229
 230 =back
 231
 232 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 233 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 234 L<Time::Local> and L<Date::Parse> for conversion functions.
 235
 236 =head1 METHODS
 237
 238 =over 4
 239
 240 =item new HASHREF
 241
 242 Create a new billing item.  To add the item to the database, see L<"insert">.
 243
 244 =cut
 245
 246 sub table { 'cust_pkg'; }
 247 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 248 sub cust_unlinked_msg {
 249   my $self = shift;
 250   "WARNING: can't find cust_main.custnum ". $self->custnum.
 251   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 252 }
 253
 254 =item set_initial_timers
 255
 256 If required by the package definition, sets any automatic expire, adjourn,
 257 or contract_end timers to some number of months after the start date
 258 (or setup date, if the package has already been setup). If the package has
 259 a delayed setup fee after a period of "free days", will also set the
 260 start date to the end of that period.
 261
 262 If the package has an automatic transfer rule (C<change_to_pkgnum>), then
 263 this will also order the package and set its start date.
 264
 265 =cut
 266
 267 sub set_initial_timers {
 268   my $self = shift;
 269   my $part_pkg = $self->part_pkg;
 270   my $start = $self->start_date || $self->setup || time;
 271
 272   foreach my $action ( qw(expire adjourn contract_end) ) {
 273     my $months = $part_pkg->get("${action}_months");
 274     if($months and !$self->get($action)) {
 275       $self->set($action, $part_pkg->add_freq($start, $months) );
 276     }
 277   }
 278
 279   # if this package has an expire date and a change_to_pkgpart, set automatic
 280   # package transfer
 281   # (but don't call change_later, as that would call $self->replace, and we're
 282   # probably in the middle of $self->insert right now)
 283   if ( $part_pkg->expire_months and $part_pkg->change_to_pkgpart ) {
 284     if ( $self->change_to_pkgnum ) {
 285       # this can happen if a package is ordered on hold, scheduled for a
 286       # future change _while on hold_, and then released from hold, causing
 287       # the automatic transfer to schedule.
 288       #
 289       # what's correct behavior in that case? I think it's to disallow
 290       # future-changing an on-hold package that has an automatic transfer.
 291       # but if we DO get into this situation, let the manual package change
 292       # win.
 293       warn "pkgnum ".$self->pkgnum.": manual future package change blocks ".
 294            "automatic transfer.\n";
 295     } else {
 296       my $change_to = FS::cust_pkg->new( {
 297           start_date  => $self->get('expire'),
 298           pkgpart     => $part_pkg->change_to_pkgpart,
 299           map { $_ => $self->get($_) }
 300             qw( custnum locationnum quantity refnum salesnum contract_end )
 301       } );
 302       my $error = $change_to->insert;
 303
 304       return $error if $error;
 305       $self->set('change_to_pkgnum', $change_to->pkgnum);
 306     }
 307   }
 308
 309   # if this package has "free days" and delayed setup fee, then
 310   # set start date that many days in the future.
 311   # (this should have been set in the UI, but enforce it here)
 312   if ( $part_pkg->option('free_days',1)
 313        && $part_pkg->option('delay_setup',1)
 314      )
 315   {
 316     $self->start_date( $part_pkg->default_start_date );
 317   }
 318
 319   '';
 320 }
 321
 322 =item insert [ OPTION => VALUE ... ]
 323
 324 Adds this billing item to the database ("Orders" the item).  If there is an
 325 error, returns the error, otherwise returns false.
 326
 327 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 328 will be used to look up the package definition and agent restrictions will be
 329 ignored.
 330
 331 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 332 be created and inserted.  Multiple FS::pkg_referral records can be created by
 333 setting I<refnum> to an array reference of refnums or a hash reference with
 334 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 335 record will be created corresponding to cust_main.refnum.
 336
 337 If the additional field I<cust_pkg_usageprice> is defined, it will be treated
 338 as an arrayref of FS::cust_pkg_usageprice objects, which will be inserted.
 339 (Note that this field cannot be set with a usual ->cust_pkg_usageprice method.
 340 It can be set as part of the hash when creating the object, or with the B<set>
 341 method.)
 342
 343 The following options are available:
 344
 345 =over 4
 346
 347 =item change
 348
 349 If set true, supresses actions that should only be taken for new package
 350 orders.  (Currently this includes: intro periods when delay_setup is on,
 351 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 352
 353 =item options
 354
 355 cust_pkg_option records will be created
 356
 357 =item ticket_subject
 358
 359 a ticket will be added to this customer with this subject
 360
 361 =item ticket_queue
 362
 363 an optional queue name for ticket additions
 364
 365 =item allow_pkgpart
 366
 367 Don't check the legality of the package definition.  This should be used
 368 when performing a package change that doesn't change the pkgpart (i.e.
 369 a location change).
 370
 371 =back
 372
 373 =cut
 374
 375 sub insert {
 376   my( $self, %options ) = @_;
 377
 378   my $oldAutoCommit = $FS::UID::AutoCommit;
 379   local $FS::UID::AutoCommit = 0;
 380   my $dbh = dbh;
 381
 382   my $error;
 383   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 384
 385   my $part_pkg = $self->part_pkg;
 386
 387   if ( ! $import && ! $options{'change'} ) {
 388
 389     # set order date to now
 390     $self->order_date(time) unless ($import && $self->order_date);
 391
 392     # if the package def says to start only on the first of the month:
 393     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 394       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 395       $mon += 1 unless $mday == 1;
 396       until ( $mon < 12 ) { $mon -= 12; $year++; }
 397       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 398     }
 399
 400     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 401       # if the package was ordered on hold:
 402       # - suspend it
 403       # - don't set the start date (it will be started manually)
 404       $self->set('susp', $self->order_date);
 405       $self->set('start_date', '');
 406     } else {
 407       # set expire/adjourn/contract_end timers, and free days, if appropriate
 408       # and automatic package transfer, which can fail, so capture the result
 409       $error = $self->set_initial_timers;
 410     }
 411   } # else this is a package change, and shouldn't have "new package" behavior
 412
 413   $error ||= $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 414   if ( $error ) {
 415     $dbh->rollback if $oldAutoCommit;
 416     return $error;
 417   }
 418
 419   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 420   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 421   $self->process_m2m( 'link_table'   => 'pkg_referral',
 422                       'target_table' => 'part_referral',
 423                       'params'       => $self->refnum,
 424                     );
 425
 426   if ( $self->hashref->{cust_pkg_usageprice} ) {
 427     for my $cust_pkg_usageprice ( @{ $self->hashref->{cust_pkg_usageprice} } ) {
 428       $cust_pkg_usageprice->pkgnum( $self->pkgnum );
 429       my $error = $cust_pkg_usageprice->insert;
 430       if ( $error ) {
 431         $dbh->rollback if $oldAutoCommit;
 432         return $error;
 433       }
 434     }
 435   }
 436
 437   if ( $self->setup_discountnum || $self->recur_discountnum ) {
 438     my $error = $self->insert_discount();
 439     if ( $error ) {
 440       $dbh->rollback if $oldAutoCommit;
 441       return $error;
 442     }
 443   }
 444
 445   my $conf = new FS::Conf;
 446
 447   if ($self->locationnum) {
 448     my @part_export =
 449       map qsearch( 'part_export', {exportnum=>$_} ),
 450         $conf->config('cust_location-exports'); #, $agentnum
 451
 452     foreach my $part_export ( @part_export ) {
 453       my $error = $part_export->export_pkg_location($self); #, @$export_args);
 454       if ( $error ) {
 455         $dbh->rollback if $oldAutoCommit;
 456         return "exporting to ". $part_export->exporttype.
 457                " (transaction rolled back): $error";
 458       }
 459     }
 460   }
 461
 462   if ( ! $import && $conf->config('ticket_system') && $options{ticket_subject} ) {
 463
 464     #this init stuff is still inefficient, but at least its limited to
 465     # the small number (any?) folks using ticket emailing on pkg order
 466
 467     #eval '
 468     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 469     #  use RT;
 470     #';
 471     #die $@ if $@;
 472     #
 473     #RT::LoadConfig();
 474     #RT::Init();
 475     use FS::TicketSystem;
 476     FS::TicketSystem->init();
 477
 478     my $q = new RT::Queue($RT::SystemUser);
 479     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 480     my $t = new RT::Ticket($RT::SystemUser);
 481     my $mime = new MIME::Entity;
 482     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 483     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 484                 Subject => $options{ticket_subject},
 485                 MIMEObj => $mime,
 486               );
 487     $t->AddLink( Type   => 'MemberOf',
 488                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 489                );
 490   }
 491
 492   if (! $import && $conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 493     my $queue = new FS::queue {
 494       'job'     => 'FS::cust_main::queueable_print',
 495     };
 496     $error = $queue->insert(
 497       'custnum'  => $self->custnum,
 498       'template' => 'welcome_letter',
 499     );
 500
 501     if ($error) {
 502       warn "can't send welcome letter: $error";
 503     }
 504
 505   }
 506
 507   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 508   '';
 509
 510 }
 511
 512 =item delete
 513
 514 This method now works but you probably shouldn't use it.
 515
 516 You don't want to delete packages, because there would then be no record
 517 the customer ever purchased the package.  Instead, see the cancel method and
 518 hide cancelled packages.
 519
 520 =cut
 521
 522 # this is still used internally to abort future package changes, so it
 523 # does need to work
 524
 525 sub delete {
 526   my $self = shift;
 527
 528   # The following foreign keys to cust_pkg are not cleaned up here, and will
 529   # cause package deletion to fail:
 530   #
 531   # cust_credit.pkgnum and commission_pkgnum (and cust_credit_void)
 532   # cust_credit_bill.pkgnum
 533   # cust_pay_pending.pkgnum
 534   # cust_pay.pkgnum (and cust_pay_void)
 535   # cust_bill_pay.pkgnum (wtf, shouldn't reference pkgnum)
 536   # cust_pkg_usage.pkgnum
 537   # cust_pkg.uncancel_pkgnum, change_pkgnum, main_pkgnum, and change_to_pkgnum
 538   # rt_field_charge.pkgnum
 539
 540   # cust_svc is handled by canceling the package before deleting it
 541   # cust_pkg_option is handled via option_Common
 542
 543   my $oldAutoCommit = $FS::UID::AutoCommit;
 544   local $FS::UID::AutoCommit = 0;
 545   my $dbh = dbh;
 546
 547   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 548     my $error = $cust_pkg_discount->delete;
 549     if ( $error ) {
 550       $dbh->rollback if $oldAutoCommit;
 551       return $error;
 552     }
 553   }
 554   #cust_bill_pkg_discount?
 555
 556   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 557     my $error = $cust_pkg_detail->delete;
 558     if ( $error ) {
 559       $dbh->rollback if $oldAutoCommit;
 560       return $error;
 561     }
 562   }
 563
 564   foreach my $cust_pkg_reason (
 565     qsearchs( {
 566                 'table' => 'cust_pkg_reason',
 567                 'hashref' => { 'pkgnum' => $self->pkgnum },
 568               }
 569             )
 570   ) {
 571     my $error = $cust_pkg_reason->delete;
 572     if ( $error ) {
 573       $dbh->rollback if $oldAutoCommit;
 574       return $error;
 575     }
 576   }
 577
 578   foreach my $pkg_referral ( $self->pkg_referral ) {
 579     my $error = $pkg_referral->delete;
 580     if ( $error ) {
 581       $dbh->rollback if $oldAutoCommit;
 582       return $error;
 583     }
 584   }
 585
 586   my $error = $self->SUPER::delete(@_);
 587   if ( $error ) {
 588     $dbh->rollback if $oldAutoCommit;
 589     return $error;
 590   }
 591
 592   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 593
 594   '';
 595
 596 }
 597
 598 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 599
 600 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 601 returns the error, otherwise returns false.
 602
 603 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 604
 605 Changing pkgpart may have disasterous effects.  See the order subroutine.
 606
 607 setup and bill are normally updated by calling the bill method of a customer
 608 object (see L<FS::cust_main>).
 609
 610 suspend is normally updated by the suspend and unsuspend methods.
 611
 612 cancel is normally updated by the cancel method (and also the order subroutine
 613 in some cases).
 614
 615 Available options are:
 616
 617 =over 4
 618
 619 =item reason
 620
 621 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 622
 623 =item reason_otaker
 624
 625 the access_user (see L<FS::access_user>) providing the reason
 626
 627 =item options
 628
 629 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 630
 631 =back
 632
 633 =cut
 634
 635 sub replace {
 636   my $new = shift;
 637
 638   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 639               ? shift
 640               : $new->replace_old;
 641
 642   my $options =
 643     ( ref($_[0]) eq 'HASH' )
 644       ? shift
 645       : { @_ };
 646
 647   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 648   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 649
 650   #allow this *sigh*
 651   #return "Can't change setup once it exists!"
 652   #  if $old->getfield('setup') &&
 653   #     $old->getfield('setup') != $new->getfield('setup');
 654
 655   #some logic for bill, susp, cancel?
 656
 657   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 658
 659   my $oldAutoCommit = $FS::UID::AutoCommit;
 660   local $FS::UID::AutoCommit = 0;
 661   my $dbh = dbh;
 662
 663   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 664     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 665       my $error = $new->insert_reason(
 666         'reason'        => $options->{'reason'},
 667         'date'          => $new->$method,
 668         'action'        => $method,
 669         'reason_otaker' => $options->{'reason_otaker'},
 670       );
 671       if ( $error ) {
 672         dbh->rollback if $oldAutoCommit;
 673         return "Error inserting cust_pkg_reason: $error";
 674       }
 675     }
 676   }
 677
 678   #save off and freeze RADIUS attributes for any associated svc_acct records
 679   my @svc_acct = ();
 680   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 681
 682                 #also check for specific exports?
 683                 # to avoid spurious modify export events
 684     @svc_acct = map  { $_->svc_x }
 685                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 686                      $old->cust_svc;
 687
 688     $_->snapshot foreach @svc_acct;
 689
 690   }
 691
 692   my $error =  $new->export_pkg_change($old)
 693             || $new->SUPER::replace( $old,
 694                                      $options->{options}
 695                                        ? $options->{options}
 696                                        : ()
 697                                    );
 698   if ( $error ) {
 699     $dbh->rollback if $oldAutoCommit;
 700     return $error;
 701   }
 702
 703   #for prepaid packages,
 704   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 705   foreach my $old_svc_acct ( @svc_acct ) {
 706     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 707     my $s_error =
 708       $new_svc_acct->replace( $old_svc_acct,
 709                               'depend_jobnum' => $options->{depend_jobnum},
 710                             );
 711     if ( $s_error ) {
 712       $dbh->rollback if $oldAutoCommit;
 713       return $s_error;
 714     }
 715   }
 716
 717   # also run exports if removing locationnum?
 718   #   doesn't seem to happen, and we don't export blank locationnum on insert...
 719   if ($new->locationnum and ($new->locationnum != $old->locationnum)) {
 720     my $conf = new FS::Conf;
 721     my @part_export =
 722       map qsearch( 'part_export', {exportnum=>$_} ),
 723         $conf->config('cust_location-exports'); #, $agentnum
 724
 725     foreach my $part_export ( @part_export ) {
 726       my $error = $part_export->export_pkg_location($new); #, @$export_args);
 727       if ( $error ) {
 728         $dbh->rollback if $oldAutoCommit;
 729         return "exporting to ". $part_export->exporttype.
 730                " (transaction rolled back): $error";
 731       }
 732     }
 733   }
 734
 735   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 736   '';
 737
 738 }
 739
 740 =item check
 741
 742 Checks all fields to make sure this is a valid billing item.  If there is an
 743 error, returns the error, otherwise returns false.  Called by the insert and
 744 replace methods.
 745
 746 =cut
 747
 748 sub check {
 749   my $self = shift;
 750
 751   if ( !$self->locationnum or $self->locationnum == -1 ) {
 752     $self->set('locationnum', $self->cust_main->ship_locationnum);
 753   }
 754
 755   my $error =
 756     $self->ut_numbern('pkgnum')
 757     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 758     || $self->ut_numbern('pkgpart')
 759     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 760     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 761     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 762     || $self->ut_numbern('quantity')
 763     || $self->ut_numbern('start_date')
 764     || $self->ut_numbern('setup')
 765     || $self->ut_numbern('bill')
 766     || $self->ut_numbern('susp')
 767     || $self->ut_numbern('cancel')
 768     || $self->ut_numbern('adjourn')
 769     || $self->ut_numbern('resume')
 770     || $self->ut_numbern('expire')
 771     || $self->ut_numbern('dundate')
 772     || $self->ut_flag('no_auto', [ '', 'Y' ])
 773     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 774     || $self->ut_flag('separate_bill')
 775     || $self->ut_textn('agent_pkgid')
 776     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 777     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 778     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 779     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 780     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 781   ;
 782   return $error if $error;
 783
 784   return "A package with both start date (future start) and setup date (already started) will never bill"
 785     if $self->start_date && $self->setup && ! $upgrade;
 786
 787   return "A future unsuspend date can only be set for a package with a suspend date"
 788     if $self->resume and !$self->susp and !$self->adjourn;
 789
 790   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 791
 792   if ( $self->dbdef_table->column('manual_flag') ) {
 793     $self->manual_flag('') if $self->manual_flag eq ' ';
 794     $self->manual_flag =~ /^([01]?)$/
 795       or return "Illegal manual_flag ". $self->manual_flag;
 796     $self->manual_flag($1);
 797   }
 798
 799   $self->SUPER::check;
 800 }
 801
 802 =item check_pkgpart
 803
 804 Check the pkgpart to make sure it's allowed with the reg_code and/or
 805 promo_code of the package (if present) and with the customer's agent.
 806 Called from C<insert>, unless we are doing a package change that doesn't
 807 affect pkgpart.
 808
 809 =cut
 810
 811 sub check_pkgpart {
 812   my $self = shift;
 813
 814   # my $error = $self->ut_numbern('pkgpart'); # already done
 815
 816   my $error;
 817   if ( $self->reg_code ) {
 818
 819     unless ( grep { $self->pkgpart == $_->pkgpart }
 820              map  { $_->reg_code_pkg }
 821              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 822                                      'agentnum' => $self->cust_main->agentnum })
 823            ) {
 824       return "Unknown registration code";
 825     }
 826
 827   } elsif ( $self->promo_code ) {
 828
 829     my $promo_part_pkg =
 830       qsearchs('part_pkg', {
 831         'pkgpart'    => $self->pkgpart,
 832         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 833       } );
 834     return 'Unknown promotional code' unless $promo_part_pkg;
 835
 836   } else {
 837
 838     unless ( $disable_agentcheck ) {
 839       my $agent =
 840         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 841       return "agent ". $agent->agentnum. ':'. $agent->agent.
 842              " can't purchase pkgpart ". $self->pkgpart
 843         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 844             || $agent->agentnum == $self->part_pkg->agentnum;
 845     }
 846
 847     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 848     return $error if $error;
 849
 850   }
 851
 852   '';
 853
 854 }
 855
 856 =item cancel [ OPTION => VALUE ... ]
 857
 858 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 859 in this package, then cancels the package itself (sets the cancel field to
 860 now).
 861
 862 Available options are:
 863
 864 =over 4
 865
 866 =item quiet - can be set true to supress email cancellation notices.
 867
 868 =item time -  can be set to cancel the package based on a specific future or
 869 historical date.  Using time ensures that the remaining amount is calculated
 870 correctly.  Note however that this is an immediate cancel and just changes
 871 the date.  You are PROBABLY looking to expire the account instead of using
 872 this.
 873
 874 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 875 either a reasonnum of an existing reason, or passing a hashref will create
 876 a new reason.  The hashref should have the following keys: typenum - Reason
 877 type (see L<FS::reason_type>, reason - Text of the new reason.
 878
 879 =item date - can be set to a unix style timestamp to specify when to
 880 cancel (expire)
 881
 882 =item nobill - can be set true to skip billing if it might otherwise be done.
 883
 884 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 885 not credit it.  This must be set (by change()) when changing the package
 886 to a different pkgpart or location, and probably shouldn't be in any other
 887 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 888 be used.
 889
 890 =item no_delay_cancel - prevents delay_cancel behavior
 891 no matter what other options say, for use when changing packages (or any
 892 other time you're really sure you want an immediate cancel)
 893
 894 =back
 895
 896 If there is an error, returns the error, otherwise returns false.
 897
 898 =cut
 899
 900 #NOT DOCUMENTING - this should only be used when calling recursively
 901 #=item delay_cancel - for internal use, to allow proper handling of
 902 #supplemental packages when the main package is flagged to suspend
 903 #before cancelling, probably shouldn't be used otherwise (set the
 904 #corresponding package option instead)
 905
 906 sub cancel {
 907   my( $self, %options ) = @_;
 908   my $error;
 909
 910   # supplemental packages can now be separately canceled, though the UI
 911   # shouldn't permit it
 912   #
 913   ## pass all suspend/cancel actions to the main package
 914   ## (unless the pkglinknum has been removed, then the link is defunct and
 915   ## this package can be canceled on its own)
 916   #if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 917   #  return $self->main_pkg->cancel(%options);
 918   #}
 919
 920   my $conf = new FS::Conf;
 921
 922   warn "cust_pkg::cancel called with options".
 923        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 924     if $DEBUG;
 925
 926   my $oldAutoCommit = $FS::UID::AutoCommit;
 927   local $FS::UID::AutoCommit = 0;
 928   my $dbh = dbh;
 929
 930   my $old = $self->select_for_update;
 931
 932   if ( $old->get('cancel') || $self->get('cancel') ) {
 933     dbh->rollback if $oldAutoCommit;
 934     return "";  # no error
 935   }
 936
 937   # XXX possibly set cancel_time to the expire date?
 938   my $cancel_time = $options{'time'} || time;
 939   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 940   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 941
 942   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 943   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 944        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 945        && !$options{'no_delay_cancel'}
 946   ) {
 947     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 948     my $expsecs = 60*60*24*$expdays;
 949     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 950     $expsecs = $expsecs - $suspfor if $suspfor;
 951     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 952       $delay_cancel = 1;
 953       $date = $cancel_time + $expsecs;
 954     }
 955   }
 956
 957   #race condition: usage could be ongoing until unprovisioned
 958   #resolved by performing a change package instead (which unprovisions) and
 959   #later cancelling
 960   if ( !$options{nobill} && !$date ) {
 961     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 962       my $copy = $self->new({$self->hash});
 963       my $error =
 964         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 965                                 'cancel'   => 1,
 966                                 'time'     => $cancel_time );
 967       warn "Error billing during cancel, custnum ".
 968         #$self->cust_main->custnum. ": $error"
 969         ": $error"
 970         if $error;
 971   }
 972
 973   if ( $options{'reason'} ) {
 974     $error = $self->insert_reason( 'reason' => $options{'reason'},
 975                                    'action' => $date ? 'expire' : 'cancel',
 976                                    'date'   => $date ? $date : $cancel_time,
 977                                    'reason_otaker' => $options{'reason_otaker'},
 978                                  );
 979     if ( $error ) {
 980       dbh->rollback if $oldAutoCommit;
 981       return "Error inserting cust_pkg_reason: $error";
 982     }
 983   }
 984
 985   my %svc_cancel_opt = ();
 986   $svc_cancel_opt{'date'} = $date if $date;
 987   foreach my $cust_svc (
 988     #schwartz
 989     map  { $_->[0] }
 990     sort { $a->[1] <=> $b->[1] }
 991     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 992     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 993   ) {
 994     my $part_svc = $cust_svc->part_svc;
 995     next if ( defined($part_svc) and $part_svc->preserve );
 996     my $error = $cust_svc->cancel( %svc_cancel_opt );
 997
 998     if ( $error ) {
 999       $dbh->rollback if $oldAutoCommit;
1000       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
1001              " cust_svc: $error";
1002     }
1003   }
1004
1005   # if a reasonnum was passed, get the actual reason object so we can check
1006   # unused_credit
1007
1008   my $reason;
1009   if ($options{'reason'} =~ /^\d+$/) {
1010     $reason = FS::reason->by_key($options{'reason'});
1011   }
1012
1013   unless ($date) {
1014     # credit remaining time if any of these are true:
1015     # - unused_credit => 1 was passed (this happens when canceling a package
1016     #   for a package change when unused_credit_change is set)
1017     # - no unused_credit option, and there is a cancel reason, and the cancel
1018     #   reason says to credit the package
1019     # - no unused_credit option, and the package definition says to credit the
1020     #   package on cancellation
1021     my $do_credit;
1022     if ( exists($options{'unused_credit'}) ) {
1023       $do_credit = $options{'unused_credit'};
1024     } elsif ( defined($reason) && $reason->unused_credit ) {
1025       $do_credit = 1;
1026     } else {
1027       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
1028     }
1029     if ( $do_credit ) {
1030       my $error = $self->credit_remaining('cancel', $cancel_time);
1031       if ($error) {
1032         $dbh->rollback if $oldAutoCommit;
1033         return $error;
1034       }
1035     }
1036   } #unless $date
1037
1038   my %hash = $self->hash;
1039   if ( $date ) {
1040     $hash{'expire'} = $date;
1041     if ($delay_cancel) {
1042       # just to be sure these are clear
1043       $hash{'adjourn'} = undef;
1044       $hash{'resume'} = undef;
1045     }
1046   } else {
1047     $hash{'cancel'} = $cancel_time;
1048   }
1049   $hash{'change_custnum'} = $options{'change_custnum'};
1050
1051   # if this is a supplemental package that's lost its part_pkg_link, and it's
1052   # being canceled for real, unlink it completely
1053   if ( !$date and ! $self->pkglinknum ) {
1054     $hash{main_pkgnum} = '';
1055   }
1056
1057   # if there is a future package change scheduled, unlink from it (like
1058   # abort_change) first, then delete it.
1059   $hash{'change_to_pkgnum'} = '';
1060
1061   # save the package state
1062   my $new = new FS::cust_pkg ( \%hash );
1063   $error = $new->replace( $self, options => { $self->options } );
1064
1065   if ( $self->change_to_pkgnum ) {
1066     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
1067     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
1068   }
1069   if ( $error ) {
1070     $dbh->rollback if $oldAutoCommit;
1071     return $error;
1072   }
1073
1074   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1075     $error = $supp_pkg->cancel(%options,
1076       'from_main' => 1,
1077       'date' => $date, #in case it got changed by delay_cancel
1078       'delay_cancel' => $delay_cancel,
1079     );
1080     if ( $error ) {
1081       $dbh->rollback if $oldAutoCommit;
1082       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1083     }
1084   }
1085
1086   if ($delay_cancel && !$options{'from_main'}) {
1087     $error = $new->suspend(
1088       'from_cancel' => 1,
1089       'time'        => $cancel_time
1090     );
1091   }
1092
1093   unless ($date) {
1094     foreach my $usage ( $self->cust_pkg_usage ) {
1095       $error = $usage->delete;
1096       if ( $error ) {
1097         $dbh->rollback if $oldAutoCommit;
1098         return "deleting usage pools: $error";
1099       }
1100     }
1101   }
1102
1103   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1104   return '' if $date; #no errors
1105
1106   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
1107   if ( !$options{'quiet'} &&
1108         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
1109         @invoicing_list ) {
1110     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1111     my $error = '';
1112     if ( $msgnum ) {
1113       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1114       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1115                                     'object'    => $self );
1116     }
1117     #should this do something on errors?
1118   }
1119
1120   ''; #no errors
1121
1122 }
1123
1124 =item cancel_if_expired [ NOW_TIMESTAMP ]
1125
1126 Cancels this package if its expire date has been reached.
1127
1128 =cut
1129
1130 sub cancel_if_expired {
1131   my $self = shift;
1132   my $time = shift || time;
1133   return '' unless $self->expire && $self->expire <= $time;
1134   my $error = $self->cancel;
1135   if ( $error ) {
1136     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1137            $self->custnum. ": $error";
1138   }
1139   '';
1140 }
1141
1142 =item uncancel_svc_x
1143
1144 For cancelled cust_pkg, returns a list of new, uninserted FS::svc_X records
1145 for services that would be inserted by L</uncancel>.  Returned objects also
1146 include the field _h_svc_x, which contains the service history object.
1147
1148 Set pkgnum before inserting.
1149
1150 Accepts the following options:
1151
1152 only_svcnum - arrayref of svcnum, only returns objects for these svcnum
1153 (and only if they would otherwise be returned by this)
1154
1155 =cut
1156
1157 sub uncancel_svc_x {
1158   my ($self, %opt) = @_;
1159
1160   die 'uncancel_svc_x called on a non-cancelled cust_pkg' unless $self->get('cancel');
1161
1162   #find historical services within this timeframe before the package cancel
1163   # (incompatible with "time" option to cust_pkg->cancel?)
1164   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1165                      #            too little? (unprovisioing export delay?)
1166   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1167   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1168
1169   my @svc_x;
1170   foreach my $h_cust_svc (@h_cust_svc) {
1171     next if $opt{'only_svcnum'} && !(grep { $_ == $h_cust_svc->svcnum } @{$opt{'only_svcnum'}});
1172     # filter out services that still exist on this package (ie preserved svcs)
1173     # but keep services that have since been provisioned on another package (for informational purposes)
1174     next if qsearchs('cust_svc',{ 'svcnum' => $h_cust_svc->svcnum, 'pkgnum' => $self->pkgnum });
1175     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1176     next unless $h_svc_x; # this probably doesn't happen, but just in case
1177     (my $table = $h_svc_x->table) =~ s/^h_//;
1178     require "FS/$table.pm";
1179     my $class = "FS::$table";
1180     my $svc_x = $class->new( {
1181       'svcpart' => $h_cust_svc->svcpart,
1182       '_h_svc_x' => $h_svc_x,
1183       map { $_ => $h_svc_x->get($_) } fields($table)
1184     } );
1185
1186     # radius_usergroup
1187     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1188       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1189     }
1190
1191     #these are pretty rare, but should handle them
1192     # - dsl_device (mac addresses)
1193     # - phone_device (mac addresses)
1194     # - dsl_note (ikano notes)
1195     # - domain_record (i.e. restore DNS information w/domains)
1196     # - inventory_item(?) (inventory w/un-cancelling service?)
1197     # - nas (svc_broaband nas stuff)
1198     #this stuff is unused in the wild afaik
1199     # - mailinglistmember
1200     # - router.svcnum?
1201     # - svc_domain.parent_svcnum?
1202     # - acct_snarf (ancient mail fetching config)
1203     # - cgp_rule (communigate)
1204     # - cust_svc_option (used by our Tron stuff)
1205     # - acct_rt_transaction (used by our time worked stuff)
1206
1207     push @svc_x, $svc_x;
1208   }
1209   return @svc_x;
1210 }
1211
1212 =item uncancel_svc_summary
1213
1214 Returns an array of hashrefs, one for each service that could
1215 potentially be reprovisioned by L</uncancel>, with the following keys:
1216
1217 svcpart
1218
1219 svc
1220
1221 uncancel_svcnum
1222
1223 label - from history table if not currently calculable, undefined if it can't be loaded
1224
1225 reprovisionable - 1 if test reprovision succeeded, otherwise 0
1226
1227 num_cust_svc - number of svcs for this svcpart, only if summarizing (see below)
1228
1229 Cannot be run from within a transaction.  Performs inserts
1230 to test the results, and then rolls back the transaction.
1231 Does not perform exports, so does not catch if export would fail.
1232
1233 Also accepts the following options:
1234
1235 no_test_reprovision - skip the test inserts (reprovisionable field will not exist)
1236
1237 summarize_size - if true, returns a single summary record for svcparts with at
1238 least this many svcs, will have key num_cust_svc but not uncancel_svcnum, label or reprovisionable
1239
1240 =cut
1241
1242 sub uncancel_svc_summary {
1243   my ($self, %opt) = @_;
1244
1245   die 'uncancel_svc_summary called on a non-cancelled cust_pkg' unless $self->get('cancel');
1246   die 'uncancel_svc_summary called from within a transaction' unless $FS::UID::AutoCommit;
1247
1248   local $FS::svc_Common::noexport_hack = 1; # very important not to run exports!!!
1249   local $FS::UID::AutoCommit = 0;
1250
1251   # sort by svcpart, to check summarize_size
1252   my $uncancel_svc_x = {};
1253   foreach my $svc_x (sort { $a->{'svcpart'} <=> $b->{'svcpart'} } $self->uncancel_svc_x) {
1254     $uncancel_svc_x->{$svc_x->svcpart} = [] unless $uncancel_svc_x->{$svc_x->svcpart};
1255     push @{$uncancel_svc_x->{$svc_x->svcpart}}, $svc_x;
1256   }
1257
1258   my @out;
1259   foreach my $svcpart (keys %$uncancel_svc_x) {
1260     my @svcpart_svc_x = @{$uncancel_svc_x->{$svcpart}};
1261     if ($opt{'summarize_size'} && (@svcpart_svc_x >= $opt{'summarize_size'})) {
1262       my $svc_x = $svcpart_svc_x[0]; #grab first one for access to $part_svc
1263       my $part_svc = $svc_x->part_svc;
1264       push @out, {
1265         'svcpart'      => $part_svc->svcpart,
1266         'svc'          => $part_svc->svc,
1267         'num_cust_svc' => scalar(@svcpart_svc_x),
1268       };
1269     } else {
1270       foreach my $svc_x (@svcpart_svc_x) {
1271         my $part_svc = $svc_x->part_svc;
1272         my $out = {
1273           'svcpart' => $part_svc->svcpart,
1274           'svc'     => $part_svc->svc,
1275           'uncancel_svcnum' => $svc_x->get('_h_svc_x')->svcnum,
1276         };
1277         $svc_x->pkgnum($self->pkgnum); # provisioning services on a canceled package, will be rolled back
1278         my $insert_error;
1279         unless ($opt{'no_test_reprovision'}) {
1280           # avoid possibly fatal errors from missing linked records
1281           eval { $insert_error = $svc_x->insert };
1282           $insert_error ||= $@;
1283         }
1284         if ($opt{'no_test_reprovision'} or $insert_error) {
1285           # avoid possibly fatal errors from missing linked records
1286           eval { $out->{'label'} = $svc_x->label };
1287           eval { $out->{'label'} = $svc_x->get('_h_svc_x')->label } unless defined($out->{'label'});
1288           $out->{'reprovisionable'} = 0 unless $opt{'no_test_reprovision'};
1289         } else {
1290           $out->{'label'} = $svc_x->label;
1291           $out->{'reprovisionable'} = 1;
1292         }
1293         push @out, $out;
1294       }
1295     }
1296   }
1297
1298   dbh->rollback;
1299   return @out;
1300 }
1301
1302 =item uncancel
1303
1304 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1305 locationnum, (other fields?).  Attempts to re-provision cancelled services
1306 using history information (errors at this stage are not fatal).
1307
1308 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1309
1310 svc_fatal: service provisioning errors are fatal
1311
1312 svc_errors: pass an array reference, will be filled in with any provisioning errors
1313
1314 only_svcnum: arrayref, only attempt to re-provision these cancelled services
1315
1316 main_pkgnum: link the package as a supplemental package of this one.  For
1317 internal use only.
1318
1319 =cut
1320
1321 sub uncancel {
1322   my( $self, %options ) = @_;
1323
1324   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1325   return '' unless $self->get('cancel');
1326
1327   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1328     return $self->main_pkg->uncancel(%options);
1329   }
1330
1331   ##
1332   # Transaction-alize
1333   ##
1334
1335   my $oldAutoCommit = $FS::UID::AutoCommit;
1336   local $FS::UID::AutoCommit = 0;
1337   my $dbh = dbh;
1338
1339   ##
1340   # insert the new package
1341   ##
1342
1343   my $cust_pkg = new FS::cust_pkg {
1344     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1345     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1346     uncancel        => time,
1347     uncancel_pkgnum => $self->pkgnum,
1348     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1349     map { $_ => $self->get($_) } qw(
1350       custnum pkgpart locationnum
1351       setup
1352       susp adjourn resume expire start_date contract_end dundate
1353       change_date change_pkgpart change_locationnum
1354       manual_flag no_auto separate_bill quantity agent_pkgid
1355       recur_show_zero setup_show_zero
1356     ),
1357   };
1358
1359   my $error = $cust_pkg->insert(
1360     'change' => 1, #supresses any referral credit to a referring customer
1361     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1362   );
1363   if ($error) {
1364     $dbh->rollback if $oldAutoCommit;
1365     return $error;
1366   }
1367
1368   ##
1369   # insert services
1370   ##
1371
1372   my @svc_errors;
1373   foreach my $svc_x ($self->uncancel_svc_x('only_svcnum' => $options{'only_svcnum'})) {
1374
1375     $svc_x->pkgnum($cust_pkg->pkgnum);
1376     my $svc_error = $svc_x->insert;
1377
1378     if ( $svc_error ) {
1379       if ( $options{svc_fatal} ) {
1380         $dbh->rollback if $oldAutoCommit;
1381         return $svc_error;
1382       } else {
1383         # if we've failed to insert the svc_x object, svc_Common->insert
1384         # will have removed the cust_svc already.  if not, then both records
1385         # were inserted but we failed for some other reason (export, most
1386         # likely).  in that case, report the error and delete the records.
1387         push @svc_errors, $svc_error;
1388         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1389         if ( $cust_svc ) {
1390           # except if export_insert failed, export_delete probably won't be
1391           # much better
1392           local $FS::svc_Common::noexport_hack = 1;
1393           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1394           if ( $cleanup_error ) { # and if THAT fails, then run away
1395             $dbh->rollback if $oldAutoCommit;
1396             return $cleanup_error;
1397           }
1398         }
1399       } # svc_fatal
1400     } # svc_error
1401   } #foreach uncancel_svc_x
1402
1403   ##
1404   # also move over any services that didn't unprovision at cancellation
1405   ##
1406
1407   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1408     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1409     my $error = $cust_svc->replace;
1410     if ( $error ) {
1411       $dbh->rollback if $oldAutoCommit;
1412       return $error;
1413     }
1414   }
1415
1416   ##
1417   # Uncancel any supplemental packages, and make them supplemental to the
1418   # new one.
1419   ##
1420
1421   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1422     my $new_pkg;
1423     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1424     if ( $error ) {
1425       $dbh->rollback if $oldAutoCommit;
1426       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1427     }
1428   }
1429
1430   ##
1431   # Finish
1432   ##
1433
1434   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1435
1436   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1437   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1438
1439   '';
1440 }
1441
1442 =item unexpire
1443
1444 Cancels any pending expiration (sets the expire field to null)
1445 for this package and any supplemental packages.
1446
1447 If there is an error, returns the error, otherwise returns false.
1448
1449 =cut
1450
1451 sub unexpire {
1452   my( $self ) = @_;
1453   my $error;
1454
1455   my $oldAutoCommit = $FS::UID::AutoCommit;
1456   local $FS::UID::AutoCommit = 0;
1457   my $dbh = dbh;
1458
1459   my $old = $self->select_for_update;
1460
1461   my $pkgnum = $old->pkgnum;
1462   if ( $old->get('cancel') || $self->get('cancel') ) {
1463     dbh->rollback if $oldAutoCommit;
1464     return "Can't unexpire cancelled package $pkgnum";
1465     # or at least it's pointless
1466   }
1467
1468   unless ( $old->get('expire') && $self->get('expire') ) {
1469     dbh->rollback if $oldAutoCommit;
1470     return "";  # no error
1471   }
1472
1473   my %hash = $self->hash;
1474   $hash{'expire'} = '';
1475   my $new = new FS::cust_pkg ( \%hash );
1476   $error = $new->replace( $self, options => { $self->options } );
1477   if ( $error ) {
1478     $dbh->rollback if $oldAutoCommit;
1479     return $error;
1480   }
1481
1482   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1483     $error = $supp_pkg->unexpire;
1484     if ( $error ) {
1485       $dbh->rollback if $oldAutoCommit;
1486       return "unexpiring supplemental pkg#".$supp_pkg->pkgnum.": $error";
1487     }
1488   }
1489
1490   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1491
1492   ''; #no errors
1493
1494 }
1495
1496 =item suspend [ OPTION => VALUE ... ]
1497
1498 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1499 package, then suspends the package itself (sets the susp field to now).
1500
1501 Available options are:
1502
1503 =over 4
1504
1505 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1506 either a reasonnum of an existing reason, or passing a hashref will create
1507 a new reason.  The hashref should have the following keys:
1508 - typenum - Reason type (see L<FS::reason_type>
1509 - reason - Text of the new reason.
1510
1511 =item date - can be set to a unix style timestamp to specify when to
1512 suspend (adjourn)
1513
1514 =item time - can be set to override the current time, for calculation
1515 of final invoices or unused-time credits
1516
1517 =item resume_date - can be set to a time when the package should be
1518 unsuspended.  This may be more convenient than calling C<unsuspend()>
1519 separately.
1520
1521 =item from_main - allows a supplemental package to be suspended, rather
1522 than redirecting the method call to its main package.  For internal use.
1523
1524 =item from_cancel - used when suspending from the cancel method, forces
1525 this to skip everything besides basic suspension.  For internal use.
1526
1527 =back
1528
1529 If there is an error, returns the error, otherwise returns false.
1530
1531 =cut
1532
1533 sub suspend {
1534   my( $self, %options ) = @_;
1535   my $error;
1536
1537   # supplemental packages still can't be separately suspended, but silently
1538   # exit instead of failing or passing the action to the main package (so
1539   # that the "Suspend customer" action doesn't trip over the supplemental
1540   # packages and die)
1541
1542   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1543     return;
1544   }
1545
1546   my $oldAutoCommit = $FS::UID::AutoCommit;
1547   local $FS::UID::AutoCommit = 0;
1548   my $dbh = dbh;
1549
1550   my $old = $self->select_for_update;
1551
1552   my $pkgnum = $old->pkgnum;
1553   if ( $old->get('cancel') || $self->get('cancel') ) {
1554     dbh->rollback if $oldAutoCommit;
1555     return "Can't suspend cancelled package $pkgnum";
1556   }
1557
1558   if ( $old->get('susp') || $self->get('susp') ) {
1559     dbh->rollback if $oldAutoCommit;
1560     return "";  # no error                     # complain on adjourn?
1561   }
1562
1563   my $suspend_time = $options{'time'} || time;
1564   my $date = $options{date} if $options{date}; # adjourn/suspend later
1565   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1566
1567   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1568     dbh->rollback if $oldAutoCommit;
1569     return "Package $pkgnum expires before it would be suspended.";
1570   }
1571
1572   # some false laziness with sub cancel
1573   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1574        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1575     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1576     # make the entire cust_main->bill path recognize 'suspend' and
1577     # 'cancel' separately.
1578     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1579     my $copy = $self->new({$self->hash});
1580     my $error =
1581       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1582                               'cancel'   => 1,
1583                               'time'     => $suspend_time );
1584     warn "Error billing during suspend, custnum ".
1585       #$self->cust_main->custnum. ": $error"
1586       ": $error"
1587       if $error;
1588   }
1589
1590   my $cust_pkg_reason;
1591   if ( $options{'reason'} ) {
1592     $error = $self->insert_reason( 'reason' => $options{'reason'},
1593                                    'action' => $date ? 'adjourn' : 'suspend',
1594                                    'date'   => $date ? $date : $suspend_time,
1595                                    'reason_otaker' => $options{'reason_otaker'},
1596                                  );
1597     if ( $error ) {
1598       dbh->rollback if $oldAutoCommit;
1599       return "Error inserting cust_pkg_reason: $error";
1600     }
1601     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1602         'date'    => $date ? $date : $suspend_time,
1603         'action'  => $date ? 'A' : 'S',
1604         'pkgnum'  => $self->pkgnum,
1605     });
1606   }
1607
1608   # if a reasonnum was passed, get the actual reason object so we can check
1609   # unused_credit
1610   # (passing a reason hashref is still allowed, but it can't be used with
1611   # the fancy behavioral options.)
1612
1613   my $reason;
1614   if ($options{'reason'} =~ /^\d+$/) {
1615     $reason = FS::reason->by_key($options{'reason'});
1616   }
1617
1618   my %hash = $self->hash;
1619   if ( $date ) {
1620     $hash{'adjourn'} = $date;
1621   } else {
1622     $hash{'susp'} = $suspend_time;
1623   }
1624
1625   my $resume_date = $options{'resume_date'} || 0;
1626   if ( $resume_date > ($date || $suspend_time) ) {
1627     $hash{'resume'} = $resume_date;
1628   }
1629
1630   $options{options} ||= {};
1631
1632   my $new = new FS::cust_pkg ( \%hash );
1633   $error = $new->replace( $self, options => { $self->options,
1634                                               %{ $options{options} },
1635                                             }
1636                         );
1637   if ( $error ) {
1638     $dbh->rollback if $oldAutoCommit;
1639     return $error;
1640   }
1641
1642   unless ( $date ) { # then we are suspending now
1643
1644     unless ($options{'from_cancel'}) {
1645       # credit remaining time if appropriate
1646       # (if required by the package def, or the suspend reason)
1647       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1648                           || ( defined($reason) && $reason->unused_credit );
1649
1650       if ( $unused_credit ) {
1651         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1652         my $error = $self->credit_remaining('suspend', $suspend_time);
1653         if ($error) {
1654           $dbh->rollback if $oldAutoCommit;
1655           return $error;
1656         }
1657       }
1658     }
1659
1660     my @cust_svc = qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } );
1661
1662     #attempt ordering ala cust_svc_suspend_cascade (without infinite-looping
1663     # on the circular dep case)
1664     #  (this is too simple for multi-level deps, we need to use something
1665     #   to resolve the DAG properly when possible)
1666     my %svcpart = ();
1667     $svcpart{$_->svcpart} = 0 foreach @cust_svc;
1668     foreach my $svcpart ( keys %svcpart ) {
1669       foreach my $part_svc_link (
1670         FS::part_svc_link->by_agentnum($self->cust_main->agentnum,
1671                                          src_svcpart => $svcpart,
1672                                          link_type => 'cust_svc_suspend_cascade'
1673                                       )
1674       ) {
1675         $svcpart{$part_svc_link->dst_svcpart} = max(
1676           $svcpart{$part_svc_link->dst_svcpart},
1677           $svcpart{$part_svc_link->src_svcpart} + 1
1678         );
1679       }
1680     }
1681     @cust_svc = sort { $svcpart{ $a->svcpart } <=> $svcpart{ $b->svcpart } }
1682                   @cust_svc;
1683
1684     my @labels = ();
1685     foreach my $cust_svc ( @cust_svc ) {
1686       $cust_svc->suspend( 'labels_arrayref' => \@labels );
1687     }
1688
1689     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1690     # and this is not a suspend-before-cancel
1691     if ( $cust_pkg_reason ) {
1692       my $reason_obj = $cust_pkg_reason->reason;
1693       if ( $reason_obj->feepart and
1694            ! $reason_obj->fee_on_unsuspend and
1695            ! $options{'from_cancel'} ) {
1696
1697         # register the need to charge a fee, cust_main->bill will do the rest
1698         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1699           if $DEBUG;
1700         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1701             'pkgreasonnum'  => $cust_pkg_reason->num,
1702             'pkgnum'        => $self->pkgnum,
1703             'feepart'       => $reason->feepart,
1704             'nextbill'      => $reason->fee_hold,
1705         });
1706         $error ||= $cust_pkg_reason_fee->insert;
1707       }
1708     }
1709
1710     my $conf = new FS::Conf;
1711     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1712
1713       my $error = send_email(
1714         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1715                                    #invoice_from ??? well as good as any
1716         'to'      => $conf->config('suspend_email_admin'),
1717         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1718         'body'    => [
1719           "This is an automatic message from your Freeside installation\n",
1720           "informing you that the following customer package has been suspended:\n",
1721           "\n",
1722           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1723           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1724           ( map { "Service : $_\n" } @labels ),
1725         ],
1726         'custnum' => $self->custnum,
1727         'msgtype' => 'admin'
1728       );
1729
1730       if ( $error ) {
1731         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1732              "$error\n";
1733       }
1734
1735     }
1736
1737   }
1738
1739   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1740     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1741     if ( $error ) {
1742       $dbh->rollback if $oldAutoCommit;
1743       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1744     }
1745   }
1746
1747   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1748
1749   ''; #no errors
1750 }
1751
1752 =item credit_remaining MODE TIME
1753
1754 Generate a credit for this package for the time remaining in the current
1755 billing period.  MODE is either "suspend" or "cancel" (determines the
1756 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1757 are mandatory.
1758
1759 =cut
1760
1761 # Implementation note:
1762 #
1763 # If you pkgpart-change a package that has been billed, and it's set to give
1764 # credit on package change, then this method gets called and then the new
1765 # package will have no last_bill date. Therefore the customer will be credited
1766 # only once (per billing period) even if there are multiple package changes.
1767 #
1768 # If you location-change a package that has been billed, this method will NOT
1769 # be called and the new package WILL have the last bill date of the old
1770 # package.
1771 #
1772 # If the new package is then canceled within the same billing cycle,
1773 # credit_remaining needs to run calc_remain on the OLD package to determine
1774 # the amount of unused time to credit.
1775
1776 sub credit_remaining {
1777   # Add a credit for remaining service
1778   my ($self, $mode, $time) = @_;
1779   die 'credit_remaining requires suspend or cancel'
1780     unless $mode eq 'suspend' or $mode eq 'cancel';
1781   die 'no suspend/cancel time' unless $time > 0;
1782
1783   my $conf = FS::Conf->new;
1784   my $reason_type = $conf->config($mode.'_credit_type');
1785
1786   $time ||= time;
1787
1788   my $remain_pkg = $self;
1789   my (@billpkgnums, @amounts, @setuprecurs);
1790
1791   # we may have to walk back past some package changes to get to the
1792   # one that actually has unused time. loop until that happens, or we
1793   # reach the first package in the chain.
1794   while (1) {
1795     my $last_bill = $remain_pkg->get('last_bill') || 0;
1796     my $next_bill = $remain_pkg->get('bill') || 0;
1797     if ( $last_bill > 0         # the package has been billed
1798         and $next_bill > 0      # the package has a next bill date
1799         and $next_bill >= $time # which is in the future
1800     ) {
1801
1802       # Find actual charges for the period ending on or after the cancel
1803       # date.
1804       my @charges = qsearch('cust_bill_pkg', {
1805         pkgnum => $remain_pkg->pkgnum,
1806         edate => {op => '>=', value => $time},
1807         recur => {op => '>' , value => 0},
1808       });
1809
1810       foreach my $cust_bill_pkg (@charges) {
1811         # hack to deal with the weird behavior of edate on package
1812         # cancellation
1813         my $edate = $cust_bill_pkg->edate;
1814         if ( $self->recur_temporality eq 'preceding' ) {
1815           $edate = $self->add_freq($cust_bill_pkg->sdate);
1816         }
1817
1818         # this will also get any package charges that are _entirely_ after
1819         # the cancellation date (can happen with advance billing). in that
1820         # case, use the entire recurring charge:
1821         my $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
1822         my $max_credit = $amount
1823             - $cust_bill_pkg->credited('', '', setuprecur => 'recur') || 0;
1824
1825         # but if the cancellation happens during the interval, prorate it:
1826         # (XXX obey prorate_round_day here?)
1827         if ( $cust_bill_pkg->sdate < $time ) {
1828           $amount = $amount *
1829                       ($edate - $time) / ($edate - $cust_bill_pkg->sdate);
1830         }
1831
1832         # if there are existing credits, don't let the sum of credits exceed
1833         # the recurring charge
1834         $amount = $max_credit if $amount > $max_credit;
1835
1836         $amount = sprintf('%.2f', $amount);
1837
1838         # if no time has been used and/or there are existing line item
1839         # credits, we may end up not needing to credit anything.
1840         if ( $amount > 0 ) {
1841
1842           push @billpkgnums, $cust_bill_pkg->billpkgnum;
1843           push @amounts,     $amount;
1844           push @setuprecurs, 'recur';
1845
1846           warn "Crediting for $amount on package ".$remain_pkg->pkgnum."\n"
1847             if $DEBUG;
1848         }
1849
1850       }
1851
1852       last if @charges;
1853     }
1854
1855     if ( my $changed_from_pkgnum = $remain_pkg->change_pkgnum ) {
1856       $remain_pkg = FS::cust_pkg->by_key($changed_from_pkgnum);
1857     } else {
1858       # the package has really never been billed
1859       return;
1860     }
1861   }
1862
1863   # keep traditional behavior here.
1864   local $@;
1865   my $reason = FS::reason->new_or_existing(
1866     reason  => 'Credit for unused time on '. $self->part_pkg->pkg,
1867     type    => $reason_type,
1868     class   => 'R',
1869   );
1870   if ( $@ ) {
1871     return "failed to set credit reason: $@";
1872   }
1873
1874   my $error = FS::cust_credit->credit_lineitems(
1875     'billpkgnums' => \@billpkgnums,
1876     'setuprecurs' => \@setuprecurs,
1877     'amounts'     => \@amounts,
1878     'custnum'     => $self->custnum,
1879     'date'        => time,
1880     'reasonnum'   => $reason->reasonnum,
1881     'apply'       => 1,
1882     'set_source'  => 1,
1883   );
1884
1885   '';
1886 }
1887
1888 =item unsuspend [ OPTION => VALUE ... ]
1889
1890 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1891 package, then unsuspends the package itself (clears the susp field and the
1892 adjourn field if it is in the past).  If the suspend reason includes an
1893 unsuspension package, that package will be ordered.
1894
1895 Available options are:
1896
1897 =over 4
1898
1899 =item date
1900
1901 Can be set to a date to unsuspend the package in the future (the 'resume'
1902 field).
1903
1904 =item adjust_next_bill
1905
1906 Can be set true to adjust the next bill date forward by
1907 the amount of time the account was inactive.  This was set true by default
1908 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1909 explicitly requested with this option or in the price plan.
1910
1911 =back
1912
1913 If there is an error, returns the error, otherwise returns false.
1914
1915 =cut
1916
1917 sub unsuspend {
1918   my( $self, %opt ) = @_;
1919   my $error;
1920
1921   # pass all suspend/cancel actions to the main package
1922   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1923     return $self->main_pkg->unsuspend(%opt);
1924   }
1925
1926   my $oldAutoCommit = $FS::UID::AutoCommit;
1927   local $FS::UID::AutoCommit = 0;
1928   my $dbh = dbh;
1929
1930   my $old = $self->select_for_update;
1931
1932   my $pkgnum = $old->pkgnum;
1933   if ( $old->get('cancel') || $self->get('cancel') ) {
1934     $dbh->rollback if $oldAutoCommit;
1935     return "Can't unsuspend cancelled package $pkgnum";
1936   }
1937
1938   unless ( $old->get('susp') && $self->get('susp') ) {
1939     $dbh->rollback if $oldAutoCommit;
1940     return "";  # no error                     # complain instead?
1941   }
1942
1943   # handle the case of setting a future unsuspend (resume) date
1944   # and do not continue to actually unsuspend the package
1945   my $date = $opt{'date'};
1946   if ( $date and $date > time ) { # return an error if $date <= time?
1947
1948     if ( $old->get('expire') && $old->get('expire') < $date ) {
1949       $dbh->rollback if $oldAutoCommit;
1950       return "Package $pkgnum expires before it would be unsuspended.";
1951     }
1952
1953     my $new = new FS::cust_pkg { $self->hash };
1954     $new->set('resume', $date);
1955     $error = $new->replace($self, options => $self->options);
1956
1957     if ( $error ) {
1958       $dbh->rollback if $oldAutoCommit;
1959       return $error;
1960     }
1961     else {
1962       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1963       return '';
1964     }
1965
1966   } #if $date
1967
1968   if (!$self->setup) {
1969     # then this package is being released from on-hold status
1970     $error = $self->set_initial_timers;
1971     if ( $error ) {
1972       $dbh->rollback if $oldAutoCommit;
1973       return $error;
1974     }
1975   }
1976
1977   my @labels = ();
1978
1979   foreach my $cust_svc (
1980     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1981   ) {
1982     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1983
1984     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1985       $dbh->rollback if $oldAutoCommit;
1986       return "Illegal svcdb value in part_svc!";
1987     };
1988     my $svcdb = $1;
1989     require "FS/$svcdb.pm";
1990
1991     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1992     if ($svc) {
1993       $error = $svc->unsuspend;
1994       if ( $error ) {
1995         $dbh->rollback if $oldAutoCommit;
1996         return $error;
1997       }
1998       my( $label, $value ) = $cust_svc->label;
1999       push @labels, "$label: $value";
2000     }
2001
2002   }
2003
2004   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
2005   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
2006
2007   my %hash = $self->hash;
2008   my $inactive = time - $hash{'susp'};
2009
2010   my $conf = new FS::Conf;
2011
2012   #adjust the next bill date forward
2013   # increment next bill date if certain conditions are met:
2014   # - it was due to be billed at some point
2015   # - either the global or local config says to do this
2016   my $adjust_bill = 0;
2017   if (
2018        $inactive > 0
2019     && ( $hash{'bill'} || $hash{'setup'} )
2020     && (    $opt{'adjust_next_bill'}
2021          || $conf->exists('unsuspend-always_adjust_next_bill_date')
2022          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
2023        )
2024   ) {
2025     $adjust_bill = 1;
2026   }
2027
2028   # but not if:
2029   # - the package billed during suspension
2030   # - or it was ordered on hold
2031   # - or the customer was credited for the unused time
2032
2033   if ( $self->option('suspend_bill',1)
2034       or ( $self->part_pkg->option('suspend_bill',1)
2035            and ! $self->option('no_suspend_bill',1)
2036          )
2037       or $hash{'order_date'} == $hash{'susp'}
2038   ) {
2039     $adjust_bill = 0;
2040   }
2041
2042   if ( $adjust_bill ) {
2043     if (    $self->part_pkg->option('unused_credit_suspend')
2044          or ( ref($reason) and $reason->unused_credit ) ) {
2045       # then the customer was credited for the unused time before suspending,
2046       # so their next bill should be immediate
2047       $hash{'bill'} = time;
2048     } else {
2049       # add the length of time suspended to the bill date
2050       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
2051     }
2052   }
2053
2054   $hash{'susp'} = '';
2055   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
2056   $hash{'resume'} = '' if !$hash{'adjourn'};
2057   my $new = new FS::cust_pkg ( \%hash );
2058   $error = $new->replace( $self, options => { $self->options } );
2059   if ( $error ) {
2060     $dbh->rollback if $oldAutoCommit;
2061     return $error;
2062   }
2063
2064   my $unsusp_pkg;
2065
2066   if ( $reason ) {
2067     if ( $reason->unsuspend_pkgpart ) {
2068       warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n";
2069       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
2070         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
2071                     " not found.";
2072       my $start_date = $self->cust_main->next_bill_date
2073         if $reason->unsuspend_hold;
2074
2075       if ( $part_pkg ) {
2076         $unsusp_pkg = FS::cust_pkg->new({
2077             'custnum'     => $self->custnum,
2078             'pkgpart'     => $reason->unsuspend_pkgpart,
2079             'start_date'  => $start_date,
2080             'locationnum' => $self->locationnum,
2081             # discount? probably not...
2082         });
2083
2084         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
2085       }
2086     }
2087     # new way, using fees
2088     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
2089       # register the need to charge a fee, cust_main->bill will do the rest
2090       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
2091         if $DEBUG;
2092       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
2093           'pkgreasonnum'  => $cust_pkg_reason->num,
2094           'pkgnum'        => $self->pkgnum,
2095           'feepart'       => $reason->feepart,
2096           'nextbill'      => $reason->fee_hold,
2097       });
2098       $error ||= $cust_pkg_reason_fee->insert;
2099     }
2100
2101     if ( $error ) {
2102       $dbh->rollback if $oldAutoCommit;
2103       return $error;
2104     }
2105   }
2106
2107   if ( $conf->config('unsuspend_email_admin') ) {
2108
2109     my $error = send_email(
2110       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
2111                                  #invoice_from ??? well as good as any
2112       'to'      => $conf->config('unsuspend_email_admin'),
2113       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
2114         "This is an automatic message from your Freeside installation\n",
2115         "informing you that the following customer package has been unsuspended:\n",
2116         "\n",
2117         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
2118         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
2119         ( map { "Service : $_\n" } @labels ),
2120         ($unsusp_pkg ?
2121           "An unsuspension fee was charged: ".
2122             $unsusp_pkg->part_pkg->pkg_comment."\n"
2123           : ''
2124         ),
2125       ],
2126       'custnum' => $self->custnum,
2127       'msgtype' => 'admin',
2128     );
2129
2130     if ( $error ) {
2131       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
2132            "$error\n";
2133     }
2134
2135   }
2136
2137   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
2138     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
2139     if ( $error ) {
2140       $dbh->rollback if $oldAutoCommit;
2141       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
2142     }
2143   }
2144
2145   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2146
2147   ''; #no errors
2148 }
2149
2150 =item unadjourn
2151
2152 Cancels any pending suspension (sets the adjourn field to null)
2153 for this package and any supplemental packages.
2154
2155 If there is an error, returns the error, otherwise returns false.
2156
2157 =cut
2158
2159 sub unadjourn {
2160   my( $self ) = @_;
2161   my $error;
2162
2163   my $oldAutoCommit = $FS::UID::AutoCommit;
2164   local $FS::UID::AutoCommit = 0;
2165   my $dbh = dbh;
2166
2167   my $old = $self->select_for_update;
2168
2169   my $pkgnum = $old->pkgnum;
2170   if ( $old->get('cancel') || $self->get('cancel') ) {
2171     dbh->rollback if $oldAutoCommit;
2172     return "Can't unadjourn cancelled package $pkgnum";
2173     # or at least it's pointless
2174   }
2175
2176   if ( $old->get('susp') || $self->get('susp') ) {
2177     dbh->rollback if $oldAutoCommit;
2178     return "Can't unadjourn suspended package $pkgnum";
2179     # perhaps this is arbitrary
2180   }
2181
2182   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
2183     dbh->rollback if $oldAutoCommit;
2184     return "";  # no error
2185   }
2186
2187   my %hash = $self->hash;
2188   $hash{'adjourn'} = '';
2189   $hash{'resume'}  = '';
2190   my $new = new FS::cust_pkg ( \%hash );
2191   $error = $new->replace( $self, options => { $self->options } );
2192   if ( $error ) {
2193     $dbh->rollback if $oldAutoCommit;
2194     return $error;
2195   }
2196
2197   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
2198     $error = $supp_pkg->unadjourn;
2199     if ( $error ) {
2200       $dbh->rollback if $oldAutoCommit;
2201       return "unadjourning supplemental pkg#".$supp_pkg->pkgnum.": $error";
2202     }
2203   }
2204
2205   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2206
2207   ''; #no errors
2208
2209 }
2210
2211
2212 =item change HASHREF | OPTION => VALUE ...
2213
2214 Changes this package: cancels it and creates a new one, with a different
2215 pkgpart or locationnum or both.  All services are transferred to the new
2216 package (no change will be made if this is not possible).
2217
2218 Options may be passed as a list of key/value pairs or as a hash reference.
2219 Options are:
2220
2221 =over 4
2222
2223 =item locationnum
2224
2225 New locationnum, to change the location for this package.
2226
2227 =item cust_location
2228
2229 New FS::cust_location object, to create a new location and assign it
2230 to this package.
2231
2232 =item cust_main
2233
2234 New FS::cust_main object, to create a new customer and assign the new package
2235 to it.
2236
2237 =item pkgpart
2238
2239 New pkgpart (see L<FS::part_pkg>).
2240
2241 =item refnum
2242
2243 New refnum (see L<FS::part_referral>).
2244
2245 =item quantity
2246
2247 New quantity; if unspecified, the new package will have the same quantity
2248 as the old.
2249
2250 =item cust_pkg
2251
2252 "New" (existing) FS::cust_pkg object.  The package's services and other
2253 attributes will be transferred to this package.
2254
2255 =item keep_dates
2256
2257 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
2258 susp, adjourn, cancel, expire, and contract_end) to the new package.
2259
2260 =item unprotect_svcs
2261
2262 Normally, change() will rollback and return an error if some services
2263 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
2264 If unprotect_svcs is true, this method will transfer as many services as
2265 it can and then unconditionally cancel the old package.
2266
2267 =item contract_end
2268
2269 If specified, sets this value for the contract_end date on the new package
2270 (without regard for keep_dates or the usual date-preservation behavior.)
2271 Will throw an error if defined but false;  the UI doesn't allow editing
2272 this unless it already exists, making removal impossible to undo.
2273
2274 =back
2275
2276 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
2277 cust_pkg must be specified (otherwise, what's the point?)
2278
2279 Returns either the new FS::cust_pkg object or a scalar error.
2280
2281 For example:
2282
2283   my $err_or_new_cust_pkg = $old_cust_pkg->change
2284
2285 =cut
2286
2287 #used by change and change_later
2288 #didn't put with documented check methods because it depends on change-specific opts
2289 #and it also possibly edits the value of opts
2290 sub _check_change {
2291   my $self = shift;
2292   my $opt = shift;
2293   if ( defined($opt->{'contract_end'}) ) {
2294     my $current_contract_end = $self->get('contract_end');
2295     unless ($opt->{'contract_end'}) {
2296       if ($current_contract_end) {
2297         return "Cannot remove contract end date when changing packages";
2298       } else {
2299         #shouldn't even pass this option if there's not a current value
2300         #but can be handled gracefully if the option is empty
2301         warn "Contract end date passed unexpectedly";
2302         delete $opt->{'contract_end'};
2303         return '';
2304       }
2305     }
2306     unless ($current_contract_end) {
2307       #option shouldn't be passed, throw error if it's non-empty
2308       return "Cannot add contract end date when changing packages " . $self->pkgnum;
2309     }
2310   }
2311   return '';
2312 }
2313
2314 #some false laziness w/order
2315 sub change {
2316   my $self = shift;
2317   my $opt = ref($_[0]) ? shift : { @_ };
2318
2319   my $conf = new FS::Conf;
2320
2321   # handle contract_end on cust_pkg same as passed option
2322   if ( $opt->{'cust_pkg'} ) {
2323     $opt->{'contract_end'} = $opt->{'cust_pkg'}->contract_end;
2324     delete $opt->{'contract_end'} unless $opt->{'contract_end'};
2325   }
2326
2327   # check contract_end, prevent adding/removing
2328   my $error = $self->_check_change($opt);
2329   return $error if $error;
2330
2331   # Transactionize this whole mess
2332   my $oldAutoCommit = $FS::UID::AutoCommit;
2333   local $FS::UID::AutoCommit = 0;
2334   my $dbh = dbh;
2335
2336   if ( $opt->{'cust_location'} ) {
2337     $error = $opt->{'cust_location'}->find_or_insert;
2338     if ( $error ) {
2339       $dbh->rollback if $oldAutoCommit;
2340       return "creating location record: $error";
2341     }
2342     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2343   }
2344
2345   # figure out if we're changing pkgpart
2346   if ( $opt->{'cust_pkg'} ) {
2347     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
2348   }
2349
2350   # whether to override pkgpart checking on the new package
2351   my $same_pkgpart = 1;
2352   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2353     $same_pkgpart = 0;
2354   }
2355
2356   # Before going any further here: if the package is still in the pre-setup
2357   # state, it's safe to modify it in place. No need to charge/credit for
2358   # partial period, transfer usage pools, copy invoice details, or change any
2359   # dates. We DO need to "transfer" services (from the package to itself) to
2360   # check their validity on the new pkgpart.
2361   if ( ! $self->setup and ! $opt->{cust_pkg} and ! $opt->{cust_main} ) {
2362     foreach ( qw( locationnum pkgpart quantity refnum salesnum ) ) {
2363       if ( length($opt->{$_}) ) {
2364         $self->set($_, $opt->{$_});
2365       }
2366     }
2367     # almost. if the new pkgpart specifies start/adjourn/expire timers,
2368     # apply those.
2369     if ( !$same_pkgpart ) {
2370       $error ||= $self->set_initial_timers;
2371     }
2372     # but if contract_end was explicitly specified, that overrides all else
2373     $self->set('contract_end', $opt->{'contract_end'})
2374       if $opt->{'contract_end'};
2375
2376     $error ||= $self->replace;
2377     if ( $error ) {
2378       $dbh->rollback if $oldAutoCommit;
2379       return "modifying package: $error";
2380     }
2381
2382     # check/convert services (only on pkgpart change, to avoid surprises
2383     # when editing locations)
2384     # (maybe do this if changing quantity?)
2385     if ( !$same_pkgpart ) {
2386
2387       $error = $self->transfer($self);
2388
2389       if ( $error and $error == 0 ) {
2390         $error = "transferring $error";
2391       } elsif ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2392         warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2393         $error = $self->transfer($self, 'change_svcpart'=>1 );
2394         if ($error and $error == 0) {
2395           $error = "converting $error";
2396         }
2397       }
2398
2399       if ($error > 0) {
2400         $error = "unable to transfer all services";
2401       }
2402
2403       if ( $error ) {
2404         $dbh->rollback if $oldAutoCommit;
2405         return $error;
2406       }
2407
2408     } # done transferring services
2409
2410     $dbh->commit if $oldAutoCommit;
2411     return $self;
2412
2413   }
2414
2415   my %hash = ();
2416
2417   my $time = time;
2418
2419   $hash{'setup'} = $time if $self->get('setup');
2420
2421   $hash{'change_date'} = $time;
2422   $hash{"change_$_"}  = $self->$_()
2423     foreach qw( pkgnum pkgpart locationnum );
2424
2425   my $unused_credit = 0;
2426   my $keep_dates = $opt->{'keep_dates'};
2427
2428   # Special case.  If the pkgpart is changing, and the customer is going to be
2429   # credited for remaining time, don't keep setup, bill, or last_bill dates,
2430   # and DO pass the flag to cancel() to credit the customer.  If the old
2431   # package had a setup date, set the new package's setup to the package
2432   # change date so that it has the same status as before.
2433   if ( $opt->{'pkgpart'}
2434        and $opt->{'pkgpart'} != $self->pkgpart
2435        and $self->part_pkg->option('unused_credit_change', 1) ) {
2436     $unused_credit = 1;
2437     $keep_dates = 0;
2438     $hash{'last_bill'} = '';
2439     $hash{'bill'} = '';
2440   }
2441
2442   if ( $keep_dates ) {
2443     foreach my $date ( qw(setup bill last_bill) ) {
2444       $hash{$date} = $self->getfield($date);
2445     }
2446   }
2447   # always keep the following dates
2448   foreach my $date (qw(order_date susp adjourn cancel expire resume
2449                     start_date contract_end)) {
2450     $hash{$date} = $self->getfield($date);
2451   }
2452   # but if contract_end was explicitly specified, that overrides all else
2453   $hash{'contract_end'} = $opt->{'contract_end'}
2454     if $opt->{'contract_end'};
2455
2456   # allow $opt->{'locationnum'} = '' to specifically set it to null
2457   # (i.e. customer default location)
2458   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2459
2460   # usually this doesn't matter.  the two cases where it does are:
2461   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2462   # and
2463   # 2. (more importantly) changing a package before it's billed
2464   $hash{'waive_setup'} = $self->waive_setup;
2465
2466   # if this package is scheduled for a future package change, preserve that
2467   $hash{'change_to_pkgnum'} = $self->change_to_pkgnum;
2468
2469   my $custnum = $self->custnum;
2470   if ( $opt->{cust_main} ) {
2471     my $cust_main = $opt->{cust_main};
2472     unless ( $cust_main->custnum ) {
2473       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2474       if ( $error ) {
2475         $dbh->rollback if $oldAutoCommit;
2476         return "inserting customer record: $error";
2477       }
2478     }
2479     $custnum = $cust_main->custnum;
2480   }
2481
2482   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2483
2484   my $cust_pkg;
2485   if ( $opt->{'cust_pkg'} ) {
2486     # The target package already exists; update it to show that it was
2487     # changed from this package.
2488     $cust_pkg = $opt->{'cust_pkg'};
2489
2490     # follow all the above rules for date changes, etc.
2491     foreach (keys %hash) {
2492       $cust_pkg->set($_, $hash{$_});
2493     }
2494     # except those that implement the future package change behavior
2495     foreach (qw(change_to_pkgnum start_date expire)) {
2496       $cust_pkg->set($_, '');
2497     }
2498
2499     $error = $cust_pkg->replace;
2500
2501   } else {
2502     # Create the new package.
2503     $cust_pkg = new FS::cust_pkg {
2504       custnum     => $custnum,
2505       locationnum => $opt->{'locationnum'},
2506       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2507           qw( pkgpart quantity refnum salesnum )
2508       ),
2509       %hash,
2510     };
2511     $error = $cust_pkg->insert( 'change' => 1,
2512                                 'allow_pkgpart' => $same_pkgpart );
2513   }
2514   if ($error) {
2515     $dbh->rollback if $oldAutoCommit;
2516     return "inserting new package: $error";
2517   }
2518
2519   # Transfer services and cancel old package.
2520   # Enforce service limits only if this is a pkgpart change.
2521   local $FS::cust_svc::ignore_quantity;
2522   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2523   $error = $self->transfer($cust_pkg);
2524   if ($error and $error == 0) {
2525     # $old_pkg->transfer failed.
2526     $dbh->rollback if $oldAutoCommit;
2527     return "transferring $error";
2528   }
2529
2530   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2531     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2532     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2533     if ($error and $error == 0) {
2534       # $old_pkg->transfer failed.
2535       $dbh->rollback if $oldAutoCommit;
2536       return "converting $error";
2537     }
2538   }
2539
2540   # We set unprotect_svcs when executing a "future package change".  It's
2541   # not a user-interactive operation, so returning an error means the
2542   # package change will just fail.  Rather than have that happen, we'll
2543   # let leftover services be deleted.
2544   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2545     # Transfers were successful, but we still had services left on the old
2546     # package.  We can't change the package under this circumstances, so abort.
2547     $dbh->rollback if $oldAutoCommit;
2548     return "unable to transfer all services";
2549   }
2550
2551   #reset usage if changing pkgpart
2552   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2553   if ($self->pkgpart != $cust_pkg->pkgpart) {
2554     my $part_pkg = $cust_pkg->part_pkg;
2555     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2556                                                  ? ()
2557                                                  : ( 'null' => 1 )
2558                                    )
2559       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2560
2561     if ($error) {
2562       $dbh->rollback if $oldAutoCommit;
2563       return "setting usage values: $error";
2564     }
2565   } else {
2566     # if NOT changing pkgpart, transfer any usage pools over
2567     foreach my $usage ($self->cust_pkg_usage) {
2568       $usage->set('pkgnum', $cust_pkg->pkgnum);
2569       $error = $usage->replace;
2570       if ( $error ) {
2571         $dbh->rollback if $oldAutoCommit;
2572         return "transferring usage pools: $error";
2573       }
2574     }
2575   }
2576
2577   # transfer usage pricing add-ons, if we're not changing pkgpart or if they were specified
2578   if ( $same_pkgpart || $opt->{'cust_pkg_usageprice'}) {
2579     my @old_cust_pkg_usageprice;
2580     if ($opt->{'cust_pkg_usageprice'}) {
2581       @old_cust_pkg_usageprice = @{ $opt->{'cust_pkg_usageprice'} };
2582     } else {
2583       @old_cust_pkg_usageprice = $self->cust_pkg_usageprice;
2584     }
2585     foreach my $old_cust_pkg_usageprice (@old_cust_pkg_usageprice) {
2586       my $new_cust_pkg_usageprice = new FS::cust_pkg_usageprice {
2587         'pkgnum'         => $cust_pkg->pkgnum,
2588         'usagepricepart' => $old_cust_pkg_usageprice->usagepricepart,
2589         'quantity'       => $old_cust_pkg_usageprice->quantity,
2590       };
2591       $error = $new_cust_pkg_usageprice->insert;
2592       if ( $error ) {
2593         $dbh->rollback if $oldAutoCommit;
2594         return "Error transferring usage pricing add-on: $error";
2595       }
2596     }
2597   }
2598
2599   # transfer discounts, if we're not changing pkgpart
2600   if ( $same_pkgpart ) {
2601     foreach my $old_discount ($self->cust_pkg_discount_active) {
2602       # don't remove the old discount, we may still need to bill that package.
2603       my $new_discount = new FS::cust_pkg_discount {
2604         'pkgnum'      => $cust_pkg->pkgnum,
2605         'discountnum' => $old_discount->discountnum,
2606         'months_used' => $old_discount->months_used,
2607       };
2608       $error = $new_discount->insert;
2609       if ( $error ) {
2610         $dbh->rollback if $oldAutoCommit;
2611         return "transferring discounts: $error";
2612       }
2613     }
2614   }
2615
2616   # transfer (copy) invoice details
2617   foreach my $detail ($self->cust_pkg_detail) {
2618     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2619     $new_detail->set('pkgdetailnum', '');
2620     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2621     $error = $new_detail->insert;
2622     if ( $error ) {
2623       $dbh->rollback if $oldAutoCommit;
2624       return "transferring package notes: $error";
2625     }
2626   }
2627
2628   # transfer scheduled expire/adjourn reasons
2629   foreach my $action ('expire', 'adjourn') {
2630     if ( $cust_pkg->get($action) ) {
2631       my $reason = $self->last_cust_pkg_reason($action);
2632       if ( $reason ) {
2633         $reason->set('pkgnum', $cust_pkg->pkgnum);
2634         $error = $reason->replace;
2635         if ( $error ) {
2636           $dbh->rollback if $oldAutoCommit;
2637           return "transferring $action reason: $error";
2638         }
2639       }
2640     }
2641   }
2642
2643   my @new_supp_pkgs;
2644
2645   if ( !$opt->{'cust_pkg'} ) {
2646     # Order any supplemental packages.
2647     my $part_pkg = $cust_pkg->part_pkg;
2648     my @old_supp_pkgs = $self->supplemental_pkgs;
2649     foreach my $link ($part_pkg->supp_part_pkg_link) {
2650       my $old;
2651       foreach (@old_supp_pkgs) {
2652         if ($_->pkgpart == $link->dst_pkgpart) {
2653           $old = $_;
2654           $_->pkgpart(0); # so that it can't match more than once
2655         }
2656         last if $old;
2657       }
2658       # false laziness with FS::cust_main::Packages::order_pkg
2659       my $new = FS::cust_pkg->new({
2660           pkgpart       => $link->dst_pkgpart,
2661           pkglinknum    => $link->pkglinknum,
2662           custnum       => $custnum,
2663           main_pkgnum   => $cust_pkg->pkgnum,
2664           locationnum   => $cust_pkg->locationnum,
2665           start_date    => $cust_pkg->start_date,
2666           order_date    => $cust_pkg->order_date,
2667           expire        => $cust_pkg->expire,
2668           adjourn       => $cust_pkg->adjourn,
2669           contract_end  => $cust_pkg->contract_end,
2670           refnum        => $cust_pkg->refnum,
2671           discountnum   => $cust_pkg->discountnum,
2672           waive_setup   => $cust_pkg->waive_setup,
2673       });
2674       if ( $old and $opt->{'keep_dates'} ) {
2675         foreach (qw(setup bill last_bill)) {
2676           $new->set($_, $old->get($_));
2677         }
2678       }
2679       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2680       # transfer services
2681       if ( $old ) {
2682         $error ||= $old->transfer($new);
2683       }
2684       if ( $error and $error > 0 ) {
2685         # no reason why this should ever fail, but still...
2686         $error = "Unable to transfer all services from supplemental package ".
2687           $old->pkgnum;
2688       }
2689       if ( $error ) {
2690         $dbh->rollback if $oldAutoCommit;
2691         return $error;
2692       }
2693       push @new_supp_pkgs, $new;
2694     }
2695   } # if !$opt->{'cust_pkg'}
2696     # because if there is one, then supplemental packages would already
2697     # have been created for it.
2698
2699   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2700   #remaining time.
2701   #Don't allow billing the package (preceding period packages and/or
2702   #outstanding usage) if we are keeping dates (i.e. location changing),
2703   #because the new package will be billed for the same date range.
2704   #Supplemental packages are also canceled here.
2705
2706   # during scheduled changes, avoid canceling the package we just
2707   # changed to (duh)
2708   $self->set('change_to_pkgnum' => '');
2709
2710   $error = $self->cancel(
2711     quiet          => 1,
2712     unused_credit  => $unused_credit,
2713     nobill         => $keep_dates,
2714     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2715     no_delay_cancel => 1,
2716   );
2717   if ($error) {
2718     $dbh->rollback if $oldAutoCommit;
2719     return "canceling old package: $error";
2720   }
2721
2722   # transfer rt_field_charge, if we're not changing pkgpart
2723   # after billing of old package, before billing of new package
2724   if ( $same_pkgpart ) {
2725     foreach my $rt_field_charge ($self->rt_field_charge) {
2726       $rt_field_charge->set('pkgnum', $cust_pkg->pkgnum);
2727       $error = $rt_field_charge->replace;
2728       if ( $error ) {
2729         $dbh->rollback if $oldAutoCommit;
2730         return "transferring rt_field_charge: $error";
2731       }
2732     }
2733   }
2734
2735   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2736     #$self->cust_main
2737     my $error = $cust_pkg->cust_main->bill(
2738       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2739     );
2740     if ( $error ) {
2741       $dbh->rollback if $oldAutoCommit;
2742       return "billing new package: $error";
2743     }
2744   }
2745
2746   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2747
2748   $cust_pkg;
2749
2750 }
2751
2752 =item change_later OPTION => VALUE...
2753
2754 Schedule a package change for a later date.  This actually orders the new
2755 package immediately, but sets its start date for a future date, and sets
2756 the current package to expire on the same date.
2757
2758 If the package is already scheduled for a change, this can be called with
2759 'start_date' to change the scheduled date, or with pkgpart and/or
2760 locationnum to modify the package change.  To cancel the scheduled change
2761 entirely, see C<abort_change>.
2762
2763 Options include:
2764
2765 =over 4
2766
2767 =item start_date
2768
2769 The date for the package change.  Required, and must be in the future.
2770
2771 =item pkgpart
2772
2773 =item locationnum
2774
2775 =item quantity
2776
2777 =item contract_end
2778
2779 The pkgpart, locationnum, quantity and optional contract_end of the new
2780 package, with the same meaning as in C<change>.
2781
2782 =back
2783
2784 =cut
2785
2786 sub change_later {
2787   my $self = shift;
2788   my $opt = ref($_[0]) ? shift : { @_ };
2789
2790   # check contract_end, prevent adding/removing
2791   my $error = $self->_check_change($opt);
2792   return $error if $error;
2793
2794   my $oldAutoCommit = $FS::UID::AutoCommit;
2795   local $FS::UID::AutoCommit = 0;
2796   my $dbh = dbh;
2797
2798   my $cust_main = $self->cust_main;
2799
2800   my $date = delete $opt->{'start_date'} or return 'start_date required';
2801
2802   if ( $date <= time ) {
2803     $dbh->rollback if $oldAutoCommit;
2804     return "start_date $date is in the past";
2805   }
2806
2807   # If the user entered a new location, set it up now.
2808   if ( $opt->{'cust_location'} ) {
2809     $error = $opt->{'cust_location'}->find_or_insert;
2810     if ( $error ) {
2811       $dbh->rollback if $oldAutoCommit;
2812       return "creating location record: $error";
2813     }
2814     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2815   }
2816
2817   if ( $self->change_to_pkgnum ) {
2818     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2819     my $new_pkgpart = $opt->{'pkgpart'}
2820         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2821     my $new_locationnum = $opt->{'locationnum'}
2822         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2823     my $new_quantity = $opt->{'quantity'}
2824         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2825     my $new_contract_end = $opt->{'contract_end'}
2826         if $opt->{'contract_end'} and $opt->{'contract_end'} != $change_to->contract_end;
2827     if ( $new_pkgpart or $new_locationnum or $new_quantity or $new_contract_end ) {
2828       # it hasn't been billed yet, so in principle we could just edit
2829       # it in place (w/o a package change), but that's bad form.
2830       # So change the package according to the new options...
2831       my $err_or_pkg = $change_to->change(%$opt);
2832       if ( ref $err_or_pkg ) {
2833         # Then set that package up for a future start.
2834         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2835         $self->set('expire', $date); # in case it's different
2836         $err_or_pkg->set('start_date', $date);
2837         $err_or_pkg->set('change_date', '');
2838         $err_or_pkg->set('change_pkgnum', '');
2839
2840         $error = $self->replace       ||
2841                  $err_or_pkg->replace ||
2842                  #because change() might've edited existing scheduled change in place
2843                  (($err_or_pkg->pkgnum == $change_to->pkgnum) ? '' :
2844                   $change_to->cancel('no_delay_cancel' => 1) ||
2845                   $change_to->delete);
2846       } else {
2847         $error = $err_or_pkg;
2848       }
2849     } else { # change the start date only.
2850       $self->set('expire', $date);
2851       $change_to->set('start_date', $date);
2852       $error = $self->replace || $change_to->replace;
2853     }
2854     if ( $error ) {
2855       $dbh->rollback if $oldAutoCommit;
2856       return $error;
2857     } else {
2858       $dbh->commit if $oldAutoCommit;
2859       return '';
2860     }
2861   } # if $self->change_to_pkgnum
2862
2863   my $new_pkgpart = $opt->{'pkgpart'}
2864       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2865   my $new_locationnum = $opt->{'locationnum'}
2866       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2867   my $new_quantity = $opt->{'quantity'}
2868       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2869   my $new_contract_end = $opt->{'contract_end'}
2870       if $opt->{'contract_end'} and $opt->{'contract_end'} != $self->contract_end;
2871
2872   return '' unless $new_pkgpart or $new_locationnum or $new_quantity or $new_contract_end; # wouldn't do anything
2873
2874   # allow $opt->{'locationnum'} = '' to specifically set it to null
2875   # (i.e. customer default location)
2876   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2877
2878   my $new = FS::cust_pkg->new( {
2879     custnum     => $self->custnum,
2880     locationnum => $opt->{'locationnum'},
2881     start_date  => $date,
2882     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2883       qw( pkgpart quantity refnum salesnum contract_end )
2884   } );
2885   $error = $new->insert('change' => 1,
2886                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2887   if ( !$error ) {
2888     $self->set('change_to_pkgnum', $new->pkgnum);
2889     $self->set('expire', $date);
2890     $error = $self->replace;
2891   }
2892   if ( $error ) {
2893     $dbh->rollback if $oldAutoCommit;
2894   } else {
2895     $dbh->commit if $oldAutoCommit;
2896   }
2897
2898   $error;
2899 }
2900
2901 =item abort_change
2902
2903 Cancels a future package change scheduled by C<change_later>.
2904
2905 =cut
2906
2907 sub abort_change {
2908   my $self = shift;
2909   my $oldAutoCommit = $FS::UID::AutoCommit;
2910   local $FS::UID::AutoCommit = 0;
2911
2912   my $pkgnum = $self->change_to_pkgnum;
2913   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2914   my $error;
2915   $self->set('change_to_pkgnum', '');
2916   $self->set('expire', '');
2917   $error = $self->replace;
2918   if ( $change_to ) {
2919     $error ||= $change_to->cancel || $change_to->delete;
2920   }
2921
2922   if ( $oldAutoCommit ) {
2923     if ( $error ) {
2924       dbh->rollback;
2925     } else {
2926       dbh->commit;
2927     }
2928   }
2929
2930   return $error;
2931 }
2932
2933 =item set_quantity QUANTITY
2934
2935 Change the package's quantity field.  This is one of the few package properties
2936 that can safely be changed without canceling and reordering the package
2937 (because it doesn't affect tax eligibility).  Returns an error or an
2938 empty string.
2939
2940 =cut
2941
2942 sub set_quantity {
2943   my $self = shift;
2944   $self = $self->replace_old; # just to make sure
2945   $self->quantity(shift);
2946   $self->replace;
2947 }
2948
2949 =item set_salesnum SALESNUM
2950
2951 Change the package's salesnum (sales person) field.  This is one of the few
2952 package properties that can safely be changed without canceling and reordering
2953 the package (because it doesn't affect tax eligibility).  Returns an error or
2954 an empty string.
2955
2956 =cut
2957
2958 sub set_salesnum {
2959   my $self = shift;
2960   $self = $self->replace_old; # just to make sure
2961   $self->salesnum(shift);
2962   $self->replace;
2963   # XXX this should probably reassign any credit that's already been given
2964 }
2965
2966 =item modify_charge OPTIONS
2967
2968 Change the properties of a one-time charge.  The following properties can
2969 be changed this way:
2970 - pkg: the package description
2971 - classnum: the package class
2972 - additional: arrayref of additional invoice details to add to this package
2973
2974 and, I<if the charge has not yet been billed>:
2975 - start_date: the date when it will be billed
2976 - amount: the setup fee to be charged
2977 - quantity: the multiplier for the setup fee
2978 - separate_bill: whether to put the charge on a separate invoice
2979
2980 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2981 commission credits linked to this charge, they will be recalculated.
2982
2983 =cut
2984
2985 sub modify_charge {
2986   my $self = shift;
2987   my %opt = @_;
2988   my $part_pkg = $self->part_pkg;
2989   my $pkgnum = $self->pkgnum;
2990
2991   my $dbh = dbh;
2992   my $oldAutoCommit = $FS::UID::AutoCommit;
2993   local $FS::UID::AutoCommit = 0;
2994
2995   return "Can't use modify_charge except on one-time charges"
2996     unless $part_pkg->freq eq '0';
2997
2998   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2999     $part_pkg->set('pkg', $opt{'pkg'});
3000   }
3001
3002   my %pkg_opt = $part_pkg->options;
3003   my $pkg_opt_modified = 0;
3004
3005   $opt{'additional'} ||= [];
3006   my $i;
3007   my @old_additional;
3008   foreach (grep /^additional/, keys %pkg_opt) {
3009     ($i) = ($_ =~ /^additional_info(\d+)$/);
3010     $old_additional[$i] = $pkg_opt{$_} if $i;
3011     delete $pkg_opt{$_};
3012   }
3013
3014   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
3015     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
3016     if (!exists($old_additional[$i])
3017         or $old_additional[$i] ne $opt{'additional'}->[$i])
3018     {
3019       $pkg_opt_modified = 1;
3020     }
3021   }
3022   $pkg_opt_modified = 1 if scalar(@old_additional) != $i;
3023   $pkg_opt{'additional_count'} = $i if $i > 0;
3024
3025   my $old_classnum;
3026   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
3027   {
3028     # remember it
3029     $old_classnum = $part_pkg->classnum;
3030     $part_pkg->set('classnum', $opt{'classnum'});
3031   }
3032
3033   if ( !$self->get('setup') ) {
3034     # not yet billed, so allow amount, setup_cost, quantity, start_date,
3035     # and separate_bill
3036
3037     if ( exists($opt{'amount'})
3038           and $part_pkg->option('setup_fee') != $opt{'amount'}
3039           and $opt{'amount'} > 0 ) {
3040
3041       $pkg_opt{'setup_fee'} = $opt{'amount'};
3042       $pkg_opt_modified = 1;
3043     }
3044
3045     if ( exists($opt{'setup_cost'})
3046           and $part_pkg->setup_cost != $opt{'setup_cost'}
3047           and $opt{'setup_cost'} > 0 ) {
3048
3049       $part_pkg->set('setup_cost', $opt{'setup_cost'});
3050     }
3051
3052     if ( exists($opt{'quantity'})
3053           and $opt{'quantity'} != $self->quantity
3054           and $opt{'quantity'} > 0 ) {
3055
3056       $self->set('quantity', $opt{'quantity'});
3057     }
3058
3059     if ( exists($opt{'start_date'})
3060           and $opt{'start_date'} != $self->start_date ) {
3061
3062       $self->set('start_date', $opt{'start_date'});
3063     }
3064
3065     if ( exists($opt{'separate_bill'})
3066           and $opt{'separate_bill'} ne $self->separate_bill ) {
3067
3068       $self->set('separate_bill', $opt{'separate_bill'});
3069     }
3070
3071
3072   } # else simply ignore them; the UI shouldn't allow editing the fields
3073
3074
3075   if ( exists($opt{'taxclass'})
3076           and $part_pkg->taxclass ne $opt{'taxclass'}) {
3077
3078       $part_pkg->set('taxclass', $opt{'taxclass'});
3079   }
3080
3081   my $error;
3082   if ( $part_pkg->modified or $pkg_opt_modified ) {
3083     # can we safely modify the package def?
3084     # Yes, if it's not available for purchase, and this is the only instance
3085     # of it.
3086     if ( $part_pkg->disabled
3087          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
3088          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
3089        ) {
3090       $error = $part_pkg->replace( options => \%pkg_opt );
3091     } else {
3092       # clone it
3093       $part_pkg = $part_pkg->clone;
3094       $part_pkg->set('disabled' => 'Y');
3095       $error = $part_pkg->insert( options => \%pkg_opt );
3096       # and associate this as yet-unbilled package to the new package def
3097       $self->set('pkgpart' => $part_pkg->pkgpart);
3098     }
3099     if ( $error ) {
3100       $dbh->rollback if $oldAutoCommit;
3101       return $error;
3102     }
3103   }
3104
3105   if ($self->modified) { # for quantity or start_date change, or if we had
3106                          # to clone the existing package def
3107     my $error = $self->replace;
3108     return $error if $error;
3109   }
3110   if (defined $old_classnum) {
3111     # fix invoice grouping records
3112     my $old_catname = $old_classnum
3113                       ? FS::pkg_class->by_key($old_classnum)->categoryname
3114                       : '';
3115     my $new_catname = $opt{'classnum'}
3116                       ? $part_pkg->pkg_class->categoryname
3117                       : '';
3118     if ( $old_catname ne $new_catname ) {
3119       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
3120         # (there should only be one...)
3121         my @display = qsearch( 'cust_bill_pkg_display', {
3122             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
3123             'section'     => $old_catname,
3124         });
3125         foreach (@display) {
3126           $_->set('section', $new_catname);
3127           $error = $_->replace;
3128           if ( $error ) {
3129             $dbh->rollback if $oldAutoCommit;
3130             return $error;
3131           }
3132         }
3133       } # foreach $cust_bill_pkg
3134     }
3135
3136     if ( $opt{'adjust_commission'} ) {
3137       # fix commission credits...tricky.
3138       foreach my $cust_event ($self->cust_event) {
3139         my $part_event = $cust_event->part_event;
3140         foreach my $table (qw(sales agent)) {
3141           my $class =
3142             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
3143           my $credit = qsearchs('cust_credit', {
3144               'eventnum' => $cust_event->eventnum,
3145           });
3146           if ( $part_event->isa($class) ) {
3147             # Yes, this results in current commission rates being applied
3148             # retroactively to a one-time charge.  For accounting purposes
3149             # there ought to be some kind of time limit on doing this.
3150             my $amount = $part_event->_calc_credit($self);
3151             if ( $credit and $credit->amount ne $amount ) {
3152               # Void the old credit.
3153               $error = $credit->void('Package class changed');
3154               if ( $error ) {
3155                 $dbh->rollback if $oldAutoCommit;
3156                 return "$error (adjusting commission credit)";
3157               }
3158             }
3159             # redo the event action to recreate the credit.
3160             local $@ = '';
3161             eval { $part_event->do_action( $self, $cust_event ) };
3162             if ( $@ ) {
3163               $dbh->rollback if $oldAutoCommit;
3164               return $@;
3165             }
3166           } # if $part_event->isa($class)
3167         } # foreach $table
3168       } # foreach $cust_event
3169     } # if $opt{'adjust_commission'}
3170   } # if defined $old_classnum
3171
3172   $dbh->commit if $oldAutoCommit;
3173   '';
3174 }
3175
3176 sub process_bulk_cust_pkg {
3177   my $job = shift;
3178   my $param = shift;
3179   warn Dumper($param) if $DEBUG;
3180
3181   my $old_part_pkg = qsearchs('part_pkg',
3182                               { pkgpart => $param->{'old_pkgpart'} });
3183   my $new_part_pkg = qsearchs('part_pkg',
3184                               { pkgpart => $param->{'new_pkgpart'} });
3185   die "Must select a new package type\n" unless $new_part_pkg;
3186   #my $keep_dates = $param->{'keep_dates'} || 0;
3187   my $keep_dates = 1; # there is no good reason to turn this off
3188
3189   my $oldAutoCommit = $FS::UID::AutoCommit;
3190   local $FS::UID::AutoCommit = 0;
3191   my $dbh = dbh;
3192
3193   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
3194
3195   my $i = 0;
3196   foreach my $old_cust_pkg ( @cust_pkgs ) {
3197     $i++;
3198     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
3199     if ( $old_cust_pkg->getfield('cancel') ) {
3200       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
3201         $old_cust_pkg->pkgnum."\n"
3202         if $DEBUG;
3203       next;
3204     }
3205     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
3206       if $DEBUG;
3207     my $error = $old_cust_pkg->change(
3208       'pkgpart'     => $param->{'new_pkgpart'},
3209       'keep_dates'  => $keep_dates
3210     );
3211     if ( !ref($error) ) { # change returns the cust_pkg on success
3212       $dbh->rollback;
3213       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
3214     }
3215   }
3216   $dbh->commit if $oldAutoCommit;
3217   return;
3218 }
3219
3220 =item last_bill
3221
3222 Returns the last bill date, or if there is no last bill date, the setup date.
3223 Useful for billing metered services.
3224
3225 =cut
3226
3227 sub last_bill {
3228   my $self = shift;
3229   return $self->setfield('last_bill', $_[0]) if @_;
3230   return $self->getfield('last_bill') if $self->getfield('last_bill');
3231   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
3232                                                   'edate'  => $self->bill,  } );
3233   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
3234 }
3235
3236 =item last_cust_pkg_reason ACTION
3237
3238 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
3239 Returns false if there is no reason or the package is not currenly ACTION'd
3240 ACTION is one of adjourn, susp, cancel, or expire.
3241
3242 =cut
3243
3244 sub last_cust_pkg_reason {
3245   my ( $self, $action ) = ( shift, shift );
3246   my $date = $self->get($action);
3247   qsearchs( {
3248               'table' => 'cust_pkg_reason',
3249               'hashref' => { 'pkgnum' => $self->pkgnum,
3250                              'action' => substr(uc($action), 0, 1),
3251                              'date'   => $date,
3252                            },
3253               'order_by' => 'ORDER BY num DESC LIMIT 1',
3254            } );
3255 }
3256
3257 =item last_reason ACTION
3258
3259 Returns the most recent ACTION FS::reason associated with the package.
3260 Returns false if there is no reason or the package is not currenly ACTION'd
3261 ACTION is one of adjourn, susp, cancel, or expire.
3262
3263 =cut
3264
3265 sub last_reason {
3266   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
3267   $cust_pkg_reason->reason
3268     if $cust_pkg_reason;
3269 }
3270
3271 =item part_pkg
3272
3273 Returns the definition for this billing item, as an FS::part_pkg object (see
3274 L<FS::part_pkg>).
3275
3276 =cut
3277
3278 sub part_pkg {
3279   my $self = shift;
3280   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
3281   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
3282   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
3283 }
3284
3285 =item old_cust_pkg
3286
3287 Returns the cancelled package this package was changed from, if any.
3288
3289 =cut
3290
3291 sub old_cust_pkg {
3292   my $self = shift;
3293   return '' unless $self->change_pkgnum;
3294   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
3295 }
3296
3297 =item change_cust_main
3298
3299 Returns the customter this package was detached to, if any.
3300
3301 =cut
3302
3303 sub change_cust_main {
3304   my $self = shift;
3305   return '' unless $self->change_custnum;
3306   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
3307 }
3308
3309 =item calc_setup
3310
3311 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
3312 item.
3313
3314 =cut
3315
3316 sub calc_setup {
3317   my $self = shift;
3318   $self->part_pkg->calc_setup($self, @_);
3319 }
3320
3321 =item calc_recur
3322
3323 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
3324 item.
3325
3326 =cut
3327
3328 sub calc_recur {
3329   my $self = shift;
3330   $self->part_pkg->calc_recur($self, @_);
3331 }
3332
3333 =item base_setup
3334
3335 Calls the I<base_setup> of the FS::part_pkg object associated with this billing
3336 item.
3337
3338 =cut
3339
3340 sub base_setup {
3341   my $self = shift;
3342   $self->part_pkg->base_setup($self, @_);
3343 }
3344
3345 =item base_recur
3346
3347 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
3348 item.
3349
3350 =cut
3351
3352 sub base_recur {
3353   my $self = shift;
3354   $self->part_pkg->base_recur($self, @_);
3355 }
3356
3357 =item calc_remain
3358
3359 Calls the I<calc_remain> of the FS::part_pkg object associated with this
3360 billing item.
3361
3362 =cut
3363
3364 sub calc_remain {
3365   my $self = shift;
3366   $self->part_pkg->calc_remain($self, @_);
3367 }
3368
3369 =item calc_cancel
3370
3371 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
3372 billing item.
3373
3374 =cut
3375
3376 sub calc_cancel {
3377   my $self = shift;
3378   $self->part_pkg->calc_cancel($self, @_);
3379 }
3380
3381 =item cust_bill_pkg
3382
3383 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
3384
3385 =cut
3386
3387 sub cust_bill_pkg {
3388   my $self = shift;
3389   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
3390 }
3391
3392 =item cust_pkg_detail [ DETAILTYPE ]
3393
3394 Returns any customer package details for this package (see
3395 L<FS::cust_pkg_detail>).
3396
3397 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
3398
3399 =cut
3400
3401 sub cust_pkg_detail {
3402   my $self = shift;
3403   my %hash = ( 'pkgnum' => $self->pkgnum );
3404   $hash{detailtype} = shift if @_;
3405   qsearch({
3406     'table'    => 'cust_pkg_detail',
3407     'hashref'  => \%hash,
3408     'order_by' => 'ORDER BY weight, pkgdetailnum',
3409   });
3410 }
3411
3412 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
3413
3414 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
3415
3416 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
3417
3418 If there is an error, returns the error, otherwise returns false.
3419
3420 =cut
3421
3422 sub set_cust_pkg_detail {
3423   my( $self, $detailtype, @details ) = @_;
3424
3425   my $oldAutoCommit = $FS::UID::AutoCommit;
3426   local $FS::UID::AutoCommit = 0;
3427   my $dbh = dbh;
3428
3429   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
3430     my $error = $current->delete;
3431     if ( $error ) {
3432       $dbh->rollback if $oldAutoCommit;
3433       return "error removing old detail: $error";
3434     }
3435   }
3436
3437   foreach my $detail ( @details ) {
3438     my $cust_pkg_detail = new FS::cust_pkg_detail {
3439       'pkgnum'     => $self->pkgnum,
3440       'detailtype' => $detailtype,
3441       'detail'     => $detail,
3442     };
3443     my $error = $cust_pkg_detail->insert;
3444     if ( $error ) {
3445       $dbh->rollback if $oldAutoCommit;
3446       return "error adding new detail: $error";
3447     }
3448
3449   }
3450
3451   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3452   '';
3453
3454 }
3455
3456 =item cust_event
3457
3458 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
3459
3460 =cut
3461
3462 #false laziness w/cust_bill.pm
3463 sub cust_event {
3464   my $self = shift;
3465   qsearch({
3466     'table'     => 'cust_event',
3467     'addl_from' => 'JOIN part_event USING ( eventpart )',
3468     'hashref'   => { 'tablenum' => $self->pkgnum },
3469     'extra_sql' => " AND eventtable = 'cust_pkg' ",
3470   });
3471 }
3472
3473 =item num_cust_event
3474
3475 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
3476
3477 =cut
3478
3479 #false laziness w/cust_bill.pm
3480 sub num_cust_event {
3481   my $self = shift;
3482   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
3483   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
3484 }
3485
3486 =item exists_cust_event
3487
3488 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
3489
3490 =cut
3491
3492 sub exists_cust_event {
3493   my $self = shift;
3494   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
3495   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
3496   $row ? $row->[0] : '';
3497 }
3498
3499 sub _from_cust_event_where {
3500   #my $self = shift;
3501   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3502   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3503 }
3504
3505 sub _prep_ex {
3506   my( $self, $sql, @args ) = @_;
3507   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3508   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3509   $sth;
3510 }
3511
3512 =item part_pkg_currency_option OPTIONNAME
3513
3514 Returns a two item list consisting of the currency of this customer, if any,
3515 and a value for the provided option.  If the customer has a currency, the value
3516 is the option value the given name and the currency (see
3517 L<FS::part_pkg_currency>).  Otherwise, if the customer has no currency, is the
3518 regular option value for the given name (see L<FS::part_pkg_option>).
3519
3520 =cut
3521
3522 sub part_pkg_currency_option {
3523   my( $self, $optionname ) = @_;
3524   my $part_pkg = $self->part_pkg;
3525   if ( my $currency = $self->cust_main->currency ) {
3526     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
3527   } else {
3528     ('', $part_pkg->option($optionname) );
3529   }
3530 }
3531
3532 =item cust_svc [ SVCPART ] (old, deprecated usage)
3533
3534 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3535
3536 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3537
3538 Returns the services for this package, as FS::cust_svc objects (see
3539 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3540 spcififed, returns only the matching services.
3541
3542 As an optimization, use the cust_svc_unsorted version if you are not displaying
3543 the results.
3544
3545 =cut
3546
3547 sub cust_svc {
3548   my $self = shift;
3549   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3550   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3551 }
3552
3553 sub cust_svc_unsorted {
3554   my $self = shift;
3555   @{ $self->cust_svc_unsorted_arrayref(@_) };
3556 }
3557
3558 sub cust_svc_unsorted_arrayref {
3559   my $self = shift;
3560
3561   return [] unless $self->num_cust_svc(@_);
3562
3563   my %opt = ();
3564   if ( @_ && $_[0] =~ /^\d+/ ) {
3565     $opt{svcpart} = shift;
3566   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3567     %opt = %{ $_[0] };
3568   } elsif ( @_ ) {
3569     %opt = @_;
3570   }
3571
3572   my %search = (
3573     'select'    => 'cust_svc.*, part_svc.*',
3574     'table'     => 'cust_svc',
3575     'hashref'   => { 'pkgnum' => $self->pkgnum },
3576     'addl_from' => 'LEFT JOIN part_svc USING ( svcpart )',
3577   );
3578   $search{hashref}->{svcpart} = $opt{svcpart}
3579     if $opt{svcpart};
3580   $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{svcdb} )
3581     if $opt{svcdb};
3582
3583   [ qsearch(\%search) ];
3584
3585 }
3586
3587 =item overlimit [ SVCPART ]
3588
3589 Returns the services for this package which have exceeded their
3590 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3591 is specified, return only the matching services.
3592
3593 =cut
3594
3595 sub overlimit {
3596   my $self = shift;
3597   return () unless $self->num_cust_svc(@_);
3598   grep { $_->overlimit } $self->cust_svc(@_);
3599 }
3600
3601 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3602
3603 Returns historical services for this package created before END TIMESTAMP and
3604 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3605 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3606 I<pkg_svc.hidden> flag will be omitted.
3607
3608 =cut
3609
3610 sub h_cust_svc {
3611   my $self = shift;
3612   warn "$me _h_cust_svc called on $self\n"
3613     if $DEBUG;
3614
3615   my ($end, $start, $mode) = @_;
3616
3617   local($FS::Record::qsearch_qualify_columns) = 0;
3618
3619   my @cust_svc = $self->_sort_cust_svc(
3620     [ qsearch( 'h_cust_svc',
3621       { 'pkgnum' => $self->pkgnum, },
3622       FS::h_cust_svc->sql_h_search(@_),
3623     ) ]
3624   );
3625
3626   if ( defined($mode) && $mode eq 'I' ) {
3627     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3628     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3629   } else {
3630     return @cust_svc;
3631   }
3632 }
3633
3634 sub _sort_cust_svc {
3635   my( $self, $arrayref ) = @_;
3636
3637   my $sort =
3638     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3639
3640   my %pkg_svc = map { $_->svcpart => $_ }
3641                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3642
3643   map  { $_->[0] }
3644   sort $sort
3645   map {
3646         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3647         [ $_,
3648           $pkg_svc ? $pkg_svc->primary_svc : '',
3649           $pkg_svc ? $pkg_svc->quantity : 0,
3650         ];
3651       }
3652   @$arrayref;
3653
3654 }
3655
3656 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3657
3658 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3659
3660 Returns the number of services for this package.  Available options are svcpart
3661 and svcdb.  If either is spcififed, returns only the matching services.
3662
3663 =cut
3664
3665 sub num_cust_svc {
3666   my $self = shift;
3667
3668   return $self->{'_num_cust_svc'}
3669     if !scalar(@_)
3670        && exists($self->{'_num_cust_svc'})
3671        && $self->{'_num_cust_svc'} =~ /\d/;
3672
3673   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3674     if $DEBUG > 2;
3675
3676   my %opt = ();
3677   if ( @_ && $_[0] =~ /^\d+/ ) {
3678     $opt{svcpart} = shift;
3679   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3680     %opt = %{ $_[0] };
3681   } elsif ( @_ ) {
3682     %opt = @_;
3683   }
3684
3685   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3686   my $where = ' WHERE pkgnum = ? ';
3687   my @param = ($self->pkgnum);
3688
3689   if ( $opt{'svcpart'} ) {
3690     $where .= ' AND svcpart = ? ';
3691     push @param, $opt{'svcpart'};
3692   }
3693   if ( $opt{'svcdb'} ) {
3694     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3695     $where .= ' AND svcdb = ? ';
3696     push @param, $opt{'svcdb'};
3697   }
3698
3699   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3700   $sth->execute(@param) or die $sth->errstr;
3701   $sth->fetchrow_arrayref->[0];
3702 }
3703
3704 =item available_part_svc
3705
3706 Returns a list of FS::part_svc objects representing services included in this
3707 package but not yet provisioned.  Each FS::part_svc object also has an extra
3708 field, I<num_avail>, which specifies the number of available services.
3709
3710 Accepts option I<provision_hold>;  if true, only returns part_svc for which the
3711 associated pkg_svc has the provision_hold flag set.
3712
3713 =cut
3714
3715 sub available_part_svc {
3716   my $self = shift;
3717   my %opt  = @_;
3718
3719   my $pkg_quantity = $self->quantity || 1;
3720
3721   grep { $_->num_avail > 0 }
3722   map {
3723     my $part_svc = $_->part_svc;
3724     $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3725     $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3726
3727     # more evil encapsulation breakage
3728     if ($part_svc->{'Hash'}{'num_avail'} > 0) {
3729       my @exports = $part_svc->part_export_did;
3730       $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3731         }
3732
3733     $part_svc;
3734   }
3735   grep { $opt{'provision_hold'} ? $_->provision_hold : 1 }
3736   $self->part_pkg->pkg_svc;
3737 }
3738
3739 =item part_svc [ OPTION => VALUE ... ]
3740
3741 Returns a list of FS::part_svc objects representing provisioned and available
3742 services included in this package.  Each FS::part_svc object also has the
3743 following extra fields:
3744
3745 =over 4
3746
3747 =item num_cust_svc
3748
3749 (count)
3750
3751 =item num_avail
3752
3753 (quantity - count)
3754
3755 =item cust_pkg_svc
3756
3757 (services) - array reference containing the provisioned services, as cust_svc objects
3758
3759 =back
3760
3761 Accepts two options:
3762
3763 =over 4
3764
3765 =item summarize_size
3766
3767 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3768 is this size or greater.
3769
3770 =item hide_discontinued
3771
3772 If true, will omit looking for services that are no longer avaialble in the
3773 package definition.
3774
3775 =back
3776
3777 =cut
3778
3779 #svcnum
3780 #label -> ($cust_svc->label)[1]
3781
3782 sub part_svc {
3783   my $self = shift;
3784   my %opt = @_;
3785
3786   my $pkg_quantity = $self->quantity || 1;
3787
3788   #XXX some sort of sort order besides numeric by svcpart...
3789   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3790     my $pkg_svc = $_;
3791     my $part_svc = $pkg_svc->part_svc;
3792     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3793     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3794     $part_svc->{'Hash'}{'num_avail'}    =
3795       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3796     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3797         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3798       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3799           && $num_cust_svc >= $opt{summarize_size};
3800     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3801     $part_svc;
3802   } $self->part_pkg->pkg_svc;
3803
3804   unless ( $opt{hide_discontinued} ) {
3805     #extras
3806     push @part_svc, map {
3807       my $part_svc = $_;
3808       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3809       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3810       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3811       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3812         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3813       $part_svc;
3814     } $self->extra_part_svc;
3815   }
3816
3817   @part_svc;
3818
3819 }
3820
3821 =item extra_part_svc
3822
3823 Returns a list of FS::part_svc objects corresponding to services in this
3824 package which are still provisioned but not (any longer) available in the
3825 package definition.
3826
3827 =cut
3828
3829 sub extra_part_svc {
3830   my $self = shift;
3831
3832   my $pkgnum  = $self->pkgnum;
3833   #my $pkgpart = $self->pkgpart;
3834
3835 #  qsearch( {
3836 #    'table'     => 'part_svc',
3837 #    'hashref'   => {},
3838 #    'extra_sql' =>
3839 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3840 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3841 #                       AND pkg_svc.pkgpart = ?
3842 #                       AND quantity > 0
3843 #                 )
3844 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3845 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3846 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3847 #                       AND pkgnum = ?
3848 #                 )",
3849 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3850 #  } );
3851
3852 #seems to benchmark slightly faster... (or did?)
3853
3854   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3855   my $pkgparts = join(',', @pkgparts);
3856
3857   qsearch( {
3858     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3859     #MySQL doesn't grok DISINCT ON
3860     'select'      => 'DISTINCT part_svc.*',
3861     'table'       => 'part_svc',
3862     'addl_from'   =>
3863       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3864                                AND pkg_svc.pkgpart IN ($pkgparts)
3865                                AND quantity > 0
3866                              )
3867        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3868        LEFT JOIN cust_pkg USING ( pkgnum )
3869       ",
3870     'hashref'     => {},
3871     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3872     'extra_param' => [ [$self->pkgnum=>'int'] ],
3873   } );
3874 }
3875
3876 =item status
3877
3878 Returns a short status string for this package, currently:
3879
3880 =over 4
3881
3882 =item on hold
3883
3884 =item not yet billed
3885
3886 =item one-time charge
3887
3888 =item active
3889
3890 =item suspended
3891
3892 =item cancelled
3893
3894 =back
3895
3896 =cut
3897
3898 sub status {
3899   my $self = shift;
3900
3901   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3902
3903   return 'cancelled' if $self->get('cancel');
3904   return 'on hold' if $self->susp && ! $self->setup;
3905   return 'suspended' if $self->susp;
3906   return 'not yet billed' unless $self->setup;
3907   return 'one-time charge' if $freq =~ /^(0|$)/;
3908   return 'active';
3909 }
3910
3911 =item ucfirst_status
3912
3913 Returns the status with the first character capitalized.
3914
3915 =cut
3916
3917 sub ucfirst_status {
3918   ucfirst(shift->status);
3919 }
3920
3921 =item statuses
3922
3923 Class method that returns the list of possible status strings for packages
3924 (see L<the status method|/status>).  For example:
3925
3926   @statuses = FS::cust_pkg->statuses();
3927
3928 =cut
3929
3930 tie my %statuscolor, 'Tie::IxHash',
3931   'on hold'         => 'FF00F5', #brighter purple!
3932   'not yet billed'  => '009999', #teal? cyan?
3933   'one-time charge' => '0000CC', #blue  #'000000',
3934   'active'          => '00CC00',
3935   'suspended'       => 'FF9900',
3936   'cancelled'       => 'FF0000',
3937 ;
3938
3939 sub statuses {
3940   my $self = shift; #could be class...
3941   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3942   #                                    # mayble split btw one-time vs. recur
3943     keys %statuscolor;
3944 }
3945
3946 sub statuscolors {
3947   #my $self = shift;
3948   \%statuscolor;
3949 }
3950
3951 =item statuscolor
3952
3953 Returns a hex triplet color string for this package's status.
3954
3955 =cut
3956
3957 sub statuscolor {
3958   my $self = shift;
3959   $statuscolor{$self->status};
3960 }
3961
3962 =item is_status_delay_cancel
3963
3964 Returns true if part_pkg has option delay_cancel,
3965 cust_pkg status is 'suspended' and expire is set
3966 to cancel package within the next day (or however
3967 many days are set in global config part_pkg-delay_cancel-days.
3968
3969 Accepts option I<part_pkg-delay_cancel-days> which should be
3970 the value of the config setting, to avoid looking it up again.
3971
3972 This is not a real status, this only meant for hacking display
3973 values, because otherwise treating the package as suspended is
3974 really the whole point of the delay_cancel option.
3975
3976 =cut
3977
3978 sub is_status_delay_cancel {
3979   my ($self,%opt) = @_;
3980   if ( $self->main_pkgnum and $self->pkglinknum ) {
3981     return $self->main_pkg->is_status_delay_cancel;
3982   }
3983   return 0 unless $self->part_pkg->option('delay_cancel',1);
3984   return 0 unless $self->status eq 'suspended';
3985   return 0 unless $self->expire;
3986   my $expdays = $opt{'part_pkg-delay_cancel-days'};
3987   unless ($expdays) {
3988     my $conf = new FS::Conf;
3989     $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3990   }
3991   my $expsecs = 60*60*24*$expdays;
3992   return 0 unless $self->expire < time + $expsecs;
3993   return 1;
3994 }
3995
3996 =item pkg_label
3997
3998 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3999 "pkg - comment" depending on user preference).
4000
4001 =cut
4002
4003 sub pkg_label {
4004   my $self = shift;
4005   my $label = $self->part_pkg->pkg_comment( cust_pkg=>$self, nopkgpart=>1 );
4006   $label = $self->pkgnum. ": $label"
4007     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
4008   $label;
4009 }
4010
4011 =item pkg_label_long
4012
4013 Returns a long label for this package, adding the primary service's label to
4014 pkg_label.
4015
4016 =cut
4017
4018 sub pkg_label_long {
4019   my $self = shift;
4020   my $label = $self->pkg_label;
4021   my $cust_svc = $self->primary_cust_svc;
4022   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
4023   $label;
4024 }
4025
4026 =item pkg_locale
4027
4028 Returns a customer-localized label for this package.
4029
4030 =cut
4031
4032 sub pkg_locale {
4033   my $self = shift;
4034   $self->part_pkg->pkg_locale( $self->cust_main->locale );
4035 }
4036
4037 =item primary_cust_svc
4038
4039 Returns a primary service (as FS::cust_svc object) if one can be identified.
4040
4041 =cut
4042
4043 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
4044
4045 sub primary_cust_svc {
4046   my $self = shift;
4047
4048   my @cust_svc = $self->cust_svc;
4049
4050   return '' unless @cust_svc; #no serivces - irrelevant then
4051
4052   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
4053
4054   # primary service as specified in the package definition
4055   # or exactly one service definition with quantity one
4056   my $svcpart = $self->part_pkg->svcpart;
4057   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
4058   return $cust_svc[0] if scalar(@cust_svc) == 1;
4059
4060   #couldn't identify one thing..
4061   return '';
4062 }
4063
4064 =item labels
4065
4066 Returns a list of lists, calling the label method for all services
4067 (see L<FS::cust_svc>) of this billing item.
4068
4069 =cut
4070
4071 sub labels {
4072   my $self = shift;
4073   map { [ $_->label ] } $self->cust_svc;
4074 }
4075
4076 =item h_labels END_TIMESTAMP [, START_TIMESTAMP [, MODE [, LOCALE ] ] ]
4077
4078 Like the labels method, but returns historical information on services that
4079 were active as of END_TIMESTAMP and (optionally) not cancelled before
4080 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
4081 I<pkg_svc.hidden> flag will be omitted.
4082
4083 If LOCALE is passed, service definition names will be localized.
4084
4085 Returns a list of lists, calling the label method for all (historical)
4086 services (see L<FS::h_cust_svc>) of this billing item.
4087
4088 =cut
4089
4090 sub h_labels {
4091   my $self = shift;
4092   my ($end, $start, $mode, $locale) = @_;
4093   warn "$me h_labels\n"
4094     if $DEBUG;
4095   map { [ $_->label($end, $start, $locale) ] }
4096         $self->h_cust_svc($end, $start, $mode);
4097 }
4098
4099 =item labels_short
4100
4101 Like labels, except returns a simple flat list, and shortens long
4102 (currently >5 or the cust_bill-max_same_services configuration value) lists of
4103 identical services to one line that lists the service label and the number of
4104 individual services rather than individual items.
4105
4106 =cut
4107
4108 sub labels_short {
4109   shift->_labels_short( 'labels' ); # 'labels' takes no further arguments
4110 }
4111
4112 =item h_labels_short END_TIMESTAMP [, START_TIMESTAMP [, MODE [, LOCALE ] ] ]
4113
4114 Like h_labels, except returns a simple flat list, and shortens long
4115 (currently >5 or the cust_bill-max_same_services configuration value) lists
4116 of identical services to one line that lists the service label and the
4117 number of individual services rather than individual items.
4118
4119 =cut
4120
4121 sub h_labels_short {
4122   shift->_labels_short( 'h_labels', @_ );
4123 }
4124
4125 # takes a method name ('labels' or 'h_labels') and all its arguments;
4126 # maybe should be "shorten($self->h_labels( ... ) )"
4127
4128 sub _labels_short {
4129   my( $self, $method ) = ( shift, shift );
4130
4131   warn "$me _labels_short called on $self with $method method\n"
4132     if $DEBUG;
4133
4134   my $conf = new FS::Conf;
4135   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
4136
4137   warn "$me _labels_short populating \%labels\n"
4138     if $DEBUG;
4139
4140   my %labels;
4141   #tie %labels, 'Tie::IxHash';
4142   push @{ $labels{$_->[0]} }, $_->[1]
4143     foreach $self->$method(@_);
4144
4145   warn "$me _labels_short populating \@labels\n"
4146     if $DEBUG;
4147
4148   my @labels;
4149   foreach my $label ( keys %labels ) {
4150     my %seen = ();
4151     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
4152     my $num = scalar(@values);
4153     warn "$me _labels_short $num items for $label\n"
4154       if $DEBUG;
4155
4156     if ( $num > $max_same_services ) {
4157       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
4158         if $DEBUG;
4159       push @labels, "$label ($num)";
4160     } else {
4161       if ( $conf->exists('cust_bill-consolidate_services') ) {
4162         warn "$me _labels_short   consolidating services\n"
4163           if $DEBUG;
4164         # push @labels, "$label: ". join(', ', @values);
4165         while ( @values ) {
4166           my $detail = "$label: ";
4167           $detail .= shift(@values). ', '
4168             while @values
4169                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
4170           $detail =~ s/, $//;
4171           push @labels, $detail;
4172         }
4173         warn "$me _labels_short   done consolidating services\n"
4174           if $DEBUG;
4175       } else {
4176         warn "$me _labels_short   adding service data\n"
4177           if $DEBUG;
4178         push @labels, map { "$label: $_" } @values;
4179       }
4180     }
4181   }
4182
4183  @labels;
4184
4185 }
4186
4187 =item cust_main
4188
4189 Returns the parent customer object (see L<FS::cust_main>).
4190
4191 =item balance
4192
4193 Returns the balance for this specific package, when using
4194 experimental package balance.
4195
4196 =cut
4197
4198 sub balance {
4199   my $self = shift;
4200   $self->cust_main->balance_pkgnum( $self->pkgnum );
4201 }
4202
4203 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
4204
4205 =item cust_location
4206
4207 Returns the location object, if any (see L<FS::cust_location>).
4208
4209 =item cust_location_or_main
4210
4211 If this package is associated with a location, returns the locaiton (see
4212 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
4213
4214 =item location_label [ OPTION => VALUE ... ]
4215
4216 Returns the label of the location object (see L<FS::cust_location>).
4217
4218 =cut
4219
4220 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
4221
4222 =item tax_locationnum
4223
4224 Returns the foreign key to a L<FS::cust_location> object for calculating
4225 tax on this package, as determined by the C<tax-pkg_address> and
4226 C<tax-ship_address> configuration flags.
4227
4228 =cut
4229
4230 sub tax_locationnum {
4231   my $self = shift;
4232   my $conf = FS::Conf->new;
4233   if ( $conf->exists('tax-pkg_address') ) {
4234     return $self->locationnum;
4235   }
4236   elsif ( $conf->exists('tax-ship_address') ) {
4237     return $self->cust_main->ship_locationnum;
4238   }
4239   else {
4240     return $self->cust_main->bill_locationnum;
4241   }
4242 }
4243
4244 =item tax_location
4245
4246 Returns the L<FS::cust_location> object for tax_locationnum.
4247
4248 =cut
4249
4250 sub tax_location {
4251   my $self = shift;
4252   my $conf = FS::Conf->new;
4253   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
4254     return FS::cust_location->by_key($self->locationnum);
4255   }
4256   elsif ( $conf->exists('tax-ship_address') ) {
4257     return $self->cust_main->ship_location;
4258   }
4259   else {
4260     return $self->cust_main->bill_location;
4261   }
4262 }
4263
4264 =item seconds_since TIMESTAMP
4265
4266 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
4267 package have been online since TIMESTAMP, according to the session monitor.
4268
4269 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
4270 L<Time::Local> and L<Date::Parse> for conversion functions.
4271
4272 =cut
4273
4274 sub seconds_since {
4275   my($self, $since) = @_;
4276   my $seconds = 0;
4277
4278   foreach my $cust_svc (
4279     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
4280   ) {
4281     $seconds += $cust_svc->seconds_since($since);
4282   }
4283
4284   $seconds;
4285
4286 }
4287
4288 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
4289
4290 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
4291 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
4292 (exclusive).
4293
4294 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
4295 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
4296 functions.
4297
4298
4299 =cut
4300
4301 sub seconds_since_sqlradacct {
4302   my($self, $start, $end) = @_;
4303
4304   my $seconds = 0;
4305
4306   foreach my $cust_svc (
4307     grep {
4308       my $part_svc = $_->part_svc;
4309       $part_svc->svcdb eq 'svc_acct'
4310         && scalar($part_svc->part_export_usage);
4311     } $self->cust_svc
4312   ) {
4313     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
4314   }
4315
4316   $seconds;
4317
4318 }
4319
4320 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
4321
4322 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
4323 in this package for sessions ending between TIMESTAMP_START (inclusive) and
4324 TIMESTAMP_END
4325 (exclusive).
4326
4327 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
4328 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
4329 functions.
4330
4331 =cut
4332
4333 sub attribute_since_sqlradacct {
4334   my($self, $start, $end, $attrib) = @_;
4335
4336   my $sum = 0;
4337
4338   foreach my $cust_svc (
4339     grep {
4340       my $part_svc = $_->part_svc;
4341       scalar($part_svc->part_export_usage);
4342     } $self->cust_svc
4343   ) {
4344     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
4345   }
4346
4347   $sum;
4348
4349 }
4350
4351 =item quantity
4352
4353 =cut
4354
4355 sub quantity {
4356   my( $self, $value ) = @_;
4357   if ( defined($value) ) {
4358     $self->setfield('quantity', $value);
4359   }
4360   $self->getfield('quantity') || 1;
4361 }
4362
4363 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
4364
4365 Transfers as many services as possible from this package to another package.
4366
4367 The destination package can be specified by pkgnum by passing an FS::cust_pkg
4368 object.  The destination package must already exist.
4369
4370 Services are moved only if the destination allows services with the correct
4371 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
4372 this option with caution!  No provision is made for export differences
4373 between the old and new service definitions.  Probably only should be used
4374 when your exports for all service definitions of a given svcdb are identical.
4375 (attempt a transfer without it first, to move all possible svcpart-matching
4376 services)
4377
4378 Any services that can't be moved remain in the original package.
4379
4380 Returns an error, if there is one; otherwise, returns the number of services
4381 that couldn't be moved.
4382
4383 =cut
4384
4385 sub transfer {
4386   my ($self, $dest_pkgnum, %opt) = @_;
4387
4388   my $remaining = 0;
4389   my $dest;
4390   my %target;
4391
4392   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
4393     $dest = $dest_pkgnum;
4394     $dest_pkgnum = $dest->pkgnum;
4395   } else {
4396     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
4397   }
4398
4399   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
4400
4401   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
4402     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
4403   }
4404
4405   foreach my $cust_svc ($dest->cust_svc) {
4406     $target{$cust_svc->svcpart}--;
4407   }
4408
4409   my %svcpart2svcparts = ();
4410   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
4411     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
4412     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
4413       next if exists $svcpart2svcparts{$svcpart};
4414       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
4415       $svcpart2svcparts{$svcpart} = [
4416         map  { $_->[0] }
4417         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
4418         map {
4419               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
4420                                                    'svcpart' => $_          } );
4421               [ $_,
4422                 $pkg_svc ? $pkg_svc->primary_svc : '',
4423                 $pkg_svc ? $pkg_svc->quantity : 0,
4424               ];
4425             }
4426
4427         grep { $_ != $svcpart }
4428         map  { $_->svcpart }
4429         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
4430       ];
4431       warn "alternates for svcpart $svcpart: ".
4432            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
4433         if $DEBUG;
4434     }
4435   }
4436
4437   my $error;
4438   foreach my $cust_svc ($self->cust_svc) {
4439     my $svcnum = $cust_svc->svcnum;
4440     if($target{$cust_svc->svcpart} > 0
4441        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
4442       $target{$cust_svc->svcpart}--;
4443       my $new = new FS::cust_svc { $cust_svc->hash };
4444       $new->pkgnum($dest_pkgnum);
4445       $error = $new->replace($cust_svc);
4446     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
4447       if ( $DEBUG ) {
4448         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
4449         warn "alternates to consider: ".
4450              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
4451       }
4452       my @alternate = grep {
4453                              warn "considering alternate svcpart $_: ".
4454                                   "$target{$_} available in new package\n"
4455                                if $DEBUG;
4456                              $target{$_} > 0;
4457                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
4458       if ( @alternate ) {
4459         warn "alternate(s) found\n" if $DEBUG;
4460         my $change_svcpart = $alternate[0];
4461         $target{$change_svcpart}--;
4462         my $new = new FS::cust_svc { $cust_svc->hash };
4463         $new->svcpart($change_svcpart);
4464         $new->pkgnum($dest_pkgnum);
4465         $error = $new->replace($cust_svc);
4466       } else {
4467         $remaining++;
4468       }
4469     } else {
4470       $remaining++
4471     }
4472     if ( $error ) {
4473       my @label = $cust_svc->label;
4474       return "$label[0] $label[1]: $error";
4475     }
4476   }
4477   return $remaining;
4478 }
4479
4480 =item grab_svcnums SVCNUM, SVCNUM ...
4481
4482 Change the pkgnum for the provided services to this packages.  If there is an
4483 error, returns the error, otherwise returns false.
4484
4485 =cut
4486
4487 sub grab_svcnums {
4488   my $self = shift;
4489   my @svcnum = @_;
4490
4491   my $oldAutoCommit = $FS::UID::AutoCommit;
4492   local $FS::UID::AutoCommit = 0;
4493   my $dbh = dbh;
4494
4495   foreach my $svcnum (@svcnum) {
4496     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
4497       $dbh->rollback if $oldAutoCommit;
4498       return "unknown svcnum $svcnum";
4499     };
4500     $cust_svc->pkgnum( $self->pkgnum );
4501     my $error = $cust_svc->replace;
4502     if ( $error ) {
4503       $dbh->rollback if $oldAutoCommit;
4504       return $error;
4505     }
4506   }
4507
4508   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4509   '';
4510
4511 }
4512
4513 =item reexport
4514
4515 This method is deprecated.  See the I<depend_jobnum> option to the insert and
4516 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
4517
4518 =cut
4519
4520 #looks like this is still used by the order_pkg and change_pkg methods in
4521 # ClientAPI/MyAccount, need to look into those before removing
4522 sub reexport {
4523   my $self = shift;
4524
4525   my $oldAutoCommit = $FS::UID::AutoCommit;
4526   local $FS::UID::AutoCommit = 0;
4527   my $dbh = dbh;
4528
4529   foreach my $cust_svc ( $self->cust_svc ) {
4530     #false laziness w/svc_Common::insert
4531     my $svc_x = $cust_svc->svc_x;
4532     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4533       my $error = $part_export->export_insert($svc_x);
4534       if ( $error ) {
4535         $dbh->rollback if $oldAutoCommit;
4536         return $error;
4537       }
4538     }
4539   }
4540
4541   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4542   '';
4543
4544 }
4545
4546 =item export_pkg_change OLD_CUST_PKG
4547
4548 Calls the "pkg_change" export action for all services attached to this package.
4549
4550 =cut
4551
4552 sub export_pkg_change {
4553   my( $self, $old )  = ( shift, shift );
4554
4555   my $oldAutoCommit = $FS::UID::AutoCommit;
4556   local $FS::UID::AutoCommit = 0;
4557   my $dbh = dbh;
4558
4559   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4560     my $error = $svc_x->export('pkg_change', $self, $old);
4561     if ( $error ) {
4562       $dbh->rollback if $oldAutoCommit;
4563       return $error;
4564     }
4565   }
4566
4567   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4568   '';
4569
4570 }
4571
4572 =item insert_reason
4573
4574 Associates this package with a (suspension or cancellation) reason (see
4575 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4576 L<FS::reason>).
4577
4578 Available options are:
4579
4580 =over 4
4581
4582 =item reason
4583
4584 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4585
4586 =item reason_otaker
4587
4588 the access_user (see L<FS::access_user>) providing the reason
4589
4590 =item date
4591
4592 a unix timestamp
4593
4594 =item action
4595
4596 the action (cancel, susp, adjourn, expire) associated with the reason
4597
4598 =back
4599
4600 If there is an error, returns the error, otherwise returns false.
4601
4602 =cut
4603
4604 sub insert_reason {
4605   my ($self, %options) = @_;
4606
4607   my $otaker = $options{reason_otaker} ||
4608                $FS::CurrentUser::CurrentUser->username;
4609
4610   my $reasonnum;
4611   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4612
4613     $reasonnum = $1;
4614
4615   } elsif ( ref($options{'reason'}) ) {
4616
4617     return 'Enter a new reason (or select an existing one)'
4618       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4619
4620     my $reason = new FS::reason({
4621       'reason_type' => $options{'reason'}->{'typenum'},
4622       'reason'      => $options{'reason'}->{'reason'},
4623     });
4624     my $error = $reason->insert;
4625     return $error if $error;
4626
4627     $reasonnum = $reason->reasonnum;
4628
4629   } else {
4630     return "Unparseable reason: ". $options{'reason'};
4631   }
4632
4633   my $cust_pkg_reason =
4634     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4635                               'reasonnum' => $reasonnum,
4636                               'otaker'    => $otaker,
4637                               'action'    => substr(uc($options{'action'}),0,1),
4638                               'date'      => $options{'date'}
4639                                                ? $options{'date'}
4640                                                : time,
4641                             });
4642
4643   $cust_pkg_reason->insert;
4644 }
4645
4646 =item insert_discount
4647
4648 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4649 inserting a new discount on the fly (see L<FS::discount>).
4650
4651 This will look at the cust_pkg for a pseudo-field named "setup_discountnum",
4652 and if present, will create a setup discount. If the discountnum is -1,
4653 a new discount definition will be inserted using the value in
4654 "setup_discountnum_amount" or "setup_discountnum_percent". Likewise for recur.
4655
4656 If there is an error, returns the error, otherwise returns false.
4657
4658 =cut
4659
4660 sub insert_discount {
4661   #my ($self, %options) = @_;
4662   my $self = shift;
4663
4664   foreach my $x (qw(setup recur)) {
4665     if ( my $discountnum = $self->get("${x}_discountnum") ) {
4666       my $cust_pkg_discount = FS::cust_pkg_discount->new( {
4667         'pkgnum'      => $self->pkgnum,
4668         'discountnum' => $discountnum,
4669         'setuprecur'  => $x,
4670         'months_used' => 0,
4671         'end_date'    => '', #XXX
4672         #for the create a new discount case
4673         'amount'      => $self->get("${x}_discountnum_amount"),
4674         'percent'     => $self->get("${x}_discountnum_percent"),
4675         'months'      => $self->get("${x}_discountnum_months"),
4676       } );
4677       if ( $x eq 'setup' ) {
4678         $cust_pkg_discount->setup('Y');
4679         $cust_pkg_discount->months('');
4680       }
4681       my $error = $cust_pkg_discount->insert;
4682       return $error if $error;
4683     }
4684   }
4685
4686   '';
4687 }
4688
4689 =item set_usage USAGE_VALUE_HASHREF
4690
4691 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4692 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4693 upbytes, downbytes, and totalbytes are appropriate keys.
4694
4695 All svc_accts which are part of this package have their values reset.
4696
4697 =cut
4698
4699 sub set_usage {
4700   my ($self, $valueref, %opt) = @_;
4701
4702   #only svc_acct can set_usage for now
4703   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4704     my $svc_x = $cust_svc->svc_x;
4705     $svc_x->set_usage($valueref, %opt)
4706       if $svc_x->can("set_usage");
4707   }
4708 }
4709
4710 =item recharge USAGE_VALUE_HASHREF
4711
4712 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4713 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4714 upbytes, downbytes, and totalbytes are appropriate keys.
4715
4716 All svc_accts which are part of this package have their values incremented.
4717
4718 =cut
4719
4720 sub recharge {
4721   my ($self, $valueref) = @_;
4722
4723   #only svc_acct can set_usage for now
4724   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4725     my $svc_x = $cust_svc->svc_x;
4726     $svc_x->recharge($valueref)
4727       if $svc_x->can("recharge");
4728   }
4729 }
4730
4731 =item apply_usageprice
4732
4733 =cut
4734
4735 sub apply_usageprice {
4736   my $self = shift;
4737
4738   my $oldAutoCommit = $FS::UID::AutoCommit;
4739   local $FS::UID::AutoCommit = 0;
4740   my $dbh = dbh;
4741
4742   my $error = '';
4743
4744   foreach my $cust_pkg_usageprice ( $self->cust_pkg_usageprice ) {
4745     $error ||= $cust_pkg_usageprice->apply;
4746   }
4747
4748   if ( $error ) {
4749     $dbh->rollback if $oldAutoCommit;
4750     die "error applying part_pkg_usageprice add-ons, pkgnum ". $self->pkgnum.
4751         ": $error\n";
4752   } else {
4753     $dbh->commit if $oldAutoCommit;
4754   }
4755
4756
4757 }
4758
4759 =item cust_pkg_discount
4760
4761 =item cust_pkg_discount_active
4762
4763 =cut
4764
4765 sub cust_pkg_discount_active {
4766   my $self = shift;
4767   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4768 }
4769
4770 =item cust_pkg_usage
4771
4772 Returns a list of all voice usage counters attached to this package.
4773
4774 =item apply_usage OPTIONS
4775
4776 Takes the following options:
4777 - cdr: a call detail record (L<FS::cdr>)
4778 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4779 - minutes: the maximum number of minutes to be charged
4780
4781 Finds available usage minutes for a call of this class, and subtracts
4782 up to that many minutes from the usage pool.  If the usage pool is empty,
4783 and the C<cdr-minutes_priority> global config option is set, minutes may
4784 be taken from other calls as well.  Either way, an allocation record will
4785 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4786 number of minutes of usage applied to the call.
4787
4788 =cut
4789
4790 sub apply_usage {
4791   my ($self, %opt) = @_;
4792   my $cdr = $opt{cdr};
4793   my $rate_detail = $opt{rate_detail};
4794   my $minutes = $opt{minutes};
4795   my $classnum = $rate_detail->classnum;
4796   my $pkgnum = $self->pkgnum;
4797   my $custnum = $self->custnum;
4798
4799   my $oldAutoCommit = $FS::UID::AutoCommit;
4800   local $FS::UID::AutoCommit = 0;
4801   my $dbh = dbh;
4802
4803   my $order = FS::Conf->new->config('cdr-minutes_priority');
4804
4805   my $is_classnum;
4806   if ( $classnum ) {
4807     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4808   } else {
4809     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4810   }
4811   my @usage_recs = qsearch({
4812       'table'     => 'cust_pkg_usage',
4813       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4814                      ' JOIN cust_pkg             USING (pkgnum)'.
4815                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4816       'select'    => 'cust_pkg_usage.*',
4817       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4818                      " ( cust_pkg.custnum = $custnum AND ".
4819                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4820                      $is_classnum . ' AND '.
4821                      " cust_pkg_usage.minutes > 0",
4822       'order_by'  => " ORDER BY priority ASC",
4823   });
4824
4825   my $orig_minutes = $minutes;
4826   my $error;
4827   while (!$error and $minutes > 0 and @usage_recs) {
4828     my $cust_pkg_usage = shift @usage_recs;
4829     $cust_pkg_usage->select_for_update;
4830     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4831         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4832         acctid      => $cdr->acctid,
4833         minutes     => min($cust_pkg_usage->minutes, $minutes),
4834     });
4835     $cust_pkg_usage->set('minutes',
4836       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4837     );
4838     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4839     $minutes -= $cdr_cust_pkg_usage->minutes;
4840   }
4841   if ( $order and $minutes > 0 and !$error ) {
4842     # then try to steal minutes from another call
4843     my %search = (
4844         'table'     => 'cdr_cust_pkg_usage',
4845         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4846                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4847                        ' JOIN cust_pkg              USING (pkgnum)'.
4848                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4849                        ' JOIN cdr                   USING (acctid)',
4850         'select'    => 'cdr_cust_pkg_usage.*',
4851         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4852                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4853                        " ( cust_pkg.custnum = $custnum AND ".
4854                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4855                        " part_pkg_usage_class.classnum = $classnum",
4856         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4857     );
4858     if ( $order eq 'time' ) {
4859       # find CDRs that are using minutes, but have a later startdate
4860       # than this call
4861       my $startdate = $cdr->startdate;
4862       if ($startdate !~ /^\d+$/) {
4863         die "bad cdr startdate '$startdate'";
4864       }
4865       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4866       # minimize needless reshuffling
4867       $search{'order_by'} .= ', cdr.startdate DESC';
4868     } else {
4869       # XXX may not work correctly with rate_time schedules.  Could
4870       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4871       # think...
4872       $search{'addl_from'} .=
4873         ' JOIN rate_detail'.
4874         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4875       if ( $order eq 'rate_high' ) {
4876         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4877                                 $rate_detail->min_charge;
4878         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4879       } elsif ( $order eq 'rate_low' ) {
4880         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4881                                 $rate_detail->min_charge;
4882         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4883       } else {
4884         #  this should really never happen
4885         die "invalid cdr-minutes_priority value '$order'\n";
4886       }
4887     }
4888     my @cdr_usage_recs = qsearch(\%search);
4889     my %reproc_cdrs;
4890     while (!$error and @cdr_usage_recs and $minutes > 0) {
4891       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4892       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4893       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4894       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4895       $cdr_cust_pkg_usage->select_for_update;
4896       $old_cdr->select_for_update;
4897       $cust_pkg_usage->select_for_update;
4898       # in case someone else stole the usage from this CDR
4899       # while waiting for the lock...
4900       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4901       # steal the usage allocation and flag the old CDR for reprocessing
4902       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4903       # if the allocation is more minutes than we need, adjust it...
4904       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4905       if ( $delta > 0 ) {
4906         $cdr_cust_pkg_usage->set('minutes', $minutes);
4907         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4908         $error = $cust_pkg_usage->replace;
4909       }
4910       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4911       $error ||= $cdr_cust_pkg_usage->replace;
4912       # deduct the stolen minutes
4913       $minutes -= $cdr_cust_pkg_usage->minutes;
4914     }
4915     # after all minute-stealing is done, reset the affected CDRs
4916     foreach (values %reproc_cdrs) {
4917       $error ||= $_->set_status('');
4918       # XXX or should we just call $cdr->rate right here?
4919       # it's not like we can create a loop this way, since the min_charge
4920       # or call time has to go monotonically in one direction.
4921       # we COULD get some very deep recursions going, though...
4922     }
4923   } # if $order and $minutes
4924   if ( $error ) {
4925     $dbh->rollback;
4926     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4927   } else {
4928     $dbh->commit if $oldAutoCommit;
4929     return $orig_minutes - $minutes;
4930   }
4931 }
4932
4933 =item supplemental_pkgs
4934
4935 Returns a list of all packages supplemental to this one.
4936
4937 =cut
4938
4939 sub supplemental_pkgs {
4940   my $self = shift;
4941   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4942 }
4943
4944 =item main_pkg
4945
4946 Returns the package that this one is supplemental to, if any.
4947
4948 =cut
4949
4950 sub main_pkg {
4951   my $self = shift;
4952   if ( $self->main_pkgnum ) {
4953     return FS::cust_pkg->by_key($self->main_pkgnum);
4954   }
4955   return;
4956 }
4957
4958 =back
4959
4960 =head1 CLASS METHODS
4961
4962 =over 4
4963
4964 =item recurring_sql
4965
4966 Returns an SQL expression identifying recurring packages.
4967
4968 =cut
4969
4970 sub recurring_sql { "
4971   '0' != ( select freq from part_pkg
4972              where cust_pkg.pkgpart = part_pkg.pkgpart )
4973 "; }
4974
4975 =item onetime_sql
4976
4977 Returns an SQL expression identifying one-time packages.
4978
4979 =cut
4980
4981 sub onetime_sql { "
4982   '0' = ( select freq from part_pkg
4983             where cust_pkg.pkgpart = part_pkg.pkgpart )
4984 "; }
4985
4986 =item ordered_sql
4987
4988 Returns an SQL expression identifying ordered packages (recurring packages not
4989 yet billed).
4990
4991 =cut
4992
4993 sub ordered_sql {
4994    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4995 }
4996
4997 =item active_sql
4998
4999 Returns an SQL expression identifying active packages.
5000
5001 =cut
5002
5003 sub active_sql {
5004   $_[0]->recurring_sql. "
5005   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
5006   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
5007   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
5008 "; }
5009
5010 =item not_yet_billed_sql
5011
5012 Returns an SQL expression identifying packages which have not yet been billed.
5013
5014 =cut
5015
5016 sub not_yet_billed_sql { "
5017       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
5018   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
5019   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
5020 "; }
5021
5022 =item inactive_sql
5023
5024 Returns an SQL expression identifying inactive packages (one-time packages
5025 that are otherwise unsuspended/uncancelled).
5026
5027 =cut
5028
5029 sub inactive_sql { "
5030   ". $_[0]->onetime_sql(). "
5031   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
5032   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
5033   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
5034 "; }
5035
5036 =item on_hold_sql
5037
5038 Returns an SQL expression identifying on-hold packages.
5039
5040 =cut
5041
5042 sub on_hold_sql {
5043   #$_[0]->recurring_sql(). ' AND '.
5044   "
5045         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
5046     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
5047     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
5048   ";
5049 }
5050
5051 =item susp_sql
5052 =item suspended_sql
5053
5054 Returns an SQL expression identifying suspended packages.
5055
5056 =cut
5057
5058 sub suspended_sql { susp_sql(@_); }
5059 sub susp_sql {
5060   #$_[0]->recurring_sql(). ' AND '.
5061   "
5062         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
5063     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
5064     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
5065   ";
5066 }
5067
5068 =item cancel_sql
5069 =item cancelled_sql
5070
5071 Returns an SQL exprression identifying cancelled packages.
5072
5073 =cut
5074
5075 sub cancelled_sql { cancel_sql(@_); }
5076 sub cancel_sql {
5077   #$_[0]->recurring_sql(). ' AND '.
5078   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
5079 }
5080
5081 =item ncancelled_recurring_sql
5082
5083 Returns an SQL expression identifying un-cancelled, recurring packages.
5084
5085 =cut
5086
5087 sub ncancelled_recurring_sql {
5088   $_[0]->recurring_sql().
5089   " AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 ) ";
5090 }
5091
5092 =item status_sql
5093
5094 Returns an SQL expression to give the package status as a string.
5095
5096 =cut
5097
5098 sub status_sql {
5099 "CASE
5100   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
5101   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
5102   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
5103   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
5104   WHEN ".onetime_sql()." THEN 'one-time charge'
5105   ELSE 'active'
5106 END"
5107 }
5108
5109 =item fcc_477_count
5110
5111 Returns a list of two package counts.  The first is a count of packages
5112 based on the supplied criteria and the second is the count of residential
5113 packages with those same criteria.  Criteria are specified as in the search
5114 method.
5115
5116 =cut
5117
5118 sub fcc_477_count {
5119   my ($class, $params) = @_;
5120
5121   my $sql_query = $class->search( $params );
5122
5123   my $count_sql = delete($sql_query->{'count_query'});
5124   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
5125     or die "couldn't parse count_sql";
5126
5127   my $count_sth = dbh->prepare($count_sql)
5128     or die "Error preparing $count_sql: ". dbh->errstr;
5129   $count_sth->execute
5130     or die "Error executing $count_sql: ". $count_sth->errstr;
5131   my $count_arrayref = $count_sth->fetchrow_arrayref;
5132
5133   return ( @$count_arrayref );
5134
5135 }
5136
5137 =item tax_locationnum_sql
5138
5139 Returns an SQL expression for the tax location for a package, based
5140 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
5141
5142 =cut
5143
5144 sub tax_locationnum_sql {
5145   my $conf = FS::Conf->new;
5146   if ( $conf->exists('tax-pkg_address') ) {
5147     'cust_pkg.locationnum';
5148   }
5149   elsif ( $conf->exists('tax-ship_address') ) {
5150     'cust_main.ship_locationnum';
5151   }
5152   else {
5153     'cust_main.bill_locationnum';
5154   }
5155 }
5156
5157 =item location_sql
5158
5159 Returns a list: the first item is an SQL fragment identifying matching
5160 packages/customers via location (taking into account shipping and package
5161 address taxation, if enabled), and subsequent items are the parameters to
5162 substitute for the placeholders in that fragment.
5163
5164 =cut
5165
5166 sub location_sql {
5167   my($class, %opt) = @_;
5168   my $ornull = $opt{'ornull'};
5169
5170   my $conf = new FS::Conf;
5171
5172   # '?' placeholders in _location_sql_where
5173   my $x = $ornull ? 3 : 2;
5174   my @bill_param = (
5175     ('district')x3,
5176     ('city')x3,
5177     ('county')x$x,
5178     ('state')x$x,
5179     'country'
5180   );
5181
5182   my $main_where;
5183   my @main_param;
5184   if ( $conf->exists('tax-ship_address') ) {
5185
5186     $main_where = "(
5187          (     ( ship_last IS NULL     OR  ship_last  = '' )
5188            AND ". _location_sql_where('cust_main', '', $ornull ). "
5189          )
5190       OR (       ship_last IS NOT NULL AND ship_last != ''
5191            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
5192          )
5193     )";
5194     #    AND payby != 'COMP'
5195
5196     @main_param = ( @bill_param, @bill_param );
5197
5198   } else {
5199
5200     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
5201     @main_param = @bill_param;
5202
5203   }
5204
5205   my $where;
5206   my @param;
5207   if ( $conf->exists('tax-pkg_address') ) {
5208
5209     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
5210
5211     $where = " (
5212                     ( cust_pkg.locationnum IS     NULL AND $main_where )
5213                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
5214                )
5215              ";
5216     @param = ( @main_param, @bill_param );
5217
5218   } else {
5219
5220     $where = $main_where;
5221     @param = @main_param;
5222
5223   }
5224
5225   ( $where, @param );
5226
5227 }
5228
5229 #subroutine, helper for location_sql
5230 sub _location_sql_where {
5231   my $table  = shift;
5232   my $prefix = @_ ? shift : '';
5233   my $ornull = @_ ? shift : '';
5234
5235 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
5236
5237   $ornull = $ornull ? ' OR ? IS NULL ' : '';
5238
5239   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
5240   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
5241   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
5242
5243   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
5244
5245 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
5246   "
5247         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5248     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5249     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
5250     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
5251     AND   $table.${prefix}country  = ?
5252   ";
5253 }
5254
5255 sub _X_show_zero {
5256   my( $self, $what ) = @_;
5257
5258   my $what_show_zero = $what. '_show_zero';
5259   length($self->$what_show_zero())
5260     ? ($self->$what_show_zero() eq 'Y')
5261     : $self->part_pkg->$what_show_zero();
5262 }
5263
5264 =head1 SUBROUTINES
5265
5266 =over 4
5267
5268 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
5269
5270 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
5271 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
5272
5273 CUSTNUM is a customer (see L<FS::cust_main>)
5274
5275 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5276 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
5277 permitted.
5278
5279 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
5280 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
5281 new billing items.  An error is returned if this is not possible (see
5282 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
5283 parameter.
5284
5285 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5286 newly-created cust_pkg objects.
5287
5288 REFNUM, if specified, will specify the FS::pkg_referral record to be created
5289 and inserted.  Multiple FS::pkg_referral records can be created by
5290 setting I<refnum> to an array reference of refnums or a hash reference with
5291 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5292 record will be created corresponding to cust_main.refnum.
5293
5294 =cut
5295
5296 sub order {
5297   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5298
5299   my $conf = new FS::Conf;
5300
5301   # Transactionize this whole mess
5302   my $oldAutoCommit = $FS::UID::AutoCommit;
5303   local $FS::UID::AutoCommit = 0;
5304   my $dbh = dbh;
5305
5306   my $error;
5307 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5308 #  return "Customer not found: $custnum" unless $cust_main;
5309
5310   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5311     if $DEBUG;
5312
5313   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5314                          @$remove_pkgnum;
5315
5316   my $change = scalar(@old_cust_pkg) != 0;
5317
5318   my %hash = ();
5319   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5320
5321     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5322          " to pkgpart ". $pkgparts->[0]. "\n"
5323       if $DEBUG;
5324
5325     my $err_or_cust_pkg =
5326       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5327                                 'refnum'  => $refnum,
5328                               );
5329
5330     unless (ref($err_or_cust_pkg)) {
5331       $dbh->rollback if $oldAutoCommit;
5332       return $err_or_cust_pkg;
5333     }
5334
5335     push @$return_cust_pkg, $err_or_cust_pkg;
5336     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5337     return '';
5338
5339   }
5340
5341   # Create the new packages.
5342   foreach my $pkgpart (@$pkgparts) {
5343
5344     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5345
5346     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5347                                       pkgpart => $pkgpart,
5348                                       refnum  => $refnum,
5349                                       %hash,
5350                                     };
5351     $error = $cust_pkg->insert( 'change' => $change );
5352     push @$return_cust_pkg, $cust_pkg;
5353
5354     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5355       my $supp_pkg = FS::cust_pkg->new({
5356           custnum => $custnum,
5357           pkgpart => $link->dst_pkgpart,
5358           refnum  => $refnum,
5359           main_pkgnum => $cust_pkg->pkgnum,
5360           %hash,
5361       });
5362       $error ||= $supp_pkg->insert( 'change' => $change );
5363       push @$return_cust_pkg, $supp_pkg;
5364     }
5365
5366     if ($error) {
5367       $dbh->rollback if $oldAutoCommit;
5368       return $error;
5369     }
5370
5371   }
5372   # $return_cust_pkg now contains refs to all of the newly
5373   # created packages.
5374
5375   # Transfer services and cancel old packages.
5376   foreach my $old_pkg (@old_cust_pkg) {
5377
5378     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5379       if $DEBUG;
5380
5381     foreach my $new_pkg (@$return_cust_pkg) {
5382       $error = $old_pkg->transfer($new_pkg);
5383       if ($error and $error == 0) {
5384         # $old_pkg->transfer failed.
5385         $dbh->rollback if $oldAutoCommit;
5386         return $error;
5387       }
5388     }
5389
5390     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5391       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5392       foreach my $new_pkg (@$return_cust_pkg) {
5393         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5394         if ($error and $error == 0) {
5395           # $old_pkg->transfer failed.
5396         $dbh->rollback if $oldAutoCommit;
5397         return $error;
5398         }
5399       }
5400     }
5401
5402     if ($error > 0) {
5403       # Transfers were successful, but we went through all of the
5404       # new packages and still had services left on the old package.
5405       # We can't cancel the package under the circumstances, so abort.
5406       $dbh->rollback if $oldAutoCommit;
5407       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5408     }
5409     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5410     if ($error) {
5411       $dbh->rollback;
5412       return $error;
5413     }
5414   }
5415   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5416   '';
5417 }
5418
5419 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5420
5421 A bulk change method to change packages for multiple customers.
5422
5423 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5424 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5425 permitted.
5426
5427 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5428 replace.  The services (see L<FS::cust_svc>) are moved to the
5429 new billing items.  An error is returned if this is not possible (see
5430 L<FS::pkg_svc>).
5431
5432 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5433 newly-created cust_pkg objects.
5434
5435 =cut
5436
5437 sub bulk_change {
5438   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5439
5440   # Transactionize this whole mess
5441   my $oldAutoCommit = $FS::UID::AutoCommit;
5442   local $FS::UID::AutoCommit = 0;
5443   my $dbh = dbh;
5444
5445   my @errors;
5446   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5447                          @$remove_pkgnum;
5448
5449   while(scalar(@old_cust_pkg)) {
5450     my @return = ();
5451     my $custnum = $old_cust_pkg[0]->custnum;
5452     my (@remove) = map { $_->pkgnum }
5453                    grep { $_->custnum == $custnum } @old_cust_pkg;
5454     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5455
5456     my $error = order $custnum, $pkgparts, \@remove, \@return;
5457
5458     push @errors, $error
5459       if $error;
5460     push @$return_cust_pkg, @return;
5461   }
5462
5463   if (scalar(@errors)) {
5464     $dbh->rollback if $oldAutoCommit;
5465     return join(' / ', @errors);
5466   }
5467
5468   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5469   '';
5470 }
5471
5472 =item forward_emails
5473
5474 Returns a hash of svcnums and corresponding email addresses
5475 for svc_acct services that can be used as source or dest
5476 for svc_forward services provisioned in this package.
5477
5478 Accepts options I<svc_forward> OR I<svcnum> for a svc_forward
5479 service;  if included, will ensure the current values of the
5480 specified service are included in the list, even if for some
5481 other reason they wouldn't be.  If called as a class method
5482 with a specified service, returns only these current values.
5483
5484 Caution: does not actually check if svc_forward services are
5485 available to be provisioned on this package.
5486
5487 =cut
5488
5489 sub forward_emails {
5490   my $self = shift;
5491   my %opt = @_;
5492
5493   #load optional service, thoroughly validated
5494   die "Use svcnum or svc_forward, not both"
5495     if $opt{'svcnum'} && $opt{'svc_forward'};
5496   my $svc_forward = $opt{'svc_forward'};
5497   $svc_forward ||= qsearchs('svc_forward',{ 'svcnum' => $opt{'svcnum'} })
5498     if $opt{'svcnum'};
5499   die "Specified service is not a forward service"
5500     if $svc_forward && (ref($svc_forward) ne 'FS::svc_forward');
5501   die "Specified service not found"
5502     if ($opt{'svcnum'} || $opt{'svc_forward'}) && !$svc_forward;
5503
5504   my %email;
5505
5506   ## everything below was basically copied from httemplate/edit/svc_forward.cgi
5507   ## with minimal refactoring, not sure why we can't just load all svc_accts for this custnum
5508
5509   #add current values from specified service, if there was one
5510   if ($svc_forward) {
5511     foreach my $method (qw( srcsvc_acct dstsvc_acct )) {
5512       my $svc_acct = $svc_forward->$method();
5513       $email{$svc_acct->svcnum} = $svc_acct->email if $svc_acct;
5514     }
5515   }
5516
5517   if (ref($self) eq 'FS::cust_pkg') {
5518
5519     #and including the rest for this customer
5520     my($u_part_svc,@u_acct_svcparts);
5521     foreach $u_part_svc ( qsearch('part_svc',{'svcdb'=>'svc_acct'}) ) {
5522       push @u_acct_svcparts,$u_part_svc->getfield('svcpart');
5523     }
5524
5525     my $custnum = $self->getfield('custnum');
5526     foreach my $i_cust_pkg ( qsearch('cust_pkg',{'custnum'=>$custnum}) ) {
5527       my $cust_pkgnum = $i_cust_pkg->getfield('pkgnum');
5528       #now find the corresponding record(s) in cust_svc (for this pkgnum!)
5529       foreach my $acct_svcpart (@u_acct_svcparts) {
5530         foreach my $i_cust_svc (
5531           qsearch( 'cust_svc', { 'pkgnum'  => $cust_pkgnum,
5532                                  'svcpart' => $acct_svcpart } )
5533         ) {
5534           my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $i_cust_svc->svcnum } );
5535           $email{$svc_acct->svcnum} = $svc_acct->email;
5536         }
5537       }
5538     }
5539   }
5540
5541   return %email;
5542 }
5543
5544 # Used by FS::Upgrade to migrate to a new database.
5545 sub _upgrade_data {  # class method
5546   my ($class, %opts) = @_;
5547   $class->_upgrade_otaker(%opts);
5548   my @statements = (
5549     # RT#10139, bug resulting in contract_end being set when it shouldn't
5550   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5551     # RT#10830, bad calculation of prorate date near end of year
5552     # the date range for bill is December 2009, and we move it forward
5553     # one year if it's before the previous bill date (which it should
5554     # never be)
5555   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5556   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5557   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5558     # RT6628, add order_date to cust_pkg
5559     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5560         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5561         history_action = \'insert\') where order_date is null',
5562   );
5563   foreach my $sql (@statements) {
5564     my $sth = dbh->prepare($sql);
5565     $sth->execute or die $sth->errstr;
5566   }
5567
5568   # RT31194: supplemental package links that are deleted don't clean up
5569   # linked records
5570   my @pkglinknums = qsearch({
5571       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5572       'table'     => 'cust_pkg',
5573       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5574       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5575                         AND part_pkg_link.pkglinknum IS NULL',
5576   });
5577   foreach (@pkglinknums) {
5578     my $pkglinknum = $_->pkglinknum;
5579     warn "cleaning part_pkg_link #$pkglinknum\n";
5580     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5581     my $error = $part_pkg_link->remove_linked;
5582     die $error if $error;
5583   }
5584
5585   # RT#73607: canceling a package with billing addons sometimes changes its
5586   # pkgpart.
5587   # Find records where the last replace_new record for the package before it
5588   # was canceled has a different pkgpart from the package itself.
5589   my @cust_pkg = qsearch({
5590     'table' => 'cust_pkg',
5591     'select' => 'cust_pkg.*, h_cust_pkg.pkgpart AS h_pkgpart',
5592     'addl_from' => ' JOIN (
5593   SELECT pkgnum, MAX(historynum) AS historynum FROM h_cust_pkg
5594     WHERE cancel IS NULL
5595       AND history_action = \'replace_new\'
5596     GROUP BY pkgnum
5597   ) AS last_history USING (pkgnum)
5598   JOIN h_cust_pkg USING (historynum)',
5599     'extra_sql' => ' WHERE cust_pkg.cancel is not null
5600                      AND cust_pkg.pkgpart != h_cust_pkg.pkgpart'
5601   });
5602   foreach my $cust_pkg ( @cust_pkg ) {
5603     my $pkgnum = $cust_pkg->pkgnum;
5604     warn "fixing pkgpart on canceled pkg#$pkgnum\n";
5605     $cust_pkg->set('pkgpart', $cust_pkg->h_pkgpart);
5606     my $error = $cust_pkg->replace;
5607     die $error if $error;
5608   }
5609
5610 }
5611
5612 =back
5613
5614 =head1 BUGS
5615
5616 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5617
5618 In sub order, the @pkgparts array (passed by reference) is clobbered.
5619
5620 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5621 method to pass dates to the recur_prog expression, it should do so.
5622
5623 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5624 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5625 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5626 configuration values.  Probably need a subroutine which decides what to do
5627 based on whether or not we've fetched the user yet, rather than a hash.  See
5628 FS::UID and the TODO.
5629
5630 Now that things are transactional should the check in the insert method be
5631 moved to check ?
5632
5633 =head1 SEE ALSO
5634
5635 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5636 L<FS::pkg_svc>, schema.html from the base documentation
5637
5638 =cut
5639
5640 1;
5641