FS/FS/cust_main/Billing_Batch.pm

   1 package FS::cust_main::Billing_Batch;
   2
   3 use strict;
   4 use vars qw( $conf );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::pay_batch;
   7 use FS::cust_pay_batch;
   8 use FS::cust_bill_pay_batch;
   9
  10 install_callback FS::UID sub {
  11   $conf = new FS::Conf;
  12   #yes, need it for stuff below (prolly should be cached)
  13 };
  14
  15 =item batch_card OPTION => VALUE...
  16
  17 Adds a payment for this invoice to the pending credit card batch (see
  18 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
  19 runs the payment using a realtime gateway.
  20
  21 Options may include:
  22
  23 B<amount>: the amount to be paid; defaults to the customer's balance minus
  24 any payments in transit.
  25
  26 B<realtime>: runs this as a realtime payment instead of adding it to a
  27 batch.  Deprecated.
  28
  29 B<invnum>: sets cust_pay_batch.invnum.
  30
  31 B<address1>, B<address2>, B<city>, B<state>, B<zip>, B<country>: sets
  32 the billing address for the payment; defaults to the customer's billing
  33 location.
  34
  35 B<payby>, B<payinfo>, B<paydate>, B<payname>: sets the payment method,
  36 payment account, expiration date, and name; defaults to those fields
  37 in cust_main.
  38
  39 =cut
  40
  41 sub batch_card {
  42   my ($self, %options) = @_;
  43
  44   my $amount;
  45   if (exists($options{amount})) {
  46     $amount = $options{amount};
  47   }else{
  48     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
  49   }
  50   if ($amount <= 0) {
  51     warn(sprintf("Customer balance %.2f - in transit amount %.2f is <= 0.\n",
  52         $self->balance,
  53         $self->in_transit_payments
  54     ));
  55     return;
  56   }
  57
  58   #my $invnum = delete $options{invnum};
  59   my $invnum = $options{invnum};
  60
  61   #pay fields should all come from either cust_payby or options, not both
  62   #  in theory, could just pass payby, and use it to select cust_payby,
  63   #  but nothing currently needs that, so not implementing it now
  64   die "Incomplete payment details"
  65     if  ($options{payby} || $options{payinfo} || $options{paydate} || $options{payname})
  66     && !($options{payby} && $options{payinfo} && $options{paydate} && $options{payname});
  67
  68   #false laziness with Billing_Realtime
  69   my @cust_payby = $self->cust_payby('CARD','CHEK');
  70
  71   # batch can't try out every one like realtime, just use first one
  72   my $cust_payby = $cust_payby[0];
  73
  74   die "No customer payment info found"
  75     unless $options{payinfo} || $cust_payby;
  76
  77   my $payby = $options{payby} || $cust_payby->payby;
  78
  79   if ($options{'realtime'}) {
  80     return $self->realtime_bop( FS::payby->payby2bop($payby),
  81                                 $amount,
  82                                 %options,
  83                               );
  84   }
  85
  86   my $oldAutoCommit = $FS::UID::AutoCommit;
  87   local $FS::UID::AutoCommit = 0;
  88   my $dbh = dbh;
  89
  90   #this needs to handle mysql as well as Pg, like svc_acct.pm
  91   #(make it into a common function if folks need to do batching with mysql)
  92   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
  93     or die "Cannot lock pay_batch: " . $dbh->errstr;
  94
  95   my %pay_batch = (
  96     'status' => 'O',
  97     'payby'  => FS::payby->payby2payment($payby),
  98   );
  99   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
 100
 101   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
 102
 103   unless ( $pay_batch ) {
 104     $pay_batch = new FS::pay_batch \%pay_batch;
 105     my $error = $pay_batch->insert;
 106     if ( $error ) {
 107       $dbh->rollback if $oldAutoCommit;
 108       die "error creating new batch: $error\n";
 109     }
 110   }
 111
 112   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
 113       'batchnum' => $pay_batch->batchnum,
 114       'custnum'  => $self->custnum,
 115   } );
 116
 117   foreach (qw( address1 address2 city state zip country latitude longitude
 118                payby payinfo paydate payname paycode paytype ))
 119   {
 120     $options{$_} = '' unless exists($options{$_});
 121   }
 122
 123   my $loc = $self->bill_location;
 124
 125   my $cust_pay_batch = new FS::cust_pay_batch ( {
 126     'batchnum' => $pay_batch->batchnum,
 127     'invnum'   => $invnum || 0,                    # is there a better value?
 128                                                    # this field should be
 129                                                    # removed...
 130                                                    # cust_bill_pay_batch now
 131     'custnum'  => $self->custnum,
 132     'last'     => $self->getfield('last'),
 133     'first'    => $self->getfield('first'),
 134     'address1' => $options{address1} || $loc->address1,
 135     'address2' => $options{address2} || $loc->address2,
 136     'city'     => $options{city}     || $loc->city,
 137     'state'    => $options{state}    || $loc->state,
 138     'zip'      => $options{zip}      || $loc->zip,
 139     'country'  => $options{country}  || $loc->country,
 140     'payby'    => $options{payby}    || $cust_payby->payby,
 141     'payinfo'  => $options{payinfo}  || $cust_payby->payinfo,
 142     'paymask'  => ( $options{payinfo}
 143                       ? FS::payinfo_Mixin->mask_payinfo( $options{payby},
 144                                                          $options{payinfo} )
 145                       : $cust_payby->paymask
 146                   ),
 147     'exp'      => $options{paydate}  || $cust_payby->paydate,
 148     'payname'  => $options{payname}  || $cust_payby->payname,
 149     'paytype'  => $options{paytype}  || $cust_payby->paytype,
 150     'amount'   => $amount,                         # consolidating
 151     'paycode'  => $options{paycode}  || '',
 152   } );
 153
 154   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
 155     if $old_cust_pay_batch;
 156
 157   my $error;
 158   if ($old_cust_pay_batch) {
 159     $error = $cust_pay_batch->replace($old_cust_pay_batch)
 160   } else {
 161     $error = $cust_pay_batch->insert;
 162   }
 163
 164   if ( $error ) {
 165     $dbh->rollback if $oldAutoCommit;
 166     #die $error;
 167     return $error; # e.g. "Illegal zip" ala RT#75998
 168   }
 169
 170   if ($options{'processing-fee'} > 0) {
 171     my $pf_cust_pkg;
 172     my $processing_fee_text = 'Payment Processing Fee';
 173     my $pf_change_error = $self->charge({
 174             'amount'  => $options{'processing-fee'},
 175             'pkg'   => $processing_fee_text,
 176             'setuptax'  => 'Y',
 177             'cust_pkg_ref' => \$pf_cust_pkg,
 178     });
 179
 180     if($pf_change_error) {
 181       warn 'Unable to add payment processing fee';
 182       return '';
 183     }
 184
 185     $pf_cust_pkg->setup(time);
 186     my $pf_error = $pf_cust_pkg->replace;
 187     if($pf_error) {
 188       warn 'Unable to set setup time on cust_pkg for processing fee';
 189       # but keep going...
 190     }
 191
 192     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $invnum });
 193     unless ( $cust_bill ) {
 194       warn "race condition + invoice deletion just happened";
 195       return '';
 196     }
 197
 198     my $grand_pf_error =
 199       $cust_bill->add_cc_surcharge($pf_cust_pkg->pkgnum,$options{'processing-fee'});
 200
 201     warn "cannot add Processing fee to invoice #$invnum: $grand_pf_error"
 202       if $grand_pf_error;
 203   }
 204
 205   my $unapplied =   $self->total_unapplied_credits
 206                   + $self->total_unapplied_payments
 207                   + $self->in_transit_payments;
 208   foreach my $cust_bill ($self->open_cust_bill) {
 209     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
 210     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
 211       'invnum' => $cust_bill->invnum,
 212       'paybatchnum' => $cust_pay_batch->paybatchnum,
 213       'amount' => $cust_bill->owed,
 214       '_date' => time,
 215     };
 216     if ($unapplied >= $cust_bill_pay_batch->amount){
 217       $unapplied -= $cust_bill_pay_batch->amount;
 218       next;
 219     }else{
 220       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
 221                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
 222     }
 223     $error = $cust_bill_pay_batch->insert;
 224     if ( $error ) {
 225       $dbh->rollback if $oldAutoCommit;
 226       die $error;
 227     }
 228   }
 229
 230   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 231   '';
 232 }
 233
 234 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
 235
 236 Returns all batched payments (see L<FS::cust_pay_batch>) for this customer.
 237
 238 Optionally, a list or hashref of additional arguments to the qsearch call can
 239 be passed.
 240
 241 =cut
 242
 243 sub cust_pay_batch {
 244   my $self = shift;
 245   my $opt = ref($_[0]) ? shift : { @_ };
 246
 247   #return $self->num_cust_statement unless wantarray || keys %$opt;
 248
 249   $opt->{'table'} = 'cust_pay_batch';
 250   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
 251   $opt->{'hashref'}{'custnum'} = $self->custnum;
 252   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
 253
 254   map { $_ } #behavior of sort undefined in scalar context
 255     sort { $a->paybatchnum <=> $b->paybatchnum }
 256       qsearch($opt);
 257 }
 258
 259 =item in_transit_payments
 260
 261 Returns the total of requests for payments for this customer pending in
 262 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
 263
 264 =cut
 265
 266 sub in_transit_payments {
 267   my $self = shift;
 268   my $in_transit_payments = 0;
 269   foreach my $pay_batch ( qsearch('pay_batch', {
 270     'status' => 'I',
 271   } ) ) {
 272     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
 273       'batchnum' => $pay_batch->batchnum,
 274       'custnum' => $self->custnum,
 275       'status'  => '',
 276     } ) ) {
 277       $in_transit_payments += $cust_pay_batch->amount;
 278     }
 279   }
 280   sprintf( "%.2f", $in_transit_payments );
 281 }
 282
 283 1;