FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12 use FS::payinfo_Mixin;
  13
  14 @EXPORT_OK = qw( smart_search );
  15
  16 # 1 is mostly method/subroutine entry and options
  17 # 2 traces progress of some operations
  18 # 3 is even more information including possibly sensitive data
  19 $DEBUG = 0;
  20 $me = '[FS::cust_main::Search]';
  21
  22 @fuzzyfields = (
  23   'cust_main.first', 'cust_main.last', 'cust_main.company',
  24   'cust_main.ship_company', # if you're using it
  25   'cust_location.address1',
  26   'contact.first',   'contact.last',
  27 );
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Search - Customer searching
  37
  38 =head1 SYNOPSIS
  39
  40   use FS::cust_main::Search;
  41
  42   FS::cust_main::Search::smart_search(%options);
  43
  44   FS::cust_main::Search::email_search(%options);
  45
  46   FS::cust_main::Search->search( \%options );
  47
  48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  49
  50 =head1 SUBROUTINES
  51
  52 =over 4
  53
  54 =item smart_search OPTION => VALUE ...
  55
  56 Accepts the following options: I<search>, the string to search for.  The string
  57 will be searched for as a customer number, phone number, name or company name,
  58 address (if address1-search is on), invoicing email address, or credit card
  59 number.
  60
  61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  63 smart_search to
  64 skip fuzzy matching when an exact match is found.
  65
  66 Any additional options are treated as an additional qualifier on the search
  67 (i.e. I<agentnum>).
  68
  69 Returns a (possibly empty) array of FS::cust_main objects.
  70
  71 =cut
  72
  73 sub smart_search {
  74   my %options = @_;
  75
  76   #here is the agent virtualization
  77   my $agentnums_sql =
  78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  80
  81   my @cust_main = ();
  82
  83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  84   my $search = delete $options{'search'};
  85   ( my $alphanum_search = $search ) =~ s/\W//g;
  86
  87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  88
  89     #false laziness w/Record::ut_phone
  90     my $phonen = "$1-$2-$3";
  91     $phonen .= " x$4" if $4;
  92
  93     my $phonenum = "$1$2$3";
  94     #my $extension = $4;
  95
  96     #cust_main phone numbers
  97     push @cust_main, qsearch( {
  98       'table'   => 'cust_main',
  99       'hashref' => { %options },
 100       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 101                      ' ( '.
 102                          join(' OR ', map "$_ = '$phonen'",
 103                                           qw( daytime night mobile fax )
 104                              ).
 105                      ' ) '.
 106                      " AND $agentnums_sql", #agent virtualization
 107     } );
 108
 109     #contact phone numbers
 110     push @cust_main,
 111       grep $agentnums_href->{$_->agentnum}, #agent virt
 112         grep $_, #skip contacts that don't have cust_main records
 113           map $_->contact->cust_main,
 114             qsearch({
 115                       'table'   => 'contact_phone',
 116                       'hashref' => { 'phonenum' => $phonenum },
 117                    });
 118
 119     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 120       #try looking for matches with extensions unless one was specified
 121
 122       push @cust_main, qsearch( {
 123         'table'   => 'cust_main',
 124         'hashref' => { %options },
 125         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 126                        ' ( '.
 127                            join(' OR ', map "$_ LIKE '$phonen\%'",
 128                                             qw( daytime night )
 129                                ).
 130                        ' ) '.
 131                        " AND $agentnums_sql", #agent virtualization
 132       } );
 133
 134     }
 135
 136   }
 137
 138
 139   if ( $search =~ /@/ ) { #email address
 140
 141       # invoicing email address
 142       push @cust_main,
 143         grep $agentnums_href->{$_->agentnum}, #agent virt
 144           map $_->cust_main,
 145               qsearch( {
 146                          'table'     => 'cust_main_invoice',
 147                          'hashref'   => { 'dest' => $search },
 148                        }
 149                      );
 150
 151       # contact email address
 152       push @cust_main,
 153         grep $agentnums_href->{$_->agentnum}, #agent virt
 154           grep $_, #skip contacts that don't have cust_main records
 155             map $_->contact->cust_main,
 156               qsearch( {
 157                          'table'     => 'contact_email',
 158                          'hashref'   => { 'emailaddress' => $search },
 159                        }
 160                      );
 161
 162   # custnum search (also try agent_custid), with some tweaking options if your
 163   # legacy cust "numbers" have letters
 164   } elsif ( $search =~ /^\s*(\d+)\s*$/
 165          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 166               && $search =~ /^\s*(\w\w?\d+)\s*$/
 167             )
 168          || ( $conf->config('cust_main-custnum-display_special')
 169            # it's not currently possible for special prefixes to contain
 170            # digits, so just strip off any alphabetic prefix and match
 171            # the rest to custnum
 172               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 173             )
 174          || ( $conf->exists('address1-search' )
 175               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 176             )
 177      )
 178   {
 179
 180     my $num = $1;
 181
 182     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 183       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 184                                 ? ' AND agent_custid IS NULL ' : '';
 185       push @cust_main, qsearch( {
 186         'table'     => 'cust_main',
 187         'hashref'   => { 'custnum' => $num, %options },
 188         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 189       } );
 190     }
 191
 192     # for all agents this user can see, if any of them have custnum prefixes
 193     # that match the search string, include customers that match the rest
 194     # of the custnum and belong to that agent
 195     foreach my $agentnum ( keys %$agentnums_href ) {
 196       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 197       next if !$p;
 198       if ( $p eq substr($num, 0, length($p)) ) {
 199         push @cust_main, qsearch( {
 200           'table'   => 'cust_main',
 201           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 202                          'agentnum' => $agentnum,
 203                           %options,
 204                        },
 205         } );
 206       }
 207     }
 208
 209     push @cust_main, qsearch( {
 210         'table'     => 'cust_main',
 211         'hashref'   => { 'agent_custid' => $num, %options },
 212         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 213     } );
 214
 215     if ( $conf->exists('address1-search') ) {
 216       my $len = length($num);
 217       $num = lc($num);
 218       # probably the Right Thing: return customers that have any associated
 219       # locations matching the string, not just bill/ship location
 220       push @cust_main, qsearch( {
 221         'table'     => 'cust_main',
 222         'addl_from' => ' JOIN cust_location USING (custnum) ',
 223         'hashref'   => { %options, },
 224         'extra_sql' =>
 225           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 226           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 227           " AND $agentnums_sql",
 228       } );
 229     }
 230
 231   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 232
 233     my($company, $last, $first) = ( $1, $2, $3 );
 234
 235     # "Company (Last, First)"
 236     #this is probably something a browser remembered,
 237     #so just do an exact search (but case-insensitive, so USPS standardization
 238     #doesn't throw a wrench in the works)
 239
 240     push @cust_main, qsearch( {
 241         'table'     => 'cust_main',
 242         'hashref'   => { %options },
 243         'extra_sql' =>
 244         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 245         join(' AND ',
 246           " LOWER(first)   = ". dbh->quote(lc($first)),
 247           " LOWER(last)    = ". dbh->quote(lc($last)),
 248           " LOWER(company) = ". dbh->quote(lc($company)),
 249           $agentnums_sql,
 250         ),
 251       } ),
 252
 253     #contacts?
 254     # probably not necessary for the "something a browser remembered" case
 255
 256   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 257                                               # try {first,last,company}
 258
 259     my $value = lc($1);
 260
 261     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 262     # # full strings the browser remembers won't work
 263     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 264
 265     use Lingua::EN::NameParse;
 266     my $NameParse = new Lingua::EN::NameParse(
 267              auto_clean     => 1,
 268              allow_reversed => 1,
 269     );
 270
 271     my($last, $first) = ( '', '' );
 272     #maybe disable this too and just rely on NameParse?
 273     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 274
 275       ($last, $first) = ( $1, $2 );
 276
 277     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 278     } elsif ( ! $NameParse->parse($value) ) {
 279
 280       my %name = $NameParse->components;
 281       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 282       $last  = $name{'surname_1'};
 283
 284     }
 285
 286     if ( $first && $last ) {
 287
 288       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 289
 290       #exact
 291       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 292       $sql .= "( LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first )";
 293
 294       #cust_main
 295       push @cust_main, qsearch( {
 296         'table'     => 'cust_main',
 297         'hashref'   => \%options,
 298         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 299       } );
 300
 301       #contacts
 302       push @cust_main,
 303         grep $agentnums_href->{$_->agentnum}, #agent virt
 304           grep $_, #skip contacts that don't have cust_main records
 305             map $_->cust_main,
 306               qsearch( {
 307                          'table'     => 'contact',
 308                          'hashref'   => { 'first' => $first,
 309                                           'last'  => $last,
 310                                         },
 311                        }
 312                      );
 313
 314       # or it just be something that was typed in... (try that in a sec)
 315
 316     }
 317
 318     my $q_value = dbh->quote($value);
 319
 320     #exact
 321     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 322     $sql .= " (    LOWER(cust_main.first)         = $q_value
 323                 OR LOWER(cust_main.last)          = $q_value
 324                 OR LOWER(cust_main.company)       = $q_value
 325                 OR LOWER(cust_main.ship_company)  = $q_value
 326             ";
 327
 328     #address1 (yes, it's a kludge)
 329     $sql .= "   OR EXISTS (
 330                             SELECT 1 FROM cust_location
 331                               WHERE LOWER(cust_location.address1) = $q_value
 332                                 AND cust_location.custnum = cust_main.custnum
 333                           )"
 334       if $conf->exists('address1-search');
 335
 336     #contacts (look, another kludge)
 337     $sql .= "   OR EXISTS ( SELECT 1 FROM contact
 338                               WHERE (    LOWER(contact.first) = $q_value
 339                                       OR LOWER(contact.last)  = $q_value
 340                                     )
 341                                 AND contact.custnum IS NOT NULL
 342                                 AND contact.custnum = cust_main.custnum
 343                           )
 344               ) ";
 345
 346     push @cust_main, qsearch( {
 347       'table'     => 'cust_main',
 348       'hashref'   => \%options,
 349       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 350     } );
 351
 352     #no exact match, trying substring/fuzzy
 353     #always do substring & fuzzy (unless they're explicity config'ed off)
 354     #getting complaints searches are not returning enough
 355     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 356
 357       #still some false laziness w/search (was search/cust_main.cgi)
 358
 359       my $min_len =
 360         $FS::CurrentUser::CurrentUser->access_right('List all customers')
 361         ? 3 : 4;
 362
 363       #substring
 364
 365       my @company_hashrefs = ();
 366       if ( length($value) >= $min_len ) {
 367         @company_hashrefs = (
 368           { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 369           { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 370         );
 371       }
 372
 373       my @hashrefs = ();
 374       if ( $first && $last ) {
 375
 376         @hashrefs = (
 377           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 378             'last'         => { op=>'ILIKE', value=>"%$last%" },
 379           },
 380         );
 381
 382       } elsif ( length($value) >= $min_len ) {
 383
 384         @hashrefs = (
 385           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 386           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 387         );
 388
 389       }
 390
 391       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 392
 393         push @cust_main, qsearch( {
 394           'table'     => 'cust_main',
 395           'hashref'   => { %$hashref,
 396                            %options,
 397                          },
 398           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 399         } );
 400
 401       }
 402
 403       if ( $conf->exists('address1-search') && length($value) >= $min_len ) {
 404
 405         push @cust_main, qsearch( {
 406           table     => 'cust_main',
 407           addl_from => 'JOIN cust_location USING (custnum)',
 408           extra_sql => 'WHERE '.
 409                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 410                         " AND $agentnums_sql", #agent virtualizaiton
 411         } );
 412
 413       }
 414
 415       #contact substring
 416
 417       foreach my $hashref ( @hashrefs ) {
 418
 419         push @cust_main,
 420           grep $agentnums_href->{$_->agentnum}, #agent virt
 421             grep $_, #skip contacts that don't have cust_main records
 422               map $_->cust_main,
 423                 qsearch({
 424                           'table'     => 'contact',
 425                           'hashref'   => { %$hashref,
 426                                            #%options,
 427                                          },
 428                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 429                        });
 430
 431       }
 432
 433       #fuzzy
 434       my %fuzopts = (
 435         'hashref'   => \%options,
 436         'select'    => '',
 437         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 438       );
 439
 440       if ( $first && $last ) {
 441         push @cust_main, FS::cust_main::Search->fuzzy_search(
 442           { 'last'   => $last,    #fuzzy hashref
 443             'first'  => $first }, #
 444           %fuzopts
 445         );
 446         push @cust_main, FS::cust_main::Search->fuzzy_search(
 447           { 'contact.last'   => $last,    #fuzzy hashref
 448             'contact.first'  => $first }, #
 449           %fuzopts
 450         );
 451       }
 452
 453       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 454         push @cust_main, FS::cust_main::Search->fuzzy_search(
 455           { $field => $value },
 456           %fuzopts
 457         );
 458       }
 459       foreach my $field ( 'first', 'last' ) {
 460         push @cust_main, FS::cust_main::Search->fuzzy_search(
 461           { "contact.$field" => $value },
 462           %fuzopts
 463         );
 464       }
 465       if ( $conf->exists('address1-search') ) {
 466         push @cust_main,
 467           FS::cust_main::Search->fuzzy_search(
 468             { 'cust_location.address1' => $value },
 469             %fuzopts
 470         );
 471       }
 472
 473     }
 474
 475   }
 476
 477   ( my $nospace_search = $search ) =~ s/\s//g;
 478   ( my $card_search = $nospace_search ) =~ s/\-//g;
 479   $card_search =~ s/[x\*\.\_]/x/gi;
 480
 481   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 482
 483     ( my $like_search = $card_search ) =~ s/x/_/g;
 484     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 485
 486     push @cust_main, qsearch({
 487       'table'     => 'cust_main',
 488       'hashref'   => {},
 489       'extra_sql' => " WHERE (    payinfo LIKE '$like_search'
 490                                OR paymask =    '$mask_search'
 491                              ) ".
 492                      " AND payby IN ('CARD','DCRD') ".
 493                      " AND $agentnums_sql", #agent virtulization
 494     });
 495
 496   }
 497
 498
 499   #eliminate duplicates
 500   my %saw = ();
 501   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 502
 503   @cust_main;
 504
 505 }
 506
 507 =item email_search
 508
 509 Accepts the following options: I<email>, the email address to search for.  The
 510 email address will be searched for as an email invoice destination and as an
 511 svc_acct account.
 512
 513 #Any additional options are treated as an additional qualifier on the search
 514 #(i.e. I<agentnum>).
 515
 516 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 517 none or one).
 518
 519 =cut
 520
 521 sub email_search {
 522   my %options = @_;
 523
 524   my $email = delete $options{'email'};
 525
 526   #no agent virtualization yet
 527   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 528
 529   my @cust_main = ();
 530
 531   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 532
 533     my ( $user, $domain ) = ( $1, $2 );
 534
 535     warn "$me smart_search: searching for $user in domain $domain"
 536       if $DEBUG;
 537
 538     push @cust_main,
 539       map $_->cust_main,
 540           qsearch( {
 541                      'table'     => 'cust_main_invoice',
 542                      'hashref'   => { 'dest' => $email },
 543                    }
 544                  );
 545
 546     push @cust_main,
 547       map  $_->cust_main,
 548       grep $_,
 549       map  $_->cust_svc->cust_pkg,
 550           qsearch( {
 551                      'table'     => 'svc_acct',
 552                      'hashref'   => { 'username' => $user, },
 553                      'extra_sql' =>
 554                        'AND ( SELECT domain FROM svc_domain
 555                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 556                             ) = '. dbh->quote($domain),
 557                    }
 558                  );
 559   }
 560
 561   my %saw = ();
 562   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 563
 564   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 565     if $DEBUG;
 566
 567   @cust_main;
 568
 569 }
 570
 571 =back
 572
 573 =head1 CLASS METHODS
 574
 575 =over 4
 576
 577 =item search HASHREF
 578
 579 (Class method)
 580
 581 Returns a qsearch hash expression to search for parameters specified in
 582 HASHREF.  Valid parameters are
 583
 584 =over 4
 585
 586 =item agentnum
 587
 588 =item status
 589
 590 =item address
 591
 592 =item zip
 593
 594 =item refnum
 595
 596 =item cancelled_pkgs
 597
 598 bool
 599
 600 =item signupdate
 601
 602 listref of start date, end date
 603
 604 =item birthdate
 605
 606 listref of start date, end date
 607
 608 =item spouse_birthdate
 609
 610 listref of start date, end date
 611
 612 =item anniversary_date
 613
 614 listref of start date, end date
 615
 616 =item payby
 617
 618 listref
 619
 620 =item paydate_year
 621
 622 =item paydate_month
 623
 624 =item current_balance
 625
 626 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 627
 628 =item cust_fields
 629
 630 =item flattened_pkgs
 631
 632 bool
 633
 634 =back
 635
 636 =cut
 637
 638 sub search {
 639   my ($class, $params) = @_;
 640
 641   my $dbh = dbh;
 642
 643   my @where = ();
 644   my $orderby;
 645
 646   # initialize these to prevent warnings
 647   $params = {
 648     'custnum'       => '',
 649     'agentnum'      => '',
 650     'usernum'       => '',
 651     'status'        => '',
 652     'address'       => '',
 653     'zip'           => '',
 654     'paydate_year'  => '',
 655     'invoice_terms' => '',
 656     'custbatch'     => '',
 657     %$params
 658   };
 659
 660   ##
 661   # explicit custnum(s)
 662   ##
 663
 664   if ( $params->{'custnum'} ) {
 665     my @custnums = ref($params->{'custnum'}) ?
 666                       @{ $params->{'custnum'} } :
 667                       $params->{'custnum'};
 668     push @where,
 669       'cust_main.custnum IN (' .
 670       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 671       ')' if scalar(@custnums) > 0;
 672   }
 673
 674   ##
 675   # parse agent
 676   ##
 677
 678   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 679     push @where,
 680       "cust_main.agentnum = $1";
 681   }
 682
 683   ##
 684   # parse sales person
 685   ##
 686
 687   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 688     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 689                            : 'cust_main.salesnum IS NULL';
 690   }
 691
 692   ##
 693   # parse usernum
 694   ##
 695
 696   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 697     push @where,
 698       "cust_main.usernum = $1";
 699   }
 700
 701   ##
 702   # parse status
 703   ##
 704
 705   #prospect ordered active inactive suspended cancelled
 706   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 707     my $method = $params->{'status'}. '_sql';
 708     #push @where, $class->$method();
 709     push @where, FS::cust_main->$method();
 710   }
 711
 712   my $current = '';
 713   unless ( $params->{location_history} ) {
 714     $current = '
 715       AND (    cust_location.locationnum IN ( cust_main.bill_locationnum,
 716                                               cust_main.ship_locationnum
 717                                             )
 718             OR cust_location.locationnum IN (
 719                  SELECT locationnum FROM cust_pkg
 720                   WHERE cust_pkg.custnum = cust_main.custnum
 721                     AND locationnum IS NOT NULL
 722                     AND '. FS::cust_pkg->ncancelled_recurring_sql.'
 723                )
 724           )';
 725   }
 726
 727   ##
 728   # address
 729   ##
 730   if ( $params->{'address'} ) {
 731     # allow this to be an arrayref
 732     my @values = ($params->{'address'});
 733     @values = @{$values[0]} if ref($values[0]);
 734     my @orwhere;
 735     foreach (grep /\S/, @values) {
 736       my $address = dbh->quote('%'. lc($_). '%');
 737       push @orwhere,
 738         "LOWER(cust_location.address1) LIKE $address",
 739         "LOWER(cust_location.address2) LIKE $address";
 740     }
 741     if (@orwhere) {
 742       push @where, "EXISTS(
 743         SELECT 1 FROM cust_location
 744         WHERE cust_location.custnum = cust_main.custnum
 745           AND (".join(' OR ',@orwhere).")
 746           $current
 747         )";
 748     }
 749   }
 750
 751   ##
 752   # city
 753   ##
 754   if ( $params->{'city'} =~ /\S/ ) {
 755     my $city = dbh->quote($params->{'city'});
 756     push @where, "EXISTS(
 757       SELECT 1 FROM cust_location
 758       WHERE cust_location.custnum = cust_main.custnum
 759         AND cust_location.city = $city
 760         $current
 761     )";
 762   }
 763
 764   ##
 765   # county
 766   ##
 767   if ( $params->{'county'} =~ /\S/ ) {
 768     my $county = dbh->quote($params->{'county'});
 769     push @where, "EXISTS(
 770       SELECT 1 FROM cust_location
 771       WHERE cust_location.custnum = cust_main.custnum
 772         AND cust_location.county = $county
 773         $current
 774     )";
 775   }
 776
 777   ##
 778   # state
 779   ##
 780   if ( $params->{'state'} =~ /\S/ ) {
 781     my $state = dbh->quote($params->{'state'});
 782     push @where, "EXISTS(
 783       SELECT 1 FROM cust_location
 784       WHERE cust_location.custnum = cust_main.custnum
 785         AND cust_location.state = $state
 786         $current
 787     )";
 788   }
 789
 790   ##
 791   # zipcode
 792   ##
 793   if ( $params->{'zip'} =~ /\S/ ) {
 794     my $zip = dbh->quote($params->{'zip'} . '%');
 795     push @where, "EXISTS(
 796       SELECT 1 FROM cust_location
 797       WHERE cust_location.custnum = cust_main.custnum
 798         AND cust_location.zip LIKE $zip
 799         $current
 800     )";
 801   }
 802
 803   ##
 804   # country
 805   ##
 806   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 807     my $country = uc($1);
 808     push @where, "EXISTS(
 809       SELECT 1 FROM cust_location
 810       WHERE cust_location.custnum = cust_main.custnum
 811         AND cust_location.country = '$country'
 812         $current
 813     )";
 814   }
 815
 816   ###
 817   # refnum
 818   ###
 819   if ( $params->{'refnum'}  ) {
 820
 821     my @refnum = ref( $params->{'refnum'} )
 822                    ? @{ $params->{'refnum'} }
 823                    :  ( $params->{'refnum'} );
 824
 825     @refnum = grep /^(\d*)$/, @refnum;
 826
 827     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 828       if @refnum;
 829
 830   }
 831
 832   ##
 833   # parse cancelled package checkbox
 834   ##
 835
 836   my $pkgwhere = "";
 837
 838   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 839     unless $params->{'cancelled_pkgs'};
 840
 841   ##
 842   # "with email address(es)" checkbox
 843   ##
 844
 845   push @where,
 846     'EXISTS ( SELECT 1 FROM cust_main_invoice
 847                 WHERE cust_main_invoice.custnum = cust_main.custnum
 848                   AND length(dest) > 5
 849             )'  # AND dest LIKE '%@%'
 850     if $params->{'with_email'};
 851
 852   ##
 853   # "with postal mail invoices" checkbox
 854   ##
 855
 856   push @where,
 857     "EXISTS ( SELECT 1 FROM cust_main_invoice
 858                 WHERE cust_main_invoice.custnum = cust_main.custnum
 859                   AND dest = 'POST' )"
 860     if $params->{'POST'};
 861
 862   ##
 863   # "without postal mail invoices" checkbox
 864   ##
 865
 866   push @where,
 867     "NOT EXISTS ( SELECT 1 FROM cust_main_invoice
 868                     WHERE cust_main_invoice.custnum = cust_main.custnum
 869                       AND dest = 'POST' )"
 870     if $params->{'no_POST'};
 871
 872   ##
 873   # "tax exempt" checkbox
 874   ##
 875   push @where, "cust_main.tax = 'Y'"
 876     if $params->{'tax'};
 877
 878   ##
 879   # "not tax exempt" checkbox
 880   ##
 881   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 882     if $params->{'no_tax'};
 883
 884   ##
 885   # with referrals
 886   ##
 887   if ( $params->{'with_referrals'} =~ /^\s*(\d+)\s*$/ ) {
 888     push @where,
 889       " $1 <= ( SELECT COUNT(*) FROM cust_main AS referred_cust_main
 890                   WHERE cust_main.custnum = referred_cust_main.referral_custnum )";
 891   }
 892
 893   ##
 894   # dates
 895   ##
 896
 897   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 898
 899     next unless exists($params->{$field});
 900
 901     my($beginning, $ending, $hour) = @{$params->{$field}};
 902
 903     push @where,
 904       "cust_main.$field IS NOT NULL",
 905       "cust_main.$field >= $beginning",
 906       "cust_main.$field <= $ending";
 907
 908     if($field eq 'signupdate' && defined $hour) {
 909       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 910         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 911       }
 912       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 913         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 914       }
 915       else {
 916         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 917       }
 918     }
 919
 920     $orderby ||= "ORDER BY cust_main.$field";
 921
 922   }
 923
 924   ###
 925   # classnum
 926   ###
 927
 928   if ( $params->{'classnum'} ) {
 929
 930     my @classnum = ref( $params->{'classnum'} )
 931                      ? @{ $params->{'classnum'} }
 932                      :  ( $params->{'classnum'} );
 933
 934     @classnum = grep /^(\d*)$/, @classnum;
 935
 936     if ( @classnum ) {
 937       push @where, '( '. join(' OR ', map {
 938                                             $_ ? "cust_main.classnum = $_"
 939                                                : "cust_main.classnum IS NULL"
 940                                           }
 941                                           @classnum
 942                              ).
 943                    ' )';
 944     }
 945
 946   }
 947
 948   ###
 949   # payby
 950   ###
 951
 952   if ( $params->{'payby'} ) {
 953
 954     my @payby = ref( $params->{'payby'} )
 955                   ? @{ $params->{'payby'} }
 956                   :  ( $params->{'payby'} );
 957
 958     @payby = grep /^([A-Z]{4})$/, @payby;
 959
 960     push @where, '( '. join(' OR ', map "cust_main.payby = '$_'", @payby). ' )'
 961       if @payby;
 962
 963   }
 964
 965   ###
 966   # paydate_year / paydate_month
 967   ###
 968
 969   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
 970     my $year = $1;
 971     $params->{'paydate_month'} =~ /^(\d\d?)$/
 972       or die "paydate_year without paydate_month?";
 973     my $month = $1;
 974
 975     push @where,
 976       'paydate IS NOT NULL',
 977       "paydate != ''",
 978       "CAST(paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
 979 ;
 980   }
 981
 982   ###
 983   # invoice terms
 984   ###
 985
 986   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 987     my $terms = $1;
 988     if ( $1 eq 'NULL' ) {
 989       push @where,
 990         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 991     } else {
 992       push @where,
 993         "cust_main.invoice_terms IS NOT NULL",
 994         "cust_main.invoice_terms = '$1'";
 995     }
 996   }
 997
 998   ##
 999   # amounts
