FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12 use FS::payinfo_Mixin;
  13
  14 @EXPORT_OK = qw( smart_search );
  15
  16 # 1 is mostly method/subroutine entry and options
  17 # 2 traces progress of some operations
  18 # 3 is even more information including possibly sensitive data
  19 $DEBUG = 0;
  20 $me = '[FS::cust_main::Search]';
  21
  22 @fuzzyfields = (
  23   'cust_main.first', 'cust_main.last', 'cust_main.company',
  24   'cust_main.ship_company', # if you're using it
  25   'cust_location.address1',
  26   'contact.first',   'contact.last',
  27 );
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Search - Customer searching
  37
  38 =head1 SYNOPSIS
  39
  40   use FS::cust_main::Search;
  41
  42   FS::cust_main::Search::smart_search(%options);
  43
  44   FS::cust_main::Search::email_search(%options);
  45
  46   FS::cust_main::Search->search( \%options );
  47
  48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  49
  50 =head1 SUBROUTINES
  51
  52 =over 4
  53
  54 =item smart_search OPTION => VALUE ...
  55
  56 Accepts the following options: I<search>, the string to search for.  The string
  57 will be searched for as a customer number, phone number, name or company name,
  58 address (if address1-search is on), invoicing email address, or credit card
  59 number.
  60
  61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  63 smart_search to
  64 skip fuzzy matching when an exact match is found.
  65
  66 Any additional options are treated as an additional qualifier on the search
  67 (i.e. I<agentnum>).
  68
  69 Returns a (possibly empty) array of FS::cust_main objects.
  70
  71 =cut
  72
  73 sub smart_search {
  74   my %options = @_;
  75
  76   #here is the agent virtualization
  77   my $agentnums_sql =
  78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  80
  81   my @cust_main = ();
  82
  83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  84   my $search = delete $options{'search'};
  85   ( my $alphanum_search = $search ) =~ s/\W//g;
  86
  87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  88
  89     #false laziness w/Record::ut_phone
  90     my $phonen = "$1-$2-$3";
  91     $phonen .= " x$4" if $4;
  92
  93     my $phonenum = "$1$2$3";
  94     #my $extension = $4;
  95
  96     #cust_main phone numbers and contact phone number
  97     push @cust_main, qsearch( {
  98       'select'    => 'cust_main.*',
  99       'table'     => 'cust_main',
 100       'addl_from' => ' left join cust_contact  using (custnum) '.
 101                      ' left join contact_phone using (contactnum) ',
 102       'hashref'   => { %options },
 103       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 104                      ' ( '.
 105                          join(' OR ', map "$_ = '$phonen'",
 106                                           qw( daytime night mobile fax )
 107                              ).
 108                           " OR phonenum = '$phonenum' ".
 109                      ' ) '.
 110                      " AND $agentnums_sql", #agent virtualization
 111     } );
 112
 113     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 114       #try looking for matches with extensions unless one was specified
 115
 116       push @cust_main, qsearch( {
 117         'table'     => 'cust_main',
 118         'hashref'   => { %options },
 119         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 120                        ' ( '.
 121                            join(' OR ', map "$_ LIKE '$phonen\%'",
 122                                             qw( daytime night )
 123                                ).
 124                        ' ) '.
 125                        " AND $agentnums_sql", #agent virtualization
 126       } );
 127
 128     }
 129
 130   }
 131
 132
 133   if ( $search =~ /@/ ) { #email address from cust_main_invoice and contact_email
 134
 135     push @cust_main, qsearch( {
 136       'select'    => 'cust_main.*',
 137       'table'     => 'cust_main',
 138       'addl_from' => ' left join cust_main_invoice using (custnum) '.
 139                      ' left join cust_contact      using (custnum) '.
 140                      ' left join contact_email     using (contactnum) ',
 141       'hashref'   => { %options },
 142       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 143                      ' ( '.
 144                          join(' OR ', map "$_ = '$search'",
 145                                           qw( dest emailaddress )
 146                              ).
 147                      ' ) '.
 148                      " AND $agentnums_sql", #agent virtualization
 149     } );
 150
 151   # custnum search (also try agent_custid), with some tweaking options if your
 152   # legacy cust "numbers" have letters
 153   } elsif (    $search =~ /^\s*(\d+)\s*$/
 154             or ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 155                  && $search =~ /^\s*(\w\w?\d+)\s*$/
 156                )
 157             or ( $conf->config('cust_main-agent_custid-format') eq 'd+-w'
 158                  && $search =~ /^\s*(\d+-\w)\s*$/
 159                )
 160             or ( $conf->config('cust_main-custnum-display_special')
 161                  # it's not currently possible for special prefixes to contain
 162                  # digits, so just strip off any alphabetic prefix and match
 163                  # the rest to custnum
 164                  && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 165                )
 166             or ( $conf->exists('address1-search' )
 167                  && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 168                )
 169           )
 170   {
 171
 172     my $num = $1;
 173
 174     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 175       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 176                                 ? ' AND agent_custid IS NULL ' : '';
 177       push @cust_main, qsearch( {
 178         'table'     => 'cust_main',
 179         'hashref'   => { 'custnum' => $num, %options },
 180         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 181       } );
 182     }
 183
 184     # for all agents this user can see, if any of them have custnum prefixes
 185     # that match the search string, include customers that match the rest
 186     # of the custnum and belong to that agent
 187     foreach my $agentnum ( keys %$agentnums_href ) {
 188       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 189       next if !$p;
 190       if ( $p eq substr($num, 0, length($p)) ) {
 191         push @cust_main, qsearch( {
 192           'table'   => 'cust_main',
 193           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 194                          'agentnum' => $agentnum,
 195                           %options,
 196                        },
 197         } );
 198       }
 199     }
 200
 201     push @cust_main, qsearch( {
 202         'table'     => 'cust_main',
 203         'hashref'   => { 'agent_custid' => $num, %options },
 204         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 205     } );
 206
 207     if ( $conf->exists('address1-search') ) {
 208       my $len = length($num);
 209       $num = lc($num);
 210       # probably the Right Thing: return customers that have any associated
 211       # locations matching the string, not just bill/ship location
 212       push @cust_main, qsearch( {
 213         'select'    => 'cust_main.*',
 214         'table'     => 'cust_main',
 215         'addl_from' => ' JOIN cust_location USING (custnum) ',
 216         'hashref'   => { %options, },
 217         'extra_sql' =>
 218           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 219           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 220           " AND $agentnums_sql",
 221       } );
 222     }
 223
 224   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 225
 226     my($company, $last, $first) = ( $1, $2, $3 );
 227
 228     # "Company (Last, First)"
 229     #this is probably something a browser remembered,
 230     #so just do an exact search (but case-insensitive, so USPS standardization
 231     #doesn't throw a wrench in the works)
 232
 233     push @cust_main, qsearch( {
 234       'table'     => 'cust_main',
 235       'hashref'   => { %options },
 236       'extra_sql' =>
 237         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 238         join(' AND ',
 239           " LOWER(first)   = ". dbh->quote(lc($first)),
 240           " LOWER(last)    = ". dbh->quote(lc($last)),
 241           " LOWER(company) = ". dbh->quote(lc($company)),
 242           $agentnums_sql,
 243         ),
 244     } );
 245
 246     #contacts?
 247     # probably not necessary for the "something a browser remembered" case
 248
 249   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 250                                               # try {first,last,company}
 251
 252     my $value = lc($1);
 253
 254     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 255     # # full strings the browser remembers won't work
 256     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 257
 258     use Lingua::EN::NameParse;
 259     my $NameParse = new Lingua::EN::NameParse(
 260              auto_clean     => 1,
 261              allow_reversed => 1,
 262     );
 263
 264     my($last, $first) = ( '', '' );
 265     #maybe disable this too and just rely on NameParse?
 266     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 267
 268       ($last, $first) = ( $1, $2 );
 269
 270     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 271     } elsif ( ! $NameParse->parse($value) ) {
 272
 273       my %name = $NameParse->components;
 274       $first = lc($name{'given_name_1'}) || $name{'initials_1'}; #wtf NameParse, Ed?
 275       $last  = lc($name{'surname_1'});
 276
 277     }
 278
 279     if ( $first && $last ) {
 280
 281       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 282
 283       #exact
 284       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 285       $sql .= "( (LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first)
 286                  OR (LOWER(contact.last) = $q_last AND LOWER(contact.first) = $q_first) )";
 287
 288       #cust_main and contacts
 289       push @cust_main, qsearch( {
 290         'select'    => 'cust_main.*',
 291         'table'     => 'cust_main',
 292         'addl_from' => ' left join cust_contact using (custnum) '.
 293                        ' left join contact using (contactnum) ',
 294         'hashref'   => { %options },
 295         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 296       } );
 297
 298       # or it just be something that was typed in... (try that in a sec)
 299
 300     }
 301
 302     my $q_value = dbh->quote($value);
 303
 304     #exact
 305     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 306     $sql .= " (    LOWER(cust_main.first)         = $q_value
 307                 OR LOWER(cust_main.last)          = $q_value
 308                 OR LOWER(cust_main.company)       = $q_value
 309                 OR LOWER(cust_main.ship_company)  = $q_value
 310                 OR LOWER(contact.first)           = $q_value
 311                 OR LOWER(contact.last)            = $q_value
 312             )";
 313
 314     #address1 (yes, it's a kludge)
 315     $sql .= "   OR EXISTS (
 316                             SELECT 1 FROM cust_location
 317                               WHERE LOWER(cust_location.address1) = $q_value
 318                                 AND cust_location.custnum = cust_main.custnum
 319                           )"
 320       if $conf->exists('address1-search');
 321
 322     push @cust_main, qsearch( {
 323       'select'    => 'cust_main.*',
 324       'table'     => 'cust_main',
 325       'addl_from' => ' left join cust_contact using (custnum) '.
 326                      ' left join contact using (contactnum) ',
 327       'hashref'   => { %options },
 328       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 329     } );
 330
 331     #no exact match, trying substring/fuzzy
 332     #always do substring & fuzzy (unless they're explicity config'ed off)
 333     #getting complaints searches are not returning enough
 334     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 335
 336       #still some false laziness w/search (was search/cust_main.cgi)
 337
 338       my $min_len =
 339         $FS::CurrentUser::CurrentUser->access_right('List all customers')
 340         ? 3 : 4;
 341
 342       #substring
 343
 344       my @company_hashrefs = ();
 345       if ( length($value) >= $min_len ) {
 346         @company_hashrefs = (
 347           { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 348           { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 349         );
 350       }
 351
 352       my @hashrefs = ();
 353       if ( $first && $last ) {
 354
 355         @hashrefs = (
 356           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 357             'last'         => { op=>'ILIKE', value=>"%$last%" },
 358           },
 359         );
 360
 361       } elsif ( length($value) >= $min_len ) {
 362
 363         @hashrefs = (
 364           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 365           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 366         );
 367
 368       }
 369
 370       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 371
 372         push @cust_main, qsearch( {
 373           'table'     => 'cust_main',
 374           'hashref'   => { %$hashref,
 375                            %options,
 376                          },
 377           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 378         } );
 379
 380       }
 381
 382       if ( $conf->exists('address1-search') && length($value) >= $min_len ) {
 383
 384         push @cust_main, qsearch( {
 385           table     => 'cust_main',
 386           addl_from => 'JOIN cust_location USING (custnum)',
 387           extra_sql => 'WHERE '.
 388                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 389                         " AND $agentnums_sql", #agent virtualizaiton
 390         } );
 391
 392       }
 393
 394       #contact substring
 395
 396       foreach my $hashref ( @hashrefs ) {
 397
 398         push @cust_main,
 399           grep $agentnums_href->{$_->agentnum}, #agent virt
 400             grep $_, #skip contacts that don't have cust_main records
 401               map $_->cust_main,
 402                 qsearch({
 403                           'table'     => 'contact',
 404                           'hashref'   => { %$hashref,
 405                                            #%options,
 406                                          },
 407                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 408                        });
 409
 410       }
 411
 412       #fuzzy
 413       my %fuzopts = (
 414         'hashref'   => \%options,
 415         'select'    => '',
 416         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 417       );
 418
 419       if ( $first && $last ) {
 420         push @cust_main, FS::cust_main::Search->fuzzy_search(
 421           { 'last'   => $last,    #fuzzy hashref
 422             'first'  => $first }, #
 423           %fuzopts
 424         );
 425         push @cust_main, FS::cust_main::Search->fuzzy_search(
 426           { 'contact.last'   => $last,    #fuzzy hashref
 427             'contact.first'  => $first }, #
 428           %fuzopts
 429         );
 430       }
 431
 432       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 433         push @cust_main, FS::cust_main::Search->fuzzy_search(
 434           { $field => $value },
 435           %fuzopts
 436         );
 437       }
 438       foreach my $field ( 'first', 'last' ) {
 439         push @cust_main, FS::cust_main::Search->fuzzy_search(
 440           { "contact.$field" => $value },
 441           %fuzopts
 442         );
 443       }
 444       if ( $conf->exists('address1-search') ) {
 445         push @cust_main,
 446           FS::cust_main::Search->fuzzy_search(
 447             { 'cust_location.address1' => $value },
 448             %fuzopts
 449         );
 450       }
 451
 452     }
 453
 454   }
 455
 456   ( my $nospace_search = $search ) =~ s/\s//g;
 457   ( my $card_search = $nospace_search ) =~ s/\-//g;
 458   $card_search =~ s/[x\*\.\_]/x/gi;
 459
 460   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 461
 462     ( my $like_search = $card_search ) =~ s/x/_/g;
 463     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 464
 465     push @cust_main, qsearch({
 466       'table'     => 'cust_main',
 467       'addl_from' => ' JOIN cust_payby USING (custnum)',
 468       'hashref'   => {},
 469       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
 470                                OR cust_payby.paymask =    '$mask_search'
 471                              ) ".
 472                      " AND cust_payby.payby IN ('CARD','DCRD') ".
 473                      " AND $agentnums_sql", #agent virtulization
 474     });
 475
 476   }
 477
 478
 479   #eliminate duplicates
 480   my %saw = ();
 481   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 482
 483   @cust_main;
 484
 485 }
 486
 487 =item email_search
 488
 489 Accepts the following options: I<email>, the email address to search for.  The
 490 email address will be searched for as an email invoice destination and as an
 491 svc_acct account.
 492
 493 #Any additional options are treated as an additional qualifier on the search
 494 #(i.e. I<agentnum>).
 495
 496 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 497 none or one).
 498
 499 =cut
 500
 501 sub email_search {
 502   my %options = @_;
 503
 504   my $email = delete $options{'email'};
 505
 506   #no agent virtualization yet
 507   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 508
 509   my @cust_main = ();
 510
 511   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 512
 513     my ( $user, $domain ) = ( $1, $2 );
 514
 515     warn "$me smart_search: searching for $user in domain $domain"
 516       if $DEBUG;
 517
 518     push @cust_main,
 519       map { $_->cust_main }
 520       map { $_->cust_contact }
 521       map { $_->contact }
 522           qsearch( {
 523                      'table'     => 'contact_email',
 524                      'hashref'   => { 'emailaddress' => $email },
 525                    }
 526                  );
 527
 528     push @cust_main,
 529       map  $_->cust_main,
 530       grep $_,
 531       map  $_->cust_svc->cust_pkg,
 532           qsearch( {
 533                      'table'     => 'svc_acct',
 534                      'hashref'   => { 'username' => $user, },
 535                      'extra_sql' =>
 536                        'AND ( SELECT domain FROM svc_domain
 537                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 538                             ) = '. dbh->quote($domain),
 539                    }
 540                  );
 541   }
 542
 543   my %saw = ();
 544   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 545
 546   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 547     if $DEBUG;
 548
 549   @cust_main;
 550
 551 }
 552
 553 =back
 554
 555 =head1 CLASS METHODS
 556
 557 =over 4
 558
 559 =item search HASHREF
 560
 561 (Class method)
 562
 563 Returns a qsearch hash expression to search for parameters specified in
 564 HASHREF.  Valid parameters are
 565
 566 =over 4
 567
 568 =item agentnum
 569
 570 =item status
 571
 572 =item address
 573
 574 =item zip
 575
 576 =item refnum
 577
 578 =item cancelled_pkgs
 579
 580 bool
 581
 582 =item signupdate
 583
 584 listref of start date, end date
 585
 586 =item birthdate
 587
 588 listref of start date, end date
 589
 590 =item spouse_birthdate
 591
 592 listref of start date, end date
 593
 594 =item anniversary_date
 595
 596 listref of start date, end date
 597
 598 =item current_balance
 599
 600 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 601
 602 =item cust_fields
 603
 604 =item flattened_pkgs
 605
 606 bool
 607
 608 =back
 609
 610 =cut
 611
 612 sub search {
 613   my ($class, $params) = @_;
 614
 615   my $dbh = dbh;
 616
 617   my @where = ();
 618   my $orderby;
 619
 620   # initialize these to prevent warnings
 621   $params = {
 622     'custnum'       => '',
 623     'agentnum'      => '',
 624     'usernum'       => '',
 625     'status'        => '',
 626     'address'       => '',
 627     'zip'           => '',
 628     'invoice_terms' => '',
 629     'custbatch'     => '',
 630     %$params
 631   };
 632
 633   ##
 634   # explicit custnum(s)
 635   ##
 636
 637   if ( $params->{'custnum'} ) {
 638     my @custnums = ref($params->{'custnum'}) ?
 639                       @{ $params->{'custnum'} } :
 640                       $params->{'custnum'};
 641     push @where,
 642       'cust_main.custnum IN (' .
 643       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 644       ')' if scalar(@custnums) > 0;
 645   }
 646
 647   ##
 648   # parse agent
 649   ##
 650
 651   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 652     push @where,
 653       "cust_main.agentnum = $1";
 654   }
 655
 656   ##
 657   # parse sales person
 658   ##
 659
 660   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 661     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 662                            : 'cust_main.salesnum IS NULL';
 663   }
 664
 665   ##
 666   # parse usernum
 667   ##
 668
 669   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 670     push @where,
 671       "cust_main.usernum = $1";
 672   }
 673
 674   ##
 675   # parse status
 676   ##
 677
 678   #prospect ordered active inactive suspended cancelled
 679   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 680     my $method = $params->{'status'}. '_sql';
 681     #push @where, $class->$method();
 682     push @where, FS::cust_main->$method();
 683   }
 684
 685   my $current = '';
 686   unless ( $params->{location_history} ) {
 687     $current = '
 688       AND (    cust_location.locationnum IN ( cust_main.bill_locationnum,
 689                                               cust_main.ship_locationnum
 690                                             )
 691             OR cust_location.locationnum IN (
 692                  SELECT locationnum FROM cust_pkg
 693                   WHERE cust_pkg.custnum = cust_main.custnum
 694                     AND locationnum IS NOT NULL
 695                     AND '. FS::cust_pkg->ncancelled_recurring_sql.'
 696                )
 697           )';
 698   }
 699
 700   ##
 701   # address
 702   ##
 703   if ( $params->{'address'} ) {
 704     # allow this to be an arrayref
 705     my @values = ($params->{'address'});
 706     @values = @{$values[0]} if ref($values[0]);
 707     my @orwhere;
 708     foreach (grep /\S/, @values) {
 709       my $address = dbh->quote('%'. lc($_). '%');
 710       push @orwhere,
 711         "LOWER(cust_location.address1) LIKE $address",
 712         "LOWER(cust_location.address2) LIKE $address";
 713     }
 714     if (@orwhere) {
 715       push @where, "EXISTS(
 716         SELECT 1 FROM cust_location
 717         WHERE cust_location.custnum = cust_main.custnum
 718           AND (".join(' OR ',@orwhere).")
 719           $current
 720         )";
 721     }
 722   }
 723
 724   ##
 725   # city
 726   ##
 727   if ( $params->{'city'} =~ /\S/ ) {
 728     my $city = dbh->quote($params->{'city'});
 729     push @where, "EXISTS(
 730       SELECT 1 FROM cust_location
 731       WHERE cust_location.custnum = cust_main.custnum
 732         AND cust_location.city = $city
 733         $current
 734     )";
 735   }
 736
 737   ##
 738   # county
 739   ##
 740   if ( $params->{'county'} =~ /\S/ ) {
 741     my $county = dbh->quote($params->{'county'});
 742     push @where, "EXISTS(
 743       SELECT 1 FROM cust_location
 744       WHERE cust_location.custnum = cust_main.custnum
 745         AND cust_location.county = $county
 746         $current
 747     )";
 748   }
 749
 750   ##
 751   # state
 752   ##
 753   if ( $params->{'state'} =~ /\S/ ) {
 754     my $state = dbh->quote($params->{'state'});
 755     push @where, "EXISTS(
 756       SELECT 1 FROM cust_location
 757       WHERE cust_location.custnum = cust_main.custnum
 758         AND cust_location.state = $state
 759         $current
 760     )";
 761   }
 762
 763   ##
 764   # zipcode
 765   ##
 766   if ( $params->{'zip'} =~ /\S/ ) {
 767     my $zip = dbh->quote($params->{'zip'} . '%');
 768     push @where, "EXISTS(
 769       SELECT 1 FROM cust_location
 770       WHERE cust_location.custnum = cust_main.custnum
 771         AND cust_location.zip LIKE $zip
 772         $current
 773     )";
 774   }
 775
 776   ##
 777   # country
 778   ##
 779   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 780     my $country = uc($1);
 781     push @where, "EXISTS(
 782       SELECT 1 FROM cust_location
 783       WHERE cust_location.custnum = cust_main.custnum
 784         AND cust_location.country = '$country'
 785         $current
 786     )";
 787   }
 788
 789   ###
 790   # refnum
 791   ###
 792   if ( $params->{'refnum'}  ) {
 793
 794     my @refnum = ref( $params->{'refnum'} )
 795                    ? @{ $params->{'refnum'} }
 796                    :  ( $params->{'refnum'} );
 797
 798     @refnum = grep /^(\d*)$/, @refnum;
 799
 800     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 801       if @refnum;
 802
 803   }
 804
 805   ##
 806   # parse cancelled package checkbox
 807   ##
 808
 809   my $pkgwhere = "";
 810
 811   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 812     unless $params->{'cancelled_pkgs'};
 813
 814   ##
 815   # "with email address(es)" checkbox
 816   ##
 817
 818   push @where,
 819     'EXISTS ( SELECT 1 FROM contact_email
 820                 JOIN cust_contact USING (contactnum)
 821                 WHERE cust_contact.custnum = cust_main.custnum
 822             )'
 823     if $params->{'with_email'};
 824
 825   ##
 826   # "with postal mail invoices" checkbox
 827   ##
 828
 829   push @where, "cust_main.postal_invoice = 'Y'"
 830     if $params->{'POST'};
 831
 832   ##
 833   # "without postal mail invoices" checkbox
 834   ##
 835
 836   push @where, "cust_main.postal_invoice IS NULL"
 837     if $params->{'no_POST'};
 838
 839   ##
 840   # "tax exempt" checkbox
 841   ##
 842   push @where, "cust_main.tax = 'Y'"
 843     if $params->{'tax'};
 844
 845   ##
 846   # "not tax exempt" checkbox
 847   ##
 848   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 849     if $params->{'no_tax'};
 850
 851   ##
 852   # with referrals
 853   ##
 854   if ( $params->{with_referrals} =~ /^\s*(\d+)\s*$/ ) {
 855
 856     my $n = $1;
 857
 858     # referral status
 859     my $and_status = '';
 860     if ( grep { $params->{referral_status} eq $_ } FS::cust_main->statuses() ) {
 861       my $method = $params->{referral_status}. '_sql';
 862       $and_status = ' AND '. FS::cust_main->$method();
 863       $and_status =~ s/ cust_main\./ referred_cust_main./g;
 864     }
 865
 866     push @where,
 867       " $n <= ( SELECT COUNT(*) FROM cust_main AS referred_cust_main
 868                   WHERE cust_main.custnum = referred_cust_main.referral_custnum
 869                     $and_status
 870               )";
 871
 872   }
 873
 874   ##
 875   # dates
 876   ##
 877
 878   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 879
 880     next unless exists($params->{$field});
 881
 882     my($beginning, $ending, $hour) = @{$params->{$field}};
 883
 884     push @where,
 885       "cust_main.$field IS NOT NULL",
 886       "cust_main.$field >= $beginning",
 887       "cust_main.$field <= $ending";
 888
 889     if($field eq 'signupdate' && defined $hour) {
 890       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 891         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 892       }
 893       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 894         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 895       }
 896       else {
 897         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 898       }
 899     }
 900
 901     $orderby ||= "ORDER BY cust_main.$field";
 902
 903   }
 904
 905   ###
 906   # classnum
 907   ###
 908
 909   if ( $params->{'classnum'} ) {
 910
 911     my @classnum = ref( $params->{'classnum'} )
 912                      ? @{ $params->{'classnum'} }
 913                      :  ( $params->{'classnum'} );
 914
 915     @classnum = grep /^(\d*)$/, @classnum;
 916
 917     if ( @classnum ) {
 918       push @where, '( '. join(' OR ', map {
 919                                             $_ ? "cust_main.classnum = $_"
 920                                                : "cust_main.classnum IS NULL"
 921                                           }
 922                                           @classnum
 923                              ).
 924                    ' )';
 925     }
 926
 927   }
 928
 929   ###
 930   # invoice terms
 931   ###
 932
 933   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 934     my $terms = $1;
 935     if ( $1 eq 'NULL' ) {
 936       push @where,
 937         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 938     } else {
 939       push @where,
 940         "cust_main.invoice_terms IS NOT NULL",
 941         "cust_main.invoice_terms = '$1'";
 942     }
 943   }
 944
 945   ##
 946   # amounts
 947   ##
 948
 949   if ( $params->{'current_balance'} ) {
 950
 951     #my $balance_sql = $class->balance_sql();
 952     my $balance_sql = FS::cust_main->balance_sql();
 953
 954     my @current_balance =
 955       ref( $params->{'current_balance'} )
 956       ? @{ $params->{'current_balance'} }
 957       :  ( $params->{'current_balance'} );
 958
 959     push @where, map { s/current_balance/$balance_sql/; $_ }
 960                      @current_balance;
 961
 962   }
 963
 964   ##
 965   # custbatch
 966   ##
 967
 968   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 969     push @where,
 970       "cust_main.custbatch = '$1'";
 971   }
 972
 973   if ( $params->{'tagnum'} ) {
 974     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 975
 976     @tagnums = grep /^(\d+)$/, @tagnums;
 977
 978     if ( @tagnums ) {
 979       if ( $params->{'all_tags'} ) {
 980         foreach ( @tagnums ) {
 981           push @where, 'exists(select 1 from cust_tag where '.
 982                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
 983                        $_ . ')';
 984         }
 985       } else { # matching any tag, not all
 986         my $tags_where = "0 < (select count(1) from cust_tag where "
 987                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 988                 . join(',', @tagnums) . "))";
 989
 990         push @where, $tags_where;
 991       }
 992     }
 993   }
 994
 995   # pkg_classnum
 996   #   all_pkg_classnums
 997   #   any_pkg_status
 998   if ( $params->{'pkg_classnum'} ) {
 999     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
1000                           @{ $params->{'pkg_classnum'} } :
1001                              $params->{'pkg_classnum'};
1002     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
1003
1004     if ( @pkg_classnums ) {
1005
1006       my @pkg_where;
1007       if ( $params->{'all_pkg_classnums'} ) {
1008         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
1009       } else {
1010         push @pkg_where,
1011           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
1012       }
1013       foreach (@pkg_where) {
1014         my $select_pkg =
1015           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
1016           "cust_pkg.custnum = cust_main.custnum AND $_ ";
1017         if ( not $params->{'any_pkg_status'} ) {
1018           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
1019         }
1020         push @where, "EXISTS($select_pkg)";
1021       }
1022     }
1023   }
1024
1025   ##
1026   # setup queries, subs, etc. for the search
1027   ##
1028
1029   $orderby ||= 'ORDER BY custnum';
1030
1031   # here is the agent virtualization
1032   push @where,
1033     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1034
1035   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1036
1037   my $addl_from = '';
1038   # always make address fields available in results
1039   for my $pre ('bill_', 'ship_') {
1040     $addl_from .=
1041       'LEFT JOIN cust_location AS '.$pre.'location '.
1042       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1043   }
1044
1045   # always make referral available in results
1046   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
1047   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
1048
1049   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1050
1051   my @select = (
1052                  'cust_main.custnum',
1053                  'cust_main.salesnum',
1054                  # there's a good chance that we'll need these
1055                  'cust_main.bill_locationnum',
1056                  'cust_main.ship_locationnum',
1057                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1058                );
1059
1060   my @extra_headers     = ();
1061   my @extra_fields      = ();
1062   my @extra_sort_fields = ();
1063
1064   ## search contacts
1065   if ($params->{'contacts'}) {
1066     my $contact_params = $params->{'contacts'};
1067
1068     $addl_from .=
1069       ' LEFT JOIN cust_contact ON ( cust_main.custnum = cust_contact.custnum ) ';
1070
1071     if ($contact_params->{'contacts_firstname'} || $contact_params->{'contacts_lastname'}) {
1072       $addl_from .= ' LEFT JOIN contact ON ( cust_contact.contactnum = contact.contactnum ) ';
1073       my $first_query = " AND contact.first = '" . $contact_params->{'contacts_firstname'} . "'"
1074         unless !$contact_params->{'contacts_firstname'};
1075       my $last_query = " AND contact.last = '" . $contact_params->{'contacts_lastname'} . "'"
1076         unless !$contact_params->{'contacts_lastname'};
1077       $extra_sql .= " AND ( '1' $first_query $last_query )";
1078     }
1079
1080     if ($contact_params->{'contacts_email'}) {
1081       $addl_from .= ' LEFT JOIN contact_email ON ( cust_contact.contactnum = contact_email.contactnum ) ';
1082       $extra_sql .= " AND ( contact_email.emailaddress = '" . $contact_params->{'contacts_email'} . "' )";
1083     }
1084
1085     if ($contact_params->{'contacts_homephone'} || $contact_params->{'contacts_workphone'} || $contact_params->{'contacts_mobilephone'}) {
1086       $addl_from .= ' LEFT JOIN contact_phone ON ( cust_contact.contactnum = contact_phone.contactnum ) ';
1087       my $contacts_mobilephone;
1088       foreach my $phone (qw( contacts_homephone contacts_workphone contacts_mobilephone )) {
1089         (my $num = $contact_params->{$phone}) =~ s/\W//g;
1090         if ( $num =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { $contact_params->{$phone} = "$1$2$3"; }
1091       }
1092       my $home_query = " AND ( contact_phone.phonetypenum = '2' AND contact_phone.phonenum = '" . $contact_params->{'contacts_homephone'} . "' )"
1093         unless !$contact_params->{'contacts_homephone'};
1094       my $work_query = " AND ( contact_phone.phonetypenum = '1' AND contact_phone.phonenum = '" . $contact_params->{'contacts_workphone'} . "' )"
1095         unless !$contact_params->{'contacts_workphone'};
1096       my $mobile_query = " AND ( contact_phone.phonetypenum = '3' AND contact_phone.phonenum = '" . $contact_params->{'contacts_mobilephone'} . "' )"
1097         unless !$contact_params->{'contacts_mobilephone'};
1098       $extra_sql .= " AND ( '1' $home_query $work_query $mobile_query )";
1099     }
1100
1101   }
1102
1103   if ($params->{'flattened_pkgs'}) {
1104
1105     #my $pkg_join = '';
1106     $addl_from .=
1107       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1108
1109     if ($dbh->{Driver}->{Name} eq 'Pg') {
1110
1111       push @select, "
1112         ARRAY_TO_STRING(
1113           ARRAY(
1114             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1115               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1116           ), '|'
1117         ) AS magic
1118       ";
1119
1120     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1121       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1122       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1123       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1124     } else {
1125       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1126            "omitting package information from report.";
1127     }
1128
1129     my $header_query = "
1130       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1131         FROM cust_main $addl_from $extra_sql $pkgwhere
1132           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1133     ";
1134
1135     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1136     $sth->execute() or die $sth->errstr;
1137     my $headerrow = $sth->fetchrow_arrayref;
1138     my $headercount = $headerrow ? $headerrow->[0] : 0;
1139     while($headercount) {
1140       unshift @extra_headers, "Package ". $headercount;
1141       unshift @extra_fields, eval q!sub {my $c = shift;
1142                                          my @a = split '\|', $c->magic;
1143                                          my $p = $a[!.--$headercount. q!];
1144                                          $p;
1145                                         };!;
1146       unshift @extra_sort_fields, '';
1147     }
1148
1149   }
1150
1151   if ( $params->{'with_referrals'} ) {
1152
1153     #XXX next: num for each customer status
1154
1155     push @select,
1156       '( SELECT COUNT(*) FROM cust_main AS referred_cust_main
1157            WHERE cust_main.custnum = referred_cust_main.referral_custnum
1158        ) AS num_referrals';
1159
1160     unshift @extra_headers, 'Referrals';
1161     unshift @extra_fields, 'num_referrals';
1162     unshift @extra_sort_fields, 'num_referrals';
1163
1164   }
1165
1166   my $select = join(', ', @select);
1167
1168   my $sql_query = {
1169     'table'             => 'cust_main',
1170     'select'            => $select,
1171     'addl_from'         => $addl_from,
1172     'hashref'           => {},
1173     'extra_sql'         => $extra_sql,
1174     'order_by'          => $orderby,
1175     'count_query'       => $count_query,
1176     'extra_headers'     => \@extra_headers,
1177     'extra_fields'      => \@extra_fields,
1178     'extra_sort_fields' => \@extra_sort_fields,
1179   };
1180   $sql_query;
1181
1182 }
1183
1184 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1185
1186 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1187 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1188 specified.
1189
1190 Additional options are the same as FS::Record::qsearch
1191
1192 =cut
1193
1194 sub fuzzy_search {
1195   my $self = shift;
1196   my $fuzzy = shift;
1197   # sensible defaults, then merge in any passed options
1198   my %fuzopts = (
1199     'table'     => 'cust_main',
1200     'addl_from' => '',
1201     'extra_sql' => '',
1202     'hashref'   => {},
1203     @_
1204   );
1205
1206   my @cust_main = ();
1207
1208   my @fuzzy_mod = 'i';
1209   my $conf = new FS::Conf;
1210   my $fuzziness = $conf->config('fuzzy-fuzziness');
1211   push @fuzzy_mod, $fuzziness if $fuzziness;
1212
1213   check_and_rebuild_fuzzyfiles();
1214   foreach my $field ( keys %$fuzzy ) {
1215
1216     my $all = $self->all_X($field);
1217     next unless scalar(@$all);
1218
1219     my %match = ();
1220     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1221     next if !keys(%match);
1222
1223     my $in_matches = 'IN (' .
1224                      join(',', map { dbh->quote($_) } keys %match) .
1225                      ')';
1226
1227     my $extra_sql = $fuzopts{extra_sql};
1228     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1229       $extra_sql .= ' AND ';
1230     } else {
1231       $extra_sql .= 'WHERE ';
1232     }
1233     $extra_sql .= "$field $in_matches";
1234
1235     my $addl_from = $fuzopts{addl_from};
1236     if ( $field =~ /^cust_location\./ ) {
1237       $addl_from .= ' JOIN cust_location USING (custnum)';
1238     } elsif ( $field =~ /^contact\./ ) {
1239       $addl_from .= ' JOIN contact USING (custnum)';
1240     }
1241
1242     push @cust_main, qsearch({
1243       %fuzopts,
1244       'addl_from' => $addl_from,
1245       'extra_sql' => $extra_sql,
1246     });
1247   }
1248
1249   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1250   my %saw = ();
1251   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1252
1253   @cust_main;
1254
1255 }
1256
1257 =back
1258
1259 =head1 UTILITY SUBROUTINES
1260
1261 =over 4
1262
1263 =item check_and_rebuild_fuzzyfiles
1264
1265 =cut
1266
1267 sub check_and_rebuild_fuzzyfiles {
1268   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1269   rebuild_fuzzyfiles()
1270     if grep { ! -e "$dir/$_" }
1271          map {
1272                my ($field, $table) = reverse split('\.', $_);
1273                $table ||= 'cust_main';
1274                "$table.$field"
1275              }
1276            @fuzzyfields;
1277 }
1278
1279 =item rebuild_fuzzyfiles
1280
1281 =cut
1282
1283 sub rebuild_fuzzyfiles {
1284
1285   use Fcntl qw(:flock);
1286
1287   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1288   mkdir $dir, 0700 unless -d $dir;
1289
1290   foreach my $fuzzy ( @fuzzyfields ) {
1291
1292     my ($field, $table) = reverse split('\.', $fuzzy);
1293     $table ||= 'cust_main';
1294
1295     open(LOCK,">>$dir/$table.$field")
1296       or die "can't open $dir/$table.$field: $!";
1297     flock(LOCK,LOCK_EX)
1298       or die "can't lock $dir/$table.$field: $!";
1299
1300     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1301       or die "can't open $dir/$table.$field.tmp: $!";
1302
1303     my $sth = dbh->prepare(
1304       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1305     );
1306     $sth->execute or die $sth->errstr;
1307
1308     while ( my $row = $sth->fetchrow_arrayref ) {
1309       print CACHE $row->[0]. "\n";
1310     }
1311
1312     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1313
1314     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1315     close LOCK;
1316   }
1317
1318 }
1319
1320 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1321
1322 =cut
1323
1324 sub append_fuzzyfiles {
1325   #my( $first, $last, $company ) = @_;
1326
1327   check_and_rebuild_fuzzyfiles();
1328
1329   #foreach my $fuzzy (@fuzzyfields) {
1330   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1331                       'cust_location.address1',
1332                       'cust_main.ship_company',
1333                     ) {
1334
1335     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1336
1337   }
1338
1339   1;
1340 }
1341
1342 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1343
1344 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1345
1346 =cut
1347
1348 use Fcntl qw(:flock);
1349 sub append_fuzzyfiles_fuzzyfield {
1350   my( $fuzzyfield, $value ) = @_;
1351
1352   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1353
1354
1355   my ($field, $table) = reverse split('\.', $fuzzyfield);
1356   $table ||= 'cust_main';
1357
1358   return unless defined($value) && length($value);
1359
1360   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1361     or die "can't open $dir/$table.$field: $!";
1362   flock(CACHE,LOCK_EX)
1363     or die "can't lock $dir/$table.$field: $!";
1364
1365   print CACHE "$value\n";
1366
1367   flock(CACHE,LOCK_UN)
1368     or die "can't unlock $dir/$table.$field: $!";
1369   close CACHE;
1370
1371 }
1372
1373 =item all_X
1374
1375 =cut
1376
1377 sub all_X {
1378   my( $self, $fuzzy ) = @_;
1379   my ($field, $table) = reverse split('\.', $fuzzy);
1380   $table ||= 'cust_main';
1381
1382   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1383   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1384     or die "can't open $dir/$table.$field: $!";
1385   my @array = map { chomp; $_; } <CACHE>;
1386   close CACHE;
1387   \@array;
1388 }
1389
1390 =head1 BUGS
1391
1392 Bed bugs
1393
1394 =head1 SEE ALSO
1395
1396 L<FS::cust_main>, L<FS::Record>
1397
1398 =cut
1399
1400 1;
1401