FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12 use FS::payinfo_Mixin;
  13
  14 @EXPORT_OK = qw( smart_search );
  15
  16 # 1 is mostly method/subroutine entry and options
  17 # 2 traces progress of some operations
  18 # 3 is even more information including possibly sensitive data
  19 $DEBUG = 0;
  20 $me = '[FS::cust_main::Search]';
  21
  22 @fuzzyfields = (
  23   'cust_main.first', 'cust_main.last', 'cust_main.company',
  24   'cust_main.ship_company', # if you're using it
  25   'cust_location.address1',
  26   'contact.first',   'contact.last',
  27 );
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Search - Customer searching
  37
  38 =head1 SYNOPSIS
  39
  40   use FS::cust_main::Search;
  41
  42   FS::cust_main::Search::smart_search(%options);
  43
  44   FS::cust_main::Search::email_search(%options);
  45
  46   FS::cust_main::Search->search( \%options );
  47
  48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  49
  50 =head1 SUBROUTINES
  51
  52 =over 4
  53
  54 =item smart_search OPTION => VALUE ...
  55
  56 Accepts the following options: I<search>, the string to search for.  The string
  57 will be searched for as a customer number, phone number, name or company name,
  58 address (if address1-search is on), invoicing email address, or credit card
  59 number.
  60
  61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  63 smart_search to
  64 skip fuzzy matching when an exact match is found.
  65
  66 Any additional options are treated as an additional qualifier on the search
  67 (i.e. I<agentnum>).
  68
  69 Returns a (possibly empty) array of FS::cust_main objects.
  70
  71 =cut
  72
  73 sub smart_search {
  74   my %options = @_;
  75
  76   #here is the agent virtualization
  77   my $agentnums_sql =
  78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  80
  81   my @cust_main = ();
  82
  83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  84   my $search = delete $options{'search'};
  85   ( my $alphanum_search = $search ) =~ s/\W//g;
  86
  87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  88
  89     #false laziness w/Record::ut_phone
  90     my $phonen = "$1-$2-$3";
  91     $phonen .= " x$4" if $4;
  92
  93     my $phonenum = "$1$2$3";
  94     #my $extension = $4;
  95
  96     #cust_main phone numbers
  97     push @cust_main, qsearch( {
  98       'table'   => 'cust_main',
  99       'hashref' => { %options },
 100       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 101                      ' ( '.
 102                          join(' OR ', map "$_ = '$phonen'",
 103                                           qw( daytime night mobile fax )
 104                              ).
 105                      ' ) '.
 106                      " AND $agentnums_sql", #agent virtualization
 107     } );
 108
 109     #contact phone numbers
 110     push @cust_main,
 111       grep $agentnums_href->{$_->agentnum}, #agent virt
 112         grep $_, #skip contacts that don't have cust_main records
 113           map $_->contact->cust_main,
 114             qsearch({
 115                       'table'   => 'contact_phone',
 116                       'hashref' => { 'phonenum' => $phonenum },
 117                    });
 118
 119     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 120       #try looking for matches with extensions unless one was specified
 121
 122       push @cust_main, qsearch( {
 123         'table'   => 'cust_main',
 124         'hashref' => { %options },
 125         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 126                        ' ( '.
 127                            join(' OR ', map "$_ LIKE '$phonen\%'",
 128                                             qw( daytime night )
 129                                ).
 130                        ' ) '.
 131                        " AND $agentnums_sql", #agent virtualization
 132       } );
 133
 134     }
 135
 136   }
 137
 138
 139   if ( $search =~ /@/ ) { #email address
 140
 141       # invoicing email address
 142       push @cust_main,
 143         grep $agentnums_href->{$_->agentnum}, #agent virt
 144           map $_->cust_main,
 145               qsearch( {
 146                          'table'     => 'cust_main_invoice',
 147                          'hashref'   => { 'dest' => $search },
 148                        }
 149                      );
 150
 151       # contact email address
 152       push @cust_main,
 153         grep $agentnums_href->{$_->agentnum}, #agent virt
 154           grep $_, #skip contacts that don't have cust_main records
 155             map $_->contact->cust_main,
 156               qsearch( {
 157                          'table'     => 'contact_email',
 158                          'hashref'   => { 'emailaddress' => $search },
 159                        }
 160                      );
 161
 162   # custnum search (also try agent_custid), with some tweaking options if your
 163   # legacy cust "numbers" have letters
 164   } elsif ( $search =~ /^\s*(\d+)\s*$/
 165          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 166               && $search =~ /^\s*(\w\w?\d+)\s*$/
 167             )
 168          || ( $conf->config('cust_main-custnum-display_special')
 169            # it's not currently possible for special prefixes to contain
 170            # digits, so just strip off any alphabetic prefix and match
 171            # the rest to custnum
 172               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 173             )
 174          || ( $conf->exists('address1-search' )
 175               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 176             )
 177      )
 178   {
 179
 180     my $num = $1;
 181
 182     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 183       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 184                                 ? ' AND agent_custid IS NULL ' : '';
 185       push @cust_main, qsearch( {
 186         'table'     => 'cust_main',
 187         'hashref'   => { 'custnum' => $num, %options },
 188         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 189       } );
 190     }
 191
 192     # for all agents this user can see, if any of them have custnum prefixes
 193     # that match the search string, include customers that match the rest
 194     # of the custnum and belong to that agent
 195     foreach my $agentnum ( keys %$agentnums_href ) {
 196       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 197       next if !$p;
 198       if ( $p eq substr($num, 0, length($p)) ) {
 199         push @cust_main, qsearch( {
 200           'table'   => 'cust_main',
 201           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 202                          'agentnum' => $agentnum,
 203                           %options,
 204                        },
 205         } );
 206       }
 207     }
 208
 209     push @cust_main, qsearch( {
 210         'table'     => 'cust_main',
 211         'hashref'   => { 'agent_custid' => $num, %options },
 212         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 213     } );
 214
 215     if ( $conf->exists('address1-search') ) {
 216       my $len = length($num);
 217       $num = lc($num);
 218       # probably the Right Thing: return customers that have any associated
 219       # locations matching the string, not just bill/ship location
 220       push @cust_main, qsearch( {
 221         'table'     => 'cust_main',
 222         'addl_from' => ' JOIN cust_location USING (custnum) ',
 223         'hashref'   => { %options, },
 224         'extra_sql' =>
 225           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 226           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 227           " AND $agentnums_sql",
 228       } );
 229     }
 230
 231   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 232
 233     my($company, $last, $first) = ( $1, $2, $3 );
 234
 235     # "Company (Last, First)"
 236     #this is probably something a browser remembered,
 237     #so just do an exact search (but case-insensitive, so USPS standardization
 238     #doesn't throw a wrench in the works)
 239
 240     push @cust_main, qsearch( {
 241         'table'     => 'cust_main',
 242         'hashref'   => { %options },
 243         'extra_sql' =>
 244         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 245         join(' AND ',
 246           " LOWER(first)   = ". dbh->quote(lc($first)),
 247           " LOWER(last)    = ". dbh->quote(lc($last)),
 248           " LOWER(company) = ". dbh->quote(lc($company)),
 249           $agentnums_sql,
 250         ),
 251       } ),
 252
 253     #contacts?
 254     # probably not necessary for the "something a browser remembered" case
 255
 256   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 257                                               # try {first,last,company}
 258
 259     my $value = lc($1);
 260
 261     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 262     # # full strings the browser remembers won't work
 263     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 264
 265     use Lingua::EN::NameParse;
 266     my $NameParse = new Lingua::EN::NameParse(
 267              auto_clean     => 1,
 268              allow_reversed => 1,
 269     );
 270
 271     my($last, $first) = ( '', '' );
 272     #maybe disable this too and just rely on NameParse?
 273     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 274
 275       ($last, $first) = ( $1, $2 );
 276
 277     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 278     } elsif ( ! $NameParse->parse($value) ) {
 279
 280       my %name = $NameParse->components;
 281       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 282       $last  = $name{'surname_1'};
 283
 284     }
 285
 286     if ( $first && $last ) {
 287
 288       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 289
 290       #exact
 291       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 292       $sql .= "( LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first )";
 293
 294       #cust_main
 295       push @cust_main, qsearch( {
 296         'table'     => 'cust_main',
 297         'hashref'   => \%options,
 298         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 299       } );
 300
 301       #contacts
 302       push @cust_main,
 303         grep $agentnums_href->{$_->agentnum}, #agent virt
 304           grep $_, #skip contacts that don't have cust_main records
 305             map $_->cust_main,
 306               qsearch( {
 307                          'table'     => 'contact',
 308                          'hashref'   => { 'first' => $first,
 309                                           'last'  => $last,
 310                                         },
 311                        }
 312                      );
 313
 314       # or it just be something that was typed in... (try that in a sec)
 315
 316     }
 317
 318     my $q_value = dbh->quote($value);
 319
 320     #exact
 321     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 322     $sql .= " (    LOWER(cust_main.first)         = $q_value
 323                 OR LOWER(cust_main.last)          = $q_value
 324                 OR LOWER(cust_main.company)       = $q_value
 325                 OR LOWER(cust_main.ship_company)  = $q_value
 326             ";
 327
 328     #address1 (yes, it's a kludge)
 329     $sql .= "   OR EXISTS (
 330                             SELECT 1 FROM cust_location
 331                               WHERE LOWER(cust_location.address1) = $q_value
 332                                 AND cust_location.custnum = cust_main.custnum
 333                           )"
 334       if $conf->exists('address1-search');
 335
 336     #contacts (look, another kludge)
 337     $sql .= "   OR EXISTS ( SELECT 1 FROM contact
 338                               WHERE (    LOWER(contact.first) = $q_value
 339                                       OR LOWER(contact.last)  = $q_value
 340                                     )
 341                                 AND contact.custnum IS NOT NULL
 342                                 AND contact.custnum = cust_main.custnum
 343                           )
 344               ) ";
 345
 346     push @cust_main, qsearch( {
 347       'table'     => 'cust_main',
 348       'hashref'   => \%options,
 349       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 350     } );
 351
 352     #no exact match, trying substring/fuzzy
 353     #always do substring & fuzzy (unless they're explicity config'ed off)
 354     #getting complaints searches are not returning enough
 355     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 356
 357       #still some false laziness w/search (was search/cust_main.cgi)
 358
 359       #substring
 360
 361       my @company_hashrefs = ();
 362       if ( length($value) >= 4 ) {
 363         @company_hashrefs = (
 364           { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 365           { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 366         );
 367       }
 368
 369       my @hashrefs = ();
 370       if ( $first && $last ) {
 371
 372         @hashrefs = (
 373           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 374             'last'         => { op=>'ILIKE', value=>"%$last%" },
 375           },
 376         );
 377
 378       } elsif ( length($value) >= 4 ) {
 379
 380         @hashrefs = (
 381           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 382           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 383         );
 384
 385       }
 386
 387       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 388
 389         push @cust_main, qsearch( {
 390           'table'     => 'cust_main',
 391           'hashref'   => { %$hashref,
 392                            %options,
 393                          },
 394           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 395         } );
 396
 397       }
 398
 399       if ( $conf->exists('address1-search') && length($value) >= 4 ) {
 400
 401         push @cust_main, qsearch( {
 402           table     => 'cust_main',
 403           addl_from => 'JOIN cust_location USING (custnum)',
 404           extra_sql => 'WHERE '.
 405                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 406                         " AND $agentnums_sql", #agent virtualizaiton
 407         } );
 408
 409       }
 410
 411       #contact substring
 412
 413       foreach my $hashref ( @hashrefs ) {
 414
 415         push @cust_main,
 416           grep $agentnums_href->{$_->agentnum}, #agent virt
 417             grep $_, #skip contacts that don't have cust_main records
 418               map $_->cust_main,
 419                 qsearch({
 420                           'table'     => 'contact',
 421                           'hashref'   => { %$hashref,
 422                                            #%options,
 423                                          },
 424                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 425                        });
 426
 427       }
 428
 429       #fuzzy
 430       my %fuzopts = (
 431         'hashref'   => \%options,
 432         'select'    => '',
 433         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 434       );
 435
 436       if ( $first && $last ) {
 437         push @cust_main, FS::cust_main::Search->fuzzy_search(
 438           { 'last'   => $last,    #fuzzy hashref
 439             'first'  => $first }, #
 440           %fuzopts
 441         );
 442         push @cust_main, FS::cust_main::Search->fuzzy_search(
 443           { 'contact.last'   => $last,    #fuzzy hashref
 444             'contact.first'  => $first }, #
 445           %fuzopts
 446         );
 447       }
 448
 449       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 450         push @cust_main, FS::cust_main::Search->fuzzy_search(
 451           { $field => $value },
 452           %fuzopts
 453         );
 454       }
 455       foreach my $field ( 'first', 'last' ) {
 456         push @cust_main, FS::cust_main::Search->fuzzy_search(
 457           { "contact.$field" => $value },
 458           %fuzopts
 459         );
 460       }
 461       if ( $conf->exists('address1-search') ) {
 462         push @cust_main,
 463           FS::cust_main::Search->fuzzy_search(
 464             { 'cust_location.address1' => $value },
 465             %fuzopts
 466         );
 467       }
 468
 469     }
 470
 471   }
 472
 473   ( my $nospace_search = $search ) =~ s/\s//g;
 474   ( my $card_search = $nospace_search ) =~ s/\-//g;
 475   $card_search =~ s/[x\*\.\_]/x/gi;
 476
 477   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 478
 479     ( my $like_search = $card_search ) =~ s/x/_/g;
 480     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 481
 482     push @cust_main, qsearch({
 483       'table'     => 'cust_main',
 484       'addl_from' => ' JOIN cust_payby USING (custnum)',
 485       'hashref'   => {},
 486       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
 487                                OR cust_payby.paymask =    '$mask_search'
 488                              ) ".
 489                      " AND cust_payby.payby IN ('CARD','DCRD') ".
 490                      " AND $agentnums_sql", #agent virtulization
 491     });
 492
 493   }
 494
 495
 496   #eliminate duplicates
 497   my %saw = ();
 498   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 499
 500   @cust_main;
 501
 502 }
 503
 504 =item email_search
 505
 506 Accepts the following options: I<email>, the email address to search for.  The
 507 email address will be searched for as an email invoice destination and as an
 508 svc_acct account.
 509
 510 #Any additional options are treated as an additional qualifier on the search
 511 #(i.e. I<agentnum>).
 512
 513 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 514 none or one).
 515
 516 =cut
 517
 518 sub email_search {
 519   my %options = @_;
 520
 521   my $email = delete $options{'email'};
 522
 523   #no agent virtualization yet
 524   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 525
 526   my @cust_main = ();
 527
 528   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 529
 530     my ( $user, $domain ) = ( $1, $2 );
 531
 532     warn "$me smart_search: searching for $user in domain $domain"
 533       if $DEBUG;
 534
 535     push @cust_main,
 536       map { $_->cust_main }
 537       map { $_->cust_contact }
 538       map { $_->contact }
 539           qsearch( {
 540                      'table'     => 'contact_email',
 541                      'hashref'   => { 'emailaddress' => $email },
 542                    }
 543                  );
 544
 545     push @cust_main,
 546       map  $_->cust_main,
 547       grep $_,
 548       map  $_->cust_svc->cust_pkg,
 549           qsearch( {
 550                      'table'     => 'svc_acct',
 551                      'hashref'   => { 'username' => $user, },
 552                      'extra_sql' =>
 553                        'AND ( SELECT domain FROM svc_domain
 554                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 555                             ) = '. dbh->quote($domain),
 556                    }
 557                  );
 558   }
 559
 560   my %saw = ();
 561   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 562
 563   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 564     if $DEBUG;
 565
 566   @cust_main;
 567
 568 }
 569
 570 =back
 571
 572 =head1 CLASS METHODS
 573
 574 =over 4
 575
 576 =item search HASHREF
 577
 578 (Class method)
 579
 580 Returns a qsearch hash expression to search for parameters specified in
 581 HASHREF.  Valid parameters are
 582
 583 =over 4
 584
 585 =item agentnum
 586
 587 =item status
 588
 589 =item address
 590
 591 =item zip
 592
 593 =item refnum
 594
 595 =item cancelled_pkgs
 596
 597 bool
 598
 599 =item signupdate
 600
 601 listref of start date, end date
 602
 603 =item birthdate
 604
 605 listref of start date, end date
 606
 607 =item spouse_birthdate
 608
 609 listref of start date, end date
 610
 611 =item anniversary_date
 612
 613 listref of start date, end date
 614
 615 =item current_balance
 616
 617 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 618
 619 =item cust_fields
 620
 621 =item flattened_pkgs
 622
 623 bool
 624
 625 =back
 626
 627 =cut
 628
 629 sub search {
 630   my ($class, $params) = @_;
 631
 632   my $dbh = dbh;
 633
 634   my @where = ();
 635   my $orderby;
 636
 637   # initialize these to prevent warnings
 638   $params = {
 639     'custnum'       => '',
 640     'agentnum'      => '',
 641     'usernum'       => '',
 642     'status'        => '',
 643     'address'       => '',
 644     'zip'           => '',
 645     'invoice_terms' => '',
 646     'custbatch'     => '',
 647     %$params
 648   };
 649
 650   ##
 651   # explicit custnum(s)
 652   ##
 653
 654   if ( $params->{'custnum'} ) {
 655     my @custnums = ref($params->{'custnum'}) ?
 656                       @{ $params->{'custnum'} } :
 657                       $params->{'custnum'};
 658     push @where,
 659       'cust_main.custnum IN (' .
 660       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 661       ')' if scalar(@custnums) > 0;
 662   }
 663
 664   ##
 665   # parse agent
 666   ##
 667
 668   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 669     push @where,
 670       "cust_main.agentnum = $1";
 671   }
 672
 673   ##
 674   # parse sales person
 675   ##
 676
 677   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 678     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 679                            : 'cust_main.salesnum IS NULL';
 680   }
 681
 682   ##
 683   # parse usernum
 684   ##
 685
 686   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 687     push @where,
 688       "cust_main.usernum = $1";
 689   }
 690
 691   ##
 692   # parse status
 693   ##
 694
 695   #prospect ordered active inactive suspended cancelled
 696   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 697     my $method = $params->{'status'}. '_sql';
 698     #push @where, $class->$method();
 699     push @where, FS::cust_main->$method();
 700   }
 701
 702   my $current = '';
 703   unless ( $params->{location_history} ) {
 704     $current = '
 705       AND (    cust_location.locationnum IN ( cust_main.bill_locationnum,
 706                                               cust_main.ship_locationnum
 707                                             )
 708             OR cust_location.locationnum IN (
 709                  SELECT locationnum FROM cust_pkg
 710                   WHERE cust_pkg.custnum = cust_main.custnum
 711                     AND locationnum IS NOT NULL
 712                     AND '. FS::cust_pkg->ncancelled_recurring_sql.'
 713                )
 714           )';
 715   }
 716
 717   ##
 718   # address
 719   ##
 720   if ( $params->{'address'} ) {
 721     # allow this to be an arrayref
 722     my @values = ($params->{'address'});
 723     @values = @{$values[0]} if ref($values[0]);
 724     my @orwhere;
 725     foreach (grep /\S/, @values) {
 726       my $address = dbh->quote('%'. lc($_). '%');
 727       push @orwhere,
 728         "LOWER(cust_location.address1) LIKE $address",
 729         "LOWER(cust_location.address2) LIKE $address";
 730     }
 731     if (@orwhere) {
 732       push @where, "EXISTS(
 733         SELECT 1 FROM cust_location
 734         WHERE cust_location.custnum = cust_main.custnum
 735           AND (".join(' OR ',@orwhere).")
 736           $current
 737         )";
 738     }
 739   }
 740
 741   ##
 742   # city
 743   ##
 744   if ( $params->{'city'} =~ /\S/ ) {
 745     my $city = dbh->quote($params->{'city'});
 746     push @where, "EXISTS(
 747       SELECT 1 FROM cust_location
 748       WHERE cust_location.custnum = cust_main.custnum
 749         AND cust_location.city = $city
 750         $current
 751     )";
 752   }
 753
 754   ##
 755   # county
 756   ##
 757   if ( $params->{'county'} =~ /\S/ ) {
 758     my $county = dbh->quote($params->{'county'});
 759     push @where, "EXISTS(
 760       SELECT 1 FROM cust_location
 761       WHERE cust_location.custnum = cust_main.custnum
 762         AND cust_location.county = $county
 763         $current
 764     )";
 765   }
 766
 767   ##
 768   # state
 769   ##
 770   if ( $params->{'state'} =~ /\S/ ) {
 771     my $state = dbh->quote($params->{'state'});
 772     push @where, "EXISTS(
 773       SELECT 1 FROM cust_location
 774       WHERE cust_location.custnum = cust_main.custnum
 775         AND cust_location.state = $state
 776         $current
 777     )";
 778   }
 779
 780   ##
 781   # zipcode
 782   ##
 783   if ( $params->{'zip'} =~ /\S/ ) {
 784     my $zip = dbh->quote($params->{'zip'} . '%');
 785     push @where, "EXISTS(
 786       SELECT 1 FROM cust_location
 787       WHERE cust_location.custnum = cust_main.custnum
 788         AND cust_location.zip LIKE $zip
 789         $current
 790     )";
 791   }
 792
 793   ##
 794   # country
 795   ##
 796   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 797     my $country = uc($1);
 798     push @where, "EXISTS(
 799       SELECT 1 FROM cust_location
 800       WHERE cust_location.custnum = cust_main.custnum
 801         AND cust_location.country = '$country'
 802         $current
 803     )";
 804   }
 805
 806   ###
 807   # refnum
 808   ###
 809   if ( $params->{'refnum'}  ) {
 810
 811     my @refnum = ref( $params->{'refnum'} )
 812                    ? @{ $params->{'refnum'} }
 813                    :  ( $params->{'refnum'} );
 814
 815     @refnum = grep /^(\d*)$/, @refnum;
 816
 817     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 818       if @refnum;
 819
 820   }
 821
 822   ##
 823   # parse cancelled package checkbox
 824   ##
 825
 826   my $pkgwhere = "";
 827
 828   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 829     unless $params->{'cancelled_pkgs'};
 830
 831   ##
 832   # "with email address(es)" checkbox
 833   ##
 834
 835   push @where,
 836     'EXISTS ( SELECT 1 FROM contact_email
 837                 JOIN cust_contact USING (contactnum)
 838                 WHERE cust_contact.custnum = cust_main.custnum
 839             )'
 840     if $params->{'with_email'};
 841
 842   ##
 843   # "with postal mail invoices" checkbox
 844   ##
 845
 846   push @where, "cust_main.postal_invoice = 'Y'"
 847     if $params->{'POST'};
 848
 849   ##
 850   # "without postal mail invoices" checkbox
 851   ##
 852
 853   push @where, "cust_main.postal_invoice IS NULL"
 854     if $params->{'no_POST'};
 855
 856   ##
 857   # "tax exempt" checkbox
 858   ##
 859   push @where, "cust_main.tax = 'Y'"
 860     if $params->{'tax'};
 861
 862   ##
 863   # "not tax exempt" checkbox
 864   ##
 865   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 866     if $params->{'no_tax'};
 867
 868   ##
 869   # dates
 870   ##
 871
 872   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 873
 874     next unless exists($params->{$field});
 875
 876     my($beginning, $ending, $hour) = @{$params->{$field}};
 877
 878     push @where,
 879       "cust_main.$field IS NOT NULL",
 880       "cust_main.$field >= $beginning",
 881       "cust_main.$field <= $ending";
 882
 883     if($field eq 'signupdate' && defined $hour) {
 884       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 885         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 886       }
 887       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 888         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 889       }
 890       else {
 891         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 892       }
 893     }
 894
 895     $orderby ||= "ORDER BY cust_main.$field";
 896
 897   }
 898
 899   ###
 900   # classnum
 901   ###
 902
 903   if ( $params->{'classnum'} ) {
 904
 905     my @classnum = ref( $params->{'classnum'} )
 906                      ? @{ $params->{'classnum'} }
 907                      :  ( $params->{'classnum'} );
 908
 909     @classnum = grep /^(\d*)$/, @classnum;
 910
 911     if ( @classnum ) {
 912       push @where, '( '. join(' OR ', map {
 913                                             $_ ? "cust_main.classnum = $_"
 914                                                : "cust_main.classnum IS NULL"
 915                                           }
 916                                           @classnum
 917                              ).
 918                    ' )';
 919     }
 920
 921   }
 922
 923   ###
 924   # invoice terms
 925   ###
 926
 927   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 928     my $terms = $1;
 929     if ( $1 eq 'NULL' ) {
 930       push @where,
 931         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 932     } else {
 933       push @where,
 934         "cust_main.invoice_terms IS NOT NULL",
 935         "cust_main.invoice_terms = '$1'";
 936     }
 937   }
 938
 939   ##
 940   # amounts
 941   ##
 942
 943   if ( $params->{'current_balance'} ) {
 944
 945     #my $balance_sql = $class->balance_sql();
 946     my $balance_sql = FS::cust_main->balance_sql();
 947
 948     my @current_balance =
 949       ref( $params->{'current_balance'} )
 950       ? @{ $params->{'current_balance'} }
 951       :  ( $params->{'current_balance'} );
 952
 953     push @where, map { s/current_balance/$balance_sql/; $_ }
 954                      @current_balance;
 955
 956   }
 957
 958   ##
 959   # custbatch
 960   ##
 961
 962   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 963     push @where,
 964       "cust_main.custbatch = '$1'";
 965   }
 966
 967   if ( $params->{'tagnum'} ) {
 968     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 969
 970     @tagnums = grep /^(\d+)$/, @tagnums;
 971
 972     if ( @tagnums ) {
 973       if ( $params->{'all_tags'} ) {
 974         foreach ( @tagnums ) {
 975           push @where, 'exists(select 1 from cust_tag where '.
 976                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
 977                        $_ . ')';
 978         }
 979       } else { # matching any tag, not all
 980         my $tags_where = "0 < (select count(1) from cust_tag where "
 981                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 982                 . join(',', @tagnums) . "))";
 983
 984         push @where, $tags_where;
 985       }
 986     }
 987   }
 988
 989   # pkg_classnum
 990   #   all_pkg_classnums
 991   #   any_pkg_status
 992   if ( $params->{'pkg_classnum'} ) {
 993     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
 994                           @{ $params->{'pkg_classnum'} } :
 995                              $params->{'pkg_classnum'};
 996     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
 997
 998     if ( @pkg_classnums ) {
 999
1000       my @pkg_where;
1001       if ( $params->{'all_pkg_classnums'} ) {
1002         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
1003       } else {
1004         push @pkg_where,
1005           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
1006       }
1007       foreach (@pkg_where) {
1008         my $select_pkg =
1009           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
1010           "cust_pkg.custnum = cust_main.custnum AND $_ ";
1011         if ( not $params->{'any_pkg_status'} ) {
1012           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
1013         }
1014         push @where, "EXISTS($select_pkg)";
1015       }
1016     }
1017   }
1018
1019   ##
1020   # setup queries, subs, etc. for the search
1021   ##
1022
1023   $orderby ||= 'ORDER BY custnum';
1024
1025   # here is the agent virtualization
1026   push @where,
1027     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1028
1029   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1030
1031   my $addl_from = '';
1032   # always make address fields available in results
1033   for my $pre ('bill_', 'ship_') {
1034     $addl_from .=
1035       'LEFT JOIN cust_location AS '.$pre.'location '.
1036       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1037   }
1038
1039   # always make referral available in results
1040   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
1041   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
1042
1043   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1044
1045   my @select = (
1046                  'cust_main.custnum',
1047                  'cust_main.salesnum',
1048                  # there's a good chance that we'll need these
1049                  'cust_main.bill_locationnum',
1050                  'cust_main.ship_locationnum',
1051                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1052                );
1053
1054   my(@extra_headers) = ();
1055   my(@extra_fields)  = ();
1056
1057   if ($params->{'flattened_pkgs'}) {
1058
1059     #my $pkg_join = '';
1060     $addl_from .=
1061       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1062
1063     if ($dbh->{Driver}->{Name} eq 'Pg') {
1064
1065       push @select, "
1066         ARRAY_TO_STRING(
1067           ARRAY(
1068             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1069               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1070           ), '|'
1071         ) AS magic
1072       ";
1073
1074     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1075       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1076       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1077       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1078     } else {
1079       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1080            "omitting package information from report.";
1081     }
1082
1083     my $header_query = "
1084       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1085         FROM cust_main $addl_from $extra_sql $pkgwhere
1086           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1087     ";
1088
1089     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1090     $sth->execute() or die $sth->errstr;
1091     my $headerrow = $sth->fetchrow_arrayref;
1092     my $headercount = $headerrow ? $headerrow->[0] : 0;
1093     while($headercount) {
1094       unshift @extra_headers, "Package ". $headercount;
1095       unshift @extra_fields, eval q!sub {my $c = shift;
1096                                          my @a = split '\|', $c->magic;
1097                                          my $p = $a[!.--$headercount. q!];
1098                                          $p;
1099                                         };!;
1100     }
1101
1102   }
1103
1104   my $select = join(', ', @select);
1105
1106   my $sql_query = {
1107     'table'         => 'cust_main',
1108     'select'        => $select,
1109     'addl_from'     => $addl_from,
1110     'hashref'       => {},
1111     'extra_sql'     => $extra_sql,
1112     'order_by'      => $orderby,
1113     'count_query'   => $count_query,
1114     'extra_headers' => \@extra_headers,
1115     'extra_fields'  => \@extra_fields,
1116   };
1117   $sql_query;
1118
1119 }
1120
1121 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1122
1123 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1124 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1125 specified.
1126
1127 Additional options are the same as FS::Record::qsearch
1128
1129 =cut
1130
1131 sub fuzzy_search {
1132   my $self = shift;
1133   my $fuzzy = shift;
1134   # sensible defaults, then merge in any passed options
1135   my %fuzopts = (
1136     'table'     => 'cust_main',
1137     'addl_from' => '',
1138     'extra_sql' => '',
1139     'hashref'   => {},
1140     @_
1141   );
1142
1143   my @cust_main = ();
1144
1145   my @fuzzy_mod = 'i';
1146   my $conf = new FS::Conf;
1147   my $fuzziness = $conf->config('fuzzy-fuzziness');
1148   push @fuzzy_mod, $fuzziness if $fuzziness;
1149
1150   check_and_rebuild_fuzzyfiles();
1151   foreach my $field ( keys %$fuzzy ) {
1152
1153     my $all = $self->all_X($field);
1154     next unless scalar(@$all);
1155
1156     my %match = ();
1157     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1158     next if !keys(%match);
1159
1160     my $in_matches = 'IN (' .
1161                      join(',', map { dbh->quote($_) } keys %match) .
1162                      ')';
1163
1164     my $extra_sql = $fuzopts{extra_sql};
1165     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1166       $extra_sql .= ' AND ';
1167     } else {
1168       $extra_sql .= 'WHERE ';
1169     }
1170     $extra_sql .= "$field $in_matches";
1171
1172     my $addl_from = $fuzopts{addl_from};
1173     if ( $field =~ /^cust_location\./ ) {
1174       $addl_from .= ' JOIN cust_location USING (custnum)';
1175     } elsif ( $field =~ /^contact\./ ) {
1176       $addl_from .= ' JOIN contact USING (custnum)';
1177     }
1178
1179     push @cust_main, qsearch({
1180       %fuzopts,
1181       'addl_from' => $addl_from,
1182       'extra_sql' => $extra_sql,
1183     });
1184   }
1185
1186   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1187   my %saw = ();
1188   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1189
1190   @cust_main;
1191
1192 }
1193
1194 =back
1195
1196 =head1 UTILITY SUBROUTINES
1197
1198 =over 4
1199
1200 =item check_and_rebuild_fuzzyfiles
1201
1202 =cut
1203
1204 sub check_and_rebuild_fuzzyfiles {
1205   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1206   rebuild_fuzzyfiles()
1207     if grep { ! -e "$dir/$_" }
1208          map {
1209                my ($field, $table) = reverse split('\.', $_);
1210                $table ||= 'cust_main';
1211                "$table.$field"
1212              }
1213            @fuzzyfields;
1214 }
1215
1216 =item rebuild_fuzzyfiles
1217
1218 =cut
1219
1220 sub rebuild_fuzzyfiles {
1221
1222   use Fcntl qw(:flock);
1223
1224   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1225   mkdir $dir, 0700 unless -d $dir;
1226
1227   foreach my $fuzzy ( @fuzzyfields ) {
1228
1229     my ($field, $table) = reverse split('\.', $fuzzy);
1230     $table ||= 'cust_main';
1231
1232     open(LOCK,">>$dir/$table.$field")
1233       or die "can't open $dir/$table.$field: $!";
1234     flock(LOCK,LOCK_EX)
1235       or die "can't lock $dir/$table.$field: $!";
1236
1237     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1238       or die "can't open $dir/$table.$field.tmp: $!";
1239
1240     my $sth = dbh->prepare(
1241       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1242     );
1243     $sth->execute or die $sth->errstr;
1244
1245     while ( my $row = $sth->fetchrow_arrayref ) {
1246       print CACHE $row->[0]. "\n";
1247     }
1248
1249     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1250
1251     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1252     close LOCK;
1253   }
1254
1255 }
1256
1257 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1258
1259 =cut
1260
1261 sub append_fuzzyfiles {
1262   #my( $first, $last, $company ) = @_;
1263
1264   check_and_rebuild_fuzzyfiles();
1265
1266   #foreach my $fuzzy (@fuzzyfields) {
1267   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1268                       'cust_location.address1',
1269                       'cust_main.ship_company',
1270                     ) {
1271
1272     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1273
1274   }
1275
1276   1;
1277 }
1278
1279 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1280
1281 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1282
1283 =cut
1284
1285 use Fcntl qw(:flock);
1286 sub append_fuzzyfiles_fuzzyfield {
1287   my( $fuzzyfield, $value ) = @_;
1288
1289   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1290
1291
1292   my ($field, $table) = reverse split('\.', $fuzzyfield);
1293   $table ||= 'cust_main';
1294
1295   return unless defined($value) && length($value);
1296
1297   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1298     or die "can't open $dir/$table.$field: $!";
1299   flock(CACHE,LOCK_EX)
1300     or die "can't lock $dir/$table.$field: $!";
1301
1302   print CACHE "$value\n";
1303
1304   flock(CACHE,LOCK_UN)
1305     or die "can't unlock $dir/$table.$field: $!";
1306   close CACHE;
1307
1308 }
1309
1310 =item all_X
1311
1312 =cut
1313
1314 sub all_X {
1315   my( $self, $fuzzy ) = @_;
1316   my ($field, $table) = reverse split('\.', $fuzzy);
1317   $table ||= 'cust_main';
1318
1319   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1320   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1321     or die "can't open $dir/$table.$field: $!";
1322   my @array = map { chomp; $_; } <CACHE>;
1323   close CACHE;
1324   \@array;
1325 }
1326
1327 =head1 BUGS
1328
1329 Bed bugs
1330
1331 =head1 SEE ALSO
1332
1333 L<FS::cust_main>, L<FS::Record>
1334
1335 =cut
1336
1337 1;
1338