FS/FS/cust_pay_void.pm

   1 package FS::cust_pay_void;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
   5              FS::Record );
   6 use vars qw( @encrypted_fields $otaker_upgrade_kludge );
   7 use Business::CreditCard;
   8 use FS::UID qw(getotaker);
   9 use FS::Record qw(qsearch qsearchs dbh fields);
  10 use FS::CurrentUser;
  11 use FS::access_user;
  12 use FS::cust_pay;
  13 #use FS::cust_bill;
  14 #use FS::cust_bill_pay;
  15 #use FS::cust_pay_refund;
  16 #use FS::cust_main;
  17 use FS::cust_pkg;
  18
  19 @encrypted_fields = ('payinfo');
  20 $otaker_upgrade_kludge = 0;
  21
  22 =head1 NAME
  23
  24 FS::cust_pay_void - Object methods for cust_pay_void objects
  25
  26 =head1 SYNOPSIS
  27
  28   use FS::cust_pay_void;
  29
  30   $record = new FS::cust_pay_void \%hash;
  31   $record = new FS::cust_pay_void { 'column' => 'value' };
  32
  33   $error = $record->insert;
  34
  35   $error = $new_record->replace($old_record);
  36
  37   $error = $record->delete;
  38
  39   $error = $record->check;
  40
  41 =head1 DESCRIPTION
  42
  43 An FS::cust_pay_void object represents a voided payment.  The following fields
  44 are currently supported:
  45
  46 =over 4
  47
  48 =item paynum
  49
  50 primary key (assigned automatically for new payments)
  51
  52 =item custnum
  53
  54 customer (see L<FS::cust_main>)
  55
  56 =item paid
  57
  58 Amount of this payment
  59
  60 =item _date
  61
  62 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  63 L<Time::Local> and L<Date::Parse> for conversion functions.
  64
  65 =item otaker
  66
  67 order taker (see L<FS::access_user>)
  68
  69 =item payby
  70
  71 Payment Type (See L<FS::payinfo_Mixin> for valid values)
  72
  73 =item payinfo
  74
  75 card number, check #, or comp issuer (4-8 lowercase alphanumerics; think username), respectively
  76
  77 =item paybatch
  78
  79 text field for tracking card processing
  80
  81 =item closed
  82
  83 books closed flag, empty or `Y'
  84
  85 =item pkgnum
  86
  87 Desired pkgnum when using experimental package balances.
  88
  89 =item void_date
  90
  91 =item reason
  92
  93 =back
  94
  95 =head1 METHODS
  96
  97 =over 4
  98
  99 =item new HASHREF
 100
 101 Creates a new payment.  To add the payment to the databse, see L<"insert">.
 102
 103 =cut
 104
 105 sub table { 'cust_pay_void'; }
 106
 107 =item insert
 108
 109 Adds this voided payment to the database.
 110
 111 =item unvoid
 112
 113 "Un-void"s this payment: Deletes the voided payment from the database and adds
 114 back a normal payment.
 115
 116 =cut
 117
 118 sub unvoid {
 119   my $self = shift;
 120
 121   local $SIG{HUP} = 'IGNORE';
 122   local $SIG{INT} = 'IGNORE';
 123   local $SIG{QUIT} = 'IGNORE';
 124   local $SIG{TERM} = 'IGNORE';
 125   local $SIG{TSTP} = 'IGNORE';
 126   local $SIG{PIPE} = 'IGNORE';
 127
 128   my $oldAutoCommit = $FS::UID::AutoCommit;
 129   local $FS::UID::AutoCommit = 0;
 130   my $dbh = dbh;
 131
 132   my $cust_pay = new FS::cust_pay ( {
 133     map { $_ => $self->get($_) } fields('cust_pay')
 134   } );
 135   my $error = $cust_pay->insert;
 136   if ( $error ) {
 137     $dbh->rollback if $oldAutoCommit;
 138     return $error;
 139   }
 140
 141   $error = $self->delete;
 142   if ( $error ) {
 143     $dbh->rollback if $oldAutoCommit;
 144     return $error;
 145   }
 146
 147   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 148
 149   '';
 150
 151 }
 152
 153 =item delete
 154
 155 Deletes this voided payment.  You probably don't want to use this directly; see
 156 the B<unvoid> method to add the original payment back.
 157
 158 =item replace [ OLD_RECORD ]
 159
 160 You can, but probably shouldn't modify voided payments...
 161
 162 Replaces the OLD_RECORD with this one in the database, or, if OLD_RECORD is not
 163 supplied, replaces this record.  If there is an error, returns the error,
 164 otherwise returns false.
 165
 166 =item check
 167
 168 Checks all fields to make sure this is a valid voided payment.  If there is an
 169 error, returns the error, otherwise returns false.  Called by the insert
 170 method.
 171
 172 =cut
 173
 174 sub check {
 175   my $self = shift;
 176
 177   my $error =
 178     $self->ut_numbern('paynum')
 179     || $self->ut_numbern('custnum')
 180     || $self->ut_money('paid')
 181     || $self->ut_number('_date')
 182     || $self->ut_textn('paybatch')
 183     || $self->ut_enum('closed', [ '', 'Y' ])
 184     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 185     || $self->ut_numbern('void_date')
 186     || $self->ut_textn('reason')
 187     || $self->payinfo_check
 188   ;
 189   return $error if $error;
 190
 191   return "paid must be > 0 " if $self->paid <= 0;
 192
 193   return "unknown cust_main.custnum: ". $self->custnum
 194     unless $self->invnum
 195            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 196
 197   $self->void_date(time) unless $self->void_date;
 198
 199   $self->void_usernum($FS::CurrentUser::CurrentUser->usernum)
 200     unless $self->void_usernum;
 201
 202   $self->SUPER::check;
 203 }
 204
 205 =item cust_main
 206
 207 Returns the parent customer object (see L<FS::cust_main>).
 208
 209 =cut
 210
 211 sub cust_main {
 212   my $self = shift;
 213   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 214 }
 215
 216 =item void_access_user
 217
 218 Returns the voiding employee object (see L<FS::access_user>).
 219
 220 =cut
 221
 222 sub void_access_user {
 223   my $self = shift;
 224   qsearchs('access_user', { 'usernum' => $self->void_usernum } );
 225 }
 226
 227 # Used by FS::Upgrade to migrate to a new database.
 228 sub _upgrade_data {  # class method
 229   my ($class, %opts) = @_;
 230
 231   my $sql = "SELECT usernum FROM access_user WHERE username = ( SELECT history_user FROM h_cust_pay_void WHERE paynum = ? AND history_action = 'insert' ORDER BY history_date LIMIT 1 ) ";
 232   my $sth = dbh->prepare($sql) or die dbh->errstr;
 233
 234   foreach my $cust_pay_void (qsearch('cust_pay_void', {'void_usernum' => ''})) {
 235     $sth->execute($cust_pay_void->paynum) or die $sth->errstr;
 236     my $row = $sth->fetchrow_arrayref;
 237     my $usernum = $row ? $row->[0] : '';
 238     if ( $usernum ) {
 239       $cust_pay_void->void_usernum($usernum);
 240       my $error = $cust_pay_void->replace;
 241       die $error if $error;
 242     } else {
 243       warn "cust_pay_void upgrade: can't find access_user record for ". $cust_pay_void->paynum. "\n";
 244     }
 245   }
 246
 247   local($otaker_upgrade_kludge) = 1;
 248   $class->_upgrade_otaker(%opts);
 249
 250   #XXX look for the h_cust_pay delete records and when that's a different
 251   # usernum, set usernum
 252 }
 253
 254 =back
 255
 256 =head1 BUGS
 257
 258 Delete and replace methods.
 259
 260 =head1 SEE ALSO
 261
 262 L<FS::cust_pay>, L<FS::Record>, schema.html from the base documentation.
 263
 264 =cut
 265
 266 1;
 267