FS/FS/cust_main_county.pm

   1 package FS::cust_main_county;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $conf
   5              @cust_main_county %cust_main_county $countyflag ); # $cityflag );
   6 use Exporter;
   7 use FS::Record qw( qsearch qsearchs dbh );
   8 use FS::cust_bill_pkg;
   9 use FS::cust_bill;
  10 use FS::cust_pkg;
  11 use FS::part_pkg;
  12 use FS::cust_tax_exempt;
  13 use FS::cust_tax_exempt_pkg;
  14
  15 @ISA = qw( FS::Record );
  16 @EXPORT_OK = qw( regionselector );
  17
  18 @cust_main_county = ();
  19 $countyflag = '';
  20 #$cityflag = '';
  21
  22 #ask FS::UID to run this stuff for us later
  23 $FS::UID::callback{'FS::cust_main_county'} = sub {
  24   $conf = new FS::Conf;
  25 };
  26
  27 =head1 NAME
  28
  29 FS::cust_main_county - Object methods for cust_main_county objects
  30
  31 =head1 SYNOPSIS
  32
  33   use FS::cust_main_county;
  34
  35   $record = new FS::cust_main_county \%hash;
  36   $record = new FS::cust_main_county { 'column' => 'value' };
  37
  38   $error = $record->insert;
  39
  40   $error = $new_record->replace($old_record);
  41
  42   $error = $record->delete;
  43
  44   $error = $record->check;
  45
  46   ($county_html, $state_html, $country_html) =
  47     FS::cust_main_county::regionselector( $county, $state, $country );
  48
  49 =head1 DESCRIPTION
  50
  51 An FS::cust_main_county object represents a tax rate, defined by locale.
  52 FS::cust_main_county inherits from FS::Record.  The following fields are
  53 currently supported:
  54
  55 =over 4
  56
  57 =item taxnum - primary key (assigned automatically for new tax rates)
  58
  59 =item district - tax district (optional)
  60
  61 =item city
  62
  63 =item county
  64
  65 =item state
  66
  67 =item country
  68
  69 =item tax - percentage
  70
  71 =item taxclass
  72
  73 =item exempt_amount
  74
  75 =item taxname - if defined, printed on invoices instead of "Tax"
  76
  77 =item setuptax - if 'Y', this tax does not apply to setup fees
  78
  79 =item recurtax - if 'Y', this tax does not apply to recurring fees
  80
  81 =back
  82
  83 =head1 METHODS
  84
  85 =over 4
  86
  87 =item new HASHREF
  88
  89 Creates a new tax rate.  To add the tax rate to the database, see L<"insert">.
  90
  91 =cut
  92
  93 sub table { 'cust_main_county'; }
  94
  95 =item insert
  96
  97 Adds this tax rate to the database.  If there is an error, returns the error,
  98 otherwise returns false.
  99
 100 =item delete
 101
 102 Deletes this tax rate from the database.  If there is an error, returns the
 103 error, otherwise returns false.
 104
 105 =item replace OLD_RECORD
 106
 107 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 108 returns the error, otherwise returns false.
 109
 110 =item check
 111
 112 Checks all fields to make sure this is a valid tax rate.  If there is an error,
 113 returns the error, otherwise returns false.  Called by the insert and replace
 114 methods.
 115
 116 =cut
 117
 118 sub check {
 119   my $self = shift;
 120
 121   $self->exempt_amount(0) unless $self->exempt_amount;
 122
 123   $self->ut_numbern('taxnum')
 124     || $self->ut_alphan('district')
 125     || $self->ut_textn('city')
 126     || $self->ut_textn('county')
 127     || $self->ut_anything('state')
 128     || $self->ut_text('country')
 129     || $self->ut_float('tax')
 130     || $self->ut_textn('taxclass') # ...
 131     || $self->ut_money('exempt_amount')
 132     || $self->ut_textn('taxname')
 133     || $self->ut_enum('setuptax', [ '', 'Y' ] )
 134     || $self->ut_enum('recurtax', [ '', 'Y' ] )
 135     || $self->SUPER::check
 136     ;
 137
 138 }
 139
 140 =item label OPTIONS
 141
 142 Returns a label looking like "Anytown, Alameda County, CA, US".
 143
 144 If the taxname field is set, it will look like
 145 "CA Sales Tax (Anytown, Alameda County, CA, US)".
 146
 147 If the taxclass is set, then it will be
 148 "Anytown, Alameda County, CA, US (International)".
 149
 150 OPTIONS may contain "with_taxclass", "with_city", and "with_district" to show
 151 those fields.  It may also contain "out", in which case, if this region
 152 (district+city+county+state+country) contains no non-zero taxes, the label
 153 will read "Out of taxable region(s)".
 154
 155 =cut
 156
 157 sub label {
 158   my ($self, %opt) = @_;
 159   if ( $opt{'out'}
 160        and $self->tax == 0
 161        and !defined(qsearchs('cust_main_county', {
 162            'district' => $self->district,
 163            'city'     => $self->city,
 164            'county'   => $self->county,
 165            'state'    => $self->state,
 166            'country'  => $self->country,
 167            'tax'  => { op => '>', value => 0 },
 168         })) )
 169   {
 170     return 'Out of taxable region(s)';
 171   }
 172   my $label = $self->country;
 173   $label = $self->state.", $label" if $self->state;
 174   $label = $self->county." County, $label" if $self->county;
 175   if ($opt{with_city}) {
 176     $label = $self->city.", $label" if $self->city;
 177     if ($opt{with_district} and $self->district) {
 178       $label = $self->district . ", $label";
 179     }
 180   }
 181   # ugly labels when taxclass and taxname are both non-null...
 182   # but this is how the tax report does it
 183   if ($opt{with_taxclass}) {
 184     $label = "$label (".$self->taxclass.')' if $self->taxclass;
 185   }
 186   $label = $self->taxname." ($label)" if $self->taxname;
 187
 188   $label;
 189 }
 190
 191 =item sql_taxclass_sameregion
 192
 193 Returns an SQL WHERE fragment or the empty string to search for entries
 194 with different tax classes.
 195
 196 =cut
 197
 198 #hmm, description above could be better...
 199
 200 sub sql_taxclass_sameregion {
 201   my $self = shift;
 202
 203   my $same_query = 'SELECT DISTINCT taxclass FROM cust_main_county '.
 204                    ' WHERE taxnum != ? AND country = ?';
 205   my @same_param = ( 'taxnum', 'country' );
 206   foreach my $opt_field (qw( state county )) {
 207     if ( $self->$opt_field() ) {
 208       $same_query .= " AND $opt_field = ?";
 209       push @same_param, $opt_field;
 210     } else {
 211       $same_query .= " AND $opt_field IS NULL";
 212     }
 213   }
 214
 215   my @taxclasses = $self->_list_sql( \@same_param, $same_query );
 216
 217   return '' unless scalar(@taxclasses);
 218
 219   '( taxclass IS NULL OR ( '.  #only if !$self->taxclass ??
 220      join(' AND ', map { 'taxclass != '.dbh->quote($_) } @taxclasses ).
 221   ' ) ) ';
 222 }
 223
 224 sub _list_sql {
 225   my( $self, $param, $sql ) = @_;
 226   my $sth = dbh->prepare($sql) or die dbh->errstr;
 227   $sth->execute( map $self->$_(), @$param )
 228     or die "Unexpected error executing statement $sql: ". $sth->errstr;
 229   map $_->[0], @{ $sth->fetchall_arrayref };
 230 }
 231
 232 =item taxline TAXABLES_ARRAYREF, [ OPTION => VALUE ... ]
 233
 234 Takes an arrayref of L<FS::cust_bill_pkg> objects representing taxable
 235 line items, and returns a new L<FS::cust_bill_pkg> object representing
 236 the tax on them under this tax rate.
 237
 238 This will have a pseudo-field, "cust_bill_pkg_tax_location", containing
 239 an arrayref of L<FS::cust_bill_pkg_tax_location> objects.  Each of these
 240 will in turn have a "taxable_cust_bill_pkg" pseudo-field linking it to one
 241 of the taxable items.  All of these links must be resolved as the objects
 242 are inserted.
 243
 244 Options may include 'custnum' and 'invoice_time' in case the cust_bill_pkg
 245 objects belong to an invoice that hasn't been inserted yet.
 246
 247 Options may include 'exemptions', an arrayref of L<FS::cust_tax_exempt_pkg>
 248 objects belonging to the same customer, to be counted against the monthly
 249 tax exemption limit if there is one.
 250
 251 =cut
 252
 253 # XXX change tax_rate.pm to work like this
 254
 255 sub taxline {
 256   my( $self, $taxables, %opt ) = @_;
 257   $taxables = [ $taxables ] unless ref($taxables) eq 'ARRAY';
 258   # remove any charge class identifiers; they're not supported here
 259   @$taxables = grep { ref $_ } @$taxables;
 260
 261   return 'taxline called with no line items' unless @$taxables;
 262
 263   local $SIG{HUP} = 'IGNORE';
 264   local $SIG{INT} = 'IGNORE';
 265   local $SIG{QUIT} = 'IGNORE';
 266   local $SIG{TERM} = 'IGNORE';
 267   local $SIG{TSTP} = 'IGNORE';
 268   local $SIG{PIPE} = 'IGNORE';
 269
 270   my $oldAutoCommit = $FS::UID::AutoCommit;
 271   local $FS::UID::AutoCommit = 0;
 272   my $dbh = dbh;
 273
 274   my $name = $self->taxname || 'Tax';
 275   my $taxable_cents = 0;
 276   my $tax_cents = 0;
 277
 278   my $cust_bill = $taxables->[0]->cust_bill;
 279   my $custnum   = $cust_bill ? $cust_bill->custnum : $opt{'custnum'};
 280   my $invoice_time = $cust_bill ? $cust_bill->_date : $opt{'invoice_time'};
 281   my $cust_main = FS::cust_main->by_key($custnum) if $custnum > 0;
 282   if (!$cust_main) {
 283     # better way to handle this?  should we just assume that it's taxable?
 284     die "unable to calculate taxes for an unknown customer\n";
 285   }
 286
 287   # Gather any exemptions that are already attached to these cust_bill_pkgs
 288   # so that we can deduct them from the customer's monthly limit.
 289   my @existing_exemptions = @{ $opt{'exemptions'} };
 290   push @existing_exemptions, @{ $_->cust_tax_exempt_pkg }
 291     for @$taxables;
 292
 293   my $tax_item = FS::cust_bill_pkg->new({
 294       'pkgnum'    => 0,
 295       'recur'     => 0,
 296       'sdate'     => '',
 297       'edate'     => '',
 298       'itemdesc'  => $name,
 299   });
 300   my @tax_location;
 301
 302   foreach my $cust_bill_pkg (@$taxables) {
 303
 304     my $taxable_charged = $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 305     foreach ( grep { $_->taxnum == $self->taxnum }
 306               @{ $cust_bill_pkg->cust_tax_exempt_pkg }
 307     ) {
 308       # deal with exemptions that have been set on this line item, and
 309       # pertain to this tax def
 310       $taxable_charged -= $_->amount;
 311     }
 312
 313     # can't determine the tax_locationnum directly for fees; they're not
 314     # yet linked to an invoice
 315     my $locationnum = $cust_bill_pkg->tax_locationnum
 316                    || $cust_main->ship_locationnum;
 317
 318     ### Monthly capped exemptions ###
 319     if ( $self->exempt_amount && $self->exempt_amount > 0
 320       and $taxable_charged > 0 ) {
 321       # If the billing period extends across multiple calendar months,
 322       # there may be several months of exemption available.
 323       my $sdate = $cust_bill_pkg->sdate || $invoice_time;
 324       my $start_month = (localtime($sdate))[4] + 1;
 325       my $start_year  = (localtime($sdate))[5] + 1900;
 326       my $edate = $cust_bill_pkg->edate || $invoice_time;
 327       my $end_month   = (localtime($edate))[4] + 1;
 328       my $end_year    = (localtime($edate))[5] + 1900;
 329
 330       # If the partial last month + partial first month <= one month,
 331       # don't use the exemption in the last month
 332       # (unless the last month is also the first month, e.g. one-time
 333       # charges)
 334       if ( (localtime($sdate))[3] >= (localtime($edate))[3]
 335            and ($start_month != $end_month or $start_year != $end_year)
 336       ) {
 337         $end_month--;
 338         if ( $end_month == 0 ) {
 339           $end_year--;
 340           $end_month = 12;
 341         }
 342       }
 343
 344       # number of months of exemption available
 345       my $freq = ($end_month - $start_month) +
 346                  ($end_year  - $start_year) * 12 +
 347                  1;
 348
 349       # divide equally among all of them
 350       my $permonth = sprintf('%.2f', $taxable_charged / $freq);
 351
 352       #call the whole thing off if this customer has any old
 353       #exemption records...
 354       my @cust_tax_exempt =
 355         qsearch( 'cust_tax_exempt' => { custnum=> $custnum } );
 356       if ( @cust_tax_exempt ) {
 357         $dbh->rollback if $oldAutoCommit;
 358         return
 359           'this customer still has old-style tax exemption records; '.
 360           'run bin/fs-migrate-cust_tax_exempt?';
 361       }
 362
 363       my ($mon, $year) = ($start_month, $start_year);
 364       while ($taxable_charged > 0.005 and
 365              ($year < $end_year or
 366                ($year == $end_year and $mon <= $end_month)
 367              )
 368       ) {
 369
 370         # find the sum of the exemption used by this customer, for this tax,
 371         # in this month
 372         my $sql = "
 373           SELECT SUM(amount)
 374             FROM cust_tax_exempt_pkg
 375               LEFT JOIN cust_bill_pkg USING ( billpkgnum )
 376               LEFT JOIN cust_bill     USING ( invnum     )
 377             WHERE custnum = ?
 378               AND taxnum  = ?
 379               AND year    = ?
 380               AND month   = ?
 381               AND exempt_monthly = 'Y'
 382         ";
 383         my $sth = dbh->prepare($sql) or do {
 384           $dbh->rollback if $oldAutoCommit;
 385           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 386         };
 387         $sth->execute(
 388           $custnum,
 389           $self->taxnum,
 390           $year,
 391           $mon,
 392         ) or do {
 393           $dbh->rollback if $oldAutoCommit;
 394           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 395         };
 396         my $existing_exemption = $sth->fetchrow_arrayref->[0] || 0;
 397
 398         # add any exemption we're already using for another line item
 399         foreach ( grep { $_->taxnum == $self->taxnum &&
 400                          $_->exempt_monthly eq 'Y'   &&
 401                          $_->month  == $mon          &&
 402                          $_->year   == $year
 403                        } @existing_exemptions
 404                 )
 405         {
 406           $existing_exemption += $_->amount;
 407         }
 408
 409         my $remaining_exemption =
 410           $self->exempt_amount - $existing_exemption;
 411         if ( $remaining_exemption > 0 ) {
 412           my $addl = $remaining_exemption > $permonth
 413             ? $permonth
 414             : $remaining_exemption;
 415           $addl = $taxable_charged if $addl > $taxable_charged;
 416
 417           my $new_exemption =
 418             FS::cust_tax_exempt_pkg->new({
 419               amount          => sprintf('%.2f', $addl),
 420               exempt_monthly  => 'Y',
 421               year            => $year,
 422               month           => $mon,
 423               taxnum          => $self->taxnum,
 424               taxtype         => ref($self)
 425             });
 426           $taxable_charged -= $addl;
 427
 428           # create a record of it
 429           push @{ $cust_bill_pkg->cust_tax_exempt_pkg }, $new_exemption;
 430           # and allow it to be counted against the limit for other packages
 431           push @existing_exemptions, $new_exemption;
 432         }
 433         # if they're using multiple months of exemption for a multi-month
 434         # package, then record the exemptions in separate months
 435         $mon++;
 436         if ( $mon > 12 ) {
 437           $mon -= 12;
 438           $year++;
 439         }
 440
 441       }
 442     } # if exempt_amount
 443
 444     $taxable_charged = sprintf( "%.2f", $taxable_charged);
 445     next if $taxable_charged == 0;
 446
 447     my $this_tax_cents = int($taxable_charged * $self->tax);
 448     my $location = FS::cust_bill_pkg_tax_location->new({
 449         'taxnum'      => $self->taxnum,
 450         'taxtype'     => ref($self),
 451         'cents'       => $this_tax_cents,
 452         'pkgnum'      => $cust_bill_pkg->pkgnum,
 453         'locationnum' => $locationnum,
 454         'taxable_cust_bill_pkg' => $cust_bill_pkg,
 455         'tax_cust_bill_pkg'     => $tax_item,
 456     });
 457     push @tax_location, $location;
 458
 459     $taxable_cents += $taxable_charged;
 460     $tax_cents += $this_tax_cents;
 461   } #foreach $cust_bill_pkg
 462
 463   # now round and distribute
 464   my $extra_cents = sprintf('%.2f', $taxable_cents * $self->tax / 100) * 100
 465                     - $tax_cents;
 466   # make sure we have an integer
 467   $extra_cents = sprintf('%.0f', $extra_cents);
 468   if ( $extra_cents < 0 ) {
 469     die "nonsense extra_cents value $extra_cents";
 470   }
 471   $tax_cents += $extra_cents;
 472   my $i = 0;
 473   foreach (@tax_location) { # can never require more than a single pass, yes?
 474     my $cents = $_->get('cents');
 475     if ( $extra_cents > 0 ) {
 476       $cents++;
 477       $extra_cents--;
 478     }
 479     $_->set('amount', sprintf('%.2f', $cents/100));
 480   }
 481   $tax_item->set('setup' => sprintf('%.2f', $tax_cents / 100));
 482   $tax_item->set('cust_bill_pkg_tax_location', \@tax_location);
 483
 484   return $tax_item;
 485 }
 486
 487 =back
 488
 489 =head1 SUBROUTINES
 490
 491 =over 4
 492
 493 =item regionselector [ COUNTY STATE COUNTRY [ PREFIX [ ONCHANGE [ DISABLED ] ] ] ]
 494
 495 =cut
 496
 497 sub regionselector {
 498   my ( $selected_county, $selected_state, $selected_country,
 499        $prefix, $onchange, $disabled ) = @_;
 500
 501   $prefix = '' unless defined $prefix;
 502
 503   $countyflag = 0;
 504
 505 #  unless ( @cust_main_county ) { #cache
 506     @cust_main_county = qsearch('cust_main_county', {} );
 507     foreach my $c ( @cust_main_county ) {
 508       $countyflag=1 if $c->county;
 509       #push @{$cust_main_county{$c->country}{$c->state}}, $c->county;
 510       $cust_main_county{$c->country}{$c->state}{$c->county} = 1;
 511     }
 512 #  }
 513   $countyflag=1 if $selected_county;
 514
 515   my $script_html = <<END;
 516     <SCRIPT>
 517     function opt(what,value,text) {
 518       var optionName = new Option(text, value, false, false);
 519       var length = what.length;
 520       what.options[length] = optionName;
 521     }
 522     function ${prefix}country_changed(what) {
 523       country = what.options[what.selectedIndex].text;
 524       for ( var i = what.form.${prefix}state.length; i >= 0; i-- )
 525           what.form.${prefix}state.options[i] = null;
 526 END
 527       #what.form.${prefix}state.options[0] = new Option('', '', false, true);
 528
 529   foreach my $country ( sort keys %cust_main_county ) {
 530     $script_html .= "\nif ( country == \"$country\" ) {\n";
 531     foreach my $state ( sort keys %{$cust_main_county{$country}} ) {
 532       ( my $dstate = $state ) =~ s/[\n\r]//g;
 533       my $text = $dstate || '(n/a)';
 534       $script_html .= qq!opt(what.form.${prefix}state, "$dstate", "$text");\n!;
 535     }
 536     $script_html .= "}\n";
 537   }
 538
 539   $script_html .= <<END;
 540     }
 541     function ${prefix}state_changed(what) {
 542 END
 543
 544   if ( $countyflag ) {
 545     $script_html .= <<END;
 546       state = what.options[what.selectedIndex].text;
 547       country = what.form.${prefix}country.options[what.form.${prefix}country.selectedIndex].text;
 548       for ( var i = what.form.${prefix}county.length; i >= 0; i-- )
 549           what.form.${prefix}county.options[i] = null;
 550 END
 551
 552     foreach my $country ( sort keys %cust_main_county ) {
 553       $script_html .= "\nif ( country == \"$country\" ) {\n";
 554       foreach my $state ( sort keys %{$cust_main_county{$country}} ) {
 555         $script_html .= "\nif ( state == \"$state\" ) {\n";
 556           #foreach my $county ( sort @{$cust_main_county{$country}{$state}} ) {
 557           foreach my $county ( sort keys %{$cust_main_county{$country}{$state}} ) {
 558             my $text = $county || '(n/a)';
 559             $script_html .=
 560               qq!opt(what.form.${prefix}county, "$county", "$text");\n!;
 561           }
 562         $script_html .= "}\n";
 563       }
 564       $script_html .= "}\n";
 565     }
 566   }
 567
 568   $script_html .= <<END;
 569     }
 570     </SCRIPT>
 571 END
 572
 573   my $county_html = $script_html;
 574   if ( $countyflag ) {
 575     $county_html .= qq!<SELECT NAME="${prefix}county" onChange="$onchange" $disabled>!;
 576     $county_html .= '</SELECT>';
 577   } else {
 578     $county_html .=
 579       qq!<INPUT TYPE="hidden" NAME="${prefix}county" VALUE="$selected_county">!;
 580   }
 581
 582   my $state_html = qq!<SELECT NAME="${prefix}state" !.
 583                    qq!onChange="${prefix}state_changed(this); $onchange" $disabled>!;
 584   foreach my $state ( sort keys %{ $cust_main_county{$selected_country} } ) {
 585     my $text = $state || '(n/a)';
 586     my $selected = $state eq $selected_state ? 'SELECTED' : '';
 587     $state_html .= qq(\n<OPTION $selected VALUE="$state">$text</OPTION>);
 588   }
 589   $state_html .= '</SELECT>';
 590
 591   $state_html .= '</SELECT>';
 592
 593   my $country_html = qq!<SELECT NAME="${prefix}country" !.
 594                      qq!onChange="${prefix}country_changed(this); $onchange" $disabled>!;
 595   my $countrydefault = $conf->config('countrydefault') || 'US';
 596   foreach my $country (
 597     sort { ($b eq $countrydefault) <=> ($a eq $countrydefault) or $a cmp $b }
 598       keys %cust_main_county
 599   ) {
 600     my $selected = $country eq $selected_country ? ' SELECTED' : '';
 601     $country_html .= qq(\n<OPTION$selected VALUE="$country">$country</OPTION>");
 602   }
 603   $country_html .= '</SELECT>';
 604
 605   ($county_html, $state_html, $country_html);
 606
 607 }
 608
 609 =back
 610
 611 =head1 BUGS
 612
 613 regionselector?  putting web ui components in here?  they should probably live
 614 somewhere else...
 615
 616 =head1 SEE ALSO
 617
 618 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill>, schema.html from the base
 619 documentation.
 620
 621 =cut
 622
 623 1;
 624