FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24 use FS::cust_event_fee;
  25 use FS::Log;
  26
  27 # 1 is mostly method/subroutine entry and options
  28 # 2 traces progress of some operations
  29 # 3 is even more information including possibly sensitive data
  30 $DEBUG = 0;
  31 $me = '[FS::cust_main::Billing]';
  32
  33 install_callback FS::UID sub {
  34   $conf = new FS::Conf;
  35   #yes, need it for stuff below (prolly should be cached)
  36 };
  37
  38 =head1 NAME
  39
  40 FS::cust_main::Billing - Billing mixin for cust_main
  41
  42 =head1 SYNOPSIS
  43
  44 =head1 DESCRIPTION
  45
  46 These methods are available on FS::cust_main objects.
  47
  48 =head1 METHODS
  49
  50 =over 4
  51
  52 =item bill_and_collect
  53
  54 Cancels and suspends any packages due, generates bills, applies payments and
  55 credits, and applies collection events to run cards, send bills and notices,
  56 etc.
  57
  58 By default, warns on errors and continues with the next operation (but see the
  59 "fatal" flag below).
  60
  61 Options are passed as name-value pairs.  Currently available options are:
  62
  63 =over 4
  64
  65 =item time
  66
  67 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  68
  69  use Date::Parse;
  70  ...
  71  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  72
  73 =item invoice_time
  74
  75 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  76
  77 =item check_freq
  78
  79 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  80
  81 =item resetup
  82
  83 If set true, re-charges setup fees.
  84
  85 =item fatal
  86
  87 If set any errors prevent subsequent operations from continusing.  If set
  88 specifically to "return", returns the error (or false, if there is no error).
  89 Any other true value causes errors to die.
  90
  91 =item debug
  92
  93 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  94
  95 =item job
  96
  97 Optional FS::queue entry to receive status updates.
  98
  99 =back
 100
 101 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 102 options of those methods are also available.
 103
 104 =cut
 105
 106 sub bill_and_collect {
 107   my( $self, %options ) = @_;
 108
 109   my $log = FS::Log->new('bill_and_collect');
 110   $log->debug('start', object => $self, agentnum => $self->agentnum);
 111
 112   my $error;
 113
 114   #$options{actual_time} not $options{time} because freeside-daily -d is for
 115   #pre-printing invoices
 116
 117   $options{'actual_time'} ||= time;
 118   my $job = $options{'job'};
 119
 120   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 121                         ? day_end( $options{actual_time} )
 122                         : $options{actual_time}
 123                     );
 124
 125   $job->update_statustext('0,cleaning expired packages') if $job;
 126   $error = $self->cancel_expired_pkgs( $actual_time );
 127   if ( $error ) {
 128     $error = "Error expiring custnum ". $self->custnum. ": $error";
 129     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 130     elsif ( $options{fatal}                                ) { die    $error; }
 131     else                                                     { warn   $error; }
 132   }
 133
 134   $error = $self->suspend_adjourned_pkgs( $actual_time );
 135   if ( $error ) {
 136     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 137     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 138     elsif ( $options{fatal}                                ) { die    $error; }
 139     else                                                     { warn   $error; }
 140   }
 141
 142   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 143   if ( $error ) {
 144     $error = "Error resuming custnum ".$self->custnum. ": $error";
 145     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 146     elsif ( $options{fatal}                                ) { die    $error; }
 147     else                                                     { warn   $error; }
 148   }
 149
 150   $job->update_statustext('20,billing packages') if $job;
 151   $error = $self->bill( %options );
 152   if ( $error ) {
 153     $error = "Error billing custnum ". $self->custnum. ": $error";
 154     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 155     elsif ( $options{fatal}                                ) { die    $error; }
 156     else                                                     { warn   $error; }
 157   }
 158
 159   $job->update_statustext('50,applying payments and credits') if $job;
 160   $error = $self->apply_payments_and_credits;
 161   if ( $error ) {
 162     $error = "Error applying custnum ". $self->custnum. ": $error";
 163     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 164     elsif ( $options{fatal}                                ) { die    $error; }
 165     else                                                     { warn   $error; }
 166   }
 167
 168   $job->update_statustext('70,running collection events') if $job;
 169   unless ( $conf->exists('cancelled_cust-noevents')
 170            && ! $self->num_ncancelled_pkgs
 171   ) {
 172     $error = $self->collect( %options );
 173     if ( $error ) {
 174       $error = "Error collecting custnum ". $self->custnum. ": $error";
 175       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 176       elsif ($options{fatal}                               ) { die    $error; }
 177       else                                                   { warn   $error; }
 178     }
 179   }
 180   $job->update_statustext('100,finished') if $job;
 181   $log->debug('finish', object => $self, agentnum => $self->agentnum);
 182
 183   '';
 184
 185 }
 186
 187 sub cancel_expired_pkgs {
 188   my ( $self, $time, %options ) = @_;
 189
 190   my @cancel_pkgs = $self->ncancelled_pkgs( {
 191     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 192   } );
 193
 194   my @errors = ();
 195
 196   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 197     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 198     my $error;
 199
 200     if ( $cust_pkg->change_to_pkgnum ) {
 201
 202       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 203       if ( !$new_pkg ) {
 204         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 205                       $cust_pkg->change_to_pkgnum.'; not expiring';
 206         next CUST_PKG;
 207       }
 208       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 209                                   'unprotect_svcs'  => 1 );
 210       $error = '' if ref $error eq 'FS::cust_pkg';
 211
 212     } else { # just cancel it
 213        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 214                                            'reason_otaker' => $cpr->otaker,
 215                                            'time'          => $time,
 216                                          )
 217                                        : ()
 218                                  );
 219     }
 220     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 221   }
 222
 223   join(' / ', @errors);
 224
 225 }
 226
 227 sub suspend_adjourned_pkgs {
 228   my ( $self, $time, %options ) = @_;
 229
 230   my @susp_pkgs = $self->ncancelled_pkgs( {
 231     'extra_sql' =>
 232       " AND ( susp IS NULL OR susp = 0 )
 233         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 234               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 235             )
 236       ",
 237   } );
 238
 239   #only because there's no SQL test for is_prepaid :/
 240   @susp_pkgs =
 241     grep {     (    $_->part_pkg->is_prepaid
 242                  && $_->bill
 243                  && $_->bill < $time
 244                )
 245             || (    $_->adjourn
 246                  && $_->adjourn <= $time
 247                )
 248
 249          }
 250          @susp_pkgs;
 251
 252   my @errors = ();
 253
 254   foreach my $cust_pkg ( @susp_pkgs ) {
 255     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 256       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 257     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 258                                             'reason_otaker' => $cpr->otaker
 259                                           )
 260                                         : ()
 261                                   );
 262     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 263   }
 264
 265   join(' / ', @errors);
 266
 267 }
 268
 269 sub unsuspend_resumed_pkgs {
 270   my ( $self, $time, %options ) = @_;
 271
 272   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 273     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 274   } );
 275
 276   my @errors = ();
 277
 278   foreach my $cust_pkg ( @unsusp_pkgs ) {
 279     my $error = $cust_pkg->unsuspend( 'time' => $time );
 280     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 281   }
 282
 283   join(' / ', @errors);
 284
 285 }
 286
 287 =item bill OPTIONS
 288
 289 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 290 conjunction with the collect method by calling B<bill_and_collect>.
 291
 292 If there is an error, returns the error, otherwise returns false.
 293
 294 Options are passed as name-value pairs.  Currently available options are:
 295
 296 =over 4
 297
 298 =item resetup
 299
 300 If set true, re-charges setup fees.
 301
 302 =item recurring_only
 303
 304 If set true then only bill recurring charges, not setup, usage, one time
 305 charges, etc.
 306
 307 =item freq_override
 308
 309 If set, then override the normal frequency and look for a part_pkg_discount
 310 to take at that frequency.  This is appropriate only when the normal
 311 frequency for all packages is monthly, and is an error otherwise.  Use
 312 C<pkg_list> to limit the set of packages included in billing.
 313
 314 =item time
 315
 316 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 317
 318  use Date::Parse;
 319  ...
 320  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 321
 322 =item pkg_list
 323
 324 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 325
 326  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 327
 328 =item not_pkgpart
 329
 330 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 331
 332 =item no_prepaid
 333
 334 Do not bill prepaid packages.  Used by freeside-daily.
 335
 336 =item invoice_time
 337
 338 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 339
 340 =item cancel
 341
 342 This boolean value informs the us that the package is being cancelled.  This
 343 typically might mean not charging the normal recurring fee but only usage
 344 fees since the last billing. Setup charges may be charged.  Not all package
 345 plans support this feature (they tend to charge 0).
 346
 347 =item no_usage_reset
 348
 349 Prevent the resetting of usage limits during this call.
 350
 351 =item no_commit
 352
 353 Do not save the generated bill in the database.  Useful with return_bill
 354
 355 =item return_bill
 356
 357 A list reference on which the generated bill(s) will be returned.
 358
 359 =item invoice_terms
 360
 361 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 362 terms or the default terms are used.
 363
 364 =back
 365
 366 =cut
 367
 368 sub bill {
 369   my( $self, %options ) = @_;
 370
 371   return '' if $self->payby eq 'COMP';
 372
 373   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 374
 375   warn "$me bill customer ". $self->custnum. "\n"
 376     if $DEBUG;
 377
 378   my $time = $options{'time'} || time;
 379   my $invoice_time = $options{'invoice_time'} || $time;
 380
 381   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 382                      ? day_end( $time )
 383                      : $time
 384                  );
 385
 386   $options{'not_pkgpart'} ||= {};
 387   $options{'not_pkgpart'} = { map { $_ => 1 }
 388                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 389                             }
 390     unless ref($options{'not_pkgpart'});
 391
 392   local $SIG{HUP} = 'IGNORE';
 393   local $SIG{INT} = 'IGNORE';
 394   local $SIG{QUIT} = 'IGNORE';
 395   local $SIG{TERM} = 'IGNORE';
 396   local $SIG{TSTP} = 'IGNORE';
 397   local $SIG{PIPE} = 'IGNORE';
 398
 399   my $oldAutoCommit = $FS::UID::AutoCommit;
 400   local $FS::UID::AutoCommit = 0;
 401   my $dbh = dbh;
 402
 403   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 404     if $DEBUG;
 405
 406   $self->select_for_update; #mutex
 407
 408   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 409     if $DEBUG;
 410
 411   my $error = $self->do_cust_event(
 412     'debug'      => ( $options{'debug'} || 0 ),
 413     'time'       => $invoice_time,
 414     'check_freq' => $options{'check_freq'},
 415     'stage'      => 'pre-bill',
 416   )
 417     unless $options{no_commit};
 418   if ( $error ) {
 419     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 420     return $error;
 421   }
 422
 423   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 424     if $DEBUG;
 425
 426   #keep auto-charge and non-auto-charge line items separate
 427   my @passes = ( '', 'no_auto' );
 428
 429   my %cust_bill_pkg = map { $_ => [] } @passes;
 430
 431   ###
 432   # find the packages which are due for billing, find out how much they are
 433   # & generate invoice database.
 434   ###
 435
 436   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 437   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 438
 439   my %taxlisthash = map { $_ => {} } @passes;
 440
 441   my @precommit_hooks = ();
 442
 443   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 444
 445   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 446
 447     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 448
 449     my $part_pkg = $cust_pkg->part_pkg;
 450
 451     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 452
 453     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 454
 455     #? to avoid use of uninitialized value errors... ?
 456     $cust_pkg->setfield('bill', '')
 457       unless defined($cust_pkg->bill);
 458
 459     my $real_pkgpart = $cust_pkg->pkgpart;
 460     my %hash = $cust_pkg->hash;
 461
 462     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 463     # suffer from performance issues
 464     $options{has_hidden} = 0;
 465     my @part_pkg = $part_pkg->self_and_bill_linked;
 466     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 467
 468     # if this package was changed from another package,
 469     # and it hasn't been billed since then,
 470     # and package balances are enabled,
 471     if ( $cust_pkg->change_pkgnum
 472         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 473         and $cust_pkg->change_date <  $invoice_time
 474       and $conf->exists('pkg-balances') )
 475     {
 476       # _transfer_balance will also create the appropriate credit
 477       my @transfer_items = $self->_transfer_balance($cust_pkg);
 478       # $part_pkg[0] is the "real" part_pkg
 479       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 480                   'no_auto' : '';
 481       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 482       # treating this as recur, just because most charges are recur...
 483       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 484     }
 485
 486     foreach my $part_pkg ( @part_pkg ) {
 487
 488       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 489
 490       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 491
 492       my $next_bill = $cust_pkg->getfield('bill') || 0;
 493       my $error;
 494       # let this run once if this is the last bill upon cancellation
 495       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 496         $error =
 497           $self->_make_lines( 'part_pkg'            => $part_pkg,
 498                               'cust_pkg'            => $cust_pkg,
 499                               'precommit_hooks'     => \@precommit_hooks,
 500                               'line_items'          => $cust_bill_pkg{$pass},
 501                               'setup'               => $total_setup{$pass},
 502                               'recur'               => $total_recur{$pass},
 503                               'tax_matrix'          => $taxlisthash{$pass},
 504                               'time'                => $time,
 505                               'real_pkgpart'        => $real_pkgpart,
 506                               'options'             => \%options,
 507                             );
 508
 509         # Stop if anything goes wrong
 510         last if $error;
 511
 512         # or if we're not incrementing the bill date.
 513         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 514
 515         # or if we're letting it run only once
 516         last if $options{cancel};
 517
 518         $next_bill = $cust_pkg->getfield('bill') || 0;
 519
 520         #stop if -o was passed to freeside-daily
 521         last if $options{'one_recur'};
 522       }
 523       if ($error) {
 524         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 525         return $error;
 526       }
 527
 528     } #foreach my $part_pkg
 529
 530   } #foreach my $cust_pkg
 531
 532   #if the customer isn't on an automatic payby, everything can go on a single
 533   #invoice anyway?
 534   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 535     #merge everything into one list
 536   #}
 537
 538   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 539
 540     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 541
 542     warn "$me billing pass $pass\n"
 543            #.Dumper(\@cust_bill_pkg)."\n"
 544       if $DEBUG > 2;
 545
 546     ###
 547     # process fees
 548     ###
 549
 550     my @pending_event_fees = FS::cust_event_fee->by_cust($self->custnum,
 551       hashref => { 'billpkgnum' => '' }
 552     );
 553     warn "$me found pending fee events:\n".Dumper(\@pending_event_fees)."\n"
 554       if @pending_event_fees and $DEBUG > 1;
 555
 556     # determine whether to generate an invoice
 557     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 558
 559     foreach my $event_fee (@pending_event_fees) {
 560       $generate_bill = 1 unless $event_fee->nextbill;
 561     }
 562
 563     # don't create an invoice with no line items, or where the only line
 564     # items are fees that are supposed to be held until the next invoice
 565     next if !$generate_bill;
 566
 567     # calculate fees...
 568     my @fee_items;
 569     foreach my $event_fee (@pending_event_fees) {
 570       my $object = $event_fee->cust_event->cust_X;
 571       my $part_fee = $event_fee->part_fee;
 572       my $cust_bill;
 573       if ( $object->isa('FS::cust_main')
 574            or $object->isa('FS::cust_pkg')
 575            or $object->isa('FS::cust_pay_batch') )
 576       {
 577         # Not the real cust_bill object that will be inserted--in particular
 578         # there are no taxes yet.  If you want to charge a fee on the total
 579         # invoice amount including taxes, you have to put the fee on the next
 580         # invoice.
 581         $cust_bill = FS::cust_bill->new({
 582             'custnum'       => $self->custnum,
 583             'cust_bill_pkg' => \@cust_bill_pkg,
 584             'charged'       => ${ $total_setup{$pass} } +
 585                                ${ $total_recur{$pass} },
 586         });
 587
 588         # If this is a package event, only apply the fee to line items
 589         # from that package.
 590         if ($object->isa('FS::cust_pkg')) {
 591           $cust_bill->set('cust_bill_pkg',
 592             [ grep  { $_->pkgnum == $object->pkgnum } @cust_bill_pkg ]
 593           );
 594         }
 595
 596       } elsif ( $object->isa('FS::cust_bill') ) {
 597         # simple case: applying the fee to a previous invoice (late fee,
 598         # etc.)
 599         $cust_bill = $object;
 600       }
 601       # if the fee def belongs to a different agent, don't charge the fee.
 602       # event conditions should prevent this, but just in case they don't,
 603       # skip the fee.
 604       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 605         warn "tried to charge fee#".$part_fee->feepart .
 606              " on customer#".$self->custnum." from a different agent.\n";
 607         next;
 608       }
 609       # also skip if it's disabled
 610       next if $part_fee->disabled eq 'Y';
 611       # calculate the fee
 612       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 613       # link this so that we can clear the marker on inserting the line item
 614       $fee_item->set('cust_event_fee', $event_fee);
 615       push @fee_items, $fee_item;
 616
 617     }
 618
 619     # add fees to the invoice
 620     foreach my $fee_item (@fee_items) {
 621
 622       push @cust_bill_pkg, $fee_item;
 623       ${ $total_setup{$pass} } += $fee_item->setup;
 624       ${ $total_recur{$pass} } += $fee_item->recur;
 625
 626       my $part_fee = $fee_item->part_fee;
 627       my $fee_location = $self->ship_location; # I think?
 628
 629       my $error = $self->_handle_taxes(
 630         $taxlisthash{$pass},
 631         $fee_item,
 632         location => $fee_location
 633         # probably not right to pass cancel => 1 for fees
 634       );
 635       return $error if $error;
 636
 637     }
 638
 639     # XXX implementation of fees is supposed to make this go away...
 640     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 641            !$conf->exists('postal_invoice-recurring_only')
 642        )
 643     {
 644
 645       my $postal_pkg = $self->charge_postal_fee();
 646       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 647
 648         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 649         return "can't charge postal invoice fee for customer ".
 650           $self->custnum. ": $postal_pkg";
 651
 652       } elsif ( $postal_pkg ) {
 653
 654         my $real_pkgpart = $postal_pkg->pkgpart;
 655         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 656         # suffer from performance issues
 657         $options{has_hidden} = 0;
 658         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 659         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 660
 661         foreach my $part_pkg ( @part_pkg ) {
 662           my %postal_options = %options;
 663           delete $postal_options{cancel};
 664           my $error =
 665             $self->_make_lines( 'part_pkg'            => $part_pkg,
 666                                 'cust_pkg'            => $postal_pkg,
 667                                 'precommit_hooks'     => \@precommit_hooks,
 668                                 'line_items'          => \@cust_bill_pkg,
 669                                 'setup'               => $total_setup{$pass},
 670                                 'recur'               => $total_recur{$pass},
 671                                 'tax_matrix'          => $taxlisthash{$pass},
 672                                 'time'                => $time,
 673                                 'real_pkgpart'        => $real_pkgpart,
 674                                 'options'             => \%postal_options,
 675                               );
 676           if ($error) {
 677             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 678             return $error;
 679           }
 680         }
 681
 682         # it's silly to have a zero value postal_pkg, but....
 683         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 684
 685       }
 686
 687     }
 688
 689     my $listref_or_error =
 690       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 691
 692     unless ( ref( $listref_or_error ) ) {
 693       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 694       return $listref_or_error;
 695     }
 696
 697     foreach my $taxline ( @$listref_or_error ) {
 698       ${ $total_setup{$pass} } =
 699         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 700       push @cust_bill_pkg, $taxline;
 701     }
 702
 703     #add tax adjustments
 704     warn "adding tax adjustments...\n" if $DEBUG > 2;
 705     foreach my $cust_tax_adjustment (
 706       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 707                                        'billpkgnum' => '',
 708                                      }
 709              )
 710     ) {
 711
 712       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 713
 714       my $itemdesc = $cust_tax_adjustment->taxname;
 715       $itemdesc = '' if $itemdesc eq 'Tax';
 716
 717       push @cust_bill_pkg, new FS::cust_bill_pkg {
 718         'pkgnum'      => 0,
 719         'setup'       => $tax,
 720         'recur'       => 0,
 721         'sdate'       => '',
 722         'edate'       => '',
 723         'itemdesc'    => $itemdesc,
 724         'itemcomment' => $cust_tax_adjustment->comment,
 725         'cust_tax_adjustment' => $cust_tax_adjustment,
 726         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 727       };
 728
 729     }
 730
 731     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 732
 733     my @cust_bill = $self->cust_bill;
 734     my $balance = $self->balance;
 735     my $previous_bill = $cust_bill[-1] if @cust_bill;
 736     my $previous_balance = 0;
 737     if ( $previous_bill ) {
 738       $previous_balance = $previous_bill->billing_balance
 739                         + $previous_bill->charged;
 740     }
 741
 742     warn "creating the new invoice\n" if $DEBUG;
 743     #create the new invoice
 744     my $cust_bill = new FS::cust_bill ( {
 745       'custnum'             => $self->custnum,
 746       '_date'               => $invoice_time,
 747       'charged'             => $charged,
 748       'billing_balance'     => $balance,
 749       'previous_balance'    => $previous_balance,
 750       'invoice_terms'       => $options{'invoice_terms'},
 751       'cust_bill_pkg'       => \@cust_bill_pkg,
 752     } );
 753     $error = $cust_bill->insert unless $options{no_commit};
 754     if ( $error ) {
 755       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 756       return "can't create invoice for customer #". $self->custnum. ": $error";
 757     }
 758     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 759
 760   } #foreach my $pass ( keys %cust_bill_pkg )
 761
 762   foreach my $hook ( @precommit_hooks ) {
 763     eval {
 764       &{$hook}; #($self) ?
 765     } unless $options{no_commit};
 766     if ( $@ ) {
 767       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 768       return "$@ running precommit hook $hook\n";
 769     }
 770   }
 771
 772   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 773
 774   ''; #no error
 775 }
 776
 777 #discard bundled packages of 0 value
 778 sub _omit_zero_value_bundles {
 779   my @in = @_;
 780
 781   my @cust_bill_pkg = ();
 782   my @cust_bill_pkg_bundle = ();
 783   my $sum = 0;
 784   my $discount_show_always = 0;
 785
 786   foreach my $cust_bill_pkg ( @in ) {
 787
 788     $discount_show_always = ($cust_bill_pkg->get('discounts')
 789                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 790                                 && $conf->exists('discount-show-always'));
 791
 792     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 793          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 794          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 795       if $DEBUG > 0;
 796
 797     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 798       push @cust_bill_pkg, @cust_bill_pkg_bundle
 799         if $sum > 0
 800         || ($sum == 0 && (    $discount_show_always
 801                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 802                                    @cust_bill_pkg_bundle
 803                          )
 804            );
 805       @cust_bill_pkg_bundle = ();
 806       $sum = 0;
 807     }
 808
 809     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 810     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 811
 812   }
 813
 814   push @cust_bill_pkg, @cust_bill_pkg_bundle
 815     if $sum > 0
 816     || ($sum == 0 && (    $discount_show_always
 817                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 818                                @cust_bill_pkg_bundle
 819                      )
 820        );
 821
 822   warn "  _omit_zero_value_bundles: ". scalar(@in).
 823        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 824     if $DEBUG > 2;
 825
 826   (@cust_bill_pkg);
 827
 828 }
 829
 830 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 831
 832 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 833 Usually used internally by bill method B<bill>.
 834
 835 If there is an error, returns the error, otherwise returns reference to a
 836 list of line items suitable for insertion.
 837
 838 =over 4
 839
 840 =item LINEITEMREF
 841
 842 An array ref of the line items being billed.
 843
 844 =item TAXHASHREF
 845
 846 A strange beast.  The keys to this hash are internal identifiers consisting
 847 of the name of the tax object type, a space, and its unique identifier ( e.g.
 848  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 849 item in the list is the tax object.  The remaining items are either line
 850 items or floating point values (currency amounts).
 851
 852 The taxes are calculated on this entity.  Calculated exemption records are
 853 transferred to the LINEITEMREF items on the assumption that they are related.
 854
 855 Read the source.
 856
 857 =item INVOICE_TIME
 858
 859 This specifies the date appearing on the associated invoice.  Some
 860 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 861
 862 =back
 863
 864 =cut
 865
 866 sub calculate_taxes {
 867   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 868
 869   # $taxlisthash is a hashref
 870   # keys are identifiers, values are arrayrefs
 871   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 872   # then any cust_bill_pkg objects the tax applies to
 873
 874   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 875
 876   warn "$me calculate_taxes\n"
 877        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 878     if $DEBUG > 2;
 879
 880   my @tax_line_items = ();
 881
 882   # keys are tax names (as printed on invoices / itemdesc )
 883   # values are arrayrefs of taxlisthash keys (internal identifiers)
 884   my %taxname = ();
 885
 886   # keys are taxlisthash keys (internal identifiers)
 887   # values are (cumulative) amounts
 888   my %tax_amount = ();
 889
 890   # keys are taxlisthash keys (internal identifiers)
 891   # values are arrayrefs of cust_bill_pkg_tax_location hashrefs
 892   my %tax_location = ();
 893
 894   # keys are taxlisthash keys (internal identifiers)
 895   # values are arrayrefs of cust_bill_pkg_tax_rate_location hashrefs
 896   my %tax_rate_location = ();
 897
 898   # keys are taxlisthash keys (internal identifiers!)
 899   # values are arrayrefs of cust_tax_exempt_pkg objects
 900   my %tax_exemption;
 901
 902   foreach my $tax ( keys %$taxlisthash ) {
 903     # $tax is a tax identifier (intersection of a tax definition record
 904     # and a cust_bill_pkg record)
 905     my $tax_object = shift @{ $taxlisthash->{$tax} };
 906     # $tax_object is a cust_main_county or tax_rate
 907     # (with billpkgnum, pkgnum, locationnum set)
 908     # the rest of @{ $taxlisthash->{$tax} } is cust_bill_pkg component objects
 909     # (setup, recurring, usage classes)
 910     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 911     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 912     # taxline calculates the tax on all cust_bill_pkgs in the
 913     # first (arrayref) argument, and returns a hashref of 'name'
 914     # (the line item description) and 'amount'.
 915     # It also calculates exemptions and attaches them to the cust_bill_pkgs
 916     # in the argument.
 917     my $taxables = $taxlisthash->{$tax};
 918     my $exemptions = $tax_exemption{$tax} ||= [];
 919     my $taxline = $tax_object->taxline(
 920                             $taxables,
 921                             'custnum'      => $self->custnum,
 922                             'invoice_time' => $invoice_time,
 923                             'exemptions'   => $exemptions,
 924                           );
 925     return $taxline unless ref($taxline);
 926
 927     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 928
 929     if ( $tax_object->isa('FS::cust_main_county') ) {
 930       # then $taxline is a real line item
 931       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 932
 933     } else {
 934       # leave this as is for now
 935
 936       my $name   = $taxline->{'name'};
 937       my $amount = $taxline->{'amount'};
 938
 939       #warn "adding $amount as $name\n";
 940       $taxname{ $name } ||= [];
 941       push @{ $taxname{ $name } }, $tax;
 942
 943       $tax_amount{ $tax } += $amount;
 944
 945       # link records between cust_main_county/tax_rate and cust_location
 946       $tax_rate_location{ $tax } ||= [];
 947       my $taxratelocationnum =
 948         $tax_object->tax_rate_location->taxratelocationnum;
 949       push @{ $tax_rate_location{ $tax }  },
 950         {
 951           'taxnum'             => $tax_object->taxnum,
 952           'taxtype'            => ref($tax_object),
 953           'amount'             => sprintf('%.2f', $amount ),
 954           'locationtaxid'      => $tax_object->location,
 955           'taxratelocationnum' => $taxratelocationnum,
 956         };
 957     } #if ref($tax_object)...
 958   } #foreach keys %$taxlisthash
 959
 960   #consolidate and create tax line items
 961   warn "consolidating and generating...\n" if $DEBUG > 2;
 962   foreach my $taxname ( keys %taxname ) {
 963     my @cust_bill_pkg_tax_location;
 964     my @cust_bill_pkg_tax_rate_location;
 965     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
 966         'pkgnum'    => 0,
 967         'recur'     => 0,
 968         'sdate'     => '',
 969         'edate'     => '',
 970         'itemdesc'  => $taxname,
 971         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
 972         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 973     });
 974
 975     my $tax_total = 0;
 976     my %seen = ();
 977     warn "adding $taxname\n" if $DEBUG > 1;
 978     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 979       if ( ref($taxitem) eq 'FS::cust_bill_pkg' ) {
 980         # then we need to transfer the amount and the links from the
 981         # line item to the new one we're creating.
 982         $tax_total += $taxitem->setup;
 983         foreach my $link ( @{ $taxitem->get('cust_bill_pkg_tax_location') } ) {
 984           $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
 985           push @cust_bill_pkg_tax_location, $link;
 986         }
 987       } else {
 988         # the tax_rate way
 989         next if $seen{$taxitem}++;
 990         warn "adding $tax_amount{$taxitem}\n" if $DEBUG > 1;
 991         $tax_total += $tax_amount{$taxitem};
 992         push @cust_bill_pkg_tax_rate_location,
 993           map { new FS::cust_bill_pkg_tax_rate_location $_ }
 994               @{ $tax_rate_location{ $taxitem } };
 995       }
 996     }
 997     next unless $tax_total;
 998
 999     # we should really neverround this up...I guess it's okay if taxline
