FS/FS/cust_main/Location.pm

   1 package FS::cust_main::Location;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me @location_fields );
   5 use FS::Record qw(qsearch qsearchs);
   6 use FS::UID qw(dbh);
   7 use FS::cust_location;
   8
   9 use Carp qw(carp);
  10
  11 $DEBUG = 0;
  12 $me = '[FS::cust_main::Location]';
  13
  14 my $init = 0;
  15 BEGIN {
  16   # set up accessors for location fields
  17   if (!$init) {
  18     no strict 'refs';
  19     @location_fields =
  20       qw( address1 address2 city county state zip country district
  21         latitude longitude coord_auto censustract censusyear geocode
  22         addr_clean );
  23
  24     foreach my $f (@location_fields) {
  25       *{"FS::cust_main::Location::$f"} = sub {
  26         carp "WARNING: tried to set cust_main.$f with accessor" if (@_ > 1);
  27         my $l = shift->bill_location;
  28         $l ? $l->$f : '';
  29       };
  30       *{"FS::cust_main::Location::ship_$f"} = sub {
  31         carp "WARNING: tried to set cust_main.ship_$f with accessor" if (@_ > 1);
  32         my $l = shift->ship_location;
  33         $l ? $l->$f : '';
  34       };
  35     }
  36     $init++;
  37   }
  38 }
  39
  40 #debugging shim--probably a performance hit, so remove this at some point
  41 sub get {
  42   my $self = shift;
  43   my $field = shift;
  44   if ( $DEBUG and grep (/^(ship_)?($field)$/, @location_fields) ) {
  45     carp "WARNING: tried to get() location field $field";
  46     $self->$field;
  47   }
  48   $self->FS::Record::get($field);
  49 }
  50
  51 =head1 NAME
  52
  53 FS::cust_main::Location - Location-related methods for cust_main
  54
  55 =head1 DESCRIPTION
  56
  57 These methods are available on FS::cust_main objects;
  58
  59 =head1 METHODS
  60
  61 =over 4
  62
  63 =item bill_location
  64
  65 Returns an L<FS::cust_location> object for the customer's billing address.
  66
  67 =cut
  68
  69 sub bill_location {
  70   my $self = shift;
  71   $self->hashref->{bill_location}
  72     ||= FS::cust_location->by_key($self->bill_locationnum);
  73 }
  74
  75 =item ship_location
  76
  77 Returns an L<FS::cust_location> object for the customer's service address.
  78
  79 =cut
  80
  81 sub ship_location {
  82   my $self = shift;
  83   $self->hashref->{ship_location}
  84     ||= FS::cust_location->by_key($self->ship_locationnum);
  85 }
  86
  87 =item location TYPE
  88
  89 An alternative way of saying "bill_location or ship_location, depending on
  90 if TYPE is 'bill' or 'ship'".
  91
  92 =cut
  93
  94 sub location {
  95   my $self = shift;
  96   return $self->bill_location if $_[0] eq 'bill';
  97   return $self->ship_location if $_[0] eq 'ship';
  98   die "bad location type '$_[0]'";
  99 }
 100
 101 =back
 102
 103 =head1 CLASS METHODS
 104
 105 =over 4
 106
 107 =item location_fields
 108
 109 Returns a list of fields found in the location objects.  All of these fields
 110 can be read (but not written) by calling them as methods on the
 111 L<FS::cust_main> object (prefixed with 'ship_' for the service address
 112 fields).
 113
 114 =cut
 115
 116 sub location_fields { @location_fields }
 117
 118 sub _upgrade_data {
 119   my $class = shift;
 120   eval "use FS::contact;
 121         use FS::contact_class;
 122         use FS::contact_phone;
 123         use FS::phone_type";
 124
 125   local $FS::cust_location::import = 1;
 126   local $DEBUG = 0;
 127   my $error;
 128
 129   my $tax_prefix = 'bill_';
 130   if ( FS::Conf->new->exists('tax-ship_address') ) {
 131     $tax_prefix = 'ship_';
 132   }
 133
 134   # Step 0: set up contact classes and phone types
 135   my $service_contact_class =
 136     qsearchs('contact_class', { classname => 'Service'})
 137     || new FS::contact_class { classname => 'Service'};
 138
 139   if ( !$service_contact_class->classnum ) {
 140     $error = $service_contact_class->insert;
 141     die "error creating contact class for Service: $error" if $error;
 142   }
 143   my %phone_type = ( # fudge slightly
 144     daytime => 'Work',
 145     night   => 'Home',
 146     mobile  => 'Mobile',
 147     fax     => 'Fax'
 148   );
 149   my $w = 10;
 150   foreach (keys %phone_type) {
 151     $phone_type{$_} = qsearchs('phone_type', { typename => $phone_type{$_}})
 152                       || new FS::phone_type  { typename => $phone_type{$_},
 153                                                weight   => $w };
 154     # just in case someone still doesn't have these
 155     if ( !$phone_type{$_}->phonetypenum ) {
 156       $error = $phone_type{$_}->insert;
 157       die "error creating phone type '$_': $error" if $error;
 158     }
 159   }
 160
 161   foreach my $cust_main (qsearch('cust_main', { bill_locationnum => '' })) {
 162     # Step 1: extract billing and service addresses into cust_location
 163     my $custnum = $cust_main->custnum;
 164     my $bill_location = FS::cust_location->new(
 165       {
 166         custnum => $custnum,
 167         map { $_ => $cust_main->get($_) } location_fields(),
 168       }
 169     );
 170     $bill_location->set('censustract', '');
 171     $bill_location->set('censusyear', '');
 172      # properly goes with ship_location; if they're the same, will be set
 173      # on ship_location before inserting either one
 174     my $ship_location = $bill_location; # until proven otherwise
 175
 176     if ( $cust_main->get('ship_address1') ) {
 177       # detect duplicates
 178       my $same = 1;
 179       foreach (location_fields()) {
 180         if ( length($cust_main->get("ship_$_")) and
 181              $cust_main->get($_) ne $cust_main->get("ship_$_") ) {
 182           $same = 0;
 183         }
 184       }
 185
 186       if ( !$same ) {
 187         $ship_location = FS::cust_location->new(
 188           {
 189             custnum => $custnum,
 190             map { $_ => $cust_main->get("ship_$_") } location_fields()
 191           }
 192         );
 193       } # else it stays equal to $bill_location
 194
 195       # Step 2: Extract shipping address contact fields into contact
 196       my %unlike = map { $_ => 1 }
 197         grep { $cust_main->get($_) ne $cust_main->get("ship_$_") }
 198         qw( last first company daytime night fax mobile );
 199
 200       if ( %unlike ) {
 201         # then there IS a service contact
 202         my $contact = FS::contact->new({
 203           'custnum'     => $custnum,
 204           'classnum'    => $service_contact_class->classnum,
 205           'locationnum' => $ship_location->locationnum,
 206           'last'        => $cust_main->get('ship_last'),
 207           'first'       => $cust_main->get('ship_first'),
 208         });
 209         if ( !$cust_main->get('ship_last') or !$cust_main->get('ship_first') )
 210         {
 211           warn "customer $custnum has no service contact name; substituting ".
 212                "customer name\n";
 213           $contact->set('last' => $cust_main->get('last'));
 214           $contact->set('first' => $cust_main->get('first'));
 215         }
 216
 217         if ( $unlike{'company'} ) {
 218           # there's no contact.company field, but keep a record of it
 219           $contact->set(comment => 'Company: '.$cust_main->get('ship_company'));
 220         }
 221         $error = $contact->insert;
 222         die "error migrating service contact for customer $custnum: $error"
 223           if $error;
 224
 225         foreach ( grep { $unlike{$_} } qw( daytime night fax mobile ) ) {
 226           my $phone = $cust_main->get("ship_$_");
 227           next if !$phone;
 228           my $contact_phone = FS::contact_phone->new({
 229             'contactnum'    => $contact->contactnum,
 230             'phonetypenum'  => $phone_type{$_}->phonetypenum,
 231             FS::contact::_parse_phonestring( $phone )
 232           });
 233           $error = $contact_phone->insert;
 234           # die "whose responsible this"
 235           die "error migrating service contact phone for customer $custnum: $error"
 236             if $error;
 237           $cust_main->set("ship_$_" => '');
 238         }
 239
 240         $cust_main->set("ship_$_" => '') foreach qw(last first company);
 241       } #if %unlike
 242     } #if ship_address1
 243
 244     # special case: should go with whichever location is used to calculate
 245     # taxes, because that's the one it originally came from
 246     if ( my $geocode = $cust_main->get('geocode') ) {
 247       $bill_location->set('geocode' => '');
 248       $ship_location->set('geocode' => '');
 249
 250       if ( $tax_prefix eq 'bill_' ) {
 251         $bill_location->set('geocode', $geocode);
 252       } elsif ( $tax_prefix eq 'ship_' ) {
 253         $ship_location->set('geocode', $geocode);
 254       }
 255     }
 256
 257     # this always goes with the ship_location (whether it's the same as
 258     # bill_location or not)
 259     $ship_location->set('censustract', $cust_main->get('censustract'));
 260     $ship_location->set('censusyear',  $cust_main->get('censusyear'));
 261
 262     $error = $bill_location->insert;
 263     die "error migrating billing address for customer $custnum: $error"
 264       if $error;
 265
 266     $cust_main->set(bill_locationnum => $bill_location->locationnum);
 267
 268     if (!$ship_location->locationnum) {
 269       $error = $ship_location->insert;
 270       die "error migrating service address for customer $custnum: $error"
 271         if $error;
 272     }
 273
 274     $cust_main->set(ship_locationnum => $ship_location->locationnum);
 275
 276     # Step 3: Wipe the migrated fields and update the cust_main
 277
 278     $cust_main->set("ship_$_" => '') foreach location_fields();
 279     $cust_main->set($_ => '') foreach location_fields();
 280
 281     $error = $cust_main->replace;
 282     die "error migrating addresses for customer $custnum: $error"
 283       if $error;
 284
 285     # Step 4: set packages at the "default service location" to ship_location
 286     foreach my $cust_pkg (
 287       qsearch('cust_pkg', { custnum => $custnum, locationnum => '' })
 288     ) {
 289       # not a location change
 290       $cust_pkg->set('locationnum', $cust_main->ship_locationnum);
 291       $error = $cust_pkg->replace;
 292       die "error migrating package ".$cust_pkg->pkgnum.": $error"
 293         if $error;
 294     }
 295
 296   } #foreach $cust_main
 297
 298   # repair an error in earlier upgrades
 299   if (!FS::upgrade_journal->is_done('cust_location_censustract_repair')
 300        and FS::Conf->new->exists('cust_main-require_censustract') ) {
 301
 302     foreach my $cust_location (
 303       qsearch('cust_location', { 'censustract' => '' })
 304     ) {
 305       my $custnum = $cust_location->custnum;
 306       next if !$custnum; # avoid doing this for prospect locations
 307       my $address1 = $cust_location->address1;
 308       # find the last history record that had that address
 309       my $last_h = qsearchs({
 310           table     => 'h_cust_main',
 311           extra_sql => " WHERE custnum = $custnum AND address1 = ".
 312                         dbh->quote($address1) .
 313                         " AND censustract IS NOT NULL",
 314           order_by  => " ORDER BY history_date DESC LIMIT 1",
 315       });
 316       if (!$last_h) {
 317         # this is normal; just means it never had a census tract before
 318         next;
 319       }
 320       $cust_location->set('censustract' => $last_h->get('censustract'));
 321       $cust_location->set('censusyear'  => $last_h->get('censusyear'));
 322       my $error = $cust_location->replace;
 323       warn "Error setting census tract for customer #$custnum:\n  $error\n"
 324         if $error;
 325     } # foreach $cust_location
 326     FS::upgrade_journal->set_done('cust_location_censustract_repair');
 327   }
 328
 329 }
 330
 331 =back
 332
 333 =cut
 334
 335 1;