FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::cust_bill;
  11 use FS::cust_bill_pkg;
  12 use FS::cust_bill_pkg_display;
  13 use FS::cust_bill_pay;
  14 use FS::cust_credit_bill;
  15 use FS::cust_tax_adjustment;
  16 use FS::tax_rate;
  17 use FS::tax_rate_location;
  18 use FS::cust_bill_pkg_tax_location;
  19 use FS::cust_bill_pkg_tax_rate_location;
  20 use FS::part_event;
  21 use FS::part_event_condition;
  22 use FS::pkg_category;
  23 use POSIX;
  24
  25 # 1 is mostly method/subroutine entry and options
  26 # 2 traces progress of some operations
  27 # 3 is even more information including possibly sensitive data
  28 $DEBUG = 0;
  29 $me = '[FS::cust_main::Billing]';
  30
  31 install_callback FS::UID sub {
  32   $conf = new FS::Conf;
  33   #yes, need it for stuff below (prolly should be cached)
  34 };
  35
  36 =head1 NAME
  37
  38 FS::cust_main::Billing - Billing mixin for cust_main
  39
  40 =head1 SYNOPSIS
  41
  42 =head1 DESCRIPTION
  43
  44 These methods are available on FS::cust_main objects.
  45
  46 =head1 METHODS
  47
  48 =over 4
  49
  50 =item bill_and_collect
  51
  52 Cancels and suspends any packages due, generates bills, applies payments and
  53 credits, and applies collection events to run cards, send bills and notices,
  54 etc.
  55
  56 By default, warns on errors and continues with the next operation (but see the
  57 "fatal" flag below).
  58
  59 Options are passed as name-value pairs.  Currently available options are:
  60
  61 =over 4
  62
  63 =item time
  64
  65 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  66
  67  use Date::Parse;
  68  ...
  69  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  70
  71 =item invoice_time
  72
  73 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  74
  75 =item check_freq
  76
  77 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  78
  79 =item resetup
  80
  81 If set true, re-charges setup fees.
  82
  83 =item fatal
  84
  85 If set any errors prevent subsequent operations from continusing.  If set
  86 specifically to "return", returns the error (or false, if there is no error).
  87 Any other true value causes errors to die.
  88
  89 =item debug
  90
  91 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  92
  93 =item job
  94
  95 Optional FS::queue entry to receive status updates.
  96
  97 =back
  98
  99 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 100 options of those methods are also available.
 101
 102 =cut
 103
 104 sub bill_and_collect {
 105   my( $self, %options ) = @_;
 106
 107   my $error;
 108
 109   #$options{actual_time} not $options{time} because freeside-daily -d is for
 110   #pre-printing invoices
 111
 112   $options{'actual_time'} ||= time;
 113   my $job = $options{'job'};
 114
 115   $job->update_statustext('0,cleaning expired packages') if $job;
 116   $error = $self->cancel_expired_pkgs( $self->day_end( $options{actual_time} ) );
 117   if ( $error ) {
 118     $error = "Error expiring custnum ". $self->custnum. ": $error";
 119     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 120     elsif ( $options{fatal}                                ) { die    $error; }
 121     else                                                     { warn   $error; }
 122   }
 123
 124   $error = $self->suspend_adjourned_pkgs( $self->day_end( $options{actual_time} ) );
 125   if ( $error ) {
 126     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 127     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 128     elsif ( $options{fatal}                                ) { die    $error; }
 129     else                                                     { warn   $error; }
 130   }
 131
 132   $job->update_statustext('20,billing packages') if $job;
 133   $error = $self->bill( %options );
 134   if ( $error ) {
 135     $error = "Error billing custnum ". $self->custnum. ": $error";
 136     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 137     elsif ( $options{fatal}                                ) { die    $error; }
 138     else                                                     { warn   $error; }
 139   }
 140
 141   $job->update_statustext('50,applying payments and credits') if $job;
 142   $error = $self->apply_payments_and_credits;
 143   if ( $error ) {
 144     $error = "Error applying custnum ". $self->custnum. ": $error";
 145     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 146     elsif ( $options{fatal}                                ) { die    $error; }
 147     else                                                     { warn   $error; }
 148   }
 149
 150   $job->update_statustext('70,running collection events') if $job;
 151   unless ( $conf->exists('cancelled_cust-noevents')
 152            && ! $self->num_ncancelled_pkgs
 153   ) {
 154     $error = $self->collect( %options );
 155     if ( $error ) {
 156       $error = "Error collecting custnum ". $self->custnum. ": $error";
 157       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 158       elsif ($options{fatal}                               ) { die    $error; }
 159       else                                                   { warn   $error; }
 160     }
 161   }
 162   $job->update_statustext('100,finished') if $job;
 163
 164   '';
 165
 166 }
 167
 168 sub day_end {
 169     # XXX: sometimes "incorrect" if crossing DST boundaries?
 170
 171     my $self = shift;
 172     my $time = shift;
 173
 174     return $time unless $conf->exists('next-bill-ignore-time');
 175
 176     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
 177         localtime($time);
 178     mktime(59,59,23,$mday,$mon,$year,$wday,$yday,$isdst);
 179 }
 180
 181 sub cancel_expired_pkgs {
 182   my ( $self, $time, %options ) = @_;
 183
 184   my @cancel_pkgs = $self->ncancelled_pkgs( {
 185     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 186   } );
 187
 188   my @errors = ();
 189
 190   foreach my $cust_pkg ( @cancel_pkgs ) {
 191     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 192     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 193                                            'reason_otaker' => $cpr->otaker
 194                                          )
 195                                        : ()
 196                                  );
 197     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 198   }
 199
 200   scalar(@errors) ? join(' / ', @errors) : '';
 201
 202 }
 203
 204 sub suspend_adjourned_pkgs {
 205   my ( $self, $time, %options ) = @_;
 206
 207   my @susp_pkgs = $self->ncancelled_pkgs( {
 208     'extra_sql' =>
 209       " AND ( susp IS NULL OR susp = 0 )
 210         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 211               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 212             )
 213       ",
 214   } );
 215
 216   #only because there's no SQL test for is_prepaid :/
 217   @susp_pkgs =
 218     grep {     (    $_->part_pkg->is_prepaid
 219                  && $_->bill
 220                  && $_->bill < $time
 221                )
 222             || (    $_->adjourn
 223                  && $_->adjourn <= $time
 224                )
 225
 226          }
 227          @susp_pkgs;
 228
 229   my @errors = ();
 230
 231   foreach my $cust_pkg ( @susp_pkgs ) {
 232     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 233       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 234     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 235                                             'reason_otaker' => $cpr->otaker
 236                                           )
 237                                         : ()
 238                                   );
 239     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 240   }
 241
 242   scalar(@errors) ? join(' / ', @errors) : '';
 243
 244 }
 245
 246 =item bill OPTIONS
 247
 248 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 249 conjunction with the collect method by calling B<bill_and_collect>.
 250
 251 If there is an error, returns the error, otherwise returns false.
 252
 253 Options are passed as name-value pairs.  Currently available options are:
 254
 255 =over 4
 256
 257 =item resetup
 258
 259 If set true, re-charges setup fees.
 260
 261 =item recurring_only
 262
 263 If set true then only bill recurring charges, not setup, usage, one time
 264 charges, etc.
 265
 266 =item freq_override
 267
 268 If set, then override the normal frequency and look for a part_pkg_discount
 269 to take at that frequency.
 270
 271 =item time
 272
 273 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 274
 275  use Date::Parse;
 276  ...
 277  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 278
 279 =item pkg_list
 280
 281 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 282
 283  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 284
 285 =item not_pkgpart
 286
 287 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 288
 289 =item invoice_time
 290
 291 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 292
 293 =item cancel
 294
 295 This boolean value informs the us that the package is being cancelled.  This
 296 typically might mean not charging the normal recurring fee but only usage
 297 fees since the last billing. Setup charges may be charged.  Not all package
 298 plans support this feature (they tend to charge 0).
 299
 300 =item no_usage_reset
 301
 302 Prevent the resetting of usage limits during this call.
 303
 304 =item no_commit
 305
 306 Do not save the generated bill in the database.  Useful with return_bill
 307
 308 =item return_bill
 309
 310 A list reference on which the generated bill(s) will be returned.
 311
 312 =item invoice_terms
 313
 314 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 315 terms or the default terms are used.
 316
 317 =back
 318
 319 =cut
 320
 321 sub bill {
 322   my( $self, %options ) = @_;
 323
 324   return '' if $self->payby eq 'COMP';
 325
 326   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 327
 328   warn "$me bill customer ". $self->custnum. "\n"
 329     if $DEBUG;
 330
 331   my $time = $options{'time'} || time;
 332   my $invoice_time = $options{'invoice_time'} || $time;
 333
 334   $options{'not_pkgpart'} ||= {};
 335   $options{'not_pkgpart'} = { map { $_ => 1 }
 336                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 337                             }
 338     unless ref($options{'not_pkgpart'});
 339
 340   local $SIG{HUP} = 'IGNORE';
 341   local $SIG{INT} = 'IGNORE';
 342   local $SIG{QUIT} = 'IGNORE';
 343   local $SIG{TERM} = 'IGNORE';
 344   local $SIG{TSTP} = 'IGNORE';
 345   local $SIG{PIPE} = 'IGNORE';
 346
 347   my $oldAutoCommit = $FS::UID::AutoCommit;
 348   local $FS::UID::AutoCommit = 0;
 349   my $dbh = dbh;
 350
 351   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 352     if $DEBUG;
 353
 354   $self->select_for_update; #mutex
 355
 356   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 357     if $DEBUG;
 358
 359   my $error = $self->do_cust_event(
 360     'debug'      => ( $options{'debug'} || 0 ),
 361     'time'       => $invoice_time,
 362     'check_freq' => $options{'check_freq'},
 363     'stage'      => 'pre-bill',
 364   )
 365     unless $options{no_commit};
 366   if ( $error ) {
 367     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 368     return $error;
 369   }
 370
 371   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 372     if $DEBUG;
 373
 374   #keep auto-charge and non-auto-charge line items separate
 375   my @passes = ( '', 'no_auto' );
 376
 377   my %cust_bill_pkg = map { $_ => [] } @passes;
 378
 379   ###
 380   # find the packages which are due for billing, find out how much they are
 381   # & generate invoice database.
 382   ###
 383
 384   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 385   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 386
 387   my %taxlisthash = map { $_ => {} } @passes;
 388
 389   my @precommit_hooks = ();
 390
 391   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 392   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 393
 394     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 395
 396     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
 397
 398     #? to avoid use of uninitialized value errors... ?
 399     $cust_pkg->setfield('bill', '')
 400       unless defined($cust_pkg->bill);
 401
 402     #my $part_pkg = $cust_pkg->part_pkg;
 403
 404     my $real_pkgpart = $cust_pkg->pkgpart;
 405     my %hash = $cust_pkg->hash;
 406
 407     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 408     # suffer from performance issues
 409     $options{has_hidden} = 0;
 410     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 411     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 412
 413     foreach my $part_pkg ( @part_pkg ) {
 414
 415       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 416
 417       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 418
 419       my $error =
 420         $self->_make_lines( 'part_pkg'            => $part_pkg,
 421                             'cust_pkg'            => $cust_pkg,
 422                             'precommit_hooks'     => \@precommit_hooks,
 423                             'line_items'          => $cust_bill_pkg{$pass},
 424                             'setup'               => $total_setup{$pass},
 425                             'recur'               => $total_recur{$pass},
 426                             'tax_matrix'          => $taxlisthash{$pass},
 427                             'time'                => $time,
 428                             'real_pkgpart'        => $real_pkgpart,
 429                             'options'             => \%options,
 430                           );
 431       if ($error) {
 432         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 433         return $error;
 434       }
 435
 436     } #foreach my $part_pkg
 437
 438   } #foreach my $cust_pkg
 439
 440   #if the customer isn't on an automatic payby, everything can go on a single
 441   #invoice anyway?
 442   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 443     #merge everything into one list
 444   #}
 445
 446   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 447
 448     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 449
 450     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 451
 452     warn "$me billing pass $pass\n"
 453            #.Dumper(\@cust_bill_pkg)."\n"
 454       if $DEBUG > 2;
 455
 456     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 457            !$conf->exists('postal_invoice-recurring_only')
 458        )
 459     {
 460
 461       my $postal_pkg = $self->charge_postal_fee();
 462       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 463
 464         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 465         return "can't charge postal invoice fee for customer ".
 466           $self->custnum. ": $postal_pkg";
 467
 468       } elsif ( $postal_pkg ) {
 469
 470         my $real_pkgpart = $postal_pkg->pkgpart;
 471         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 472         # suffer from performance issues
 473         $options{has_hidden} = 0;
 474         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 475         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 476
 477         foreach my $part_pkg ( @part_pkg ) {
 478           my %postal_options = %options;
 479           delete $postal_options{cancel};
 480           my $error =
 481             $self->_make_lines( 'part_pkg'            => $part_pkg,
 482                                 'cust_pkg'            => $postal_pkg,
 483                                 'precommit_hooks'     => \@precommit_hooks,
 484                                 'line_items'          => \@cust_bill_pkg,
 485                                 'setup'               => $total_setup{$pass},
 486                                 'recur'               => $total_recur{$pass},
 487                                 'tax_matrix'          => $taxlisthash{$pass},
 488                                 'time'                => $time,
 489                                 'real_pkgpart'        => $real_pkgpart,
 490                                 'options'             => \%postal_options,
 491                               );
 492           if ($error) {
 493             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 494             return $error;
 495           }
 496         }
 497
 498         # it's silly to have a zero value postal_pkg, but....
 499         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 500
 501       }
 502
 503     }
 504
 505     my $listref_or_error =
 506       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 507
 508     unless ( ref( $listref_or_error ) ) {
 509       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 510       return $listref_or_error;
 511     }
 512
 513     foreach my $taxline ( @$listref_or_error ) {
 514       ${ $total_setup{$pass} } =
 515         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 516       push @cust_bill_pkg, $taxline;
 517     }
 518
 519     #add tax adjustments
 520     warn "adding tax adjustments...\n" if $DEBUG > 2;
 521     foreach my $cust_tax_adjustment (
 522       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 523                                        'billpkgnum' => '',
 524                                      }
 525              )
 526     ) {
 527
 528       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 529
 530       my $itemdesc = $cust_tax_adjustment->taxname;
 531       $itemdesc = '' if $itemdesc eq 'Tax';
 532
 533       push @cust_bill_pkg, new FS::cust_bill_pkg {
 534         'pkgnum'      => 0,
 535         'setup'       => $tax,
 536         'recur'       => 0,
 537         'sdate'       => '',
 538         'edate'       => '',
 539         'itemdesc'    => $itemdesc,
 540         'itemcomment' => $cust_tax_adjustment->comment,
 541         'cust_tax_adjustment' => $cust_tax_adjustment,
 542         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 543       };
 544
 545     }
 546
 547     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 548
 549     my @cust_bill = $self->cust_bill;
 550     my $balance = $self->balance;
 551     my $previous_balance = scalar(@cust_bill)
 552                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 553                              : 0;
 554
 555     $previous_balance += $cust_bill[$#cust_bill]->charged
 556       if scalar(@cust_bill);
 557     #my $balance_adjustments =
 558     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 559
 560     warn "creating the new invoice\n" if $DEBUG;
 561     #create the new invoice
 562     my $cust_bill = new FS::cust_bill ( {
 563       'custnum'             => $self->custnum,
 564       '_date'               => $invoice_time,
 565       'charged'             => $charged,
 566       'billing_balance'     => $balance,
 567       'previous_balance'    => $previous_balance,
 568       'invoice_terms'       => $options{'invoice_terms'},
 569       'cust_bill_pkg'       => \@cust_bill_pkg,
 570     } );
 571     $error = $cust_bill->insert unless $options{no_commit};
 572     if ( $error ) {
 573       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 574       return "can't create invoice for customer #". $self->custnum. ": $error";
 575     }
 576     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 577
 578   } #foreach my $pass ( keys %cust_bill_pkg )
 579
 580   foreach my $hook ( @precommit_hooks ) {
 581     eval {
 582       &{$hook}; #($self) ?
 583     } unless $options{no_commit};
 584     if ( $@ ) {
 585       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 586       return "$@ running precommit hook $hook\n";
 587     }
 588   }
 589
 590   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 591
 592   ''; #no error
 593 }
 594
 595 #discard bundled packages of 0 value
 596 sub _omit_zero_value_bundles {
 597
 598   my @cust_bill_pkg = ();
 599   my @cust_bill_pkg_bundle = ();
 600   my $sum = 0;
 601   my $discount_show_always = 0;
 602
 603   foreach my $cust_bill_pkg ( @_ ) {
 604     $discount_show_always = ($cust_bill_pkg->get('discounts')
 605                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 606                                 && $conf->exists('discount-show-always'));
 607     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 608       push @cust_bill_pkg, @cust_bill_pkg_bundle
 609                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 610       @cust_bill_pkg_bundle = ();
 611       $sum = 0;
 612     }
 613     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 614     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 615   }
 616   push @cust_bill_pkg, @cust_bill_pkg_bundle
 617                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 618
 619   (@cust_bill_pkg);
 620
 621 }
 622
 623 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 624
 625 This is a weird one.  Perhaps it should not even be exposed.
 626
 627 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 628 Usually used internally by bill method B<bill>.
 629
 630 If there is an error, returns the error, otherwise returns reference to a
 631 list of line items suitable for insertion.
 632
 633 =over 4
 634
 635 =item LINEITEMREF
 636
 637 An array ref of the line items being billed.
 638
 639 =item TAXHASHREF
 640
 641 A strange beast.  The keys to this hash are internal identifiers consisting
 642 of the name of the tax object type, a space, and its unique identifier ( e.g.
 643  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 644 item in the list is the tax object.  The remaining items are either line
 645 items or floating point values (currency amounts).
 646
 647 The taxes are calculated on this entity.  Calculated exemption records are
 648 transferred to the LINEITEMREF items on the assumption that they are related.
 649
 650 Read the source.
 651
 652 =item INVOICE_TIME
 653
 654 This specifies the date appearing on the associated invoice.  Some
 655 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 656
 657 =back
 658
 659 =cut
 660
 661 sub calculate_taxes {
 662   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 663
 664   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 665
 666   warn "$me calculate_taxes\n"
 667        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 668     if $DEBUG > 2;
 669
 670   my @tax_line_items = ();
 671
 672   # keys are tax names (as printed on invoices / itemdesc )
 673   # values are listrefs of taxlisthash keys (internal identifiers)
 674   my %taxname = ();
 675
 676   # keys are taxlisthash keys (internal identifiers)
 677   # values are (cumulative) amounts
 678   my %tax = ();
 679
 680   # keys are taxlisthash keys (internal identifiers)
 681   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 682   my %tax_location = ();
 683
 684   # keys are taxlisthash keys (internal identifiers)
 685   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 686   my %tax_rate_location = ();
 687
 688   foreach my $tax ( keys %$taxlisthash ) {
 689     my $tax_object = shift @{ $taxlisthash->{$tax} };
 690     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 691     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 692     my $hashref_or_error =
 693       $tax_object->taxline( $taxlisthash->{$tax},
 694                             'custnum'      => $self->custnum,
 695                             'invoice_time' => $invoice_time
 696                           );
 697     return $hashref_or_error unless ref($hashref_or_error);
 698
 699     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 700
 701     my $name   = $hashref_or_error->{'name'};
 702     my $amount = $hashref_or_error->{'amount'};
 703
 704     #warn "adding $amount as $name\n";
 705     $taxname{ $name } ||= [];
 706     push @{ $taxname{ $name } }, $tax;
 707
 708     $tax{ $tax } += $amount;
 709
 710     $tax_location{ $tax } ||= [];
 711     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 712       push @{ $tax_location{ $tax }  },
 713         {
 714           'taxnum'      => $tax_object->taxnum,
 715           'taxtype'     => ref($tax_object),
 716           'pkgnum'      => $tax_object->get('pkgnum'),
 717           'locationnum' => $tax_object->get('locationnum'),
 718           'amount'      => sprintf('%.2f', $amount ),
 719         };
 720     }
 721
 722     $tax_rate_location{ $tax } ||= [];
 723     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 724       my $taxratelocationnum =
 725         $tax_object->tax_rate_location->taxratelocationnum;
 726       push @{ $tax_rate_location{ $tax }  },
 727         {
 728           'taxnum'             => $tax_object->taxnum,
 729           'taxtype'            => ref($tax_object),
 730           'amount'             => sprintf('%.2f', $amount ),
 731           'locationtaxid'      => $tax_object->location,
 732           'taxratelocationnum' => $taxratelocationnum,
 733         };
 734     }
 735
 736   }
 737
 738   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 739   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 740   foreach my $tax ( keys %$taxlisthash ) {
 741     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 742       next unless ref($_) eq 'FS::cust_bill_pkg';
 743
 744       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 745
 746       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 747       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 748           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 749         unless $packagemap{$_->pkgnum};
 750
 751       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 752            @cust_tax_exempt_pkg;
 753     }
 754   }
 755
 756   #consolidate and create tax line items
 757   warn "consolidating and generating...\n" if $DEBUG > 2;
 758   foreach my $taxname ( keys %taxname ) {
 759     my $tax = 0;
 760     my %seen = ();
 761     my @cust_bill_pkg_tax_location = ();
 762     my @cust_bill_pkg_tax_rate_location = ();
 763     warn "adding $taxname\n" if $DEBUG > 1;
 764     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 765       next if $seen{$taxitem}++;
 766       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 767       $tax += $tax{$taxitem};
 768       push @cust_bill_pkg_tax_location,
 769         map { new FS::cust_bill_pkg_tax_location $_ }
 770             @{ $tax_location{ $taxitem } };
 771       push @cust_bill_pkg_tax_rate_location,
 772         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 773             @{ $tax_rate_location{ $taxitem } };
 774     }
 775     next unless $tax;
 776
 777     $tax = sprintf('%.2f', $tax );
 778
 779     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 780                                                    'disabled'     => '',
 781                                                  },
 782                                );
 783
 784     my @display = ();
 785     if ( $pkg_category and
 786          $conf->config('invoice_latexsummary') ||
 787          $conf->config('invoice_htmlsummary')
 788        )
 789     {
 790
 791       my %hash = (  'section' => $pkg_category->categoryname );
 792       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 793
 794     }
 795
 796     push @tax_line_items, new FS::cust_bill_pkg {
 797       'pkgnum'   => 0,
 798       'setup'    => $tax,
 799       'recur'    => 0,
 800       'sdate'    => '',
 801       'edate'    => '',
 802       'itemdesc' => $taxname,
 803       'display'  => \@display,
 804       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 805       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 806     };
 807
 808   }
 809
 810   \@tax_line_items;
 811 }
 812
 813 sub _make_lines {
 814   my ($self, %params) = @_;
 815
 816   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 817
 818   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 819   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 820   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 821   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 822   my $total_setup = $params{setup} or die "no setup accumulator specified";
 823   my $total_recur = $params{recur} or die "no recur accumulator specified";
 824   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 825   my $time = $params{'time'} or die "no time specified";
 826   my (%options) = %{$params{options}};
 827
 828   my $dbh = dbh;
 829   my $real_pkgpart = $params{real_pkgpart};
 830   my %hash = $cust_pkg->hash;
 831   my $old_cust_pkg = new FS::cust_pkg \%hash;
 832
 833   my @details = ();
 834   my @discounts = ();
 835   my $lineitems = 0;
 836
 837   $cust_pkg->pkgpart($part_pkg->pkgpart);
 838
 839   ###
 840   # bill setup
 841   ###
 842
 843   my $setup = 0;
 844   my $unitsetup = 0;
 845   if (     ! $options{recurring_only}
 846        and ! $options{cancel}
 847        and ( $options{'resetup'}
 848              || ( ! $cust_pkg->setup
 849                   && ( ! $cust_pkg->start_date
 850                        || $cust_pkg->start_date <= $self->day_end($time)
 851                      )
 852                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 853                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 854                             ! $cust_pkg->getfield('susp')
 855                           )
 856                      )
 857                 )
 858            )
 859      )
 860   {
 861
 862     warn "    bill setup\n" if $DEBUG > 1;
 863
 864     unless ( $cust_pkg->waive_setup ) {
 865         $lineitems++;
 866
 867         $setup = eval { $cust_pkg->calc_setup( $time, \@details ) };
 868         return "$@ running calc_setup for $cust_pkg\n"
 869           if $@;
 870
 871         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 872     }
 873
 874     $cust_pkg->setfield('setup', $time)
 875       unless $cust_pkg->setup;
 876           #do need it, but it won't get written to the db
 877           #|| $cust_pkg->pkgpart != $real_pkgpart;
 878
 879     $cust_pkg->setfield('start_date', '')
 880       if $cust_pkg->start_date;
 881
 882   }
 883
 884   ###
 885   # bill recurring fee
 886   ###
 887
 888   #XXX unit stuff here too
 889   my $recur = 0;
 890   my $unitrecur = 0;
 891   my $sdate;
 892   if (     ! $cust_pkg->start_date
 893        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 894        and
 895             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $self->day_end($time) )
 896          || ( $part_pkg->plan eq 'voip_cdr'
 897                && $part_pkg->option('bill_every_call')
 898             )
 899          || $options{cancel}
 900   ) {
 901
 902     # XXX should this be a package event?  probably.  events are called
 903     # at collection time at the moment, though...
 904     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 905       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 906       #don't want to reset usage just cause we want a line item??
 907       #&& $part_pkg->pkgpart == $real_pkgpart;
 908
 909     warn "    bill recur\n" if $DEBUG > 1;
 910     $lineitems++;
 911
 912     # XXX shared with $recur_prog
 913     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 914              || $cust_pkg->setup
 915              || $time;
 916
 917     #over two params!  lets at least switch to a hashref for the rest...
 918     my $increment_next_bill = ( $part_pkg->freq ne '0'
 919                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $self->day_end($time)
 920                                 && !$options{cancel}
 921                               );
 922     my %param = ( 'precommit_hooks'     => $precommit_hooks,
 923                   'increment_next_bill' => $increment_next_bill,
 924                   'discounts'           => \@discounts,
 925                   'real_pkgpart'        => $real_pkgpart,
 926                   'freq_override'       => $options{freq_override} || '',
 927                   'setup_fee'           => 0,
 928                 );
 929
 930     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
 931
 932     # There may be some part_pkg for which this is wrong.  Only those
 933     # which can_discount are supported.
 934     # (the UI should prevent adding discounts to these at the moment)
 935
 936     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
 937          " for pkgpart ". $cust_pkg->pkgpart.
 938          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
 939       if $DEBUG > 2;
 940
 941     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
 942     return "$@ running $method for $cust_pkg\n"
 943       if ( $@ );
 944
 945     if ( $increment_next_bill ) {
 946
 947       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
 948       return "unparsable frequency: ". $part_pkg->freq
 949         if $next_bill == -1;
 950
 951       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
 952       # only for figuring next bill date, nothing else, so, reset $sdate again
 953       # here
 954       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 955       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
 956       $cust_pkg->last_bill($sdate);
 957
 958       $cust_pkg->setfield('bill', $next_bill );
 959
 960     }
 961
 962     if ( $param{'setup_fee'} ) {
 963       # Add an additional setup fee at the billing stage.
 964       # Used for prorate_defer_bill.
 965       $setup += $param{'setup_fee'};
 966       $unitsetup += $param{'setup_fee'};
 967       $lineitems++;
 968     }
 969
 970   }
 971
 972   warn "\$setup is undefined" unless defined($setup);
 973   warn "\$recur is undefined" unless defined($recur);
 974   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 975
 976   ###
 977   # If there's line items, create em cust_bill_pkg records
 978   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
 979   ###
 980
 981   if ( $lineitems ) {
 982
 983     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
 984       # hmm.. and if just the options are modified in some weird price plan?
 985
 986       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
 987         if $DEBUG >1;
 988
 989       my $error = $cust_pkg->replace( $old_cust_pkg,
 990                                       'depend_jobnum'=>$options{depend_jobnum},
 991                                       'options' => { $cust_pkg->options },
 992                                     )
 993         unless $options{no_commit};
 994       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
 995         if $error; #just in case
 996     }
 997
 998     $setup = sprintf( "%.2f", $setup );
 999     $recur = sprintf( "%.2f", $recur );
