FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me $conf @encrypted_fields
   5              $unsuspendauto $ignore_noapply
   6            );
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Text::Template;
  10 use FS::UID qw( getotaker );
  11 use FS::Misc qw( send_email );
  12 use FS::Record qw( dbh qsearch qsearchs );
  13 use FS::payby;
  14 use FS::cust_main_Mixin;
  15 use FS::payinfo_transaction_Mixin;
  16 use FS::cust_bill;
  17 use FS::cust_bill_pay;
  18 use FS::cust_pay_refund;
  19 use FS::cust_main;
  20 use FS::cust_pkg;
  21 use FS::cust_pay_void;
  22
  23 @ISA = qw( FS::payinfo_transaction_Mixin FS::cust_main_Mixin FS::Record );
  24
  25 $DEBUG = 1;
  26
  27 $me = '[FS::cust_pay]';
  28
  29 $ignore_noapply = 0;
  30
  31 #ask FS::UID to run this stuff for us later
  32 FS::UID->install_callback( sub {
  33   $conf = new FS::Conf;
  34   $unsuspendauto = $conf->exists('unsuspendauto');
  35 } );
  36
  37 @encrypted_fields = ('payinfo');
  38
  39 =head1 NAME
  40
  41 FS::cust_pay - Object methods for cust_pay objects
  42
  43 =head1 SYNOPSIS
  44
  45   use FS::cust_pay;
  46
  47   $record = new FS::cust_pay \%hash;
  48   $record = new FS::cust_pay { 'column' => 'value' };
  49
  50   $error = $record->insert;
  51
  52   $error = $new_record->replace($old_record);
  53
  54   $error = $record->delete;
  55
  56   $error = $record->check;
  57
  58 =head1 DESCRIPTION
  59
  60 An FS::cust_pay object represents a payment; the transfer of money from a
  61 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  62 currently supported:
  63
  64 =over 4
  65
  66 =item paynum
  67
  68 primary key (assigned automatically for new payments)
  69
  70 =item custnum
  71
  72 customer (see L<FS::cust_main>)
  73
  74 =item _date
  75
  76 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  77 L<Time::Local> and L<Date::Parse> for conversion functions.
  78
  79 =item paid
  80
  81 Amount of this payment
  82
  83 =item otaker
  84
  85 order taker (assigned automatically, see L<FS::UID>)
  86
  87 =item payby
  88
  89 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
  90
  91 =item payinfo
  92
  93 Payment Information (See L<FS::payinfo_Mixin> for data format)
  94
  95 =item paymask
  96
  97 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
  98
  99 =item paybatch
 100
 101 text field for tracking card processing or other batch grouping
 102
 103 =item payunique
 104
 105 Optional unique identifer to prevent duplicate transactions.
 106
 107 =item closed
 108
 109 books closed flag, empty or `Y'
 110
 111 =item pkgnum
 112
 113 Desired pkgnum when using experimental package balances.
 114
 115 =back
 116
 117 =head1 METHODS
 118
 119 =over 4
 120
 121 =item new HASHREF
 122
 123 Creates a new payment.  To add the payment to the databse, see L<"insert">.
 124
 125 =cut
 126
 127 sub table { 'cust_pay'; }
 128 sub cust_linked { $_[0]->cust_main_custnum; }
 129 sub cust_unlinked_msg {
 130   my $self = shift;
 131   "WARNING: can't find cust_main.custnum ". $self->custnum.
 132   ' (cust_pay.paynum '. $self->paynum. ')';
 133 }
 134
 135 =item insert [ OPTION => VALUE ... ]
 136
 137 Adds this payment to the database.
 138
 139 For backwards-compatibility and convenience, if the additional field invnum
 140 is defined, an FS::cust_bill_pay record for the full amount of the payment
 141 will be created.  In this case, custnum is optional.
 142
 143 A hash of optional arguments may be passed.  Currently "manual" is supported.
 144 If true, a payment receipt is sent instead of a statement when
 145 'payment_receipt_email' configuration option is set.
 146
 147 =cut
 148
 149 sub insert {
 150   my($self, %options) = @_;
 151
 152   local $SIG{HUP} = 'IGNORE';
 153   local $SIG{INT} = 'IGNORE';
 154   local $SIG{QUIT} = 'IGNORE';
 155   local $SIG{TERM} = 'IGNORE';
 156   local $SIG{TSTP} = 'IGNORE';
 157   local $SIG{PIPE} = 'IGNORE';
 158
 159   my $oldAutoCommit = $FS::UID::AutoCommit;
 160   local $FS::UID::AutoCommit = 0;
 161   my $dbh = dbh;
 162
 163   my $cust_bill;
 164   if ( $self->invnum ) {
 165     $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 166       or do {
 167         $dbh->rollback if $oldAutoCommit;
 168         return "Unknown cust_bill.invnum: ". $self->invnum;
 169       };
 170     $self->custnum($cust_bill->custnum );
 171   }
 172
 173   my $error = $self->check;
 174   return $error if $error;
 175
 176   my $cust_main = $self->cust_main;
 177   my $old_balance = $cust_main->balance;
 178
 179   $error = $self->SUPER::insert;
 180   if ( $error ) {
 181     $dbh->rollback if $oldAutoCommit;
 182     return "error inserting $self: $error";
 183   }
 184
 185   if ( $self->invnum ) {
 186     my $cust_bill_pay = new FS::cust_bill_pay {
 187       'invnum' => $self->invnum,
 188       'paynum' => $self->paynum,
 189       'amount' => $self->paid,
 190       '_date'  => $self->_date,
 191     };
 192     $error = $cust_bill_pay->insert(%options);
 193     if ( $error ) {
 194       if ( $ignore_noapply ) {
 195         warn "warning: error inserting $cust_bill_pay: $error ".
 196              "(ignore_noapply flag set; inserting cust_pay record anyway)\n";
 197       } else {
 198         $dbh->rollback if $oldAutoCommit;
 199         return "error inserting $cust_bill_pay: $error";
 200       }
 201     }
 202   }
 203
 204   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 205
 206   #false laziness w/ cust_credit::insert
 207   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 208     my @errors = $cust_main->unsuspend;
 209     #return
 210     # side-fx with nested transactions?  upstack rolls back?
 211     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 212          join(' / ', @errors)
 213       if @errors;
 214   }
 215   #eslaf
 216
 217   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 218
 219   #payment receipt
 220   my $trigger = $conf->config('payment_receipt-trigger') || 'cust_pay';
 221   if ( $trigger eq 'cust_pay' ) {
 222     my $error = $self->send_receipt(
 223       'manual'    => $options{'manual'},
 224       'cust_bill' => $cust_bill,
 225       'cust_main' => $cust_main,
 226     );
 227     warn "can't send payment receipt/statement: $error" if $error;
 228   }
 229
 230   '';
 231
 232 }
 233
 234 =item void [ REASON ]
 235
 236 Voids this payment: deletes the payment and all associated applications and
 237 adds a record of the voided payment to the FS::cust_pay_void table.
 238
 239 =cut
 240
 241 sub void {
 242   my $self = shift;
 243
 244   local $SIG{HUP} = 'IGNORE';
 245   local $SIG{INT} = 'IGNORE';
 246   local $SIG{QUIT} = 'IGNORE';
 247   local $SIG{TERM} = 'IGNORE';
 248   local $SIG{TSTP} = 'IGNORE';
 249   local $SIG{PIPE} = 'IGNORE';
 250
 251   my $oldAutoCommit = $FS::UID::AutoCommit;
 252   local $FS::UID::AutoCommit = 0;
 253   my $dbh = dbh;
 254
 255   my $cust_pay_void = new FS::cust_pay_void ( {
 256     map { $_ => $self->get($_) } $self->fields
 257   } );
 258   $cust_pay_void->reason(shift) if scalar(@_);
 259   my $error = $cust_pay_void->insert;
 260   if ( $error ) {
 261     $dbh->rollback if $oldAutoCommit;
 262     return $error;
 263   }
 264
 265   $error = $self->delete;
 266   if ( $error ) {
 267     $dbh->rollback if $oldAutoCommit;
 268     return $error;
 269   }
 270
 271   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 272
 273   '';
 274
 275 }
 276
 277 =item delete
 278
 279 Unless the closed flag is set, deletes this payment and all associated
 280 applications (see L<FS::cust_bill_pay> and L<FS::cust_pay_refund>).  In most
 281 cases, you want to use the void method instead to leave a record of the
 282 deleted payment.
 283
 284 =cut
 285
 286 # very similar to FS::cust_credit::delete
 287 sub delete {
 288   my $self = shift;
 289   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 290
 291   local $SIG{HUP} = 'IGNORE';
 292   local $SIG{INT} = 'IGNORE';
 293   local $SIG{QUIT} = 'IGNORE';
 294   local $SIG{TERM} = 'IGNORE';
 295   local $SIG{TSTP} = 'IGNORE';
 296   local $SIG{PIPE} = 'IGNORE';
 297
 298   my $oldAutoCommit = $FS::UID::AutoCommit;
 299   local $FS::UID::AutoCommit = 0;
 300   my $dbh = dbh;
 301
 302   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 303     my $error = $app->delete;
 304     if ( $error ) {
 305       $dbh->rollback if $oldAutoCommit;
 306       return $error;
 307     }
 308   }
 309
 310   my $error = $self->SUPER::delete(@_);
 311   if ( $error ) {
 312     $dbh->rollback if $oldAutoCommit;
 313     return $error;
 314   }
 315
 316   if (    $conf->exists('deletepayments')
 317        && $conf->config('deletepayments') ne '' ) {
 318
 319     my $cust_main = $self->cust_main;
 320
 321     my $error = send_email(
 322       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
 323                                  #invoice_from??? well as good as any
 324       'to'      => $conf->config('deletepayments'),
 325       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 326       'body'    => [
 327         "This is an automatic message from your Freeside installation\n",
 328         "informing you that the following payment has been deleted:\n",
 329         "\n",
 330         'paynum: '. $self->paynum. "\n",
 331         'custnum: '. $self->custnum.
 332           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 333         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 334         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 335         'payby: '. $self->payby. "\n",
 336         'payinfo: '. $self->paymask. "\n",
 337         'paybatch: '. $self->paybatch. "\n",
 338       ],
 339     );
 340
 341     if ( $error ) {
 342       $dbh->rollback if $oldAutoCommit;
 343       return "can't send payment deletion notification: $error";
 344     }
 345
 346   }
 347
 348   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 349
 350   '';
 351
 352 }
 353
 354 =item replace OLD_RECORD
 355
 356 You can, but probably shouldn't modify payments...
 357
 358 =cut
 359
 360 sub replace {
 361   #return "Can't modify payment!"
 362   my $self = shift;
 363   return "Can't modify closed payment" if $self->closed =~ /^Y/i;
 364   $self->SUPER::replace(@_);
 365 }
 366
 367 =item check
 368
 369 Checks all fields to make sure this is a valid payment.  If there is an error,
 370 returns the error, otherwise returns false.  Called by the insert method.
 371
 372 =cut
 373
 374 sub check {
 375   my $self = shift;
 376
 377   $self->otaker(getotaker) unless ($self->otaker);
 378
 379   my $error =
 380     $self->ut_numbern('paynum')
 381     || $self->ut_numbern('custnum')
 382     || $self->ut_numbern('_date')
 383     || $self->ut_money('paid')
 384     || $self->ut_alpha('otaker')
 385     || $self->ut_textn('paybatch')
 386     || $self->ut_textn('payunique')
 387     || $self->ut_enum('closed', [ '', 'Y' ])
 388     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 389     || $self->payinfo_check()
 390   ;
 391   return $error if $error;
 392
 393   return "paid must be > 0 " if $self->paid <= 0;
 394
 395   return "unknown cust_main.custnum: ". $self->custnum
 396     unless $self->invnum
 397            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 398
 399   $self->_date(time) unless $self->_date;
 400
 401 #i guess not now, with cust_pay_pending, if we actually make it here, we _do_ want to record it
 402 #  # UNIQUE index should catch this too, without race conditions, but this
 403 #  # should give a better error message the other 99.9% of the time...
 404 #  if ( length($self->payunique)
 405 #       && qsearchs('cust_pay', { 'payunique' => $self->payunique } ) ) {
 406 #    #well, it *could* be a better error message
 407 #    return "duplicate transaction".
 408 #           " - a payment with unique identifer ". $self->payunique.
 409 #           " already exists";
 410 #  }
 411
 412   $self->SUPER::check;
 413 }
 414
 415 =item send_receipt HASHREF | OPTION => VALUE ...
 416
 417 Sends a payment receipt for this payment..
 418
 419 Available options:
 420
 421 =over 4
 422
 423 =item manual
 424
 425 Flag indicating the payment is being made manually.
 426
 427 =item cust_bill
 428
 429 Invoice (FS::cust_bill) object.  If not specified, the most recent invoice
 430 will be assumed.
 431
 432 =item cust_main
 433
 434 Customer (FS::cust_main) object (for efficiency).
 435
 436 =back
 437
 438 =cut
 439
 440 sub send_receipt {
 441   my $self = shift;
 442   my $opt = ref($_[0]) ? shift : { @_ };
 443
 444   my $cust_bill = $opt->{'cust_bill'};
 445   my $cust_main = $opt->{'cust_main'} || $self->cust_main;
 446
 447   my $conf = new FS::Conf;
 448
 449   return '' unless $conf->exists('payment_receipt');
 450
 451   my @invoicing_list = $cust_main->invoicing_list_emailonly;
 452   return '' unless @invoicing_list;
 453
 454   $cust_bill ||= ($cust_main->cust_bill)[-1]; #rather inefficient though?
 455
 456   my $error = '';
 457
 458   if (    ( exists($opt->{'manual'}) && $opt->{'manual'} )
 459        || ! $conf->exists('invoice_html_statement')
 460        || ! $cust_bill
 461      )
 462   {
 463
 464     if ( $conf->exists('payment_receipt_msgnum')
 465          && $conf->config('payment_receipt_msgnum')
 466        )
 467     {
 468       my $msg_template =
 469           FS::msg_template->by_key($conf->config('payment_receipt_msgnum'));
 470       $error = $msg_template->send('cust_main'=> $cust_main, 'object'=> $self);
 471
 472     } elsif ( $conf->exists('payment_receipt_email') ) {
 473
 474       my $receipt_template = new Text::Template (
 475         TYPE   => 'ARRAY',
 476         SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 477       ) or do {
 478         warn "can't create payment receipt template: $Text::Template::ERROR";
 479         return '';
 480       };
 481
 482       my $payby = $self->payby;
 483       my $payinfo = $self->payinfo;
 484       $payby =~ s/^BILL$/Check/ if $payinfo;
 485       if ( $payby eq 'CARD' || $payby eq 'CHEK' ) {
 486         $payinfo = $self->paymask
 487       } else {
 488         $payinfo = $self->decrypt($payinfo);
 489       }
 490       $payby =~ s/^CHEK$/Electronic check/;
 491
 492       my %fill_in = (
 493         'date'         => time2str("%a %B %o, %Y", $self->_date),
 494         'name'         => $cust_main->name,
 495         'paynum'       => $self->paynum,
 496         'paid'         => sprintf("%.2f", $self->paid),
 497         'payby'        => ucfirst(lc($payby)),
 498         'payinfo'      => $payinfo,
 499         'balance'      => $cust_main->balance,
 500         'company_name' => $conf->config('company_name', $cust_main->agentnum),
 501       );
 502
 503       if ( $opt->{'cust_pkg'} ) {
 504         $fill_in{'pkg'} = $opt->{'cust_pkg'}->part_pkg->pkg;
 505         #setup date, other things?
 506       }
 507
 508       $error = send_email(
 509         'from'    => $conf->config('invoice_from', $cust_main->agentnum),
 510                                    #invoice_from??? well as good as any
 511         'to'      => \@invoicing_list,
 512         'subject' => 'Payment receipt',
 513         'body'    => [ $receipt_template->fill_in( HASH => \%fill_in ) ],
 514       );
 515
 516     } else {
 517
 518       warn "payment_receipt is on, but no payment_receipt_msgnum or invoice_html_statement is configured\n";
 519
 520     }
 521
 522   } else { #not manual
 523
 524     my $queue = new FS::queue {
 525        'paynum' => $self->paynum,
 526        'job'    => 'FS::cust_bill::queueable_email',
 527     };
 528
 529     $error = $queue->insert(
 530       'invnum'   => $cust_bill->invnum,
 531       'template' => 'statement',
 532     );
 533
 534   }
 535
 536     warn "send_receipt: $error\n" if $error;
 537 }
 538
 539 =item cust_bill_pay
 540
 541 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 542 payment.
 543
 544 =cut
 545
 546 sub cust_bill_pay {
 547   my $self = shift;
 548   sort {    $a->_date  <=> $b->_date
 549          || $a->invnum <=> $b->invnum }
 550     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 551   ;
 552 }
 553
 554 =item cust_pay_refund
 555
 556 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 557 payment.
 558
 559 =cut
 560
 561 sub cust_pay_refund {
 562   my $self = shift;
 563   sort { $a->_date <=> $b->_date }
 564     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 565   ;
 566 }
 567
 568
 569 =item unapplied
 570
 571 Returns the amount of this payment that is still unapplied; which is
 572 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 573 applications (see L<FS::cust_pay_refund>).
 574
 575 =cut
 576
 577 sub unapplied {
 578   my $self = shift;
 579   my $amount = $self->paid;
 580   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 581   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 582   sprintf("%.2f", $amount );
 583 }
 584
 585 =item unrefunded
 586
 587 Returns the amount of this payment that has not been refuned; which is
 588 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 589
 590 =cut
 591
 592 sub unrefunded {
 593   my $self = shift;
 594   my $amount = $self->paid;
 595   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 596   sprintf("%.2f", $amount );
 597 }
 598
 599 =item amount
 600
 601 Returns the "paid" field.
 602
 603 =cut
 604
 605 sub amount {
 606   my $self = shift;
 607   $self->paid();
 608 }
 609
 610 =back
 611
 612 =head1 CLASS METHODS
 613
 614 =over 4
 615
 616 =item batch_insert CUST_PAY_OBJECT, ...
 617
 618 Class method which inserts multiple payments.  Takes a list of FS::cust_pay
 619 objects.  Returns a list, each element representing the status of inserting the
 620 corresponding payment - empty.  If there is an error inserting any payment, the
 621 entire transaction is rolled back, i.e. all payments are inserted or none are.
 622
 623 For example:
 624
 625   my @errors = FS::cust_pay->batch_insert(@cust_pay);
 626   my $num_errors = scalar(grep $_, @errors);
 627   if ( $num_errors == 0 ) {
 628     #success; all payments were inserted
 629   } else {
 630     #failure; no payments were inserted.
 631   }
 632
 633 =cut
 634
 635 sub batch_insert {
 636   my $self = shift; #class method
 637
 638   local $SIG{HUP} = 'IGNORE';
 639   local $SIG{INT} = 'IGNORE';
 640   local $SIG{QUIT} = 'IGNORE';
 641   local $SIG{TERM} = 'IGNORE';
 642   local $SIG{TSTP} = 'IGNORE';
 643   local $SIG{PIPE} = 'IGNORE';
 644
 645   my $oldAutoCommit = $FS::UID::AutoCommit;
 646   local $FS::UID::AutoCommit = 0;
 647   my $dbh = dbh;
 648
 649   my $errors = 0;
 650
 651   my @errors = map {
 652     my $error = $_->insert( 'manual' => 1 );
 653     if ( $error ) {
 654       $errors++;
 655     } else {
 656       $_->cust_main->apply_payments;
 657     }
 658     $error;
 659   } @_;
 660
 661   if ( $errors ) {
 662     $dbh->rollback if $oldAutoCommit;
 663   } else {
 664     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 665   }
 666
 667   @errors;
 668
 669 }
 670
 671 =item unapplied_sql
 672
 673 Returns an SQL fragment to retreive the unapplied amount.
 674
 675 =cut
 676
 677 sub unapplied_sql {
 678   my ($class, $start, $end) = @_;
 679   my $bill_start   = $start ? "AND cust_bill_pay._date <= $start"   : '';
 680   my $bill_end     = $end   ? "AND cust_bill_pay._date > $end"     : '';
 681   my $refund_start = $start ? "AND cust_pay_refund._date <= $start" : '';
 682   my $refund_end   = $end   ? "AND cust_pay_refund._date > $end"   : '';
 683
 684   "paid
 685         - COALESCE(
 686                     ( SELECT SUM(amount) FROM cust_bill_pay
 687                         WHERE cust_pay.paynum = cust_bill_pay.paynum
 688                         $bill_start $bill_end )
 689                     ,0
 690                   )
 691         - COALESCE(
 692                     ( SELECT SUM(amount) FROM cust_pay_refund
 693                         WHERE cust_pay.paynum = cust_pay_refund.paynum
 694                         $refund_start $refund_end )
 695                     ,0
 696                   )
 697   ";
 698
 699 }
 700
 701 # _upgrade_data
 702 #
 703 # Used by FS::Upgrade to migrate to a new database.
 704
 705 use FS::h_cust_pay;
 706
 707 sub _upgrade_data {  #class method
 708   my ($class, %opts) = @_;
 709
 710   warn "$me upgrading $class\n" if $DEBUG;
 711
 712   #not the most efficient, but hey, it only has to run once
 713
 714   my $where = "WHERE ( otaker IS NULL OR otaker = '' OR otaker = 'ivan' ) ".
 715               "  AND 0 < ( SELECT COUNT(*) FROM cust_main                 ".
 716               "              WHERE cust_main.custnum = cust_pay.custnum ) ";
 717
 718   my $count_sql = "SELECT COUNT(*) FROM cust_pay $where";
 719
 720   my $sth = dbh->prepare($count_sql) or die dbh->errstr;
 721   $sth->execute or die $sth->errstr;
 722   my $total = $sth->fetchrow_arrayref->[0];
 723   #warn "$total cust_pay records to update\n"
 724   #  if $DEBUG;
 725   local($DEBUG) = 2 if $total > 1000; #could be a while, force progress info
 726
 727   my $count = 0;
 728   my $lastprog = 0;
 729
 730   my @cust_pay = qsearch( {
 731       'table'     => 'cust_pay',
 732       'hashref'   => {},
 733       'extra_sql' => $where,
 734       'order_by'  => 'ORDER BY paynum',
 735   } );
 736
 737   foreach my $cust_pay (@cust_pay) {
 738
 739     my $h_cust_pay = $cust_pay->h_search('insert');
 740     if ( $h_cust_pay ) {
 741       next if $cust_pay->otaker eq $h_cust_pay->history_user;
 742       $cust_pay->otaker($h_cust_pay->history_user);
 743     } else {
 744       $cust_pay->otaker('legacy');
 745     }
 746
 747     delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
 748     my $error = $cust_pay->replace;
 749
 750     if ( $error ) {
 751       warn " *** WARNING: Error updating order taker for payment paynum ".
 752            $cust_pay->paynun. ": $error\n";
 753       next;
 754     }
 755
 756     $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
 757
 758     $count++;
 759     if ( $DEBUG > 1 && $lastprog + 30 < time ) {
 760       warn "$me $count/$total (". sprintf('%.2f',100*$count/$total). '%)'. "\n";
 761       $lastprog = time;
 762     }
 763
 764   }
 765
 766 }
 767
 768 =back
 769
 770 =head1 SUBROUTINES
 771
 772 =over 4
 773
 774 =item batch_import HASHREF
 775
 776 Inserts new payments.
 777
 778 =cut
 779
 780 sub batch_import {
 781   my $param = shift;
 782
 783   my $fh = $param->{filehandle};
 784   my $agentnum = $param->{agentnum};
 785   my $format = $param->{'format'};
 786   my $paybatch = $param->{'paybatch'};
 787
 788   # here is the agent virtualization
 789   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
 790
 791   my @fields;
 792   my $payby;
 793   if ( $format eq 'simple' ) {
 794     @fields = qw( custnum agent_custid paid payinfo );
 795     $payby = 'BILL';
 796   } elsif ( $format eq 'extended' ) {
 797     die "unimplemented\n";
 798     @fields = qw( );
 799     $payby = 'BILL';
 800   } else {
 801     die "unknown format $format";
 802   }
 803
 804   eval "use Text::CSV_XS;";
 805   die $@ if $@;
 806
 807   my $csv = new Text::CSV_XS;
 808
 809   my $imported = 0;
 810
 811   local $SIG{HUP} = 'IGNORE';
 812   local $SIG{INT} = 'IGNORE';
 813   local $SIG{QUIT} = 'IGNORE';
 814   local $SIG{TERM} = 'IGNORE';
 815   local $SIG{TSTP} = 'IGNORE';
 816   local $SIG{PIPE} = 'IGNORE';
 817
 818   my $oldAutoCommit = $FS::UID::AutoCommit;
 819   local $FS::UID::AutoCommit = 0;
 820   my $dbh = dbh;
 821
 822   my $line;
 823   while ( defined($line=<$fh>) ) {
 824
 825     $csv->parse($line) or do {
 826       $dbh->rollback if $oldAutoCommit;
 827       return "can't parse: ". $csv->error_input();
 828     };
 829
 830     my @columns = $csv->fields();
 831
 832     my %cust_pay = (
 833       payby    => $payby,
 834       paybatch => $paybatch,
 835     );
 836
 837     my $cust_main;
 838     foreach my $field ( @fields ) {
 839
 840       if ( $field eq 'agent_custid'
 841         && $agentnum
 842         && $columns[0] =~ /\S+/ )
 843       {
 844
 845         my $agent_custid = $columns[0];
 846         my %hash = ( 'agent_custid' => $agent_custid,
 847                      'agentnum'     => $agentnum,
 848                    );
 849
 850         if ( $cust_pay{'custnum'} !~ /^\s*$/ ) {
 851           $dbh->rollback if $oldAutoCommit;
 852           return "can't specify custnum with agent_custid $agent_custid";
 853         }
 854
 855         $cust_main = qsearchs({
 856                                 'table'     => 'cust_main',
 857                                 'hashref'   => \%hash,
 858                                 'extra_sql' => $extra_sql,
 859                              });
 860
 861         unless ( $cust_main ) {
 862           $dbh->rollback if $oldAutoCommit;
 863           return "can't find customer with agent_custid $agent_custid";
 864         }
 865
 866         $field = 'custnum';
 867         $columns[0] = $cust_main->custnum;
 868       }
 869
 870       $cust_pay{$field} = shift @columns;
 871     }
 872
 873     my $cust_pay = new FS::cust_pay( \%cust_pay );
 874     my $error = $cust_pay->insert;
 875
 876     if ( $error ) {
 877       $dbh->rollback if $oldAutoCommit;
 878       return "can't insert payment for $line: $error";
 879     }
 880
 881     if ( $format eq 'simple' ) {
 882       # include agentnum for less surprise?
 883       $cust_main = qsearchs({
 884                              'table'     => 'cust_main',
 885                              'hashref'   => { 'custnum' => $cust_pay->custnum },
 886                              'extra_sql' => $extra_sql,
 887                            })
 888         unless $cust_main;
 889
 890       unless ( $cust_main ) {
 891         $dbh->rollback if $oldAutoCommit;
 892         return "can't find customer to which payments apply at line: $line";
 893       }
 894
 895       $error = $cust_main->apply_payments_and_credits;
 896       if ( $error ) {
 897         $dbh->rollback if $oldAutoCommit;
 898         return "can't apply payments to customer for $line: $error";
 899       }
 900
 901     }
 902
 903     $imported++;
 904   }
 905
 906   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 907
 908   return "Empty file!" unless $imported;
 909
 910   ''; #no error
 911
 912 }
 913
 914 =back
 915
 916 =head1 BUGS
 917
 918 Delete and replace methods.
 919
 920 =head1 SEE ALSO
 921
 922 L<FS::cust_pay_pending>, L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>,
 923 schema.html from the base documentation.
 924
 925 =cut
 926
 927 1;
 928