FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12 use FS::payinfo_Mixin;
  13
  14 @EXPORT_OK = qw( smart_search );
  15
  16 # 1 is mostly method/subroutine entry and options
  17 # 2 traces progress of some operations
  18 # 3 is even more information including possibly sensitive data
  19 $DEBUG = 0;
  20 $me = '[FS::cust_main::Search]';
  21
  22 @fuzzyfields = (
  23   'cust_main.first', 'cust_main.last', 'cust_main.company',
  24   'cust_main.ship_company', # if you're using it
  25   'cust_location.address1',
  26   'contact.first',   'contact.last',
  27 );
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Search - Customer searching
  37
  38 =head1 SYNOPSIS
  39
  40   use FS::cust_main::Search;
  41
  42   FS::cust_main::Search::smart_search(%options);
  43
  44   FS::cust_main::Search::email_search(%options);
  45
  46   FS::cust_main::Search->search( \%options );
  47
  48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  49
  50 =head1 SUBROUTINES
  51
  52 =over 4
  53
  54 =item smart_search OPTION => VALUE ...
  55
  56 Accepts the following options: I<search>, the string to search for.  The string
  57 will be searched for as a customer number, phone number, name or company name,
  58 address (if address1-search is on), invoicing email address, or credit card
  59 number.
  60
  61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  63 smart_search to
  64 skip fuzzy matching when an exact match is found.
  65
  66 Any additional options are treated as an additional qualifier on the search
  67 (i.e. I<agentnum>).
  68
  69 Returns a (possibly empty) array of FS::cust_main objects.
  70
  71 =cut
  72
  73 sub smart_search {
  74   my %options = @_;
  75
  76   #here is the agent virtualization
  77   my $agentnums_sql =
  78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  80
  81   my @cust_main = ();
  82
  83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  84   my $search = delete $options{'search'};
  85   ( my $alphanum_search = $search ) =~ s/\W//g;
  86
  87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  88
  89     #false laziness w/Record::ut_phone
  90     my $phonen = "$1-$2-$3";
  91     $phonen .= " x$4" if $4;
  92
  93     my $phonenum = "$1$2$3";
  94     #my $extension = $4;
  95
  96     #cust_main phone numbers and contact phone number
  97     push @cust_main, qsearch( {
  98       'select'    => 'cust_main.*',
  99       'table'     => 'cust_main',
 100       'addl_from' => ' left join cust_contact  using (custnum) '.
 101                      ' left join contact_phone using (contactnum) ',
 102       'hashref'   => { %options },
 103       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 104                      ' ( '.
 105                          join(' OR ', map "$_ = '$phonen'",
 106                                           qw( daytime night mobile fax )
 107                              ).
 108                           " OR phonenum = '$phonenum' ".
 109                      ' ) '.
 110                      " AND $agentnums_sql", #agent virtualization
 111     } );
 112
 113     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 114       #try looking for matches with extensions unless one was specified
 115
 116       push @cust_main, qsearch( {
 117         'table'     => 'cust_main',
 118         'hashref'   => { %options },
 119         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 120                        ' ( '.
 121                            join(' OR ', map "$_ LIKE '$phonen\%'",
 122                                             qw( daytime night )
 123                                ).
 124                        ' ) '.
 125                        " AND $agentnums_sql", #agent virtualization
 126       } );
 127
 128     }
 129
 130   }
 131
 132
 133   if ( $search =~ /@/ ) { #email address from cust_main_invoice and contact_email
 134
 135     push @cust_main, qsearch( {
 136       'select'    => 'cust_main.*',
 137       'table'     => 'cust_main',
 138       'addl_from' => ' left join cust_main_invoice using (custnum) '.
 139                      ' left join cust_contact      using (custnum) '.
 140                      ' left join contact_email     using (contactnum) ',
 141       'hashref'   => { %options },
 142       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 143                      ' ( '.
 144                          join(' OR ', map "$_ = '$search'",
 145                                           qw( dest emailaddress )
 146                              ).
 147                      ' ) '.
 148                      " AND $agentnums_sql", #agent virtualization
 149     } );
 150
 151   # custnum search (also try agent_custid), with some tweaking options if your
 152   # legacy cust "numbers" have letters
 153   } elsif (    $search =~ /^\s*(\d+)\s*$/
 154             or ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 155                  && $search =~ /^\s*(\w\w?\d+)\s*$/
 156                )
 157             or ( $conf->config('cust_main-agent_custid-format') eq 'd+-w'
 158                  && $search =~ /^\s*(\d+-\w)\s*$/
 159                )
 160             or ( $conf->config('cust_main-custnum-display_special')
 161                  # it's not currently possible for special prefixes to contain
 162                  # digits, so just strip off any alphabetic prefix and match
 163                  # the rest to custnum
 164                  && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 165                )
 166             or ( $conf->exists('address1-search' )
 167                  && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 168                )
 169           )
 170   {
 171
 172     my $num = $1;
 173
 174     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 175       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 176                                 ? ' AND agent_custid IS NULL ' : '';
 177       push @cust_main, qsearch( {
 178         'table'     => 'cust_main',
 179         'hashref'   => { 'custnum' => $num, %options },
 180         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 181       } );
 182     }
 183
 184     # for all agents this user can see, if any of them have custnum prefixes
 185     # that match the search string, include customers that match the rest
 186     # of the custnum and belong to that agent
 187     foreach my $agentnum ( keys %$agentnums_href ) {
 188       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 189       next if !$p;
 190       if ( $p eq substr($num, 0, length($p)) ) {
 191         push @cust_main, qsearch( {
 192           'table'   => 'cust_main',
 193           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 194                          'agentnum' => $agentnum,
 195                           %options,
 196                        },
 197         } );
 198       }
 199     }
 200
 201     push @cust_main, qsearch( {
 202         'table'     => 'cust_main',
 203         'hashref'   => { 'agent_custid' => $num, %options },
 204         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 205     } );
 206
 207     if ( $conf->exists('address1-search') ) {
 208       my $len = length($num);
 209       $num = lc($num);
 210       # probably the Right Thing: return customers that have any associated
 211       # locations matching the string, not just bill/ship location
 212       push @cust_main, qsearch( {
 213         'select'    => 'cust_main.*',
 214         'table'     => 'cust_main',
 215         'addl_from' => ' JOIN cust_location USING (custnum) ',
 216         'hashref'   => { %options, },
 217         'extra_sql' =>
 218           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 219           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 220           " AND $agentnums_sql",
 221       } );
 222     }
 223
 224   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 225
 226     my($company, $last, $first) = ( $1, $2, $3 );
 227
 228     # "Company (Last, First)"
 229     #this is probably something a browser remembered,
 230     #so just do an exact search (but case-insensitive, so USPS standardization
 231     #doesn't throw a wrench in the works)
 232
 233     push @cust_main, qsearch( {
 234       'table'     => 'cust_main',
 235       'hashref'   => { %options },
 236       'extra_sql' =>
 237         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 238         join(' AND ',
 239           " LOWER(first)   = ". dbh->quote(lc($first)),
 240           " LOWER(last)    = ". dbh->quote(lc($last)),
 241           " LOWER(company) = ". dbh->quote(lc($company)),
 242           $agentnums_sql,
 243         ),
 244     } );
 245
 246     #contacts?
 247     # probably not necessary for the "something a browser remembered" case
 248
 249   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 250                                               # try {first,last,company}
 251
 252     my $value = lc($1);
 253
 254     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 255     # # full strings the browser remembers won't work
 256     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 257
 258     use Lingua::EN::NameParse;
 259     my $NameParse = new Lingua::EN::NameParse(
 260              auto_clean     => 1,
 261              allow_reversed => 1,
 262     );
 263
 264     my($last, $first) = ( '', '' );
 265     #maybe disable this too and just rely on NameParse?
 266     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 267
 268       ($last, $first) = ( $1, $2 );
 269
 270     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 271     } elsif ( ! $NameParse->parse($value) ) {
 272
 273       my %name = $NameParse->components;
 274       $first = lc($name{'given_name_1'}) || $name{'initials_1'}; #wtf NameParse, Ed?
 275       $last  = lc($name{'surname_1'});
 276
 277     }
 278
 279     if ( $first && $last ) {
 280
 281       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 282
 283       #exact
 284       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 285       $sql .= "( (LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first)
 286                  OR (LOWER(contact.last) = $q_last AND LOWER(contact.first) = $q_first) )";
 287
 288       #cust_main and contacts
 289       push @cust_main, qsearch( {
 290         'select'    => 'cust_main.*',
 291         'table'     => 'cust_main',
 292         'addl_from' => ' left join cust_contact using (custnum) '.
 293                        ' left join contact using (contactnum) ',
 294         'hashref'   => { %options },
 295         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 296       } );
 297
 298       # or it just be something that was typed in... (try that in a sec)
 299
 300     }
 301
 302     my $q_value = dbh->quote($value);
 303
 304     #exact
 305     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 306     $sql .= " (    LOWER(cust_main.first)         = $q_value
 307                 OR LOWER(cust_main.last)          = $q_value
 308                 OR LOWER(cust_main.company)       = $q_value
 309                 OR LOWER(cust_main.ship_company)  = $q_value
 310                 OR LOWER(contact.first)           = $q_value
 311                 OR LOWER(contact.last)            = $q_value
 312             )";
 313
 314     #address1 (yes, it's a kludge)
 315     $sql .= "   OR EXISTS (
 316                             SELECT 1 FROM cust_location
 317                               WHERE LOWER(cust_location.address1) = $q_value
 318                                 AND cust_location.custnum = cust_main.custnum
 319                           )"
 320       if $conf->exists('address1-search');
 321
 322     push @cust_main, qsearch( {
 323       'select'    => 'cust_main.*',
 324       'table'     => 'cust_main',
 325       'addl_from' => ' left join cust_contact using (custnum) '.
 326                      ' left join contact using (contactnum) ',
 327       'hashref'   => { %options },
 328       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 329     } );
 330
 331     #no exact match, trying substring/fuzzy
 332     #always do substring & fuzzy (unless they're explicity config'ed off)
 333     #getting complaints searches are not returning enough
 334     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 335
 336       #still some false laziness w/search (was search/cust_main.cgi)
 337
 338       my $min_len =
 339         $FS::CurrentUser::CurrentUser->access_right('List all customers')
 340         ? 3 : 4;
 341
 342       #substring
 343
 344       my @company_hashrefs = ();
 345       if ( length($value) >= $min_len ) {
 346         @company_hashrefs = (
 347           { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 348           { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 349         );
 350       }
 351
 352       my @hashrefs = ();
 353       if ( $first && $last ) {
 354
 355         @hashrefs = (
 356           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 357             'last'         => { op=>'ILIKE', value=>"%$last%" },
 358           },
 359         );
 360
 361       } elsif ( length($value) >= $min_len ) {
 362
 363         @hashrefs = (
 364           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 365           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 366         );
 367
 368       }
 369
 370       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 371
 372         push @cust_main, qsearch( {
 373           'table'     => 'cust_main',
 374           'hashref'   => { %$hashref,
 375                            %options,
 376                          },
 377           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 378         } );
 379
 380       }
 381
 382       if ( $conf->exists('address1-search') && length($value) >= $min_len ) {
 383
 384         push @cust_main, qsearch( {
 385           select    => 'cust_main.*',
 386           table     => 'cust_main',
 387           addl_from => 'JOIN cust_location USING (custnum)',
 388           extra_sql => 'WHERE '.
 389                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 390                         " AND $agentnums_sql", #agent virtualizaiton
 391         } );
 392
 393       }
 394
 395       #contact substring
 396
 397       foreach my $hashref ( @hashrefs ) {
 398
 399         push @cust_main,
 400           grep $agentnums_href->{$_->agentnum}, #agent virt
 401             grep $_, #skip contacts that don't have cust_main records
 402               map $_->cust_main,
 403                 qsearch({
 404                           'table'     => 'contact',
 405                           'hashref'   => { %$hashref,
 406                                            #%options,
 407                                          },
 408                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 409                        });
 410
 411       }
 412
 413       #fuzzy
 414       my %fuzopts = (
 415         'hashref'   => \%options,
 416         'select'    => '',
 417         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 418       );
 419
 420       if ( $first && $last ) {
 421         push @cust_main, FS::cust_main::Search->fuzzy_search(
 422           { 'last'   => $last,    #fuzzy hashref
 423             'first'  => $first }, #
 424           %fuzopts
 425         );
 426         push @cust_main, FS::cust_main::Search->fuzzy_search(
 427           { 'contact.last'   => $last,    #fuzzy hashref
 428             'contact.first'  => $first }, #
 429           %fuzopts
 430         );
 431       }
 432
 433       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 434         push @cust_main, FS::cust_main::Search->fuzzy_search(
 435           { $field => $value },
 436           %fuzopts
 437         );
 438       }
 439       foreach my $field ( 'first', 'last' ) {
 440         push @cust_main, FS::cust_main::Search->fuzzy_search(
 441           { "contact.$field" => $value },
 442           %fuzopts
 443         );
 444       }
 445       if ( $conf->exists('address1-search') ) {
 446         push @cust_main,
 447           FS::cust_main::Search->fuzzy_search(
 448             { 'cust_location.address1' => $value },
 449             %fuzopts
 450         );
 451       }
 452
 453     }
 454
 455   }
 456
 457   ( my $nospace_search = $search ) =~ s/\s//g;
 458   ( my $card_search = $nospace_search ) =~ s/\-//g;
 459   $card_search =~ s/[x\*\.\_]/x/gi;
 460
 461   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 462
 463     ( my $like_search = $card_search ) =~ s/x/_/g;
 464     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 465
 466     push @cust_main, qsearch({
 467       'select'    => 'cust_main.*',
 468       'table'     => 'cust_main',
 469       'addl_from' => ' JOIN cust_payby USING (custnum)',
 470       'hashref'   => {},
 471       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
 472                                OR cust_payby.paymask =    '$mask_search'
 473                              ) ".
 474                      " AND cust_payby.payby IN ('CARD','DCRD') ".
 475                      " AND $agentnums_sql", #agent virtulization
 476     });
 477
 478   }
 479
 480
 481   #eliminate duplicates
 482   my %saw = ();
 483   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 484
 485   @cust_main;
 486
 487 }
 488
 489 =item email_search
 490
 491 Accepts the following options: I<email>, the email address to search for.  The
 492 email address will be searched for as an email invoice destination and as an
 493 svc_acct account.
 494
 495 #Any additional options are treated as an additional qualifier on the search
 496 #(i.e. I<agentnum>).
 497
 498 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 499 none or one).
 500
 501 =cut
 502
 503 sub email_search {
 504   my %options = @_;
 505
 506   my $email = delete $options{'email'};
 507
 508   #no agent virtualization yet
 509   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 510
 511   my @cust_main = ();
 512
 513   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 514
 515     my ( $user, $domain ) = ( $1, $2 );
 516
 517     warn "$me smart_search: searching for $user in domain $domain"
 518       if $DEBUG;
 519
 520     push @cust_main,
 521       map { $_->cust_main }
 522       map { $_->cust_contact }
 523       map { $_->contact }
 524           qsearch( {
 525                      'table'     => 'contact_email',
 526                      'hashref'   => { 'emailaddress' => $email },
 527                    }
 528                  );
 529
 530     push @cust_main,
 531       map  $_->cust_main,
 532       grep $_,
 533       map  $_->cust_svc->cust_pkg,
 534           qsearch( {
 535                      'table'     => 'svc_acct',
 536                      'hashref'   => { 'username' => $user, },
 537                      'extra_sql' =>
 538                        'AND ( SELECT domain FROM svc_domain
 539                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 540                             ) = '. dbh->quote($domain),
 541                    }
 542                  );
 543   }
 544
 545   my %saw = ();
 546   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 547
 548   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 549     if $DEBUG;
 550
 551   @cust_main;
 552
 553 }
 554
 555 =back
 556
 557 =head1 CLASS METHODS
 558
 559 =over 4
 560
 561 =item search HASHREF
 562
 563 (Class method)
 564
 565 Returns a qsearch hash expression to search for parameters specified in
 566 HASHREF.  Valid parameters are
 567
 568 =over 4
 569
 570 =item agentnum
 571
 572 =item status
 573
 574 =item address
 575
 576 =item zip
 577
 578 =item refnum
 579
 580 =item cancelled_pkgs
 581
 582 bool
 583
 584 =item signupdate
 585
 586 listref of start date, end date
 587
 588 =item birthdate
 589
 590 listref of start date, end date
 591
 592 =item spouse_birthdate
 593
 594 listref of start date, end date
 595
 596 =item anniversary_date
 597
 598 listref of start date, end date
 599
 600 =item current_balance
 601
 602 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 603
 604 =item cust_fields
 605
 606 =item flattened_pkgs
 607
 608 bool
 609
 610 =back
 611
 612 =cut
 613
 614 sub search {
 615   my ($class, $params) = @_;
 616
 617   my $dbh = dbh;
 618
 619   my @where = ();
 620   my $orderby;
 621
 622   # initialize these to prevent warnings
 623   $params = {
 624     'custnum'       => '',
 625     'agentnum'      => '',
 626     'usernum'       => '',
 627     'status'        => '',
 628     'address'       => '',
 629     'zip'           => '',
 630     'invoice_terms' => '',
 631     'custbatch'     => '',
 632     %$params
 633   };
 634
 635   ##
 636   # explicit custnum(s)
 637   ##
 638
 639   if ( $params->{'custnum'} ) {
 640     my @custnums = ref($params->{'custnum'}) ?
 641                       @{ $params->{'custnum'} } :
 642                       $params->{'custnum'};
 643     push @where,
 644       'cust_main.custnum IN (' .
 645       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 646       ')' if scalar(@custnums) > 0;
 647   }
 648
 649   ##
 650   # parse agent
 651   ##
 652
 653   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 654     push @where,
 655       "cust_main.agentnum = $1";
 656   }
 657
 658   ##
 659   # parse sales person
 660   ##
 661
 662   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 663     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 664                            : 'cust_main.salesnum IS NULL';
 665   }
 666
 667   ##
 668   # parse usernum
 669   ##
 670
 671   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 672     push @where,
 673       "cust_main.usernum = $1";
 674   }
 675
 676   ##
 677   # parse status
 678   ##
 679
 680   #prospect ordered active inactive suspended cancelled
 681   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 682     my $method = $params->{'status'}. '_sql';
 683     #push @where, $class->$method();
 684     push @where, FS::cust_main->$method();
 685   }
 686
 687   my $current = '';
 688   unless ( $params->{location_history} ) {
 689     $current = '
 690       AND (    cust_location.locationnum IN ( cust_main.bill_locationnum,
 691                                               cust_main.ship_locationnum
 692                                             )
 693             OR cust_location.locationnum IN (
 694                  SELECT locationnum FROM cust_pkg
 695                   WHERE cust_pkg.custnum = cust_main.custnum
 696                     AND locationnum IS NOT NULL
 697                     AND '. FS::cust_pkg->ncancelled_recurring_sql.'
 698                )
 699           )';
 700   }
 701
 702   ##
 703   # address
 704   ##
 705   if ( $params->{'address'} ) {
 706     # allow this to be an arrayref
 707     my @values = ($params->{'address'});
 708     @values = @{$values[0]} if ref($values[0]);
 709     my @orwhere;
 710     foreach (grep /\S/, @values) {
 711       my $address = dbh->quote('%'. lc($_). '%');
 712       push @orwhere,
 713         "LOWER(cust_location.address1) LIKE $address",
 714         "LOWER(cust_location.address2) LIKE $address";
 715     }
 716     if (@orwhere) {
 717       push @where, "EXISTS(
 718         SELECT 1 FROM cust_location
 719         WHERE cust_location.custnum = cust_main.custnum
 720           AND (".join(' OR ',@orwhere).")
 721           $current
 722         )";
 723     }
 724   }
 725
 726   ##
 727   # city
 728   ##
 729   if ( $params->{'city'} =~ /\S/ ) {
 730     my $city = dbh->quote($params->{'city'});
 731     push @where, "EXISTS(
 732       SELECT 1 FROM cust_location
 733       WHERE cust_location.custnum = cust_main.custnum
 734         AND cust_location.city = $city
 735         $current
 736     )";
 737   }
 738
 739   ##
 740   # county
 741   ##
 742   if ( $params->{'county'} =~ /\S/ ) {
 743     my $county = dbh->quote($params->{'county'});
 744     push @where, "EXISTS(
 745       SELECT 1 FROM cust_location
 746       WHERE cust_location.custnum = cust_main.custnum
 747         AND cust_location.county = $county
 748         $current
 749     )";
 750   }
 751
 752   ##
 753   # state
 754   ##
 755   if ( $params->{'state'} =~ /\S/ ) {
 756     my $state = dbh->quote($params->{'state'});
 757     push @where, "EXISTS(
 758       SELECT 1 FROM cust_location
 759       WHERE cust_location.custnum = cust_main.custnum
 760         AND cust_location.state = $state
 761         $current
 762     )";
 763   }
 764
 765   ##
 766   # zipcode
 767   ##
 768   if ( $params->{'zip'} =~ /\S/ ) {
 769     my $zip = dbh->quote($params->{'zip'} . '%');
 770     push @where, "EXISTS(
 771       SELECT 1 FROM cust_location
 772       WHERE cust_location.custnum = cust_main.custnum
 773         AND cust_location.zip LIKE $zip
 774         $current
 775     )";
 776   }
 777
 778   ##
 779   # country
 780   ##
 781   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 782     my $country = uc($1);
 783     push @where, "EXISTS(
 784       SELECT 1 FROM cust_location
 785       WHERE cust_location.custnum = cust_main.custnum
 786         AND cust_location.country = '$country'
 787         $current
 788     )";
 789   }
 790
 791   ###
 792   # refnum
 793   ###
 794   if ( $params->{'refnum'}  ) {
 795
 796     my @refnum = ref( $params->{'refnum'} )
 797                    ? @{ $params->{'refnum'} }
 798                    :  ( $params->{'refnum'} );
 799
 800     @refnum = grep /^(\d*)$/, @refnum;
 801
 802     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 803       if @refnum;
 804
 805   }
 806
 807   ##
 808   # parse cancelled package checkbox
 809   ##
 810
 811   my $pkgwhere = "";
 812
 813   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 814     unless $params->{'cancelled_pkgs'};
 815
 816   ##
 817   # "with email address(es)" checkbox
 818   ##
 819
 820   push @where,
 821     'EXISTS ( SELECT 1 FROM contact_email
 822                 JOIN cust_contact USING (contactnum)
 823                 WHERE cust_contact.custnum = cust_main.custnum
 824             )'
 825     if $params->{'with_email'};
 826
 827   ##
 828   # "with postal mail invoices" checkbox
 829   ##
 830
 831   push @where, "cust_main.postal_invoice = 'Y'"
 832     if $params->{'POST'};
 833
 834   ##
 835   # "without postal mail invoices" checkbox
 836   ##
 837
 838   push @where, "cust_main.postal_invoice IS NULL"
 839     if $params->{'no_POST'};
 840
 841   ##
 842   # "tax exempt" checkbox
 843   ##
 844   push @where, "cust_main.tax = 'Y'"
 845     if $params->{'tax'};
 846
 847   ##
 848   # "not tax exempt" checkbox
 849   ##
 850   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 851     if $params->{'no_tax'};
 852
 853   ##
 854   # with referrals
 855   ##
 856   if ( $params->{with_referrals} =~ /^\s*(\d+)\s*$/ ) {
 857
 858     my $n = $1;
 859
 860     # referral status
 861     my $and_status = '';
 862     if ( grep { $params->{referral_status} eq $_ } FS::cust_main->statuses() ) {
 863       my $method = $params->{referral_status}. '_sql';
 864       $and_status = ' AND '. FS::cust_main->$method();
 865       $and_status =~ s/ cust_main\./ referred_cust_main./g;
 866     }
 867
 868     push @where,
 869       " $n <= ( SELECT COUNT(*) FROM cust_main AS referred_cust_main
 870                   WHERE cust_main.custnum = referred_cust_main.referral_custnum
 871                     $and_status
 872               )";
 873
 874   }
 875
 876   ##
 877   # dates
 878   ##
 879
 880   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 881
 882     next unless exists($params->{$field});
 883
 884     my($beginning, $ending, $hour) = @{$params->{$field}};
 885
 886     push @where,
 887       "cust_main.$field IS NOT NULL",
 888       "cust_main.$field >= $beginning",
 889       "cust_main.$field <= $ending";
 890
 891     if($field eq 'signupdate' && defined $hour) {
 892       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 893         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 894       }
 895       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 896         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 897       }
 898       else {
 899         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 900       }
 901     }
 902
 903     $orderby ||= "ORDER BY cust_main.$field";
 904
 905   }
 906
 907   ###
 908   # classnum
 909   ###
 910
 911   if ( $params->{'classnum'} ) {
 912
 913     my @classnum = ref( $params->{'classnum'} )
 914                      ? @{ $params->{'classnum'} }
 915                      :  ( $params->{'classnum'} );
 916
 917     @classnum = grep /^(\d*)$/, @classnum;
 918
 919     if ( @classnum ) {
 920       push @where, '( '. join(' OR ', map {
 921                                             $_ ? "cust_main.classnum = $_"
 922                                                : "cust_main.classnum IS NULL"
 923                                           }
 924                                           @classnum
 925                              ).
 926                    ' )';
 927     }
 928
 929   }
 930
 931   ###
 932   # invoice terms
 933   ###
 934
 935   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 936     my $terms = $1;
 937     if ( $1 eq 'NULL' ) {
 938       push @where,
 939         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 940     } else {
 941       push @where,
 942         "cust_main.invoice_terms IS NOT NULL",
 943         "cust_main.invoice_terms = '$1'";
 944     }
 945   }
 946
 947   ##
 948   # amounts
 949   ##
 950
 951   if ( $params->{'current_balance'} ) {
 952
 953     #my $balance_sql = $class->balance_sql();
 954     my $balance_sql = FS::cust_main->balance_sql();
 955
 956     my @current_balance =
 957       ref( $params->{'current_balance'} )
 958       ? @{ $params->{'current_balance'} }
 959       :  ( $params->{'current_balance'} );
 960
 961     push @where, map { s/current_balance/$balance_sql/; $_ }
 962                      @current_balance;
 963
 964   }
 965
 966   ##
 967   # custbatch
 968   ##
 969
 970   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 971     push @where,
 972       "cust_main.custbatch = '$1'";
 973   }
 974
 975   if ( $params->{'tagnum'} ) {
 976     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 977
 978     @tagnums = grep /^(\d+)$/, @tagnums;
 979
 980     if ( @tagnums ) {
 981       if ( $params->{'all_tags'} ) {
 982         foreach ( @tagnums ) {
 983           push @where, 'exists(select 1 from cust_tag where '.
 984                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
 985                        $_ . ')';
 986         }
 987       } else { # matching any tag, not all
 988         my $tags_where = "0 < (select count(1) from cust_tag where "
 989                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 990                 . join(',', @tagnums) . "))";
 991
 992         push @where, $tags_where;
 993       }
 994     }
 995   }
 996
 997   # pkg_classnum
 998   #   all_pkg_classnums
 999   #   any_pkg_status
