FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24
  25 # 1 is mostly method/subroutine entry and options
  26 # 2 traces progress of some operations
  27 # 3 is even more information including possibly sensitive data
  28 $DEBUG = 0;
  29 $me = '[FS::cust_main::Billing]';
  30
  31 install_callback FS::UID sub {
  32   $conf = new FS::Conf;
  33   #yes, need it for stuff below (prolly should be cached)
  34 };
  35
  36 =head1 NAME
  37
  38 FS::cust_main::Billing - Billing mixin for cust_main
  39
  40 =head1 SYNOPSIS
  41
  42 =head1 DESCRIPTION
  43
  44 These methods are available on FS::cust_main objects.
  45
  46 =head1 METHODS
  47
  48 =over 4
  49
  50 =item bill_and_collect
  51
  52 Cancels and suspends any packages due, generates bills, applies payments and
  53 credits, and applies collection events to run cards, send bills and notices,
  54 etc.
  55
  56 By default, warns on errors and continues with the next operation (but see the
  57 "fatal" flag below).
  58
  59 Options are passed as name-value pairs.  Currently available options are:
  60
  61 =over 4
  62
  63 =item time
  64
  65 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  66
  67  use Date::Parse;
  68  ...
  69  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  70
  71 =item invoice_time
  72
  73 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  74
  75 =item check_freq
  76
  77 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  78
  79 =item resetup
  80
  81 If set true, re-charges setup fees.
  82
  83 =item fatal
  84
  85 If set any errors prevent subsequent operations from continusing.  If set
  86 specifically to "return", returns the error (or false, if there is no error).
  87 Any other true value causes errors to die.
  88
  89 =item debug
  90
  91 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  92
  93 =item job
  94
  95 Optional FS::queue entry to receive status updates.
  96
  97 =back
  98
  99 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 100 options of those methods are also available.
 101
 102 =cut
 103
 104 sub bill_and_collect {
 105   my( $self, %options ) = @_;
 106
 107   my $error;
 108
 109   #$options{actual_time} not $options{time} because freeside-daily -d is for
 110   #pre-printing invoices
 111
 112   $options{'actual_time'} ||= time;
 113   my $job = $options{'job'};
 114
 115   $job->update_statustext('0,cleaning expired packages') if $job;
 116   $error = $self->cancel_expired_pkgs( day_end( $options{actual_time} ) );
 117   if ( $error ) {
 118     $error = "Error expiring custnum ". $self->custnum. ": $error";
 119     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 120     elsif ( $options{fatal}                                ) { die    $error; }
 121     else                                                     { warn   $error; }
 122   }
 123
 124   $error = $self->suspend_adjourned_pkgs( day_end( $options{actual_time} ) );
 125   if ( $error ) {
 126     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 127     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 128     elsif ( $options{fatal}                                ) { die    $error; }
 129     else                                                     { warn   $error; }
 130   }
 131
 132   $error = $self->unsuspend_resumed_pkgs( day_end( $options{actual_time} ) );
 133   if ( $error ) {
 134     $error = "Error resuming custnum ".$self->custnum. ": $error";
 135     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 136     elsif ( $options{fatal}                                ) { die    $error; }
 137     else                                                     { warn   $error; }
 138   }
 139
 140   $job->update_statustext('20,billing packages') if $job;
 141   $error = $self->bill( %options );
 142   if ( $error ) {
 143     $error = "Error billing custnum ". $self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('50,applying payments and credits') if $job;
 150   $error = $self->apply_payments_and_credits;
 151   if ( $error ) {
 152     $error = "Error applying custnum ". $self->custnum. ": $error";
 153     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 154     elsif ( $options{fatal}                                ) { die    $error; }
 155     else                                                     { warn   $error; }
 156   }
 157
 158   $job->update_statustext('70,running collection events') if $job;
 159   unless ( $conf->exists('cancelled_cust-noevents')
 160            && ! $self->num_ncancelled_pkgs
 161   ) {
 162     $error = $self->collect( %options );
 163     if ( $error ) {
 164       $error = "Error collecting custnum ". $self->custnum. ": $error";
 165       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 166       elsif ($options{fatal}                               ) { die    $error; }
 167       else                                                   { warn   $error; }
 168     }
 169   }
 170   $job->update_statustext('100,finished') if $job;
 171
 172   '';
 173
 174 }
 175
 176 sub cancel_expired_pkgs {
 177   my ( $self, $time, %options ) = @_;
 178
 179   my @cancel_pkgs = $self->ncancelled_pkgs( {
 180     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 181   } );
 182
 183   my @errors = ();
 184
 185   foreach my $cust_pkg ( @cancel_pkgs ) {
 186     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 187     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 188                                            'reason_otaker' => $cpr->otaker,
 189                                            'time'          => $time,
 190                                          )
 191                                        : ()
 192                                  );
 193     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 194   }
 195
 196   join(' / ', @errors);
 197
 198 }
 199
 200 sub suspend_adjourned_pkgs {
 201   my ( $self, $time, %options ) = @_;
 202
 203   my @susp_pkgs = $self->ncancelled_pkgs( {
 204     'extra_sql' =>
 205       " AND ( susp IS NULL OR susp = 0 )
 206         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 207               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 208             )
 209       ",
 210   } );
 211
 212   #only because there's no SQL test for is_prepaid :/
 213   @susp_pkgs =
 214     grep {     (    $_->part_pkg->is_prepaid
 215                  && $_->bill
 216                  && $_->bill < $time
 217                )
 218             || (    $_->adjourn
 219                  && $_->adjourn <= $time
 220                )
 221
 222          }
 223          @susp_pkgs;
 224
 225   my @errors = ();
 226
 227   foreach my $cust_pkg ( @susp_pkgs ) {
 228     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 229       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 230     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 231                                             'reason_otaker' => $cpr->otaker
 232                                           )
 233                                         : ()
 234                                   );
 235     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 236   }
 237
 238   join(' / ', @errors);
 239
 240 }
 241
 242 sub unsuspend_resumed_pkgs {
 243   my ( $self, $time, %options ) = @_;
 244
 245   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 246     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 247   } );
 248
 249   my @errors = ();
 250
 251   foreach my $cust_pkg ( @unsusp_pkgs ) {
 252     my $error = $cust_pkg->unsuspend( 'time' => $time );
 253     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 254   }
 255
 256   join(' / ', @errors);
 257
 258 }
 259
 260 =item bill OPTIONS
 261
 262 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 263 conjunction with the collect method by calling B<bill_and_collect>.
 264
 265 If there is an error, returns the error, otherwise returns false.
 266
 267 Options are passed as name-value pairs.  Currently available options are:
 268
 269 =over 4
 270
 271 =item resetup
 272
 273 If set true, re-charges setup fees.
 274
 275 =item recurring_only
 276
 277 If set true then only bill recurring charges, not setup, usage, one time
 278 charges, etc.
 279
 280 =item freq_override
 281
 282 If set, then override the normal frequency and look for a part_pkg_discount
 283 to take at that frequency.  This is appropriate only when the normal
 284 frequency for all packages is monthly, and is an error otherwise.  Use
 285 C<pkg_list> to limit the set of packages included in billing.
 286
 287 =item time
 288
 289 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 290
 291  use Date::Parse;
 292  ...
 293  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 294
 295 =item pkg_list
 296
 297 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 298
 299  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 300
 301 =item not_pkgpart
 302
 303 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 304
 305 =item invoice_time
 306
 307 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 308
 309 =item cancel
 310
 311 This boolean value informs the us that the package is being cancelled.  This
 312 typically might mean not charging the normal recurring fee but only usage
 313 fees since the last billing. Setup charges may be charged.  Not all package
 314 plans support this feature (they tend to charge 0).
 315
 316 =item no_usage_reset
 317
 318 Prevent the resetting of usage limits during this call.
 319
 320 =item no_commit
 321
 322 Do not save the generated bill in the database.  Useful with return_bill
 323
 324 =item return_bill
 325
 326 A list reference on which the generated bill(s) will be returned.
 327
 328 =item invoice_terms
 329
 330 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 331 terms or the default terms are used.
 332
 333 =back
 334
 335 =cut
 336
 337 sub bill {
 338   my( $self, %options ) = @_;
 339
 340   return '' if $self->payby eq 'COMP';
 341
 342   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 343
 344   warn "$me bill customer ". $self->custnum. "\n"
 345     if $DEBUG;
 346
 347   my $time = $options{'time'} || time;
 348   my $invoice_time = $options{'invoice_time'} || $time;
 349
 350   $options{'not_pkgpart'} ||= {};
 351   $options{'not_pkgpart'} = { map { $_ => 1 }
 352                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 353                             }
 354     unless ref($options{'not_pkgpart'});
 355
 356   local $SIG{HUP} = 'IGNORE';
 357   local $SIG{INT} = 'IGNORE';
 358   local $SIG{QUIT} = 'IGNORE';
 359   local $SIG{TERM} = 'IGNORE';
 360   local $SIG{TSTP} = 'IGNORE';
 361   local $SIG{PIPE} = 'IGNORE';
 362
 363   my $oldAutoCommit = $FS::UID::AutoCommit;
 364   local $FS::UID::AutoCommit = 0;
 365   my $dbh = dbh;
 366
 367   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 368     if $DEBUG;
 369
 370   $self->select_for_update; #mutex
 371
 372   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 373     if $DEBUG;
 374
 375   my $error = $self->do_cust_event(
 376     'debug'      => ( $options{'debug'} || 0 ),
 377     'time'       => $invoice_time,
 378     'check_freq' => $options{'check_freq'},
 379     'stage'      => 'pre-bill',
 380   )
 381     unless $options{no_commit};
 382   if ( $error ) {
 383     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 384     return $error;
 385   }
 386
 387   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   #keep auto-charge and non-auto-charge line items separate
 391   my @passes = ( '', 'no_auto' );
 392
 393   my %cust_bill_pkg = map { $_ => [] } @passes;
 394
 395   ###
 396   # find the packages which are due for billing, find out how much they are
 397   # & generate invoice database.
 398   ###
 399
 400   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 401   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 402
 403   my %taxlisthash = map { $_ => {} } @passes;
 404
 405   my @precommit_hooks = ();
 406
 407   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 408   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 409
 410     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 411
 412     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 413
 414     #? to avoid use of uninitialized value errors... ?
 415     $cust_pkg->setfield('bill', '')
 416       unless defined($cust_pkg->bill);
 417
 418     #my $part_pkg = $cust_pkg->part_pkg;
 419
 420     my $real_pkgpart = $cust_pkg->pkgpart;
 421     my %hash = $cust_pkg->hash;
 422
 423     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 424     # suffer from performance issues
 425     $options{has_hidden} = 0;
 426     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 427     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 428
 429     foreach my $part_pkg ( @part_pkg ) {
 430
 431       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 432
 433       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 434
 435       my $next_bill = $cust_pkg->getfield('bill') || 0;
 436       my $error;
 437       # let this run once if this is the last bill upon cancellation
 438       while ( $next_bill <= $time or $options{cancel} ) {
 439         $error =
 440           $self->_make_lines( 'part_pkg'            => $part_pkg,
 441                               'cust_pkg'            => $cust_pkg,
 442                               'precommit_hooks'     => \@precommit_hooks,
 443                               'line_items'          => $cust_bill_pkg{$pass},
 444                               'setup'               => $total_setup{$pass},
 445                               'recur'               => $total_recur{$pass},
 446                               'tax_matrix'          => $taxlisthash{$pass},
 447                               'time'                => $time,
 448                               'real_pkgpart'        => $real_pkgpart,
 449                               'options'             => \%options,
 450                             );
 451
 452         # Stop if anything goes wrong
 453         last if $error;
 454
 455         # or if we're not incrementing the bill date.
 456         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 457
 458         # or if we're letting it run only once
 459         last if $options{cancel};
 460
 461         $next_bill = $cust_pkg->getfield('bill') || 0;
 462
 463         #stop if -o was passed to freeside-daily
 464         last if $options{'one_recur'};
 465       }
 466       if ($error) {
 467         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 468         return $error;
 469       }
 470
 471     } #foreach my $part_pkg
 472
 473   } #foreach my $cust_pkg
 474
 475   #if the customer isn't on an automatic payby, everything can go on a single
 476   #invoice anyway?
 477   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 478     #merge everything into one list
 479   #}
 480
 481   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 482
 483     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 484
 485     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 486
 487     warn "$me billing pass $pass\n"
 488            #.Dumper(\@cust_bill_pkg)."\n"
 489       if $DEBUG > 2;
 490
 491     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 492            !$conf->exists('postal_invoice-recurring_only')
 493        )
 494     {
 495
 496       my $postal_pkg = $self->charge_postal_fee();
 497       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 498
 499         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 500         return "can't charge postal invoice fee for customer ".
 501           $self->custnum. ": $postal_pkg";
 502
 503       } elsif ( $postal_pkg ) {
 504
 505         my $real_pkgpart = $postal_pkg->pkgpart;
 506         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 507         # suffer from performance issues
 508         $options{has_hidden} = 0;
 509         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 510         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 511
 512         foreach my $part_pkg ( @part_pkg ) {
 513           my %postal_options = %options;
 514           delete $postal_options{cancel};
 515           my $error =
 516             $self->_make_lines( 'part_pkg'            => $part_pkg,
 517                                 'cust_pkg'            => $postal_pkg,
 518                                 'precommit_hooks'     => \@precommit_hooks,
 519                                 'line_items'          => \@cust_bill_pkg,
 520                                 'setup'               => $total_setup{$pass},
 521                                 'recur'               => $total_recur{$pass},
 522                                 'tax_matrix'          => $taxlisthash{$pass},
 523                                 'time'                => $time,
 524                                 'real_pkgpart'        => $real_pkgpart,
 525                                 'options'             => \%postal_options,
 526                               );
 527           if ($error) {
 528             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 529             return $error;
 530           }
 531         }
 532
 533         # it's silly to have a zero value postal_pkg, but....
 534         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 535
 536       }
 537
 538     }
 539
 540     my $listref_or_error =
 541       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 542
 543     unless ( ref( $listref_or_error ) ) {
 544       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 545       return $listref_or_error;
 546     }
 547
 548     foreach my $taxline ( @$listref_or_error ) {
 549       ${ $total_setup{$pass} } =
 550         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 551       push @cust_bill_pkg, $taxline;
 552     }
 553
 554     #add tax adjustments
 555     warn "adding tax adjustments...\n" if $DEBUG > 2;
 556     foreach my $cust_tax_adjustment (
 557       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 558                                        'billpkgnum' => '',
 559                                      }
 560              )
 561     ) {
 562
 563       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 564
 565       my $itemdesc = $cust_tax_adjustment->taxname;
 566       $itemdesc = '' if $itemdesc eq 'Tax';
 567
 568       push @cust_bill_pkg, new FS::cust_bill_pkg {
 569         'pkgnum'      => 0,
 570         'setup'       => $tax,
 571         'recur'       => 0,
 572         'sdate'       => '',
 573         'edate'       => '',
 574         'itemdesc'    => $itemdesc,
 575         'itemcomment' => $cust_tax_adjustment->comment,
 576         'cust_tax_adjustment' => $cust_tax_adjustment,
 577         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 578       };
 579
 580     }
 581
 582     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 583
 584     my @cust_bill = $self->cust_bill;
 585     my $balance = $self->balance;
 586     my $previous_balance = scalar(@cust_bill)
 587                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 588                              : 0;
 589
 590     $previous_balance += $cust_bill[$#cust_bill]->charged
 591       if scalar(@cust_bill);
 592     #my $balance_adjustments =
 593     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 594
 595     warn "creating the new invoice\n" if $DEBUG;
 596     #create the new invoice
 597     my $cust_bill = new FS::cust_bill ( {
 598       'custnum'             => $self->custnum,
 599       '_date'               => $invoice_time,
 600       'charged'             => $charged,
 601       'billing_balance'     => $balance,
 602       'previous_balance'    => $previous_balance,
 603       'invoice_terms'       => $options{'invoice_terms'},
 604       'cust_bill_pkg'       => \@cust_bill_pkg,
 605     } );
 606     $error = $cust_bill->insert unless $options{no_commit};
 607     if ( $error ) {
 608       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 609       return "can't create invoice for customer #". $self->custnum. ": $error";
 610     }
 611     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 612
 613   } #foreach my $pass ( keys %cust_bill_pkg )
 614
 615   foreach my $hook ( @precommit_hooks ) {
 616     eval {
 617       &{$hook}; #($self) ?
 618     } unless $options{no_commit};
 619     if ( $@ ) {
 620       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 621       return "$@ running precommit hook $hook\n";
 622     }
 623   }
 624
 625   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 626
 627   ''; #no error
 628 }
 629
 630 #discard bundled packages of 0 value
 631 sub _omit_zero_value_bundles {
 632   my @in = @_;
 633
 634   my @cust_bill_pkg = ();
 635   my @cust_bill_pkg_bundle = ();
 636   my $sum = 0;
 637   my $discount_show_always = 0;
 638
 639   foreach my $cust_bill_pkg ( @in ) {
 640
 641     $discount_show_always = ($cust_bill_pkg->get('discounts')
 642                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 643                                 && $conf->exists('discount-show-always'));
 644
 645     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 646          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 647          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 648       if $DEBUG > 0;
 649
 650     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 651       push @cust_bill_pkg, @cust_bill_pkg_bundle
 652         if $sum > 0
 653         || ($sum == 0 && (    $discount_show_always
 654                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 655                                    @cust_bill_pkg_bundle
 656                          )
 657            );
 658       @cust_bill_pkg_bundle = ();
 659       $sum = 0;
 660     }
 661
 662     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 663     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 664
 665   }
 666
 667   push @cust_bill_pkg, @cust_bill_pkg_bundle
 668     if $sum > 0
 669     || ($sum == 0 && (    $discount_show_always
 670                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 671                                @cust_bill_pkg_bundle
 672                      )
 673        );
 674
 675   warn "  _omit_zero_value_bundles: ". scalar(@in).
 676        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 677     if $DEBUG > 2;
 678
 679   (@cust_bill_pkg);
 680
 681 }
 682
 683 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 684
 685 This is a weird one.  Perhaps it should not even be exposed.
 686
 687 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 688 Usually used internally by bill method B<bill>.
 689
 690 If there is an error, returns the error, otherwise returns reference to a
 691 list of line items suitable for insertion.
 692
 693 =over 4
 694
 695 =item LINEITEMREF
 696
 697 An array ref of the line items being billed.
 698
 699 =item TAXHASHREF
 700
 701 A strange beast.  The keys to this hash are internal identifiers consisting
 702 of the name of the tax object type, a space, and its unique identifier ( e.g.
 703  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 704 item in the list is the tax object.  The remaining items are either line
 705 items or floating point values (currency amounts).
 706
 707 The taxes are calculated on this entity.  Calculated exemption records are
 708 transferred to the LINEITEMREF items on the assumption that they are related.
 709
 710 Read the source.
 711
 712 =item INVOICE_TIME
 713
 714 This specifies the date appearing on the associated invoice.  Some
 715 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 716
 717 =back
 718
 719 =cut
 720
 721 sub calculate_taxes {
 722   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 723
 724   # $taxlisthash is a hashref
 725   # keys are identifiers, values are arrayrefs
 726   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 727   # then any cust_bill_pkg objects the tax applies to
 728
 729   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 730
 731   warn "$me calculate_taxes\n"
 732        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 733     if $DEBUG > 2;
 734
 735   my @tax_line_items = ();
 736
 737   # keys are tax names (as printed on invoices / itemdesc )
 738   # values are listrefs of taxlisthash keys (internal identifiers)
 739   my %taxname = ();
 740
 741   # keys are taxlisthash keys (internal identifiers)
 742   # values are (cumulative) amounts
 743   my %tax = ();
 744
 745   # keys are taxlisthash keys (internal identifiers)
 746   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 747   my %tax_location = ();
 748
 749   # keys are taxlisthash keys (internal identifiers)
 750   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 751   my %tax_rate_location = ();
 752
 753   foreach my $tax ( keys %$taxlisthash ) {
 754     # $tax is a tax identifier
 755     my $tax_object = shift @{ $taxlisthash->{$tax} };
 756     # $tax_object is a cust_main_county or tax_rate
 757     # (with pkgnum and locationnum set)
 758     # the rest of @{ $taxlisthash->{$tax} } is cust_bill_pkg objects
 759     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 760     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 761     # taxline calculates the tax on all cust_bill_pkgs in the
 762     # first (arrayref) argument
 763     my $hashref_or_error =
 764       $tax_object->taxline( $taxlisthash->{$tax},
 765                             'custnum'      => $self->custnum,
 766                             'invoice_time' => $invoice_time
 767                           );
 768     return $hashref_or_error unless ref($hashref_or_error);
 769
 770     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 771
 772     my $name   = $hashref_or_error->{'name'};
 773     my $amount = $hashref_or_error->{'amount'};
 774
 775     #warn "adding $amount as $name\n";
 776     $taxname{ $name } ||= [];
 777     push @{ $taxname{ $name } }, $tax;
 778
 779     $tax{ $tax } += $amount;
 780
 781     # link records between cust_main_county/tax_rate and cust_location
 782     $tax_location{ $tax } ||= [];
 783     $tax_rate_location{ $tax } ||= [];
 784     if ( ref($tax_object) eq 'FS::cust_main_county' ) {
 785       push @{ $tax_location{ $tax }  },
 786         {
 787           'taxnum'      => $tax_object->taxnum,
 788           'taxtype'     => ref($tax_object),
 789           'pkgnum'      => $tax_object->get('pkgnum'),
 790           'locationnum' => $tax_object->get('locationnum'),
 791           'amount'      => sprintf('%.2f', $amount ),
 792         };
 793     }
 794     elsif ( ref($tax_object) eq 'FS::tax_rate' ) {
 795       my $taxratelocationnum =
 796         $tax_object->tax_rate_location->taxratelocationnum;
 797       push @{ $tax_rate_location{ $tax }  },
 798         {
 799           'taxnum'             => $tax_object->taxnum,
 800           'taxtype'            => ref($tax_object),
 801           'amount'             => sprintf('%.2f', $amount ),
 802           'locationtaxid'      => $tax_object->location,
 803           'taxratelocationnum' => $taxratelocationnum,
 804         };
 805     }
 806
 807   }
 808
 809   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 810   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 811   foreach my $tax ( keys %$taxlisthash ) {
 812     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 813       next unless ref($_) eq 'FS::cust_bill_pkg';
 814
 815       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 816
 817       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 818       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 819           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 820         unless $packagemap{$_->pkgnum};
 821
 822       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 823            @cust_tax_exempt_pkg;
 824     }
 825   }
 826
 827   #consolidate and create tax line items
 828   warn "consolidating and generating...\n" if $DEBUG > 2;
 829   foreach my $taxname ( keys %taxname ) {
 830     my $tax = 0;
 831     my %seen = ();
 832     my @cust_bill_pkg_tax_location = ();
 833     my @cust_bill_pkg_tax_rate_location = ();
 834     warn "adding $taxname\n" if $DEBUG > 1;
 835     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 836       next if $seen{$taxitem}++;
 837       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 838       $tax += $tax{$taxitem};
 839       push @cust_bill_pkg_tax_location,
 840         map { new FS::cust_bill_pkg_tax_location $_ }
 841             @{ $tax_location{ $taxitem } };
 842       push @cust_bill_pkg_tax_rate_location,
 843         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 844             @{ $tax_rate_location{ $taxitem } };
 845     }
 846     next unless $tax;
 847
 848     $tax = sprintf('%.2f', $tax );
 849
 850     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 851                                                    'disabled'     => '',
 852                                                  },
 853                                );
 854
 855     my @display = ();
 856     if ( $pkg_category and
 857          $conf->config('invoice_latexsummary') ||
 858          $conf->config('invoice_htmlsummary')
 859        )
 860     {
 861
 862       my %hash = (  'section' => $pkg_category->categoryname );
 863       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 864
 865     }
 866
 867     push @tax_line_items, new FS::cust_bill_pkg {
 868       'pkgnum'   => 0,
 869       'setup'    => $tax,
 870       'recur'    => 0,
 871       'sdate'    => '',
 872       'edate'    => '',
 873       'itemdesc' => $taxname,
 874       'display'  => \@display,
 875       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 876       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 877     };
 878
 879   }
 880
 881   \@tax_line_items;
 882 }
 883
 884 sub _make_lines {
 885   my ($self, %params) = @_;
 886
 887   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 888
 889   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 890   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 891   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
 892   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 893   my $total_setup = $params{setup} or die "no setup accumulator specified";
 894   my $total_recur = $params{recur} or die "no recur accumulator specified";
 895   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 896   my $time = $params{'time'} or die "no time specified";
 897   my (%options) = %{$params{options}};
 898
 899   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
 900     # this should never happen
 901     die 'freq_override billing attempted on non-monthly package '.
 902       $cust_pkg->pkgnum;
 903   }
 904
 905   my $dbh = dbh;
 906   my $real_pkgpart = $params{real_pkgpart};
 907   my %hash = $cust_pkg->hash;
 908   my $old_cust_pkg = new FS::cust_pkg \%hash;
 909
 910   my @details = ();
 911   my $lineitems = 0;
 912
 913   $cust_pkg->pkgpart($part_pkg->pkgpart);
 914
 915   ###
 916   # bill setup
 917   ###
 918
 919   my $setup = 0;
 920   my $unitsetup = 0;
 921   my @setup_discounts = ();
 922   my %setup_param = ( 'discounts' => \@setup_discounts );
 923   if (     ! $options{recurring_only}
 924        and ! $options{cancel}
 925        and ( $options{'resetup'}
 926              || ( ! $cust_pkg->setup
 927                   && ( ! $cust_pkg->start_date
 928                        || $cust_pkg->start_date <= day_end($time)
 929                      )
 930                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 931                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 932                             ! $cust_pkg->getfield('susp')
 933                           )
 934                      )
 935                 )
 936            )
 937      )
 938   {
 939
 940     warn "    bill setup\n" if $DEBUG > 1;
 941
 942     unless ( $cust_pkg->waive_setup ) {
 943         $lineitems++;
 944
 945         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
 946         return "$@ running calc_setup for $cust_pkg\n"
 947           if $@;
 948
 949         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 950     }
 951
 952     $cust_pkg->setfield('setup', $time)
 953       unless $cust_pkg->setup;
 954           #do need it, but it won't get written to the db
 955           #|| $cust_pkg->pkgpart != $real_pkgpart;
 956
 957     $cust_pkg->setfield('start_date', '')
 958       if $cust_pkg->start_date;
 959
 960   }
 961
 962   ###
 963   # bill recurring fee
 964   ###
 965
 966   #XXX unit stuff here too
 967   my $recur = 0;
 968   my $unitrecur = 0;
 969   my @recur_discounts = ();
 970   my $sdate;
 971   if (     ! $cust_pkg->start_date
 972        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 973        and
 974             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= day_end($time) )
 975          || ( $part_pkg->plan eq 'voip_cdr'
 976                && $part_pkg->option('bill_every_call')
 977             )
 978          || $options{cancel}
 979   ) {
 980
 981     # XXX should this be a package event?  probably.  events are called
 982     # at collection time at the moment, though...
 983     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 984       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 985       #don't want to reset usage just cause we want a line item??
 986       #&& $part_pkg->pkgpart == $real_pkgpart;
 987
 988     warn "    bill recur\n" if $DEBUG > 1;
 989     $lineitems++;
 990
 991     # XXX shared with $recur_prog
 992     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 993              || $cust_pkg->setup
 994              || $time;
 995
 996     #over two params!  lets at least switch to a hashref for the rest...
 997     my $increment_next_bill = ( $part_pkg->freq ne '0'
 998                                 && ( $cust_pkg->getfield('bill') || 0 ) <= day_end($time)
 999                                 && !$options{cancel}
1000                               );
1001     my %param = ( %setup_param,
1002                   'precommit_hooks'     => $precommit_hooks,
1003                   'increment_next_bill' => $increment_next_bill,
1004                   'discounts'           => \@recur_discounts,
1005                   'real_pkgpart'        => $real_pkgpart,
1006                   'freq_override'       => $options{freq_override} || '',
1007                   'setup_fee'           => 0,
1008                 );
1009
1010     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1011
1012     # There may be some part_pkg for which this is wrong.  Only those
1013     # which can_discount are supported.
1014     # (the UI should prevent adding discounts to these at the moment)
1015
1016     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1017          " for pkgpart ". $cust_pkg->pkgpart.
1018          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1019       if $DEBUG > 2;
1020
1021     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1022     return "$@ running $method for $cust_pkg\n"
1023       if ( $@ );
1024
1025     if ( $increment_next_bill ) {
1026
1027       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1028       return "unparsable frequency: ". $part_pkg->freq
1029         if $next_bill == -1;
1030
1031       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1032       # only for figuring next bill date, nothing else, so, reset $sdate again
1033       # here
1034       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1035       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1036       $cust_pkg->last_bill($sdate);
1037
1038       $cust_pkg->setfield('bill', $next_bill );
1039
1040     }
1041
1042     if ( $param{'setup_fee'} ) {
1043       # Add an additional setup fee at the billing stage.
1044       # Used for prorate_defer_bill.
1045       $setup += $param{'setup_fee'};
1046       $unitsetup += $param{'setup_fee'};
1047       $lineitems++;
1048     }
1049
1050     if ( defined $param{'discount_left_setup'} ) {
1051         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1052             $setup -= $discount_setup;
1053         }
1054     }
1055
1056   }
1057
1058   warn "\$setup is undefined" unless defined($setup);
1059   warn "\$recur is undefined" unless defined($recur);
1060   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1061
1062   ###
1063   # If there's line items, create em cust_bill_pkg records
1064   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1065   ###
1066
1067   if ( $lineitems ) {
1068
1069     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1070       # hmm.. and if just the options are modified in some weird price plan?
1071
1072       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1073         if $DEBUG >1;
1074
1075       my $error = $cust_pkg->replace( $old_cust_pkg,
1076                                       'depend_jobnum'=>$options{depend_jobnum},
1077                                       'options' => { $cust_pkg->options },
1078                                     )
1079         unless $options{no_commit};
1080       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1081         if $error; #just in case
1082     }
1083
1084     $setup = sprintf( "%.2f", $setup );
1085     $recur = sprintf( "%.2f", $recur );
1086     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1087       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1088     }
1089     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1090       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1091     }
1092
1093     my $discount_show_always = $conf->exists('discount-show-always')
1094                                && (    ($setup == 0 && scalar(@setup_discounts))
1095                                     || ($recur == 0 && scalar(@recur_discounts))
1096                                   );
1097
1098     if (    $setup != 0
1099          || $recur != 0
1100          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1101          || $discount_show_always
1102          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1103          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1104        )
1105     {
1106
1107       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1108         if $DEBUG > 1;
1109
1110       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1111       if ( $DEBUG > 1 ) {
1112         warn "      adding customer package invoice detail: $_\n"
1113           foreach @cust_pkg_detail;
1114       }
1115       push @details, @cust_pkg_detail;
1116
1117       my $cust_bill_pkg = new FS::cust_bill_pkg {
1118         'pkgnum'    => $cust_pkg->pkgnum,
1119         'setup'     => $setup,
1120         'unitsetup' => $unitsetup,
1121         'recur'     => $recur,
1122         'unitrecur' => $unitrecur,
1123         'quantity'  => $cust_pkg->quantity,
1124         'details'   => \@details,
1125         'discounts' => [ @setup_discounts, @recur_discounts ],
1126         'hidden'    => $part_pkg->hidden,
1127         'freq'      => $part_pkg->freq,
1128       };
1129
1130       if ( $part_pkg->option('prorate_defer_bill',1)
1131            and !$hash{last_bill} ) {
1132         # both preceding and upcoming, technically
1133         $cust_bill_pkg->sdate( $cust_pkg->setup );
1134         $cust_bill_pkg->edate( $cust_pkg->bill );
1135       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1136         $cust_bill_pkg->sdate( $hash{last_bill} );
1137         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1138         $cust_bill_pkg->edate( $time ) if $options{cancel};
1139       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1140         $cust_bill_pkg->sdate( $sdate );
1141         $cust_bill_pkg->edate( $cust_pkg->bill );
1142         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1143       }
1144
1145       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1146         unless $part_pkg->pkgpart == $real_pkgpart;
1147
1148       $$total_setup += $setup;
1149       $$total_recur += $recur;
1150
1151       ###
1152       # handle taxes
1153       ###
1154
1155       unless ( $discount_show_always ) {
1156           my $error =
1157             $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1158           return $error if $error;
1159       }
1160
1161       push @$cust_bill_pkgs, $cust_bill_pkg;
1162
1163     } #if $setup != 0 || $recur != 0
1164
1165   } #if $line_items
1166
1167   '';
1168
1169 }
1170
1171 sub _handle_taxes {
1172   my $self = shift;
1173   my $part_pkg = shift;
1174   my $taxlisthash = shift;
1175   my $cust_bill_pkg = shift;
1176   my $cust_pkg = shift;
1177   my $invoice_time = shift;
1178   my $real_pkgpart = shift;
1179   my $options = shift;
1180
1181   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1182
1183   my %cust_bill_pkg = ();
1184   my %taxes = ();
1185
1186   my @classes;
1187   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1188   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1189   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1190   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1191
1192   my $exempt = $conf->exists('cust_class-tax_exempt')
1193                  ? ( $self->cust_class ? $self->cust_class->tax : '' )
1194                  : $self->tax;
1195
1196   if ( $exempt !~ /Y/i && $self->payby ne 'COMP' ) {
1197
1198     if ( $conf->exists('enable_taxproducts')
1199          && ( scalar($part_pkg->part_pkg_taxoverride)
1200               || $part_pkg->has_taxproduct
1201             )
1202        )
1203     {
1204
1205       foreach my $class (@classes) {
1206         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1207         return $err_or_ref unless ref($err_or_ref);
1208         $taxes{$class} = $err_or_ref;
1209       }
1210
1211       unless (exists $taxes{''}) {
1212         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1213         return $err_or_ref unless ref($err_or_ref);
1214         $taxes{''} = $err_or_ref;
1215       }
1216
1217     } else {
1218
1219       my @loc_keys = qw( district city county state country );
1220       my $location = $cust_pkg->tax_location;
1221       my %taxhash = map { $_ => $location->$_ } @loc_keys;
1222
1223       $taxhash{'taxclass'} = $part_pkg->taxclass;
1224
1225       my @taxes = (); # entries are cust_main_county objects
1226       my %taxhash_elim = %taxhash;
1227       my @elim = qw( district city county state );
1228       do {
1229
1230         #first try a match with taxclass
1231         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1232
1233         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1234           #then try a match without taxclass
1235           my %no_taxclass = %taxhash_elim;
1236           $no_taxclass{ 'taxclass' } = '';
1237           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1238         }
1239
1240         $taxhash_elim{ shift(@elim) } = '';
1241
1242       } while ( !scalar(@taxes) && scalar(@elim) );
1243
1244       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1245                     @taxes
1246         if $self->cust_main_exemption; #just to be safe
1247
1248       # all packages now have a locationnum and should get a
1249       # cust_bill_pkg_tax_location record.  The tax_locationnum
1250       # may be the package's locationnum, or the customer's bill
1251       # or service location.
1252       foreach (@taxes) {
1253         $_->set('pkgnum',      $cust_pkg->pkgnum);
1254         $_->set('locationnum', $cust_pkg->tax_locationnum);
1255       }
1256
1257       $taxes{''} = [ @taxes ];
1258       $taxes{'setup'} = [ @taxes ];
1259       $taxes{'recur'} = [ @taxes ];
1260       $taxes{$_} = [ @taxes ] foreach (@classes);
1261
1262       # # maybe eliminate this entirely, along with all the 0% records
1263       # unless ( @taxes ) {
1264       #   return
1265       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1266       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1267       # }
1268
1269     } #if $conf->exists('enable_taxproducts') ...
1270
1271   }
1272
1273   #what's this doing in the middle of _handle_taxes?  probably should split
1274   #this into three parts above in _make_lines
1275   $cust_bill_pkg->set_display(   part_pkg     => $part_pkg,
1276                                  real_pkgpart => $real_pkgpart,
1277                              );
1278
1279   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1280   foreach my $key (keys %tax_cust_bill_pkg) {
1281     # $key is "setup", "recur", or a usage class name. ('' is a usage class.)
1282     # $tax_cust_bill_pkg{$key} is a cust_bill_pkg for that component of
1283     # the line item.
1284     # $taxes{$key} is an arrayref of cust_main_county or tax_rate objects that
1285     # apply to $key-class charges.
1286     my @taxes = @{ $taxes{$key} || [] };
1287     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1288
1289     my %localtaxlisthash = ();
1290     foreach my $tax ( @taxes ) {
1291
1292       # this is the tax identifier, not the taxname
1293       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1294 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1295 #                  ' locationnum'. $cust_pkg->locationnum
1296 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1297
1298       # $taxlisthash: keys are "setup", "recur", and usage classes
1299       # values are arrayrefs, first the tax object (cust_main_county
1300       # or tax_rate) and then any cust_bill_pkg objects that the
1301       # tax applies to
1302       $taxlisthash->{ $taxname } ||= [ $tax ];
1303       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1304
1305       $localtaxlisthash{ $taxname } ||= [ $tax ];
1306       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1307
1308     }
1309
1310     warn "finding taxed taxes...\n" if $DEBUG > 2;
1311     foreach my $tax ( keys %localtaxlisthash ) {
1312       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1313       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1314         if $DEBUG > 2;
1315       next unless $tax_object->can('tax_on_tax');
1316
1317       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1318         my $totname = ref( $tot ). ' '. $tot->taxnum;
1319
1320         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1321           if $DEBUG > 2;
1322         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1323                                                              # existing taxes
1324         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1325         my $hashref_or_error =
1326           $tax_object->taxline( $localtaxlisthash{$tax},
1327                                 'custnum'      => $self->custnum,
1328                                 'invoice_time' => $invoice_time,
1329                               );
1330         return $hashref_or_error
1331           unless ref($hashref_or_error);
1332
1333         $taxlisthash->{ $totname } ||= [ $tot ];
1334         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1335
1336       }
1337     }
1338
1339   }
1340
1341   '';
1342 }
1343
1344 sub _gather_taxes {
1345   my $self = shift;
1346   my $part_pkg = shift;
1347   my $class = shift;
1348   my $cust_pkg = shift;
1349
1350   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1351
1352   my $geocode;
1353   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1354     $geocode = $cust_pkg->cust_location->geocode('cch');
1355   } else {
1356     $geocode = $self->geocode('cch');
1357   }
1358
1359   my @taxes = ();
1360
1361   my @taxclassnums = map { $_->taxclassnum }
1362                      $part_pkg->part_pkg_taxoverride($class);
1363
1364   unless (@taxclassnums) {
1365     @taxclassnums = map { $_->taxclassnum }
1366                     grep { $_->taxable eq 'Y' }
1367                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1368   }
1369   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1370     if $DEBUG;
1371
1372   my $extra_sql =
1373     "AND (".
1374     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1375
1376   @taxes = qsearch({ 'table' => 'tax_rate',
1377                      'hashref' => { 'geocode' => $geocode, },
1378                      'extra_sql' => $extra_sql,
1379                   })
1380     if scalar(@taxclassnums);
1381
1382   warn "Found taxes ".
1383        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1384    if $DEBUG;
1385
1386   [ @taxes ];
1387
1388 }
1389
1390 =item collect [ HASHREF | OPTION => VALUE ... ]
1391
1392 (Attempt to) collect money for this customer's outstanding invoices (see
1393 L<FS::cust_bill>).  Usually used after the bill method.
1394
1395 Actions are now triggered by billing events; see L<FS::part_event> and the
1396 billing events web interface.  Old-style invoice events (see
1397 L<FS::part_bill_event>) have been deprecated.
1398
1399 If there is an error, returns the error, otherwise returns false.
1400
1401 Options are passed as name-value pairs.
1402
1403 Currently available options are:
1404
1405 =over 4
1406
1407 =item invoice_time
1408
1409 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1410
1411 =item retry
1412
1413 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1414
1415 =item check_freq
1416
1417 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1418
1419 =item quiet
1420
1421 set true to surpress email card/ACH decline notices.
1422
1423 =item debug
1424
1425 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1426
1427 =back
1428
1429 # =item payby
1430 #
1431 # allows for one time override of normal customer billing method
1432
1433 =cut
1434
1435 sub collect {
1436   my( $self, %options ) = @_;
1437
1438   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1439
1440   my $invoice_time = $options{'invoice_time'} || time;
1441
1442   #put below somehow?
1443   local $SIG{HUP} = 'IGNORE';
1444   local $SIG{INT} = 'IGNORE';
1445   local $SIG{QUIT} = 'IGNORE';
1446   local $SIG{TERM} = 'IGNORE';
1447   local $SIG{TSTP} = 'IGNORE';
1448   local $SIG{PIPE} = 'IGNORE';
1449
1450   my $oldAutoCommit = $FS::UID::AutoCommit;
1451   local $FS::UID::AutoCommit = 0;
1452   my $dbh = dbh;
1453
1454   $self->select_for_update; #mutex
1455
1456   if ( $DEBUG ) {
1457     my $balance = $self->balance;
1458     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1459   }
1460
1461   if ( exists($options{'retry_card'}) ) {
1462     carp 'retry_card option passed to collect is deprecated; use retry';
1463     $options{'retry'} ||= $options{'retry_card'};
1464   }
1465   if ( exists($options{'retry'}) && $options{'retry'} ) {
1466     my $error = $self->retry_realtime;
1467     if ( $error ) {
1468       $dbh->rollback if $oldAutoCommit;
1469       return $error;
1470     }
1471   }
1472
1473   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1474
1475   #never want to roll back an event just because it returned an error
1476   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1477
1478   $self->do_cust_event(
1479     'debug'      => ( $options{'debug'} || 0 ),
1480     'time'       => $invoice_time,
1481     'check_freq' => $options{'check_freq'},
1482     'stage'      => 'collect',
1483   );
1484
1485 }
1486
1487 =item retry_realtime
1488
1489 Schedules realtime / batch  credit card / electronic check / LEC billing
1490 events for for retry.  Useful if card information has changed or manual
1491 retry is desired.  The 'collect' method must be called to actually retry
1492 the transaction.
1493
1494 Implementation details: For either this customer, or for each of this
1495 customer's open invoices, changes the status of the first "done" (with
1496 statustext error) realtime processing event to "failed".
1497
1498 =cut
1499
1500 sub retry_realtime {
1501   my $self = shift;
1502
1503   local $SIG{HUP} = 'IGNORE';
1504   local $SIG{INT} = 'IGNORE';
1505   local $SIG{QUIT} = 'IGNORE';
1506   local $SIG{TERM} = 'IGNORE';
1507   local $SIG{TSTP} = 'IGNORE';
1508   local $SIG{PIPE} = 'IGNORE';
1509
1510   my $oldAutoCommit = $FS::UID::AutoCommit;
1511   local $FS::UID::AutoCommit = 0;
1512   my $dbh = dbh;
1513
1514   #a little false laziness w/due_cust_event (not too bad, really)
1515
1516   my $join = FS::part_event_condition->join_conditions_sql;
1517   my $order = FS::part_event_condition->order_conditions_sql;
1518   my $mine =
1519   '( '
1520    . join ( ' OR ' , map {
1521     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1522     my $custnum = FS::part_event->eventtables_custnum->{$_};
1523     "( part_event.eventtable = " . dbh->quote($_)
1524     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1525     . " from $_ $cust_join"
1526     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1527    } FS::part_event->eventtables)
1528    . ') ';
1529
1530   #here is the agent virtualization
1531   my $agent_virt = " (    part_event.agentnum IS NULL
1532                        OR part_event.agentnum = ". $self->agentnum. ' )';
1533
1534   #XXX this shouldn't be hardcoded, actions should declare it...
1535   my @realtime_events = qw(
1536     cust_bill_realtime_card
1537     cust_bill_realtime_check
1538     cust_bill_realtime_lec
1539     cust_bill_batch
1540   );
1541
1542   my $is_realtime_event =
1543     ' part_event.action IN ( '.
1544         join(',', map "'$_'", @realtime_events ).
1545     ' ) ';
1546
1547   my $batch_or_statustext =
1548     "( part_event.action = 'cust_bill_batch'
1549        OR ( statustext IS NOT NULL AND statustext != '' )
1550      )";
1551
1552
1553   my @cust_event = qsearch({
1554     'table'     => 'cust_event',
1555     'select'    => 'cust_event.*',
1556     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1557     'hashref'   => { 'status' => 'done' },
1558     'extra_sql' => " AND $batch_or_statustext ".
1559                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1560   });
1561
1562   my %seen_invnum = ();
1563   foreach my $cust_event (@cust_event) {
1564
1565     #max one for the customer, one for each open invoice
1566     my $cust_X = $cust_event->cust_X;
1567     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1568                           ? $cust_X->invnum
1569                           : 0
1570                         }++
1571          or $cust_event->part_event->eventtable eq 'cust_bill'
1572             && ! $cust_X->owed;
1573
1574     my $error = $cust_event->retry;
1575     if ( $error ) {
1576       $dbh->rollback if $oldAutoCommit;
1577       return "error scheduling event for retry: $error";
1578     }
1579
1580   }
1581
1582   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1583   '';
1584
1585 }
1586
1587 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1588
1589 Runs billing events; see L<FS::part_event> and the billing events web
1590 interface.
1591
1592 If there is an error, returns the error, otherwise returns false.
1593
1594 Options are passed as name-value pairs.
1595
1596 Currently available options are:
1597
1598 =over 4
1599
1600 =item time
1601
1602 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1603
1604 =item check_freq
1605
1606 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1607
1608 =item stage
1609
1610 "collect" (the default) or "pre-bill"
1611
1612 =item quiet
1613
1614 set true to surpress email card/ACH decline notices.
1615
1616 =item debug
1617
1618 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1619
1620 =back
1621 =cut
1622
1623 # =item payby
1624 #
1625 # allows for one time override of normal customer billing method
1626
1627 # =item retry
1628 #
1629 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1630
1631 sub do_cust_event {
1632   my( $self, %options ) = @_;
1633
1634   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1635
1636   my $time = $options{'time'} || time;
1637
1638   #put below somehow?
1639   local $SIG{HUP} = 'IGNORE';
1640   local $SIG{INT} = 'IGNORE';
1641   local $SIG{QUIT} = 'IGNORE';
1642   local $SIG{TERM} = 'IGNORE';
1643   local $SIG{TSTP} = 'IGNORE';
1644   local $SIG{PIPE} = 'IGNORE';
1645
1646   my $oldAutoCommit = $FS::UID::AutoCommit;
1647   local $FS::UID::AutoCommit = 0;
1648   my $dbh = dbh;
1649
1650   $self->select_for_update; #mutex
1651
1652   if ( $DEBUG ) {
1653     my $balance = $self->balance;
1654     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1655   }
1656
1657 #  if ( exists($options{'retry_card'}) ) {
1658 #    carp 'retry_card option passed to collect is deprecated; use retry';
1659 #    $options{'retry'} ||= $options{'retry_card'};
1660 #  }
1661 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1662 #    my $error = $self->retry_realtime;
1663 #    if ( $error ) {
1664 #      $dbh->rollback if $oldAutoCommit;
1665 #      return $error;
1666 #    }
1667 #  }
1668
1669   # false laziness w/pay_batch::import_results
1670
1671   my $due_cust_event = $self->due_cust_event(
1672     'debug'      => ( $options{'debug'} || 0 ),
1673     'time'       => $time,
1674     'check_freq' => $options{'check_freq'},
1675     'stage'      => ( $options{'stage'} || 'collect' ),
1676   );
1677   unless( ref($due_cust_event) ) {
1678     $dbh->rollback if $oldAutoCommit;
1679     return $due_cust_event;
1680   }
1681
1682   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1683   #never want to roll back an event just because it or a different one
1684   # returned an error
1685   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1686
1687   foreach my $cust_event ( @$due_cust_event ) {
1688
1689     #XXX lock event
1690
1691     #re-eval event conditions (a previous event could have changed things)
1692     unless ( $cust_event->test_conditions ) {
1693       #don't leave stray "new/locked" records around
1694       my $error = $cust_event->delete;
1695       return $error if $error;
1696       next;
1697     }
1698
1699     {
1700       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1701         if $options{'quiet'};
1702       warn "  running cust_event ". $cust_event->eventnum. "\n"
1703         if $DEBUG > 1;
1704
1705       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1706       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1707         #XXX wtf is this?  figure out a proper dealio with return value
1708         #from do_event
1709         return $error;
1710       }
1711     }
1712
1713   }
1714
1715   '';
1716
1717 }
1718
1719 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1720
1721 Inserts database records for and returns an ordered listref of new events due
1722 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1723 events are due, an empty listref is returned.  If there is an error, returns a
1724 scalar error message.
1725
1726 To actually run the events, call each event's test_condition method, and if
1727 still true, call the event's do_event method.
1728
1729 Options are passed as a hashref or as a list of name-value pairs.  Available
1730 options are:
1731
1732 =over 4
1733
1734 =item check_freq
1735
1736 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1737
1738 =item stage
1739
1740 "collect" (the default) or "pre-bill"
1741
1742 =item time
1743
1744 "Current time" for the events.
1745
1746 =item debug
1747
1748 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1749
1750 =item eventtable
1751
1752 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1753
1754 =item objects
1755
1756 Explicitly pass the objects to be tested (typically used with eventtable).
1757
1758 =item testonly
1759
1760 Set to true to return the objects, but not actually insert them into the
1761 database.
1762
1763 =back
1764
1765 =cut
1766
1767 sub due_cust_event {
1768   my $self = shift;
1769   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1770
1771   #???
1772   #my $DEBUG = $opt{'debug'}
1773   local($DEBUG) = $opt{'debug'}
1774     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1775   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1776
1777   warn "$me due_cust_event called with options ".
1778        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1779     if $DEBUG;
1780
1781   $opt{'time'} ||= time;
1782
1783   local $SIG{HUP} = 'IGNORE';
1784   local $SIG{INT} = 'IGNORE';
1785   local $SIG{QUIT} = 'IGNORE';
1786   local $SIG{TERM} = 'IGNORE';
1787   local $SIG{TSTP} = 'IGNORE';
1788   local $SIG{PIPE} = 'IGNORE';
1789
1790   my $oldAutoCommit = $FS::UID::AutoCommit;
1791   local $FS::UID::AutoCommit = 0;
1792   my $dbh = dbh;
1793
1794   $self->select_for_update #mutex
1795     unless $opt{testonly};
1796
1797   ###
1798   # find possible events (initial search)
1799   ###
1800
1801   my @cust_event = ();
1802
1803   my @eventtable = $opt{'eventtable'}
1804                      ? ( $opt{'eventtable'} )
1805                      : FS::part_event->eventtables_runorder;
1806
1807   my $check_freq = $opt{'check_freq'} || '1d';
1808
1809   foreach my $eventtable ( @eventtable ) {
1810
1811     my @objects;
1812     if ( $opt{'objects'} ) {
1813
1814       @objects = @{ $opt{'objects'} };
1815
1816     } elsif ( $eventtable eq 'cust_main' ) {
1817
1818       @objects = ( $self );
1819
1820     } else {
1821
1822       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
1823       # linkage not needed here because FS::cust_main->$eventtable will
1824       # already supply it
1825
1826       #some false laziness w/Cron::bill bill_where
1827
1828       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1829       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1830         'time'=>$opt{'time'},
1831       );
1832       $where = $where ? "AND $where" : '';
1833
1834       my $are_part_event =
1835       "EXISTS ( SELECT 1 FROM part_event $join
1836         WHERE check_freq = '$check_freq'
1837         AND eventtable = '$eventtable'
1838         AND ( disabled = '' OR disabled IS NULL )
1839         $where
1840         )
1841       ";
1842       #eofalse
1843
1844       @objects = $self->$eventtable(
1845         'addl_from' => $cm_join,
1846         'extra_sql' => " AND $are_part_event",
1847       );
1848     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
1849
1850     my @e_cust_event = ();
1851
1852     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
1853
1854     my $cross = "CROSS JOIN $eventtable $linkage";
1855     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1856       unless $eventtable eq 'cust_main';
1857
1858     foreach my $object ( @objects ) {
1859
1860       #this first search uses the condition_sql magic for optimization.
1861       #the more possible events we can eliminate in this step the better
1862
1863       my $cross_where = '';
1864       my $pkey = $object->primary_key;
1865       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1866
1867       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1868       my $extra_sql =
1869         FS::part_event_condition->where_conditions_sql( $eventtable,
1870                                                         'time'=>$opt{'time'}
1871                                                       );
1872       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1873
1874       $extra_sql = "AND $extra_sql" if $extra_sql;
1875
1876       #here is the agent virtualization
1877       $extra_sql .= " AND (    part_event.agentnum IS NULL
1878                             OR part_event.agentnum = ". $self->agentnum. ' )';
1879
1880       $extra_sql .= " $order";
1881
1882       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1883         if $opt{'debug'} > 2;
1884       my @part_event = qsearch( {
1885         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1886         'select'    => 'part_event.*',
1887         'table'     => 'part_event',
1888         'addl_from' => "$cross $join",
1889         'hashref'   => { 'check_freq' => $check_freq,
1890                          'eventtable' => $eventtable,
1891                          'disabled'   => '',
1892                        },
1893         'extra_sql' => "AND $cross_where $extra_sql",
1894       } );
1895
1896       if ( $DEBUG > 2 ) {
1897         my $pkey = $object->primary_key;
1898         warn "      ". scalar(@part_event).
1899              " possible events found for $eventtable ". $object->$pkey(). "\n";
1900       }
1901
1902       push @e_cust_event, map {
1903         $_->new_cust_event($object, 'time' => $opt{'time'})
1904       } @part_event;
1905
1906     }
1907
1908     warn "    ". scalar(@e_cust_event).
1909          " subtotal possible cust events found for $eventtable\n"
1910       if $DEBUG > 1;
1911
1912     push @cust_event, @e_cust_event;
1913
1914   }
1915
1916   warn "  ". scalar(@cust_event).
1917        " total possible cust events found in initial search\n"
1918     if $DEBUG; # > 1;
1919
1920
1921   ##
1922   # test stage
1923   ##
1924
1925   $opt{stage} ||= 'collect';
1926   @cust_event =
1927     grep { my $stage = $_->part_event->event_stage;
1928            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1929          }
1930          @cust_event;
1931
1932   ##
1933   # test conditions
1934   ##
1935
1936   my %unsat = ();
1937
1938   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
1939                      @cust_event;
1940
1941   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1942     if $DEBUG; # > 1;
1943
1944   warn "    invalid conditions not eliminated with condition_sql:\n".
1945        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1946     if keys %unsat && $DEBUG; # > 1;
1947
1948   ##
1949   # insert
1950   ##
1951
1952   unless( $opt{testonly} ) {
1953     foreach my $cust_event ( @cust_event ) {
1954
1955       my $error = $cust_event->insert();
1956       if ( $error ) {
1957         $dbh->rollback if $oldAutoCommit;
1958         return $error;
1959       }
1960
1961     }
1962   }
1963
1964   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1965
1966   ##
1967   # return
1968   ##
1969
1970   warn "  returning events: ". Dumper(@cust_event). "\n"
1971     if $DEBUG > 2;
1972
1973   \@cust_event;
1974
1975 }
1976
1977 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1978
1979 Applies unapplied payments and credits.
1980
1981 In most cases, this new method should be used in place of sequential
1982 apply_payments and apply_credits methods.
1983
1984 A hash of optional arguments may be passed.  Currently "manual" is supported.
1985 If true, a payment receipt is sent instead of a statement when
1986 'payment_receipt_email' configuration option is set.
1987
1988 If there is an error, returns the error, otherwise returns false.
1989
1990 =cut
1991
1992 sub apply_payments_and_credits {
1993   my( $self, %options ) = @_;
1994
1995   local $SIG{HUP} = 'IGNORE';
1996   local $SIG{INT} = 'IGNORE';
1997   local $SIG{QUIT} = 'IGNORE';
1998   local $SIG{TERM} = 'IGNORE';
1999   local $SIG{TSTP} = 'IGNORE';
2000   local $SIG{PIPE} = 'IGNORE';
2001
2002   my $oldAutoCommit = $FS::UID::AutoCommit;
2003   local $FS::UID::AutoCommit = 0;
2004   my $dbh = dbh;
2005
2006   $self->select_for_update; #mutex
2007
2008   foreach my $cust_bill ( $self->open_cust_bill ) {
2009     my $error = $cust_bill->apply_payments_and_credits(%options);
2010     if ( $error ) {
2011       $dbh->rollback if $oldAutoCommit;
2012       return "Error applying: $error";
2013     }
2014   }
2015
2016   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2017   ''; #no error
2018
2019 }
2020
2021 =item apply_credits OPTION => VALUE ...
2022
2023 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2024 to outstanding invoice balances in chronological order (or reverse
2025 chronological order if the I<order> option is set to B<newest>) and returns the
2026 value of any remaining unapplied credits available for refund (see
2027 L<FS::cust_refund>).
2028
2029 Dies if there is an error.
2030
2031 =cut
2032
2033 sub apply_credits {
2034   my $self = shift;
2035   my %opt = @_;
2036
2037   local $SIG{HUP} = 'IGNORE';
2038   local $SIG{INT} = 'IGNORE';
2039   local $SIG{QUIT} = 'IGNORE';
2040   local $SIG{TERM} = 'IGNORE';
2041   local $SIG{TSTP} = 'IGNORE';
2042   local $SIG{PIPE} = 'IGNORE';
2043
2044   my $oldAutoCommit = $FS::UID::AutoCommit;
2045   local $FS::UID::AutoCommit = 0;
2046   my $dbh = dbh;
2047
2048   $self->select_for_update; #mutex
2049
2050   unless ( $self->total_unapplied_credits ) {
2051     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2052     return 0;
2053   }
2054
2055   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2056       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2057
2058   my @invoices = $self->open_cust_bill;
2059   @invoices = sort { $b->_date <=> $a->_date } @invoices
2060     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2061
2062   if ( $conf->exists('pkg-balances') ) {
2063     # limit @credits to those w/ a pkgnum grepped from $self
2064     my %pkgnums = ();
2065     foreach my $i (@invoices) {
2066       foreach my $li ( $i->cust_bill_pkg ) {
2067         $pkgnums{$li->pkgnum} = 1;
2068       }
2069     }
2070     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2071   }
2072
2073   my $credit;
2074
2075   foreach my $cust_bill ( @invoices ) {
2076
2077     if ( !defined($credit) || $credit->credited == 0) {
2078       $credit = pop @credits or last;
2079     }
2080
2081     my $owed;
2082     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2083       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2084     } else {
2085       $owed = $cust_bill->owed;
2086     }
2087     unless ( $owed > 0 ) {
2088       push @credits, $credit;
2089       next;
2090     }
2091
2092     my $amount = min( $credit->credited, $owed );
2093
2094     my $cust_credit_bill = new FS::cust_credit_bill ( {
2095       'crednum' => $credit->crednum,
2096       'invnum'  => $cust_bill->invnum,
2097       'amount'  => $amount,
2098     } );
2099     $cust_credit_bill->pkgnum( $credit->pkgnum )
2100       if $conf->exists('pkg-balances') && $credit->pkgnum;
2101     my $error = $cust_credit_bill->insert;
2102     if ( $error ) {
2103       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2104       die $error;
2105     }
2106
2107     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2108
2109   }
2110
2111   my $total_unapplied_credits = $self->total_unapplied_credits;
2112
2113   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2114
2115   return $total_unapplied_credits;
2116 }
2117
2118 =item apply_payments  [ OPTION => VALUE ... ]
2119
2120 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2121 to outstanding invoice balances in chronological order.
2122
2123  #and returns the value of any remaining unapplied payments.
2124
2125 A hash of optional arguments may be passed.  Currently "manual" is supported.
2126 If true, a payment receipt is sent instead of a statement when
2127 'payment_receipt_email' configuration option is set.
2128
2129 Dies if there is an error.
2130
2131 =cut
2132
2133 sub apply_payments {
2134   my( $self, %options ) = @_;
2135
2136   local $SIG{HUP} = 'IGNORE';
2137   local $SIG{INT} = 'IGNORE';
2138   local $SIG{QUIT} = 'IGNORE';
2139   local $SIG{TERM} = 'IGNORE';
2140   local $SIG{TSTP} = 'IGNORE';
2141   local $SIG{PIPE} = 'IGNORE';
2142
2143   my $oldAutoCommit = $FS::UID::AutoCommit;
2144   local $FS::UID::AutoCommit = 0;
2145   my $dbh = dbh;
2146
2147   $self->select_for_update; #mutex
2148
2149   #return 0 unless
2150
2151   my @payments = sort { $b->_date <=> $a->_date }
2152                  grep { $_->unapplied > 0 }
2153                  $self->cust_pay;
2154
2155   my @invoices = sort { $a->_date <=> $b->_date}
2156                  grep { $_->owed > 0 }
2157                  $self->cust_bill;
2158
2159   if ( $conf->exists('pkg-balances') ) {
2160     # limit @payments to those w/ a pkgnum grepped from $self
2161     my %pkgnums = ();
2162     foreach my $i (@invoices) {
2163       foreach my $li ( $i->cust_bill_pkg ) {
2164         $pkgnums{$li->pkgnum} = 1;
2165       }
2166     }
2167     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2168   }
2169
2170   my $payment;
2171
2172   foreach my $cust_bill ( @invoices ) {
2173
2174     if ( !defined($payment) || $payment->unapplied == 0 ) {
2175       $payment = pop @payments or last;
2176     }
2177
2178     my $owed;
2179     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2180       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2181     } else {
2182       $owed = $cust_bill->owed;
2183     }
2184     unless ( $owed > 0 ) {
2185       push @payments, $payment;
2186       next;
2187     }
2188
2189     my $amount = min( $payment->unapplied, $owed );
2190
2191     my $cbp = {
2192       'paynum' => $payment->paynum,
2193       'invnum' => $cust_bill->invnum,
2194       'amount' => $amount,
2195     };
2196     $cbp->{_date} = $payment->_date
2197         if $options{'manual'} && $options{'backdate_application'};
2198     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2199     $cust_bill_pay->pkgnum( $payment->pkgnum )
2200       if $conf->exists('pkg-balances') && $payment->pkgnum;
2201     my $error = $cust_bill_pay->insert(%options);
2202     if ( $error ) {
2203       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2204       die $error;
2205     }
2206
2207     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2208
2209   }
2210
2211   my $total_unapplied_payments = $self->total_unapplied_payments;
2212
2213   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2214
2215   return $total_unapplied_payments;
2216 }
2217
2218 =back
2219
2220 =head1 FLOW
2221
2222   bill_and_collect
2223
2224     cancel_expired_pkgs
2225     suspend_adjourned_pkgs
2226     unsuspend_resumed_pkgs
2227
2228     bill
2229       (do_cust_event pre-bill)
2230       _make_lines
2231         _handle_taxes
2232           (vendor-only) _gather_taxes
2233       _omit_zero_value_bundles
2234       calculate_taxes
2235
2236     apply_payments_and_credits
2237     collect
2238       do_cust_event
2239         due_cust_event
2240
2241 =head1 BUGS
2242
2243 =head1 SEE ALSO
2244
2245 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2246
2247 =cut
2248
2249 1;