FS/FS/cust_pay_batch.pm

   1 package FS::cust_pay_batch;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG );
   5 use Carp qw( confess );
   6 use Business::CreditCard 0.28;
   7 use FS::Record qw(dbh qsearch qsearchs);
   8 use FS::payinfo_Mixin;
   9 use FS::cust_main;
  10 use FS::cust_bill;
  11
  12 @ISA = qw( FS::payinfo_Mixin FS::cust_main_Mixin FS::Record );
  13
  14 # 1 is mostly method/subroutine entry and options
  15 # 2 traces progress of some operations
  16 # 3 is even more information including possibly sensitive data
  17 $DEBUG = 0;
  18
  19 =head1 NAME
  20
  21 FS::cust_pay_batch - Object methods for batch cards
  22
  23 =head1 SYNOPSIS
  24
  25   use FS::cust_pay_batch;
  26
  27   $record = new FS::cust_pay_batch \%hash;
  28   $record = new FS::cust_pay_batch { 'column' => 'value' };
  29
  30   $error = $record->insert;
  31
  32   $error = $new_record->replace($old_record);
  33
  34   $error = $record->delete;
  35
  36   $error = $record->check;
  37
  38   #deprecated# $error = $record->retriable;
  39
  40 =head1 DESCRIPTION
  41
  42 An FS::cust_pay_batch object represents a credit card transaction ready to be
  43 batched (sent to a processor).  FS::cust_pay_batch inherits from FS::Record.
  44 Typically called by the collect method of an FS::cust_main object.  The
  45 following fields are currently supported:
  46
  47 =over 4
  48
  49 =item paybatchnum - primary key (automatically assigned)
  50
  51 =item batchnum - indentifies group in batch
  52
  53 =item payby - CARD/CHEK/LECB/BILL/COMP
  54
  55 =item payinfo
  56
  57 =item exp - card expiration
  58
  59 =item amount
  60
  61 =item invnum - invoice
  62
  63 =item custnum - customer
  64
  65 =item payname - name on card
  66
  67 =item first - name
  68
  69 =item last - name
  70
  71 =item address1
  72
  73 =item address2
  74
  75 =item city
  76
  77 =item state
  78
  79 =item zip
  80
  81 =item country
  82
  83 =item status - 'Approved' or 'Declined'
  84
  85 =item error_message - the error returned by the gateway if any
  86
  87 =back
  88
  89 =head1 METHODS
  90
  91 =over 4
  92
  93 =item new HASHREF
  94
  95 Creates a new record.  To add the record to the database, see L<"insert">.
  96
  97 Note that this stores the hash reference, not a distinct copy of the hash it
  98 points to.  You can ask the object for a copy with the I<hash> method.
  99
 100 =cut
 101
 102 sub table { 'cust_pay_batch'; }
 103
 104 =item insert
 105
 106 Adds this record to the database.  If there is an error, returns the error,
 107 otherwise returns false.
 108
 109 =item delete
 110
 111 Delete this record from the database.  If there is an error, returns the error,
 112 otherwise returns false.
 113
 114 =item replace OLD_RECORD
 115
 116 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 117 returns the error, otherwise returns false.
 118
 119 =item check
 120
 121 Checks all fields to make sure this is a valid transaction.  If there is
 122 an error, returns the error, otherwise returns false.  Called by the insert
 123 and replace methods.
 124
 125 =cut
 126
 127 sub check {
 128   my $self = shift;
 129
 130   my $error =
 131       $self->ut_numbern('paybatchnum')
 132     || $self->ut_numbern('trancode') #deprecated
 133     || $self->ut_money('amount')
 134     || $self->ut_number('invnum')
 135     || $self->ut_number('custnum')
 136     || $self->ut_text('address1')
 137     || $self->ut_textn('address2')
 138     || $self->ut_text('city')
 139     || $self->ut_textn('state')
 140   ;
 141
 142   return $error if $error;
 143
 144   $self->getfield('last') =~ /^([\w \,\.\-\']+)$/ or return "Illegal last name";
 145   $self->setfield('last',$1);
 146
 147   $self->first =~ /^([\w \,\.\-\']+)$/ or return "Illegal first name";
 148   $self->first($1);
 149
 150   $error = $self->payinfo_check();
 151   return $error if $error;
 152
 153   if ( $self->exp eq '' ) {
 154     return "Expiration date required"
 155       unless $self->payby =~ /^(CHEK|DCHK|LECB|WEST)$/;
 156     $self->exp('');
 157   } else {
 158     if ( $self->exp =~ /^(\d{4})[\/\-](\d{1,2})[\/\-](\d{1,2})$/ ) {
 159       $self->exp("$1-$2-$3");
 160     } elsif ( $self->exp =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 161       if ( length($2) == 4 ) {
 162         $self->exp("$2-$1-01");
 163       } elsif ( $2 > 98 ) { #should pry change to check for "this year"
 164         $self->exp("19$2-$1-01");
 165       } else {
 166         $self->exp("20$2-$1-01");
 167       }
 168     } else {
 169       return "Illegal expiration date";
 170     }
 171   }
 172
 173   if ( $self->payname eq '' ) {
 174     $self->payname( $self->first. " ". $self->getfield('last') );
 175   } else {
 176     $self->payname =~ /^([\w \,\.\-\']+)$/
 177       or return "Illegal billing name";
 178     $self->payname($1);
 179   }
 180
 181   #we have lots of old zips in there... don't hork up batch results cause of em
 182   $self->zip =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
 183     or return "Illegal zip: ". $self->zip;
 184   $self->zip($1);
 185
 186   $self->country =~ /^(\w\w)$/ or return "Illegal country: ". $self->country;
 187   $self->country($1);
 188
 189   #$error = $self->ut_zip('zip', $self->country);
 190   #return $error if $error;
 191
 192   #check invnum, custnum, ?
 193
 194   $self->SUPER::check;
 195 }
 196
 197 =item cust_main
 198
 199 Returns the customer (see L<FS::cust_main>) for this batched credit card
 200 payment.
 201
 202 =cut
 203
 204 sub cust_main {
 205   my $self = shift;
 206   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 207 }
 208
 209 =item pay_batch
 210
 211 Returns the payment batch this payment belongs to (L<FS::pay_batch).
 212
 213 =cut
 214
 215 sub pay_batch {
 216   my $self = shift;
 217   FS::pay_batch->by_key($self->batchnum);
 218 }
 219
 220 #you know what, screw this in the new world of events.  we should be able to
 221 #get the event defs to retry (remove once.pm condition, add every.pm) without
 222 #mucking about with statuses of previous cust_event records.  right?
 223 #
 224 #=item retriable
 225 #
 226 #Marks the corresponding event (see L<FS::cust_bill_event>) for this batched
 227 #credit card payment as retriable.  Useful if the corresponding financial
 228 #institution account was declined for temporary reasons and/or a manual
 229 #retry is desired.
 230 #
 231 #Implementation details: For the named customer's invoice, changes the
 232 #statustext of the 'done' (without statustext) event to 'retriable.'
 233 #
 234 #=cut
 235
 236 sub retriable {
 237
 238   confess "deprecated method cust_pay_batch->retriable called; try removing ".
 239           "the once condition and adding an every condition?";
 240
 241   my $self = shift;
 242
 243   local $SIG{HUP} = 'IGNORE';        #Hmm
 244   local $SIG{INT} = 'IGNORE';
 245   local $SIG{QUIT} = 'IGNORE';
 246   local $SIG{TERM} = 'IGNORE';
 247   local $SIG{TSTP} = 'IGNORE';
 248   local $SIG{PIPE} = 'IGNORE';
 249
 250   my $oldAutoCommit = $FS::UID::AutoCommit;
 251   local $FS::UID::AutoCommit = 0;
 252   my $dbh = dbh;
 253
 254   my $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 255     or return "event $self->eventnum references nonexistant invoice $self->invnum";
 256
 257   warn "cust_pay_batch->retriable working with self of " . $self->paybatchnum . " and invnum of " . $self->invnum;
 258   my @cust_bill_event =
 259     sort { $a->part_bill_event->seconds <=> $b->part_bill_event->seconds }
 260       grep {
 261         $_->part_bill_event->eventcode =~ /\$cust_bill->batch_card/
 262           && $_->status eq 'done'
 263           && ! $_->statustext
 264         }
 265       $cust_bill->cust_bill_event;
 266   # complain loudly if scalar(@cust_bill_event) > 1 ?
 267   my $error = $cust_bill_event[0]->retriable;
 268   if ($error ) {
 269     # gah, even with transactions.
 270     $dbh->commit if $oldAutoCommit; #well.
 271     return "error marking invoice event retriable: $error";
 272   }
 273   '';
 274 }
 275
 276 =item approve PAYBATCH
 277
 278 Approve this payment.  This will replace the existing record with the
 279 same paybatchnum, set its status to 'Approved', and generate a payment
 280 record (L<FS::cust_pay>).  This should only be called from the batch
 281 import process.
 282
 283 =cut
 284
 285 sub approve {
 286   # to break up the Big Wall of Code that is import_results
 287   my $new = shift;
 288   my $paybatch = shift;
 289   my $paybatchnum = $new->paybatchnum;
 290   my $old = qsearchs('cust_pay_batch', { paybatchnum => $paybatchnum })
 291     or return "paybatchnum $paybatchnum not found";
 292   return "paybatchnum $paybatchnum already resolved ('".$old->status."')"
 293     if $old->status;
 294   $new->status('Approved');
 295   my $error = $new->replace($old);
 296   if ( $error ) {
 297     return "error updating status of paybatchnum $paybatchnum: $error\n";
 298   }
 299   my $cust_pay = new FS::cust_pay ( {
 300       'custnum'   => $new->custnum,
 301       'payby'     => $new->payby,
 302       'paybatch'  => $paybatch,
 303       'payinfo'   => $new->payinfo || $old->payinfo,
 304       'paid'      => $new->paid,
 305       '_date'     => $new->_date,
 306       'usernum'   => $new->usernum,
 307       'batchnum'  => $new->batchnum,
 308     } );
 309   $error = $cust_pay->insert;
 310   if ( $error ) {
 311     return "error inserting payment for paybatchnum $paybatchnum: $error\n";
 312   }
 313   $cust_pay->cust_main->apply_payments;
 314   return;
 315 }
 316
 317 =item decline [ REASON ]
 318
 319 Decline this payment.  This will replace the existing record with the
 320 same paybatchnum, set its status to 'Declined', and run collection events
 321 as appropriate.  This should only be called from the batch import process.
 322
 323 REASON is a string description of the decline reason, defaulting to
 324 'Returned payment'.
 325
 326 =cut
 327
 328 sub decline {
 329   my $new = shift;
 330   my $reason = shift || 'Returned payment';
 331   #my $conf = new FS::Conf;
 332
 333   my $paybatchnum = $new->paybatchnum;
 334   my $old = qsearchs('cust_pay_batch', { paybatchnum => $paybatchnum })
 335     or return "paybatchnum $paybatchnum not found";
 336   if ( $old->status ) {
 337     # Handle the case where payments are rejected after the batch has been
 338     # approved.  FS::pay_batch::import_results won't allow results to be
 339     # imported to a closed batch unless batch-manual_approval is enabled,
 340     # so we don't check it here.
 341 #    if ( $conf->exists('batch-manual_approval') and
 342     if ( lc($old->status) eq 'approved' ) {
 343       # Void the payment
 344       my $cust_pay = qsearchs('cust_pay', {
 345           custnum  => $new->custnum,
 346           batchnum => $new->batchnum
 347         });
 348       # pre-3.0 style
 349       $cust_pay ||= qsearchs('cust_pay', {
 350           custnum  => $new->custnum,
 351           paybatch => $new->batchnum
 352         });
 353       if ( !$cust_pay ) {
 354         # should never happen...
 355         return "failed to revoke paybatchnum $paybatchnum, payment not found";
 356       }
 357       $cust_pay->void($reason);
 358     }
 359     else {
 360       # normal case: refuse to do anything
 361       return "paybatchnum $paybatchnum already resolved ('".$old->status."')";
 362     }
 363   } # !$old->status
 364   $new->status('Declined');
 365   $new->error_message($reason);
 366   my $error = $new->replace($old);
 367   if ( $error ) {
 368     return "error updating status of paybatchnum $paybatchnum: $error\n";
 369   }
 370   my $due_cust_event = $new->cust_main->due_cust_event(
 371     'eventtable'  => 'cust_pay_batch',
 372     'objects'     => [ $new ],
 373   );
 374   if ( !ref($due_cust_event) ) {
 375     return $due_cust_event;
 376   }
 377   # XXX breaks transaction integrity
 378   foreach my $cust_event (@$due_cust_event) {
 379     next unless $cust_event->test_conditions;
 380     if ( my $error = $cust_event->do_event() ) {
 381       return $error;
 382     }
 383   }
 384   return;
 385 }
 386
 387 =back
 388
 389 =head1 BUGS
 390
 391 There should probably be a configuration file with a list of allowed credit
 392 card types.
 393
 394 =head1 SEE ALSO
 395
 396 L<FS::cust_main>, L<FS::Record>
 397
 398 =cut
 399
 400 1;
 401