FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::cust_bill;
  11 use FS::cust_bill_pkg;
  12 use FS::cust_bill_pkg_display;
  13 use FS::cust_bill_pay;
  14 use FS::cust_credit_bill;
  15 use FS::cust_tax_adjustment;
  16 use FS::tax_rate;
  17 use FS::tax_rate_location;
  18 use FS::cust_bill_pkg_tax_location;
  19 use FS::cust_bill_pkg_tax_rate_location;
  20 use FS::part_event;
  21 use FS::part_event_condition;
  22 use FS::pkg_category;
  23
  24 # 1 is mostly method/subroutine entry and options
  25 # 2 traces progress of some operations
  26 # 3 is even more information including possibly sensitive data
  27 $DEBUG = 0;
  28 $me = '[FS::cust_main::Billing]';
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Billing - Billing mixin for cust_main
  38
  39 =head1 SYNOPSIS
  40
  41 =head1 DESCRIPTION
  42
  43 These methods are available on FS::cust_main objects.
  44
  45 =head1 METHODS
  46
  47 =over 4
  48
  49 =item bill_and_collect
  50
  51 Cancels and suspends any packages due, generates bills, applies payments and
  52 credits, and applies collection events to run cards, send bills and notices,
  53 etc.
  54
  55 By default, warns on errors and continues with the next operation (but see the
  56 "fatal" flag below).
  57
  58 Options are passed as name-value pairs.  Currently available options are:
  59
  60 =over 4
  61
  62 =item time
  63
  64 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  65
  66  use Date::Parse;
  67  ...
  68  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  69
  70 =item invoice_time
  71
  72 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  73
  74 =item check_freq
  75
  76 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  77
  78 =item resetup
  79
  80 If set true, re-charges setup fees.
  81
  82 =item fatal
  83
  84 If set any errors prevent subsequent operations from continusing.  If set
  85 specifically to "return", returns the error (or false, if there is no error).
  86 Any other true value causes errors to die.
  87
  88 =item debug
  89
  90 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  91
  92 =item job
  93
  94 Optional FS::queue entry to receive status updates.
  95
  96 =back
  97
  98 Options are passed to the B<bill> and B<collect> methods verbatim, so all
  99 options of those methods are also available.
 100
 101 =cut
 102
 103 sub bill_and_collect {
 104   my( $self, %options ) = @_;
 105
 106   my $error;
 107
 108   #$options{actual_time} not $options{time} because freeside-daily -d is for
 109   #pre-printing invoices
 110
 111   $options{'actual_time'} ||= time;
 112   my $job = $options{'job'};
 113
 114   $job->update_statustext('0,cleaning expired packages') if $job;
 115   $error = $self->cancel_expired_pkgs( $options{actual_time} );
 116   if ( $error ) {
 117     $error = "Error expiring custnum ". $self->custnum. ": $error";
 118     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 119     elsif ( $options{fatal}                                ) { die    $error; }
 120     else                                                     { warn   $error; }
 121   }
 122
 123   $error = $self->suspend_adjourned_pkgs( $options{actual_time} );
 124   if ( $error ) {
 125     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 126     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 127     elsif ( $options{fatal}                                ) { die    $error; }
 128     else                                                     { warn   $error; }
 129   }
 130
 131   $job->update_statustext('20,billing packages') if $job;
 132   $error = $self->bill( %options );
 133   if ( $error ) {
 134     $error = "Error billing custnum ". $self->custnum. ": $error";
 135     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 136     elsif ( $options{fatal}                                ) { die    $error; }
 137     else                                                     { warn   $error; }
 138   }
 139
 140   $job->update_statustext('50,applying payments and credits') if $job;
 141   $error = $self->apply_payments_and_credits;
 142   if ( $error ) {
 143     $error = "Error applying custnum ". $self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('70,running collection events') if $job;
 150   unless ( $conf->exists('cancelled_cust-noevents')
 151            && ! $self->num_ncancelled_pkgs
 152   ) {
 153     $error = $self->collect( %options );
 154     if ( $error ) {
 155       $error = "Error collecting custnum ". $self->custnum. ": $error";
 156       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 157       elsif ($options{fatal}                               ) { die    $error; }
 158       else                                                   { warn   $error; }
 159     }
 160   }
 161   $job->update_statustext('100,finished') if $job;
 162
 163   '';
 164
 165 }
 166
 167 sub cancel_expired_pkgs {
 168   my ( $self, $time, %options ) = @_;
 169
 170   my @cancel_pkgs = $self->ncancelled_pkgs( {
 171     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 172   } );
 173
 174   my @errors = ();
 175
 176   foreach my $cust_pkg ( @cancel_pkgs ) {
 177     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 178     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 179                                            'reason_otaker' => $cpr->otaker
 180                                          )
 181                                        : ()
 182                                  );
 183     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 184   }
 185
 186   scalar(@errors) ? join(' / ', @errors) : '';
 187
 188 }
 189
 190 sub suspend_adjourned_pkgs {
 191   my ( $self, $time, %options ) = @_;
 192
 193   my @susp_pkgs = $self->ncancelled_pkgs( {
 194     'extra_sql' =>
 195       " AND ( susp IS NULL OR susp = 0 )
 196         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 197               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 198             )
 199       ",
 200   } );
 201
 202   #only because there's no SQL test for is_prepaid :/
 203   @susp_pkgs =
 204     grep {     (    $_->part_pkg->is_prepaid
 205                  && $_->bill
 206                  && $_->bill < $time
 207                )
 208             || (    $_->adjourn
 209                  && $_->adjourn <= $time
 210                )
 211
 212          }
 213          @susp_pkgs;
 214
 215   my @errors = ();
 216
 217   foreach my $cust_pkg ( @susp_pkgs ) {
 218     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 219       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 220     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 221                                             'reason_otaker' => $cpr->otaker
 222                                           )
 223                                         : ()
 224                                   );
 225     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 226   }
 227
 228   scalar(@errors) ? join(' / ', @errors) : '';
 229
 230 }
 231
 232 =item bill OPTIONS
 233
 234 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 235 conjunction with the collect method by calling B<bill_and_collect>.
 236
 237 If there is an error, returns the error, otherwise returns false.
 238
 239 Options are passed as name-value pairs.  Currently available options are:
 240
 241 =over 4
 242
 243 =item resetup
 244
 245 If set true, re-charges setup fees.
 246
 247 =item recurring_only
 248
 249 If set true then only bill recurring charges, not setup, usage, one time
 250 charges, etc.
 251
 252 =item freq_override
 253
 254 If set, then override the normal frequency and look for a part_pkg_discount
 255 to take at that frequency.
 256
 257 =item time
 258
 259 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 260
 261  use Date::Parse;
 262  ...
 263  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 264
 265 =item pkg_list
 266
 267 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 268
 269  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 270
 271 =item not_pkgpart
 272
 273 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 274
 275 =item invoice_time
 276
 277 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 278
 279 =item cancel
 280
 281 This boolean value informs the us that the package is being cancelled.  This
 282 typically might mean not charging the normal recurring fee but only usage
 283 fees since the last billing. Setup charges may be charged.  Not all package
 284 plans support this feature (they tend to charge 0).
 285
 286 =item no_usage_reset
 287
 288 Prevent the resetting of usage limits during this call.
 289
 290 =item no_commit
 291
 292 Do not save the generated bill in the database.  Useful with return_bill
 293
 294 =item return_bill
 295
 296 A list reference on which the generated bill(s) will be returned.
 297
 298 =item invoice_terms
 299
 300 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 301 terms or the default terms are used.
 302
 303 =back
 304
 305 =cut
 306
 307 sub bill {
 308   my( $self, %options ) = @_;
 309
 310   return '' if $self->payby eq 'COMP';
 311
 312   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 313
 314   warn "$me bill customer ". $self->custnum. "\n"
 315     if $DEBUG;
 316
 317   my $time = $options{'time'} || time;
 318   my $invoice_time = $options{'invoice_time'} || $time;
 319
 320   $options{'not_pkgpart'} ||= {};
 321   $options{'not_pkgpart'} = { map { $_ => 1 }
 322                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 323                             }
 324     unless ref($options{'not_pkgpart'});
 325
 326   local $SIG{HUP} = 'IGNORE';
 327   local $SIG{INT} = 'IGNORE';
 328   local $SIG{QUIT} = 'IGNORE';
 329   local $SIG{TERM} = 'IGNORE';
 330   local $SIG{TSTP} = 'IGNORE';
 331   local $SIG{PIPE} = 'IGNORE';
 332
 333   my $oldAutoCommit = $FS::UID::AutoCommit;
 334   local $FS::UID::AutoCommit = 0;
 335   my $dbh = dbh;
 336
 337   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 338     if $DEBUG;
 339
 340   $self->select_for_update; #mutex
 341
 342   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 343     if $DEBUG;
 344
 345   my $error = $self->do_cust_event(
 346     'debug'      => ( $options{'debug'} || 0 ),
 347     'time'       => $invoice_time,
 348     'check_freq' => $options{'check_freq'},
 349     'stage'      => 'pre-bill',
 350   )
 351     unless $options{no_commit};
 352   if ( $error ) {
 353     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 354     return $error;
 355   }
 356
 357   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 358     if $DEBUG;
 359
 360   #keep auto-charge and non-auto-charge line items separate
 361   my @passes = ( '', 'no_auto' );
 362
 363   my %cust_bill_pkg = map { $_ => [] } @passes;
 364
 365   ###
 366   # find the packages which are due for billing, find out how much they are
 367   # & generate invoice database.
 368   ###
 369
 370   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 371   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 372
 373   my %taxlisthash = map { $_ => {} } @passes;
 374
 375   my @precommit_hooks = ();
 376
 377   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 378   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 379
 380     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 381
 382     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
 383
 384     #? to avoid use of uninitialized value errors... ?
 385     $cust_pkg->setfield('bill', '')
 386       unless defined($cust_pkg->bill);
 387
 388     #my $part_pkg = $cust_pkg->part_pkg;
 389
 390     my $real_pkgpart = $cust_pkg->pkgpart;
 391     my %hash = $cust_pkg->hash;
 392
 393     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 394     # suffer from performance issues
 395     $options{has_hidden} = 0;
 396     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 397     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 398
 399     foreach my $part_pkg ( @part_pkg ) {
 400
 401       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 402
 403       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 404
 405       my $error =
 406         $self->_make_lines( 'part_pkg'            => $part_pkg,
 407                             'cust_pkg'            => $cust_pkg,
 408                             'precommit_hooks'     => \@precommit_hooks,
 409                             'line_items'          => $cust_bill_pkg{$pass},
 410                             'setup'               => $total_setup{$pass},
 411                             'recur'               => $total_recur{$pass},
 412                             'tax_matrix'          => $taxlisthash{$pass},
 413                             'time'                => $time,
 414                             'real_pkgpart'        => $real_pkgpart,
 415                             'options'             => \%options,
 416                           );
 417       if ($error) {
 418         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 419         return $error;
 420       }
 421
 422     } #foreach my $part_pkg
 423
 424   } #foreach my $cust_pkg
 425
 426   #if the customer isn't on an automatic payby, everything can go on a single
 427   #invoice anyway?
 428   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 429     #merge everything into one list
 430   #}
 431
 432   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 433
 434     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 435
 436     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 437
 438     warn "$me billing pass $pass\n"
 439            #.Dumper(\@cust_bill_pkg)."\n"
 440       if $DEBUG > 2;
 441
 442     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 443            !$conf->exists('postal_invoice-recurring_only')
 444        )
 445     {
 446
 447       my $postal_pkg = $self->charge_postal_fee();
 448       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 449
 450         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 451         return "can't charge postal invoice fee for customer ".
 452           $self->custnum. ": $postal_pkg";
 453
 454       } elsif ( $postal_pkg ) {
 455
 456         my $real_pkgpart = $postal_pkg->pkgpart;
 457         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 458         # suffer from performance issues
 459         $options{has_hidden} = 0;
 460         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 461         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 462
 463         foreach my $part_pkg ( @part_pkg ) {
 464           my %postal_options = %options;
 465           delete $postal_options{cancel};
 466           my $error =
 467             $self->_make_lines( 'part_pkg'            => $part_pkg,
 468                                 'cust_pkg'            => $postal_pkg,
 469                                 'precommit_hooks'     => \@precommit_hooks,
 470                                 'line_items'          => \@cust_bill_pkg,
 471                                 'setup'               => $total_setup{$pass},
 472                                 'recur'               => $total_recur{$pass},
 473                                 'tax_matrix'          => $taxlisthash{$pass},
 474                                 'time'                => $time,
 475                                 'real_pkgpart'        => $real_pkgpart,
 476                                 'options'             => \%postal_options,
 477                               );
 478           if ($error) {
 479             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 480             return $error;
 481           }
 482         }
 483
 484         # it's silly to have a zero value postal_pkg, but....
 485         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 486
 487       }
 488
 489     }
 490
 491     my $listref_or_error =
 492       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 493
 494     unless ( ref( $listref_or_error ) ) {
 495       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 496       return $listref_or_error;
 497     }
 498
 499     foreach my $taxline ( @$listref_or_error ) {
 500       ${ $total_setup{$pass} } =
 501         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 502       push @cust_bill_pkg, $taxline;
 503     }
 504
 505     #add tax adjustments
 506     warn "adding tax adjustments...\n" if $DEBUG > 2;
 507     foreach my $cust_tax_adjustment (
 508       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 509                                        'billpkgnum' => '',
 510                                      }
 511              )
 512     ) {
 513
 514       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 515
 516       my $itemdesc = $cust_tax_adjustment->taxname;
 517       $itemdesc = '' if $itemdesc eq 'Tax';
 518
 519       push @cust_bill_pkg, new FS::cust_bill_pkg {
 520         'pkgnum'      => 0,
 521         'setup'       => $tax,
 522         'recur'       => 0,
 523         'sdate'       => '',
 524         'edate'       => '',
 525         'itemdesc'    => $itemdesc,
 526         'itemcomment' => $cust_tax_adjustment->comment,
 527         'cust_tax_adjustment' => $cust_tax_adjustment,
 528         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 529       };
 530
 531     }
 532
 533     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 534
 535     my @cust_bill = $self->cust_bill;
 536     my $balance = $self->balance;
 537     my $previous_balance = scalar(@cust_bill)
 538                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 539                              : 0;
 540
 541     $previous_balance += $cust_bill[$#cust_bill]->charged
 542       if scalar(@cust_bill);
 543     #my $balance_adjustments =
 544     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 545
 546     warn "creating the new invoice\n" if $DEBUG;
 547     #create the new invoice
 548     my $cust_bill = new FS::cust_bill ( {
 549       'custnum'             => $self->custnum,
 550       '_date'               => ( $invoice_time ),
 551       'charged'             => $charged,
 552       'billing_balance'     => $balance,
 553       'previous_balance'    => $previous_balance,
 554       'invoice_terms'       => $options{'invoice_terms'},
 555       'cust_bill_pkg'       => \@cust_bill_pkg,
 556     } );
 557     $error = $cust_bill->insert unless $options{no_commit};
 558     if ( $error ) {
 559       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 560       return "can't create invoice for customer #". $self->custnum. ": $error";
 561     }
 562     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 563
 564   } #foreach my $pass ( keys %cust_bill_pkg )
 565
 566   foreach my $hook ( @precommit_hooks ) {
 567     eval {
 568       &{$hook}; #($self) ?
 569     } unless $options{no_commit};
 570     if ( $@ ) {
 571       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 572       return "$@ running precommit hook $hook\n";
 573     }
 574   }
 575
 576   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 577
 578   ''; #no error
 579 }
 580
 581 #discard bundled packages of 0 value
 582 sub _omit_zero_value_bundles {
 583
 584   my @cust_bill_pkg = ();
 585   my @cust_bill_pkg_bundle = ();
 586   my $sum = 0;
 587
 588   foreach my $cust_bill_pkg ( @_ ) {
 589     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 590       push @cust_bill_pkg, @cust_bill_pkg_bundle if $sum > 0;
 591       @cust_bill_pkg_bundle = ();
 592       $sum = 0;
 593     }
 594     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 595     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 596   }
 597   push @cust_bill_pkg, @cust_bill_pkg_bundle if $sum > 0;
 598
 599   (@cust_bill_pkg);
 600
 601 }
 602
 603 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 604
 605 This is a weird one.  Perhaps it should not even be exposed.
 606
 607 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 608 Usually used internally by bill method B<bill>.
 609
 610 If there is an error, returns the error, otherwise returns reference to a
 611 list of line items suitable for insertion.
 612
 613 =over 4
 614
 615 =item LINEITEMREF
 616
 617 An array ref of the line items being billed.
 618
 619 =item TAXHASHREF
 620
 621 A strange beast.  The keys to this hash are internal identifiers consisting
 622 of the name of the tax object type, a space, and its unique identifier ( e.g.
 623  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 624 item in the list is the tax object.  The remaining items are either line
 625 items or floating point values (currency amounts).
 626
 627 The taxes are calculated on this entity.  Calculated exemption records are
 628 transferred to the LINEITEMREF items on the assumption that they are related.
 629
 630 Read the source.
 631
 632 =item INVOICE_TIME
 633
 634 This specifies the date appearing on the associated invoice.  Some
 635 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 636
 637 =back
 638
 639 =cut
 640
 641 sub calculate_taxes {
 642   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 643
 644   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 645
 646   warn "$me calculate_taxes\n"
 647        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 648     if $DEBUG > 2;
 649
 650   my @tax_line_items = ();
 651
 652   # keys are tax names (as printed on invoices / itemdesc )
 653   # values are listrefs of taxlisthash keys (internal identifiers)
 654   my %taxname = ();
 655
 656   # keys are taxlisthash keys (internal identifiers)
 657   # values are (cumulative) amounts
 658   my %tax = ();
 659
 660   # keys are taxlisthash keys (internal identifiers)
 661   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 662   my %tax_location = ();
 663
 664   # keys are taxlisthash keys (internal identifiers)
 665   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 666   my %tax_rate_location = ();
 667
 668   foreach my $tax ( keys %$taxlisthash ) {
 669     my $tax_object = shift @{ $taxlisthash->{$tax} };
 670     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 671     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 672     my $hashref_or_error =
 673       $tax_object->taxline( $taxlisthash->{$tax},
 674                             'custnum'      => $self->custnum,
 675                             'invoice_time' => $invoice_time
 676                           );
 677     return $hashref_or_error unless ref($hashref_or_error);
 678
 679     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 680
 681     my $name   = $hashref_or_error->{'name'};
 682     my $amount = $hashref_or_error->{'amount'};
 683
 684     #warn "adding $amount as $name\n";
 685     $taxname{ $name } ||= [];
 686     push @{ $taxname{ $name } }, $tax;
 687
 688     $tax{ $tax } += $amount;
 689
 690     $tax_location{ $tax } ||= [];
 691     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 692       push @{ $tax_location{ $tax }  },
 693         {
 694           'taxnum'      => $tax_object->taxnum,
 695           'taxtype'     => ref($tax_object),
 696           'pkgnum'      => $tax_object->get('pkgnum'),
 697           'locationnum' => $tax_object->get('locationnum'),
 698           'amount'      => sprintf('%.2f', $amount ),
 699         };
 700     }
 701
 702     $tax_rate_location{ $tax } ||= [];
 703     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 704       my $taxratelocationnum =
 705         $tax_object->tax_rate_location->taxratelocationnum;
 706       push @{ $tax_rate_location{ $tax }  },
 707         {
 708           'taxnum'             => $tax_object->taxnum,
 709           'taxtype'            => ref($tax_object),
 710           'amount'             => sprintf('%.2f', $amount ),
 711           'locationtaxid'      => $tax_object->location,
 712           'taxratelocationnum' => $taxratelocationnum,
 713         };
 714     }
 715
 716   }
 717
 718   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 719   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 720   foreach my $tax ( keys %$taxlisthash ) {
 721     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 722       next unless ref($_) eq 'FS::cust_bill_pkg';
 723       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 724         splice( @{ $_->_cust_tax_exempt_pkg } );
 725     }
 726   }
 727
 728   #consolidate and create tax line items
 729   warn "consolidating and generating...\n" if $DEBUG > 2;
 730   foreach my $taxname ( keys %taxname ) {
 731     my $tax = 0;
 732     my %seen = ();
 733     my @cust_bill_pkg_tax_location = ();
 734     my @cust_bill_pkg_tax_rate_location = ();
 735     warn "adding $taxname\n" if $DEBUG > 1;
 736     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 737       next if $seen{$taxitem}++;
 738       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 739       $tax += $tax{$taxitem};
 740       push @cust_bill_pkg_tax_location,
 741         map { new FS::cust_bill_pkg_tax_location $_ }
 742             @{ $tax_location{ $taxitem } };
 743       push @cust_bill_pkg_tax_rate_location,
 744         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 745             @{ $tax_rate_location{ $taxitem } };
 746     }
 747     next unless $tax;
 748
 749     $tax = sprintf('%.2f', $tax );
 750
 751     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 752                                                    'disabled'     => '',
 753                                                  },
 754                                );
 755
 756     my @display = ();
 757     if ( $pkg_category and
 758          $conf->config('invoice_latexsummary') ||
 759          $conf->config('invoice_htmlsummary')
 760        )
 761     {
 762
 763       my %hash = (  'section' => $pkg_category->categoryname );
 764       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 765
 766     }
 767
 768     push @tax_line_items, new FS::cust_bill_pkg {
 769       'pkgnum'   => 0,
 770       'setup'    => $tax,
 771       'recur'    => 0,
 772       'sdate'    => '',
 773       'edate'    => '',
 774       'itemdesc' => $taxname,
 775       'display'  => \@display,
 776       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 777       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 778     };
 779
 780   }
 781
 782   \@tax_line_items;
 783 }
 784
 785 sub _make_lines {
 786   my ($self, %params) = @_;
 787
 788   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 789
 790   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 791   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 792   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 793   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 794   my $total_setup = $params{setup} or die "no setup accumulator specified";
 795   my $total_recur = $params{recur} or die "no recur accumulator specified";
 796   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 797   my $time = $params{'time'} or die "no time specified";
 798   my (%options) = %{$params{options}};
 799
 800   my $dbh = dbh;
 801   my $real_pkgpart = $params{real_pkgpart};
 802   my %hash = $cust_pkg->hash;
 803   my $old_cust_pkg = new FS::cust_pkg \%hash;
 804
 805   my @details = ();
 806   my @discounts = ();
 807   my $lineitems = 0;
 808
 809   $cust_pkg->pkgpart($part_pkg->pkgpart);
 810
 811   ###
 812   # bill setup
 813   ###
 814
 815   my $setup = 0;
 816   my $unitsetup = 0;
 817   if ( $options{'resetup'}
 818        || ( ! $cust_pkg->setup
 819             && ( ! $cust_pkg->start_date
 820                  || $cust_pkg->start_date <= $time
 821                )
 822             && ( ! $conf->exists('disable_setup_suspended_pkgs')
 823                  || ( $conf->exists('disable_setup_suspended_pkgs') &&
 824                       ! $cust_pkg->getfield('susp')
 825                     )
 826                )
 827           )
 828         and !$options{recurring_only}
 829     )
 830   {
 831
 832     warn "    bill setup\n" if $DEBUG > 1;
 833     $lineitems++;
 834
 835     $setup = eval { $cust_pkg->calc_setup( $time, \@details ) };
 836     return "$@ running calc_setup for $cust_pkg\n"
 837       if $@;
 838
 839     $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 840
 841     $cust_pkg->setfield('setup', $time)
 842       unless $cust_pkg->setup;
 843           #do need it, but it won't get written to the db
 844           #|| $cust_pkg->pkgpart != $real_pkgpart;
 845
 846     $cust_pkg->setfield('start_date', '')
 847       if $cust_pkg->start_date;
 848
 849   }
 850
 851   ###
 852   # bill recurring fee
 853   ###
 854
 855   #XXX unit stuff here too
 856   my $recur = 0;
 857   my $unitrecur = 0;
 858   my $sdate;
 859   if (     ! $cust_pkg->start_date
 860        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 861        and
 862             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $time )
 863          || ( $part_pkg->plan eq 'voip_cdr'
 864                && $part_pkg->option('bill_every_call')
 865             )
 866          || $options{cancel}
 867   ) {
 868
 869     # XXX should this be a package event?  probably.  events are called
 870     # at collection time at the moment, though...
 871     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 872       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 873       #don't want to reset usage just cause we want a line item??
 874       #&& $part_pkg->pkgpart == $real_pkgpart;
 875
 876     warn "    bill recur\n" if $DEBUG > 1;
 877     $lineitems++;
 878
 879     # XXX shared with $recur_prog
 880     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 881              || $cust_pkg->setup
 882              || $time;
 883
 884     #over two params!  lets at least switch to a hashref for the rest...
 885     my $increment_next_bill = ( $part_pkg->freq ne '0'
 886                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $time
 887                                 && !$options{cancel}
 888                               );
 889     my %param = ( 'precommit_hooks'     => $precommit_hooks,
 890                   'increment_next_bill' => $increment_next_bill,
 891                   'discounts'           => \@discounts,
 892                   'real_pkgpart'        => $real_pkgpart,
 893                   'freq_override'       => $options{freq_override} || '',
 894                 );
 895
 896     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
 897
 898     # There may be some part_pkg for which this is wrong.  Only those
 899     # which can_discount are supported.
 900     # (the UI should prevent adding discounts to these at the moment)
 901
 902     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
 903     return "$@ running $method for $cust_pkg\n"
 904       if ( $@ );
 905
 906     if ( $increment_next_bill ) {
 907
 908       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
 909       return "unparsable frequency: ". $part_pkg->freq
 910         if $next_bill == -1;
 911
 912       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
 913       # only for figuring next bill date, nothing else, so, reset $sdate again
 914       # here
 915       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 916       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
 917       $cust_pkg->last_bill($sdate);
 918
 919       $cust_pkg->setfield('bill', $next_bill );
 920
 921     }
 922
 923   }
 924
 925   warn "\$setup is undefined" unless defined($setup);
 926   warn "\$recur is undefined" unless defined($recur);
 927   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 928
 929   ###
 930   # If there's line items, create em cust_bill_pkg records
 931   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
 932   ###
 933
 934   if ( $lineitems ) {
 935
 936     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
 937       # hmm.. and if just the options are modified in some weird price plan?
 938
 939       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
 940         if $DEBUG >1;
 941
 942       my $error = $cust_pkg->replace( $old_cust_pkg,
 943                                       'options' => { $cust_pkg->options },
 944                                     )
 945         unless $options{no_commit};
 946       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
 947         if $error; #just in case
 948     }
 949
 950     $setup = sprintf( "%.2f", $setup );
 951     $recur = sprintf( "%.2f", $recur );
 952     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
 953       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
 954     }
 955     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
 956       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
 957     }
 958
 959     if ( $setup != 0 ||
 960          $recur != 0 ||
 961          !$part_pkg->hidden && $options{has_hidden} ) #include some $0 lines
 962     {
 963
 964       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
 965         if $DEBUG > 1;
 966
 967       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
 968       if ( $DEBUG > 1 ) {
 969         warn "      adding customer package invoice detail: $_\n"
 970           foreach @cust_pkg_detail;
 971       }
 972       push @details, @cust_pkg_detail;
 973
 974       my $cust_bill_pkg = new FS::cust_bill_pkg {
 975         'pkgnum'    => $cust_pkg->pkgnum,
 976         'setup'     => $setup,
 977         'unitsetup' => $unitsetup,
 978         'recur'     => $recur,
 979         'unitrecur' => $unitrecur,
 980         'quantity'  => $cust_pkg->quantity,
 981         'details'   => \@details,
 982         'discounts' => \@discounts,
 983         'hidden'    => $part_pkg->hidden,
 984         'freq'      => $part_pkg->freq,
 985       };
 986
 987       if ( $part_pkg->option('recur_temporality', 1) eq 'preceding' ) {
 988         $cust_bill_pkg->sdate( $hash{last_bill} );
 989         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
 990         $cust_bill_pkg->edate( $time ) if $options{cancel};
 991       } else { #if ( $part_pkg->option('recur_temporality', 1) eq 'upcoming' ) {
 992         $cust_bill_pkg->sdate( $sdate );
 993         $cust_bill_pkg->edate( $cust_pkg->bill );
 994         #$cust_bill_pkg->edate( $time ) if $options{cancel};
 995       }
 996
 997       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
 998         unless $part_pkg->pkgpart == $real_pkgpart;
 999
1000       $$total_setup += $setup;
1001       $$total_recur += $recur;
1002
1003       ###
1004       # handle taxes
1005       ###
1006
1007       my $error =
1008         $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1009       return $error if $error;
1010
1011       push @$cust_bill_pkgs, $cust_bill_pkg;
1012
1013     } #if $setup != 0 || $recur != 0
1014
1015   } #if $line_items
1016
1017   '';
1018
1019 }
1020
1021 sub _handle_taxes {
1022   my $self = shift;
1023   my $part_pkg = shift;
1024   my $taxlisthash = shift;
1025   my $cust_bill_pkg = shift;
1026   my $cust_pkg = shift;
1027   my $invoice_time = shift;
1028   my $real_pkgpart = shift;
1029   my $options = shift;
1030
1031   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1032
1033   my %cust_bill_pkg = ();
1034   my %taxes = ();
1035
1036   my @classes;
1037   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1038   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1039   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1040   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1041
1042   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1043
1044     if ( $conf->exists('enable_taxproducts')
1045          && ( scalar($part_pkg->part_pkg_taxoverride)
1046               || $part_pkg->has_taxproduct
1047             )
1048        )
1049     {
1050
1051       foreach my $class (@classes) {
1052         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1053         return $err_or_ref unless ref($err_or_ref);
1054         $taxes{$class} = $err_or_ref;
1055       }
1056
1057       unless (exists $taxes{''}) {
1058         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1059         return $err_or_ref unless ref($err_or_ref);
1060         $taxes{''} = $err_or_ref;
1061       }
1062
1063     } else {
1064
1065       my @loc_keys = qw( city county state country );
1066       my %taxhash;
1067       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1068         my $cust_location = $cust_pkg->cust_location;
1069         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1070       } else {
1071         my $prefix =
1072           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1073           ? 'ship_'
1074           : '';
1075         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1076       }
1077
1078       $taxhash{'taxclass'} = $part_pkg->taxclass;
1079
1080       my @taxes = ();
1081       my %taxhash_elim = %taxhash;
1082       my @elim = qw( city county state );
1083       do {
1084
1085         #first try a match with taxclass
1086         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1087
1088         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1089           #then try a match without taxclass
1090           my %no_taxclass = %taxhash_elim;
1091           $no_taxclass{ 'taxclass' } = '';
1092           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1093         }
1094
1095         $taxhash_elim{ shift(@elim) } = '';
1096
1097       } while ( !scalar(@taxes) && scalar(@elim) );
1098
1099       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1100                     @taxes
1101         if $self->cust_main_exemption; #just to be safe
1102
1103       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1104         foreach (@taxes) {
1105           $_->set('pkgnum',      $cust_pkg->pkgnum );
1106           $_->set('locationnum', $cust_pkg->locationnum );
1107         }
1108       }
1109
1110       $taxes{''} = [ @taxes ];
1111       $taxes{'setup'} = [ @taxes ];
1112       $taxes{'recur'} = [ @taxes ];
1113       $taxes{$_} = [ @taxes ] foreach (@classes);
1114
1115       # # maybe eliminate this entirely, along with all the 0% records
1116       # unless ( @taxes ) {
1117       #   return
1118       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1119       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1120       # }
1121
1122     } #if $conf->exists('enable_taxproducts') ...
1123
1124   }
1125
1126   my @display = ();
1127   my $separate = $conf->exists('separate_usage');
1128   my $temp_pkg = new FS::cust_pkg { pkgpart => $real_pkgpart };
1129   my $usage_mandate = $temp_pkg->part_pkg->option('usage_mandate', 'Hush!');
1130   my $section = $temp_pkg->part_pkg->categoryname;
1131   if ( $separate || $section || $usage_mandate ) {
1132
1133     my %hash = ( 'section' => $section );
1134
1135     $section = $temp_pkg->part_pkg->option('usage_section', 'Hush!');
1136     my $summary = $temp_pkg->part_pkg->option('summarize_usage', 'Hush!');
1137     if ( $separate ) {
1138       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1139       push @display, new FS::cust_bill_pkg_display { type => 'R', %hash };
1140     } else {
1141       push @display, new FS::cust_bill_pkg_display
1142                        { type => '',
1143                          %hash,
1144                          ( ( $usage_mandate ) ? ( 'summary' => 'Y' ) : () ),
1145                        };
1146     }
1147
1148     if ($separate && $section && $summary) {
1149       push @display, new FS::cust_bill_pkg_display { type    => 'U',
1150                                                      summary => 'Y',
1151                                                      %hash,
1152                                                    };
1153     }
1154     if ($usage_mandate || $section && $summary) {
1155       $hash{post_total} = 'Y';
1156     }
1157
1158     if ($separate || $usage_mandate) {
1159       $hash{section} = $section if ($separate || $usage_mandate);
1160       push @display, new FS::cust_bill_pkg_display { type => 'U', %hash };
1161     }
1162
1163   }
1164   $cust_bill_pkg->set('display', \@display);
1165
1166   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1167   foreach my $key (keys %tax_cust_bill_pkg) {
1168     my @taxes = @{ $taxes{$key} || [] };
1169     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1170
1171     my %localtaxlisthash = ();
1172     foreach my $tax ( @taxes ) {
1173
1174       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1175 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1176 #                  ' locationnum'. $cust_pkg->locationnum
1177 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1178
1179       $taxlisthash->{ $taxname } ||= [ $tax ];
1180       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1181
1182       $localtaxlisthash{ $taxname } ||= [ $tax ];
1183       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1184
1185     }
1186
1187     warn "finding taxed taxes...\n" if $DEBUG > 2;
1188     foreach my $tax ( keys %localtaxlisthash ) {
1189       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1190       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1191         if $DEBUG > 2;
1192       next unless $tax_object->can('tax_on_tax');
1193
1194       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1195         my $totname = ref( $tot ). ' '. $tot->taxnum;
1196
1197         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1198           if $DEBUG > 2;
1199         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1200                                                              # existing taxes
1201         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1202         my $hashref_or_error =
1203           $tax_object->taxline( $localtaxlisthash{$tax},
1204                                 'custnum'      => $self->custnum,
1205                                 'invoice_time' => $invoice_time,
1206                               );
1207         return $hashref_or_error
1208           unless ref($hashref_or_error);
1209
1210         $taxlisthash->{ $totname } ||= [ $tot ];
1211         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1212
1213       }
1214     }
1215
1216   }
1217
1218   '';
1219 }
1220
1221 sub _gather_taxes {
1222   my $self = shift;
1223   my $part_pkg = shift;
1224   my $class = shift;
1225   my $cust_pkg = shift;
1226
1227   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1228
1229   my $geocode;
1230   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1231     $geocode = $cust_pkg->cust_location->geocode('cch');
1232   } else {
1233     $geocode = $self->geocode('cch');
1234   }
1235
1236   my @taxes = ();
1237
1238   my @taxclassnums = map { $_->taxclassnum }
1239                      $part_pkg->part_pkg_taxoverride($class);
1240
1241   unless (@taxclassnums) {
1242     @taxclassnums = map { $_->taxclassnum }
1243                     grep { $_->taxable eq 'Y' }
1244                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1245   }
1246   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1247     if $DEBUG;
1248
1249   my $extra_sql =
1250     "AND (".
1251     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1252
1253   @taxes = qsearch({ 'table' => 'tax_rate',
1254                      'hashref' => { 'geocode' => $geocode, },
1255                      'extra_sql' => $extra_sql,
1256                   })
1257     if scalar(@taxclassnums);
1258
1259   warn "Found taxes ".
1260        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1261    if $DEBUG;
1262
1263   [ @taxes ];
1264
1265 }
1266
1267 =item collect [ HASHREF | OPTION => VALUE ... ]
1268
1269 (Attempt to) collect money for this customer's outstanding invoices (see
1270 L<FS::cust_bill>).  Usually used after the bill method.
1271
1272 Actions are now triggered by billing events; see L<FS::part_event> and the
1273 billing events web interface.  Old-style invoice events (see
1274 L<FS::part_bill_event>) have been deprecated.
1275
1276 If there is an error, returns the error, otherwise returns false.
1277
1278 Options are passed as name-value pairs.
1279
1280 Currently available options are:
1281
1282 =over 4
1283
1284 =item invoice_time
1285
1286 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1287
1288 =item retry
1289
1290 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1291
1292 =item check_freq
1293
1294 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1295
1296 =item quiet
1297
1298 set true to surpress email card/ACH decline notices.
1299
1300 =item debug
1301
1302 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1303
1304 =back
1305
1306 # =item payby
1307 #
1308 # allows for one time override of normal customer billing method
1309
1310 =cut
1311
1312 sub collect {
1313   my( $self, %options ) = @_;
1314
1315   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1316
1317   my $invoice_time = $options{'invoice_time'} || time;
1318
1319   #put below somehow?
1320   local $SIG{HUP} = 'IGNORE';
1321   local $SIG{INT} = 'IGNORE';
1322   local $SIG{QUIT} = 'IGNORE';
1323   local $SIG{TERM} = 'IGNORE';
1324   local $SIG{TSTP} = 'IGNORE';
1325   local $SIG{PIPE} = 'IGNORE';
1326
1327   my $oldAutoCommit = $FS::UID::AutoCommit;
1328   local $FS::UID::AutoCommit = 0;
1329   my $dbh = dbh;
1330
1331   $self->select_for_update; #mutex
1332
1333   if ( $DEBUG ) {
1334     my $balance = $self->balance;
1335     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1336   }
1337
1338   if ( exists($options{'retry_card'}) ) {
1339     carp 'retry_card option passed to collect is deprecated; use retry';
1340     $options{'retry'} ||= $options{'retry_card'};
1341   }
1342   if ( exists($options{'retry'}) && $options{'retry'} ) {
1343     my $error = $self->retry_realtime;
1344     if ( $error ) {
1345       $dbh->rollback if $oldAutoCommit;
1346       return $error;
1347     }
1348   }
1349
1350   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1351
1352   #never want to roll back an event just because it returned an error
1353   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1354
1355   $self->do_cust_event(
1356     'debug'      => ( $options{'debug'} || 0 ),
1357     'time'       => $invoice_time,
1358     'check_freq' => $options{'check_freq'},
1359     'stage'      => 'collect',
1360   );
1361
1362 }
1363
1364 =item retry_realtime
1365
1366 Schedules realtime / batch  credit card / electronic check / LEC billing
1367 events for for retry.  Useful if card information has changed or manual
1368 retry is desired.  The 'collect' method must be called to actually retry
1369 the transaction.
1370
1371 Implementation details: For either this customer, or for each of this
1372 customer's open invoices, changes the status of the first "done" (with
1373 statustext error) realtime processing event to "failed".
1374
1375 =cut
1376
1377 sub retry_realtime {
1378   my $self = shift;
1379
1380   local $SIG{HUP} = 'IGNORE';
1381   local $SIG{INT} = 'IGNORE';
1382   local $SIG{QUIT} = 'IGNORE';
1383   local $SIG{TERM} = 'IGNORE';
1384   local $SIG{TSTP} = 'IGNORE';
1385   local $SIG{PIPE} = 'IGNORE';
1386
1387   my $oldAutoCommit = $FS::UID::AutoCommit;
1388   local $FS::UID::AutoCommit = 0;
1389   my $dbh = dbh;
1390
1391   #a little false laziness w/due_cust_event (not too bad, really)
1392
1393   my $join = FS::part_event_condition->join_conditions_sql;
1394   my $order = FS::part_event_condition->order_conditions_sql;
1395   my $mine =
1396   '( '
1397    . join ( ' OR ' , map {
1398     "( part_event.eventtable = " . dbh->quote($_)
1399     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1400    } FS::part_event->eventtables)
1401    . ') ';
1402
1403   #here is the agent virtualization
1404   my $agent_virt = " (    part_event.agentnum IS NULL
1405                        OR part_event.agentnum = ". $self->agentnum. ' )';
1406
1407   #XXX this shouldn't be hardcoded, actions should declare it...
1408   my @realtime_events = qw(
1409     cust_bill_realtime_card
1410     cust_bill_realtime_check
1411     cust_bill_realtime_lec
1412     cust_bill_batch
1413   );
1414
1415   my $is_realtime_event = ' ( '. join(' OR ', map "part_event.action = '$_'",
1416                                                   @realtime_events
1417                                      ).
1418                           ' ) ';
1419
1420   my @cust_event = qsearchs({
1421     'table'     => 'cust_event',
1422     'select'    => 'cust_event.*',
1423     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1424     'hashref'   => { 'status' => 'done' },
1425     'extra_sql' => " AND statustext IS NOT NULL AND statustext != '' ".
1426                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1427   });
1428
1429   my %seen_invnum = ();
1430   foreach my $cust_event (@cust_event) {
1431
1432     #max one for the customer, one for each open invoice
1433     my $cust_X = $cust_event->cust_X;
1434     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1435                           ? $cust_X->invnum
1436                           : 0
1437                         }++
1438          or $cust_event->part_event->eventtable eq 'cust_bill'
1439             && ! $cust_X->owed;
1440
1441     my $error = $cust_event->retry;
1442     if ( $error ) {
1443       $dbh->rollback if $oldAutoCommit;
1444       return "error scheduling event for retry: $error";
1445     }
1446
1447   }
1448
1449   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1450   '';
1451
1452 }
1453
1454 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1455
1456 Runs billing events; see L<FS::part_event> and the billing events web
1457 interface.
1458
1459 If there is an error, returns the error, otherwise returns false.
1460
1461 Options are passed as name-value pairs.
1462
1463 Currently available options are:
1464
1465 =over 4
1466
1467 =item time
1468
1469 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1470
1471 =item check_freq
1472
1473 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1474
1475 =item stage
1476
1477 "collect" (the default) or "pre-bill"
1478
1479 =item quiet
1480
1481 set true to surpress email card/ACH decline notices.
1482
1483 =item debug
1484
1485 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1486
1487 =back
1488 =cut
1489
1490 # =item payby
1491 #
1492 # allows for one time override of normal customer billing method
1493
1494 # =item retry
1495 #
1496 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1497
1498 sub do_cust_event {
1499   my( $self, %options ) = @_;
1500
1501   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1502
1503   my $time = $options{'time'} || time;
1504
1505   #put below somehow?
1506   local $SIG{HUP} = 'IGNORE';
1507   local $SIG{INT} = 'IGNORE';
1508   local $SIG{QUIT} = 'IGNORE';
1509   local $SIG{TERM} = 'IGNORE';
1510   local $SIG{TSTP} = 'IGNORE';
1511   local $SIG{PIPE} = 'IGNORE';
1512
1513   my $oldAutoCommit = $FS::UID::AutoCommit;
1514   local $FS::UID::AutoCommit = 0;
1515   my $dbh = dbh;
1516
1517   $self->select_for_update; #mutex
1518
1519   if ( $DEBUG ) {
1520     my $balance = $self->balance;
1521     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1522   }
1523
1524 #  if ( exists($options{'retry_card'}) ) {
1525 #    carp 'retry_card option passed to collect is deprecated; use retry';
1526 #    $options{'retry'} ||= $options{'retry_card'};
1527 #  }
1528 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1529 #    my $error = $self->retry_realtime;
1530 #    if ( $error ) {
1531 #      $dbh->rollback if $oldAutoCommit;
1532 #      return $error;
1533 #    }
1534 #  }
1535
1536   # false laziness w/pay_batch::import_results
1537
1538   my $due_cust_event = $self->due_cust_event(
1539     'debug'      => ( $options{'debug'} || 0 ),
1540     'time'       => $time,
1541     'check_freq' => $options{'check_freq'},
1542     'stage'      => ( $options{'stage'} || 'collect' ),
1543   );
1544   unless( ref($due_cust_event) ) {
1545     $dbh->rollback if $oldAutoCommit;
1546     return $due_cust_event;
1547   }
1548
1549   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1550   #never want to roll back an event just because it or a different one
1551   # returned an error
1552   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1553
1554   foreach my $cust_event ( @$due_cust_event ) {
1555
1556     #XXX lock event
1557
1558     #re-eval event conditions (a previous event could have changed things)
1559     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1560       #don't leave stray "new/locked" records around
1561       my $error = $cust_event->delete;
1562       return $error if $error;
1563       next;
1564     }
1565
1566     {
1567       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1568         if $options{'quiet'};
1569       warn "  running cust_event ". $cust_event->eventnum. "\n"
1570         if $DEBUG > 1;
1571
1572       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1573       if ( my $error = $cust_event->do_event() ) {
1574         #XXX wtf is this?  figure out a proper dealio with return value
1575         #from do_event
1576         return $error;
1577       }
1578     }
1579
1580   }
1581
1582   '';
1583
1584 }
1585
1586 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1587
1588 Inserts database records for and returns an ordered listref of new events due
1589 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1590 events are due, an empty listref is returned.  If there is an error, returns a
1591 scalar error message.
1592
1593 To actually run the events, call each event's test_condition method, and if
1594 still true, call the event's do_event method.
1595
1596 Options are passed as a hashref or as a list of name-value pairs.  Available
1597 options are:
1598
1599 =over 4
1600
1601 =item check_freq
1602
1603 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1604
1605 =item stage
1606
1607 "collect" (the default) or "pre-bill"
1608
1609 =item time
1610
1611 "Current time" for the events.
1612
1613 =item debug
1614
1615 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1616
1617 =item eventtable
1618
1619 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1620
1621 =item objects
1622
1623 Explicitly pass the objects to be tested (typically used with eventtable).
1624
1625 =item testonly
1626
1627 Set to true to return the objects, but not actually insert them into the
1628 database.
1629
1630 =back
1631
1632 =cut
1633
1634 sub due_cust_event {
1635   my $self = shift;
1636   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1637
1638   #???
1639   #my $DEBUG = $opt{'debug'}
1640   local($DEBUG) = $opt{'debug'}
1641     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1642   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1643
1644   warn "$me due_cust_event called with options ".
1645        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1646     if $DEBUG;
1647
1648   $opt{'time'} ||= time;
1649
1650   local $SIG{HUP} = 'IGNORE';
1651   local $SIG{INT} = 'IGNORE';
1652   local $SIG{QUIT} = 'IGNORE';
1653   local $SIG{TERM} = 'IGNORE';
1654   local $SIG{TSTP} = 'IGNORE';
1655   local $SIG{PIPE} = 'IGNORE';
1656
1657   my $oldAutoCommit = $FS::UID::AutoCommit;
1658   local $FS::UID::AutoCommit = 0;
1659   my $dbh = dbh;
1660
1661   $self->select_for_update #mutex
1662     unless $opt{testonly};
1663
1664   ###
1665   # find possible events (initial search)
1666   ###
1667
1668   my @cust_event = ();
1669
1670   my @eventtable = $opt{'eventtable'}
1671                      ? ( $opt{'eventtable'} )
1672                      : FS::part_event->eventtables_runorder;
1673
1674   my $check_freq = $opt{'check_freq'} || '1d';
1675
1676   foreach my $eventtable ( @eventtable ) {
1677
1678     my @objects;
1679     if ( $opt{'objects'} ) {
1680
1681       @objects = @{ $opt{'objects'} };
1682
1683     } else {
1684
1685       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1686       if ( $eventtable eq 'cust_main' ) {
1687         @objects = ( $self );
1688       } else {
1689
1690         my $cm_join =
1691           "LEFT JOIN cust_main USING ( custnum )";
1692
1693         #some false laziness w/Cron::bill bill_where
1694
1695         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1696         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1697                                                            'time'=>$opt{'time'},
1698                                                                   );
1699         $where = $where ? "AND $where" : '';
1700
1701         my $are_part_event =
1702           "EXISTS ( SELECT 1 FROM part_event $join
1703                       WHERE check_freq = '$check_freq'
1704                         AND eventtable = '$eventtable'
1705                         AND ( disabled = '' OR disabled IS NULL )
1706                         $where
1707                   )
1708           ";
1709         #eofalse
1710
1711         @objects = $self->$eventtable(
1712                      'addl_from' => $cm_join,
1713                      'extra_sql' => " AND $are_part_event",
1714                    );
1715       }
1716
1717     }
1718
1719     my @e_cust_event = ();
1720
1721     my $cross = "CROSS JOIN $eventtable";
1722     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1723       unless $eventtable eq 'cust_main';
1724
1725     foreach my $object ( @objects ) {
1726
1727       #this first search uses the condition_sql magic for optimization.
1728       #the more possible events we can eliminate in this step the better
1729
1730       my $cross_where = '';
1731       my $pkey = $object->primary_key;
1732       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1733
1734       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1735       my $extra_sql =
1736         FS::part_event_condition->where_conditions_sql( $eventtable,
1737                                                         'time'=>$opt{'time'}
1738                                                       );
1739       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1740
1741       $extra_sql = "AND $extra_sql" if $extra_sql;
1742
1743       #here is the agent virtualization
1744       $extra_sql .= " AND (    part_event.agentnum IS NULL
1745                             OR part_event.agentnum = ". $self->agentnum. ' )';
1746
1747       $extra_sql .= " $order";
1748
1749       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1750         if $opt{'debug'} > 2;
1751       my @part_event = qsearch( {
1752         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1753         'select'    => 'part_event.*',
1754         'table'     => 'part_event',
1755         'addl_from' => "$cross $join",
1756         'hashref'   => { 'check_freq' => $check_freq,
1757                          'eventtable' => $eventtable,
1758                          'disabled'   => '',
1759                        },
1760         'extra_sql' => "AND $cross_where $extra_sql",
1761       } );
1762
1763       if ( $DEBUG > 2 ) {
1764         my $pkey = $object->primary_key;
1765         warn "      ". scalar(@part_event).
1766              " possible events found for $eventtable ". $object->$pkey(). "\n";
1767       }
1768
1769       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1770
1771     }
1772
1773     warn "    ". scalar(@e_cust_event).
1774          " subtotal possible cust events found for $eventtable\n"
1775       if $DEBUG > 1;
1776
1777     push @cust_event, @e_cust_event;
1778
1779   }
1780
1781   warn "  ". scalar(@cust_event).
1782        " total possible cust events found in initial search\n"
1783     if $DEBUG; # > 1;
1784
1785
1786   ##
1787   # test stage
1788   ##
1789
1790   $opt{stage} ||= 'collect';
1791   @cust_event =
1792     grep { my $stage = $_->part_event->event_stage;
1793            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1794          }
1795          @cust_event;
1796
1797   ##
1798   # test conditions
1799   ##
1800
1801   my %unsat = ();
1802
1803   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1804                                           'stats_hashref' => \%unsat ),
1805                      @cust_event;
1806
1807   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1808     if $DEBUG; # > 1;
1809
1810   warn "    invalid conditions not eliminated with condition_sql:\n".
1811        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1812     if keys %unsat && $DEBUG; # > 1;
1813
1814   ##
1815   # insert
1816   ##
1817
1818   unless( $opt{testonly} ) {
1819     foreach my $cust_event ( @cust_event ) {
1820
1821       my $error = $cust_event->insert();
1822       if ( $error ) {
1823         $dbh->rollback if $oldAutoCommit;
1824         return $error;
1825       }
1826
1827     }
1828   }
1829
1830   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1831
1832   ##
1833   # return
1834   ##
1835
1836   warn "  returning events: ". Dumper(@cust_event). "\n"
1837     if $DEBUG > 2;
1838
1839   \@cust_event;
1840
1841 }
1842
1843 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1844
1845 Applies unapplied payments and credits.
1846
1847 In most cases, this new method should be used in place of sequential
1848 apply_payments and apply_credits methods.
1849
1850 A hash of optional arguments may be passed.  Currently "manual" is supported.
1851 If true, a payment receipt is sent instead of a statement when
1852 'payment_receipt_email' configuration option is set.
1853
1854 If there is an error, returns the error, otherwise returns false.
1855
1856 =cut
1857
1858 sub apply_payments_and_credits {
1859   my( $self, %options ) = @_;
1860
1861   local $SIG{HUP} = 'IGNORE';
1862   local $SIG{INT} = 'IGNORE';
1863   local $SIG{QUIT} = 'IGNORE';
1864   local $SIG{TERM} = 'IGNORE';
1865   local $SIG{TSTP} = 'IGNORE';
1866   local $SIG{PIPE} = 'IGNORE';
1867
1868   my $oldAutoCommit = $FS::UID::AutoCommit;
1869   local $FS::UID::AutoCommit = 0;
1870   my $dbh = dbh;
1871
1872   $self->select_for_update; #mutex
1873
1874   foreach my $cust_bill ( $self->open_cust_bill ) {
1875     my $error = $cust_bill->apply_payments_and_credits(%options);
1876     if ( $error ) {
1877       $dbh->rollback if $oldAutoCommit;
1878       return "Error applying: $error";
1879     }
1880   }
1881
1882   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1883   ''; #no error
1884
1885 }
1886
1887 =item apply_credits OPTION => VALUE ...
1888
1889 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1890 to outstanding invoice balances in chronological order (or reverse
1891 chronological order if the I<order> option is set to B<newest>) and returns the
1892 value of any remaining unapplied credits available for refund (see
1893 L<FS::cust_refund>).
1894
1895 Dies if there is an error.
1896
1897 =cut
1898
1899 sub apply_credits {
1900   my $self = shift;
1901   my %opt = @_;
1902
1903   local $SIG{HUP} = 'IGNORE';
1904   local $SIG{INT} = 'IGNORE';
1905   local $SIG{QUIT} = 'IGNORE';
1906   local $SIG{TERM} = 'IGNORE';
1907   local $SIG{TSTP} = 'IGNORE';
1908   local $SIG{PIPE} = 'IGNORE';
1909
1910   my $oldAutoCommit = $FS::UID::AutoCommit;
1911   local $FS::UID::AutoCommit = 0;
1912   my $dbh = dbh;
1913
1914   $self->select_for_update; #mutex
1915
1916   unless ( $self->total_unapplied_credits ) {
1917     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1918     return 0;
1919   }
1920
1921   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1922       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1923
1924   my @invoices = $self->open_cust_bill;
1925   @invoices = sort { $b->_date <=> $a->_date } @invoices
1926     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
1927
1928   if ( $conf->exists('pkg-balances') ) {
1929     # limit @credits to those w/ a pkgnum grepped from $self
1930     my %pkgnums = ();
1931     foreach my $i (@invoices) {
1932       foreach my $li ( $i->cust_bill_pkg ) {
1933         $pkgnums{$li->pkgnum} = 1;
1934       }
1935     }
1936     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
1937   }
1938
1939   my $credit;
1940
1941   foreach my $cust_bill ( @invoices ) {
1942
1943     if ( !defined($credit) || $credit->credited == 0) {
1944       $credit = pop @credits or last;
1945     }
1946
1947     my $owed;
1948     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
1949       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
1950     } else {
1951       $owed = $cust_bill->owed;
1952     }
1953     unless ( $owed > 0 ) {
1954       push @credits, $credit;
1955       next;
1956     }
1957
1958     my $amount = min( $credit->credited, $owed );
1959
1960     my $cust_credit_bill = new FS::cust_credit_bill ( {
1961       'crednum' => $credit->crednum,
1962       'invnum'  => $cust_bill->invnum,
1963       'amount'  => $amount,
1964     } );
1965     $cust_credit_bill->pkgnum( $credit->pkgnum )
1966       if $conf->exists('pkg-balances') && $credit->pkgnum;
1967     my $error = $cust_credit_bill->insert;
1968     if ( $error ) {
1969       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
1970       die $error;
1971     }
1972
1973     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
1974
1975   }
1976
1977   my $total_unapplied_credits = $self->total_unapplied_credits;
1978
1979   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1980
1981   return $total_unapplied_credits;
1982 }
1983
1984 =item apply_payments  [ OPTION => VALUE ... ]
1985
1986 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
1987 to outstanding invoice balances in chronological order.
1988
1989  #and returns the value of any remaining unapplied payments.
1990
1991 A hash of optional arguments may be passed.  Currently "manual" is supported.
1992 If true, a payment receipt is sent instead of a statement when
1993 'payment_receipt_email' configuration option is set.
1994
1995 Dies if there is an error.
1996
1997 =cut
1998
1999 sub apply_payments {
2000   my( $self, %options ) = @_;
2001
2002   local $SIG{HUP} = 'IGNORE';
2003   local $SIG{INT} = 'IGNORE';
2004   local $SIG{QUIT} = 'IGNORE';
2005   local $SIG{TERM} = 'IGNORE';
2006   local $SIG{TSTP} = 'IGNORE';
2007   local $SIG{PIPE} = 'IGNORE';
2008
2009   my $oldAutoCommit = $FS::UID::AutoCommit;
2010   local $FS::UID::AutoCommit = 0;
2011   my $dbh = dbh;
2012
2013   $self->select_for_update; #mutex
2014
2015   #return 0 unless
2016
2017   my @payments = sort { $b->_date <=> $a->_date }
2018                  grep { $_->unapplied > 0 }
2019                  $self->cust_pay;
2020
2021   my @invoices = sort { $a->_date <=> $b->_date}
2022                  grep { $_->owed > 0 }
2023                  $self->cust_bill;
2024
2025   if ( $conf->exists('pkg-balances') ) {
2026     # limit @payments to those w/ a pkgnum grepped from $self
2027     my %pkgnums = ();
2028     foreach my $i (@invoices) {
2029       foreach my $li ( $i->cust_bill_pkg ) {
2030         $pkgnums{$li->pkgnum} = 1;
2031       }
2032     }
2033     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2034   }
2035
2036   my $payment;
2037
2038   foreach my $cust_bill ( @invoices ) {
2039
2040     if ( !defined($payment) || $payment->unapplied == 0 ) {
2041       $payment = pop @payments or last;
2042     }
2043
2044     my $owed;
2045     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2046       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2047     } else {
2048       $owed = $cust_bill->owed;
2049     }
2050     unless ( $owed > 0 ) {
2051       push @payments, $payment;
2052       next;
2053     }
2054
2055     my $amount = min( $payment->unapplied, $owed );
2056
2057     my $cust_bill_pay = new FS::cust_bill_pay ( {
2058       'paynum' => $payment->paynum,
2059       'invnum' => $cust_bill->invnum,
2060       'amount' => $amount,
2061     } );
2062     $cust_bill_pay->pkgnum( $payment->pkgnum )
2063       if $conf->exists('pkg-balances') && $payment->pkgnum;
2064     my $error = $cust_bill_pay->insert(%options);
2065     if ( $error ) {
2066       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2067       die $error;
2068     }
2069
2070     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2071
2072   }
2073
2074   my $total_unapplied_payments = $self->total_unapplied_payments;
2075
2076   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2077
2078   return $total_unapplied_payments;
2079 }
2080
2081 =back
2082
2083 =head1 FLOW
2084
2085   bill_and_collect
2086
2087     cancel_expired_pkgs
2088     suspend_adjourned_pkgs
2089
2090     bill
2091       (do_cust_event pre-bill)
2092       _make_lines
2093         _handle_taxes
2094           (vendor-only) _gather_taxes
2095       _omit_zero_value_bundles
2096       calculate_taxes
2097
2098     apply_payments_and_credits
2099     collect
2100       do_cust_event
2101         due_cust_event
2102
2103 =head1 BUGS
2104
2105 =head1 SEE ALSO
2106
2107 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2108
2109 =cut
2110
2111 1;