FS/FS/cust_pay_void.pm

   1 package FS::cust_pay_void;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::payinfo_transaction_Mixin FS::cust_main_Mixin
   5              FS::Record );
   6 use vars qw( @encrypted_fields $otaker_upgrade_kludge );
   7 use Business::CreditCard;
   8 use FS::UID qw(getotaker);
   9 use FS::Record qw(qsearch qsearchs dbh fields);
  10 use FS::CurrentUser;
  11 use FS::access_user;
  12 use FS::cust_pay;
  13 #use FS::cust_bill;
  14 #use FS::cust_bill_pay;
  15 #use FS::cust_pay_refund;
  16 #use FS::cust_main;
  17 use FS::cust_pkg;
  18
  19 @encrypted_fields = ('payinfo');
  20 sub nohistory_fields { ('payinfo'); }
  21
  22 $otaker_upgrade_kludge = 0;
  23
  24 =head1 NAME
  25
  26 FS::cust_pay_void - Object methods for cust_pay_void objects
  27
  28 =head1 SYNOPSIS
  29
  30   use FS::cust_pay_void;
  31
  32   $record = new FS::cust_pay_void \%hash;
  33   $record = new FS::cust_pay_void { 'column' => 'value' };
  34
  35   $error = $record->insert;
  36
  37   $error = $new_record->replace($old_record);
  38
  39   $error = $record->delete;
  40
  41   $error = $record->check;
  42
  43 =head1 DESCRIPTION
  44
  45 An FS::cust_pay_void object represents a voided payment.  The following fields
  46 are currently supported:
  47
  48 =over 4
  49
  50 =item paynum
  51
  52 primary key (assigned automatically for new payments)
  53
  54 =item custnum
  55
  56 customer (see L<FS::cust_main>)
  57
  58 =item paid
  59
  60 Amount of this payment
  61
  62 =item _date
  63
  64 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  65 L<Time::Local> and L<Date::Parse> for conversion functions.
  66
  67 =item otaker
  68
  69 order taker (see L<FS::access_user>)
  70
  71 =item payby
  72
  73 Payment Type (See L<FS::payinfo_Mixin> for valid values)
  74
  75 =item payinfo
  76
  77 card number, check #, or comp issuer (4-8 lowercase alphanumerics; think username), respectively
  78
  79 =item paybatch
  80
  81 text field for tracking card processing
  82
  83 =item closed
  84
  85 books closed flag, empty or `Y'
  86
  87 =item pkgnum
  88
  89 Desired pkgnum when using experimental package balances.
  90
  91 =item void_date
  92
  93 =item reason
  94
  95 =back
  96
  97 =head1 METHODS
  98
  99 =over 4
 100
 101 =item new HASHREF
 102
 103 Creates a new payment.  To add the payment to the databse, see L<"insert">.
 104
 105 =cut
 106
 107 sub table { 'cust_pay_void'; }
 108
 109 =item insert
 110
 111 Adds this voided payment to the database.
 112
 113 =item unvoid
 114
 115 "Un-void"s this payment: Deletes the voided payment from the database and adds
 116 back a normal payment.
 117
 118 =cut
 119
 120 sub unvoid {
 121   my $self = shift;
 122
 123   local $SIG{HUP} = 'IGNORE';
 124   local $SIG{INT} = 'IGNORE';
 125   local $SIG{QUIT} = 'IGNORE';
 126   local $SIG{TERM} = 'IGNORE';
 127   local $SIG{TSTP} = 'IGNORE';
 128   local $SIG{PIPE} = 'IGNORE';
 129
 130   my $oldAutoCommit = $FS::UID::AutoCommit;
 131   local $FS::UID::AutoCommit = 0;
 132   my $dbh = dbh;
 133
 134   my $cust_pay = new FS::cust_pay ( {
 135     map { $_ => $self->get($_) } fields('cust_pay')
 136   } );
 137   my $error = $cust_pay->insert;
 138
 139   my $cust_pay_pending =
 140     qsearchs('cust_pay_pending', { void_paynum => $self->paynum });
 141   if ( $cust_pay_pending ) {
 142     $cust_pay_pending->set('paynum', $cust_pay->paynum);
 143     $cust_pay_pending->set('void_paynum', '');
 144     $error ||= $cust_pay_pending->replace;
 145   }
 146
 147   $error ||= $self->delete;
 148   if ( $error ) {
 149     $dbh->rollback if $oldAutoCommit;
 150     return $error;
 151   }
 152
 153   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 154
 155   '';
 156
 157 }
 158
 159 =item delete
 160
 161 Deletes this voided payment.  You probably don't want to use this directly; see
 162 the B<unvoid> method to add the original payment back.
 163
 164 =item replace [ OLD_RECORD ]
 165
 166 You can, but probably shouldn't modify voided payments...
 167
 168 Replaces the OLD_RECORD with this one in the database, or, if OLD_RECORD is not
 169 supplied, replaces this record.  If there is an error, returns the error,
 170 otherwise returns false.
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid voided payment.  If there is an
 175 error, returns the error, otherwise returns false.  Called by the insert
 176 method.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('paynum')
 185     || $self->ut_numbern('custnum')
 186     || $self->ut_money('paid')
 187     || $self->ut_number('_date')
 188     || $self->ut_textn('paybatch')
 189     || $self->ut_enum('closed', [ '', 'Y' ])
 190     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 191     || $self->ut_numbern('void_date')
 192     || $self->ut_textn('reason')
 193     || $self->payinfo_check
 194   ;
 195   return $error if $error;
 196
 197   return "paid must be > 0 " if $self->paid <= 0;
 198
 199   return "unknown cust_main.custnum: ". $self->custnum
 200     unless $self->invnum
 201            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 202
 203   $self->void_date(time) unless $self->void_date;
 204
 205   $self->void_usernum($FS::CurrentUser::CurrentUser->usernum)
 206     unless $self->void_usernum;
 207
 208   $self->SUPER::check;
 209 }
 210
 211 =item cust_main
 212
 213 Returns the parent customer object (see L<FS::cust_main>).
 214
 215 =cut
 216
 217 sub cust_main {
 218   my $self = shift;
 219   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 220 }
 221
 222 =item void_access_user
 223
 224 Returns the voiding employee object (see L<FS::access_user>).
 225
 226 =cut
 227
 228 sub void_access_user {
 229   my $self = shift;
 230   qsearchs('access_user', { 'usernum' => $self->void_usernum } );
 231 }
 232
 233 # Used by FS::Upgrade to migrate to a new database.
 234 sub _upgrade_data {  # class method
 235   my ($class, %opts) = @_;
 236
 237   my $sql = "SELECT usernum FROM access_user WHERE username = ( SELECT history_user FROM h_cust_pay_void WHERE paynum = ? AND history_action = 'insert' ORDER BY history_date LIMIT 1 ) ";
 238   my $sth = dbh->prepare($sql) or die dbh->errstr;
 239
 240   foreach my $cust_pay_void (qsearch('cust_pay_void', {'void_usernum' => ''})) {
 241     $sth->execute($cust_pay_void->paynum) or die $sth->errstr;
 242     my $row = $sth->fetchrow_arrayref;
 243     my $usernum = $row ? $row->[0] : '';
 244     if ( $usernum ) {
 245       $cust_pay_void->void_usernum($usernum);
 246       my $error = $cust_pay_void->replace;
 247       die $error if $error;
 248     } else {
 249       warn "cust_pay_void upgrade: can't find access_user record for ". $cust_pay_void->paynum. "\n";
 250     }
 251   }
 252
 253   local($otaker_upgrade_kludge) = 1;
 254   $class->_upgrade_otaker(%opts);
 255
 256   #XXX look for the h_cust_pay delete records and when that's a different
 257   # usernum, set usernum
 258 }
 259
 260 =back
 261
 262 =head1 BUGS
 263
 264 Delete and replace methods.
 265
 266 =head1 SEE ALSO
 267
 268 L<FS::cust_pay>, L<FS::Record>, schema.html from the base documentation.
 269
 270 =cut
 271
 272 1;
 273