FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12
  13 @EXPORT_OK = qw( smart_search );
  14
  15 # 1 is mostly method/subroutine entry and options
  16 # 2 traces progress of some operations
  17 # 3 is even more information including possibly sensitive data
  18 $DEBUG = 0;
  19 $me = '[FS::cust_main::Search]';
  20
  21 @fuzzyfields = @FS::cust_main::fuzzyfields;
  22
  23 install_callback FS::UID sub {
  24   $conf = new FS::Conf;
  25   #yes, need it for stuff below (prolly should be cached)
  26 };
  27
  28 =head1 NAME
  29
  30 FS::cust_main::Search - Customer searching
  31
  32 =head1 SYNOPSIS
  33
  34   use FS::cust_main::Search;
  35
  36   FS::cust_main::Search::smart_search(%options);
  37
  38   FS::cust_main::Search::email_search(%options);
  39
  40   FS::cust_main::Search->search( \%options );
  41
  42   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  43
  44 =head1 SUBROUTINES
  45
  46 =over 4
  47
  48 =item smart_search OPTION => VALUE ...
  49
  50 Accepts the following options: I<search>, the string to search for.  The string
  51 will be searched for as a customer number, phone number, name or company name,
  52 as an exact, or, in some cases, a substring or fuzzy match (see the source code
  53 for the exact heuristics used); I<no_fuzzy_on_exact>, causes smart_search to
  54 skip fuzzy matching when an exact match is found.
  55
  56 Any additional options are treated as an additional qualifier on the search
  57 (i.e. I<agentnum>).
  58
  59 Returns a (possibly empty) array of FS::cust_main objects.
  60
  61 =cut
  62
  63 sub smart_search {
  64   my %options = @_;
  65
  66   #here is the agent virtualization
  67   my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
  68
  69   my @cust_main = ();
  70
  71   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  72   my $search = delete $options{'search'};
  73   ( my $alphanum_search = $search ) =~ s/\W//g;
  74
  75   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  76
  77     #false laziness w/Record::ut_phone
  78     my $phonen = "$1-$2-$3";
  79     $phonen .= " x$4" if $4;
  80
  81     push @cust_main, qsearch( {
  82       'table'   => 'cust_main',
  83       'hashref' => { %options },
  84       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
  85                      ' ( '.
  86                          join(' OR ', map "$_ = '$phonen'",
  87                                           qw( daytime night fax
  88                                               ship_daytime ship_night ship_fax )
  89                              ).
  90                      ' ) '.
  91                      " AND $agentnums_sql", #agent virtualization
  92     } );
  93
  94     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
  95       #try looking for matches with extensions unless one was specified
  96
  97       push @cust_main, qsearch( {
  98         'table'   => 'cust_main',
  99         'hashref' => { %options },
 100         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 101                        ' ( '.
 102                            join(' OR ', map "$_ LIKE '$phonen\%'",
 103                                             qw( daytime night
 104                                                 ship_daytime ship_night )
 105                                ).
 106                        ' ) '.
 107                        " AND $agentnums_sql", #agent virtualization
 108       } );
 109
 110     }
 111
 112   # custnum search (also try agent_custid), with some tweaking options if your
 113   # legacy cust "numbers" have letters
 114   }
 115
 116
 117   if ( $search =~ /@/ ) {
 118       push @cust_main,
 119           map $_->cust_main,
 120               qsearch( {
 121                          'table'     => 'cust_main_invoice',
 122                          'hashref'   => { 'dest' => $search },
 123                        }
 124                      );
 125   } elsif ( $search =~ /^\s*(\d+)\s*$/
 126          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 127               && $search =~ /^\s*(\w\w?\d+)\s*$/
 128             )
 129          || ( $conf->exists('address1-search' )
 130               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 131             )
 132      )
 133   {
 134
 135     my $num = $1;
 136
 137     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 138       push @cust_main, qsearch( {
 139         'table'     => 'cust_main',
 140         'hashref'   => { 'custnum' => $num, %options },
 141         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 142       } );
 143     }
 144
 145     push @cust_main, qsearch( {
 146       'table'     => 'cust_main',
 147       'hashref'   => { 'agent_custid' => $num, %options },
 148       'extra_sql' => " AND $agentnums_sql", #agent virtualization
 149     } );
 150
 151     if ( $conf->exists('address1-search') ) {
 152       my $len = length($num);
 153       $num = lc($num);
 154       foreach my $prefix ( '', 'ship_' ) {
 155         push @cust_main, qsearch( {
 156           'table'     => 'cust_main',
 157           'hashref'   => { %options, },
 158           'extra_sql' =>
 159             ( keys(%options) ? ' AND ' : ' WHERE ' ).
 160             " LOWER(SUBSTRING(${prefix}address1 FROM 1 FOR $len)) = '$num' ".
 161             " AND $agentnums_sql",
 162         } );
 163       }
 164     }
 165
 166   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 167
 168     my($company, $last, $first) = ( $1, $2, $3 );
 169
 170     # "Company (Last, First)"
 171     #this is probably something a browser remembered,
 172     #so just do an exact search (but case-insensitive, so USPS standardization
 173     #doesn't throw a wrench in the works)
 174
 175     foreach my $prefix ( '', 'ship_' ) {
 176       push @cust_main, qsearch( {
 177         'table'     => 'cust_main',
 178         'hashref'   => { %options },
 179         'extra_sql' =>
 180           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 181           join(' AND ',
 182             " LOWER(${prefix}first)   = ". dbh->quote(lc($first)),
 183             " LOWER(${prefix}last)    = ". dbh->quote(lc($last)),
 184             " LOWER(${prefix}company) = ". dbh->quote(lc($company)),
 185             $agentnums_sql,
 186           ),
 187       } );
 188     }
 189
 190   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 191                                               # try (ship_){last,company}
 192
 193     my $value = lc($1);
 194
 195     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 196     # # full strings the browser remembers won't work
 197     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 198
 199     use Lingua::EN::NameParse;
 200     my $NameParse = new Lingua::EN::NameParse(
 201              auto_clean     => 1,
 202              allow_reversed => 1,
 203     );
 204
 205     my($last, $first) = ( '', '' );
 206     #maybe disable this too and just rely on NameParse?
 207     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 208
 209       ($last, $first) = ( $1, $2 );
 210
 211     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 212     } elsif ( ! $NameParse->parse($value) ) {
 213
 214       my %name = $NameParse->components;
 215       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 216       $last  = $name{'surname_1'};
 217
 218     }
 219
 220     if ( $first && $last ) {
 221
 222       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 223
 224       #exact
 225       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 226       $sql .= "
 227         (     ( LOWER(last) = $q_last AND LOWER(first) = $q_first )
 228            OR ( LOWER(ship_last) = $q_last AND LOWER(ship_first) = $q_first )
 229         )";
 230
 231       push @cust_main, qsearch( {
 232         'table'     => 'cust_main',
 233         'hashref'   => \%options,
 234         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 235       } );
 236
 237       # or it just be something that was typed in... (try that in a sec)
 238
 239     }
 240
 241     my $q_value = dbh->quote($value);
 242
 243     #exact
 244     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 245     $sql .= " (    LOWER(last)          = $q_value
 246                 OR LOWER(company)       = $q_value
 247                 OR LOWER(ship_last)     = $q_value
 248                 OR LOWER(ship_company)  = $q_value
 249             ";
 250     $sql .= "   OR LOWER(address1)      = $q_value
 251                 OR LOWER(ship_address1) = $q_value
 252             "
 253       if $conf->exists('address1-search');
 254     $sql .= " )";
 255
 256     push @cust_main, qsearch( {
 257       'table'     => 'cust_main',
 258       'hashref'   => \%options,
 259       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 260     } );
 261
 262     #no exact match, trying substring/fuzzy
 263     #always do substring & fuzzy (unless they're explicity config'ed off)
 264     #getting complaints searches are not returning enough
 265     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 266
 267       #still some false laziness w/search (was search/cust_main.cgi)
 268
 269       #substring
 270
 271       my @hashrefs = (
 272         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 273         { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 274       );
 275
 276       if ( $first && $last ) {
 277
 278         push @hashrefs,
 279           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 280             'last'         => { op=>'ILIKE', value=>"%$last%" },
 281           },
 282           { 'ship_first'   => { op=>'ILIKE', value=>"%$first%" },
 283             'ship_last'    => { op=>'ILIKE', value=>"%$last%" },
 284           },
 285         ;
 286
 287       } else {
 288
 289         push @hashrefs,
 290           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 291           { 'ship_last'    => { op=>'ILIKE', value=>"%$value%" }, },
 292         ;
 293       }
 294
 295       if ( $conf->exists('address1-search') ) {
 296         push @hashrefs,
 297           { 'address1'      => { op=>'ILIKE', value=>"%$value%" }, },
 298           { 'ship_address1' => { op=>'ILIKE', value=>"%$value%" }, },
 299         ;
 300       }
 301
 302       foreach my $hashref ( @hashrefs ) {
 303
 304         push @cust_main, qsearch( {
 305           'table'     => 'cust_main',
 306           'hashref'   => { %$hashref,
 307                            %options,
 308                          },
 309           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 310         } );
 311
 312       }
 313
 314       #fuzzy
 315       my @fuzopts = (
 316         \%options,                #hashref
 317         '',                       #select
 318         " AND $agentnums_sql",    #extra_sql  #agent virtualization
 319       );
 320
 321       if ( $first && $last ) {
 322         push @cust_main, FS::cust_main::Search->fuzzy_search(
 323           { 'last'   => $last,    #fuzzy hashref
 324             'first'  => $first }, #
 325           @fuzopts
 326         );
 327       }
 328       foreach my $field ( 'last', 'company' ) {
 329         push @cust_main,
 330           FS::cust_main::Search->fuzzy_search( { $field => $value }, @fuzopts );
 331       }
 332       if ( $conf->exists('address1-search') ) {
 333         push @cust_main,
 334           FS::cust_main::Search->fuzzy_search( { 'address1' => $value }, @fuzopts );
 335       }
 336
 337     }
 338
 339   }
 340
 341   #eliminate duplicates
 342   my %saw = ();
 343   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 344
 345   @cust_main;
 346
 347 }
 348
 349 =item email_search
 350
 351 Accepts the following options: I<email>, the email address to search for.  The
 352 email address will be searched for as an email invoice destination and as an
 353 svc_acct account.
 354
 355 #Any additional options are treated as an additional qualifier on the search
 356 #(i.e. I<agentnum>).
 357
 358 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 359 none or one).
 360
 361 =cut
 362
 363 sub email_search {
 364   my %options = @_;
 365
 366   local($DEBUG) = 1;
 367
 368   my $email = delete $options{'email'};
 369
 370   #we're only being used by RT at the moment... no agent virtualization yet
 371   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 372
 373   my @cust_main = ();
 374
 375   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 376
 377     my ( $user, $domain ) = ( $1, $2 );
 378
 379     warn "$me smart_search: searching for $user in domain $domain"
 380       if $DEBUG;
 381
 382     push @cust_main,
 383       map $_->cust_main,
 384           qsearch( {
 385                      'table'     => 'cust_main_invoice',
 386                      'hashref'   => { 'dest' => $email },
 387                    }
 388                  );
 389
 390     push @cust_main,
 391       map  $_->cust_main,
 392       grep $_,
 393       map  $_->cust_svc->cust_pkg,
 394           qsearch( {
 395                      'table'     => 'svc_acct',
 396                      'hashref'   => { 'username' => $user, },
 397                      'extra_sql' =>
 398                        'AND ( SELECT domain FROM svc_domain
 399                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 400                             ) = '. dbh->quote($domain),
 401                    }
 402                  );
 403   }
 404
 405   my %saw = ();
 406   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 407
 408   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 409     if $DEBUG;
 410
 411   @cust_main;
 412
 413 }
 414
 415 =back
 416
 417 =head1 CLASS METHODS
 418
 419 =over 4
 420
 421 =item search HASHREF
 422
 423 (Class method)
 424
 425 Returns a qsearch hash expression to search for parameters specified in
 426 HASHREF.  Valid parameters are
 427
 428 =over 4
 429
 430 =item agentnum
 431
 432 =item status
 433
 434 =item address
 435
 436 =item cancelled_pkgs
 437
 438 bool
 439
 440 =item signupdate
 441
 442 listref of start date, end date
 443
 444 =item payby
 445
 446 listref
 447
 448 =item paydate_year
 449
 450 =item paydate_month
 451
 452 =item current_balance
 453
 454 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 455
 456 =item cust_fields
 457
 458 =item flattened_pkgs
 459
 460 bool
 461
 462 =back
 463
 464 =cut
 465
 466 sub search {
 467   my ($class, $params) = @_;
 468
 469   my $dbh = dbh;
 470
 471   my @where = ();
 472   my $orderby;
 473
 474   ##
 475   # parse agent
 476   ##
 477
 478   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 479     push @where,
 480       "cust_main.agentnum = $1";
 481   }
 482
 483   ##
 484   # do the same for user
 485   ##
 486
 487   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 488     push @where,
 489       "cust_main.usernum = $1";
 490   }
 491
 492   ##
 493   # parse status
 494   ##
 495
 496   #prospect ordered active inactive suspended cancelled
 497   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 498     my $method = $params->{'status'}. '_sql';
 499     #push @where, $class->$method();
 500     push @where, FS::cust_main->$method();
 501   }
 502
 503   ##
 504   # address
 505   ##
 506   if ( $params->{'address'} =~ /\S/ ) {
 507     my $address = dbh->quote('%'. lc($params->{'address'}). '%');
 508     push @where, '('. join(' OR ',
 509                              map "LOWER($_) LIKE $address",
 510                                qw(address1 address2 ship_address1 ship_address2)
 511                           ).
 512                  ')';
 513   }
 514
 515   ##
 516   # parse cancelled package checkbox
 517   ##
 518
 519   my $pkgwhere = "";
 520
 521   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 522     unless $params->{'cancelled_pkgs'};
 523
 524   ##
 525   # parse without census tract checkbox
 526   ##
 527
 528   push @where, "(censustract = '' or censustract is null)"
 529     if $params->{'no_censustract'};
 530
 531   ##
 532   # parse with hardcoded tax location checkbox
 533   ##
 534
 535   push @where, "geocode is not null"
 536     if $params->{'with_geocode'};
 537
 538   ##
 539   # dates
 540   ##
 541
 542   foreach my $field (qw( signupdate )) {
 543
 544     next unless exists($params->{$field});
 545
 546     my($beginning, $ending, $hour) = @{$params->{$field}};
 547
 548     push @where,
 549       "cust_main.$field IS NOT NULL",
 550       "cust_main.$field >= $beginning",
 551       "cust_main.$field <= $ending";
 552
 553     if(defined $hour) {
 554       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 555         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 556       }
 557       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 558         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 559       }
 560       else {
 561         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 562       }
 563     }
 564
 565     $orderby ||= "ORDER BY cust_main.$field";
 566
 567   }
 568
 569   ###
 570   # classnum
 571   ###
 572
 573   if ( $params->{'classnum'} ) {
 574
 575     my @classnum = ref( $params->{'classnum'} )
 576                      ? @{ $params->{'classnum'} }
 577                      :  ( $params->{'classnum'} );
 578
 579     @classnum = grep /^(\d*)$/, @classnum;
 580
 581     if ( @classnum ) {
 582       push @where, '( '. join(' OR ', map {
 583                                             $_ ? "cust_main.classnum = $_"
 584                                                : "cust_main.classnum IS NULL"
 585                                           }
 586                                           @classnum
 587                              ).
 588                    ' )';
 589     }
 590
 591   }
 592
 593   ###
 594   # payby
 595   ###
 596
 597   if ( $params->{'payby'} ) {
 598
 599     my @payby = ref( $params->{'payby'} )
 600                   ? @{ $params->{'payby'} }
 601                   :  ( $params->{'payby'} );
 602
 603     @payby = grep /^([A-Z]{4})$/, @payby;
 604
 605     push @where, '( '. join(' OR ', map "cust_main.payby = '$_'", @payby). ' )'
 606       if @payby;
 607
 608   }
 609
 610   ###
 611   # paydate_year / paydate_month
 612   ###
 613
 614   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
 615     my $year = $1;
 616     $params->{'paydate_month'} =~ /^(\d\d?)$/
 617       or die "paydate_year without paydate_month?";
 618     my $month = $1;
 619
 620     push @where,
 621       'paydate IS NOT NULL',
 622       "paydate != ''",
 623       "CAST(paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
 624 ;
 625   }
 626
 627   ###
 628   # invoice terms
 629   ###
 630
 631   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 632     my $terms = $1;
 633     if ( $1 eq 'NULL' ) {
 634       push @where,
 635         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 636     } else {
 637       push @where,
 638         "cust_main.invoice_terms IS NOT NULL",
 639         "cust_main.invoice_terms = '$1'";
 640     }
 641   }
 642
 643   ##
 644   # amounts
 645   ##
 646
 647   if ( $params->{'current_balance'} ) {
 648
 649     #my $balance_sql = $class->balance_sql();
 650     my $balance_sql = FS::cust_main->balance_sql();
 651
 652     my @current_balance =
 653       ref( $params->{'current_balance'} )
 654       ? @{ $params->{'current_balance'} }
 655       :  ( $params->{'current_balance'} );
 656
 657     push @where, map { s/current_balance/$balance_sql/; $_ }
 658                      @current_balance;
 659
 660   }
 661
 662   ##
 663   # custbatch
 664   ##
 665
 666   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 667     push @where,
 668       "cust_main.custbatch = '$1'";
 669   }
 670
 671   if ( $params->{'tagnum'} ) {
 672     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 673
 674     @tagnums = grep /^(\d+)$/, @tagnums;
 675
 676     if ( @tagnums ) {
 677         my $tags_where = "0 < (select count(1) from cust_tag where "
 678                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 679                 . join(',', @tagnums) . "))";
 680
 681         push @where, $tags_where;
 682     }
 683   }
 684
 685
 686   ##
 687   # setup queries, subs, etc. for the search
 688   ##
 689
 690   $orderby ||= 'ORDER BY custnum';
 691
 692   # here is the agent virtualization
 693   push @where, $FS::CurrentUser::CurrentUser->agentnums_sql;
 694
 695   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
 696
 697   my $addl_from = 'LEFT JOIN cust_pkg USING ( custnum  ) ';
 698
 699   my $count_query = "SELECT COUNT(*) FROM cust_main $extra_sql";
 700
 701   my @select = (
 702                  'cust_main.custnum',
 703                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
 704                );
 705
 706   my(@extra_headers) = ();
 707   my(@extra_fields)  = ();
 708
 709   if ($params->{'flattened_pkgs'}) {
 710
 711     if ($dbh->{Driver}->{Name} eq 'Pg') {
 712
 713       push @select, "array_to_string(array(select pkg from cust_pkg left join part_pkg using ( pkgpart ) where cust_main.custnum = cust_pkg.custnum $pkgwhere),'|') as magic";
 714
 715     }elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
 716       push @select, "GROUP_CONCAT(pkg SEPARATOR '|') as magic";
 717       $addl_from .= " LEFT JOIN part_pkg using ( pkgpart )";
 718     }else{
 719       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 720            "omitting packing information from report.";
 721     }
 722
 723     my $header_query = "SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count FROM cust_main $addl_from $extra_sql $pkgwhere group by cust_main.custnum order by count desc limit 1";
 724
 725     my $sth = dbh->prepare($header_query) or die dbh->errstr;
 726     $sth->execute() or die $sth->errstr;
 727     my $headerrow = $sth->fetchrow_arrayref;
 728     my $headercount = $headerrow ? $headerrow->[0] : 0;
 729     while($headercount) {
 730       unshift @extra_headers, "Package ". $headercount;
 731       unshift @extra_fields, eval q!sub {my $c = shift;
 732                                          my @a = split '\|', $c->magic;
 733                                          my $p = $a[!.--$headercount. q!];
 734                                          $p;
 735                                         };!;
 736     }
 737
 738   }
 739
 740   if ( $params->{'with_geocode'} ) {
 741
 742     unshift @extra_headers, 'Tax location override', 'Calculated tax location';
 743     unshift @extra_fields, sub { my $c = shift; $c->get('geocode'); },
 744                            sub { my $c = shift;
 745                                  $c->set('geocode', '');
 746                                  $c->geocode('cch'); #XXX only cch right now
 747                                };
 748     push @select, 'geocode';
 749     push @select, 'zip' unless grep { $_ eq 'zip' } @select;
 750     push @select, 'ship_zip' unless grep { $_ eq 'ship_zip' } @select;
 751   }
 752
 753   my $select = join(', ', @select);
 754
 755   my $sql_query = {
 756     'table'         => 'cust_main',
 757     'select'        => $select,
 758     'hashref'       => {},
 759     'extra_sql'     => $extra_sql,
 760     'order_by'      => $orderby,
 761     'count_query'   => $count_query,
 762     'extra_headers' => \@extra_headers,
 763     'extra_fields'  => \@extra_fields,
 764   };
 765
 766 }
 767
 768 =item fuzzy_search FUZZY_HASHREF [ HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ ]
 769
 770 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
 771 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
 772 specified (the appropriate ship_ field is also searched).
 773
 774 Additional options are the same as FS::Record::qsearch
 775
 776 =cut
 777
 778 sub fuzzy_search {
 779   my( $self, $fuzzy, $hash, @opt) = @_;
 780   #$self
 781   $hash ||= {};
 782   my @cust_main = ();
 783
 784   check_and_rebuild_fuzzyfiles();
 785   foreach my $field ( keys %$fuzzy ) {
 786
 787     my $all = $self->all_X($field);
 788     next unless scalar(@$all);
 789
 790     my %match = ();
 791     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, ['i'], @$all ) );
 792
 793     my @fcust = ();
 794     foreach ( keys %match ) {
 795       push @fcust, qsearch('cust_main', { %$hash, $field=>$_}, @opt);
 796       push @fcust, qsearch('cust_main', { %$hash, "ship_$field"=>$_}, @opt);
 797     }
 798     my %fsaw = ();
 799     push @cust_main, grep { ! $fsaw{$_->custnum}++ } @fcust;
 800   }
 801
 802   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
 803   my %saw = ();
 804   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
 805
 806   @cust_main;
 807
 808 }
 809
 810 =back
 811
 812 =head1 UTILITY SUBROUTINES
 813
 814 =over 4
 815
 816 =item check_and_rebuild_fuzzyfiles
 817
 818 =cut
 819
 820 sub check_and_rebuild_fuzzyfiles {
 821   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 822   rebuild_fuzzyfiles() if grep { ! -e "$dir/cust_main.$_" } @fuzzyfields
 823 }
 824
 825 =item rebuild_fuzzyfiles
 826
 827 =cut
 828
 829 sub rebuild_fuzzyfiles {
 830
 831   use Fcntl qw(:flock);
 832
 833   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 834   mkdir $dir, 0700 unless -d $dir;
 835
 836   foreach my $fuzzy ( @fuzzyfields ) {
 837
 838     open(LOCK,">>$dir/cust_main.$fuzzy")
 839       or die "can't open $dir/cust_main.$fuzzy: $!";
 840     flock(LOCK,LOCK_EX)
 841       or die "can't lock $dir/cust_main.$fuzzy: $!";
 842
 843     open (CACHE,">$dir/cust_main.$fuzzy.tmp")
 844       or die "can't open $dir/cust_main.$fuzzy.tmp: $!";
 845
 846     foreach my $field ( $fuzzy, "ship_$fuzzy" ) {
 847       my $sth = dbh->prepare("SELECT $field FROM cust_main".
 848                              " WHERE $field != '' AND $field IS NOT NULL");
 849       $sth->execute or die $sth->errstr;
 850
 851       while ( my $row = $sth->fetchrow_arrayref ) {
 852         print CACHE $row->[0]. "\n";
 853       }
 854
 855     }
 856
 857     close CACHE or die "can't close $dir/cust_main.$fuzzy.tmp: $!";
 858
 859     rename "$dir/cust_main.$fuzzy.tmp", "$dir/cust_main.$fuzzy";
 860     close LOCK;
 861   }
 862
 863 }
 864
 865 =item all_X
 866
 867 =cut
 868
 869 sub all_X {
 870   my( $self, $field ) = @_;
 871   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 872   open(CACHE,"<$dir/cust_main.$field")
 873     or die "can't open $dir/cust_main.$field: $!";
 874   my @array = map { chomp; $_; } <CACHE>;
 875   close CACHE;
 876   \@array;
 877 }
 878
 879 =head1 BUGS
 880
 881 Bed bugs
 882
 883 =head1 SEE ALSO
 884
 885 L<FS::cust_main>, L<FS::Record>
 886
 887 =cut
 888
 889 1;
 890