FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $conf @encrypted_fields
   5              $unsuspendauto $ignore_noapply
   6            );
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Text::Template;
  10 use FS::UID qw( getotaker );
  11 use FS::Misc qw( send_email );
  12 use FS::Record qw( dbh qsearch qsearchs );
  13 use FS::payby;
  14 use FS::cust_main_Mixin;
  15 use FS::payinfo_transaction_Mixin;
  16 use FS::cust_bill;
  17 use FS::cust_bill_pay;
  18 use FS::cust_pay_refund;
  19 use FS::cust_main;
  20 use FS::cust_pay_void;
  21
  22 @ISA = qw( FS::payinfo_transaction_Mixin FS::cust_main_Mixin FS::Record );
  23
  24 $DEBUG = 1;
  25
  26 $me = '[FS::cust_pay]';
  27
  28 $ignore_noapply = 0;
  29
  30 #ask FS::UID to run this stuff for us later
  31 FS::UID->install_callback( sub {
  32   $conf = new FS::Conf;
  33   $unsuspendauto = $conf->exists('unsuspendauto');
  34 } );
  35
  36 @encrypted_fields = ('payinfo');
  37
  38 =head1 NAME
  39
  40 FS::cust_pay - Object methods for cust_pay objects
  41
  42 =head1 SYNOPSIS
  43
  44   use FS::cust_pay;
  45
  46   $record = new FS::cust_pay \%hash;
  47   $record = new FS::cust_pay { 'column' => 'value' };
  48
  49   $error = $record->insert;
  50
  51   $error = $new_record->replace($old_record);
  52
  53   $error = $record->delete;
  54
  55   $error = $record->check;
  56
  57 =head1 DESCRIPTION
  58
  59 An FS::cust_pay object represents a payment; the transfer of money from a
  60 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  61 currently supported:
  62
  63 =over 4
  64
  65 =item paynum - primary key (assigned automatically for new payments)
  66
  67 =item custnum - customer (see L<FS::cust_main>)
  68
  69 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  70 L<Time::Local> and L<Date::Parse> for conversion functions.
  71
  72 =item paid - Amount of this payment
  73
  74 =item otaker - order taker (assigned automatically, see L<FS::UID>)
  75
  76 =item payby - Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
  77
  78 =item payinfo - Payment Information (See L<FS::payinfo_Mixin> for data format)
  79
  80 =item paymask - Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
  81
  82 =item paybatch - text field for tracking card processing or other batch grouping
  83
  84 =item payunique - Optional unique identifer to prevent duplicate transactions.
  85
  86 =item closed - books closed flag, empty or `Y'
  87
  88 =back
  89
  90 =head1 METHODS
  91
  92 =over 4
  93
  94 =item new HASHREF
  95
  96 Creates a new payment.  To add the payment to the databse, see L<"insert">.
  97
  98 =cut
  99
 100 sub table { 'cust_pay'; }
 101 sub cust_linked { $_[0]->cust_main_custnum; }
 102 sub cust_unlinked_msg {
 103   my $self = shift;
 104   "WARNING: can't find cust_main.custnum ". $self->custnum.
 105   ' (cust_pay.paynum '. $self->paynum. ')';
 106 }
 107
 108 =item insert
 109
 110 Adds this payment to the database.
 111
 112 For backwards-compatibility and convenience, if the additional field invnum
 113 is defined, an FS::cust_bill_pay record for the full amount of the payment
 114 will be created.  In this case, custnum is optional.  An hash of optional
 115 arguments may be passed.  Currently "manual" is supported.  If true, a
 116 payment receipt is sent instead of a statement when 'payment_receipt_email'
 117 configuration option is set.
 118
 119 =cut
 120
 121 sub insert {
 122   my ($self, %options) = @_;
 123
 124   local $SIG{HUP} = 'IGNORE';
 125   local $SIG{INT} = 'IGNORE';
 126   local $SIG{QUIT} = 'IGNORE';
 127   local $SIG{TERM} = 'IGNORE';
 128   local $SIG{TSTP} = 'IGNORE';
 129   local $SIG{PIPE} = 'IGNORE';
 130
 131   my $oldAutoCommit = $FS::UID::AutoCommit;
 132   local $FS::UID::AutoCommit = 0;
 133   my $dbh = dbh;
 134
 135   my $cust_bill;
 136   if ( $self->invnum ) {
 137     $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 138       or do {
 139         $dbh->rollback if $oldAutoCommit;
 140         return "Unknown cust_bill.invnum: ". $self->invnum;
 141       };
 142     $self->custnum($cust_bill->custnum );
 143   }
 144
 145
 146   my $error = $self->check;
 147   return $error if $error;
 148
 149   my $cust_main = $self->cust_main;
 150   my $old_balance = $cust_main->balance;
 151
 152   $error = $self->SUPER::insert;
 153   if ( $error ) {
 154     $dbh->rollback if $oldAutoCommit;
 155     return "error inserting $self: $error";
 156   }
 157
 158   if ( $self->invnum ) {
 159     my $cust_bill_pay = new FS::cust_bill_pay {
 160       'invnum' => $self->invnum,
 161       'paynum' => $self->paynum,
 162       'amount' => $self->paid,
 163       '_date'  => $self->_date,
 164     };
 165     $error = $cust_bill_pay->insert;
 166     if ( $error ) {
 167       if ( $ignore_noapply ) {
 168         warn "warning: error inserting $cust_bill_pay: $error ".
 169              "(ignore_noapply flag set; inserting cust_pay record anyway)\n";
 170       } else {
 171         $dbh->rollback if $oldAutoCommit;
 172         return "error inserting $cust_bill_pay: $error";
 173       }
 174     }
 175   }
 176
 177   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 178
 179   #false laziness w/ cust_credit::insert
 180   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 181     my @errors = $cust_main->unsuspend;
 182     #return
 183     # side-fx with nested transactions?  upstack rolls back?
 184     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 185          join(' / ', @errors)
 186       if @errors;
 187   }
 188   #eslaf
 189
 190   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 191
 192   #my $cust_main = $self->cust_main;
 193   if ( $conf->exists('payment_receipt_email')
 194        && grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list
 195   ) {
 196
 197     $cust_bill ||= ($cust_main->cust_bill)[-1]; #rather inefficient though?
 198
 199     my $error;
 200     if (    ( exists($options{'manual'}) && $options{'manual'} )
 201          || ! $conf->exists('invoice_html_statement')
 202          || ! $cust_bill
 203        ) {
 204
 205       my $receipt_template = new Text::Template (
 206         TYPE   => 'ARRAY',
 207         SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 208       ) or do {
 209         warn "can't create payment receipt template: $Text::Template::ERROR";
 210         return '';
 211       };
 212
 213       my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ }
 214                              $cust_main->invoicing_list;
 215
 216       my $payby = $self->payby;
 217       my $payinfo = $self->payinfo;
 218       $payby =~ s/^BILL$/Check/ if $payinfo;
 219       $payinfo = $self->paymask if $payby eq 'CARD' || $payby eq 'CHEK';
 220       $payby =~ s/^CHEK$/Electronic check/;
 221
 222       $error = send_email(
 223         'from'    => $conf->config('invoice_from'), #??? well as good as any
 224         'to'      => \@invoicing_list,
 225         'subject' => 'Payment receipt',
 226         'body'    => [ $receipt_template->fill_in( HASH => {
 227                        'date'    => time2str("%a %B %o, %Y", $self->_date),
 228                        'name'    => $cust_main->name,
 229                        'paynum'  => $self->paynum,
 230                        'paid'    => sprintf("%.2f", $self->paid),
 231                        'payby'   => ucfirst(lc($payby)),
 232                        'payinfo' => $payinfo,
 233                        'balance' => $cust_main->balance,
 234                      } ) ],
 235       );
 236
 237     } else {
 238
 239       my $queue = new FS::queue {
 240          'paynum' => $self->paynum,
 241          'job'    => 'FS::cust_bill::queueable_email',
 242       };
 243       $error = $queue->insert(
 244         'invnum' => $cust_bill->invnum,
 245         'template' => 'statement',
 246       );
 247
 248     }
 249
 250     if ( $error ) {
 251       warn "can't send payment receipt/statement: $error";
 252     }
 253
 254   }
 255
 256   '';
 257
 258 }
 259
 260 =item void [ REASON ]
 261
 262 Voids this payment: deletes the payment and all associated applications and
 263 adds a record of the voided payment to the FS::cust_pay_void table.
 264
 265 =cut
 266
 267 sub void {
 268   my $self = shift;
 269
 270   local $SIG{HUP} = 'IGNORE';
 271   local $SIG{INT} = 'IGNORE';
 272   local $SIG{QUIT} = 'IGNORE';
 273   local $SIG{TERM} = 'IGNORE';
 274   local $SIG{TSTP} = 'IGNORE';
 275   local $SIG{PIPE} = 'IGNORE';
 276
 277   my $oldAutoCommit = $FS::UID::AutoCommit;
 278   local $FS::UID::AutoCommit = 0;
 279   my $dbh = dbh;
 280
 281   my $cust_pay_void = new FS::cust_pay_void ( {
 282     map { $_ => $self->get($_) } $self->fields
 283   } );
 284   $cust_pay_void->reason(shift) if scalar(@_);
 285   my $error = $cust_pay_void->insert;
 286   if ( $error ) {
 287     $dbh->rollback if $oldAutoCommit;
 288     return $error;
 289   }
 290
 291   $error = $self->delete;
 292   if ( $error ) {
 293     $dbh->rollback if $oldAutoCommit;
 294     return $error;
 295   }
 296
 297   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 298
 299   '';
 300
 301 }
 302
 303 =item delete
 304
 305 Unless the closed flag is set, deletes this payment and all associated
 306 applications (see L<FS::cust_bill_pay> and L<FS::cust_pay_refund>).  In most
 307 cases, you want to use the void method instead to leave a record of the
 308 deleted payment.
 309
 310 =cut
 311
 312 # very similar to FS::cust_credit::delete
 313 sub delete {
 314   my $self = shift;
 315   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 316
 317   local $SIG{HUP} = 'IGNORE';
 318   local $SIG{INT} = 'IGNORE';
 319   local $SIG{QUIT} = 'IGNORE';
 320   local $SIG{TERM} = 'IGNORE';
 321   local $SIG{TSTP} = 'IGNORE';
 322   local $SIG{PIPE} = 'IGNORE';
 323
 324   my $oldAutoCommit = $FS::UID::AutoCommit;
 325   local $FS::UID::AutoCommit = 0;
 326   my $dbh = dbh;
 327
 328   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 329     my $error = $app->delete;
 330     if ( $error ) {
 331       $dbh->rollback if $oldAutoCommit;
 332       return $error;
 333     }
 334   }
 335
 336   my $error = $self->SUPER::delete(@_);
 337   if ( $error ) {
 338     $dbh->rollback if $oldAutoCommit;
 339     return $error;
 340   }
 341
 342   if ( $conf->config('deletepayments') ne '' ) {
 343
 344     my $cust_main = $self->cust_main;
 345
 346     my $error = send_email(
 347       'from'    => $conf->config('invoice_from'), #??? well as good as any
 348       'to'      => $conf->config('deletepayments'),
 349       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 350       'body'    => [
 351         "This is an automatic message from your Freeside installation\n",
 352         "informing you that the following payment has been deleted:\n",
 353         "\n",
 354         'paynum: '. $self->paynum. "\n",
 355         'custnum: '. $self->custnum.
 356           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 357         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 358         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 359         'payby: '. $self->payby. "\n",
 360         'payinfo: '. $self->paymask. "\n",
 361         'paybatch: '. $self->paybatch. "\n",
 362       ],
 363     );
 364
 365     if ( $error ) {
 366       $dbh->rollback if $oldAutoCommit;
 367       return "can't send payment deletion notification: $error";
 368     }
 369
 370   }
 371
 372   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 373
 374   '';
 375
 376 }
 377
 378 =item replace OLD_RECORD
 379
 380 You can, but probably shouldn't modify payments...
 381
 382 =cut
 383
 384 sub replace {
 385   #return "Can't modify payment!"
 386   my $self = shift;
 387   return "Can't modify closed payment" if $self->closed =~ /^Y/i;
 388   $self->SUPER::replace(@_);
 389 }
 390
 391 =item check
 392
 393 Checks all fields to make sure this is a valid payment.  If there is an error,
 394 returns the error, otherwise returns false.  Called by the insert method.
 395
 396 =cut
 397
 398 sub check {
 399   my $self = shift;
 400
 401   $self->otaker(getotaker) unless ($self->otaker);
 402
 403   my $error =
 404     $self->ut_numbern('paynum')
 405     || $self->ut_numbern('custnum')
 406     || $self->ut_numbern('_date')
 407     || $self->ut_money('paid')
 408     || $self->ut_alpha('otaker')
 409     || $self->ut_textn('paybatch')
 410     || $self->ut_textn('payunique')
 411     || $self->ut_enum('closed', [ '', 'Y' ])
 412     || $self->payinfo_check()
 413   ;
 414   return $error if $error;
 415
 416   return "paid must be > 0 " if $self->paid <= 0;
 417
 418   return "unknown cust_main.custnum: ". $self->custnum
 419     unless $self->invnum
 420            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 421
 422   $self->_date(time) unless $self->_date;
 423
 424 #i guess not now, with cust_pay_pending, if we actually make it here, we _do_ want to record it
 425 #  # UNIQUE index should catch this too, without race conditions, but this
 426 #  # should give a better error message the other 99.9% of the time...
 427 #  if ( length($self->payunique)
 428 #       && qsearchs('cust_pay', { 'payunique' => $self->payunique } ) ) {
 429 #    #well, it *could* be a better error message
 430 #    return "duplicate transaction".
 431 #           " - a payment with unique identifer ". $self->payunique.
 432 #           " already exists";
 433 #  }
 434
 435   $self->SUPER::check;
 436 }
 437
 438 =item batch_insert CUST_PAY_OBJECT, ...
 439
 440 Class method which inserts multiple payments.  Takes a list of FS::cust_pay
 441 objects.  Returns a list, each element representing the status of inserting the
 442 corresponding payment - empty.  If there is an error inserting any payment, the
 443 entire transaction is rolled back, i.e. all payments are inserted or none are.
 444
 445 For example:
 446
 447   my @errors = FS::cust_pay->batch_insert(@cust_pay);
 448   my $num_errors = scalar(grep $_, @errors);
 449   if ( $num_errors == 0 ) {
 450     #success; all payments were inserted
 451   } else {
 452     #failure; no payments were inserted.
 453   }
 454
 455 =cut
 456
 457 sub batch_insert {
 458   my $self = shift; #class method
 459
 460   local $SIG{HUP} = 'IGNORE';
 461   local $SIG{INT} = 'IGNORE';
 462   local $SIG{QUIT} = 'IGNORE';
 463   local $SIG{TERM} = 'IGNORE';
 464   local $SIG{TSTP} = 'IGNORE';
 465   local $SIG{PIPE} = 'IGNORE';
 466
 467   my $oldAutoCommit = $FS::UID::AutoCommit;
 468   local $FS::UID::AutoCommit = 0;
 469   my $dbh = dbh;
 470
 471   my $errors = 0;
 472
 473   my @errors = map {
 474     my $error = $_->insert( 'manual' => 1 );
 475     if ( $error ) {
 476       $errors++;
 477     } else {
 478       $_->cust_main->apply_payments;
 479     }
 480     $error;
 481   } @_;
 482
 483   if ( $errors ) {
 484     $dbh->rollback if $oldAutoCommit;
 485   } else {
 486     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 487   }
 488
 489   @errors;
 490
 491 }
 492
 493 =item cust_bill_pay
 494
 495 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 496 payment.
 497
 498 =cut
 499
 500 sub cust_bill_pay {
 501   my $self = shift;
 502   sort {    $a->_date  <=> $b->_date
 503          || $a->invnum <=> $b->invnum }
 504     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 505   ;
 506 }
 507
 508 =item cust_pay_refund
 509
 510 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 511 payment.
 512
 513 =cut
 514
 515 sub cust_pay_refund {
 516   my $self = shift;
 517   sort { $a->_date <=> $b->_date }
 518     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 519   ;
 520 }
 521
 522
 523 =item unapplied
 524
 525 Returns the amount of this payment that is still unapplied; which is
 526 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 527 applications (see L<FS::cust_pay_refund>).
 528
 529 =cut
 530
 531 sub unapplied {
 532   my $self = shift;
 533   my $amount = $self->paid;
 534   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 535   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 536   sprintf("%.2f", $amount );
 537 }
 538
 539 =item unrefunded
 540
 541 Returns the amount of this payment that has not been refuned; which is
 542 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 543
 544 =cut
 545
 546 sub unrefunded {
 547   my $self = shift;
 548   my $amount = $self->paid;
 549   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 550   sprintf("%.2f", $amount );
 551 }
 552
 553 =item amount
 554
 555 Returns the "paid" field.
 556
 557 =cut
 558
 559 sub amount {
 560   my $self = shift;
 561   $self->paid();
 562 }
 563
 564 =back
 565
 566 =head1 CLASS METHODS
 567
 568 =over 4
 569
 570 =item unapplied_sql
 571
 572 Returns an SQL fragment to retreive the unapplied amount.
 573
 574 =cut
 575
 576 sub unapplied_sql {
 577   #my $class = shift;
 578
 579   "paid
 580         - COALESCE(
 581                     ( SELECT SUM(amount) FROM cust_bill_pay
 582                         WHERE cust_pay.paynum = cust_bill_pay.paynum )
 583                     ,0
 584                   )
 585         - COALESCE(
 586                     ( SELECT SUM(amount) FROM cust_pay_refund
 587                         WHERE cust_pay.paynum = cust_pay_refund.paynum )
 588                     ,0
 589                   )
 590   ";
 591
 592 }
 593
 594 # _upgrade_data
 595 #
 596 # Used by FS::Upgrade to migrate to a new database.
 597
 598 use FS::h_cust_pay;
 599
 600 sub _upgrade_data {  #class method
 601   my ($class, %opts) = @_;
 602
 603   warn "$me upgrading $class\n" if $DEBUG;
 604
 605   #not the most efficient, but hey, it only has to run once
 606
 607   my $where = "WHERE ( otaker IS NULL OR otaker = '' OR otaker = 'ivan' ) ".
 608               "  AND 0 < ( SELECT COUNT(*) FROM cust_main                 ".
 609               "              WHERE cust_main.custnum = cust_pay.custnum ) ";
 610
 611   my $count_sql = "SELECT COUNT(*) FROM cust_pay $where";
 612
 613   my $sth = dbh->prepare($count_sql) or die dbh->errstr;
 614   $sth->execute or die $sth->errstr;
 615   my $total = $sth->fetchrow_arrayref->[0];
 616   #warn "$total cust_pay records to update\n"
 617   #  if $DEBUG;
 618   local($DEBUG) = 2 if $total > 1000; #could be a while, force progress info
 619
 620   my $count = 0;
 621   my $lastprog = 0;
 622
 623   my @cust_pay = qsearch( {
 624       'table'     => 'cust_pay',
 625       'hashref'   => {},
 626       'extra_sql' => $where,
 627       'order_by'  => 'ORDER BY paynum',
 628   } );
 629
 630   foreach my $cust_pay (@cust_pay) {
 631
 632     my $h_cust_pay = $cust_pay->h_search('insert');
 633     if ( $h_cust_pay ) {
 634       next if $cust_pay->otaker eq $h_cust_pay->history_user;
 635       $cust_pay->otaker($h_cust_pay->history_user);
 636     } else {
 637       $cust_pay->otaker('legacy');
 638     }
 639
 640     delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
 641     my $error = $cust_pay->replace;
 642
 643     if ( $error ) {
 644       warn " *** WARNING: Error updating order taker for payment paynum ".
 645            $cust_pay->paynun. ": $error\n";
 646       next;
 647     }
 648
 649     $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
 650
 651     $count++;
 652     if ( $DEBUG > 1 && $lastprog + 30 < time ) {
 653       warn "$me $count/$total (". sprintf('%.2f',100*$count/$total). '%)'. "\n";
 654       $lastprog = time;
 655     }
 656
 657   }
 658
 659 }
 660
 661 =back
 662
 663 =head1 SUBROUTINES
 664
 665 =over 4
 666
 667 =item batch_import HASHREF
 668
 669 Inserts new payments.
 670
 671 =cut
 672
 673 sub batch_import {
 674   my $param = shift;
 675
 676   my $fh = $param->{filehandle};
 677   my $agentnum = $param->{agentnum};
 678   my $format = $param->{'format'};
 679   my $paybatch = $param->{'paybatch'};
 680
 681   # here is the agent virtualization
 682   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
 683
 684   my @fields;
 685   my $payby;
 686   if ( $format eq 'simple' ) {
 687     @fields = qw( custnum agent_custid paid payinfo );
 688     $payby = 'BILL';
 689   } elsif ( $format eq 'extended' ) {
 690     die "unimplemented\n";
 691     @fields = qw( );
 692     $payby = 'BILL';
 693   } else {
 694     die "unknown format $format";
 695   }
 696
 697   eval "use Text::CSV_XS;";
 698   die $@ if $@;
 699
 700   my $csv = new Text::CSV_XS;
 701
 702   my $imported = 0;
 703
 704   local $SIG{HUP} = 'IGNORE';
 705   local $SIG{INT} = 'IGNORE';
 706   local $SIG{QUIT} = 'IGNORE';
 707   local $SIG{TERM} = 'IGNORE';
 708   local $SIG{TSTP} = 'IGNORE';
 709   local $SIG{PIPE} = 'IGNORE';
 710
 711   my $oldAutoCommit = $FS::UID::AutoCommit;
 712   local $FS::UID::AutoCommit = 0;
 713   my $dbh = dbh;
 714
 715   my $line;
 716   while ( defined($line=<$fh>) ) {
 717
 718     $csv->parse($line) or do {
 719       $dbh->rollback if $oldAutoCommit;
 720       return "can't parse: ". $csv->error_input();
 721     };
 722
 723     my @columns = $csv->fields();
 724
 725     my %cust_pay = (
 726       payby    => $payby,
 727       paybatch => $paybatch,
 728     );
 729
 730     my $cust_main;
 731     foreach my $field ( @fields ) {
 732
 733       if ( $field eq 'agent_custid'
 734         && $agentnum
 735         && $columns[0] =~ /\S+/ )
 736       {
 737
 738         my $agent_custid = $columns[0];
 739         my %hash = ( 'agent_custid' => $agent_custid,
 740                      'agentnum'     => $agentnum,
 741                    );
 742
 743         if ( $cust_pay{'custnum'} !~ /^\s*$/ ) {
 744           $dbh->rollback if $oldAutoCommit;
 745           return "can't specify custnum with agent_custid $agent_custid";
 746         }
 747
 748         $cust_main = qsearchs({
 749                                 'table'     => 'cust_main',
 750                                 'hashref'   => \%hash,
 751                                 'extra_sql' => $extra_sql,
 752                              });
 753
 754         unless ( $cust_main ) {
 755           $dbh->rollback if $oldAutoCommit;
 756           return "can't find customer with agent_custid $agent_custid";
 757         }
 758
 759         $field = 'custnum';
 760         $columns[0] = $cust_main->custnum;
 761       }
 762
 763       $cust_pay{$field} = shift @columns;
 764     }
 765
 766     my $cust_pay = new FS::cust_pay( \%cust_pay );
 767     my $error = $cust_pay->insert;
 768
 769     if ( $error ) {
 770       $dbh->rollback if $oldAutoCommit;
 771       return "can't insert payment for $line: $error";
 772     }
 773
 774     if ( $format eq 'simple' ) {
 775       # include agentnum for less surprise?
 776       $cust_main = qsearchs({
 777                              'table'     => 'cust_main',
 778                              'hashref'   => { 'custnum' => $cust_pay->custnum },
 779                              'extra_sql' => $extra_sql,
 780                            })
 781         unless $cust_main;
 782
 783       unless ( $cust_main ) {
 784         $dbh->rollback if $oldAutoCommit;
 785         return "can't find customer to which payments apply at line: $line";
 786       }
 787
 788       $error = $cust_main->apply_payments_and_credits;
 789       if ( $error ) {
 790         $dbh->rollback if $oldAutoCommit;
 791         return "can't apply payments to customer for $line: $error";
 792       }
 793
 794     }
 795
 796     $imported++;
 797   }
 798
 799   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 800
 801   return "Empty file!" unless $imported;
 802
 803   ''; #no error
 804
 805 }
 806
 807 =back
 808
 809 =head1 BUGS
 810
 811 Delete and replace methods.
 812
 813 =head1 SEE ALSO
 814
 815 L<FS::cust_pay_pending>, L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>,
 816 schema.html from the base documentation.
 817
 818 =cut
 819
 820 1;
 821