FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24 use FS::Log;
  25
  26 # 1 is mostly method/subroutine entry and options
  27 # 2 traces progress of some operations
  28 # 3 is even more information including possibly sensitive data
  29 $DEBUG = 0;
  30 $me = '[FS::cust_main::Billing]';
  31
  32 install_callback FS::UID sub {
  33   $conf = new FS::Conf;
  34   #yes, need it for stuff below (prolly should be cached)
  35 };
  36
  37 =head1 NAME
  38
  39 FS::cust_main::Billing - Billing mixin for cust_main
  40
  41 =head1 SYNOPSIS
  42
  43 =head1 DESCRIPTION
  44
  45 These methods are available on FS::cust_main objects.
  46
  47 =head1 METHODS
  48
  49 =over 4
  50
  51 =item bill_and_collect
  52
  53 Cancels and suspends any packages due, generates bills, applies payments and
  54 credits, and applies collection events to run cards, send bills and notices,
  55 etc.
  56
  57 By default, warns on errors and continues with the next operation (but see the
  58 "fatal" flag below).
  59
  60 Options are passed as name-value pairs.  Currently available options are:
  61
  62 =over 4
  63
  64 =item time
  65
  66 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  67
  68  use Date::Parse;
  69  ...
  70  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  71
  72 =item invoice_time
  73
  74 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  75
  76 =item check_freq
  77
  78 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  79
  80 =item resetup
  81
  82 If set true, re-charges setup fees.
  83
  84 =item fatal
  85
  86 If set any errors prevent subsequent operations from continusing.  If set
  87 specifically to "return", returns the error (or false, if there is no error).
  88 Any other true value causes errors to die.
  89
  90 =item debug
  91
  92 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  93
  94 =item job
  95
  96 Optional FS::queue entry to receive status updates.
  97
  98 =back
  99
 100 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 101 options of those methods are also available.
 102
 103 =cut
 104
 105 sub bill_and_collect {
 106   my( $self, %options ) = @_;
 107
 108   my $log = FS::Log->new('bill_and_collect');
 109   $log->debug('start', object => $self, agentnum => $self->agentnum);
 110
 111   my $error;
 112
 113   #$options{actual_time} not $options{time} because freeside-daily -d is for
 114   #pre-printing invoices
 115
 116   $options{'actual_time'} ||= time;
 117   my $job = $options{'job'};
 118
 119   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 120                         ? day_end( $options{actual_time} )
 121                         : $options{actual_time}
 122                     );
 123
 124   $job->update_statustext('0,cleaning expired packages') if $job;
 125   $error = $self->cancel_expired_pkgs( $actual_time );
 126   if ( $error ) {
 127     $error = "Error expiring custnum ". $self->custnum. ": $error";
 128     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 129     elsif ( $options{fatal}                                ) { die    $error; }
 130     else                                                     { warn   $error; }
 131   }
 132
 133   $error = $self->suspend_adjourned_pkgs( $actual_time );
 134   if ( $error ) {
 135     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 136     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 137     elsif ( $options{fatal}                                ) { die    $error; }
 138     else                                                     { warn   $error; }
 139   }
 140
 141   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 142   if ( $error ) {
 143     $error = "Error resuming custnum ".$self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('20,billing packages') if $job;
 150   $error = $self->bill( %options );
 151   if ( $error ) {
 152     $error = "Error billing custnum ". $self->custnum. ": $error";
 153     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 154     elsif ( $options{fatal}                                ) { die    $error; }
 155     else                                                     { warn   $error; }
 156   }
 157
 158   $job->update_statustext('50,applying payments and credits') if $job;
 159   $error = $self->apply_payments_and_credits;
 160   if ( $error ) {
 161     $error = "Error applying custnum ". $self->custnum. ": $error";
 162     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 163     elsif ( $options{fatal}                                ) { die    $error; }
 164     else                                                     { warn   $error; }
 165   }
 166
 167   $job->update_statustext('70,running collection events') if $job;
 168   unless ( $conf->exists('cancelled_cust-noevents')
 169            && ! $self->num_ncancelled_pkgs
 170   ) {
 171     $error = $self->collect( %options );
 172     if ( $error ) {
 173       $error = "Error collecting custnum ". $self->custnum. ": $error";
 174       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 175       elsif ($options{fatal}                               ) { die    $error; }
 176       else                                                   { warn   $error; }
 177     }
 178   }
 179   $job->update_statustext('100,finished') if $job;
 180   $log->debug('finish', object => $self, agentnum => $self->agentnum);
 181
 182   '';
 183
 184 }
 185
 186 sub cancel_expired_pkgs {
 187   my ( $self, $time, %options ) = @_;
 188
 189   my @cancel_pkgs = $self->ncancelled_pkgs( {
 190     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 191   } );
 192
 193   my @errors = ();
 194
 195   foreach my $cust_pkg ( @cancel_pkgs ) {
 196     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 197     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 198                                            'reason_otaker' => $cpr->otaker
 199                                          )
 200                                        : ()
 201                                  );
 202     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 203   }
 204
 205   join(' / ', @errors);
 206
 207 }
 208
 209 sub suspend_adjourned_pkgs {
 210   my ( $self, $time, %options ) = @_;
 211
 212   my @susp_pkgs = $self->ncancelled_pkgs( {
 213     'extra_sql' =>
 214       " AND ( susp IS NULL OR susp = 0 )
 215         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 216               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 217             )
 218       ",
 219   } );
 220
 221   #only because there's no SQL test for is_prepaid :/
 222   @susp_pkgs =
 223     grep {     (    $_->part_pkg->is_prepaid
 224                  && $_->bill
 225                  && $_->bill < $time
 226                )
 227             || (    $_->adjourn
 228                  && $_->adjourn <= $time
 229                )
 230
 231          }
 232          @susp_pkgs;
 233
 234   my @errors = ();
 235
 236   foreach my $cust_pkg ( @susp_pkgs ) {
 237     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 238       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 239     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 240                                             'reason_otaker' => $cpr->otaker
 241                                           )
 242                                         : ()
 243                                   );
 244     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 245   }
 246
 247   join(' / ', @errors);
 248
 249 }
 250
 251 sub unsuspend_resumed_pkgs {
 252   my ( $self, $time, %options ) = @_;
 253
 254   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 255     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 256   } );
 257
 258   my @errors = ();
 259
 260   foreach my $cust_pkg ( @unsusp_pkgs ) {
 261     my $error = $cust_pkg->unsuspend( 'time' => $time );
 262     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 263   }
 264
 265   join(' / ', @errors);
 266
 267 }
 268
 269 =item bill OPTIONS
 270
 271 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 272 conjunction with the collect method by calling B<bill_and_collect>.
 273
 274 If there is an error, returns the error, otherwise returns false.
 275
 276 Options are passed as name-value pairs.  Currently available options are:
 277
 278 =over 4
 279
 280 =item resetup
 281
 282 If set true, re-charges setup fees.
 283
 284 =item recurring_only
 285
 286 If set true then only bill recurring charges, not setup, usage, one time
 287 charges, etc.
 288
 289 =item freq_override
 290
 291 If set, then override the normal frequency and look for a part_pkg_discount
 292 to take at that frequency.  This is appropriate only when the normal
 293 frequency for all packages is monthly, and is an error otherwise.  Use
 294 C<pkg_list> to limit the set of packages included in billing.
 295
 296 =item time
 297
 298 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 299
 300  use Date::Parse;
 301  ...
 302  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 303
 304 =item pkg_list
 305
 306 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 307
 308  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 309
 310 =item not_pkgpart
 311
 312 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 313
 314 =item invoice_time
 315
 316 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 317
 318 =item cancel
 319
 320 This boolean value informs the us that the package is being cancelled.  This
 321 typically might mean not charging the normal recurring fee but only usage
 322 fees since the last billing. Setup charges may be charged.  Not all package
 323 plans support this feature (they tend to charge 0).
 324
 325 =item no_usage_reset
 326
 327 Prevent the resetting of usage limits during this call.
 328
 329 =item no_commit
 330
 331 Do not save the generated bill in the database.  Useful with return_bill
 332
 333 =item return_bill
 334
 335 A list reference on which the generated bill(s) will be returned.
 336
 337 =item invoice_terms
 338
 339 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 340 terms or the default terms are used.
 341
 342 =back
 343
 344 =cut
 345
 346 sub bill {
 347   my( $self, %options ) = @_;
 348
 349   return '' if $self->payby eq 'COMP';
 350
 351   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 352
 353   warn "$me bill customer ". $self->custnum. "\n"
 354     if $DEBUG;
 355
 356   my $time = $options{'time'} || time;
 357   my $invoice_time = $options{'invoice_time'} || $time;
 358
 359   $options{'not_pkgpart'} ||= {};
 360   $options{'not_pkgpart'} = { map { $_ => 1 }
 361                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 362                             }
 363     unless ref($options{'not_pkgpart'});
 364
 365   local $SIG{HUP} = 'IGNORE';
 366   local $SIG{INT} = 'IGNORE';
 367   local $SIG{QUIT} = 'IGNORE';
 368   local $SIG{TERM} = 'IGNORE';
 369   local $SIG{TSTP} = 'IGNORE';
 370   local $SIG{PIPE} = 'IGNORE';
 371
 372   my $oldAutoCommit = $FS::UID::AutoCommit;
 373   local $FS::UID::AutoCommit = 0;
 374   my $dbh = dbh;
 375
 376   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 377     if $DEBUG;
 378
 379   $self->select_for_update; #mutex
 380
 381   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 382     if $DEBUG;
 383
 384   my $error = $self->do_cust_event(
 385     'debug'      => ( $options{'debug'} || 0 ),
 386     'time'       => $invoice_time,
 387     'check_freq' => $options{'check_freq'},
 388     'stage'      => 'pre-bill',
 389   )
 390     unless $options{no_commit};
 391   if ( $error ) {
 392     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 393     return $error;
 394   }
 395
 396   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 397     if $DEBUG;
 398
 399   #keep auto-charge and non-auto-charge line items separate
 400   my @passes = ( '', 'no_auto' );
 401
 402   my %cust_bill_pkg = map { $_ => [] } @passes;
 403
 404   ###
 405   # find the packages which are due for billing, find out how much they are
 406   # & generate invoice database.
 407   ###
 408
 409   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 410   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 411
 412   my %taxlisthash = map { $_ => {} } @passes;
 413
 414   my @precommit_hooks = ();
 415
 416   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 417   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 418
 419     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 420
 421     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 422
 423     #? to avoid use of uninitialized value errors... ?
 424     $cust_pkg->setfield('bill', '')
 425       unless defined($cust_pkg->bill);
 426
 427     #my $part_pkg = $cust_pkg->part_pkg;
 428
 429     my $real_pkgpart = $cust_pkg->pkgpart;
 430     my %hash = $cust_pkg->hash;
 431
 432     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 433     # suffer from performance issues
 434     $options{has_hidden} = 0;
 435     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 436     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 437
 438     foreach my $part_pkg ( @part_pkg ) {
 439
 440       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 441
 442       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 443
 444       my $next_bill = $cust_pkg->getfield('bill') || 0;
 445       my $error;
 446       while ( $next_bill <= $time ) {
 447         $error =
 448           $self->_make_lines( 'part_pkg'            => $part_pkg,
 449                               'cust_pkg'            => $cust_pkg,
 450                               'precommit_hooks'     => \@precommit_hooks,
 451                               'line_items'          => $cust_bill_pkg{$pass},
 452                               'setup'               => $total_setup{$pass},
 453                               'recur'               => $total_recur{$pass},
 454                               'tax_matrix'          => $taxlisthash{$pass},
 455                               'time'                => $time,
 456                               'real_pkgpart'        => $real_pkgpart,
 457                               'options'             => \%options,
 458                             );
 459
 460         # Stop if anything goes wrong
 461         last if $error;
 462
 463         # or if we're not incrementing the bill date.
 464         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 465
 466         $next_bill = $cust_pkg->getfield('bill') || 0;
 467
 468         #stop if -o was passed to freeside-daily
 469         last if $options{'one_recur'};
 470       }
 471       if ($error) {
 472         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 473         return $error;
 474       }
 475
 476     } #foreach my $part_pkg
 477
 478   } #foreach my $cust_pkg
 479
 480   #if the customer isn't on an automatic payby, everything can go on a single
 481   #invoice anyway?
 482   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 483     #merge everything into one list
 484   #}
 485
 486   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 487
 488     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 489
 490     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 491
 492     warn "$me billing pass $pass\n"
 493            #.Dumper(\@cust_bill_pkg)."\n"
 494       if $DEBUG > 2;
 495
 496     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 497            !$conf->exists('postal_invoice-recurring_only')
 498        )
 499     {
 500
 501       my $postal_pkg = $self->charge_postal_fee();
 502       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 503
 504         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 505         return "can't charge postal invoice fee for customer ".
 506           $self->custnum. ": $postal_pkg";
 507
 508       } elsif ( $postal_pkg ) {
 509
 510         my $real_pkgpart = $postal_pkg->pkgpart;
 511         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 512         # suffer from performance issues
 513         $options{has_hidden} = 0;
 514         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 515         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 516
 517         foreach my $part_pkg ( @part_pkg ) {
 518           my %postal_options = %options;
 519           delete $postal_options{cancel};
 520           my $error =
 521             $self->_make_lines( 'part_pkg'            => $part_pkg,
 522                                 'cust_pkg'            => $postal_pkg,
 523                                 'precommit_hooks'     => \@precommit_hooks,
 524                                 'line_items'          => \@cust_bill_pkg,
 525                                 'setup'               => $total_setup{$pass},
 526                                 'recur'               => $total_recur{$pass},
 527                                 'tax_matrix'          => $taxlisthash{$pass},
 528                                 'time'                => $time,
 529                                 'real_pkgpart'        => $real_pkgpart,
 530                                 'options'             => \%postal_options,
 531                               );
 532           if ($error) {
 533             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 534             return $error;
 535           }
 536         }
 537
 538         # it's silly to have a zero value postal_pkg, but....
 539         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 540
 541       }
 542
 543     }
 544
 545     my $listref_or_error =
 546       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 547
 548     unless ( ref( $listref_or_error ) ) {
 549       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 550       return $listref_or_error;
 551     }
 552
 553     foreach my $taxline ( @$listref_or_error ) {
 554       ${ $total_setup{$pass} } =
 555         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 556       push @cust_bill_pkg, $taxline;
 557     }
 558
 559     #add tax adjustments
 560     warn "adding tax adjustments...\n" if $DEBUG > 2;
 561     foreach my $cust_tax_adjustment (
 562       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 563                                        'billpkgnum' => '',
 564                                      }
 565              )
 566     ) {
 567
 568       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 569
 570       my $itemdesc = $cust_tax_adjustment->taxname;
 571       $itemdesc = '' if $itemdesc eq 'Tax';
 572
 573       push @cust_bill_pkg, new FS::cust_bill_pkg {
 574         'pkgnum'      => 0,
 575         'setup'       => $tax,
 576         'recur'       => 0,
 577         'sdate'       => '',
 578         'edate'       => '',
 579         'itemdesc'    => $itemdesc,
 580         'itemcomment' => $cust_tax_adjustment->comment,
 581         'cust_tax_adjustment' => $cust_tax_adjustment,
 582         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 583       };
 584
 585     }
 586
 587     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 588
 589     my @cust_bill = $self->cust_bill;
 590     my $balance = $self->balance;
 591     my $previous_balance = scalar(@cust_bill)
 592                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 593                              : 0;
 594
 595     $previous_balance += $cust_bill[$#cust_bill]->charged
 596       if scalar(@cust_bill);
 597     #my $balance_adjustments =
 598     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 599
 600     warn "creating the new invoice\n" if $DEBUG;
 601     #create the new invoice
 602     my $cust_bill = new FS::cust_bill ( {
 603       'custnum'             => $self->custnum,
 604       '_date'               => $invoice_time,
 605       'charged'             => $charged,
 606       'billing_balance'     => $balance,
 607       'previous_balance'    => $previous_balance,
 608       'invoice_terms'       => $options{'invoice_terms'},
 609       'cust_bill_pkg'       => \@cust_bill_pkg,
 610     } );
 611     $error = $cust_bill->insert unless $options{no_commit};
 612     if ( $error ) {
 613       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 614       return "can't create invoice for customer #". $self->custnum. ": $error";
 615     }
 616     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 617
 618   } #foreach my $pass ( keys %cust_bill_pkg )
 619
 620   foreach my $hook ( @precommit_hooks ) {
 621     eval {
 622       &{$hook}; #($self) ?
 623     } unless $options{no_commit};
 624     if ( $@ ) {
 625       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 626       return "$@ running precommit hook $hook\n";
 627     }
 628   }
 629
 630   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 631
 632   ''; #no error
 633 }
 634
 635 #discard bundled packages of 0 value
 636 sub _omit_zero_value_bundles {
 637   my @in = @_;
 638
 639   my @cust_bill_pkg = ();
 640   my @cust_bill_pkg_bundle = ();
 641   my $sum = 0;
 642   my $discount_show_always = 0;
 643
 644   foreach my $cust_bill_pkg ( @in ) {
 645
 646     $discount_show_always = ($cust_bill_pkg->get('discounts')
 647                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 648                                 && $conf->exists('discount-show-always'));
 649
 650     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 651          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 652          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 653       if $DEBUG > 0;
 654
 655     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 656       push @cust_bill_pkg, @cust_bill_pkg_bundle
 657         if $sum > 0
 658         || ($sum == 0 && (    $discount_show_always
 659                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 660                                    @cust_bill_pkg_bundle
 661                          )
 662            );
 663       @cust_bill_pkg_bundle = ();
 664       $sum = 0;
 665     }
 666
 667     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 668     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 669
 670   }
 671
 672   push @cust_bill_pkg, @cust_bill_pkg_bundle
 673     if $sum > 0
 674     || ($sum == 0 && (    $discount_show_always
 675                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 676                                @cust_bill_pkg_bundle
 677                      )
 678        );
 679
 680   warn "  _omit_zero_value_bundles: ". scalar(@in).
 681        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 682     if $DEBUG > 2;
 683
 684   (@cust_bill_pkg);
 685
 686 }
 687
 688 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 689
 690 This is a weird one.  Perhaps it should not even be exposed.
 691
 692 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 693 Usually used internally by bill method B<bill>.
 694
 695 If there is an error, returns the error, otherwise returns reference to a
 696 list of line items suitable for insertion.
 697
 698 =over 4
 699
 700 =item LINEITEMREF
 701
 702 An array ref of the line items being billed.
 703
 704 =item TAXHASHREF
 705
 706 A strange beast.  The keys to this hash are internal identifiers consisting
 707 of the name of the tax object type, a space, and its unique identifier ( e.g.
 708  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 709 item in the list is the tax object.  The remaining items are either line
 710 items or floating point values (currency amounts).
 711
 712 The taxes are calculated on this entity.  Calculated exemption records are
 713 transferred to the LINEITEMREF items on the assumption that they are related.
 714
 715 Read the source.
 716
 717 =item INVOICE_TIME
 718
 719 This specifies the date appearing on the associated invoice.  Some
 720 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 721
 722 =back
 723
 724 =cut
 725
 726 sub calculate_taxes {
 727   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 728
 729   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 730
 731   warn "$me calculate_taxes\n"
 732        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 733     if $DEBUG > 2;
 734
 735   my @tax_line_items = ();
 736
 737   # keys are tax names (as printed on invoices / itemdesc )
 738   # values are listrefs of taxlisthash keys (internal identifiers)
 739   my %taxname = ();
 740
 741   # keys are taxlisthash keys (internal identifiers)
 742   # values are (cumulative) amounts
 743   my %tax = ();
 744
 745   # keys are taxlisthash keys (internal identifiers)
 746   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 747   my %tax_location = ();
 748
 749   # keys are taxlisthash keys (internal identifiers)
 750   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 751   my %tax_rate_location = ();
 752
 753   foreach my $tax ( keys %$taxlisthash ) {
 754     my $tax_object = shift @{ $taxlisthash->{$tax} };
 755     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 756     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 757     my $hashref_or_error =
 758       $tax_object->taxline( $taxlisthash->{$tax},
 759                             'custnum'      => $self->custnum,
 760                             'invoice_time' => $invoice_time
 761                           );
 762     return $hashref_or_error unless ref($hashref_or_error);
 763
 764     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 765
 766     my $name   = $hashref_or_error->{'name'};
 767     my $amount = $hashref_or_error->{'amount'};
 768
 769     #warn "adding $amount as $name\n";
 770     $taxname{ $name } ||= [];
 771     push @{ $taxname{ $name } }, $tax;
 772
 773     $tax{ $tax } += $amount;
 774
 775     $tax_location{ $tax } ||= [];
 776     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 777       push @{ $tax_location{ $tax }  },
 778         {
 779           'taxnum'      => $tax_object->taxnum,
 780           'taxtype'     => ref($tax_object),
 781           'pkgnum'      => $tax_object->get('pkgnum'),
 782           'locationnum' => $tax_object->get('locationnum'),
 783           'amount'      => sprintf('%.2f', $amount ),
 784         };
 785     }
 786
 787     $tax_rate_location{ $tax } ||= [];
 788     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 789       my $taxratelocationnum =
 790         $tax_object->tax_rate_location->taxratelocationnum;
 791       push @{ $tax_rate_location{ $tax }  },
 792         {
 793           'taxnum'             => $tax_object->taxnum,
 794           'taxtype'            => ref($tax_object),
 795           'amount'             => sprintf('%.2f', $amount ),
 796           'locationtaxid'      => $tax_object->location,
 797           'taxratelocationnum' => $taxratelocationnum,
 798         };
 799     }
 800
 801   }
 802
 803   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 804   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 805   foreach my $tax ( keys %$taxlisthash ) {
 806     foreach ( @{ $taxlisthash->{$tax} }[1 .. scalar(@{ $taxlisthash->{$tax}}) - 1] ) {
 807       next unless ref($_) eq 'FS::cust_bill_pkg'; #IS needed for CCH tax-on-tax
 808
 809       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 810
 811       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 812       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 813           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 814         unless $packagemap{$_->pkgnum};
 815
 816       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 817            @cust_tax_exempt_pkg;
 818     }
 819   }
 820
 821   #consolidate and create tax line items
 822   warn "consolidating and generating...\n" if $DEBUG > 2;
 823   foreach my $taxname ( keys %taxname ) {
 824     my $tax = 0;
 825     my %seen = ();
 826     my @cust_bill_pkg_tax_location = ();
 827     my @cust_bill_pkg_tax_rate_location = ();
 828     warn "adding $taxname\n" if $DEBUG > 1;
 829     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 830       next if $seen{$taxitem}++;
 831       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 832       $tax += $tax{$taxitem};
 833       push @cust_bill_pkg_tax_location,
 834         map { new FS::cust_bill_pkg_tax_location $_ }
 835             @{ $tax_location{ $taxitem } };
 836       push @cust_bill_pkg_tax_rate_location,
 837         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 838             @{ $tax_rate_location{ $taxitem } };
 839     }
 840     next unless $tax;
 841
 842     $tax = sprintf('%.2f', $tax );
 843
 844     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 845                                                    'disabled'     => '',
 846                                                  },
 847                                );
 848
 849     my @display = ();
 850     if ( $pkg_category and
 851          $conf->config('invoice_latexsummary') ||
 852          $conf->config('invoice_htmlsummary')
 853        )
 854     {
 855
 856       my %hash = (  'section' => $pkg_category->categoryname );
 857       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 858
 859     }
 860
 861     push @tax_line_items, new FS::cust_bill_pkg {
 862       'pkgnum'   => 0,
 863       'setup'    => $tax,
 864       'recur'    => 0,
 865       'sdate'    => '',
 866       'edate'    => '',
 867       'itemdesc' => $taxname,
 868       'display'  => \@display,
 869       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 870       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 871     };
 872
 873   }
 874
 875   \@tax_line_items;
 876 }
 877
 878 sub _make_lines {
 879   my ($self, %params) = @_;
 880
 881   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 882
 883   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 884   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 885   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 886   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 887   my $total_setup = $params{setup} or die "no setup accumulator specified";
 888   my $total_recur = $params{recur} or die "no recur accumulator specified";
 889   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 890   my $time = $params{'time'} or die "no time specified";
 891   my (%options) = %{$params{options}};
 892
 893   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
 894     # this should never happen
 895     die 'freq_override billing attempted on non-monthly package '.
 896       $cust_pkg->pkgnum;
 897   }
 898
 899   my $dbh = dbh;
 900   my $real_pkgpart = $params{real_pkgpart};
 901   my %hash = $cust_pkg->hash;
 902   my $old_cust_pkg = new FS::cust_pkg \%hash;
 903
 904   my @details = ();
 905   my $lineitems = 0;
 906
 907   $cust_pkg->pkgpart($part_pkg->pkgpart);
 908
 909   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 910                      ? day_end( $time )
 911                      : $time
 912                  );
 913
 914   ###
 915   # bill setup
 916   ###
 917
 918   my $setup = 0;
 919   my $unitsetup = 0;
 920   my @setup_discounts = ();
 921   my %setup_param = ( 'discounts' => \@setup_discounts );
 922   if (     ! $options{recurring_only}
 923        and ! $options{cancel}
 924        and ( $options{'resetup'}
 925              || ( ! $cust_pkg->setup
 926                   && ( ! $cust_pkg->start_date
 927                        || $cust_pkg->start_date <= $cmp_time
 928                      )
 929                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 930                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 931                             ! $cust_pkg->getfield('susp')
 932                           )
 933                      )
 934                 )
 935            )
 936      )
 937   {
 938
 939     warn "    bill setup\n" if $DEBUG > 1;
 940
 941     unless ( $cust_pkg->waive_setup ) {
 942         $lineitems++;
 943
 944         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
 945         return "$@ running calc_setup for $cust_pkg\n"
 946           if $@;
 947
 948         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 949     }
 950
 951     $cust_pkg->setfield('setup', $time)
 952       unless $cust_pkg->setup;
 953           #do need it, but it won't get written to the db
 954           #|| $cust_pkg->pkgpart != $real_pkgpart;
 955
 956     $cust_pkg->setfield('start_date', '')
 957       if $cust_pkg->start_date;
 958
 959   }
 960
 961   ###
 962   # bill recurring fee
 963   ###
 964
 965   #XXX unit stuff here too
 966   my $recur = 0;
 967   my $unitrecur = 0;
 968   my @recur_discounts = ();
 969   my $sdate;
 970   if (     ! $cust_pkg->start_date
 971        and ( ! $cust_pkg->susp || $cust_pkg->option('suspend_bill',1)
 972                                || ( $part_pkg->option('suspend_bill', 1) )
 973                                      && ! $cust_pkg->option('no_suspend_bill',1)
 974                                   )
 975        and
 976             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
 977          || ( $part_pkg->plan eq 'voip_cdr'
 978                && $part_pkg->option('bill_every_call')
 979             )
 980          || $options{cancel}
 981   ) {
 982
 983     # XXX should this be a package event?  probably.  events are called
 984     # at collection time at the moment, though...
 985     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 986       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 987       #don't want to reset usage just cause we want a line item??
 988       #&& $part_pkg->pkgpart == $real_pkgpart;
 989
 990     warn "    bill recur\n" if $DEBUG > 1;
 991     $lineitems++;
 992
 993     # XXX shared with $recur_prog
 994     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 995              || $cust_pkg->setup
 996              || $time;
 997
 998     #over two params!  lets at least switch to a hashref for the rest...
 999     my $increment_next_bill = ( $part_pkg->freq ne '0'
1000                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1001                                 && !$options{cancel}
1002                               );
1003     my %param = ( %setup_param,
1004                   'precommit_hooks'     => $precommit_hooks,
1005                   'increment_next_bill' => $increment_next_bill,
1006                   'discounts'           => \@recur_discounts,
1007                   'real_pkgpart'        => $real_pkgpart,
1008                   'freq_override'       => $options{freq_override} || '',
1009                   'setup_fee'           => 0,
1010                 );
1011
1012     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1013
1014     # There may be some part_pkg for which this is wrong.  Only those
1015     # which can_discount are supported.
1016     # (the UI should prevent adding discounts to these at the moment)
1017
1018     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1019          " for pkgpart ". $cust_pkg->pkgpart.
1020          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1021       if $DEBUG > 2;
1022
1023     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1024     return "$@ running $method for $cust_pkg\n"
1025       if ( $@ );
1026
1027     if ( $increment_next_bill ) {
1028
1029       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1030       return "unparsable frequency: ". $part_pkg->freq
1031         if $next_bill == -1;
1032
1033       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1034       # only for figuring next bill date, nothing else, so, reset $sdate again
1035       # here
1036       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1037       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1038       $cust_pkg->last_bill($sdate);
1039
1040       $cust_pkg->setfield('bill', $next_bill );
1041
1042     }
1043
1044     if ( $param{'setup_fee'} ) {
1045       # Add an additional setup fee at the billing stage.
1046       # Used for prorate_defer_bill.
1047       $setup += $param{'setup_fee'};
1048       $unitsetup += $param{'setup_fee'};
1049       $lineitems++;
1050     }
1051
1052     if ( defined $param{'discount_left_setup'} ) {
1053         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1054             $setup -= $discount_setup;
1055         }
1056     }
1057
1058   }
1059
1060   warn "\$setup is undefined" unless defined($setup);
1061   warn "\$recur is undefined" unless defined($recur);
1062   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1063
1064   ###
1065   # If there's line items, create em cust_bill_pkg records
1066   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1067   ###
1068
1069   if ( $lineitems ) {
1070
1071     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1072       # hmm.. and if just the options are modified in some weird price plan?
1073
1074       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1075         if $DEBUG >1;
1076
1077       my $error = $cust_pkg->replace( $old_cust_pkg,
1078                                       'depend_jobnum'=>$options{depend_jobnum},
1079                                       'options' => { $cust_pkg->options },
1080                                     )
1081         unless $options{no_commit};
1082       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1083         if $error; #just in case
1084     }
1085
1086     $setup = sprintf( "%.2f", $setup );
1087     $recur = sprintf( "%.2f", $recur );
1088     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1089       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1090     }
1091     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1092       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1093     }
1094
1095     my $discount_show_always = $conf->exists('discount-show-always')
1096                                && (    ($setup == 0 && scalar(@setup_discounts))
1097                                     || ($recur == 0 && scalar(@recur_discounts))
1098                                   );
1099
1100     if (    $setup != 0
1101          || $recur != 0
1102          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1103          || $discount_show_always
1104          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1105          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1106        )
1107     {
1108
1109       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1110         if $DEBUG > 1;
1111
1112       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1113       if ( $DEBUG > 1 ) {
1114         warn "      adding customer package invoice detail: $_\n"
1115           foreach @cust_pkg_detail;
1116       }
1117       push @details, @cust_pkg_detail;
1118
1119       my $cust_bill_pkg = new FS::cust_bill_pkg {
1120         'pkgnum'    => $cust_pkg->pkgnum,
1121         'setup'     => $setup,
1122         'unitsetup' => $unitsetup,
1123         'recur'     => $recur,
1124         'unitrecur' => $unitrecur,
1125         'quantity'  => $cust_pkg->quantity,
1126         'details'   => \@details,
1127         'discounts' => [ @setup_discounts, @recur_discounts ],
1128         'hidden'    => $part_pkg->hidden,
1129         'freq'      => $part_pkg->freq,
1130       };
1131
1132       if ( $part_pkg->option('prorate_defer_bill',1)
1133            and !$hash{last_bill} ) {
1134         # both preceding and upcoming, technically
1135         $cust_bill_pkg->sdate( $cust_pkg->setup );
1136         $cust_bill_pkg->edate( $cust_pkg->bill );
1137       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1138         $cust_bill_pkg->sdate( $hash{last_bill} );
1139         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1140         $cust_bill_pkg->edate( $time ) if $options{cancel};
1141       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1142         $cust_bill_pkg->sdate( $sdate );
1143         $cust_bill_pkg->edate( $cust_pkg->bill );
1144         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1145       }
1146
1147       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1148         unless $part_pkg->pkgpart == $real_pkgpart;
1149
1150       $$total_setup += $setup;
1151       $$total_recur += $recur;
1152
1153       ###
1154       # handle taxes
1155       ###
1156
1157       unless ( $discount_show_always ) {
1158           my $error =
1159             $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1160           return $error if $error;
1161       }
1162
1163       push @$cust_bill_pkgs, $cust_bill_pkg;
1164
1165     } #if $setup != 0 || $recur != 0
1166
1167   } #if $line_items
1168
1169   '';
1170
1171 }
1172
1173 sub _handle_taxes {
1174   my $self = shift;
1175   my $part_pkg = shift;
1176   my $taxlisthash = shift;
1177   my $cust_bill_pkg = shift;
1178   my $cust_pkg = shift;
1179   my $invoice_time = shift;
1180   my $real_pkgpart = shift;
1181   my $options = shift;
1182
1183   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1184
1185   my %cust_bill_pkg = ();
1186   my %taxes = ();
1187
1188   my @classes;
1189   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1190   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1191   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1192   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1193
1194   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1195
1196     if ( $conf->exists('enable_taxproducts')
1197          && ( scalar($part_pkg->part_pkg_taxoverride)
1198               || $part_pkg->has_taxproduct
1199             )
1200        )
1201     {
1202
1203       foreach my $class (@classes) {
1204         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1205         return $err_or_ref unless ref($err_or_ref);
1206         $taxes{$class} = $err_or_ref;
1207       }
1208
1209       unless (exists $taxes{''}) {
1210         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1211         return $err_or_ref unless ref($err_or_ref);
1212         $taxes{''} = $err_or_ref;
1213       }
1214
1215     } else {
1216
1217       my @loc_keys = qw( district city county state country );
1218       my %taxhash;
1219       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1220         my $cust_location = $cust_pkg->cust_location;
1221         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1222       } else {
1223         my $prefix =
1224           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1225           ? 'ship_'
1226           : '';
1227         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1228         # special case--there's no 'ship_district' field
1229         $taxhash{'district'} = $self->get('district');
1230       }
1231
1232       $taxhash{'taxclass'} = $part_pkg->taxclass;
1233
1234       my @taxes = ();
1235       my %taxhash_elim = %taxhash;
1236       my @elim = qw( district city county state );
1237       do {
1238
1239         #first try a match with taxclass
1240         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1241
1242         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1243           #then try a match without taxclass
1244           my %no_taxclass = %taxhash_elim;
1245           $no_taxclass{ 'taxclass' } = '';
1246           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1247         }
1248
1249         $taxhash_elim{ shift(@elim) } = '';
1250
1251       } while ( !scalar(@taxes) && scalar(@elim) );
1252
1253       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1254                     @taxes
1255         if $self->cust_main_exemption; #just to be safe
1256
1257       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1258         foreach (@taxes) {
1259           $_->set('pkgnum',      $cust_pkg->pkgnum );
1260           $_->set('locationnum', $cust_pkg->locationnum );
1261         }
1262       }
1263
1264       $taxes{''} = [ @taxes ];
1265       $taxes{'setup'} = [ @taxes ];
1266       $taxes{'recur'} = [ @taxes ];
1267       $taxes{$_} = [ @taxes ] foreach (@classes);
1268
1269       # # maybe eliminate this entirely, along with all the 0% records
1270       # unless ( @taxes ) {
1271       #   return
1272       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1273       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1274       # }
1275
1276     } #if $conf->exists('enable_taxproducts') ...
1277
1278   }
1279
1280   #what's this doing in the middle of _handle_taxes?  probably should split
1281   #this into three parts above in _make_lines
1282   $cust_bill_pkg->set_display(   part_pkg     => $part_pkg,
1283                                  real_pkgpart => $real_pkgpart,
1284                              );
1285
1286   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1287   foreach my $key (keys %tax_cust_bill_pkg) {
1288     my @taxes = @{ $taxes{$key} || [] };
1289     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1290
1291     my %localtaxlisthash = ();
1292     foreach my $tax ( @taxes ) {
1293
1294       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1295 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1296 #                  ' locationnum'. $cust_pkg->locationnum
1297 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1298
1299       $taxlisthash->{ $taxname } ||= [ $tax ];
1300       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1301
1302       $localtaxlisthash{ $taxname } ||= [ $tax ];
1303       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1304
1305     }
1306
1307     warn "finding taxed taxes...\n" if $DEBUG > 2;
1308     foreach my $tax ( keys %localtaxlisthash ) {
1309       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1310       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1311         if $DEBUG > 2;
1312       next unless $tax_object->can('tax_on_tax');
1313
1314       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1315         my $totname = ref( $tot ). ' '. $tot->taxnum;
1316
1317         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1318           if $DEBUG > 2;
1319         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1320                                                              # existing taxes
1321         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1322         my $hashref_or_error =
1323           $tax_object->taxline( $localtaxlisthash{$tax},
1324                                 'custnum'      => $self->custnum,
1325                                 'invoice_time' => $invoice_time,
1326                               );
1327         return $hashref_or_error
1328           unless ref($hashref_or_error);
1329
1330         $taxlisthash->{ $totname } ||= [ $tot ];
1331         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1332
1333       }
1334     }
1335
1336   }
1337
1338   '';
1339 }
1340
1341 sub _gather_taxes {
1342   my $self = shift;
1343   my $part_pkg = shift;
1344   my $class = shift;
1345   my $cust_pkg = shift;
1346
1347   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1348
1349   my $geocode;
1350   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1351     $geocode = $cust_pkg->cust_location->geocode('cch');
1352   } else {
1353     $geocode = $self->geocode('cch');
1354   }
1355
1356   my @taxes = ();
1357
1358   my @taxclassnums = map { $_->taxclassnum }
1359                      $part_pkg->part_pkg_taxoverride($class);
1360
1361   unless (@taxclassnums) {
1362     @taxclassnums = map { $_->taxclassnum }
1363                     grep { $_->taxable eq 'Y' }
1364                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1365   }
1366   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1367     if $DEBUG;
1368
1369   my $extra_sql =
1370     "AND (".
1371     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1372
1373   @taxes = qsearch({ 'table' => 'tax_rate',
1374                      'hashref' => { 'geocode' => $geocode, },
1375                      'extra_sql' => $extra_sql,
1376                   })
1377     if scalar(@taxclassnums);
1378
1379   warn "Found taxes ".
1380        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1381    if $DEBUG;
1382
1383   [ @taxes ];
1384
1385 }
1386
1387 =item collect [ HASHREF | OPTION => VALUE ... ]
1388
1389 (Attempt to) collect money for this customer's outstanding invoices (see
1390 L<FS::cust_bill>).  Usually used after the bill method.
1391
1392 Actions are now triggered by billing events; see L<FS::part_event> and the
1393 billing events web interface.  Old-style invoice events (see
1394 L<FS::part_bill_event>) have been deprecated.
1395
1396 If there is an error, returns the error, otherwise returns false.
1397
1398 Options are passed as name-value pairs.
1399
1400 Currently available options are:
1401
1402 =over 4
1403
1404 =item invoice_time
1405
1406 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1407
1408 =item retry
1409
1410 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1411
1412 =item check_freq
1413
1414 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1415
1416 =item quiet
1417
1418 set true to surpress email card/ACH decline notices.
1419
1420 =item debug
1421
1422 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1423
1424 =back
1425
1426 # =item payby
1427 #
1428 # allows for one time override of normal customer billing method
1429
1430 =cut
1431
1432 sub collect {
1433   my( $self, %options ) = @_;
1434
1435   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1436
1437   my $invoice_time = $options{'invoice_time'} || time;
1438
1439   #put below somehow?
1440   local $SIG{HUP} = 'IGNORE';
1441   local $SIG{INT} = 'IGNORE';
1442   local $SIG{QUIT} = 'IGNORE';
1443   local $SIG{TERM} = 'IGNORE';
1444   local $SIG{TSTP} = 'IGNORE';
1445   local $SIG{PIPE} = 'IGNORE';
1446
1447   my $oldAutoCommit = $FS::UID::AutoCommit;
1448   local $FS::UID::AutoCommit = 0;
1449   my $dbh = dbh;
1450
1451   $self->select_for_update; #mutex
1452
1453   if ( $DEBUG ) {
1454     my $balance = $self->balance;
1455     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1456   }
1457
1458   if ( exists($options{'retry_card'}) ) {
1459     carp 'retry_card option passed to collect is deprecated; use retry';
1460     $options{'retry'} ||= $options{'retry_card'};
1461   }
1462   if ( exists($options{'retry'}) && $options{'retry'} ) {
1463     my $error = $self->retry_realtime;
1464     if ( $error ) {
1465       $dbh->rollback if $oldAutoCommit;
1466       return $error;
1467     }
1468   }
1469
1470   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1471
1472   #never want to roll back an event just because it returned an error
1473   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1474
1475   $self->do_cust_event(
1476     'debug'      => ( $options{'debug'} || 0 ),
1477     'time'       => $invoice_time,
1478     'check_freq' => $options{'check_freq'},
1479     'stage'      => 'collect',
1480   );
1481
1482 }
1483
1484 =item retry_realtime
1485
1486 Schedules realtime / batch  credit card / electronic check / LEC billing
1487 events for for retry.  Useful if card information has changed or manual
1488 retry is desired.  The 'collect' method must be called to actually retry
1489 the transaction.
1490
1491 Implementation details: For either this customer, or for each of this
1492 customer's open invoices, changes the status of the first "done" (with
1493 statustext error) realtime processing event to "failed".
1494
1495 =cut
1496
1497 sub retry_realtime {
1498   my $self = shift;
1499
1500   local $SIG{HUP} = 'IGNORE';
1501   local $SIG{INT} = 'IGNORE';
1502   local $SIG{QUIT} = 'IGNORE';
1503   local $SIG{TERM} = 'IGNORE';
1504   local $SIG{TSTP} = 'IGNORE';
1505   local $SIG{PIPE} = 'IGNORE';
1506
1507   my $oldAutoCommit = $FS::UID::AutoCommit;
1508   local $FS::UID::AutoCommit = 0;
1509   my $dbh = dbh;
1510
1511   #a little false laziness w/due_cust_event (not too bad, really)
1512
1513   my $join = FS::part_event_condition->join_conditions_sql;
1514   my $order = FS::part_event_condition->order_conditions_sql;
1515   my $mine =
1516   '( '
1517    . join ( ' OR ' , map {
1518     "( part_event.eventtable = " . dbh->quote($_)
1519     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1520    } FS::part_event->eventtables)
1521    . ') ';
1522
1523   #here is the agent virtualization
1524   my $agent_virt = " (    part_event.agentnum IS NULL
1525                        OR part_event.agentnum = ". $self->agentnum. ' )';
1526
1527   #XXX this shouldn't be hardcoded, actions should declare it...
1528   my @realtime_events = qw(
1529     cust_bill_realtime_card
1530     cust_bill_realtime_check
1531     cust_bill_realtime_lec
1532     cust_bill_batch
1533   );
1534
1535   my $is_realtime_event =
1536     ' part_event.action IN ( '.
1537         join(',', map "'$_'", @realtime_events ).
1538     ' ) ';
1539
1540   my $batch_or_statustext =
1541     "( part_event.action = 'cust_bill_batch'
1542        OR ( statustext IS NOT NULL AND statustext != '' )
1543      )";
1544
1545
1546   my @cust_event = qsearch({
1547     'table'     => 'cust_event',
1548     'select'    => 'cust_event.*',
1549     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1550     'hashref'   => { 'status' => 'done' },
1551     'extra_sql' => " AND $batch_or_statustext ".
1552                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1553   });
1554
1555   my %seen_invnum = ();
1556   foreach my $cust_event (@cust_event) {
1557
1558     #max one for the customer, one for each open invoice
1559     my $cust_X = $cust_event->cust_X;
1560     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1561                           ? $cust_X->invnum
1562                           : 0
1563                         }++
1564          or $cust_event->part_event->eventtable eq 'cust_bill'
1565             && ! $cust_X->owed;
1566
1567     my $error = $cust_event->retry;
1568     if ( $error ) {
1569       $dbh->rollback if $oldAutoCommit;
1570       return "error scheduling event for retry: $error";
1571     }
1572
1573   }
1574
1575   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1576   '';
1577
1578 }
1579
1580 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1581
1582 Runs billing events; see L<FS::part_event> and the billing events web
1583 interface.
1584
1585 If there is an error, returns the error, otherwise returns false.
1586
1587 Options are passed as name-value pairs.
1588
1589 Currently available options are:
1590
1591 =over 4
1592
1593 =item time
1594
1595 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1596
1597 =item check_freq
1598
1599 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1600
1601 =item stage
1602
1603 "collect" (the default) or "pre-bill"
1604
1605 =item quiet
1606
1607 set true to surpress email card/ACH decline notices.
1608
1609 =item debug
1610
1611 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1612
1613 =back
1614 =cut
1615
1616 # =item payby
1617 #
1618 # allows for one time override of normal customer billing method
1619
1620 # =item retry
1621 #
1622 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1623
1624 sub do_cust_event {
1625   my( $self, %options ) = @_;
1626
1627   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1628
1629   my $time = $options{'time'} || time;
1630
1631   #put below somehow?
1632   local $SIG{HUP} = 'IGNORE';
1633   local $SIG{INT} = 'IGNORE';
1634   local $SIG{QUIT} = 'IGNORE';
1635   local $SIG{TERM} = 'IGNORE';
1636   local $SIG{TSTP} = 'IGNORE';
1637   local $SIG{PIPE} = 'IGNORE';
1638
1639   my $oldAutoCommit = $FS::UID::AutoCommit;
1640   local $FS::UID::AutoCommit = 0;
1641   my $dbh = dbh;
1642
1643   $self->select_for_update; #mutex
1644
1645   if ( $DEBUG ) {
1646     my $balance = $self->balance;
1647     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1648   }
1649
1650 #  if ( exists($options{'retry_card'}) ) {
1651 #    carp 'retry_card option passed to collect is deprecated; use retry';
1652 #    $options{'retry'} ||= $options{'retry_card'};
1653 #  }
1654 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1655 #    my $error = $self->retry_realtime;
1656 #    if ( $error ) {
1657 #      $dbh->rollback if $oldAutoCommit;
1658 #      return $error;
1659 #    }
1660 #  }
1661
1662   # false laziness w/pay_batch::import_results
1663
1664   my $due_cust_event = $self->due_cust_event(
1665     'debug'      => ( $options{'debug'} || 0 ),
1666     'time'       => $time,
1667     'check_freq' => $options{'check_freq'},
1668     'stage'      => ( $options{'stage'} || 'collect' ),
1669   );
1670   unless( ref($due_cust_event) ) {
1671     $dbh->rollback if $oldAutoCommit;
1672     return $due_cust_event;
1673   }
1674
1675   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1676   #never want to roll back an event just because it or a different one
1677   # returned an error
1678   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1679
1680   foreach my $cust_event ( @$due_cust_event ) {
1681
1682     #XXX lock event
1683
1684     #re-eval event conditions (a previous event could have changed things)
1685     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1686       #don't leave stray "new/locked" records around
1687       my $error = $cust_event->delete;
1688       return $error if $error;
1689       next;
1690     }
1691
1692     {
1693       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1694         if $options{'quiet'};
1695       warn "  running cust_event ". $cust_event->eventnum. "\n"
1696         if $DEBUG > 1;
1697
1698       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1699       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1700         #XXX wtf is this?  figure out a proper dealio with return value
1701         #from do_event
1702         return $error;
1703       }
1704     }
1705
1706   }
1707
1708   '';
1709
1710 }
1711
1712 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1713
1714 Inserts database records for and returns an ordered listref of new events due
1715 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1716 events are due, an empty listref is returned.  If there is an error, returns a
1717 scalar error message.
1718
1719 To actually run the events, call each event's test_condition method, and if
1720 still true, call the event's do_event method.
1721
1722 Options are passed as a hashref or as a list of name-value pairs.  Available
1723 options are:
1724
1725 =over 4
1726
1727 =item check_freq
1728
1729 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1730
1731 =item stage
1732
1733 "collect" (the default) or "pre-bill"
1734
1735 =item time
1736
1737 "Current time" for the events.
1738
1739 =item debug
1740
1741 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1742
1743 =item eventtable
1744
1745 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1746
1747 =item objects
1748
1749 Explicitly pass the objects to be tested (typically used with eventtable).
1750
1751 =item testonly
1752
1753 Set to true to return the objects, but not actually insert them into the
1754 database.
1755
1756 =back
1757
1758 =cut
1759
1760 sub due_cust_event {
1761   my $self = shift;
1762   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1763
1764   #???
1765   #my $DEBUG = $opt{'debug'}
1766   $opt{'debug'} ||= 0; # silence some warnings
1767   local($DEBUG) = $opt{'debug'}
1768     if $opt{'debug'} > $DEBUG;
1769   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1770
1771   warn "$me due_cust_event called with options ".
1772        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1773     if $DEBUG;
1774
1775   $opt{'time'} ||= time;
1776
1777   local $SIG{HUP} = 'IGNORE';
1778   local $SIG{INT} = 'IGNORE';
1779   local $SIG{QUIT} = 'IGNORE';
1780   local $SIG{TERM} = 'IGNORE';
1781   local $SIG{TSTP} = 'IGNORE';
1782   local $SIG{PIPE} = 'IGNORE';
1783
1784   my $oldAutoCommit = $FS::UID::AutoCommit;
1785   local $FS::UID::AutoCommit = 0;
1786   my $dbh = dbh;
1787
1788   $self->select_for_update #mutex
1789     unless $opt{testonly};
1790
1791   ###
1792   # find possible events (initial search)
1793   ###
1794
1795   my @cust_event = ();
1796
1797   my @eventtable = $opt{'eventtable'}
1798                      ? ( $opt{'eventtable'} )
1799                      : FS::part_event->eventtables_runorder;
1800
1801   my $check_freq = $opt{'check_freq'} || '1d';
1802
1803   foreach my $eventtable ( @eventtable ) {
1804
1805     my @objects;
1806     if ( $opt{'objects'} ) {
1807
1808       @objects = @{ $opt{'objects'} };
1809
1810     } else {
1811
1812       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1813       if ( $eventtable eq 'cust_main' ) {
1814         @objects = ( $self );
1815       } else {
1816
1817         my $cm_join =
1818           "LEFT JOIN cust_main USING ( custnum )";
1819
1820         #some false laziness w/Cron::bill bill_where
1821
1822         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1823         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1824                                                            'time'=>$opt{'time'},
1825                                                                   );
1826         $where = $where ? "AND $where" : '';
1827
1828         my $are_part_event =
1829           "EXISTS ( SELECT 1 FROM part_event $join
1830                       WHERE check_freq = '$check_freq'
1831                         AND eventtable = '$eventtable'
1832                         AND ( disabled = '' OR disabled IS NULL )
1833                         $where
1834                   )
1835           ";
1836         #eofalse
1837
1838         @objects = $self->$eventtable(
1839                      'addl_from' => $cm_join,
1840                      'extra_sql' => " AND $are_part_event",
1841                    );
1842       }
1843
1844     }
1845
1846     my @e_cust_event = ();
1847
1848     my $cross = "CROSS JOIN $eventtable";
1849     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1850       unless $eventtable eq 'cust_main';
1851
1852     foreach my $object ( @objects ) {
1853
1854       #this first search uses the condition_sql magic for optimization.
1855       #the more possible events we can eliminate in this step the better
1856
1857       my $cross_where = '';
1858       my $pkey = $object->primary_key;
1859       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1860
1861       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1862       my $extra_sql =
1863         FS::part_event_condition->where_conditions_sql( $eventtable,
1864                                                         'time'=>$opt{'time'}
1865                                                       );
1866       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1867
1868       $extra_sql = "AND $extra_sql" if $extra_sql;
1869
1870       #here is the agent virtualization
1871       $extra_sql .= " AND (    part_event.agentnum IS NULL
1872                             OR part_event.agentnum = ". $self->agentnum. ' )';
1873
1874       $extra_sql .= " $order";
1875
1876       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1877         if $opt{'debug'} > 2;
1878       my @part_event = qsearch( {
1879         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1880         'select'    => 'part_event.*',
1881         'table'     => 'part_event',
1882         'addl_from' => "$cross $join",
1883         'hashref'   => { 'check_freq' => $check_freq,
1884                          'eventtable' => $eventtable,
1885                          'disabled'   => '',
1886                        },
1887         'extra_sql' => "AND $cross_where $extra_sql",
1888       } );
1889
1890       if ( $DEBUG > 2 ) {
1891         my $pkey = $object->primary_key;
1892         warn "      ". scalar(@part_event).
1893              " possible events found for $eventtable ". $object->$pkey(). "\n";
1894       }
1895
1896       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1897
1898     }
1899
1900     warn "    ". scalar(@e_cust_event).
1901          " subtotal possible cust events found for $eventtable\n"
1902       if $DEBUG > 1;
1903
1904     push @cust_event, @e_cust_event;
1905
1906   }
1907
1908   warn "  ". scalar(@cust_event).
1909        " total possible cust events found in initial search\n"
1910     if $DEBUG; # > 1;
1911
1912
1913   ##
1914   # test stage
1915   ##
1916
1917   $opt{stage} ||= 'collect';
1918   @cust_event =
1919     grep { my $stage = $_->part_event->event_stage;
1920            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1921          }
1922          @cust_event;
1923
1924   ##
1925   # test conditions
1926   ##
1927
1928   my %unsat = ();
1929
1930   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1931                                           'stats_hashref' => \%unsat ),
1932                      @cust_event;
1933
1934   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1935     if $DEBUG; # > 1;
1936
1937   warn "    invalid conditions not eliminated with condition_sql:\n".
1938        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1939     if keys %unsat && $DEBUG; # > 1;
1940
1941   ##
1942   # insert
1943   ##
1944
1945   unless( $opt{testonly} ) {
1946     foreach my $cust_event ( @cust_event ) {
1947
1948       my $error = $cust_event->insert();
1949       if ( $error ) {
1950         $dbh->rollback if $oldAutoCommit;
1951         return $error;
1952       }
1953
1954     }
1955   }
1956
1957   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1958
1959   ##
1960   # return
1961   ##
1962
1963   warn "  returning events: ". Dumper(@cust_event). "\n"
1964     if $DEBUG > 2;
1965
1966   \@cust_event;
1967
1968 }
1969
1970 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1971
1972 Applies unapplied payments and credits.
1973
1974 In most cases, this new method should be used in place of sequential
1975 apply_payments and apply_credits methods.
1976
1977 A hash of optional arguments may be passed.  Currently "manual" is supported.
1978 If true, a payment receipt is sent instead of a statement when
1979 'payment_receipt_email' configuration option is set.
1980
1981 If there is an error, returns the error, otherwise returns false.
1982
1983 =cut
1984
1985 sub apply_payments_and_credits {
1986   my( $self, %options ) = @_;
1987
1988   local $SIG{HUP} = 'IGNORE';
1989   local $SIG{INT} = 'IGNORE';
1990   local $SIG{QUIT} = 'IGNORE';
1991   local $SIG{TERM} = 'IGNORE';
1992   local $SIG{TSTP} = 'IGNORE';
1993   local $SIG{PIPE} = 'IGNORE';
1994
1995   my $oldAutoCommit = $FS::UID::AutoCommit;
1996   local $FS::UID::AutoCommit = 0;
1997   my $dbh = dbh;
1998
1999   $self->select_for_update; #mutex
2000
2001   foreach my $cust_bill ( $self->open_cust_bill ) {
2002     my $error = $cust_bill->apply_payments_and_credits(%options);
2003     if ( $error ) {
2004       $dbh->rollback if $oldAutoCommit;
2005       return "Error applying: $error";
2006     }
2007   }
2008
2009   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2010   ''; #no error
2011
2012 }
2013
2014 =item apply_credits OPTION => VALUE ...
2015
2016 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2017 to outstanding invoice balances in chronological order (or reverse
2018 chronological order if the I<order> option is set to B<newest>) and returns the
2019 value of any remaining unapplied credits available for refund (see
2020 L<FS::cust_refund>).
2021
2022 Dies if there is an error.
2023
2024 =cut
2025
2026 sub apply_credits {
2027   my $self = shift;
2028   my %opt = @_;
2029
2030   local $SIG{HUP} = 'IGNORE';
2031   local $SIG{INT} = 'IGNORE';
2032   local $SIG{QUIT} = 'IGNORE';
2033   local $SIG{TERM} = 'IGNORE';
2034   local $SIG{TSTP} = 'IGNORE';
2035   local $SIG{PIPE} = 'IGNORE';
2036
2037   my $oldAutoCommit = $FS::UID::AutoCommit;
2038   local $FS::UID::AutoCommit = 0;
2039   my $dbh = dbh;
2040
2041   $self->select_for_update; #mutex
2042
2043   unless ( $self->total_unapplied_credits ) {
2044     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2045     return 0;
2046   }
2047
2048   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2049       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2050
2051   my @invoices = $self->open_cust_bill;
2052   @invoices = sort { $b->_date <=> $a->_date } @invoices
2053     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2054
2055   if ( $conf->exists('pkg-balances') ) {
2056     # limit @credits to those w/ a pkgnum grepped from $self
2057     my %pkgnums = ();
2058     foreach my $i (@invoices) {
2059       foreach my $li ( $i->cust_bill_pkg ) {
2060         $pkgnums{$li->pkgnum} = 1;
2061       }
2062     }
2063     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2064   }
2065
2066   my $credit;
2067
2068   foreach my $cust_bill ( @invoices ) {
2069
2070     if ( !defined($credit) || $credit->credited == 0) {
2071       $credit = pop @credits or last;
2072     }
2073
2074     my $owed;
2075     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2076       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2077     } else {
2078       $owed = $cust_bill->owed;
2079     }
2080     unless ( $owed > 0 ) {
2081       push @credits, $credit;
2082       next;
2083     }
2084
2085     my $amount = min( $credit->credited, $owed );
2086
2087     my $cust_credit_bill = new FS::cust_credit_bill ( {
2088       'crednum' => $credit->crednum,
2089       'invnum'  => $cust_bill->invnum,
2090       'amount'  => $amount,
2091     } );
2092     $cust_credit_bill->pkgnum( $credit->pkgnum )
2093       if $conf->exists('pkg-balances') && $credit->pkgnum;
2094     my $error = $cust_credit_bill->insert;
2095     if ( $error ) {
2096       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2097       die $error;
2098     }
2099
2100     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2101
2102   }
2103
2104   my $total_unapplied_credits = $self->total_unapplied_credits;
2105
2106   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2107
2108   return $total_unapplied_credits;
2109 }
2110
2111 =item apply_payments  [ OPTION => VALUE ... ]
2112
2113 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2114 to outstanding invoice balances in chronological order.
2115
2116  #and returns the value of any remaining unapplied payments.
2117
2118 A hash of optional arguments may be passed.  Currently "manual" is supported.
2119 If true, a payment receipt is sent instead of a statement when
2120 'payment_receipt_email' configuration option is set.
2121
2122 Dies if there is an error.
2123
2124 =cut
2125
2126 sub apply_payments {
2127   my( $self, %options ) = @_;
2128
2129   local $SIG{HUP} = 'IGNORE';
2130   local $SIG{INT} = 'IGNORE';
2131   local $SIG{QUIT} = 'IGNORE';
2132   local $SIG{TERM} = 'IGNORE';
2133   local $SIG{TSTP} = 'IGNORE';
2134   local $SIG{PIPE} = 'IGNORE';
2135
2136   my $oldAutoCommit = $FS::UID::AutoCommit;
2137   local $FS::UID::AutoCommit = 0;
2138   my $dbh = dbh;
2139
2140   $self->select_for_update; #mutex
2141
2142   #return 0 unless
2143
2144   my @payments = sort { $b->_date <=> $a->_date }
2145                  grep { $_->unapplied > 0 }
2146                  $self->cust_pay;
2147
2148   my @invoices = sort { $a->_date <=> $b->_date}
2149                  grep { $_->owed > 0 }
2150                  $self->cust_bill;
2151
2152   if ( $conf->exists('pkg-balances') ) {
2153     # limit @payments to those w/ a pkgnum grepped from $self
2154     my %pkgnums = ();
2155     foreach my $i (@invoices) {
2156       foreach my $li ( $i->cust_bill_pkg ) {
2157         $pkgnums{$li->pkgnum} = 1;
2158       }
2159     }
2160     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2161   }
2162
2163   my $payment;
2164
2165   foreach my $cust_bill ( @invoices ) {
2166
2167     if ( !defined($payment) || $payment->unapplied == 0 ) {
2168       $payment = pop @payments or last;
2169     }
2170
2171     my $owed;
2172     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2173       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2174     } else {
2175       $owed = $cust_bill->owed;
2176     }
2177     unless ( $owed > 0 ) {
2178       push @payments, $payment;
2179       next;
2180     }
2181
2182     my $amount = min( $payment->unapplied, $owed );
2183
2184     my $cbp = {
2185       'paynum' => $payment->paynum,
2186       'invnum' => $cust_bill->invnum,
2187       'amount' => $amount,
2188     };
2189     $cbp->{_date} = $payment->_date
2190         if $options{'manual'} && $options{'backdate_application'};
2191     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2192     $cust_bill_pay->pkgnum( $payment->pkgnum )
2193       if $conf->exists('pkg-balances') && $payment->pkgnum;
2194     my $error = $cust_bill_pay->insert(%options);
2195     if ( $error ) {
2196       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2197       die $error;
2198     }
2199
2200     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2201
2202   }
2203
2204   my $total_unapplied_payments = $self->total_unapplied_payments;
2205
2206   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2207
2208   return $total_unapplied_payments;
2209 }
2210
2211 =back
2212
2213 =head1 FLOW
2214
2215   bill_and_collect
2216
2217     cancel_expired_pkgs
2218     suspend_adjourned_pkgs
2219     unsuspend_resumed_pkgs
2220
2221     bill
2222       (do_cust_event pre-bill)
2223       _make_lines
2224         _handle_taxes
2225           (vendor-only) _gather_taxes
2226       _omit_zero_value_bundles
2227       calculate_taxes
2228
2229     apply_payments_and_credits
2230     collect
2231       do_cust_event
2232         due_cust_event
2233
2234 =head1 BUGS
2235
2236 =head1 SEE ALSO
2237
2238 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2239
2240 =cut
2241
2242 1;