1000     # already returns amounts with 2 decimal places
1001     $tax_total = sprintf('%.2f', $tax_total );
1002     $tax_cust_bill_pkg->set('setup', $tax_total);
1003
1004     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1005                                                    'disabled'     => '',
1006                                                  },
1007                                );
1008
1009     my @display = ();
1010     if ( $pkg_category and
1011          $conf->config('invoice_latexsummary') ||
1012          $conf->config('invoice_htmlsummary')
1013        )
1014     {
1015
1016       my %hash = (  'section' => $pkg_category->categoryname );
1017       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1018
1019     }
1020     $tax_cust_bill_pkg->set('display', \@display);
1021
1022     push @tax_line_items, $tax_cust_bill_pkg;
1023   }
1024
1025   \@tax_line_items;
1026 }
1027
1028 sub _make_lines {
1029   my ($self, %params) = @_;
1030
1031   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1032
1033   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1034   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1035   my $cust_location = $cust_pkg->tax_location;
1036   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1037   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1038   my $total_setup = $params{setup} or die "no setup accumulator specified";
1039   my $total_recur = $params{recur} or die "no recur accumulator specified";
1040   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1041   my $time = $params{'time'} or die "no time specified";
1042   my (%options) = %{$params{options}};
1043
1044   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1045     # this should never happen
1046     die 'freq_override billing attempted on non-monthly package '.
1047       $cust_pkg->pkgnum;
1048   }
1049
1050   my $dbh = dbh;
1051   my $real_pkgpart = $params{real_pkgpart};
1052   my %hash = $cust_pkg->hash;
1053   my $old_cust_pkg = new FS::cust_pkg \%hash;
1054
1055   my @details = ();
1056   my $lineitems = 0;
1057
1058   $cust_pkg->pkgpart($part_pkg->pkgpart);
1059
1060   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1061                      ? day_end( $time )
1062                      : $time
1063                  );
1064
1065   ###
1066   # bill setup
1067   ###
1068
1069   my $setup = 0;
1070   my $unitsetup = 0;
1071   my @setup_discounts = ();
1072   my %setup_param = ( 'discounts' => \@setup_discounts );
1073   my $setup_billed_currency = '';
1074   my $setup_billed_amount = 0;
1075   if (     ! $options{recurring_only}
1076        and ! $options{cancel}
1077        and ( $options{'resetup'}
1078              || ( ! $cust_pkg->setup
1079                   && ( ! $cust_pkg->start_date
1080                        || $cust_pkg->start_date <= $cmp_time
1081                      )
1082                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
1083                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
1084                             ! $cust_pkg->getfield('susp')
1085                           )
1086                      )
1087                 )
1088            )
1089      )
1090   {
1091
1092     warn "    bill setup\n" if $DEBUG > 1;
1093
1094     unless ( $cust_pkg->waive_setup ) {
1095         $lineitems++;
1096
1097         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1098         return "$@ running calc_setup for $cust_pkg\n"
1099           if $@;
1100
1101         $unitsetup = $cust_pkg->base_setup()
1102                        || $setup; #XXX uuh
1103
1104         if ( $setup_param{'billed_currency'} ) {
1105           $setup_billed_currency = delete $setup_param{'billed_currency'};
1106           $setup_billed_amount   = delete $setup_param{'billed_amount'};
1107         }
1108     }
1109
1110     $cust_pkg->setfield('setup', $time)
1111       unless $cust_pkg->setup;
1112           #do need it, but it won't get written to the db
1113           #|| $cust_pkg->pkgpart != $real_pkgpart;
1114
1115     $cust_pkg->setfield('start_date', '')
1116       if $cust_pkg->start_date;
1117
1118   }
1119
1120   ###
1121   # bill recurring fee
1122   ###
1123
1124   my $recur = 0;
1125   my $unitrecur = 0;
1126   my @recur_discounts = ();
1127   my $recur_billed_currency = '';
1128   my $recur_billed_amount = 0;
1129   my $sdate;
1130   if (     ! $cust_pkg->start_date
1131        and
1132            ( ! $cust_pkg->susp
1133                || ( $cust_pkg->susp != $cust_pkg->order_date
1134                       && (    $cust_pkg->option('suspend_bill',1)
1135                            || ( $part_pkg->option('suspend_bill', 1)
1136                                  && ! $cust_pkg->option('no_suspend_bill',1)
1137                               )
1138                          )
1139                   )
1140            )
1141        and
1142             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1143          || ( $part_pkg->plan eq 'voip_cdr'
1144                && $part_pkg->option('bill_every_call')
1145             )
1146          || $options{cancel}
1147   ) {
1148
1149     # XXX should this be a package event?  probably.  events are called
1150     # at collection time at the moment, though...
1151     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1152       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1153       #don't want to reset usage just cause we want a line item??
1154       #&& $part_pkg->pkgpart == $real_pkgpart;
1155
1156     warn "    bill recur\n" if $DEBUG > 1;
1157     $lineitems++;
1158
1159     # XXX shared with $recur_prog
1160     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1161              || $cust_pkg->setup
1162              || $time;
1163
1164     #over two params!  lets at least switch to a hashref for the rest...
1165     my $increment_next_bill = ( $part_pkg->freq ne '0'
1166                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1167                                 && !$options{cancel}
1168                               );
1169     my %param = ( %setup_param,
1170                   'precommit_hooks'     => $precommit_hooks,
1171                   'increment_next_bill' => $increment_next_bill,
1172                   'discounts'           => \@recur_discounts,
1173                   'real_pkgpart'        => $real_pkgpart,
1174                   'freq_override'       => $options{freq_override} || '',
1175                   'setup_fee'           => 0,
1176                 );
1177
1178     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1179
1180     # There may be some part_pkg for which this is wrong.  Only those
1181     # which can_discount are supported.
1182     # (the UI should prevent adding discounts to these at the moment)
1183
1184     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1185          " for pkgpart ". $cust_pkg->pkgpart.
1186          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1187       if $DEBUG > 2;
1188
1189     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1190     return "$@ running $method for $cust_pkg\n"
1191       if ( $@ );
1192
1193     #base_cancel???
1194     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1195
1196     if ( $param{'billed_currency'} ) {
1197       $recur_billed_currency = delete $param{'billed_currency'};
1198       $recur_billed_amount   = delete $param{'billed_amount'};
1199     }
1200
1201     if ( $increment_next_bill ) {
1202
1203       my $next_bill;
1204
1205       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1206         # supplemental package
1207         # to keep in sync with the main package, simulate billing at
1208         # its frequency
1209         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1210         my $supp_pkg_freq = $part_pkg->freq;
1211         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1212         if ( $ratio != int($ratio) ) {
1213           # the UI should prevent setting up packages like this, but just
1214           # in case
1215           return "supplemental package period is not an integer multiple of main  package period";
1216         }
1217         $next_bill = $sdate;
1218         for (1..$ratio) {
1219           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1220         }
1221
1222       } else {
1223         # the normal case
1224       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1225       return "unparsable frequency: ". $part_pkg->freq
1226         if $next_bill == -1;
1227       }
1228
1229       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1230       # only for figuring next bill date, nothing else, so, reset $sdate again
1231       # here
1232       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1233       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1234       $cust_pkg->last_bill($sdate);
1235
1236       $cust_pkg->setfield('bill', $next_bill );
1237
1238     }
1239
1240     if ( $param{'setup_fee'} ) {
1241       # Add an additional setup fee at the billing stage.
1242       # Used for prorate_defer_bill.
1243       $setup += $param{'setup_fee'};
1244       $unitsetup += $param{'setup_fee'};
1245       $lineitems++;
1246     }
1247
1248     if ( defined $param{'discount_left_setup'} ) {
1249         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1250             $setup -= $discount_setup;
1251         }
1252     }
1253
1254   }
1255
1256   warn "\$setup is undefined" unless defined($setup);
1257   warn "\$recur is undefined" unless defined($recur);
1258   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1259
1260   ###
1261   # If there's line items, create em cust_bill_pkg records
1262   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1263   ###
1264
1265   if ( $lineitems ) {
1266
1267     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1268       # hmm.. and if just the options are modified in some weird price plan?
1269
1270       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1271         if $DEBUG >1;
1272
1273       my $error = $cust_pkg->replace( $old_cust_pkg,
1274                                       'depend_jobnum'=>$options{depend_jobnum},
1275                                       'options' => { $cust_pkg->options },
1276                                     )
1277         unless $options{no_commit};
1278       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1279         if $error; #just in case
1280     }
1281
1282     $setup = sprintf( "%.2f", $setup );
1283     $recur = sprintf( "%.2f", $recur );
1284     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1285       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1286     }
1287     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1288       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1289     }
1290
1291     my $discount_show_always = $conf->exists('discount-show-always')
1292                                && (    ($setup == 0 && scalar(@setup_discounts))
1293                                     || ($recur == 0 && scalar(@recur_discounts))
1294                                   );
1295
1296     if (    $setup != 0
1297          || $recur != 0
1298          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1299          || $discount_show_always
1300          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1301          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1302        )
1303     {
1304
1305       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1306         if $DEBUG > 1;
1307
1308       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1309       if ( $DEBUG > 1 ) {
1310         warn "      adding customer package invoice detail: $_\n"
1311           foreach @cust_pkg_detail;
1312       }
1313       push @details, @cust_pkg_detail;
1314
1315       my $cust_bill_pkg = new FS::cust_bill_pkg {
1316         'pkgnum'                => $cust_pkg->pkgnum,
1317         'setup'                 => $setup,
1318         'unitsetup'             => $unitsetup,
1319         'setup_billed_currency' => $setup_billed_currency,
1320         'setup_billed_amount'   => $setup_billed_amount,
1321         'recur'                 => $recur,
1322         'unitrecur'             => $unitrecur,
1323         'recur_billed_currency' => $recur_billed_currency,
1324         'recur_billed_amount'   => $recur_billed_amount,
1325         'quantity'              => $cust_pkg->quantity,
1326         'details'               => \@details,
1327         'discounts'             => [ @setup_discounts, @recur_discounts ],
1328         'hidden'                => $part_pkg->hidden,
1329         'freq'                  => $part_pkg->freq,
1330       };
1331
1332       if ( $part_pkg->option('prorate_defer_bill',1)
1333            and !$hash{last_bill} ) {
1334         # both preceding and upcoming, technically
1335         $cust_bill_pkg->sdate( $cust_pkg->setup );
1336         $cust_bill_pkg->edate( $cust_pkg->bill );
1337       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1338         $cust_bill_pkg->sdate( $hash{last_bill} );
1339         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1340         $cust_bill_pkg->edate( $time ) if $options{cancel};
1341       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' )
1342         $cust_bill_pkg->sdate( $sdate );
1343         $cust_bill_pkg->edate( $cust_pkg->bill );
1344         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1345       }
1346
1347       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1348         unless $part_pkg->pkgpart == $real_pkgpart;
1349
1350       $$total_setup += $setup;
1351       $$total_recur += $recur;
1352
1353       ###
1354       # handle taxes
1355       ###
1356
1357       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1358         cancel => $options{cancel} );
1359       return $error if $error;
1360
1361       $cust_bill_pkg->set_display(
1362         part_pkg     => $part_pkg,
1363         real_pkgpart => $real_pkgpart,
1364       );
1365
1366       push @$cust_bill_pkgs, $cust_bill_pkg;
1367
1368     } #if $setup != 0 || $recur != 0
1369
1370   } #if $line_items
1371
1372   '';
1373
1374 }
1375
1376 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1377
1378 Takes one argument, a cust_pkg object that is being billed.  This will
1379 be called only if the package was created by a package change, and has
1380 not been billed since the package change, and package balance tracking
1381 is enabled.  The second argument can be an alternate package number to
1382 transfer the balance from; this should not be used externally.
1383
1384 Transfers the balance from the previous package (now canceled) to
1385 this package, by crediting one package and creating an invoice item for
1386 the other.  Inserts the credit and returns the invoice item (so that it
1387 can be added to an invoice that's being built).
1388
1389 If the previous package was never billed, and was also created by a package
1390 change, then this will also transfer the balance from I<its> previous
1391 package, and so on, until reaching a package that either has been billed
1392 or was not created by a package change.
1393
1394 =cut
1395
1396 my $balance_transfer_reason;
1397
1398 sub _transfer_balance {
1399   my $self = shift;
1400   my $cust_pkg = shift;
1401   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1402   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1403
1404   my @transfers;
1405
1406   # if $from_pkg is not the first package in the chain, and it was never
1407   # billed, walk back
1408   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1409     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1410   }
1411
1412   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1413   if ( $prev_balance != 0 ) {
1414     $balance_transfer_reason ||= FS::reason->new_or_existing(
1415       'reason' => 'Package balance transfer',
1416       'type'   => 'Internal adjustment',
1417       'class'  => 'R'
1418     );
1419
1420     my $credit = FS::cust_credit->new({
1421         'custnum'   => $self->custnum,
1422         'amount'    => abs($prev_balance),
1423         'reasonnum' => $balance_transfer_reason->reasonnum,
1424         '_date'     => $cust_pkg->change_date,
1425     });
1426
1427     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1428         'setup'     => 0,
1429         'recur'     => abs($prev_balance),
1430         #'sdate'     => $from_pkg->last_bill, # not sure about this
1431         #'edate'     => $cust_pkg->change_date,
1432         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1433                                  $from_pkg->part_pkg->pkg),
1434     });
1435
1436     if ( $prev_balance > 0 ) {
1437       # credit the old package, charge the new one
1438       $credit->set('pkgnum', $from_pkgnum);
1439       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1440     } else {
1441       # the reverse
1442       $credit->set('pkgnum', $cust_pkg->pkgnum);
1443       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1444     }
1445     my $error = $credit->insert;
1446     die "error transferring package balance from #".$from_pkgnum.
1447         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1448
1449     push @transfers, $cust_bill_pkg;
1450   } # $prev_balance != 0
1451
1452   return @transfers;
1453 }
1454
1455 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1456
1457 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1458 from _make_lines.
1459
1460 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1461 this:
1462 {
1463   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1464   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1465 }
1466
1467 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1468 is always the cust_main_county or tax_rate identified by the key.
1469
1470 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1471 the 'taxline' method to calculate the amount of the tax.  This doesn't
1472 happen until calculate_taxes, though.
1473
1474 OPTIONS may include:
1475 - part_item: a part_pkg or part_fee object to be used as the package/fee
1476   definition.
1477 - location: a cust_location to be used as the billing location.
1478 - cancel: true if this package is being billed on cancellation.  This
1479   allows tax to be calculated on usage charges only.
1480
1481 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1482 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1483 the customer's default service location).
1484
1485 =cut
1486
1487 sub _handle_taxes {
1488   my $self = shift;
1489   my $taxlisthash = shift;
1490   my $cust_bill_pkg = shift;
1491   my %options = @_;
1492
1493   # at this point I realize that we have enough information to infer all this
1494   # stuff, instead of passing around giant honking argument lists
1495   my $location = $options{location} || $cust_bill_pkg->tax_location;
1496   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1497
1498   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1499
1500   return if ( $self->payby eq 'COMP' ); #dubious
1501
1502   if ( $conf->exists('enable_taxproducts')
1503        && ( scalar($part_item->part_pkg_taxoverride)
1504             || $part_item->has_taxproduct
1505           )
1506      )
1507     {
1508
1509     # EXTERNAL TAX RATES (via tax_rate)
1510     my %cust_bill_pkg = ();
1511     my %taxes = ();
1512
1513     my @classes;
1514     push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1515     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1516     push @classes, 'recur' if $cust_bill_pkg->recur and !$options{cancel};
1517
1518     my $exempt = $conf->exists('cust_class-tax_exempt')
1519                    ? ( $self->cust_class ? $self->cust_class->tax : '' )
1520                    : $self->tax;
1521     # standardize this just to be sure
1522     $exempt = ($exempt eq 'Y') ? 'Y' : '';
1523
1524     if ( !$exempt ) {
1525
1526       foreach my $class (@classes) {
1527         my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1528         return $err_or_ref unless ref($err_or_ref);
1529         $taxes{$class} = $err_or_ref;
1530       }
1531
1532       unless (exists $taxes{''}) {
1533         my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1534         return $err_or_ref unless ref($err_or_ref);
1535         $taxes{''} = $err_or_ref;
1536       }
1537
1538     }
1539
1540     my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate; # grrr
1541     foreach my $key (keys %tax_cust_bill_pkg) {
1542       # $key is "setup", "recur", or a usage class name. ('' is a usage class.)
1543       # $tax_cust_bill_pkg{$key} is a cust_bill_pkg for that component of
1544       # the line item.
1545       # $taxes{$key} is an arrayref of cust_main_county or tax_rate objects that
1546       # apply to $key-class charges.
1547       my @taxes = @{ $taxes{$key} || [] };
1548       my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1549
1550       my %localtaxlisthash = ();
1551       foreach my $tax ( @taxes ) {
1552
1553         # this is the tax identifier, not the taxname
1554         my $taxname = ref( $tax ). ' '. $tax->taxnum;
1555         # $taxlisthash: keys are "setup", "recur", and usage classes.
1556         # Values are arrayrefs, first the tax object (cust_main_county
1557         # or tax_rate) and then any cust_bill_pkg objects that the
1558         # tax applies to.
1559         $taxlisthash->{ $taxname } ||= [ $tax ];
1560         push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1561
1562         $localtaxlisthash{ $taxname } ||= [ $tax ];
1563         push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1564
1565       }
1566
1567       warn "finding taxed taxes...\n" if $DEBUG > 2;
1568       foreach my $tax ( keys %localtaxlisthash ) {
1569         my $tax_object = shift @{ $localtaxlisthash{$tax} };
1570         warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1571           if $DEBUG > 2;
1572         next unless $tax_object->can('tax_on_tax');
1573
1574         foreach my $tot ( $tax_object->tax_on_tax( $location ) ) {
1575           my $totname = ref( $tot ). ' '. $tot->taxnum;
1576
1577           warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1578             if $DEBUG > 2;
1579           next unless exists( $localtaxlisthash{ $totname } ); # only increase
1580                                                                # existing taxes
1581           warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1582           # calculate the tax amount that the tax_on_tax will apply to
1583           my $hashref_or_error =
1584             $tax_object->taxline( $localtaxlisthash{$tax} );
1585           return $hashref_or_error
1586             unless ref($hashref_or_error);
1587
1588           # and append it to the list of taxable items
1589           $taxlisthash->{ $totname } ||= [ $tot ];
1590           push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1591
1592         }
1593       }
1594     }
1595
1596   } else {
1597
1598     # INTERNAL TAX RATES (cust_main_county)
1599
1600     # We fetch taxes even if the customer is completely exempt,
1601     # because we need to record that fact.
1602
1603     my @loc_keys = qw( district city county state country );
1604     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1605
1606     $taxhash{'taxclass'} = $part_item->taxclass;
1607
1608     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1609
1610     my @taxes = (); # entries are cust_main_county objects
1611     my %taxhash_elim = %taxhash;
1612     my @elim = qw( district city county state );
1613     do {
1614
1615       #first try a match with taxclass
1616       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1617
1618       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1619         #then try a match without taxclass
1620         my %no_taxclass = %taxhash_elim;
1621         $no_taxclass{ 'taxclass' } = '';
1622         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1623       }
1624
1625       $taxhash_elim{ shift(@elim) } = '';
1626
1627     } while ( !scalar(@taxes) && scalar(@elim) );
1628
1629     foreach (@taxes) {
1630       my $tax_id = 'cust_main_county '.$_->taxnum;
1631       $taxlisthash->{$tax_id} ||= [ $_ ];
1632       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1633     }
1634
1635   }
1636   '';
1637 }
1638
1639 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1640
1641 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1642 or part_fee (which will define the tax eligibility of the product), CLASS is
1643 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1644 location where the service was provided (or billed, depending on
1645 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1646 can apply to this line item.
1647
1648 =cut
1649
1650 sub _gather_taxes {
1651   my $self = shift;
1652   my $part_item = shift;
1653   my $class = shift;
1654   my $location = shift;
1655
1656   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1657
1658   my $geocode = $location->geocode('cch');
1659
1660   [ $part_item->tax_rates('cch', $geocode, $class) ]
1661
1662 }
1663
1664 =item collect [ HASHREF | OPTION => VALUE ... ]
1665
1666 (Attempt to) collect money for this customer's outstanding invoices (see
1667 L<FS::cust_bill>).  Usually used after the bill method.
1668
1669 Actions are now triggered by billing events; see L<FS::part_event> and the
1670 billing events web interface.  Old-style invoice events (see
1671 L<FS::part_bill_event>) have been deprecated.
1672
1673 If there is an error, returns the error, otherwise returns false.
1674
1675 Options are passed as name-value pairs.
1676
1677 Currently available options are:
1678
1679 =over 4
1680
1681 =item invoice_time
1682
1683 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1684
1685 =item retry
1686
1687 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1688
1689 =item check_freq
1690
1691 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1692
1693 =item quiet
1694
1695 set true to surpress email card/ACH decline notices.
1696
1697 =item debug
1698
1699 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1700
1701 =back
1702
1703 # =item payby
1704 #
1705 # allows for one time override of normal customer billing method
1706
1707 =cut
1708
1709 sub collect {
1710   my( $self, %options ) = @_;
1711
1712   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1713
1714   my $invoice_time = $options{'invoice_time'} || time;
1715
1716   #put below somehow?
1717   local $SIG{HUP} = 'IGNORE';
1718   local $SIG{INT} = 'IGNORE';
1719   local $SIG{QUIT} = 'IGNORE';
1720   local $SIG{TERM} = 'IGNORE';
1721   local $SIG{TSTP} = 'IGNORE';
1722   local $SIG{PIPE} = 'IGNORE';
1723
1724   my $oldAutoCommit = $FS::UID::AutoCommit;
1725   local $FS::UID::AutoCommit = 0;
1726   my $dbh = dbh;
1727
1728   $self->select_for_update; #mutex
1729
1730   if ( $DEBUG ) {
1731     my $balance = $self->balance;
1732     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1733   }
1734
1735   if ( exists($options{'retry_card'}) ) {
1736     carp 'retry_card option passed to collect is deprecated; use retry';
1737     $options{'retry'} ||= $options{'retry_card'};
1738   }
1739   if ( exists($options{'retry'}) && $options{'retry'} ) {
1740     my $error = $self->retry_realtime;
1741     if ( $error ) {
1742       $dbh->rollback if $oldAutoCommit;
1743       return $error;
1744     }
1745   }
1746
1747   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1748
1749   #never want to roll back an event just because it returned an error
1750   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1751
1752   $self->do_cust_event(
1753     'debug'      => ( $options{'debug'} || 0 ),
1754     'time'       => $invoice_time,
1755     'check_freq' => $options{'check_freq'},
1756     'stage'      => 'collect',
1757   );
1758
1759 }
1760
1761 =item retry_realtime
1762
1763 Schedules realtime / batch  credit card / electronic check / LEC billing
1764 events for for retry.  Useful if card information has changed or manual
1765 retry is desired.  The 'collect' method must be called to actually retry
1766 the transaction.
1767
1768 Implementation details: For either this customer, or for each of this
1769 customer's open invoices, changes the status of the first "done" (with
1770 statustext error) realtime processing event to "failed".
1771
1772 =cut
1773
1774 sub retry_realtime {
1775   my $self = shift;
1776
1777   local $SIG{HUP} = 'IGNORE';
1778   local $SIG{INT} = 'IGNORE';
1779   local $SIG{QUIT} = 'IGNORE';
1780   local $SIG{TERM} = 'IGNORE';
1781   local $SIG{TSTP} = 'IGNORE';
1782   local $SIG{PIPE} = 'IGNORE';
1783
1784   my $oldAutoCommit = $FS::UID::AutoCommit;
1785   local $FS::UID::AutoCommit = 0;
1786   my $dbh = dbh;
1787
1788   #a little false laziness w/due_cust_event (not too bad, really)
1789
1790   # I guess this is always as of now?
1791   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1792   my $order = FS::part_event_condition->order_conditions_sql;
1793   my $mine =
1794   '( '
1795    . join ( ' OR ' , map {
1796     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1797     my $custnum = FS::part_event->eventtables_custnum->{$_};
1798     "( part_event.eventtable = " . dbh->quote($_)
1799     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1800     . " from $_ $cust_join"
1801     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1802    } FS::part_event->eventtables)
1803    . ') ';
1804
1805   #here is the agent virtualization
1806   my $agent_virt = " (    part_event.agentnum IS NULL
1807                        OR part_event.agentnum = ". $self->agentnum. ' )';
1808
1809   #XXX this shouldn't be hardcoded, actions should declare it...
1810   my @realtime_events = qw(
1811     cust_bill_realtime_card
1812     cust_bill_realtime_check
1813     cust_bill_realtime_lec
1814     cust_bill_batch
1815   );
1816
1817   my $is_realtime_event =
1818     ' part_event.action IN ( '.
1819         join(',', map "'$_'", @realtime_events ).
1820     ' ) ';
1821
1822   my $batch_or_statustext =
1823     "( part_event.action = 'cust_bill_batch'
1824        OR ( statustext IS NOT NULL AND statustext != '' )
1825      )";
1826
1827
1828   my @cust_event = qsearch({
1829     'table'     => 'cust_event',
1830     'select'    => 'cust_event.*',
1831     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1832     'hashref'   => { 'status' => 'done' },
1833     'extra_sql' => " AND $batch_or_statustext ".
1834                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1835   });
1836
1837   my %seen_invnum = ();
1838   foreach my $cust_event (@cust_event) {
1839
1840     #max one for the customer, one for each open invoice
1841     my $cust_X = $cust_event->cust_X;
1842     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1843                           ? $cust_X->invnum
1844                           : 0
1845                         }++
1846          or $cust_event->part_event->eventtable eq 'cust_bill'
1847             && ! $cust_X->owed;
1848
1849     my $error = $cust_event->retry;
1850     if ( $error ) {
1851       $dbh->rollback if $oldAutoCommit;
1852       return "error scheduling event for retry: $error";
1853     }
1854
1855   }
1856
1857   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1858   '';
1859
1860 }
1861
1862 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1863
1864 Runs billing events; see L<FS::part_event> and the billing events web
1865 interface.
1866
1867 If there is an error, returns the error, otherwise returns false.
1868
1869 Options are passed as name-value pairs.
1870
1871 Currently available options are:
1872
1873 =over 4
1874
1875 =item time
1876
1877 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1878
1879 =item check_freq
1880
1881 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1882
1883 =item stage
1884
1885 "collect" (the default) or "pre-bill"
1886
1887 =item quiet
1888
1889 set true to surpress email card/ACH decline notices.
1890
1891 =item debug
1892
1893 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1894
1895 =back
1896 =cut
1897
1898 # =item payby
1899 #
1900 # allows for one time override of normal customer billing method
1901
1902 # =item retry
1903 #
1904 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1905
1906 sub do_cust_event {
1907   my( $self, %options ) = @_;
1908
1909   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1910
1911   my $time = $options{'time'} || time;
1912
1913   #put below somehow?
1914   local $SIG{HUP} = 'IGNORE';
1915   local $SIG{INT} = 'IGNORE';
1916   local $SIG{QUIT} = 'IGNORE';
1917   local $SIG{TERM} = 'IGNORE';
1918   local $SIG{TSTP} = 'IGNORE';
1919   local $SIG{PIPE} = 'IGNORE';
1920
1921   my $oldAutoCommit = $FS::UID::AutoCommit;
1922   local $FS::UID::AutoCommit = 0;
1923   my $dbh = dbh;
1924
1925   $self->select_for_update; #mutex
1926
1927   if ( $DEBUG ) {
1928     my $balance = $self->balance;
1929     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1930   }
1931
1932 #  if ( exists($options{'retry_card'}) ) {
1933 #    carp 'retry_card option passed to collect is deprecated; use retry';
1934 #    $options{'retry'} ||= $options{'retry_card'};
1935 #  }
1936 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1937 #    my $error = $self->retry_realtime;
1938 #    if ( $error ) {
1939 #      $dbh->rollback if $oldAutoCommit;
1940 #      return $error;
1941 #    }
1942 #  }
1943
1944   # false laziness w/pay_batch::import_results
1945
1946   my $due_cust_event = $self->due_cust_event(
1947     'debug'      => ( $options{'debug'} || 0 ),
1948     'time'       => $time,
1949     'check_freq' => $options{'check_freq'},
1950     'stage'      => ( $options{'stage'} || 'collect' ),
1951   );
1952   unless( ref($due_cust_event) ) {
1953     $dbh->rollback if $oldAutoCommit;
1954     return $due_cust_event;
1955   }
1956
1957   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1958   #never want to roll back an event just because it or a different one
1959   # returned an error
1960   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1961
1962   foreach my $cust_event ( @$due_cust_event ) {
1963
1964     #XXX lock event
1965
1966     #re-eval event conditions (a previous event could have changed things)
1967     unless ( $cust_event->test_conditions ) {
1968       #don't leave stray "new/locked" records around
1969       my $error = $cust_event->delete;
1970       return $error if $error;
1971       next;
1972     }
1973
1974     {
1975       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1976         if $options{'quiet'};
1977       warn "  running cust_event ". $cust_event->eventnum. "\n"
1978         if $DEBUG > 1;
1979
1980       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1981       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1982         #XXX wtf is this?  figure out a proper dealio with return value
1983         #from do_event
1984         return $error;
1985       }
1986     }
1987
1988   }
1989
1990   '';
1991
1992 }
1993
1994 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1995
1996 Inserts database records for and returns an ordered listref of new events due
1997 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1998 events are due, an empty listref is returned.  If there is an error, returns a
1999 scalar error message.
2000
2001 To actually run the events, call each event's test_condition method, and if
2002 still true, call the event's do_event method.
2003
2004 Options are passed as a hashref or as a list of name-value pairs.  Available
2005 options are:
2006
2007 =over 4
2008
2009 =item check_freq
2010
2011 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2012
2013 =item stage
2014
2015 "collect" (the default) or "pre-bill"
2016
2017 =item time
2018
2019 "Current time" for the events.
2020
2021 =item debug
2022
2023 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2024
2025 =item eventtable
2026
2027 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2028
2029 =item objects
2030
2031 Explicitly pass the objects to be tested (typically used with eventtable).
2032
2033 =item testonly
2034
2035 Set to true to return the objects, but not actually insert them into the
2036 database.
2037
2038 =back
2039
2040 =cut
2041
2042 sub due_cust_event {
2043   my $self = shift;
2044   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2045
2046   #???
2047   #my $DEBUG = $opt{'debug'}
2048   $opt{'debug'} ||= 0; # silence some warnings
2049   local($DEBUG) = $opt{'debug'}
2050     if $opt{'debug'} > $DEBUG;
2051   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2052
2053   warn "$me due_cust_event called with options ".
2054        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2055     if $DEBUG;
2056
2057   $opt{'time'} ||= time;
2058
2059   local $SIG{HUP} = 'IGNORE';
2060   local $SIG{INT} = 'IGNORE';
2061   local $SIG{QUIT} = 'IGNORE';
2062   local $SIG{TERM} = 'IGNORE';
2063   local $SIG{TSTP} = 'IGNORE';
2064   local $SIG{PIPE} = 'IGNORE';
2065
2066   my $oldAutoCommit = $FS::UID::AutoCommit;
2067   local $FS::UID::AutoCommit = 0;
2068   my $dbh = dbh;
2069
2070   $self->select_for_update #mutex
2071     unless $opt{testonly};
2072
2073   ###
2074   # find possible events (initial search)
2075   ###
2076
2077   my @cust_event = ();
2078
2079   my @eventtable = $opt{'eventtable'}
2080                      ? ( $opt{'eventtable'} )
2081                      : FS::part_event->eventtables_runorder;
2082
2083   my $check_freq = $opt{'check_freq'} || '1d';
2084
2085   foreach my $eventtable ( @eventtable ) {
2086
2087     my @objects;
2088     if ( $opt{'objects'} ) {
2089
2090       @objects = @{ $opt{'objects'} };
2091
2092     } elsif ( $eventtable eq 'cust_main' ) {
2093
2094       @objects = ( $self );
2095
2096     } else {
2097
2098       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2099       # linkage not needed here because FS::cust_main->$eventtable will
2100       # already supply it
2101
2102       #some false laziness w/Cron::bill bill_where
2103
2104       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2105         'time' => $opt{'time'});
2106       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2107         'time'=>$opt{'time'},
2108       );
2109       $where = $where ? "AND $where" : '';
2110
2111       my $are_part_event =
2112       "EXISTS ( SELECT 1 FROM part_event $join
2113         WHERE check_freq = '$check_freq'
2114         AND eventtable = '$eventtable'
2115         AND ( disabled = '' OR disabled IS NULL )
2116         $where
2117         )
2118       ";
2119       #eofalse
2120
2121       @objects = $self->$eventtable(
2122         'addl_from' => $cm_join,
2123         'extra_sql' => " AND $are_part_event",
2124       );
2125     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2126
2127     my @e_cust_event = ();
2128
2129     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2130
2131     my $cross = "CROSS JOIN $eventtable $linkage";
2132     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2133       unless $eventtable eq 'cust_main';
2134
2135     foreach my $object ( @objects ) {
2136
2137       #this first search uses the condition_sql magic for optimization.
2138       #the more possible events we can eliminate in this step the better
2139
2140       my $cross_where = '';
2141       my $pkey = $object->primary_key;
2142       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2143
2144       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2145         'time' => $opt{'time'});
2146       my $extra_sql =
2147         FS::part_event_condition->where_conditions_sql( $eventtable,
2148                                                         'time'=>$opt{'time'}
2149                                                       );
2150       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2151
2152       $extra_sql = "AND $extra_sql" if $extra_sql;
2153
2154       #here is the agent virtualization
2155       $extra_sql .= " AND (    part_event.agentnum IS NULL
2156                             OR part_event.agentnum = ". $self->agentnum. ' )';
2157
2158       $extra_sql .= " $order";
2159
2160       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2161         if $opt{'debug'} > 2;
2162       my @part_event = qsearch( {
2163         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2164         'select'    => 'part_event.*',
2165         'table'     => 'part_event',
2166         'addl_from' => "$cross $join",
2167         'hashref'   => { 'check_freq' => $check_freq,
2168                          'eventtable' => $eventtable,
2169                          'disabled'   => '',
2170                        },
2171         'extra_sql' => "AND $cross_where $extra_sql",
2172       } );
2173
2174       if ( $DEBUG > 2 ) {
2175         my $pkey = $object->primary_key;
2176         warn "      ". scalar(@part_event).
2177              " possible events found for $eventtable ". $object->$pkey(). "\n";
2178       }
2179
2180       push @e_cust_event, map {
2181         $_->new_cust_event($object, 'time' => $opt{'time'})
2182       } @part_event;
2183
2184     }
2185
2186     warn "    ". scalar(@e_cust_event).
2187          " subtotal possible cust events found for $eventtable\n"
2188       if $DEBUG > 1;
2189
2190     push @cust_event, @e_cust_event;
2191
2192   }
2193
2194   warn "  ". scalar(@cust_event).
2195        " total possible cust events found in initial search\n"
2196     if $DEBUG; # > 1;
2197
2198
2199   ##
2200   # test stage
2201   ##
2202
2203   $opt{stage} ||= 'collect';
2204   @cust_event =
2205     grep { my $stage = $_->part_event->event_stage;
2206            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2207          }
2208          @cust_event;
2209
2210   ##
2211   # test conditions
2212   ##
2213
2214   my %unsat = ();
2215
2216   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2217                      @cust_event;
2218
2219   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2220     if $DEBUG; # > 1;
2221
2222   warn "    invalid conditions not eliminated with condition_sql:\n".
2223        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2224     if keys %unsat && $DEBUG; # > 1;
2225
2226   ##
2227   # insert
2228   ##
2229
2230   unless( $opt{testonly} ) {
2231     foreach my $cust_event ( @cust_event ) {
2232
2233       my $error = $cust_event->insert();
2234       if ( $error ) {
2235         $dbh->rollback if $oldAutoCommit;
2236         return $error;
2237       }
2238
2239     }
2240   }
2241
2242   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2243
2244   ##
2245   # return
2246   ##
2247
2248   warn "  returning events: ". Dumper(@cust_event). "\n"
2249     if $DEBUG > 2;
2250
2251   \@cust_event;
2252
2253 }
2254
2255 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2256
2257 Applies unapplied payments and credits.
2258
2259 In most cases, this new method should be used in place of sequential
2260 apply_payments and apply_credits methods.
2261
2262 A hash of optional arguments may be passed.  Currently "manual" is supported.
2263 If true, a payment receipt is sent instead of a statement when
2264 'payment_receipt_email' configuration option is set.
2265
2266 If there is an error, returns the error, otherwise returns false.
2267
2268 =cut
2269
2270 sub apply_payments_and_credits {
2271   my( $self, %options ) = @_;
2272
2273   local $SIG{HUP} = 'IGNORE';
2274   local $SIG{INT} = 'IGNORE';
2275   local $SIG{QUIT} = 'IGNORE';
2276   local $SIG{TERM} = 'IGNORE';
2277   local $SIG{TSTP} = 'IGNORE';
2278   local $SIG{PIPE} = 'IGNORE';
2279
2280   my $oldAutoCommit = $FS::UID::AutoCommit;
2281   local $FS::UID::AutoCommit = 0;
2282   my $dbh = dbh;
2283
2284   $self->select_for_update; #mutex
2285
2286   foreach my $cust_bill ( $self->open_cust_bill ) {
2287     my $error = $cust_bill->apply_payments_and_credits(%options);
2288     if ( $error ) {
2289       $dbh->rollback if $oldAutoCommit;
2290       return "Error applying: $error";
2291     }
2292   }
2293
2294   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2295   ''; #no error
2296
2297 }
2298
2299 =item apply_credits OPTION => VALUE ...
2300
2301 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2302 to outstanding invoice balances in chronological order (or reverse
2303 chronological order if the I<order> option is set to B<newest>) and returns the
2304 value of any remaining unapplied credits available for refund (see
2305 L<FS::cust_refund>).
2306
2307 Dies if there is an error.
2308
2309 =cut
2310
2311 sub apply_credits {
2312   my $self = shift;
2313   my %opt = @_;
2314
2315   local $SIG{HUP} = 'IGNORE';
2316   local $SIG{INT} = 'IGNORE';
2317   local $SIG{QUIT} = 'IGNORE';
2318   local $SIG{TERM} = 'IGNORE';
2319   local $SIG{TSTP} = 'IGNORE';
2320   local $SIG{PIPE} = 'IGNORE';
2321
2322   my $oldAutoCommit = $FS::UID::AutoCommit;
2323   local $FS::UID::AutoCommit = 0;
2324   my $dbh = dbh;
2325
2326   $self->select_for_update; #mutex
2327
2328   unless ( $self->total_unapplied_credits ) {
2329     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2330     return 0;
2331   }
2332
2333   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2334       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2335
2336   my @invoices = $self->open_cust_bill;
2337   @invoices = sort { $b->_date <=> $a->_date } @invoices
2338     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2339
2340   if ( $conf->exists('pkg-balances') ) {
2341     # limit @credits to those w/ a pkgnum grepped from $self
2342     my %pkgnums = ();
2343     foreach my $i (@invoices) {
2344       foreach my $li ( $i->cust_bill_pkg ) {
2345         $pkgnums{$li->pkgnum} = 1;
2346       }
2347     }
2348     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2349   }
2350
2351   my $credit;
2352
2353   foreach my $cust_bill ( @invoices ) {
2354
2355     if ( !defined($credit) || $credit->credited == 0) {
2356       $credit = pop @credits or last;
2357     }
2358
2359     my $owed;
2360     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2361       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2362     } else {
2363       $owed = $cust_bill->owed;
2364     }
2365     unless ( $owed > 0 ) {
2366       push @credits, $credit;
2367       next;
2368     }
2369
2370     my $amount = min( $credit->credited, $owed );
2371
2372     my $cust_credit_bill = new FS::cust_credit_bill ( {
2373       'crednum' => $credit->crednum,
2374       'invnum'  => $cust_bill->invnum,
2375       'amount'  => $amount,
2376     } );
2377     $cust_credit_bill->pkgnum( $credit->pkgnum )
2378       if $conf->exists('pkg-balances') && $credit->pkgnum;
2379     my $error = $cust_credit_bill->insert;
2380     if ( $error ) {
2381       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2382       die $error;
2383     }
2384
2385     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2386
2387   }
2388
2389   my $total_unapplied_credits = $self->total_unapplied_credits;
2390
2391   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2392
2393   return $total_unapplied_credits;
2394 }
2395
2396 =item apply_payments  [ OPTION => VALUE ... ]
2397
2398 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2399 to outstanding invoice balances in chronological order.
2400
2401  #and returns the value of any remaining unapplied payments.
2402
2403 A hash of optional arguments may be passed.  Currently "manual" is supported.
2404 If true, a payment receipt is sent instead of a statement when
2405 'payment_receipt_email' configuration option is set.
2406
2407 Dies if there is an error.
2408
2409 =cut
2410
2411 sub apply_payments {
2412   my( $self, %options ) = @_;
2413
2414   local $SIG{HUP} = 'IGNORE';
2415   local $SIG{INT} = 'IGNORE';
2416   local $SIG{QUIT} = 'IGNORE';
2417   local $SIG{TERM} = 'IGNORE';
2418   local $SIG{TSTP} = 'IGNORE';
2419   local $SIG{PIPE} = 'IGNORE';
2420
2421   my $oldAutoCommit = $FS::UID::AutoCommit;
2422   local $FS::UID::AutoCommit = 0;
2423   my $dbh = dbh;
2424
2425   $self->select_for_update; #mutex
2426
2427   #return 0 unless
2428
2429   my @payments = sort { $b->_date <=> $a->_date }
2430                  grep { $_->unapplied > 0 }
2431                  $self->cust_pay;
2432
2433   my @invoices = sort { $a->_date <=> $b->_date}
2434                  grep { $_->owed > 0 }
2435                  $self->cust_bill;
2436
2437   if ( $conf->exists('pkg-balances') ) {
2438     # limit @payments to those w/ a pkgnum grepped from $self
2439     my %pkgnums = ();
2440     foreach my $i (@invoices) {
2441       foreach my $li ( $i->cust_bill_pkg ) {
2442         $pkgnums{$li->pkgnum} = 1;
2443       }
2444     }
2445     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2446   }
2447
2448   my $payment;
2449
2450   foreach my $cust_bill ( @invoices ) {
2451
2452     if ( !defined($payment) || $payment->unapplied == 0 ) {
2453       $payment = pop @payments or last;
2454     }
2455
2456     my $owed;
2457     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2458       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2459     } else {
2460       $owed = $cust_bill->owed;
2461     }
2462     unless ( $owed > 0 ) {
2463       push @payments, $payment;
2464       next;
2465     }
2466
2467     my $amount = min( $payment->unapplied, $owed );
2468
2469     my $cbp = {
2470       'paynum' => $payment->paynum,
2471       'invnum' => $cust_bill->invnum,
2472       'amount' => $amount,
2473     };
2474     $cbp->{_date} = $payment->_date
2475         if $options{'manual'} && $options{'backdate_application'};
2476     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2477     $cust_bill_pay->pkgnum( $payment->pkgnum )
2478       if $conf->exists('pkg-balances') && $payment->pkgnum;
2479     my $error = $cust_bill_pay->insert(%options);
2480     if ( $error ) {
2481       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2482       die $error;
2483     }
2484
2485     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2486
2487   }
2488
2489   my $total_unapplied_payments = $self->total_unapplied_payments;
2490
2491   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2492
2493   return $total_unapplied_payments;
2494 }
2495
2496 =back
2497
2498 =head1 FLOW
2499
2500   bill_and_collect
2501
2502     cancel_expired_pkgs
2503     suspend_adjourned_pkgs
2504     unsuspend_resumed_pkgs
2505
2506     bill
2507       (do_cust_event pre-bill)
2508       _make_lines
2509         _handle_taxes
2510           (vendor-only) _gather_taxes
2511       _omit_zero_value_bundles
2512       _handle_taxes (for fees)
2513       calculate_taxes
2514
2515     apply_payments_and_credits
2516     collect
2517       do_cust_event
2518         due_cust_event
2519
2520 =head1 BUGS
2521
2522 =head1 SEE ALSO
2523
2524 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2525
2526 =cut
2527
2528 1;