FS/FS/cust_main/Location.pm

   1 package FS::cust_main::Location;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me @location_fields );
   5 use FS::Record qw(qsearch qsearchs);
   6 use FS::UID qw(dbh);
   7 use FS::cust_location;
   8
   9 use Carp qw(carp);
  10
  11 $DEBUG = 0;
  12 $me = '[FS::cust_main::Location]';
  13
  14 my $init = 0;
  15 BEGIN {
  16   # set up accessors for location fields
  17   if (!$init) {
  18     no strict 'refs';
  19     @location_fields =
  20       qw( address1 address2 city county state zip country district
  21         latitude longitude coord_auto censustract censusyear geocode
  22         addr_clean );
  23
  24     foreach my $f (@location_fields) {
  25       *{"FS::cust_main::Location::$f"} = sub {
  26         carp "WARNING: tried to set cust_main.$f with accessor" if (@_ > 1);
  27         shift->bill_location->$f
  28       };
  29       *{"FS::cust_main::Location::ship_$f"} = sub {
  30         carp "WARNING: tried to set cust_main.ship_$f with accessor" if (@_ > 1);
  31         shift->ship_location->$f
  32       };
  33     }
  34     $init++;
  35   }
  36 }
  37
  38 #debugging shim--probably a performance hit, so remove this at some point
  39 sub get {
  40   my $self = shift;
  41   my $field = shift;
  42   if ( $DEBUG and grep (/^(ship_)?($field)$/, @location_fields) ) {
  43     carp "WARNING: tried to get() location field $field";
  44     $self->$field;
  45   }
  46   $self->FS::Record::get($field);
  47 }
  48
  49 =head1 NAME
  50
  51 FS::cust_main::Location - Location-related methods for cust_main
  52
  53 =head1 DESCRIPTION
  54
  55 These methods are available on FS::cust_main objects;
  56
  57 =head1 METHODS
  58
  59 =over 4
  60
  61 =item bill_location
  62
  63 Returns an L<FS::cust_location> object for the customer's billing address.
  64
  65 =cut
  66
  67 sub bill_location {
  68   my $self = shift;
  69   $self->hashref->{bill_location}
  70     ||= FS::cust_location->by_key($self->bill_locationnum);
  71 }
  72
  73 =item ship_location
  74
  75 Returns an L<FS::cust_location> object for the customer's service address.
  76
  77 =cut
  78
  79 sub ship_location {
  80   my $self = shift;
  81   $self->hashref->{ship_location}
  82     ||= FS::cust_location->by_key($self->ship_locationnum);
  83 }
  84
  85 =item location TYPE
  86
  87 An alternative way of saying "bill_location or ship_location, depending on
  88 if TYPE is 'bill' or 'ship'".
  89
  90 =cut
  91
  92 sub location {
  93   my $self = shift;
  94   return $self->bill_location if $_[0] eq 'bill';
  95   return $self->ship_location if $_[0] eq 'ship';
  96   die "bad location type '$_[0]'";
  97 }
  98
  99 =back
 100
 101 =head1 CLASS METHODS
 102
 103 =over 4
 104
 105 =item location_fields
 106
 107 Returns a list of fields found in the location objects.  All of these fields
 108 can be read (but not written) by calling them as methods on the
 109 L<FS::cust_main> object (prefixed with 'ship_' for the service address
 110 fields).
 111
 112 =cut
 113
 114 sub location_fields { @location_fields }
 115
 116 sub _upgrade_data {
 117   my $class = shift;
 118   eval "use FS::contact;
 119         use FS::contact_class;
 120         use FS::contact_phone;
 121         use FS::phone_type";
 122
 123   local $FS::cust_location::import = 1;
 124   local $DEBUG = 0;
 125   my $error;
 126
 127   # Step 0: set up contact classes and phone types
 128   my $service_contact_class =
 129     qsearchs('contact_class', { classname => 'Service'})
 130     || new FS::contact_class { classname => 'Service'};
 131
 132   if ( !$service_contact_class->classnum ) {
 133     $error = $service_contact_class->insert;
 134     die "error creating contact class for Service: $error" if $error;
 135   }
 136   my %phone_type = ( # fudge slightly
 137     daytime => 'Work',
 138     night   => 'Home',
 139     mobile  => 'Mobile',
 140     fax     => 'Fax'
 141   );
 142   my $w = 10;
 143   foreach (keys %phone_type) {
 144     $phone_type{$_} = qsearchs('phone_type', { typename => $phone_type{$_}})
 145                       || new FS::phone_type  { typename => $phone_type{$_},
 146                                                weight   => $w };
 147     # just in case someone still doesn't have these
 148     if ( !$phone_type{$_}->phonetypenum ) {
 149       $error = $phone_type{$_}->insert;
 150       die "error creating phone type '$_': $error" if $error;
 151     }
 152   }
 153
 154   foreach my $cust_main (qsearch('cust_main', { bill_locationnum => '' })) {
 155     # Step 1: extract billing and service addresses into cust_location
 156     my $custnum = $cust_main->custnum;
 157     my $bill_location = FS::cust_location->new(
 158       {
 159         custnum => $custnum,
 160         map { $_ => $cust_main->get($_) } location_fields()
 161       }
 162     );
 163     $error = $bill_location->insert;
 164     die "error migrating billing address for customer $custnum: $error"
 165       if $error;
 166
 167     $cust_main->set(bill_locationnum => $bill_location->locationnum);
 168
 169     if ( $cust_main->get('ship_address1') ) {
 170       my $ship_location = FS::cust_location->new(
 171         {
 172           custnum => $custnum,
 173           map { $_ => $cust_main->get("ship_$_") } location_fields()
 174         }
 175       );
 176       $error = $ship_location->insert;
 177       die "error migrating service address for customer $custnum: $error"
 178         if $error;
 179
 180       $cust_main->set(ship_locationnum => $ship_location->locationnum);
 181
 182       # Step 2: Extract shipping address contact fields into contact
 183       my %unlike = map { $_ => 1 }
 184         grep { $cust_main->get($_) ne $cust_main->get("ship_$_") }
 185         qw( last first company daytime night fax mobile );
 186
 187       if ( %unlike ) {
 188         # then there IS a service contact
 189         my $contact = FS::contact->new({
 190           'custnum'     => $custnum,
 191           'classnum'    => $service_contact_class->classnum,
 192           'locationnum' => $ship_location->locationnum,
 193           'last'        => $cust_main->get('ship_last'),
 194           'first'       => $cust_main->get('ship_first'),
 195         });
 196         if ( $unlike{'company'} ) {
 197           # there's no contact.company field, but keep a record of it
 198           $contact->set(comment => 'Company: '.$cust_main->get('ship_company'));
 199         }
 200         $error = $contact->insert;
 201         die "error migrating service contact for customer $custnum: $error"
 202           if $error;
 203
 204         foreach ( grep { $unlike{$_} } qw( daytime night fax mobile ) ) {
 205           my $phone = $cust_main->get("ship_$_");
 206           next if !$phone;
 207           my $contact_phone = FS::contact_phone->new({
 208             'contactnum'    => $contact->contactnum,
 209             'phonetypenum'  => $phone_type{$_}->phonetypenum,
 210             FS::contact::_parse_phonestring( $phone )
 211           });
 212           $error = $contact_phone->insert;
 213           # die "whose responsible this"
 214           die "error migrating service contact phone for customer $custnum: $error"
 215             if $error;
 216           $cust_main->set("ship_$_" => '');
 217         }
 218
 219         $cust_main->set("ship_$_" => '') foreach qw(last first company);
 220       } #if %unlike
 221     } #if ship_address1
 222     else {
 223       $cust_main->set(ship_locationnum => $bill_location->locationnum);
 224     }
 225
 226     # Step 3: Wipe the migrated fields and update the cust_main
 227
 228     $cust_main->set("ship_$_" => '') foreach location_fields();
 229     $cust_main->set($_ => '') foreach location_fields();
 230
 231     $error = $cust_main->replace;
 232     die "error migrating addresses for customer $custnum: $error"
 233       if $error;
 234
 235     # Step 4: set packages at the "default service location" to ship_location
 236     foreach my $cust_pkg (
 237       qsearch('cust_pkg', { custnum => $custnum, locationnum => '' })
 238     ) {
 239       # not a location change
 240       $cust_pkg->set('locationnum', $cust_main->ship_locationnum);
 241       $error = $cust_pkg->replace;
 242       die "error migrating package ".$cust_pkg->pkgnum.": $error"
 243         if $error;
 244     }
 245
 246   } #foreach $cust_main
 247 }
 248
 249 =back
 250
 251 =cut
 252
 253 1;