FS/FS/cust_main_county.pm

   1 package FS::cust_main_county;
   2 use base qw( FS::Record );
   3
   4 use strict;
   5 use vars qw( @EXPORT_OK $conf
   6              @cust_main_county %cust_main_county $countyflag ); # $cityflag );
   7 use Exporter;
   8 use FS::Record qw( qsearch qsearchs dbh );
   9 use FS::cust_bill_pkg;
  10 use FS::cust_bill;
  11 use FS::cust_pkg;
  12 use FS::part_pkg;
  13 use FS::cust_tax_exempt;
  14 use FS::cust_tax_exempt_pkg;
  15
  16 @EXPORT_OK = qw( regionselector );
  17
  18 @cust_main_county = ();
  19 $countyflag = '';
  20 #$cityflag = '';
  21
  22 #ask FS::UID to run this stuff for us later
  23 $FS::UID::callback{'FS::cust_main_county'} = sub {
  24   $conf = new FS::Conf;
  25 };
  26
  27 =head1 NAME
  28
  29 FS::cust_main_county - Object methods for cust_main_county objects
  30
  31 =head1 SYNOPSIS
  32
  33   use FS::cust_main_county;
  34
  35   $record = new FS::cust_main_county \%hash;
  36   $record = new FS::cust_main_county { 'column' => 'value' };
  37
  38   $error = $record->insert;
  39
  40   $error = $new_record->replace($old_record);
  41
  42   $error = $record->delete;
  43
  44   $error = $record->check;
  45
  46   ($county_html, $state_html, $country_html) =
  47     FS::cust_main_county::regionselector( $county, $state, $country );
  48
  49 =head1 DESCRIPTION
  50
  51 An FS::cust_main_county object represents a tax rate, defined by locale.
  52 FS::cust_main_county inherits from FS::Record.  The following fields are
  53 currently supported:
  54
  55 =over 4
  56
  57 =item taxnum - primary key (assigned automatically for new tax rates)
  58
  59 =item district - tax district (optional)
  60
  61 =item city
  62
  63 =item county
  64
  65 =item state
  66
  67 =item country
  68
  69 =item tax - percentage
  70
  71 =item taxclass
  72
  73 =item exempt_amount
  74
  75 =item taxname - if defined, printed on invoices instead of "Tax"
  76
  77 =item setuptax - if 'Y', this tax does not apply to setup fees
  78
  79 =item recurtax - if 'Y', this tax does not apply to recurring fees
  80
  81 =back
  82
  83 =head1 METHODS
  84
  85 =over 4
  86
  87 =item new HASHREF
  88
  89 Creates a new tax rate.  To add the tax rate to the database, see L<"insert">.
  90
  91 =cut
  92
  93 sub table { 'cust_main_county'; }
  94
  95 =item insert
  96
  97 Adds this tax rate to the database.  If there is an error, returns the error,
  98 otherwise returns false.
  99
 100 =item delete
 101
 102 Deletes this tax rate from the database.  If there is an error, returns the
 103 error, otherwise returns false.
 104
 105 =item replace OLD_RECORD
 106
 107 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 108 returns the error, otherwise returns false.
 109
 110 =item check
 111
 112 Checks all fields to make sure this is a valid tax rate.  If there is an error,
 113 returns the error, otherwise returns false.  Called by the insert and replace
 114 methods.
 115
 116 =cut
 117
 118 sub check {
 119   my $self = shift;
 120
 121   $self->exempt_amount(0) unless $self->exempt_amount;
 122
 123   $self->ut_numbern('taxnum')
 124     || $self->ut_alphan('district')
 125     || $self->ut_textn('city')
 126     || $self->ut_textn('county')
 127     || $self->ut_anything('state')
 128     || $self->ut_text('country')
 129     || $self->ut_float('tax')
 130     || $self->ut_textn('taxclass') # ...
 131     || $self->ut_money('exempt_amount')
 132     || $self->ut_textn('taxname')
 133     || $self->ut_enum('setuptax', [ '', 'Y' ] )
 134     || $self->ut_enum('recurtax', [ '', 'Y' ] )
 135     || $self->SUPER::check
 136     ;
 137
 138 }
 139
 140 =item label OPTIONS
 141
 142 Returns a label looking like "Anytown, Alameda County, CA, US".
 143
 144 If the taxname field is set, it will look like
 145 "CA Sales Tax (Anytown, Alameda County, CA, US)".
 146
 147 If the taxclass is set, then it will be
 148 "Anytown, Alameda County, CA, US (International)".
 149
 150 OPTIONS may contain "with_taxclass", "with_city", and "with_district" to show
 151 those fields.  It may also contain "out", in which case, if this region
 152 (district+city+county+state+country) contains no non-zero taxes, the label
 153 will read "Out of taxable region(s)".
 154
 155 =cut
 156
 157 sub label {
 158   my ($self, %opt) = @_;
 159   if ( $opt{'out'}
 160        and $self->tax == 0
 161        and !defined(qsearchs('cust_main_county', {
 162            'district' => $self->district,
 163            'city'     => $self->city,
 164            'county'   => $self->county,
 165            'state'    => $self->state,
 166            'country'  => $self->country,
 167            'tax'  => { op => '>', value => 0 },
 168         })) )
 169   {
 170     return 'Out of taxable region(s)';
 171   }
 172   my $label = $self->country;
 173   $label = $self->state.", $label" if $self->state;
 174   $label = $self->county." County, $label" if $self->county;
 175   if ($opt{with_city}) {
 176     $label = $self->city.", $label" if $self->city;
 177     if ($opt{with_district} and $self->district) {
 178       $label = $self->district . ", $label";
 179     }
 180   }
 181   # ugly labels when taxclass and taxname are both non-null...
 182   # but this is how the tax report does it
 183   if ($opt{with_taxclass}) {
 184     $label = "$label (".$self->taxclass.')' if $self->taxclass;
 185   }
 186   $label = $self->taxname." ($label)" if $self->taxname;
 187
 188   $label;
 189 }
 190
 191 =item sql_taxclass_sameregion
 192
 193 Returns an SQL WHERE fragment or the empty string to search for entries
 194 with different tax classes.
 195
 196 =cut
 197
 198 #hmm, description above could be better...
 199
 200 sub sql_taxclass_sameregion {
 201   my $self = shift;
 202
 203   my $same_query = 'SELECT DISTINCT taxclass FROM cust_main_county '.
 204                    ' WHERE taxnum != ? AND country = ?';
 205   my @same_param = ( 'taxnum', 'country' );
 206   foreach my $opt_field (qw( state county )) {
 207     if ( $self->$opt_field() ) {
 208       $same_query .= " AND $opt_field = ?";
 209       push @same_param, $opt_field;
 210     } else {
 211       $same_query .= " AND $opt_field IS NULL";
 212     }
 213   }
 214
 215   my @taxclasses = $self->_list_sql( \@same_param, $same_query );
 216
 217   return '' unless scalar(@taxclasses);
 218
 219   '( taxclass IS NULL OR ( '.  #only if !$self->taxclass ??
 220      join(' AND ', map { 'taxclass != '.dbh->quote($_) } @taxclasses ).
 221   ' ) ) ';
 222 }
 223
 224 sub _list_sql {
 225   my( $self, $param, $sql ) = @_;
 226   my $sth = dbh->prepare($sql) or die dbh->errstr;
 227   $sth->execute( map $self->$_(), @$param )
 228     or die "Unexpected error executing statement $sql: ". $sth->errstr;
 229   map $_->[0], @{ $sth->fetchall_arrayref };
 230 }
 231
 232 =item taxline TAXABLES_ARRAYREF, [ OPTION => VALUE ... ]
 233
 234 Takes an arrayref of L<FS::cust_bill_pkg> objects representing taxable
 235 line items, and returns a new L<FS::cust_bill_pkg> object representing
 236 the tax on them under this tax rate.
 237
 238 This will have a pseudo-field, "cust_bill_pkg_tax_location", containing
 239 an arrayref of L<FS::cust_bill_pkg_tax_location> objects.  Each of these
 240 will in turn have a "taxable_cust_bill_pkg" pseudo-field linking it to one
 241 of the taxable items.  All of these links must be resolved as the objects
 242 are inserted.
 243
 244 In addition to calculating the tax for the line items, this will calculate
 245 any appropriate tax exemptions and attach them to the line items.
 246
 247 Options may include 'custnum' and 'invoice_time' in case the cust_bill_pkg
 248 objects belong to an invoice that hasn't been inserted yet.
 249
 250 Options may include 'exemptions', an arrayref of L<FS::cust_tax_exempt_pkg>
 251 objects belonging to the same customer, to be counted against the monthly
 252 tax exemption limit if there is one.
 253
 254 =cut
 255
 256 # XXX change tax_rate.pm to work like this
 257
 258 sub taxline {
 259   my( $self, $taxables, %opt ) = @_;
 260   return 'taxline called with no line items' unless @$taxables;
 261
 262   local $SIG{HUP} = 'IGNORE';
 263   local $SIG{INT} = 'IGNORE';
 264   local $SIG{QUIT} = 'IGNORE';
 265   local $SIG{TERM} = 'IGNORE';
 266   local $SIG{TSTP} = 'IGNORE';
 267   local $SIG{PIPE} = 'IGNORE';
 268
 269   my $oldAutoCommit = $FS::UID::AutoCommit;
 270   local $FS::UID::AutoCommit = 0;
 271   my $dbh = dbh;
 272
 273   my $name = $self->taxname || 'Tax';
 274   my $taxable_cents = 0;
 275   my $tax_cents = 0;
 276
 277   my $cust_bill = $taxables->[0]->cust_bill;
 278   my $custnum   = $cust_bill ? $cust_bill->custnum : $opt{'custnum'};
 279   my $invoice_time = $cust_bill ? $cust_bill->_date : $opt{'invoice_time'};
 280   my $cust_main = FS::cust_main->by_key($custnum) if $custnum > 0;
 281   if (!$cust_main) {
 282     # better way to handle this?  should we just assume that it's taxable?
 283     die "unable to calculate taxes for an unknown customer\n";
 284   }
 285
 286   # set a flag if the customer is tax-exempt
 287   my $exempt_cust;
 288   my $conf = FS::Conf->new;
 289   if ( $conf->exists('cust_class-tax_exempt') ) {
 290     my $cust_class = $cust_main->cust_class;
 291     $exempt_cust = $cust_class->tax if $cust_class;
 292   } else {
 293     $exempt_cust = $cust_main->tax;
 294   }
 295
 296   # set a flag if the customer is exempt from this tax here
 297   my $exempt_cust_taxname = $cust_main->tax_exemption($self->taxname)
 298     if $self->taxname;
 299
 300   # Gather any exemptions that are already attached to these cust_bill_pkgs
 301   # so that we can deduct them from the customer's monthly limit.
 302   my @existing_exemptions = @{ $opt{'exemptions'} };
 303   push @existing_exemptions, @{ $_->cust_tax_exempt_pkg }
 304     for @$taxables;
 305
 306   my $tax_item = FS::cust_bill_pkg->new({
 307       'pkgnum'    => 0,
 308       'recur'     => 0,
 309       'sdate'     => '',
 310       'edate'     => '',
 311       'itemdesc'  => $name,
 312   });
 313   my @tax_location;
 314
 315   foreach my $cust_bill_pkg (@$taxables) {
 316
 317     my $cust_pkg  = $cust_bill_pkg->cust_pkg;
 318     my $part_pkg  = $cust_bill_pkg->part_pkg;
 319
 320     my @new_exemptions;
 321     my $taxable_charged = $cust_bill_pkg->setup + $cust_bill_pkg->recur
 322       or next; # don't create zero-amount exemptions
 323
 324     # XXX the following procedure should probably be in cust_bill_pkg
 325
 326     if ( $exempt_cust ) {
 327
 328       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 329           amount => $taxable_charged,
 330           exempt_cust => 'Y',
 331         });
 332       $taxable_charged = 0;
 333
 334     } elsif ( $exempt_cust_taxname ) {
 335
 336       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 337           amount => $taxable_charged,
 338           exempt_cust_taxname => 'Y',
 339         });
 340       $taxable_charged = 0;
 341
 342     }
 343
 344     if ( ($part_pkg->setuptax eq 'Y' or $self->setuptax eq 'Y')
 345         and $cust_bill_pkg->setup > 0 and $taxable_charged > 0 ) {
 346
 347       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 348           amount => $cust_bill_pkg->setup,
 349           exempt_setup => 'Y'
 350       });
 351       $taxable_charged -= $cust_bill_pkg->setup;
 352
 353     }
 354     if ( ($part_pkg->recurtax eq 'Y' or $self->recurtax eq 'Y')
 355         and $cust_bill_pkg->recur > 0 and $taxable_charged > 0 ) {
 356
 357       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 358           amount => $cust_bill_pkg->recur,
 359           exempt_recur => 'Y'
 360       });
 361       $taxable_charged -= $cust_bill_pkg->recur;
 362
 363     }
 364
 365     if ( $self->exempt_amount && $self->exempt_amount > 0
 366       and $taxable_charged > 0 ) {
 367       # If the billing period extends across multiple calendar months,
 368       # there may be several months of exemption available.
 369       my $sdate = $cust_bill_pkg->sdate || $invoice_time;
 370       my $start_month = (localtime($sdate))[4] + 1;
 371       my $start_year  = (localtime($sdate))[5] + 1900;
 372       my $edate = $cust_bill_pkg->edate || $invoice_time;
 373       my $end_month   = (localtime($edate))[4] + 1;
 374       my $end_year    = (localtime($edate))[5] + 1900;
 375
 376       # If the partial last month + partial first month <= one month,
 377       # don't use the exemption in the last month
 378       # (unless the last month is also the first month, e.g. one-time
 379       # charges)
 380       if ( (localtime($sdate))[3] >= (localtime($edate))[3]
 381            and ($start_month != $end_month or $start_year != $end_year)
 382       ) {
 383         $end_month--;
 384         if ( $end_month == 0 ) {
 385           $end_year--;
 386           $end_month = 12;
 387         }
 388       }
 389
 390       # number of months of exemption available
 391       my $freq = ($end_month - $start_month) +
 392                  ($end_year  - $start_year) * 12 +
 393                  1;
 394
 395       # divide equally among all of them
 396       my $permonth = sprintf('%.2f', $taxable_charged / $freq);
 397
 398       #call the whole thing off if this customer has any old
 399       #exemption records...
 400       my @cust_tax_exempt =
 401         qsearch( 'cust_tax_exempt' => { custnum=> $custnum } );
 402       if ( @cust_tax_exempt ) {
 403         $dbh->rollback if $oldAutoCommit;
 404         return
 405           'this customer still has old-style tax exemption records; '.
 406           'run bin/fs-migrate-cust_tax_exempt?';
 407       }
 408
 409       my ($mon, $year) = ($start_month, $start_year);
 410       while ($taxable_charged > 0.005 and
 411              ($year < $end_year or
 412                ($year == $end_year and $mon <= $end_month)
 413              )
 414       ) {
 415
 416         # find the sum of the exemption used by this customer, for this tax,
 417         # in this month
 418         my $sql = "
 419           SELECT SUM(amount)
 420             FROM cust_tax_exempt_pkg
 421               LEFT JOIN cust_bill_pkg USING ( billpkgnum )
 422               LEFT JOIN cust_bill     USING ( invnum     )
 423             WHERE custnum = ?
 424               AND taxnum  = ?
 425               AND year    = ?
 426               AND month   = ?
 427               AND exempt_monthly = 'Y'
 428         ";
 429         my $sth = dbh->prepare($sql) or do {
 430           $dbh->rollback if $oldAutoCommit;
 431           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 432         };
 433         $sth->execute(
 434           $custnum,
 435           $self->taxnum,
 436           $year,
 437           $mon,
 438         ) or do {
 439           $dbh->rollback if $oldAutoCommit;
 440           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 441         };
 442         my $existing_exemption = $sth->fetchrow_arrayref->[0] || 0;
 443
 444         # add any exemption we're already using for another line item
 445         foreach ( grep { $_->taxnum == $self->taxnum &&
 446                          $_->exempt_monthly eq 'Y'   &&
 447                          $_->month  == $mon          &&
 448                          $_->year   == $year
 449                        } @existing_exemptions
 450                 )
 451         {
 452           $existing_exemption += $_->amount;
 453         }
 454
 455         my $remaining_exemption =
 456           $self->exempt_amount - $existing_exemption;
 457         if ( $remaining_exemption > 0 ) {
 458           my $addl = $remaining_exemption > $permonth
 459             ? $permonth
 460             : $remaining_exemption;
 461           $addl = $taxable_charged if $addl > $taxable_charged;
 462
 463           push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 464               amount          => sprintf('%.2f', $addl),
 465               exempt_monthly  => 'Y',
 466               year            => $year,
 467               month           => $mon,
 468             });
 469           $taxable_charged -= $addl;
 470         }
 471         # if they're using multiple months of exemption for a multi-month
 472         # package, then record the exemptions in separate months
 473         $mon++;
 474         if ( $mon > 12 ) {
 475           $mon -= 12;
 476           $year++;
 477         }
 478
 479       }
 480     } # if exempt_amount
 481
 482     $_->taxnum($self->taxnum) foreach @new_exemptions;
 483
 484     # attach them to the line item
 485     push @{ $cust_bill_pkg->cust_tax_exempt_pkg }, @new_exemptions;
 486     push @existing_exemptions, @new_exemptions;
 487
 488     $taxable_charged = sprintf( "%.2f", $taxable_charged);
 489     next if $taxable_charged == 0;
 490
 491     my $this_tax_cents = int($taxable_charged * $self->tax);
 492     my $location = FS::cust_bill_pkg_tax_location->new({
 493         'taxnum'      => $self->taxnum,
 494         'taxtype'     => ref($self),
 495         'cents'       => $this_tax_cents,
 496         'pkgnum'      => $cust_bill_pkg->pkgnum,
 497         'locationnum' => $cust_bill_pkg->cust_pkg->tax_locationnum,
 498         'taxable_cust_bill_pkg' => $cust_bill_pkg,
 499         'tax_cust_bill_pkg'     => $tax_item,
 500     });
 501     push @tax_location, $location;
 502
 503     $taxable_cents += $taxable_charged;
 504     $tax_cents += $this_tax_cents;
 505   } #foreach $cust_bill_pkg
 506
 507   # now round and distribute
 508   my $extra_cents = sprintf('%.2f', $taxable_cents * $self->tax / 100) * 100
 509                     - $tax_cents;
 510   # make sure we have an integer
 511   $extra_cents = sprintf('%.0f', $extra_cents);
 512   if ( $extra_cents < 0 ) {
 513     die "nonsense extra_cents value $extra_cents";
 514   }
 515   $tax_cents += $extra_cents;
 516   my $i = 0;
 517   foreach (@tax_location) { # can never require more than a single pass, yes?
 518     my $cents = $_->get('cents');
 519     if ( $extra_cents > 0 ) {
 520       $cents++;
 521       $extra_cents--;
 522     }
 523     $_->set('amount', sprintf('%.2f', $cents/100));
 524   }
 525   $tax_item->set('setup' => sprintf('%.2f', $tax_cents / 100));
 526   $tax_item->set('cust_bill_pkg_tax_location', \@tax_location);
 527
 528   return $tax_item;
 529 }
 530
 531 =back
 532
 533 =head1 SUBROUTINES
 534
 535 =over 4
 536
 537 =item regionselector [ COUNTY STATE COUNTRY [ PREFIX [ ONCHANGE [ DISABLED ] ] ] ]
 538
 539 =cut
 540
 541 sub regionselector {
 542   my ( $selected_county, $selected_state, $selected_country,
 543        $prefix, $onchange, $disabled ) = @_;
 544
 545   $prefix = '' unless defined $prefix;
 546
 547   $countyflag = 0;
 548
 549 #  unless ( @cust_main_county ) { #cache
 550     @cust_main_county = qsearch('cust_main_county', {} );
 551     foreach my $c ( @cust_main_county ) {
 552       $countyflag=1 if $c->county;
 553       #push @{$cust_main_county{$c->country}{$c->state}}, $c->county;
 554       $cust_main_county{$c->country}{$c->state}{$c->county} = 1;
 555     }
 556 #  }
 557   $countyflag=1 if $selected_county;
 558
 559   my $script_html = <<END;
 560     <SCRIPT>
 561     function opt(what,value,text) {
 562       var optionName = new Option(text, value, false, false);
 563       var length = what.length;
 564       what.options[length] = optionName;
 565     }
 566     function ${prefix}country_changed(what) {
 567       country = what.options[what.selectedIndex].text;
 568       for ( var i = what.form.${prefix}state.length; i >= 0; i-- )
 569           what.form.${prefix}state.options[i] = null;
 570 END
 571       #what.form.${prefix}state.options[0] = new Option('', '', false, true);
 572
 573   foreach my $country ( sort keys %cust_main_county ) {
 574     $script_html .= "\nif ( country == \"$country\" ) {\n";
 575     foreach my $state ( sort keys %{$cust_main_county{$country}} ) {
 576       ( my $dstate = $state ) =~ s/[\n\r]//g;
 577       my $text = $dstate || '(n/a)';
 578       $script_html .= qq!opt(what.form.${prefix}state, "$dstate", "$text");\n!;
 579     }
 580     $script_html .= "}\n";
 581   }
 582
 583   $script_html .= <<END;
 584     }
 585     function ${prefix}state_changed(what) {
 586 END
 587
 588   if ( $countyflag ) {
 589     $script_html .= <<END;
 590       state = what.options[what.selectedIndex].text;
 591       country = what.form.${prefix}country.options[what.form.${prefix}country.selectedIndex].text;
 592       for ( var i = what.form.${prefix}county.length; i >= 0; i-- )
 593           what.form.${prefix}county.options[i] = null;
 594 END
 595
 596     foreach my $country ( sort keys %cust_main_county ) {
 597       $script_html .= "\nif ( country == \"$country\" ) {\n";
 598       foreach my $state ( sort keys %{$cust_main_county{$country}} ) {
 599         $script_html .= "\nif ( state == \"$state\" ) {\n";
 600           #foreach my $county ( sort @{$cust_main_county{$country}{$state}} ) {
 601           foreach my $county ( sort keys %{$cust_main_county{$country}{$state}} ) {
 602             my $text = $county || '(n/a)';
 603             $script_html .=
 604               qq!opt(what.form.${prefix}county, "$county", "$text");\n!;
 605           }
 606         $script_html .= "}\n";
 607       }
 608       $script_html .= "}\n";
 609     }
 610   }
 611
 612   $script_html .= <<END;
 613     }
 614     </SCRIPT>
 615 END
 616
 617   my $county_html = $script_html;
 618   if ( $countyflag ) {
 619     $county_html .= qq!<SELECT NAME="${prefix}county" onChange="$onchange" $disabled>!;
 620     $county_html .= '</SELECT>';
 621   } else {
 622     $county_html .=
 623       qq!<INPUT TYPE="hidden" NAME="${prefix}county" VALUE="$selected_county">!;
 624   }
 625
 626   my $state_html = qq!<SELECT NAME="${prefix}state" !.
 627                    qq!onChange="${prefix}state_changed(this); $onchange" $disabled>!;
 628   foreach my $state ( sort keys %{ $cust_main_county{$selected_country} } ) {
 629     my $text = $state || '(n/a)';
 630     my $selected = $state eq $selected_state ? 'SELECTED' : '';
 631     $state_html .= qq(\n<OPTION $selected VALUE="$state">$text</OPTION>);
 632   }
 633   $state_html .= '</SELECT>';
 634
 635   $state_html .= '</SELECT>';
 636
 637   my $country_html = qq!<SELECT NAME="${prefix}country" !.
 638                      qq!onChange="${prefix}country_changed(this); $onchange" $disabled>!;
 639   my $countrydefault = $conf->config('countrydefault') || 'US';
 640   foreach my $country (
 641     sort { ($b eq $countrydefault) <=> ($a eq $countrydefault) or $a cmp $b }
 642       keys %cust_main_county
 643   ) {
 644     my $selected = $country eq $selected_country ? ' SELECTED' : '';
 645     $country_html .= qq(\n<OPTION$selected VALUE="$country">$country</OPTION>");
 646   }
 647   $country_html .= '</SELECT>';
 648
 649   ($county_html, $state_html, $country_html);
 650
 651 }
 652
 653 =back
 654
 655 =head1 BUGS
 656
 657 regionselector?  putting web ui components in here?  they should probably live
 658 somewhere else...
 659
 660 =head1 SEE ALSO
 661
 662 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill>, schema.html from the base
 663 documentation.
 664
 665 =cut
 666
 667 1;
 668