1000     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1001       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1002     }
1003     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1004       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1005     }
1006
1007     my $discount_show_always = ($recur == 0 && scalar(@discounts)
1008                                 && $conf->exists('discount-show-always'));
1009
1010     if ( $setup != 0 ||
1011          $recur != 0 ||
1012          (!$part_pkg->hidden && $options{has_hidden}) || #include some $0 lines
1013          $discount_show_always )
1014     {
1015
1016       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1017         if $DEBUG > 1;
1018
1019       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1020       if ( $DEBUG > 1 ) {
1021         warn "      adding customer package invoice detail: $_\n"
1022           foreach @cust_pkg_detail;
1023       }
1024       push @details, @cust_pkg_detail;
1025
1026       my $cust_bill_pkg = new FS::cust_bill_pkg {
1027         'pkgnum'    => $cust_pkg->pkgnum,
1028         'setup'     => $setup,
1029         'unitsetup' => $unitsetup,
1030         'recur'     => $recur,
1031         'unitrecur' => $unitrecur,
1032         'quantity'  => $cust_pkg->quantity,
1033         'details'   => \@details,
1034         'discounts' => \@discounts,
1035         'hidden'    => $part_pkg->hidden,
1036         'freq'      => $part_pkg->freq,
1037       };
1038
1039       if ( $part_pkg->recur_temporality eq 'preceding' ) {
1040         $cust_bill_pkg->sdate( $hash{last_bill} );
1041         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1042         $cust_bill_pkg->edate( $time ) if $options{cancel};
1043       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1044         $cust_bill_pkg->sdate( $sdate );
1045         $cust_bill_pkg->edate( $cust_pkg->bill );
1046         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1047       }
1048
1049       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1050         unless $part_pkg->pkgpart == $real_pkgpart;
1051
1052       $$total_setup += $setup;
1053       $$total_recur += $recur;
1054
1055       ###
1056       # handle taxes
1057       ###
1058
1059       unless ( $discount_show_always ) {
1060           my $error =
1061             $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1062           return $error if $error;
1063       }
1064
1065       push @$cust_bill_pkgs, $cust_bill_pkg;
1066
1067     } #if $setup != 0 || $recur != 0
1068
1069   } #if $line_items
1070
1071   '';
1072
1073 }
1074
1075 sub _handle_taxes {
1076   my $self = shift;
1077   my $part_pkg = shift;
1078   my $taxlisthash = shift;
1079   my $cust_bill_pkg = shift;
1080   my $cust_pkg = shift;
1081   my $invoice_time = shift;
1082   my $real_pkgpart = shift;
1083   my $options = shift;
1084
1085   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1086
1087   my %cust_bill_pkg = ();
1088   my %taxes = ();
1089
1090   my @classes;
1091   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1092   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1093   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1094   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1095
1096   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1097
1098     if ( $conf->exists('enable_taxproducts')
1099          && ( scalar($part_pkg->part_pkg_taxoverride)
1100               || $part_pkg->has_taxproduct
1101             )
1102        )
1103     {
1104
1105       foreach my $class (@classes) {
1106         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1107         return $err_or_ref unless ref($err_or_ref);
1108         $taxes{$class} = $err_or_ref;
1109       }
1110
1111       unless (exists $taxes{''}) {
1112         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1113         return $err_or_ref unless ref($err_or_ref);
1114         $taxes{''} = $err_or_ref;
1115       }
1116
1117     } else {
1118
1119       my @loc_keys = qw( city county state country );
1120       my %taxhash;
1121       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1122         my $cust_location = $cust_pkg->cust_location;
1123         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1124       } else {
1125         my $prefix =
1126           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1127           ? 'ship_'
1128           : '';
1129         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1130       }
1131
1132       $taxhash{'taxclass'} = $part_pkg->taxclass;
1133
1134       my @taxes = ();
1135       my %taxhash_elim = %taxhash;
1136       my @elim = qw( city county state );
1137       do {
1138
1139         #first try a match with taxclass
1140         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1141
1142         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1143           #then try a match without taxclass
1144           my %no_taxclass = %taxhash_elim;
1145           $no_taxclass{ 'taxclass' } = '';
1146           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1147         }
1148
1149         $taxhash_elim{ shift(@elim) } = '';
1150
1151       } while ( !scalar(@taxes) && scalar(@elim) );
1152
1153       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1154                     @taxes
1155         if $self->cust_main_exemption; #just to be safe
1156
1157       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1158         foreach (@taxes) {
1159           $_->set('pkgnum',      $cust_pkg->pkgnum );
1160           $_->set('locationnum', $cust_pkg->locationnum );
1161         }
1162       }
1163
1164       $taxes{''} = [ @taxes ];
1165       $taxes{'setup'} = [ @taxes ];
1166       $taxes{'recur'} = [ @taxes ];
1167       $taxes{$_} = [ @taxes ] foreach (@classes);
1168
1169       # # maybe eliminate this entirely, along with all the 0% records
1170       # unless ( @taxes ) {
1171       #   return
1172       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1173       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1174       # }
1175
1176     } #if $conf->exists('enable_taxproducts') ...
1177
1178   }
1179
1180   my @display = ();
1181   my $separate = $conf->exists('separate_usage');
1182   my $temp_pkg = new FS::cust_pkg { pkgpart => $real_pkgpart };
1183   my $usage_mandate = $temp_pkg->part_pkg->option('usage_mandate', 'Hush!');
1184   my $section = $temp_pkg->part_pkg->categoryname;
1185   if ( $separate || $section || $usage_mandate ) {
1186
1187     my %hash = ( 'section' => $section );
1188
1189     $section = $temp_pkg->part_pkg->option('usage_section', 'Hush!');
1190     my $summary = $temp_pkg->part_pkg->option('summarize_usage', 'Hush!');
1191     if ( $separate ) {
1192       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1193       push @display, new FS::cust_bill_pkg_display { type => 'R', %hash };
1194     } else {
1195       push @display, new FS::cust_bill_pkg_display
1196                        { type => '',
1197                          %hash,
1198                          ( ( $usage_mandate ) ? ( 'summary' => 'Y' ) : () ),
1199                        };
1200     }
1201
1202     if ($separate && $section && $summary) {
1203       push @display, new FS::cust_bill_pkg_display { type    => 'U',
1204                                                      summary => 'Y',
1205                                                      %hash,
1206                                                    };
1207     }
1208     if ($usage_mandate || $section && $summary) {
1209       $hash{post_total} = 'Y';
1210     }
1211
1212     if ($separate || $usage_mandate) {
1213       $hash{section} = $section if ($separate || $usage_mandate);
1214       push @display, new FS::cust_bill_pkg_display { type => 'U', %hash };
1215     }
1216
1217   }
1218   $cust_bill_pkg->set('display', \@display);
1219
1220   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1221   foreach my $key (keys %tax_cust_bill_pkg) {
1222     my @taxes = @{ $taxes{$key} || [] };
1223     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1224
1225     my %localtaxlisthash = ();
1226     foreach my $tax ( @taxes ) {
1227
1228       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1229 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1230 #                  ' locationnum'. $cust_pkg->locationnum
1231 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1232
1233       $taxlisthash->{ $taxname } ||= [ $tax ];
1234       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1235
1236       $localtaxlisthash{ $taxname } ||= [ $tax ];
1237       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1238
1239     }
1240
1241     warn "finding taxed taxes...\n" if $DEBUG > 2;
1242     foreach my $tax ( keys %localtaxlisthash ) {
1243       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1244       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1245         if $DEBUG > 2;
1246       next unless $tax_object->can('tax_on_tax');
1247
1248       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1249         my $totname = ref( $tot ). ' '. $tot->taxnum;
1250
1251         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1252           if $DEBUG > 2;
1253         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1254                                                              # existing taxes
1255         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1256         my $hashref_or_error =
1257           $tax_object->taxline( $localtaxlisthash{$tax},
1258                                 'custnum'      => $self->custnum,
1259                                 'invoice_time' => $invoice_time,
1260                               );
1261         return $hashref_or_error
1262           unless ref($hashref_or_error);
1263
1264         $taxlisthash->{ $totname } ||= [ $tot ];
1265         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1266
1267       }
1268     }
1269
1270   }
1271
1272   '';
1273 }
1274
1275 sub _gather_taxes {
1276   my $self = shift;
1277   my $part_pkg = shift;
1278   my $class = shift;
1279   my $cust_pkg = shift;
1280
1281   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1282
1283   my $geocode;
1284   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1285     $geocode = $cust_pkg->cust_location->geocode('cch');
1286   } else {
1287     $geocode = $self->geocode('cch');
1288   }
1289
1290   my @taxes = ();
1291
1292   my @taxclassnums = map { $_->taxclassnum }
1293                      $part_pkg->part_pkg_taxoverride($class);
1294
1295   unless (@taxclassnums) {
1296     @taxclassnums = map { $_->taxclassnum }
1297                     grep { $_->taxable eq 'Y' }
1298                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1299   }
1300   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1301     if $DEBUG;
1302
1303   my $extra_sql =
1304     "AND (".
1305     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1306
1307   @taxes = qsearch({ 'table' => 'tax_rate',
1308                      'hashref' => { 'geocode' => $geocode, },
1309                      'extra_sql' => $extra_sql,
1310                   })
1311     if scalar(@taxclassnums);
1312
1313   warn "Found taxes ".
1314        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1315    if $DEBUG;
1316
1317   [ @taxes ];
1318
1319 }
1320
1321 =item collect [ HASHREF | OPTION => VALUE ... ]
1322
1323 (Attempt to) collect money for this customer's outstanding invoices (see
1324 L<FS::cust_bill>).  Usually used after the bill method.
1325
1326 Actions are now triggered by billing events; see L<FS::part_event> and the
1327 billing events web interface.  Old-style invoice events (see
1328 L<FS::part_bill_event>) have been deprecated.
1329
1330 If there is an error, returns the error, otherwise returns false.
1331
1332 Options are passed as name-value pairs.
1333
1334 Currently available options are:
1335
1336 =over 4
1337
1338 =item invoice_time
1339
1340 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1341
1342 =item retry
1343
1344 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1345
1346 =item check_freq
1347
1348 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1349
1350 =item quiet
1351
1352 set true to surpress email card/ACH decline notices.
1353
1354 =item debug
1355
1356 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1357
1358 =back
1359
1360 # =item payby
1361 #
1362 # allows for one time override of normal customer billing method
1363
1364 =cut
1365
1366 sub collect {
1367   my( $self, %options ) = @_;
1368
1369   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1370
1371   my $invoice_time = $options{'invoice_time'} || time;
1372
1373   #put below somehow?
1374   local $SIG{HUP} = 'IGNORE';
1375   local $SIG{INT} = 'IGNORE';
1376   local $SIG{QUIT} = 'IGNORE';
1377   local $SIG{TERM} = 'IGNORE';
1378   local $SIG{TSTP} = 'IGNORE';
1379   local $SIG{PIPE} = 'IGNORE';
1380
1381   my $oldAutoCommit = $FS::UID::AutoCommit;
1382   local $FS::UID::AutoCommit = 0;
1383   my $dbh = dbh;
1384
1385   $self->select_for_update; #mutex
1386
1387   if ( $DEBUG ) {
1388     my $balance = $self->balance;
1389     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1390   }
1391
1392   if ( exists($options{'retry_card'}) ) {
1393     carp 'retry_card option passed to collect is deprecated; use retry';
1394     $options{'retry'} ||= $options{'retry_card'};
1395   }
1396   if ( exists($options{'retry'}) && $options{'retry'} ) {
1397     my $error = $self->retry_realtime;
1398     if ( $error ) {
1399       $dbh->rollback if $oldAutoCommit;
1400       return $error;
1401     }
1402   }
1403
1404   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1405
1406   #never want to roll back an event just because it returned an error
1407   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1408
1409   $self->do_cust_event(
1410     'debug'      => ( $options{'debug'} || 0 ),
1411     'time'       => $invoice_time,
1412     'check_freq' => $options{'check_freq'},
1413     'stage'      => 'collect',
1414   );
1415
1416 }
1417
1418 =item retry_realtime
1419
1420 Schedules realtime / batch  credit card / electronic check / LEC billing
1421 events for for retry.  Useful if card information has changed or manual
1422 retry is desired.  The 'collect' method must be called to actually retry
1423 the transaction.
1424
1425 Implementation details: For either this customer, or for each of this
1426 customer's open invoices, changes the status of the first "done" (with
1427 statustext error) realtime processing event to "failed".
1428
1429 =cut
1430
1431 sub retry_realtime {
1432   my $self = shift;
1433
1434   local $SIG{HUP} = 'IGNORE';
1435   local $SIG{INT} = 'IGNORE';
1436   local $SIG{QUIT} = 'IGNORE';
1437   local $SIG{TERM} = 'IGNORE';
1438   local $SIG{TSTP} = 'IGNORE';
1439   local $SIG{PIPE} = 'IGNORE';
1440
1441   my $oldAutoCommit = $FS::UID::AutoCommit;
1442   local $FS::UID::AutoCommit = 0;
1443   my $dbh = dbh;
1444
1445   #a little false laziness w/due_cust_event (not too bad, really)
1446
1447   my $join = FS::part_event_condition->join_conditions_sql;
1448   my $order = FS::part_event_condition->order_conditions_sql;
1449   my $mine =
1450   '( '
1451    . join ( ' OR ' , map {
1452     "( part_event.eventtable = " . dbh->quote($_)
1453     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1454    } FS::part_event->eventtables)
1455    . ') ';
1456
1457   #here is the agent virtualization
1458   my $agent_virt = " (    part_event.agentnum IS NULL
1459                        OR part_event.agentnum = ". $self->agentnum. ' )';
1460
1461   #XXX this shouldn't be hardcoded, actions should declare it...
1462   my @realtime_events = qw(
1463     cust_bill_realtime_card
1464     cust_bill_realtime_check
1465     cust_bill_realtime_lec
1466     cust_bill_batch
1467   );
1468
1469   my $is_realtime_event = ' ( '. join(' OR ', map "part_event.action = '$_'",
1470                                                   @realtime_events
1471                                      ).
1472                           ' ) ';
1473
1474   my @cust_event = qsearchs({
1475     'table'     => 'cust_event',
1476     'select'    => 'cust_event.*',
1477     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1478     'hashref'   => { 'status' => 'done' },
1479     'extra_sql' => " AND statustext IS NOT NULL AND statustext != '' ".
1480                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1481   });
1482
1483   my %seen_invnum = ();
1484   foreach my $cust_event (@cust_event) {
1485
1486     #max one for the customer, one for each open invoice
1487     my $cust_X = $cust_event->cust_X;
1488     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1489                           ? $cust_X->invnum
1490                           : 0
1491                         }++
1492          or $cust_event->part_event->eventtable eq 'cust_bill'
1493             && ! $cust_X->owed;
1494
1495     my $error = $cust_event->retry;
1496     if ( $error ) {
1497       $dbh->rollback if $oldAutoCommit;
1498       return "error scheduling event for retry: $error";
1499     }
1500
1501   }
1502
1503   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1504   '';
1505
1506 }
1507
1508 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1509
1510 Runs billing events; see L<FS::part_event> and the billing events web
1511 interface.
1512
1513 If there is an error, returns the error, otherwise returns false.
1514
1515 Options are passed as name-value pairs.
1516
1517 Currently available options are:
1518
1519 =over 4
1520
1521 =item time
1522
1523 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1524
1525 =item check_freq
1526
1527 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1528
1529 =item stage
1530
1531 "collect" (the default) or "pre-bill"
1532
1533 =item quiet
1534
1535 set true to surpress email card/ACH decline notices.
1536
1537 =item debug
1538
1539 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1540
1541 =back
1542 =cut
1543
1544 # =item payby
1545 #
1546 # allows for one time override of normal customer billing method
1547
1548 # =item retry
1549 #
1550 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1551
1552 sub do_cust_event {
1553   my( $self, %options ) = @_;
1554
1555   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1556
1557   my $time = $options{'time'} || time;
1558
1559   #put below somehow?
1560   local $SIG{HUP} = 'IGNORE';
1561   local $SIG{INT} = 'IGNORE';
1562   local $SIG{QUIT} = 'IGNORE';
1563   local $SIG{TERM} = 'IGNORE';
1564   local $SIG{TSTP} = 'IGNORE';
1565   local $SIG{PIPE} = 'IGNORE';
1566
1567   my $oldAutoCommit = $FS::UID::AutoCommit;
1568   local $FS::UID::AutoCommit = 0;
1569   my $dbh = dbh;
1570
1571   $self->select_for_update; #mutex
1572
1573   if ( $DEBUG ) {
1574     my $balance = $self->balance;
1575     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1576   }
1577
1578 #  if ( exists($options{'retry_card'}) ) {
1579 #    carp 'retry_card option passed to collect is deprecated; use retry';
1580 #    $options{'retry'} ||= $options{'retry_card'};
1581 #  }
1582 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1583 #    my $error = $self->retry_realtime;
1584 #    if ( $error ) {
1585 #      $dbh->rollback if $oldAutoCommit;
1586 #      return $error;
1587 #    }
1588 #  }
1589
1590   # false laziness w/pay_batch::import_results
1591
1592   my $due_cust_event = $self->due_cust_event(
1593     'debug'      => ( $options{'debug'} || 0 ),
1594     'time'       => $time,
1595     'check_freq' => $options{'check_freq'},
1596     'stage'      => ( $options{'stage'} || 'collect' ),
1597   );
1598   unless( ref($due_cust_event) ) {
1599     $dbh->rollback if $oldAutoCommit;
1600     return $due_cust_event;
1601   }
1602
1603   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1604   #never want to roll back an event just because it or a different one
1605   # returned an error
1606   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1607
1608   foreach my $cust_event ( @$due_cust_event ) {
1609
1610     #XXX lock event
1611
1612     #re-eval event conditions (a previous event could have changed things)
1613     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1614       #don't leave stray "new/locked" records around
1615       my $error = $cust_event->delete;
1616       return $error if $error;
1617       next;
1618     }
1619
1620     {
1621       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1622         if $options{'quiet'};
1623       warn "  running cust_event ". $cust_event->eventnum. "\n"
1624         if $DEBUG > 1;
1625
1626       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1627       if ( my $error = $cust_event->do_event() ) {
1628         #XXX wtf is this?  figure out a proper dealio with return value
1629         #from do_event
1630         return $error;
1631       }
1632     }
1633
1634   }
1635
1636   '';
1637
1638 }
1639
1640 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1641
1642 Inserts database records for and returns an ordered listref of new events due
1643 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1644 events are due, an empty listref is returned.  If there is an error, returns a
1645 scalar error message.
1646
1647 To actually run the events, call each event's test_condition method, and if
1648 still true, call the event's do_event method.
1649
1650 Options are passed as a hashref or as a list of name-value pairs.  Available
1651 options are:
1652
1653 =over 4
1654
1655 =item check_freq
1656
1657 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1658
1659 =item stage
1660
1661 "collect" (the default) or "pre-bill"
1662
1663 =item time
1664
1665 "Current time" for the events.
1666
1667 =item debug
1668
1669 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1670
1671 =item eventtable
1672
1673 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1674
1675 =item objects
1676
1677 Explicitly pass the objects to be tested (typically used with eventtable).
1678
1679 =item testonly
1680
1681 Set to true to return the objects, but not actually insert them into the
1682 database.
1683
1684 =back
1685
1686 =cut
1687
1688 sub due_cust_event {
1689   my $self = shift;
1690   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1691
1692   #???
1693   #my $DEBUG = $opt{'debug'}
1694   local($DEBUG) = $opt{'debug'}
1695     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1696   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1697
1698   warn "$me due_cust_event called with options ".
1699        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1700     if $DEBUG;
1701
1702   $opt{'time'} ||= time;
1703
1704   local $SIG{HUP} = 'IGNORE';
1705   local $SIG{INT} = 'IGNORE';
1706   local $SIG{QUIT} = 'IGNORE';
1707   local $SIG{TERM} = 'IGNORE';
1708   local $SIG{TSTP} = 'IGNORE';
1709   local $SIG{PIPE} = 'IGNORE';
1710
1711   my $oldAutoCommit = $FS::UID::AutoCommit;
1712   local $FS::UID::AutoCommit = 0;
1713   my $dbh = dbh;
1714
1715   $self->select_for_update #mutex
1716     unless $opt{testonly};
1717
1718   ###
1719   # find possible events (initial search)
1720   ###
1721
1722   my @cust_event = ();
1723
1724   my @eventtable = $opt{'eventtable'}
1725                      ? ( $opt{'eventtable'} )
1726                      : FS::part_event->eventtables_runorder;
1727
1728   my $check_freq = $opt{'check_freq'} || '1d';
1729
1730   foreach my $eventtable ( @eventtable ) {
1731
1732     my @objects;
1733     if ( $opt{'objects'} ) {
1734
1735       @objects = @{ $opt{'objects'} };
1736
1737     } else {
1738
1739       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1740       if ( $eventtable eq 'cust_main' ) {
1741         @objects = ( $self );
1742       } else {
1743
1744         my $cm_join =
1745           "LEFT JOIN cust_main USING ( custnum )";
1746
1747         #some false laziness w/Cron::bill bill_where
1748
1749         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1750         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1751                                                            'time'=>$opt{'time'},
1752                                                                   );
1753         $where = $where ? "AND $where" : '';
1754
1755         my $are_part_event =
1756           "EXISTS ( SELECT 1 FROM part_event $join
1757                       WHERE check_freq = '$check_freq'
1758                         AND eventtable = '$eventtable'
1759                         AND ( disabled = '' OR disabled IS NULL )
1760                         $where
1761                   )
1762           ";
1763         #eofalse
1764
1765         @objects = $self->$eventtable(
1766                      'addl_from' => $cm_join,
1767                      'extra_sql' => " AND $are_part_event",
1768                    );
1769       }
1770
1771     }
1772
1773     my @e_cust_event = ();
1774
1775     my $cross = "CROSS JOIN $eventtable";
1776     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1777       unless $eventtable eq 'cust_main';
1778
1779     foreach my $object ( @objects ) {
1780
1781       #this first search uses the condition_sql magic for optimization.
1782       #the more possible events we can eliminate in this step the better
1783
1784       my $cross_where = '';
1785       my $pkey = $object->primary_key;
1786       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1787
1788       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1789       my $extra_sql =
1790         FS::part_event_condition->where_conditions_sql( $eventtable,
1791                                                         'time'=>$opt{'time'}
1792                                                       );
1793       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1794
1795       $extra_sql = "AND $extra_sql" if $extra_sql;
1796
1797       #here is the agent virtualization
1798       $extra_sql .= " AND (    part_event.agentnum IS NULL
1799                             OR part_event.agentnum = ". $self->agentnum. ' )';
1800
1801       $extra_sql .= " $order";
1802
1803       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1804         if $opt{'debug'} > 2;
1805       my @part_event = qsearch( {
1806         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1807         'select'    => 'part_event.*',
1808         'table'     => 'part_event',
1809         'addl_from' => "$cross $join",
1810         'hashref'   => { 'check_freq' => $check_freq,
1811                          'eventtable' => $eventtable,
1812                          'disabled'   => '',
1813                        },
1814         'extra_sql' => "AND $cross_where $extra_sql",
1815       } );
1816
1817       if ( $DEBUG > 2 ) {
1818         my $pkey = $object->primary_key;
1819         warn "      ". scalar(@part_event).
1820              " possible events found for $eventtable ". $object->$pkey(). "\n";
1821       }
1822
1823       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1824
1825     }
1826
1827     warn "    ". scalar(@e_cust_event).
1828          " subtotal possible cust events found for $eventtable\n"
1829       if $DEBUG > 1;
1830
1831     push @cust_event, @e_cust_event;
1832
1833   }
1834
1835   warn "  ". scalar(@cust_event).
1836        " total possible cust events found in initial search\n"
1837     if $DEBUG; # > 1;
1838
1839
1840   ##
1841   # test stage
1842   ##
1843
1844   $opt{stage} ||= 'collect';
1845   @cust_event =
1846     grep { my $stage = $_->part_event->event_stage;
1847            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1848          }
1849          @cust_event;
1850
1851   ##
1852   # test conditions
1853   ##
1854
1855   my %unsat = ();
1856
1857   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1858                                           'stats_hashref' => \%unsat ),
1859                      @cust_event;
1860
1861   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1862     if $DEBUG; # > 1;
1863
1864   warn "    invalid conditions not eliminated with condition_sql:\n".
1865        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1866     if keys %unsat && $DEBUG; # > 1;
1867
1868   ##
1869   # insert
1870   ##
1871
1872   unless( $opt{testonly} ) {
1873     foreach my $cust_event ( @cust_event ) {
1874
1875       my $error = $cust_event->insert();
1876       if ( $error ) {
1877         $dbh->rollback if $oldAutoCommit;
1878         return $error;
1879       }
1880
1881     }
1882   }
1883
1884   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1885
1886   ##
1887   # return
1888   ##
1889
1890   warn "  returning events: ". Dumper(@cust_event). "\n"
1891     if $DEBUG > 2;
1892
1893   \@cust_event;
1894
1895 }
1896
1897 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1898
1899 Applies unapplied payments and credits.
1900
1901 In most cases, this new method should be used in place of sequential
1902 apply_payments and apply_credits methods.
1903
1904 A hash of optional arguments may be passed.  Currently "manual" is supported.
1905 If true, a payment receipt is sent instead of a statement when
1906 'payment_receipt_email' configuration option is set.
1907
1908 If there is an error, returns the error, otherwise returns false.
1909
1910 =cut
1911
1912 sub apply_payments_and_credits {
1913   my( $self, %options ) = @_;
1914
1915   local $SIG{HUP} = 'IGNORE';
1916   local $SIG{INT} = 'IGNORE';
1917   local $SIG{QUIT} = 'IGNORE';
1918   local $SIG{TERM} = 'IGNORE';
1919   local $SIG{TSTP} = 'IGNORE';
1920   local $SIG{PIPE} = 'IGNORE';
1921
1922   my $oldAutoCommit = $FS::UID::AutoCommit;
1923   local $FS::UID::AutoCommit = 0;
1924   my $dbh = dbh;
1925
1926   $self->select_for_update; #mutex
1927
1928   foreach my $cust_bill ( $self->open_cust_bill ) {
1929     my $error = $cust_bill->apply_payments_and_credits(%options);
1930     if ( $error ) {
1931       $dbh->rollback if $oldAutoCommit;
1932       return "Error applying: $error";
1933     }
1934   }
1935
1936   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1937   ''; #no error
1938
1939 }
1940
1941 =item apply_credits OPTION => VALUE ...
1942
1943 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1944 to outstanding invoice balances in chronological order (or reverse
1945 chronological order if the I<order> option is set to B<newest>) and returns the
1946 value of any remaining unapplied credits available for refund (see
1947 L<FS::cust_refund>).
1948
1949 Dies if there is an error.
1950
1951 =cut
1952
1953 sub apply_credits {
1954   my $self = shift;
1955   my %opt = @_;
1956
1957   local $SIG{HUP} = 'IGNORE';
1958   local $SIG{INT} = 'IGNORE';
1959   local $SIG{QUIT} = 'IGNORE';
1960   local $SIG{TERM} = 'IGNORE';
1961   local $SIG{TSTP} = 'IGNORE';
1962   local $SIG{PIPE} = 'IGNORE';
1963
1964   my $oldAutoCommit = $FS::UID::AutoCommit;
1965   local $FS::UID::AutoCommit = 0;
1966   my $dbh = dbh;
1967
1968   $self->select_for_update; #mutex
1969
1970   unless ( $self->total_unapplied_credits ) {
1971     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1972     return 0;
1973   }
1974
1975   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1976       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1977
1978   my @invoices = $self->open_cust_bill;
1979   @invoices = sort { $b->_date <=> $a->_date } @invoices
1980     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
1981
1982   if ( $conf->exists('pkg-balances') ) {
1983     # limit @credits to those w/ a pkgnum grepped from $self
1984     my %pkgnums = ();
1985     foreach my $i (@invoices) {
1986       foreach my $li ( $i->cust_bill_pkg ) {
1987         $pkgnums{$li->pkgnum} = 1;
1988       }
1989     }
1990     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
1991   }
1992
1993   my $credit;
1994
1995   foreach my $cust_bill ( @invoices ) {
1996
1997     if ( !defined($credit) || $credit->credited == 0) {
1998       $credit = pop @credits or last;
1999     }
2000
2001     my $owed;
2002     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2003       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2004     } else {
2005       $owed = $cust_bill->owed;
2006     }
2007     unless ( $owed > 0 ) {
2008       push @credits, $credit;
2009       next;
2010     }
2011
2012     my $amount = min( $credit->credited, $owed );
2013
2014     my $cust_credit_bill = new FS::cust_credit_bill ( {
2015       'crednum' => $credit->crednum,
2016       'invnum'  => $cust_bill->invnum,
2017       'amount'  => $amount,
2018     } );
2019     $cust_credit_bill->pkgnum( $credit->pkgnum )
2020       if $conf->exists('pkg-balances') && $credit->pkgnum;
2021     my $error = $cust_credit_bill->insert;
2022     if ( $error ) {
2023       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2024       die $error;
2025     }
2026
2027     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2028
2029   }
2030
2031   my $total_unapplied_credits = $self->total_unapplied_credits;
2032
2033   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2034
2035   return $total_unapplied_credits;
2036 }
2037
2038 =item apply_payments  [ OPTION => VALUE ... ]
2039
2040 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2041 to outstanding invoice balances in chronological order.
2042
2043  #and returns the value of any remaining unapplied payments.
2044
2045 A hash of optional arguments may be passed.  Currently "manual" is supported.
2046 If true, a payment receipt is sent instead of a statement when
2047 'payment_receipt_email' configuration option is set.
2048
2049 Dies if there is an error.
2050
2051 =cut
2052
2053 sub apply_payments {
2054   my( $self, %options ) = @_;
2055
2056   local $SIG{HUP} = 'IGNORE';
2057   local $SIG{INT} = 'IGNORE';
2058   local $SIG{QUIT} = 'IGNORE';
2059   local $SIG{TERM} = 'IGNORE';
2060   local $SIG{TSTP} = 'IGNORE';
2061   local $SIG{PIPE} = 'IGNORE';
2062
2063   my $oldAutoCommit = $FS::UID::AutoCommit;
2064   local $FS::UID::AutoCommit = 0;
2065   my $dbh = dbh;
2066
2067   $self->select_for_update; #mutex
2068
2069   #return 0 unless
2070
2071   my @payments = sort { $b->_date <=> $a->_date }
2072                  grep { $_->unapplied > 0 }
2073                  $self->cust_pay;
2074
2075   my @invoices = sort { $a->_date <=> $b->_date}
2076                  grep { $_->owed > 0 }
2077                  $self->cust_bill;
2078
2079   if ( $conf->exists('pkg-balances') ) {
2080     # limit @payments to those w/ a pkgnum grepped from $self
2081     my %pkgnums = ();
2082     foreach my $i (@invoices) {
2083       foreach my $li ( $i->cust_bill_pkg ) {
2084         $pkgnums{$li->pkgnum} = 1;
2085       }
2086     }
2087     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2088   }
2089
2090   my $payment;
2091
2092   foreach my $cust_bill ( @invoices ) {
2093
2094     if ( !defined($payment) || $payment->unapplied == 0 ) {
2095       $payment = pop @payments or last;
2096     }
2097
2098     my $owed;
2099     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2100       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2101     } else {
2102       $owed = $cust_bill->owed;
2103     }
2104     unless ( $owed > 0 ) {
2105       push @payments, $payment;
2106       next;
2107     }
2108
2109     my $amount = min( $payment->unapplied, $owed );
2110
2111     my $cust_bill_pay = new FS::cust_bill_pay ( {
2112       'paynum' => $payment->paynum,
2113       'invnum' => $cust_bill->invnum,
2114       'amount' => $amount,
2115     } );
2116     $cust_bill_pay->pkgnum( $payment->pkgnum )
2117       if $conf->exists('pkg-balances') && $payment->pkgnum;
2118     my $error = $cust_bill_pay->insert(%options);
2119     if ( $error ) {
2120       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2121       die $error;
2122     }
2123
2124     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2125
2126   }
2127
2128   my $total_unapplied_payments = $self->total_unapplied_payments;
2129
2130   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2131
2132   return $total_unapplied_payments;
2133 }
2134
2135 =back
2136
2137 =head1 FLOW
2138
2139   bill_and_collect
2140
2141     cancel_expired_pkgs
2142     suspend_adjourned_pkgs
2143
2144     bill
2145       (do_cust_event pre-bill)
2146       _make_lines
2147         _handle_taxes
2148           (vendor-only) _gather_taxes
2149       _omit_zero_value_bundles
2150       calculate_taxes
2151
2152     apply_payments_and_credits
2153     collect
2154       do_cust_event
2155         due_cust_event
2156
2157 =head1 BUGS
2158
2159 =head1 SEE ALSO
2160
2161 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2162
2163 =cut
2164
2165 1;