1000   ##
1001
1002   if ( $params->{'current_balance'} ) {
1003
1004     #my $balance_sql = $class->balance_sql();
1005     my $balance_sql = FS::cust_main->balance_sql();
1006
1007     my @current_balance =
1008       ref( $params->{'current_balance'} )
1009       ? @{ $params->{'current_balance'} }
1010       :  ( $params->{'current_balance'} );
1011
1012     push @where, map { s/current_balance/$balance_sql/; $_ }
1013                      @current_balance;
1014
1015   }
1016
1017   ##
1018   # custbatch
1019   ##
1020
1021   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
1022     push @where,
1023       "cust_main.custbatch = '$1'";
1024   }
1025
1026   if ( $params->{'tagnum'} ) {
1027     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
1028
1029     @tagnums = grep /^(\d+)$/, @tagnums;
1030
1031     if ( @tagnums ) {
1032       if ( $params->{'all_tags'} ) {
1033         foreach ( @tagnums ) {
1034           push @where, 'exists(select 1 from cust_tag where '.
1035                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
1036                        $_ . ')';
1037         }
1038       } else { # matching any tag, not all
1039         my $tags_where = "0 < (select count(1) from cust_tag where "
1040                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
1041                 . join(',', @tagnums) . "))";
1042
1043         push @where, $tags_where;
1044       }
1045     }
1046   }
1047
1048   # pkg_classnum
1049   #   all_pkg_classnums
1050   #   any_pkg_status
1051   if ( $params->{'pkg_classnum'} ) {
1052     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
1053                           @{ $params->{'pkg_classnum'} } :
1054                              $params->{'pkg_classnum'};
1055     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
1056
1057     if ( @pkg_classnums ) {
1058
1059       my @pkg_where;
1060       if ( $params->{'all_pkg_classnums'} ) {
1061         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
1062       } else {
1063         push @pkg_where,
1064           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
1065       }
1066       foreach (@pkg_where) {
1067         my $select_pkg =
1068           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
1069           "cust_pkg.custnum = cust_main.custnum AND $_ ";
1070         if ( not $params->{'any_pkg_status'} ) {
1071           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
1072         }
1073         push @where, "EXISTS($select_pkg)";
1074       }
1075     }
1076   }
1077
1078   ##
1079   # setup queries, subs, etc. for the search
1080   ##
1081
1082   $orderby ||= 'ORDER BY custnum';
1083
1084   # here is the agent virtualization
1085   push @where,
1086     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1087
1088   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1089
1090   my $addl_from = '';
1091   # always make address fields available in results
1092   for my $pre ('bill_', 'ship_') {
1093     $addl_from .=
1094       'LEFT JOIN cust_location AS '.$pre.'location '.
1095       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1096   }
1097
1098   # always make referral available in results
1099   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
1100   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
1101
1102   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1103
1104   my @select = (
1105                  'cust_main.custnum',
1106                  'cust_main.salesnum',
1107                  # there's a good chance that we'll need these
1108                  'cust_main.bill_locationnum',
1109                  'cust_main.ship_locationnum',
1110                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1111                );
1112
1113   my(@extra_headers) = ();
1114   my(@extra_fields)  = ();
1115
1116   if ($params->{'flattened_pkgs'}) {
1117
1118     #my $pkg_join = '';
1119     $addl_from .=
1120       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1121
1122     if ($dbh->{Driver}->{Name} eq 'Pg') {
1123
1124       push @select, "
1125         ARRAY_TO_STRING(
1126           ARRAY(
1127             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1128               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1129           ), '|'
1130         ) AS magic
1131       ";
1132
1133     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1134       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1135       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1136       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1137     } else {
1138       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1139            "omitting package information from report.";
1140     }
1141
1142     my $header_query = "
1143       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1144         FROM cust_main $addl_from $extra_sql $pkgwhere
1145           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1146     ";
1147
1148     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1149     $sth->execute() or die $sth->errstr;
1150     my $headerrow = $sth->fetchrow_arrayref;
1151     my $headercount = $headerrow ? $headerrow->[0] : 0;
1152     while($headercount) {
1153       unshift @extra_headers, "Package ". $headercount;
1154       unshift @extra_fields, eval q!sub {my $c = shift;
1155                                          my @a = split '\|', $c->magic;
1156                                          my $p = $a[!.--$headercount. q!];
1157                                          $p;
1158                                         };!;
1159     }
1160
1161   }
1162
1163   if ( $params->{'with_referrals'} ) {
1164
1165     #XXX next: num for each customer status
1166
1167     push @select,
1168       '( SELECT COUNT(*) FROM cust_main AS referred_cust_main
1169            WHERE cust_main.custnum = referred_cust_main.referral_custnum
1170        ) AS num_referrals';
1171
1172     unshift @extra_headers, 'Referrals';
1173     unshift @extra_fields, 'num_referrals';
1174
1175   }
1176
1177   my $select = join(', ', @select);
1178
1179   my $sql_query = {
1180     'table'         => 'cust_main',
1181     'select'        => $select,
1182     'addl_from'     => $addl_from,
1183     'hashref'       => {},
1184     'extra_sql'     => $extra_sql,
1185     'order_by'      => $orderby,
1186     'count_query'   => $count_query,
1187     'extra_headers' => \@extra_headers,
1188     'extra_fields'  => \@extra_fields,
1189   };
1190   #warn Data::Dumper::Dumper($sql_query);
1191   $sql_query;
1192
1193 }
1194
1195 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1196
1197 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1198 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1199 specified.
1200
1201 Additional options are the same as FS::Record::qsearch
1202
1203 =cut
1204
1205 sub fuzzy_search {
1206   my $self = shift;
1207   my $fuzzy = shift;
1208   # sensible defaults, then merge in any passed options
1209   my %fuzopts = (
1210     'table'     => 'cust_main',
1211     'addl_from' => '',
1212     'extra_sql' => '',
1213     'hashref'   => {},
1214     @_
1215   );
1216
1217   my @cust_main = ();
1218
1219   my @fuzzy_mod = 'i';
1220   my $conf = new FS::Conf;
1221   my $fuzziness = $conf->config('fuzzy-fuzziness');
1222   push @fuzzy_mod, $fuzziness if $fuzziness;
1223
1224   check_and_rebuild_fuzzyfiles();
1225   foreach my $field ( keys %$fuzzy ) {
1226
1227     my $all = $self->all_X($field);
1228     next unless scalar(@$all);
1229
1230     my %match = ();
1231     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1232     next if !keys(%match);
1233
1234     my $in_matches = 'IN (' .
1235                      join(',', map { dbh->quote($_) } keys %match) .
1236                      ')';
1237
1238     my $extra_sql = $fuzopts{extra_sql};
1239     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1240       $extra_sql .= ' AND ';
1241     } else {
1242       $extra_sql .= 'WHERE ';
1243     }
1244     $extra_sql .= "$field $in_matches";
1245
1246     my $addl_from = $fuzopts{addl_from};
1247     if ( $field =~ /^cust_location\./ ) {
1248       $addl_from .= ' JOIN cust_location USING (custnum)';
1249     } elsif ( $field =~ /^contact\./ ) {
1250       $addl_from .= ' JOIN contact USING (custnum)';
1251     }
1252
1253     push @cust_main, qsearch({
1254       %fuzopts,
1255       'addl_from' => $addl_from,
1256       'extra_sql' => $extra_sql,
1257     });
1258   }
1259
1260   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1261   my %saw = ();
1262   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1263
1264   @cust_main;
1265
1266 }
1267
1268 =back
1269
1270 =head1 UTILITY SUBROUTINES
1271
1272 =over 4
1273
1274 =item check_and_rebuild_fuzzyfiles
1275
1276 =cut
1277
1278 sub check_and_rebuild_fuzzyfiles {
1279   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1280   rebuild_fuzzyfiles()
1281     if grep { ! -e "$dir/$_" }
1282          map {
1283                my ($field, $table) = reverse split('\.', $_);
1284                $table ||= 'cust_main';
1285                "$table.$field"
1286              }
1287            @fuzzyfields;
1288 }
1289
1290 =item rebuild_fuzzyfiles
1291
1292 =cut
1293
1294 sub rebuild_fuzzyfiles {
1295
1296   use Fcntl qw(:flock);
1297
1298   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1299   mkdir $dir, 0700 unless -d $dir;
1300
1301   foreach my $fuzzy ( @fuzzyfields ) {
1302
1303     my ($field, $table) = reverse split('\.', $fuzzy);
1304     $table ||= 'cust_main';
1305
1306     open(LOCK,">>$dir/$table.$field")
1307       or die "can't open $dir/$table.$field: $!";
1308     flock(LOCK,LOCK_EX)
1309       or die "can't lock $dir/$table.$field: $!";
1310
1311     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1312       or die "can't open $dir/$table.$field.tmp: $!";
1313
1314     my $sth = dbh->prepare(
1315       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1316     );
1317     $sth->execute or die $sth->errstr;
1318
1319     while ( my $row = $sth->fetchrow_arrayref ) {
1320       print CACHE $row->[0]. "\n";
1321     }
1322
1323     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1324
1325     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1326     close LOCK;
1327   }
1328
1329 }
1330
1331 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1332
1333 =cut
1334
1335 sub append_fuzzyfiles {
1336   #my( $first, $last, $company ) = @_;
1337
1338   check_and_rebuild_fuzzyfiles();
1339
1340   #foreach my $fuzzy (@fuzzyfields) {
1341   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1342                       'cust_location.address1',
1343                       'cust_main.ship_company',
1344                     ) {
1345
1346     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1347
1348   }
1349
1350   1;
1351 }
1352
1353 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1354
1355 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1356
1357 =cut
1358
1359 use Fcntl qw(:flock);
1360 sub append_fuzzyfiles_fuzzyfield {
1361   my( $fuzzyfield, $value ) = @_;
1362
1363   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1364
1365
1366   my ($field, $table) = reverse split('\.', $fuzzyfield);
1367   $table ||= 'cust_main';
1368
1369   return unless length($value);
1370
1371   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1372     or die "can't open $dir/$table.$field: $!";
1373   flock(CACHE,LOCK_EX)
1374     or die "can't lock $dir/$table.$field: $!";
1375
1376   print CACHE "$value\n";
1377
1378   flock(CACHE,LOCK_UN)
1379     or die "can't unlock $dir/$table.$field: $!";
1380   close CACHE;
1381
1382 }
1383
1384 =item all_X
1385
1386 =cut
1387
1388 sub all_X {
1389   my( $self, $fuzzy ) = @_;
1390   my ($field, $table) = reverse split('\.', $fuzzy);
1391   $table ||= 'cust_main';
1392
1393   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1394   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1395     or die "can't open $dir/$table.$field: $!";
1396   my @array = map { chomp; $_; } <CACHE>;
1397   close CACHE;
1398   \@array;
1399 }
1400
1401 =head1 BUGS
1402
1403 Bed bugs
1404
1405 =head1 SEE ALSO
1406
1407 L<FS::cust_main>, L<FS::Record>
1408
1409 =cut
1410
1411 1;
1412