1000   if ( $params->{'pkg_classnum'} ) {
1001     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
1002                           @{ $params->{'pkg_classnum'} } :
1003                              $params->{'pkg_classnum'};
1004     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
1005
1006     if ( @pkg_classnums ) {
1007
1008       my @pkg_where;
1009       if ( $params->{'all_pkg_classnums'} ) {
1010         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
1011       } else {
1012         push @pkg_where,
1013           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
1014       }
1015       foreach (@pkg_where) {
1016         my $select_pkg =
1017           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
1018           "cust_pkg.custnum = cust_main.custnum AND $_ ";
1019         if ( not $params->{'any_pkg_status'} ) {
1020           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
1021         }
1022         push @where, "EXISTS($select_pkg)";
1023       }
1024     }
1025   }
1026
1027   ##
1028   # setup queries, subs, etc. for the search
1029   ##
1030
1031   $orderby ||= 'ORDER BY custnum';
1032
1033   # here is the agent virtualization
1034   push @where,
1035     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1036
1037   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1038
1039   my $addl_from = '';
1040   # always make address fields available in results
1041   for my $pre ('bill_', 'ship_') {
1042     $addl_from .=
1043       'LEFT JOIN cust_location AS '.$pre.'location '.
1044       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1045   }
1046
1047   # always make referral available in results
1048   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
1049   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
1050
1051   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1052
1053   my @select = (
1054                  'cust_main.custnum',
1055                  'cust_main.salesnum',
1056                  # there's a good chance that we'll need these
1057                  'cust_main.bill_locationnum',
1058                  'cust_main.ship_locationnum',
1059                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1060                );
1061
1062   my @extra_headers     = ();
1063   my @extra_fields      = ();
1064   my @extra_sort_fields = ();
1065
1066   ## search contacts
1067   if ($params->{'contacts'}) {
1068     my $contact_params = $params->{'contacts'};
1069
1070     $addl_from .=
1071       ' LEFT JOIN cust_contact ON ( cust_main.custnum = cust_contact.custnum ) ';
1072
1073     if ($contact_params->{'contacts_firstname'} || $contact_params->{'contacts_lastname'}) {
1074       $addl_from .= ' LEFT JOIN contact ON ( cust_contact.contactnum = contact.contactnum ) ';
1075       my $first_query = " AND contact.first = '" . $contact_params->{'contacts_firstname'} . "'"
1076         unless !$contact_params->{'contacts_firstname'};
1077       my $last_query = " AND contact.last = '" . $contact_params->{'contacts_lastname'} . "'"
1078         unless !$contact_params->{'contacts_lastname'};
1079       $extra_sql .= " AND ( '1' $first_query $last_query )";
1080     }
1081
1082     if ($contact_params->{'contacts_email'}) {
1083       $addl_from .= ' LEFT JOIN contact_email ON ( cust_contact.contactnum = contact_email.contactnum ) ';
1084       $extra_sql .= " AND ( contact_email.emailaddress = '" . $contact_params->{'contacts_email'} . "' )";
1085     }
1086
1087     if ($contact_params->{'contacts_homephone'} || $contact_params->{'contacts_workphone'} || $contact_params->{'contacts_mobilephone'}) {
1088       $addl_from .= ' LEFT JOIN contact_phone ON ( cust_contact.contactnum = contact_phone.contactnum ) ';
1089       my $contacts_mobilephone;
1090       foreach my $phone (qw( contacts_homephone contacts_workphone contacts_mobilephone )) {
1091         (my $num = $contact_params->{$phone}) =~ s/\W//g;
1092         if ( $num =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { $contact_params->{$phone} = "$1$2$3"; }
1093       }
1094       my $home_query = " AND ( contact_phone.phonetypenum = '2' AND contact_phone.phonenum = '" . $contact_params->{'contacts_homephone'} . "' )"
1095         unless !$contact_params->{'contacts_homephone'};
1096       my $work_query = " AND ( contact_phone.phonetypenum = '1' AND contact_phone.phonenum = '" . $contact_params->{'contacts_workphone'} . "' )"
1097         unless !$contact_params->{'contacts_workphone'};
1098       my $mobile_query = " AND ( contact_phone.phonetypenum = '3' AND contact_phone.phonenum = '" . $contact_params->{'contacts_mobilephone'} . "' )"
1099         unless !$contact_params->{'contacts_mobilephone'};
1100       $extra_sql .= " AND ( '1' $home_query $work_query $mobile_query )";
1101     }
1102
1103   }
1104
1105   if ($params->{'flattened_pkgs'}) {
1106
1107     #my $pkg_join = '';
1108     $addl_from .=
1109       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1110
1111     if ($dbh->{Driver}->{Name} eq 'Pg') {
1112
1113       push @select, "
1114         ARRAY_TO_STRING(
1115           ARRAY(
1116             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1117               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1118           ), '|'
1119         ) AS magic
1120       ";
1121
1122     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1123       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1124       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1125       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1126     } else {
1127       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1128            "omitting package information from report.";
1129     }
1130
1131     my $header_query = "
1132       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1133         FROM cust_main $addl_from $extra_sql $pkgwhere
1134           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1135     ";
1136
1137     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1138     $sth->execute() or die $sth->errstr;
1139     my $headerrow = $sth->fetchrow_arrayref;
1140     my $headercount = $headerrow ? $headerrow->[0] : 0;
1141     while($headercount) {
1142       unshift @extra_headers, "Package ". $headercount;
1143       unshift @extra_fields, eval q!sub {my $c = shift;
1144                                          my @a = split '\|', $c->magic;
1145                                          my $p = $a[!.--$headercount. q!];
1146                                          $p;
1147                                         };!;
1148       unshift @extra_sort_fields, '';
1149     }
1150
1151   }
1152
1153   if ( $params->{'with_referrals'} ) {
1154
1155     #XXX next: num for each customer status
1156
1157     push @select,
1158       '( SELECT COUNT(*) FROM cust_main AS referred_cust_main
1159            WHERE cust_main.custnum = referred_cust_main.referral_custnum
1160        ) AS num_referrals';
1161
1162     unshift @extra_headers, 'Referrals';
1163     unshift @extra_fields, 'num_referrals';
1164     unshift @extra_sort_fields, 'num_referrals';
1165
1166   }
1167
1168   my $select = join(', ', @select);
1169
1170   my $sql_query = {
1171     'table'             => 'cust_main',
1172     'select'            => $select,
1173     'addl_from'         => $addl_from,
1174     'hashref'           => {},
1175     'extra_sql'         => $extra_sql,
1176     'order_by'          => $orderby,
1177     'count_query'       => $count_query,
1178     'extra_headers'     => \@extra_headers,
1179     'extra_fields'      => \@extra_fields,
1180     'extra_sort_fields' => \@extra_sort_fields,
1181   };
1182   $sql_query;
1183
1184 }
1185
1186 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1187
1188 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1189 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1190 specified.
1191
1192 Additional options are the same as FS::Record::qsearch
1193
1194 =cut
1195
1196 sub fuzzy_search {
1197   my $self = shift;
1198   my $fuzzy = shift;
1199   # sensible defaults, then merge in any passed options
1200   my %fuzopts = (
1201     'table'     => 'cust_main',
1202     'addl_from' => '',
1203     'extra_sql' => '',
1204     'hashref'   => {},
1205     @_
1206   );
1207
1208   my @cust_main = ();
1209
1210   my @fuzzy_mod = 'i';
1211   my $conf = new FS::Conf;
1212   my $fuzziness = $conf->config('fuzzy-fuzziness');
1213   push @fuzzy_mod, $fuzziness if $fuzziness;
1214
1215   check_and_rebuild_fuzzyfiles();
1216   foreach my $field ( keys %$fuzzy ) {
1217
1218     my $all = $self->all_X($field);
1219     next unless scalar(@$all);
1220
1221     my %match = ();
1222     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1223     next if !keys(%match);
1224
1225     my $in_matches = 'IN (' .
1226                      join(',', map { dbh->quote($_) } keys %match) .
1227                      ')';
1228
1229     my $extra_sql = $fuzopts{extra_sql};
1230     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1231       $extra_sql .= ' AND ';
1232     } else {
1233       $extra_sql .= 'WHERE ';
1234     }
1235     $extra_sql .= "$field $in_matches";
1236
1237     my $addl_from = $fuzopts{addl_from};
1238     if ( $field =~ /^cust_location\./ ) {
1239       $addl_from .= ' JOIN cust_location USING (custnum)';
1240     } elsif ( $field =~ /^contact\./ ) {
1241       $addl_from .= ' JOIN contact USING (custnum)';
1242     }
1243
1244     push @cust_main, qsearch({
1245       %fuzopts,
1246       'addl_from' => $addl_from,
1247       'extra_sql' => $extra_sql,
1248     });
1249   }
1250
1251   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1252   my %saw = ();
1253   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1254
1255   @cust_main;
1256
1257 }
1258
1259 =back
1260
1261 =head1 UTILITY SUBROUTINES
1262
1263 =over 4
1264
1265 =item check_and_rebuild_fuzzyfiles
1266
1267 =cut
1268
1269 sub check_and_rebuild_fuzzyfiles {
1270   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1271   rebuild_fuzzyfiles()
1272     if grep { ! -e "$dir/$_" }
1273          map {
1274                my ($field, $table) = reverse split('\.', $_);
1275                $table ||= 'cust_main';
1276                "$table.$field"
1277              }
1278            @fuzzyfields;
1279 }
1280
1281 =item rebuild_fuzzyfiles
1282
1283 =cut
1284
1285 sub rebuild_fuzzyfiles {
1286
1287   use Fcntl qw(:flock);
1288
1289   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1290   mkdir $dir, 0700 unless -d $dir;
1291
1292   foreach my $fuzzy ( @fuzzyfields ) {
1293
1294     my ($field, $table) = reverse split('\.', $fuzzy);
1295     $table ||= 'cust_main';
1296
1297     open(LOCK,">>$dir/$table.$field")
1298       or die "can't open $dir/$table.$field: $!";
1299     flock(LOCK,LOCK_EX)
1300       or die "can't lock $dir/$table.$field: $!";
1301
1302     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1303       or die "can't open $dir/$table.$field.tmp: $!";
1304
1305     my $sth = dbh->prepare(
1306       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1307     );
1308     $sth->execute or die $sth->errstr;
1309
1310     while ( my $row = $sth->fetchrow_arrayref ) {
1311       print CACHE $row->[0]. "\n";
1312     }
1313
1314     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1315
1316     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1317     close LOCK;
1318   }
1319
1320 }
1321
1322 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1323
1324 =cut
1325
1326 sub append_fuzzyfiles {
1327   #my( $first, $last, $company ) = @_;
1328
1329   check_and_rebuild_fuzzyfiles();
1330
1331   #foreach my $fuzzy (@fuzzyfields) {
1332   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1333                       'cust_location.address1',
1334                       'cust_main.ship_company',
1335                     ) {
1336
1337     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1338
1339   }
1340
1341   1;
1342 }
1343
1344 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1345
1346 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1347
1348 =cut
1349
1350 use Fcntl qw(:flock);
1351 sub append_fuzzyfiles_fuzzyfield {
1352   my( $fuzzyfield, $value ) = @_;
1353
1354   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1355
1356
1357   my ($field, $table) = reverse split('\.', $fuzzyfield);
1358   $table ||= 'cust_main';
1359
1360   return unless defined($value) && length($value);
1361
1362   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1363     or die "can't open $dir/$table.$field: $!";
1364   flock(CACHE,LOCK_EX)
1365     or die "can't lock $dir/$table.$field: $!";
1366
1367   print CACHE "$value\n";
1368
1369   flock(CACHE,LOCK_UN)
1370     or die "can't unlock $dir/$table.$field: $!";
1371   close CACHE;
1372
1373 }
1374
1375 =item all_X
1376
1377 =cut
1378
1379 sub all_X {
1380   my( $self, $fuzzy ) = @_;
1381   my ($field, $table) = reverse split('\.', $fuzzy);
1382   $table ||= 'cust_main';
1383
1384   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1385   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1386     or die "can't open $dir/$table.$field: $!";
1387   my @array = map { chomp; $_; } <CACHE>;
1388   close CACHE;
1389   \@array;
1390 }
1391
1392 =head1 BUGS
1393
1394 Bed bugs
1395
1396 =head1 SEE ALSO
1397
1398 L<FS::cust_main>, L<FS::Record>
1399
1400 =cut
1401
1402 1;
1403