search for tax-exempt customers, RT#31481
[freeside.git] / FS / FS / cust_main / Search.pm
1 package FS::cust_main::Search;
2
3 use strict;
4 use base qw( Exporter );
5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
6 use String::Approx qw(amatch);
7 use FS::UID qw( dbh );
8 use FS::Record qw( qsearch );
9 use FS::cust_main;
10 use FS::cust_main_invoice;
11 use FS::svc_acct;
12 use FS::payinfo_Mixin;
13
14 @EXPORT_OK = qw( smart_search );
15
16 # 1 is mostly method/subroutine entry and options
17 # 2 traces progress of some operations
18 # 3 is even more information including possibly sensitive data
19 $DEBUG = 0;
20 $me = '[FS::cust_main::Search]';
21
22 @fuzzyfields = (
23   'cust_main.first', 'cust_main.last', 'cust_main.company', 
24   'cust_main.ship_company', # if you're using it
25   'cust_location.address1',
26   'contact.first',   'contact.last',
27 );
28
29 install_callback FS::UID sub { 
30   $conf = new FS::Conf;
31   #yes, need it for stuff below (prolly should be cached)
32 };
33
34 =head1 NAME
35
36 FS::cust_main::Search - Customer searching
37
38 =head1 SYNOPSIS
39
40   use FS::cust_main::Search;
41
42   FS::cust_main::Search::smart_search(%options);
43
44   FS::cust_main::Search::email_search(%options);
45
46   FS::cust_main::Search->search( \%options );
47   
48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
49
50 =head1 SUBROUTINES
51
52 =over 4
53
54 =item smart_search OPTION => VALUE ...
55
56 Accepts the following options: I<search>, the string to search for.  The string
57 will be searched for as a customer number, phone number, name or company name,
58 address (if address1-search is on), invoicing email address, or credit card
59 number.
60
61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
63 smart_search to
64 skip fuzzy matching when an exact match is found.
65
66 Any additional options are treated as an additional qualifier on the search
67 (i.e. I<agentnum>).
68
69 Returns a (possibly empty) array of FS::cust_main objects.
70
71 =cut
72
73 sub smart_search {
74   my %options = @_;
75
76   #here is the agent virtualization
77   my $agentnums_sql = 
78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
80
81   my @cust_main = ();
82
83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
84   my $search = delete $options{'search'};
85   ( my $alphanum_search = $search ) =~ s/\W//g;
86   
87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
88
89     #false laziness w/Record::ut_phone
90     my $phonen = "$1-$2-$3";
91     $phonen .= " x$4" if $4;
92
93     my $phonenum = "$1$2$3";
94     #my $extension = $4;
95
96     #cust_main phone numbers
97     push @cust_main, qsearch( {
98       'table'   => 'cust_main',
99       'hashref' => { %options },
100       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
101                      ' ( '.
102                          join(' OR ', map "$_ = '$phonen'",
103                                           qw( daytime night mobile fax )
104                              ).
105                      ' ) '.
106                      " AND $agentnums_sql", #agent virtualization
107     } );
108
109     #contact phone numbers
110     push @cust_main,
111       grep $agentnums_href->{$_->agentnum}, #agent virt
112         grep $_, #skip contacts that don't have cust_main records
113           map $_->contact->cust_main,
114             qsearch({
115                       'table'   => 'contact_phone',
116                       'hashref' => { 'phonenum' => $phonenum },
117                    });
118
119     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
120       #try looking for matches with extensions unless one was specified
121
122       push @cust_main, qsearch( {
123         'table'   => 'cust_main',
124         'hashref' => { %options },
125         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
126                        ' ( '.
127                            join(' OR ', map "$_ LIKE '$phonen\%'",
128                                             qw( daytime night )
129                                ).
130                        ' ) '.
131                        " AND $agentnums_sql", #agent virtualization
132       } );
133
134     }
135
136   } 
137   
138   
139   if ( $search =~ /@/ ) { #email address
140
141       # invoicing email address
142       push @cust_main,
143         grep $agentnums_href->{$_->agentnum}, #agent virt
144           map $_->cust_main,
145               qsearch( {
146                          'table'     => 'cust_main_invoice',
147                          'hashref'   => { 'dest' => $search },
148                        }
149                      );
150
151       # contact email address
152       push @cust_main,
153         grep $agentnums_href->{$_->agentnum}, #agent virt
154           grep $_, #skip contacts that don't have cust_main records
155             map $_->contact->cust_main,
156               qsearch( {
157                          'table'     => 'contact_email',
158                          'hashref'   => { 'emailaddress' => $search },
159                        }
160                      );
161
162   # custnum search (also try agent_custid), with some tweaking options if your
163   # legacy cust "numbers" have letters
164   } elsif ( $search =~ /^\s*(\d+)\s*$/
165          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
166               && $search =~ /^\s*(\w\w?\d+)\s*$/
167             )
168          || ( $conf->config('cust_main-custnum-display_special')
169            # it's not currently possible for special prefixes to contain
170            # digits, so just strip off any alphabetic prefix and match 
171            # the rest to custnum
172               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
173             )
174          || ( $conf->exists('address1-search' )
175               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
176             )
177      )
178   {
179
180     my $num = $1;
181
182     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
183       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
184                                 ? ' AND agent_custid IS NULL ' : '';
185       push @cust_main, qsearch( {
186         'table'     => 'cust_main',
187         'hashref'   => { 'custnum' => $num, %options },
188         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
189       } );
190     }
191
192     # for all agents this user can see, if any of them have custnum prefixes 
193     # that match the search string, include customers that match the rest 
194     # of the custnum and belong to that agent
195     foreach my $agentnum ( keys %$agentnums_href ) {
196       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
197       next if !$p;
198       if ( $p eq substr($num, 0, length($p)) ) {
199         push @cust_main, qsearch( {
200           'table'   => 'cust_main',
201           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
202                          'agentnum' => $agentnum,
203                           %options,
204                        },
205         } );
206       }
207     }
208
209     push @cust_main, qsearch( {
210         'table'     => 'cust_main',
211         'hashref'   => { 'agent_custid' => $num, %options },
212         'extra_sql' => " AND $agentnums_sql", #agent virtualization
213     } );
214
215     if ( $conf->exists('address1-search') ) {
216       my $len = length($num);
217       $num = lc($num);
218       # probably the Right Thing: return customers that have any associated
219       # locations matching the string, not just bill/ship location
220       push @cust_main, qsearch( {
221         'table'     => 'cust_main',
222         'addl_from' => ' JOIN cust_location USING (custnum) ',
223         'hashref'   => { %options, },
224         'extra_sql' => 
225           ( keys(%options) ? ' AND ' : ' WHERE ' ).
226           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
227           " AND $agentnums_sql",
228       } );
229     }
230
231   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
232
233     my($company, $last, $first) = ( $1, $2, $3 );
234
235     # "Company (Last, First)"
236     #this is probably something a browser remembered,
237     #so just do an exact search (but case-insensitive, so USPS standardization
238     #doesn't throw a wrench in the works)
239
240     push @cust_main, qsearch( {
241         'table'     => 'cust_main',
242         'hashref'   => { %options },
243         'extra_sql' => 
244         ( keys(%options) ? ' AND ' : ' WHERE ' ).
245         join(' AND ',
246           " LOWER(first)   = ". dbh->quote(lc($first)),
247           " LOWER(last)    = ". dbh->quote(lc($last)),
248           " LOWER(company) = ". dbh->quote(lc($company)),
249           $agentnums_sql,
250         ),
251       } ),
252
253     #contacts?
254     # probably not necessary for the "something a browser remembered" case
255
256   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
257                                               # try {first,last,company}
258
259     my $value = lc($1);
260
261     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
262     # # full strings the browser remembers won't work
263     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
264
265     use Lingua::EN::NameParse;
266     my $NameParse = new Lingua::EN::NameParse(
267              auto_clean     => 1,
268              allow_reversed => 1,
269     );
270
271     my($last, $first) = ( '', '' );
272     #maybe disable this too and just rely on NameParse?
273     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
274     
275       ($last, $first) = ( $1, $2 );
276     
277     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
278     } elsif ( ! $NameParse->parse($value) ) {
279
280       my %name = $NameParse->components;
281       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
282       $last  = $name{'surname_1'};
283
284     }
285
286     if ( $first && $last ) {
287
288       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
289
290       #exact
291       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
292       $sql .= "( LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first )";
293
294       #cust_main
295       push @cust_main, qsearch( {
296         'table'     => 'cust_main',
297         'hashref'   => \%options,
298         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
299       } );
300
301       #contacts
302       push @cust_main,
303         grep $agentnums_href->{$_->agentnum}, #agent virt
304           grep $_, #skip contacts that don't have cust_main records
305             map $_->cust_main,
306               qsearch( {
307                          'table'     => 'contact',
308                          'hashref'   => { 'first' => $first,
309                                           'last'  => $last,
310                                         }, 
311                        }
312                      );
313
314       # or it just be something that was typed in... (try that in a sec)
315
316     }
317
318     my $q_value = dbh->quote($value);
319
320     #exact
321     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
322     $sql .= " (    LOWER(cust_main.first)         = $q_value
323                 OR LOWER(cust_main.last)          = $q_value
324                 OR LOWER(cust_main.company)       = $q_value
325                 OR LOWER(cust_main.ship_company)  = $q_value
326             ";
327
328     #address1 (yes, it's a kludge)
329     $sql .= "   OR EXISTS ( 
330                             SELECT 1 FROM cust_location 
331                               WHERE LOWER(cust_location.address1) = $q_value
332                                 AND cust_location.custnum = cust_main.custnum
333                           )"
334       if $conf->exists('address1-search');
335
336     #contacts (look, another kludge)
337     $sql .= "   OR EXISTS ( SELECT 1 FROM contact
338                               WHERE (    LOWER(contact.first) = $q_value
339                                       OR LOWER(contact.last)  = $q_value
340                                     )
341                                 AND contact.custnum IS NOT NULL
342                                 AND contact.custnum = cust_main.custnum
343                           )
344               ) ";
345
346     push @cust_main, qsearch( {
347       'table'     => 'cust_main',
348       'hashref'   => \%options,
349       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
350     } );
351
352     #no exact match, trying substring/fuzzy
353     #always do substring & fuzzy (unless they're explicity config'ed off)
354     #getting complaints searches are not returning enough
355     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
356
357       #still some false laziness w/search (was search/cust_main.cgi)
358
359       #substring
360
361       my @company_hashrefs = (
362         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
363         { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
364       );
365
366       my @hashrefs = ();
367
368       if ( $first && $last ) {
369
370         @hashrefs = (
371           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
372             'last'         => { op=>'ILIKE', value=>"%$last%" },
373           },
374         );
375
376       } else {
377
378         @hashrefs = (
379           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
380           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
381         );
382       }
383
384       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
385
386         push @cust_main, qsearch( {
387           'table'     => 'cust_main',
388           'hashref'   => { %$hashref,
389                            %options,
390                          },
391           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
392         } );
393
394       }
395
396       if ( $conf->exists('address1-search') ) {
397
398         push @cust_main, qsearch( {
399           table     => 'cust_main',
400           addl_from => 'JOIN cust_location USING (custnum)',
401           extra_sql => 'WHERE '.
402                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
403                         " AND $agentnums_sql", #agent virtualizaiton
404         } );
405
406       }
407
408       #contact substring
409
410       foreach my $hashref ( @hashrefs ) {
411
412         push @cust_main,
413           grep $agentnums_href->{$_->agentnum}, #agent virt
414             grep $_, #skip contacts that don't have cust_main records
415               map $_->cust_main,
416                 qsearch({
417                           'table'     => 'contact',
418                           'hashref'   => { %$hashref,
419                                            #%options,
420                                          },
421                           #'extra_sql' => " AND $agentnums_sql", #agent virt
422                        });
423
424       }
425
426       #fuzzy
427       my %fuzopts = (
428         'hashref'   => \%options,
429         'select'    => '',
430         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
431       );
432
433       if ( $first && $last ) {
434         push @cust_main, FS::cust_main::Search->fuzzy_search(
435           { 'last'   => $last,    #fuzzy hashref
436             'first'  => $first }, #
437           %fuzopts
438         );
439         push @cust_main, FS::cust_main::Search->fuzzy_search(
440           { 'contact.last'   => $last,    #fuzzy hashref
441             'contact.first'  => $first }, #
442           %fuzopts
443         );
444      }
445       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
446         push @cust_main, FS::cust_main::Search->fuzzy_search(
447           { $field => $value },
448           %fuzopts
449         );
450       }
451       foreach my $field ( 'first', 'last' ) {
452         push @cust_main, FS::cust_main::Search->fuzzy_search(
453           { "contact.$field" => $value },
454           %fuzopts
455         );
456       }
457       if ( $conf->exists('address1-search') ) {
458         push @cust_main,
459           FS::cust_main::Search->fuzzy_search(
460             { 'cust_location.address1' => $value },
461             %fuzopts
462         );
463       }
464
465     }
466
467   }
468
469   ( my $nospace_search = $search ) =~ s/\s//g;
470   ( my $card_search = $nospace_search ) =~ s/\-//g;
471   $card_search =~ s/[x\*\.\_]/x/gi;
472   
473   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
474
475     ( my $like_search = $card_search ) =~ s/x/_/g;
476     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
477
478     push @cust_main, qsearch({
479       'table'     => 'cust_main',
480       'addl_from' => ' JOIN cust_payby USING (custnum)',
481       'hashref'   => {},
482       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
483                                OR cust_payby.paymask =    '$mask_search'
484                              ) ".
485                      " AND cust_payby.payby IN ('CARD','DCRD') ".
486                      " AND $agentnums_sql", #agent virtulization
487     });
488
489   }
490   
491
492   #eliminate duplicates
493   my %saw = ();
494   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
495
496   @cust_main;
497
498 }
499
500 =item email_search
501
502 Accepts the following options: I<email>, the email address to search for.  The
503 email address will be searched for as an email invoice destination and as an
504 svc_acct account.
505
506 #Any additional options are treated as an additional qualifier on the search
507 #(i.e. I<agentnum>).
508
509 Returns a (possibly empty) array of FS::cust_main objects (but usually just
510 none or one).
511
512 =cut
513
514 sub email_search {
515   my %options = @_;
516
517   local($DEBUG) = 1;
518
519   my $email = delete $options{'email'};
520
521   #we're only being used by RT at the moment... no agent virtualization yet
522   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
523
524   my @cust_main = ();
525
526   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
527
528     my ( $user, $domain ) = ( $1, $2 );
529
530     warn "$me smart_search: searching for $user in domain $domain"
531       if $DEBUG;
532
533     push @cust_main,
534       map $_->cust_main,
535           qsearch( {
536                      'table'     => 'cust_main_invoice',
537                      'hashref'   => { 'dest' => $email },
538                    }
539                  );
540
541     push @cust_main,
542       map  $_->cust_main,
543       grep $_,
544       map  $_->cust_svc->cust_pkg,
545           qsearch( {
546                      'table'     => 'svc_acct',
547                      'hashref'   => { 'username' => $user, },
548                      'extra_sql' =>
549                        'AND ( SELECT domain FROM svc_domain
550                                 WHERE svc_acct.domsvc = svc_domain.svcnum
551                             ) = '. dbh->quote($domain),
552                    }
553                  );
554   }
555
556   my %saw = ();
557   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
558
559   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
560     if $DEBUG;
561
562   @cust_main;
563
564 }
565
566 =back
567
568 =head1 CLASS METHODS
569
570 =over 4
571
572 =item search HASHREF
573
574 (Class method)
575
576 Returns a qsearch hash expression to search for parameters specified in
577 HASHREF.  Valid parameters are
578
579 =over 4
580
581 =item agentnum
582
583 =item status
584
585 =item address
586
587 =item zip
588
589 =item refnum
590
591 =item cancelled_pkgs
592
593 bool
594
595 =item signupdate
596
597 listref of start date, end date
598
599 =item birthdate
600
601 listref of start date, end date
602
603 =item spouse_birthdate
604
605 listref of start date, end date
606
607 =item anniversary_date
608
609 listref of start date, end date
610
611 =item payby
612
613 listref
614
615 =item paydate_year
616
617 =item paydate_month
618
619 =item current_balance
620
621 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
622
623 =item cust_fields
624
625 =item flattened_pkgs
626
627 bool
628
629 =back
630
631 =cut
632
633 sub search {
634   my ($class, $params) = @_;
635
636   my $dbh = dbh;
637
638   my @where = ();
639   my $orderby;
640
641   # initialize these to prevent warnings
642   $params = {
643     'custnum'       => '',
644     'agentnum'      => '',
645     'usernum'       => '',
646     'status'        => '',
647     'address'       => '',
648     'zip'           => '',
649     'paydate_year'  => '',
650     'invoice_terms' => '',
651     'custbatch'     => '',
652     %$params
653   };
654
655   ##
656   # explicit custnum(s)
657   ##
658
659   if ( $params->{'custnum'} ) {
660     my @custnums = ref($params->{'custnum'}) ? 
661                       @{ $params->{'custnum'} } : 
662                       $params->{'custnum'};
663     push @where, 
664       'cust_main.custnum IN (' . 
665       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
666       ')' if scalar(@custnums) > 0;
667   }
668
669   ##
670   # parse agent
671   ##
672
673   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
674     push @where,
675       "cust_main.agentnum = $1";
676   }
677
678   ##
679   # parse sales person
680   ##
681
682   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
683     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
684                            : 'cust_main.salesnum IS NULL';
685   }
686
687   ##
688   # parse usernum
689   ##
690
691   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
692     push @where,
693       "cust_main.usernum = $1";
694   }
695
696   ##
697   # parse status
698   ##
699
700   #prospect ordered active inactive suspended cancelled
701   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
702     my $method = $params->{'status'}. '_sql';
703     #push @where, $class->$method();
704     push @where, FS::cust_main->$method();
705   }
706
707   ##
708   # address
709   ##
710   if ( $params->{'address'} ) {
711     # allow this to be an arrayref
712     my @values = ($params->{'address'});
713     @values = @{$values[0]} if ref($values[0]);
714     my @orwhere;
715     foreach (grep /\S/, @values) {
716       my $address = dbh->quote('%'. lc($_). '%');
717       push @orwhere,
718         "LOWER(cust_location.address1) LIKE $address",
719         "LOWER(cust_location.address2) LIKE $address";
720     }
721     if (@orwhere) {
722       push @where, "EXISTS(
723         SELECT 1 FROM cust_location 
724         WHERE cust_location.custnum = cust_main.custnum
725           AND (".join(' OR ',@orwhere).")
726         )";
727     }
728   }
729
730   ##
731   # county
732   ##
733   if ( $params->{'county'} =~ /\S/ ) {
734     my $county = dbh->quote($params->{'county'});
735     push @where, "EXISTS(
736       SELECT 1 FROM cust_location
737       WHERE cust_location.custnum = cust_main.custnum
738         AND cust_location.county = $county
739     )";
740   }
741
742   ##
743   # state
744   ##
745   if ( $params->{'state'} =~ /\S/ ) {
746     my $state = dbh->quote($params->{'state'});
747     push @where, "EXISTS(
748       SELECT 1 FROM cust_location
749       WHERE cust_location.custnum = cust_main.custnum
750         AND cust_location.state = $state
751     )";
752   }
753
754   ##
755   # zipcode
756   ##
757   if ( $params->{'zip'} =~ /\S/ ) {
758     my $zip = dbh->quote($params->{'zip'} . '%');
759     push @where, "EXISTS(
760       SELECT 1 FROM cust_location
761       WHERE cust_location.custnum = cust_main.custnum
762         AND cust_location.zip LIKE $zip
763     )";
764   }
765
766   ##
767   # country
768   ##
769   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
770     my $country = uc($1);
771     push @where, "EXISTS(
772       SELECT 1 FROM cust_location
773       WHERE cust_location.custnum = cust_main.custnum
774         AND cust_location.country = '$country'
775     )";
776   }
777
778   ###
779   # refnum
780   ###
781   if ( $params->{'refnum'}  ) {
782
783     my @refnum = ref( $params->{'refnum'} )
784                    ? @{ $params->{'refnum'} }
785                    :  ( $params->{'refnum'} );
786
787     @refnum = grep /^(\d*)$/, @refnum;
788
789     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
790       if @refnum;
791
792   }
793
794   ##
795   # parse cancelled package checkbox
796   ##
797
798   my $pkgwhere = "";
799
800   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
801     unless $params->{'cancelled_pkgs'};
802
803   ##
804   # "with email address(es)" checkbox
805   ##
806
807   push @where,
808     'EXISTS ( SELECT 1 FROM cust_main_invoice
809                 WHERE cust_main_invoice.custnum = cust_main.custnum
810                   AND length(dest) > 5
811             )'  # AND dest LIKE '%@%'
812     if $params->{'with_email'};
813
814   ##
815   # "with postal mail invoices" checkbox
816   ##
817
818   push @where,
819     "EXISTS ( SELECT 1 FROM cust_main_invoice
820                 WHERE cust_main_invoice.custnum = cust_main.custnum
821                   AND dest = 'POST' )"
822     if $params->{'POST'};
823
824   ##
825   # "without postal mail invoices" checkbox
826   ##
827
828   push @where,
829     "NOT EXISTS ( SELECT 1 FROM cust_main_invoice
830                     WHERE cust_main_invoice.custnum = cust_main.custnum
831                       AND dest = 'POST' )"
832     if $params->{'no_POST'};
833
834   ##
835   # "tax exempt" checkbox
836   ##
837   push @where, "cust_main.tax = 'Y'"
838     if $params->{'tax'};
839
840   ##
841   # "not tax exempt" checkbox
842   ##
843   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
844     if $params->{'no_tax'};
845
846   ##
847   # dates
848   ##
849
850   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
851
852     next unless exists($params->{$field});
853
854     my($beginning, $ending, $hour) = @{$params->{$field}};
855
856     push @where,
857       "cust_main.$field IS NOT NULL",
858       "cust_main.$field >= $beginning",
859       "cust_main.$field <= $ending";
860
861     if($field eq 'signupdate' && defined $hour) {
862       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
863         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
864       }
865       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
866         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
867       }
868       else {
869         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
870       }
871     }
872
873     $orderby ||= "ORDER BY cust_main.$field";
874
875   }
876
877   ###
878   # classnum
879   ###
880
881   if ( $params->{'classnum'} ) {
882
883     my @classnum = ref( $params->{'classnum'} )
884                      ? @{ $params->{'classnum'} }
885                      :  ( $params->{'classnum'} );
886
887     @classnum = grep /^(\d*)$/, @classnum;
888
889     if ( @classnum ) {
890       push @where, '( '. join(' OR ', map {
891                                             $_ ? "cust_main.classnum = $_"
892                                                : "cust_main.classnum IS NULL"
893                                           }
894                                           @classnum
895                              ).
896                    ' )';
897     }
898
899   }
900
901   ###
902   # payby
903   ###
904
905   if ( $params->{'payby'} ) {
906
907     my @payby = ref( $params->{'payby'} )
908                   ? @{ $params->{'payby'} }
909                   :  ( $params->{'payby'} );
910
911     @payby = grep /^([A-Z]{4})$/, @payby;
912     my $in_payby = 'IN(' . join(',', map {"'$_'"} @payby) . ')';
913     push @where, "EXISTS( SELECT 1 FROM cust_payby WHERE payby $in_payby ".
914                  "AND cust_payby.custnum = cust_main.custnum)"
915       if @payby;
916   }
917
918   ###
919   # paydate_year / paydate_month
920   ###
921
922   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
923     my $year = $1;
924     $params->{'paydate_month'} =~ /^(\d\d?)$/
925       or die "paydate_year without paydate_month?";
926     my $month = $1;
927
928     push @where,
929       'paydate IS NOT NULL',
930       "paydate != ''",
931       "CAST(paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
932 ;
933   }
934
935   ###
936   # invoice terms
937   ###
938
939   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
940     my $terms = $1;
941     if ( $1 eq 'NULL' ) {
942       push @where,
943         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
944     } else {
945       push @where,
946         "cust_main.invoice_terms IS NOT NULL",
947         "cust_main.invoice_terms = '$1'";
948     }
949   }
950
951   ##
952   # amounts
953   ##
954
955   if ( $params->{'current_balance'} ) {
956
957     #my $balance_sql = $class->balance_sql();
958     my $balance_sql = FS::cust_main->balance_sql();
959
960     my @current_balance =
961       ref( $params->{'current_balance'} )
962       ? @{ $params->{'current_balance'} }
963       :  ( $params->{'current_balance'} );
964
965     push @where, map { s/current_balance/$balance_sql/; $_ }
966                      @current_balance;
967
968   }
969
970   ##
971   # custbatch
972   ##
973
974   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
975     push @where,
976       "cust_main.custbatch = '$1'";
977   }
978   
979   if ( $params->{'tagnum'} ) {
980     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
981
982     @tagnums = grep /^(\d+)$/, @tagnums;
983
984     if ( @tagnums ) {
985       if ( $params->{'all_tags'} ) {
986         foreach ( @tagnums ) {
987           push @where, 'exists(select 1 from cust_tag where '.
988                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
989                        $_ . ')';
990         }
991       } else { # matching any tag, not all
992         my $tags_where = "0 < (select count(1) from cust_tag where " 
993                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
994                 . join(',', @tagnums) . "))";
995
996         push @where, $tags_where;
997       }
998     }
999   }
1000
1001   # pkg_classnum
1002   #   all_pkg_classnums
1003   #   any_pkg_status
1004   if ( $params->{'pkg_classnum'} ) {
1005     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
1006                           @{ $params->{'pkg_classnum'} } :
1007                              $params->{'pkg_classnum'};
1008     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
1009
1010     if ( @pkg_classnums ) {
1011
1012       my @pkg_where;
1013       if ( $params->{'all_pkg_classnums'} ) {
1014         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
1015       } else {
1016         push @pkg_where,
1017           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
1018       }
1019       foreach (@pkg_where) {
1020         my $select_pkg = 
1021           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
1022           "cust_pkg.custnum = cust_main.custnum AND $_ ";
1023         if ( not $params->{'any_pkg_status'} ) {
1024           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
1025         }
1026         push @where, "EXISTS($select_pkg)";
1027       }
1028     }
1029   }
1030
1031   ##
1032   # setup queries, subs, etc. for the search
1033   ##
1034
1035   $orderby ||= 'ORDER BY custnum';
1036
1037   # here is the agent virtualization
1038   push @where,
1039     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1040
1041   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1042
1043   my $addl_from = '';
1044   # always make address fields available in results
1045   for my $pre ('bill_', 'ship_') {
1046     $addl_from .= 
1047       'LEFT JOIN cust_location AS '.$pre.'location '.
1048       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1049   }
1050
1051   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1052
1053   my @select = (
1054                  'cust_main.custnum',
1055                  'cust_main.salesnum',
1056                  # there's a good chance that we'll need these
1057                  'cust_main.bill_locationnum',
1058                  'cust_main.ship_locationnum',
1059                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1060                );
1061
1062   my(@extra_headers) = ();
1063   my(@extra_fields)  = ();
1064
1065   if ($params->{'flattened_pkgs'}) {
1066
1067     #my $pkg_join = '';
1068     $addl_from .=
1069       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1070
1071     if ($dbh->{Driver}->{Name} eq 'Pg') {
1072
1073       push @select, "
1074         ARRAY_TO_STRING(
1075           ARRAY(
1076             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1077               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1078           ), '|'
1079         ) AS magic
1080       ";
1081
1082     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1083       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1084       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1085       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1086     } else {
1087       warn "warning: unknown database type ". $dbh->{Driver}->{Name}. 
1088            "omitting package information from report.";
1089     }
1090
1091     my $header_query = "
1092       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1093         FROM cust_main $addl_from $extra_sql $pkgwhere
1094           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1095     ";
1096
1097     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1098     $sth->execute() or die $sth->errstr;
1099     my $headerrow = $sth->fetchrow_arrayref;
1100     my $headercount = $headerrow ? $headerrow->[0] : 0;
1101     while($headercount) {
1102       unshift @extra_headers, "Package ". $headercount;
1103       unshift @extra_fields, eval q!sub {my $c = shift;
1104                                          my @a = split '\|', $c->magic;
1105                                          my $p = $a[!.--$headercount. q!];
1106                                          $p;
1107                                         };!;
1108     }
1109
1110   }
1111
1112   my $select = join(', ', @select);
1113
1114   my $sql_query = {
1115     'table'         => 'cust_main',
1116     'select'        => $select,
1117     'addl_from'     => $addl_from,
1118     'hashref'       => {},
1119     'extra_sql'     => $extra_sql,
1120     'order_by'      => $orderby,
1121     'count_query'   => $count_query,
1122     'extra_headers' => \@extra_headers,
1123     'extra_fields'  => \@extra_fields,
1124   };
1125   #warn Data::Dumper::Dumper($sql_query);
1126   $sql_query;
1127
1128 }
1129
1130 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1131
1132 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1133 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1134 specified.
1135
1136 Additional options are the same as FS::Record::qsearch
1137
1138 =cut
1139
1140 sub fuzzy_search {
1141   my $self = shift;
1142   my $fuzzy = shift;
1143   # sensible defaults, then merge in any passed options
1144   my %fuzopts = (
1145     'table'     => 'cust_main',
1146     'addl_from' => '',
1147     'extra_sql' => '',
1148     'hashref'   => {},
1149     @_
1150   );
1151
1152   my @cust_main = ();
1153
1154   my @fuzzy_mod = 'i';
1155   my $conf = new FS::Conf;
1156   my $fuzziness = $conf->config('fuzzy-fuzziness');
1157   push @fuzzy_mod, $fuzziness if $fuzziness;
1158
1159   check_and_rebuild_fuzzyfiles();
1160   foreach my $field ( keys %$fuzzy ) {
1161
1162     my $all = $self->all_X($field);
1163     next unless scalar(@$all);
1164
1165     my %match = ();
1166     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1167     next if !keys(%match);
1168
1169     my $in_matches = 'IN (' .
1170                      join(',', map { dbh->quote($_) } keys %match) .
1171                      ')';
1172
1173     my $extra_sql = $fuzopts{extra_sql};
1174     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1175       $extra_sql .= ' AND ';
1176     } else {
1177       $extra_sql .= 'WHERE ';
1178     }
1179     $extra_sql .= "$field $in_matches";
1180
1181     my $addl_from = $fuzopts{addl_from};
1182     if ( $field =~ /^cust_location\./ ) {
1183       $addl_from .= ' JOIN cust_location USING (custnum)';
1184     } elsif ( $field =~ /^contact\./ ) {
1185       $addl_from .= ' JOIN contact USING (custnum)';
1186     }
1187
1188     push @cust_main, qsearch({
1189       %fuzopts,
1190       'addl_from' => $addl_from,
1191       'extra_sql' => $extra_sql,
1192     });
1193   }
1194
1195   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1196   my %saw = ();
1197   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1198
1199   @cust_main;
1200
1201 }
1202
1203 =back
1204
1205 =head1 UTILITY SUBROUTINES
1206
1207 =over 4
1208
1209 =item check_and_rebuild_fuzzyfiles
1210
1211 =cut
1212
1213 sub check_and_rebuild_fuzzyfiles {
1214   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1215   rebuild_fuzzyfiles()
1216     if grep { ! -e "$dir/$_" }
1217          map {
1218                my ($field, $table) = reverse split('\.', $_);
1219                $table ||= 'cust_main';
1220                "$table.$field"
1221              }
1222            @fuzzyfields;
1223 }
1224
1225 =item rebuild_fuzzyfiles
1226
1227 =cut
1228
1229 sub rebuild_fuzzyfiles {
1230
1231   use Fcntl qw(:flock);
1232
1233   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1234   mkdir $dir, 0700 unless -d $dir;
1235
1236   foreach my $fuzzy ( @fuzzyfields ) {
1237
1238     my ($field, $table) = reverse split('\.', $fuzzy);
1239     $table ||= 'cust_main';
1240
1241     open(LOCK,">>$dir/$table.$field")
1242       or die "can't open $dir/$table.$field: $!";
1243     flock(LOCK,LOCK_EX)
1244       or die "can't lock $dir/$table.$field: $!";
1245
1246     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1247       or die "can't open $dir/$table.$field.tmp: $!";
1248
1249     my $sth = dbh->prepare(
1250       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1251     );
1252     $sth->execute or die $sth->errstr;
1253
1254     while ( my $row = $sth->fetchrow_arrayref ) {
1255       print CACHE $row->[0]. "\n";
1256     }
1257
1258     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1259   
1260     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1261     close LOCK;
1262   }
1263
1264 }
1265
1266 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1267
1268 =cut
1269
1270 sub append_fuzzyfiles {
1271   #my( $first, $last, $company ) = @_;
1272
1273   check_and_rebuild_fuzzyfiles();
1274
1275   #foreach my $fuzzy (@fuzzyfields) {
1276   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company', 
1277                       'cust_location.address1',
1278                       'cust_main.ship_company',
1279                     ) {
1280
1281     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1282
1283   }
1284
1285   1;
1286 }
1287
1288 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1289
1290 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1291
1292 =cut
1293
1294 use Fcntl qw(:flock);
1295 sub append_fuzzyfiles_fuzzyfield {
1296   my( $fuzzyfield, $value ) = @_;
1297
1298   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1299
1300
1301   my ($field, $table) = reverse split('\.', $fuzzyfield);
1302   $table ||= 'cust_main';
1303
1304   return unless defined($value) && length($value);
1305
1306   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1307     or die "can't open $dir/$table.$field: $!";
1308   flock(CACHE,LOCK_EX)
1309     or die "can't lock $dir/$table.$field: $!";
1310
1311   print CACHE "$value\n";
1312
1313   flock(CACHE,LOCK_UN)
1314     or die "can't unlock $dir/$table.$field: $!";
1315   close CACHE;
1316
1317 }
1318
1319 =item all_X
1320
1321 =cut
1322
1323 sub all_X {
1324   my( $self, $fuzzy ) = @_;
1325   my ($field, $table) = reverse split('\.', $fuzzy);
1326   $table ||= 'cust_main';
1327
1328   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1329   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1330     or die "can't open $dir/$table.$field: $!";
1331   my @array = map { chomp; $_; } <CACHE>;
1332   close CACHE;
1333   \@array;
1334 }
1335
1336 =head1 BUGS
1337
1338 Bed bugs
1339
1340 =head1 SEE ALSO
1341
1342 L<FS::cust_main>, L<FS::Record>
1343
1344 =cut
1345
1346 1;
1347