FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24 use FS::cust_event_fee;
  25 use FS::Log;
  26
  27 # 1 is mostly method/subroutine entry and options
  28 # 2 traces progress of some operations
  29 # 3 is even more information including possibly sensitive data
  30 $DEBUG = 0;
  31 $me = '[FS::cust_main::Billing]';
  32
  33 install_callback FS::UID sub {
  34   $conf = new FS::Conf;
  35   #yes, need it for stuff below (prolly should be cached)
  36 };
  37
  38 =head1 NAME
  39
  40 FS::cust_main::Billing - Billing mixin for cust_main
  41
  42 =head1 SYNOPSIS
  43
  44 =head1 DESCRIPTION
  45
  46 These methods are available on FS::cust_main objects.
  47
  48 =head1 METHODS
  49
  50 =over 4
  51
  52 =item bill_and_collect
  53
  54 Cancels and suspends any packages due, generates bills, applies payments and
  55 credits, and applies collection events to run cards, send bills and notices,
  56 etc.
  57
  58 By default, warns on errors and continues with the next operation (but see the
  59 "fatal" flag below).
  60
  61 Options are passed as name-value pairs.  Currently available options are:
  62
  63 =over 4
  64
  65 =item time
  66
  67 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  68
  69  use Date::Parse;
  70  ...
  71  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  72
  73 =item invoice_time
  74
  75 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  76
  77 =item check_freq
  78
  79 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  80
  81 =item resetup
  82
  83 If set true, re-charges setup fees.
  84
  85 =item fatal
  86
  87 If set any errors prevent subsequent operations from continusing.  If set
  88 specifically to "return", returns the error (or false, if there is no error).
  89 Any other true value causes errors to die.
  90
  91 =item debug
  92
  93 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  94
  95 =item job
  96
  97 Optional FS::queue entry to receive status updates.
  98
  99 =back
 100
 101 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 102 options of those methods are also available.
 103
 104 =cut
 105
 106 sub bill_and_collect {
 107   my( $self, %options ) = @_;
 108
 109   my $log = FS::Log->new('bill_and_collect');
 110   $log->debug('start', object => $self, agentnum => $self->agentnum);
 111
 112   my $error;
 113
 114   #$options{actual_time} not $options{time} because freeside-daily -d is for
 115   #pre-printing invoices
 116
 117   $options{'actual_time'} ||= time;
 118   my $job = $options{'job'};
 119
 120   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 121                         ? day_end( $options{actual_time} )
 122                         : $options{actual_time}
 123                     );
 124
 125   $job->update_statustext('0,cleaning expired packages') if $job;
 126   $error = $self->cancel_expired_pkgs( $actual_time );
 127   if ( $error ) {
 128     $error = "Error expiring custnum ". $self->custnum. ": $error";
 129     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 130     elsif ( $options{fatal}                                ) { die    $error; }
 131     else                                                     { warn   $error; }
 132   }
 133
 134   $error = $self->suspend_adjourned_pkgs( $actual_time );
 135   if ( $error ) {
 136     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 137     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 138     elsif ( $options{fatal}                                ) { die    $error; }
 139     else                                                     { warn   $error; }
 140   }
 141
 142   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 143   if ( $error ) {
 144     $error = "Error resuming custnum ".$self->custnum. ": $error";
 145     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 146     elsif ( $options{fatal}                                ) { die    $error; }
 147     else                                                     { warn   $error; }
 148   }
 149
 150   $job->update_statustext('20,billing packages') if $job;
 151   $error = $self->bill( %options );
 152   if ( $error ) {
 153     $error = "Error billing custnum ". $self->custnum. ": $error";
 154     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 155     elsif ( $options{fatal}                                ) { die    $error; }
 156     else                                                     { warn   $error; }
 157   }
 158
 159   $job->update_statustext('50,applying payments and credits') if $job;
 160   $error = $self->apply_payments_and_credits;
 161   if ( $error ) {
 162     $error = "Error applying custnum ". $self->custnum. ": $error";
 163     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 164     elsif ( $options{fatal}                                ) { die    $error; }
 165     else                                                     { warn   $error; }
 166   }
 167
 168   $job->update_statustext('70,running collection events') if $job;
 169   unless ( $conf->exists('cancelled_cust-noevents')
 170            && ! $self->num_ncancelled_pkgs
 171   ) {
 172     $error = $self->collect( %options );
 173     if ( $error ) {
 174       $error = "Error collecting custnum ". $self->custnum. ": $error";
 175       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 176       elsif ($options{fatal}                               ) { die    $error; }
 177       else                                                   { warn   $error; }
 178     }
 179   }
 180   $job->update_statustext('100,finished') if $job;
 181   $log->debug('finish', object => $self, agentnum => $self->agentnum);
 182
 183   '';
 184
 185 }
 186
 187 sub cancel_expired_pkgs {
 188   my ( $self, $time, %options ) = @_;
 189
 190   my @cancel_pkgs = $self->ncancelled_pkgs( {
 191     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 192   } );
 193
 194   my @errors = ();
 195
 196   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 197     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 198     my $error;
 199
 200     if ( $cust_pkg->change_to_pkgnum ) {
 201
 202       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 203       if ( !$new_pkg ) {
 204         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 205                       $cust_pkg->change_to_pkgnum.'; not expiring';
 206         next CUST_PKG;
 207       }
 208       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 209                                   'unprotect_svcs'  => 1 );
 210       $error = '' if ref $error eq 'FS::cust_pkg';
 211
 212     } else { # just cancel it
 213        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 214                                            'reason_otaker' => $cpr->otaker,
 215                                            'time'          => $time,
 216                                          )
 217                                        : ()
 218                                  );
 219     }
 220     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 221   }
 222
 223   join(' / ', @errors);
 224
 225 }
 226
 227 sub suspend_adjourned_pkgs {
 228   my ( $self, $time, %options ) = @_;
 229
 230   my @susp_pkgs = $self->ncancelled_pkgs( {
 231     'extra_sql' =>
 232       " AND ( susp IS NULL OR susp = 0 )
 233         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 234               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 235             )
 236       ",
 237   } );
 238
 239   #only because there's no SQL test for is_prepaid :/
 240   @susp_pkgs =
 241     grep {     (    $_->part_pkg->is_prepaid
 242                  && $_->bill
 243                  && $_->bill < $time
 244                )
 245             || (    $_->adjourn
 246                  && $_->adjourn <= $time
 247                )
 248
 249          }
 250          @susp_pkgs;
 251
 252   my @errors = ();
 253
 254   foreach my $cust_pkg ( @susp_pkgs ) {
 255     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 256       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 257     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 258                                             'reason_otaker' => $cpr->otaker
 259                                           )
 260                                         : ()
 261                                   );
 262     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 263   }
 264
 265   join(' / ', @errors);
 266
 267 }
 268
 269 sub unsuspend_resumed_pkgs {
 270   my ( $self, $time, %options ) = @_;
 271
 272   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 273     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 274   } );
 275
 276   my @errors = ();
 277
 278   foreach my $cust_pkg ( @unsusp_pkgs ) {
 279     my $error = $cust_pkg->unsuspend( 'time' => $time );
 280     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 281   }
 282
 283   join(' / ', @errors);
 284
 285 }
 286
 287 =item bill OPTIONS
 288
 289 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 290 conjunction with the collect method by calling B<bill_and_collect>.
 291
 292 If there is an error, returns the error, otherwise returns false.
 293
 294 Options are passed as name-value pairs.  Currently available options are:
 295
 296 =over 4
 297
 298 =item resetup
 299
 300 If set true, re-charges setup fees.
 301
 302 =item recurring_only
 303
 304 If set true then only bill recurring charges, not setup, usage, one time
 305 charges, etc.
 306
 307 =item freq_override
 308
 309 If set, then override the normal frequency and look for a part_pkg_discount
 310 to take at that frequency.  This is appropriate only when the normal
 311 frequency for all packages is monthly, and is an error otherwise.  Use
 312 C<pkg_list> to limit the set of packages included in billing.
 313
 314 =item time
 315
 316 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 317
 318  use Date::Parse;
 319  ...
 320  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 321
 322 =item pkg_list
 323
 324 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 325
 326  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 327
 328 =item not_pkgpart
 329
 330 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 331
 332 =item no_prepaid
 333
 334 Do not bill prepaid packages.  Used by freeside-daily.
 335
 336 =item invoice_time
 337
 338 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 339
 340 =item cancel
 341
 342 This boolean value informs the us that the package is being cancelled.  This
 343 typically might mean not charging the normal recurring fee but only usage
 344 fees since the last billing. Setup charges may be charged.  Not all package
 345 plans support this feature (they tend to charge 0).
 346
 347 =item no_usage_reset
 348
 349 Prevent the resetting of usage limits during this call.
 350
 351 =item no_commit
 352
 353 Do not save the generated bill in the database.  Useful with return_bill
 354
 355 =item return_bill
 356
 357 A list reference on which the generated bill(s) will be returned.
 358
 359 =item invoice_terms
 360
 361 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 362 terms or the default terms are used.
 363
 364 =back
 365
 366 =cut
 367
 368 sub bill {
 369   my( $self, %options ) = @_;
 370
 371   return '' if $self->payby eq 'COMP';
 372
 373   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 374
 375   warn "$me bill customer ". $self->custnum. "\n"
 376     if $DEBUG;
 377
 378   my $time = $options{'time'} || time;
 379   my $invoice_time = $options{'invoice_time'} || $time;
 380
 381   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 382                      ? day_end( $time )
 383                      : $time
 384                  );
 385
 386   $options{'not_pkgpart'} ||= {};
 387   $options{'not_pkgpart'} = { map { $_ => 1 }
 388                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 389                             }
 390     unless ref($options{'not_pkgpart'});
 391
 392   local $SIG{HUP} = 'IGNORE';
 393   local $SIG{INT} = 'IGNORE';
 394   local $SIG{QUIT} = 'IGNORE';
 395   local $SIG{TERM} = 'IGNORE';
 396   local $SIG{TSTP} = 'IGNORE';
 397   local $SIG{PIPE} = 'IGNORE';
 398
 399   my $oldAutoCommit = $FS::UID::AutoCommit;
 400   local $FS::UID::AutoCommit = 0;
 401   my $dbh = dbh;
 402
 403   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 404     if $DEBUG;
 405
 406   $self->select_for_update; #mutex
 407
 408   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 409     if $DEBUG;
 410
 411   my $error = $self->do_cust_event(
 412     'debug'      => ( $options{'debug'} || 0 ),
 413     'time'       => $invoice_time,
 414     'check_freq' => $options{'check_freq'},
 415     'stage'      => 'pre-bill',
 416   )
 417     unless $options{no_commit};
 418   if ( $error ) {
 419     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 420     return $error;
 421   }
 422
 423   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 424     if $DEBUG;
 425
 426   #keep auto-charge and non-auto-charge line items separate
 427   my @passes = ( '', 'no_auto' );
 428
 429   my %cust_bill_pkg = map { $_ => [] } @passes;
 430
 431   ###
 432   # find the packages which are due for billing, find out how much they are
 433   # & generate invoice database.
 434   ###
 435
 436   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 437   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 438
 439   my %taxlisthash = map { $_ => {} } @passes;
 440
 441   my @precommit_hooks = ();
 442
 443   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 444
 445   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 446
 447     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 448
 449     my $part_pkg = $cust_pkg->part_pkg;
 450
 451     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 452
 453     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 454
 455     #? to avoid use of uninitialized value errors... ?
 456     $cust_pkg->setfield('bill', '')
 457       unless defined($cust_pkg->bill);
 458
 459     my $real_pkgpart = $cust_pkg->pkgpart;
 460     my %hash = $cust_pkg->hash;
 461
 462     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 463     # suffer from performance issues
 464     $options{has_hidden} = 0;
 465     my @part_pkg = $part_pkg->self_and_bill_linked;
 466     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 467
 468     # if this package was changed from another package,
 469     # and it hasn't been billed since then,
 470     # and package balances are enabled,
 471     if ( $cust_pkg->change_pkgnum
 472         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 473         and $cust_pkg->change_date <  $invoice_time
 474       and $conf->exists('pkg-balances') )
 475     {
 476       # _transfer_balance will also create the appropriate credit
 477       my @transfer_items = $self->_transfer_balance($cust_pkg);
 478       # $part_pkg[0] is the "real" part_pkg
 479       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 480                   'no_auto' : '';
 481       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 482       # treating this as recur, just because most charges are recur...
 483       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 484     }
 485
 486     foreach my $part_pkg ( @part_pkg ) {
 487
 488       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 489
 490       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 491
 492       my $next_bill = $cust_pkg->getfield('bill') || 0;
 493       my $error;
 494       # let this run once if this is the last bill upon cancellation
 495       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 496         $error =
 497           $self->_make_lines( 'part_pkg'            => $part_pkg,
 498                               'cust_pkg'            => $cust_pkg,
 499                               'precommit_hooks'     => \@precommit_hooks,
 500                               'line_items'          => $cust_bill_pkg{$pass},
 501                               'setup'               => $total_setup{$pass},
 502                               'recur'               => $total_recur{$pass},
 503                               'tax_matrix'          => $taxlisthash{$pass},
 504                               'time'                => $time,
 505                               'real_pkgpart'        => $real_pkgpart,
 506                               'options'             => \%options,
 507                             );
 508
 509         # Stop if anything goes wrong
 510         last if $error;
 511
 512         # or if we're not incrementing the bill date.
 513         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 514
 515         # or if we're letting it run only once
 516         last if $options{cancel};
 517
 518         $next_bill = $cust_pkg->getfield('bill') || 0;
 519
 520         #stop if -o was passed to freeside-daily
 521         last if $options{'one_recur'};
 522       }
 523       if ($error) {
 524         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 525         return $error;
 526       }
 527
 528     } #foreach my $part_pkg
 529
 530   } #foreach my $cust_pkg
 531
 532   #if the customer isn't on an automatic payby, everything can go on a single
 533   #invoice anyway?
 534   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 535     #merge everything into one list
 536   #}
 537
 538   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 539
 540     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 541
 542     warn "$me billing pass $pass\n"
 543            #.Dumper(\@cust_bill_pkg)."\n"
 544       if $DEBUG > 2;
 545
 546     ###
 547     # process fees
 548     ###
 549
 550     my @pending_event_fees = FS::cust_event_fee->by_cust($self->custnum,
 551       hashref => { 'billpkgnum' => '' }
 552     );
 553     warn "$me found pending fee events:\n".Dumper(\@pending_event_fees)."\n"
 554       if @pending_event_fees and $DEBUG > 1;
 555
 556     # determine whether to generate an invoice
 557     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 558
 559     foreach my $event_fee (@pending_event_fees) {
 560       $generate_bill = 1 unless $event_fee->nextbill;
 561     }
 562
 563     # don't create an invoice with no line items, or where the only line
 564     # items are fees that are supposed to be held until the next invoice
 565     next if !$generate_bill;
 566
 567     # calculate fees...
 568     my @fee_items;
 569     foreach my $event_fee (@pending_event_fees) {
 570       my $object = $event_fee->cust_event->cust_X;
 571       my $part_fee = $event_fee->part_fee;
 572       my $cust_bill;
 573       if ( $object->isa('FS::cust_main')
 574            or $object->isa('FS::cust_pkg')
 575            or $object->isa('FS::cust_pay_batch') )
 576       {
 577         # Not the real cust_bill object that will be inserted--in particular
 578         # there are no taxes yet.  If you want to charge a fee on the total
 579         # invoice amount including taxes, you have to put the fee on the next
 580         # invoice.
 581         $cust_bill = FS::cust_bill->new({
 582             'custnum'       => $self->custnum,
 583             'cust_bill_pkg' => \@cust_bill_pkg,
 584             'charged'       => ${ $total_setup{$pass} } +
 585                                ${ $total_recur{$pass} },
 586         });
 587
 588         # If this is a package event, only apply the fee to line items
 589         # from that package.
 590         if ($object->isa('FS::cust_pkg')) {
 591           $cust_bill->set('cust_bill_pkg',
 592             [ grep  { $_->pkgnum == $object->pkgnum } @cust_bill_pkg ]
 593           );
 594         }
 595
 596       } elsif ( $object->isa('FS::cust_bill') ) {
 597         # simple case: applying the fee to a previous invoice (late fee,
 598         # etc.)
 599         $cust_bill = $object;
 600       }
 601       # if the fee def belongs to a different agent, don't charge the fee.
 602       # event conditions should prevent this, but just in case they don't,
 603       # skip the fee.
 604       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 605         warn "tried to charge fee#".$part_fee->feepart .
 606              " on customer#".$self->custnum." from a different agent.\n";
 607         next;
 608       }
 609       # also skip if it's disabled
 610       next if $part_fee->disabled eq 'Y';
 611       # calculate the fee
 612       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 613       # link this so that we can clear the marker on inserting the line item
 614       $fee_item->set('cust_event_fee', $event_fee);
 615       push @fee_items, $fee_item;
 616
 617     }
 618
 619     # add fees to the invoice
 620     foreach my $fee_item (@fee_items) {
 621
 622       push @cust_bill_pkg, $fee_item;
 623       ${ $total_setup{$pass} } += $fee_item->setup;
 624       ${ $total_recur{$pass} } += $fee_item->recur;
 625
 626       my $part_fee = $fee_item->part_fee;
 627       my $fee_location = $self->ship_location; # I think?
 628
 629       my $error = $self->_handle_taxes(
 630         $taxlisthash{$pass},
 631         $fee_item,
 632         location => $fee_location
 633       );
 634       return $error if $error;
 635
 636     }
 637
 638     # XXX implementation of fees is supposed to make this go away...
 639     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 640            !$conf->exists('postal_invoice-recurring_only')
 641        )
 642     {
 643
 644       my $postal_pkg = $self->charge_postal_fee();
 645       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 646
 647         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 648         return "can't charge postal invoice fee for customer ".
 649           $self->custnum. ": $postal_pkg";
 650
 651       } elsif ( $postal_pkg ) {
 652
 653         my $real_pkgpart = $postal_pkg->pkgpart;
 654         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 655         # suffer from performance issues
 656         $options{has_hidden} = 0;
 657         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 658         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 659
 660         foreach my $part_pkg ( @part_pkg ) {
 661           my %postal_options = %options;
 662           delete $postal_options{cancel};
 663           my $error =
 664             $self->_make_lines( 'part_pkg'            => $part_pkg,
 665                                 'cust_pkg'            => $postal_pkg,
 666                                 'precommit_hooks'     => \@precommit_hooks,
 667                                 'line_items'          => \@cust_bill_pkg,
 668                                 'setup'               => $total_setup{$pass},
 669                                 'recur'               => $total_recur{$pass},
 670                                 'tax_matrix'          => $taxlisthash{$pass},
 671                                 'time'                => $time,
 672                                 'real_pkgpart'        => $real_pkgpart,
 673                                 'options'             => \%postal_options,
 674                               );
 675           if ($error) {
 676             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 677             return $error;
 678           }
 679         }
 680
 681         # it's silly to have a zero value postal_pkg, but....
 682         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 683
 684       }
 685
 686     }
 687
 688     my $listref_or_error =
 689       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 690
 691     unless ( ref( $listref_or_error ) ) {
 692       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 693       return $listref_or_error;
 694     }
 695
 696     foreach my $taxline ( @$listref_or_error ) {
 697       ${ $total_setup{$pass} } =
 698         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 699       push @cust_bill_pkg, $taxline;
 700     }
 701
 702     #add tax adjustments
 703     warn "adding tax adjustments...\n" if $DEBUG > 2;
 704     foreach my $cust_tax_adjustment (
 705       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 706                                        'billpkgnum' => '',
 707                                      }
 708              )
 709     ) {
 710
 711       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 712
 713       my $itemdesc = $cust_tax_adjustment->taxname;
 714       $itemdesc = '' if $itemdesc eq 'Tax';
 715
 716       push @cust_bill_pkg, new FS::cust_bill_pkg {
 717         'pkgnum'      => 0,
 718         'setup'       => $tax,
 719         'recur'       => 0,
 720         'sdate'       => '',
 721         'edate'       => '',
 722         'itemdesc'    => $itemdesc,
 723         'itemcomment' => $cust_tax_adjustment->comment,
 724         'cust_tax_adjustment' => $cust_tax_adjustment,
 725         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 726       };
 727
 728     }
 729
 730     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 731
 732     my @cust_bill = $self->cust_bill;
 733     my $balance = $self->balance;
 734     my $previous_bill = $cust_bill[-1] if @cust_bill;
 735     my $previous_balance = 0;
 736     if ( $previous_bill ) {
 737       $previous_balance = $previous_bill->billing_balance
 738                         + $previous_bill->charged;
 739     }
 740
 741     warn "creating the new invoice\n" if $DEBUG;
 742     #create the new invoice
 743     my $cust_bill = new FS::cust_bill ( {
 744       'custnum'             => $self->custnum,
 745       '_date'               => $invoice_time,
 746       'charged'             => $charged,
 747       'billing_balance'     => $balance,
 748       'previous_balance'    => $previous_balance,
 749       'invoice_terms'       => $options{'invoice_terms'},
 750       'cust_bill_pkg'       => \@cust_bill_pkg,
 751     } );
 752     $error = $cust_bill->insert unless $options{no_commit};
 753     if ( $error ) {
 754       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 755       return "can't create invoice for customer #". $self->custnum. ": $error";
 756     }
 757     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 758
 759   } #foreach my $pass ( keys %cust_bill_pkg )
 760
 761   foreach my $hook ( @precommit_hooks ) {
 762     eval {
 763       &{$hook}; #($self) ?
 764     } unless $options{no_commit};
 765     if ( $@ ) {
 766       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 767       return "$@ running precommit hook $hook\n";
 768     }
 769   }
 770
 771   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 772
 773   ''; #no error
 774 }
 775
 776 #discard bundled packages of 0 value
 777 sub _omit_zero_value_bundles {
 778   my @in = @_;
 779
 780   my @cust_bill_pkg = ();
 781   my @cust_bill_pkg_bundle = ();
 782   my $sum = 0;
 783   my $discount_show_always = 0;
 784
 785   foreach my $cust_bill_pkg ( @in ) {
 786
 787     $discount_show_always = ($cust_bill_pkg->get('discounts')
 788                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 789                                 && $conf->exists('discount-show-always'));
 790
 791     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 792          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 793          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 794       if $DEBUG > 0;
 795
 796     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 797       push @cust_bill_pkg, @cust_bill_pkg_bundle
 798         if $sum > 0
 799         || ($sum == 0 && (    $discount_show_always
 800                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 801                                    @cust_bill_pkg_bundle
 802                          )
 803            );
 804       @cust_bill_pkg_bundle = ();
 805       $sum = 0;
 806     }
 807
 808     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 809     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 810
 811   }
 812
 813   push @cust_bill_pkg, @cust_bill_pkg_bundle
 814     if $sum > 0
 815     || ($sum == 0 && (    $discount_show_always
 816                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 817                                @cust_bill_pkg_bundle
 818                      )
 819        );
 820
 821   warn "  _omit_zero_value_bundles: ". scalar(@in).
 822        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 823     if $DEBUG > 2;
 824
 825   (@cust_bill_pkg);
 826
 827 }
 828
 829 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 830
 831 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 832 Usually used internally by bill method B<bill>.
 833
 834 If there is an error, returns the error, otherwise returns reference to a
 835 list of line items suitable for insertion.
 836
 837 =over 4
 838
 839 =item LINEITEMREF
 840
 841 An array ref of the line items being billed.
 842
 843 =item TAXHASHREF
 844
 845 A strange beast.  The keys to this hash are internal identifiers consisting
 846 of the name of the tax object type, a space, and its unique identifier ( e.g.
 847  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 848 item in the list is the tax object.  The remaining items are either line
 849 items or floating point values (currency amounts).
 850
 851 The taxes are calculated on this entity.  Calculated exemption records are
 852 transferred to the LINEITEMREF items on the assumption that they are related.
 853
 854 Read the source.
 855
 856 =item INVOICE_TIME
 857
 858 This specifies the date appearing on the associated invoice.  Some
 859 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 860
 861 =back
 862
 863 =cut
 864
 865 sub calculate_taxes {
 866   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 867
 868   # $taxlisthash is a hashref
 869   # keys are identifiers, values are arrayrefs
 870   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 871   # then any cust_bill_pkg objects the tax applies to
 872
 873   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 874
 875   warn "$me calculate_taxes\n"
 876        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 877     if $DEBUG > 2;
 878
 879   my @tax_line_items = ();
 880
 881   # keys are tax names (as printed on invoices / itemdesc )
 882   # values are arrayrefs of taxlisthash keys (internal identifiers)
 883   my %taxname = ();
 884
 885   # keys are taxlisthash keys (internal identifiers)
 886   # values are (cumulative) amounts
 887   my %tax_amount = ();
 888
 889   # keys are taxlisthash keys (internal identifiers)
 890   # values are arrayrefs of cust_bill_pkg_tax_location hashrefs
 891   my %tax_location = ();
 892
 893   # keys are taxlisthash keys (internal identifiers)
 894   # values are arrayrefs of cust_bill_pkg_tax_rate_location hashrefs
 895   my %tax_rate_location = ();
 896
 897   # keys are taxlisthash keys (internal identifiers!)
 898   # values are arrayrefs of cust_tax_exempt_pkg objects
 899   my %tax_exemption;
 900
 901   foreach my $tax ( keys %$taxlisthash ) {
 902     # $tax is a tax identifier (intersection of a tax definition record
 903     # and a cust_bill_pkg record)
 904     my $tax_object = shift @{ $taxlisthash->{$tax} };
 905     # $tax_object is a cust_main_county or tax_rate
 906     # (with billpkgnum, pkgnum, locationnum set)
 907     # the rest of @{ $taxlisthash->{$tax} } is cust_bill_pkg component objects
 908     # (setup, recurring, usage classes)
 909     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 910     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 911     # taxline calculates the tax on all cust_bill_pkgs in the
 912     # first (arrayref) argument, and returns a hashref of 'name'
 913     # (the line item description) and 'amount'.
 914     # It also calculates exemptions and attaches them to the cust_bill_pkgs
 915     # in the argument.
 916     my $taxables = $taxlisthash->{$tax};
 917     my $exemptions = $tax_exemption{$tax} ||= [];
 918     my $taxline = $tax_object->taxline(
 919                             $taxables,
 920                             'custnum'      => $self->custnum,
 921                             'invoice_time' => $invoice_time,
 922                             'exemptions'   => $exemptions,
 923                           );
 924     return $taxline unless ref($taxline);
 925
 926     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 927
 928     if ( $tax_object->isa('FS::cust_main_county') ) {
 929       # then $taxline is a real line item
 930       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 931
 932     } else {
 933       # leave this as is for now
 934
 935       my $name   = $taxline->{'name'};
 936       my $amount = $taxline->{'amount'};
 937
 938       #warn "adding $amount as $name\n";
 939       $taxname{ $name } ||= [];
 940       push @{ $taxname{ $name } }, $tax;
 941
 942       $tax_amount{ $tax } += $amount;
 943
 944       # link records between cust_main_county/tax_rate and cust_location
 945       $tax_rate_location{ $tax } ||= [];
 946       my $taxratelocationnum =
 947         $tax_object->tax_rate_location->taxratelocationnum;
 948       push @{ $tax_rate_location{ $tax }  },
 949         {
 950           'taxnum'             => $tax_object->taxnum,
 951           'taxtype'            => ref($tax_object),
 952           'amount'             => sprintf('%.2f', $amount ),
 953           'locationtaxid'      => $tax_object->location,
 954           'taxratelocationnum' => $taxratelocationnum,
 955         };
 956     } #if ref($tax_object)...
 957   } #foreach keys %$taxlisthash
 958
 959   #consolidate and create tax line items
 960   warn "consolidating and generating...\n" if $DEBUG > 2;
 961   foreach my $taxname ( keys %taxname ) {
 962     my @cust_bill_pkg_tax_location;
 963     my @cust_bill_pkg_tax_rate_location;
 964     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
 965         'pkgnum'    => 0,
 966         'recur'     => 0,
 967         'sdate'     => '',
 968         'edate'     => '',
 969         'itemdesc'  => $taxname,
 970         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
 971         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 972     });
 973
 974     my $tax_total = 0;
 975     my %seen = ();
 976     warn "adding $taxname\n" if $DEBUG > 1;
 977     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 978       if ( ref($taxitem) eq 'FS::cust_bill_pkg' ) {
 979         # then we need to transfer the amount and the links from the
 980         # line item to the new one we're creating.
 981         $tax_total += $taxitem->setup;
 982         foreach my $link ( @{ $taxitem->get('cust_bill_pkg_tax_location') } ) {
 983           $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
 984           push @cust_bill_pkg_tax_location, $link;
 985         }
 986       } else {
 987         # the tax_rate way
 988         next if $seen{$taxitem}++;
 989         warn "adding $tax_amount{$taxitem}\n" if $DEBUG > 1;
 990         $tax_total += $tax_amount{$taxitem};
 991         push @cust_bill_pkg_tax_rate_location,
 992           map { new FS::cust_bill_pkg_tax_rate_location $_ }
 993               @{ $tax_rate_location{ $taxitem } };
 994       }
 995     }
 996     next unless $tax_total;
 997
 998     # we should really neverround this up...I guess it's okay if taxline
 999     # already returns amounts with 2 decimal places
1000     $tax_total = sprintf('%.2f', $tax_total );
1001     $tax_cust_bill_pkg->set('setup', $tax_total);
1002
1003     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1004                                                    'disabled'     => '',
1005                                                  },
1006                                );
1007
1008     my @display = ();
1009     if ( $pkg_category and
1010          $conf->config('invoice_latexsummary') ||
1011          $conf->config('invoice_htmlsummary')
1012        )
1013     {
1014
1015       my %hash = (  'section' => $pkg_category->categoryname );
1016       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1017
1018     }
1019     $tax_cust_bill_pkg->set('display', \@display);
1020
1021     push @tax_line_items, $tax_cust_bill_pkg;
1022   }
1023
1024   \@tax_line_items;
1025 }
1026
1027 sub _make_lines {
1028   my ($self, %params) = @_;
1029
1030   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1031
1032   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1033   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1034   my $cust_location = $cust_pkg->tax_location;
1035   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1036   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1037   my $total_setup = $params{setup} or die "no setup accumulator specified";
1038   my $total_recur = $params{recur} or die "no recur accumulator specified";
1039   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1040   my $time = $params{'time'} or die "no time specified";
1041   my (%options) = %{$params{options}};
1042
1043   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1044     # this should never happen
1045     die 'freq_override billing attempted on non-monthly package '.
1046       $cust_pkg->pkgnum;
1047   }
1048
1049   my $dbh = dbh;
1050   my $real_pkgpart = $params{real_pkgpart};
1051   my %hash = $cust_pkg->hash;
1052   my $old_cust_pkg = new FS::cust_pkg \%hash;
1053
1054   my @details = ();
1055   my $lineitems = 0;
1056
1057   $cust_pkg->pkgpart($part_pkg->pkgpart);
1058
1059   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1060                      ? day_end( $time )
1061                      : $time
1062                  );
1063
1064   ###
1065   # bill setup
1066   ###
1067
1068   my $setup = 0;
1069   my $unitsetup = 0;
1070   my @setup_discounts = ();
1071   my %setup_param = ( 'discounts' => \@setup_discounts );
1072   my $setup_billed_currency = '';
1073   my $setup_billed_amount = 0;
1074   if (     ! $options{recurring_only}
1075        and ! $options{cancel}
1076        and ( $options{'resetup'}
1077              || ( ! $cust_pkg->setup
1078                   && ( ! $cust_pkg->start_date
1079                        || $cust_pkg->start_date <= $cmp_time
1080                      )
1081                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
1082                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
1083                             ! $cust_pkg->getfield('susp')
1084                           )
1085                      )
1086                 )
1087            )
1088      )
1089   {
1090
1091     warn "    bill setup\n" if $DEBUG > 1;
1092
1093     unless ( $cust_pkg->waive_setup ) {
1094         $lineitems++;
1095
1096         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1097         return "$@ running calc_setup for $cust_pkg\n"
1098           if $@;
1099
1100         $unitsetup = $cust_pkg->base_setup()
1101                        || $setup; #XXX uuh
1102
1103         if ( $setup_param{'billed_currency'} ) {
1104           $setup_billed_currency = delete $setup_param{'billed_currency'};
1105           $setup_billed_amount   = delete $setup_param{'billed_amount'};
1106         }
1107     }
1108
1109     $cust_pkg->setfield('setup', $time)
1110       unless $cust_pkg->setup;
1111           #do need it, but it won't get written to the db
1112           #|| $cust_pkg->pkgpart != $real_pkgpart;
1113
1114     $cust_pkg->setfield('start_date', '')
1115       if $cust_pkg->start_date;
1116
1117   }
1118
1119   ###
1120   # bill recurring fee
1121   ###
1122
1123   my $recur = 0;
1124   my $unitrecur = 0;
1125   my @recur_discounts = ();
1126   my $recur_billed_currency = '';
1127   my $recur_billed_amount = 0;
1128   my $sdate;
1129   if (     ! $cust_pkg->start_date
1130        and
1131            ( ! $cust_pkg->susp
1132                || ( $cust_pkg->susp != $cust_pkg->order_date
1133                       && (    $cust_pkg->option('suspend_bill',1)
1134                            || ( $part_pkg->option('suspend_bill', 1)
1135                                  && ! $cust_pkg->option('no_suspend_bill',1)
1136                               )
1137                          )
1138                   )
1139            )
1140        and
1141             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1142          || ( $part_pkg->plan eq 'voip_cdr'
1143                && $part_pkg->option('bill_every_call')
1144             )
1145          || $options{cancel}
1146   ) {
1147
1148     # XXX should this be a package event?  probably.  events are called
1149     # at collection time at the moment, though...
1150     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1151       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1152       #don't want to reset usage just cause we want a line item??
1153       #&& $part_pkg->pkgpart == $real_pkgpart;
1154
1155     warn "    bill recur\n" if $DEBUG > 1;
1156     $lineitems++;
1157
1158     # XXX shared with $recur_prog
1159     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1160              || $cust_pkg->setup
1161              || $time;
1162
1163     #over two params!  lets at least switch to a hashref for the rest...
1164     my $increment_next_bill = ( $part_pkg->freq ne '0'
1165                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1166                                 && !$options{cancel}
1167                               );
1168     my %param = ( %setup_param,
1169                   'precommit_hooks'     => $precommit_hooks,
1170                   'increment_next_bill' => $increment_next_bill,
1171                   'discounts'           => \@recur_discounts,
1172                   'real_pkgpart'        => $real_pkgpart,
1173                   'freq_override'       => $options{freq_override} || '',
1174                   'setup_fee'           => 0,
1175                 );
1176
1177     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1178
1179     # There may be some part_pkg for which this is wrong.  Only those
1180     # which can_discount are supported.
1181     # (the UI should prevent adding discounts to these at the moment)
1182
1183     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1184          " for pkgpart ". $cust_pkg->pkgpart.
1185          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1186       if $DEBUG > 2;
1187
1188     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1189     return "$@ running $method for $cust_pkg\n"
1190       if ( $@ );
1191
1192     #base_cancel???
1193     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1194
1195     if ( $param{'billed_currency'} ) {
1196       $recur_billed_currency = delete $param{'billed_currency'};
1197       $recur_billed_amount   = delete $param{'billed_amount'};
1198     }
1199
1200     if ( $increment_next_bill ) {
1201
1202       my $next_bill;
1203
1204       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1205         # supplemental package
1206         # to keep in sync with the main package, simulate billing at
1207         # its frequency
1208         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1209         my $supp_pkg_freq = $part_pkg->freq;
1210         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1211         if ( $ratio != int($ratio) ) {
1212           # the UI should prevent setting up packages like this, but just
1213           # in case
1214           return "supplemental package period is not an integer multiple of main  package period";
1215         }
1216         $next_bill = $sdate;
1217         for (1..$ratio) {
1218           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1219         }
1220
1221       } else {
1222         # the normal case
1223       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1224       return "unparsable frequency: ". $part_pkg->freq
1225         if $next_bill == -1;
1226       }
1227
1228       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1229       # only for figuring next bill date, nothing else, so, reset $sdate again
1230       # here
1231       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1232       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1233       $cust_pkg->last_bill($sdate);
1234
1235       $cust_pkg->setfield('bill', $next_bill );
1236
1237     }
1238
1239     if ( $param{'setup_fee'} ) {
1240       # Add an additional setup fee at the billing stage.
1241       # Used for prorate_defer_bill.
1242       $setup += $param{'setup_fee'};
1243       $unitsetup += $param{'setup_fee'};
1244       $lineitems++;
1245     }
1246
1247     if ( defined $param{'discount_left_setup'} ) {
1248         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1249             $setup -= $discount_setup;
1250         }
1251     }
1252
1253   }
1254
1255   warn "\$setup is undefined" unless defined($setup);
1256   warn "\$recur is undefined" unless defined($recur);
1257   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1258
1259   ###
1260   # If there's line items, create em cust_bill_pkg records
1261   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1262   ###
1263
1264   if ( $lineitems ) {
1265
1266     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1267       # hmm.. and if just the options are modified in some weird price plan?
1268
1269       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1270         if $DEBUG >1;
1271
1272       my $error = $cust_pkg->replace( $old_cust_pkg,
1273                                       'depend_jobnum'=>$options{depend_jobnum},
1274                                       'options' => { $cust_pkg->options },
1275                                     )
1276         unless $options{no_commit};
1277       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1278         if $error; #just in case
1279     }
1280
1281     $setup = sprintf( "%.2f", $setup );
1282     $recur = sprintf( "%.2f", $recur );
1283     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1284       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1285     }
1286     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1287       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1288     }
1289
1290     my $discount_show_always = $conf->exists('discount-show-always')
1291                                && (    ($setup == 0 && scalar(@setup_discounts))
1292                                     || ($recur == 0 && scalar(@recur_discounts))
1293                                   );
1294
1295     if (    $setup != 0
1296          || $recur != 0
1297          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1298          || $discount_show_always
1299          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1300          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1301        )
1302     {
1303
1304       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1305         if $DEBUG > 1;
1306
1307       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1308       if ( $DEBUG > 1 ) {
1309         warn "      adding customer package invoice detail: $_\n"
1310           foreach @cust_pkg_detail;
1311       }
1312       push @details, @cust_pkg_detail;
1313
1314       my $cust_bill_pkg = new FS::cust_bill_pkg {
1315         'pkgnum'                => $cust_pkg->pkgnum,
1316         'setup'                 => $setup,
1317         'unitsetup'             => $unitsetup,
1318         'setup_billed_currency' => $setup_billed_currency,
1319         'setup_billed_amount'   => $setup_billed_amount,
1320         'recur'                 => $recur,
1321         'unitrecur'             => $unitrecur,
1322         'recur_billed_currency' => $recur_billed_currency,
1323         'recur_billed_amount'   => $recur_billed_amount,
1324         'quantity'              => $cust_pkg->quantity,
1325         'details'               => \@details,
1326         'discounts'             => [ @setup_discounts, @recur_discounts ],
1327         'hidden'                => $part_pkg->hidden,
1328         'freq'                  => $part_pkg->freq,
1329       };
1330
1331       if ( $part_pkg->option('prorate_defer_bill',1)
1332            and !$hash{last_bill} ) {
1333         # both preceding and upcoming, technically
1334         $cust_bill_pkg->sdate( $cust_pkg->setup );
1335         $cust_bill_pkg->edate( $cust_pkg->bill );
1336       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1337         $cust_bill_pkg->sdate( $hash{last_bill} );
1338         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1339         $cust_bill_pkg->edate( $time ) if $options{cancel};
1340       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' )
1341         $cust_bill_pkg->sdate( $sdate );
1342         $cust_bill_pkg->edate( $cust_pkg->bill );
1343         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1344       }
1345
1346       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1347         unless $part_pkg->pkgpart == $real_pkgpart;
1348
1349       $$total_setup += $setup;
1350       $$total_recur += $recur;
1351
1352       ###
1353       # handle taxes
1354       ###
1355
1356       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg );
1357       return $error if $error;
1358
1359       $cust_bill_pkg->set_display(
1360         part_pkg     => $part_pkg,
1361         real_pkgpart => $real_pkgpart,
1362       );
1363
1364       push @$cust_bill_pkgs, $cust_bill_pkg;
1365
1366     } #if $setup != 0 || $recur != 0
1367
1368   } #if $line_items
1369
1370   '';
1371
1372 }
1373
1374 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1375
1376 Takes one argument, a cust_pkg object that is being billed.  This will
1377 be called only if the package was created by a package change, and has
1378 not been billed since the package change, and package balance tracking
1379 is enabled.  The second argument can be an alternate package number to
1380 transfer the balance from; this should not be used externally.
1381
1382 Transfers the balance from the previous package (now canceled) to
1383 this package, by crediting one package and creating an invoice item for
1384 the other.  Inserts the credit and returns the invoice item (so that it
1385 can be added to an invoice that's being built).
1386
1387 If the previous package was never billed, and was also created by a package
1388 change, then this will also transfer the balance from I<its> previous
1389 package, and so on, until reaching a package that either has been billed
1390 or was not created by a package change.
1391
1392 =cut
1393
1394 my $balance_transfer_reason;
1395
1396 sub _transfer_balance {
1397   my $self = shift;
1398   my $cust_pkg = shift;
1399   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1400   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1401
1402   my @transfers;
1403
1404   # if $from_pkg is not the first package in the chain, and it was never
1405   # billed, walk back
1406   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1407     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1408   }
1409
1410   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1411   if ( $prev_balance != 0 ) {
1412     $balance_transfer_reason ||= FS::reason->new_or_existing(
1413       'reason' => 'Package balance transfer',
1414       'type'   => 'Internal adjustment',
1415       'class'  => 'R'
1416     );
1417
1418     my $credit = FS::cust_credit->new({
1419         'custnum'   => $self->custnum,
1420         'amount'    => abs($prev_balance),
1421         'reasonnum' => $balance_transfer_reason->reasonnum,
1422         '_date'     => $cust_pkg->change_date,
1423     });
1424
1425     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1426         'setup'     => 0,
1427         'recur'     => abs($prev_balance),
1428         #'sdate'     => $from_pkg->last_bill, # not sure about this
1429         #'edate'     => $cust_pkg->change_date,
1430         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1431                                  $from_pkg->part_pkg->pkg),
1432     });
1433
1434     if ( $prev_balance > 0 ) {
1435       # credit the old package, charge the new one
1436       $credit->set('pkgnum', $from_pkgnum);
1437       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1438     } else {
1439       # the reverse
1440       $credit->set('pkgnum', $cust_pkg->pkgnum);
1441       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1442     }
1443     my $error = $credit->insert;
1444     die "error transferring package balance from #".$from_pkgnum.
1445         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1446
1447     push @transfers, $cust_bill_pkg;
1448   } # $prev_balance != 0
1449
1450   return @transfers;
1451 }
1452
1453 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1454
1455 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1456 from _make_lines.
1457
1458 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1459 this:
1460 {
1461   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1462   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1463 }
1464
1465 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1466 is always the cust_main_county or tax_rate identified by the key.
1467
1468 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1469 the 'taxline' method to calculate the amount of the tax.  This doesn't
1470 happen until calculate_taxes, though.
1471
1472 OPTIONS may include:
1473 - part_item: a part_pkg or part_fee object to be used as the package/fee
1474   definition.
1475 - location: a cust_location to be used as the billing location.
1476
1477 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1478 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1479 the customer's default service location).
1480
1481 =cut
1482
1483 sub _handle_taxes {
1484   my $self = shift;
1485   my $taxlisthash = shift;
1486   my $cust_bill_pkg = shift;
1487   my %options = @_;
1488
1489   # at this point I realize that we have enough information to infer all this
1490   # stuff, instead of passing around giant honking argument lists
1491   my $location = $options{location} || $cust_bill_pkg->tax_location;
1492   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1493
1494   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1495
1496   return if ( $self->payby eq 'COMP' ); #dubious
1497
1498   if ( $conf->exists('enable_taxproducts')
1499        && ( scalar($part_item->part_pkg_taxoverride)
1500             || $part_item->has_taxproduct
1501           )
1502      )
1503     {
1504
1505     # EXTERNAL TAX RATES (via tax_rate)
1506     my %cust_bill_pkg = ();
1507     my %taxes = ();
1508
1509     my @classes;
1510     #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1511     push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1512     push @classes, 'setup' if $cust_bill_pkg->setup;
1513     push @classes, 'recur' if $cust_bill_pkg->recur;
1514
1515     my $exempt = $conf->exists('cust_class-tax_exempt')
1516                    ? ( $self->cust_class ? $self->cust_class->tax : '' )
1517                    : $self->tax;
1518     # standardize this just to be sure
1519     $exempt = ($exempt eq 'Y') ? 'Y' : '';
1520
1521     if ( !$exempt ) {
1522
1523       foreach my $class (@classes) {
1524         my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1525         return $err_or_ref unless ref($err_or_ref);
1526         $taxes{$class} = $err_or_ref;
1527       }
1528
1529       unless (exists $taxes{''}) {
1530         my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1531         return $err_or_ref unless ref($err_or_ref);
1532         $taxes{''} = $err_or_ref;
1533       }
1534
1535     }
1536
1537     my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate; # grrr
1538     foreach my $key (keys %tax_cust_bill_pkg) {
1539       # $key is "setup", "recur", or a usage class name. ('' is a usage class.)
1540       # $tax_cust_bill_pkg{$key} is a cust_bill_pkg for that component of
1541       # the line item.
1542       # $taxes{$key} is an arrayref of cust_main_county or tax_rate objects that
1543       # apply to $key-class charges.
1544       my @taxes = @{ $taxes{$key} || [] };
1545       my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1546
1547       my %localtaxlisthash = ();
1548       foreach my $tax ( @taxes ) {
1549
1550         # this is the tax identifier, not the taxname
1551         my $taxname = ref( $tax ). ' '. $tax->taxnum;
1552         # $taxlisthash: keys are "setup", "recur", and usage classes.
1553         # Values are arrayrefs, first the tax object (cust_main_county
1554         # or tax_rate) and then any cust_bill_pkg objects that the
1555         # tax applies to.
1556         $taxlisthash->{ $taxname } ||= [ $tax ];
1557         push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1558
1559         $localtaxlisthash{ $taxname } ||= [ $tax ];
1560         push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1561
1562       }
1563
1564       warn "finding taxed taxes...\n" if $DEBUG > 2;
1565       foreach my $tax ( keys %localtaxlisthash ) {
1566         my $tax_object = shift @{ $localtaxlisthash{$tax} };
1567         warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1568           if $DEBUG > 2;
1569         next unless $tax_object->can('tax_on_tax');
1570
1571         foreach my $tot ( $tax_object->tax_on_tax( $location ) ) {
1572           my $totname = ref( $tot ). ' '. $tot->taxnum;
1573
1574           warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1575             if $DEBUG > 2;
1576           next unless exists( $localtaxlisthash{ $totname } ); # only increase
1577                                                                # existing taxes
1578           warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1579           # calculate the tax amount that the tax_on_tax will apply to
1580           my $hashref_or_error =
1581             $tax_object->taxline( $localtaxlisthash{$tax} );
1582           return $hashref_or_error
1583             unless ref($hashref_or_error);
1584
1585           # and append it to the list of taxable items
1586           $taxlisthash->{ $totname } ||= [ $tot ];
1587           push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1588
1589         }
1590       }
1591     }
1592
1593   } else {
1594
1595     # INTERNAL TAX RATES (cust_main_county)
1596
1597     # We fetch taxes even if the customer is completely exempt,
1598     # because we need to record that fact.
1599
1600     my @loc_keys = qw( district city county state country );
1601     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1602
1603     $taxhash{'taxclass'} = $part_item->taxclass;
1604
1605     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1606
1607     my @taxes = (); # entries are cust_main_county objects
1608     my %taxhash_elim = %taxhash;
1609     my @elim = qw( district city county state );
1610     do {
1611
1612       #first try a match with taxclass
1613       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1614
1615       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1616         #then try a match without taxclass
1617         my %no_taxclass = %taxhash_elim;
1618         $no_taxclass{ 'taxclass' } = '';
1619         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1620       }
1621
1622       $taxhash_elim{ shift(@elim) } = '';
1623
1624     } while ( !scalar(@taxes) && scalar(@elim) );
1625
1626     foreach (@taxes) {
1627       my $tax_id = 'cust_main_county '.$_->taxnum;
1628       $taxlisthash->{$tax_id} ||= [ $_ ];
1629       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1630     }
1631
1632   }
1633   '';
1634 }
1635
1636 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1637
1638 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1639 or part_fee (which will define the tax eligibility of the product), CLASS is
1640 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1641 location where the service was provided (or billed, depending on
1642 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1643 can apply to this line item.
1644
1645 =cut
1646
1647 sub _gather_taxes {
1648   my $self = shift;
1649   my $part_item = shift;
1650   my $class = shift;
1651   my $location = shift;
1652
1653   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1654
1655   my $geocode = $location->geocode('cch');
1656
1657   [ $part_item->tax_rates('cch', $geocode, $class) ]
1658
1659 }
1660
1661 =item collect [ HASHREF | OPTION => VALUE ... ]
1662
1663 (Attempt to) collect money for this customer's outstanding invoices (see
1664 L<FS::cust_bill>).  Usually used after the bill method.
1665
1666 Actions are now triggered by billing events; see L<FS::part_event> and the
1667 billing events web interface.  Old-style invoice events (see
1668 L<FS::part_bill_event>) have been deprecated.
1669
1670 If there is an error, returns the error, otherwise returns false.
1671
1672 Options are passed as name-value pairs.
1673
1674 Currently available options are:
1675
1676 =over 4
1677
1678 =item invoice_time
1679
1680 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1681
1682 =item retry
1683
1684 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1685
1686 =item check_freq
1687
1688 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1689
1690 =item quiet
1691
1692 set true to surpress email card/ACH decline notices.
1693
1694 =item debug
1695
1696 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1697
1698 =back
1699
1700 # =item payby
1701 #
1702 # allows for one time override of normal customer billing method
1703
1704 =cut
1705
1706 sub collect {
1707   my( $self, %options ) = @_;
1708
1709   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1710
1711   my $invoice_time = $options{'invoice_time'} || time;
1712
1713   #put below somehow?
1714   local $SIG{HUP} = 'IGNORE';
1715   local $SIG{INT} = 'IGNORE';
1716   local $SIG{QUIT} = 'IGNORE';
1717   local $SIG{TERM} = 'IGNORE';
1718   local $SIG{TSTP} = 'IGNORE';
1719   local $SIG{PIPE} = 'IGNORE';
1720
1721   my $oldAutoCommit = $FS::UID::AutoCommit;
1722   local $FS::UID::AutoCommit = 0;
1723   my $dbh = dbh;
1724
1725   $self->select_for_update; #mutex
1726
1727   if ( $DEBUG ) {
1728     my $balance = $self->balance;
1729     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1730   }
1731
1732   if ( exists($options{'retry_card'}) ) {
1733     carp 'retry_card option passed to collect is deprecated; use retry';
1734     $options{'retry'} ||= $options{'retry_card'};
1735   }
1736   if ( exists($options{'retry'}) && $options{'retry'} ) {
1737     my $error = $self->retry_realtime;
1738     if ( $error ) {
1739       $dbh->rollback if $oldAutoCommit;
1740       return $error;
1741     }
1742   }
1743
1744   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1745
1746   #never want to roll back an event just because it returned an error
1747   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1748
1749   $self->do_cust_event(
1750     'debug'      => ( $options{'debug'} || 0 ),
1751     'time'       => $invoice_time,
1752     'check_freq' => $options{'check_freq'},
1753     'stage'      => 'collect',
1754   );
1755
1756 }
1757
1758 =item retry_realtime
1759
1760 Schedules realtime / batch  credit card / electronic check / LEC billing
1761 events for for retry.  Useful if card information has changed or manual
1762 retry is desired.  The 'collect' method must be called to actually retry
1763 the transaction.
1764
1765 Implementation details: For either this customer, or for each of this
1766 customer's open invoices, changes the status of the first "done" (with
1767 statustext error) realtime processing event to "failed".
1768
1769 =cut
1770
1771 sub retry_realtime {
1772   my $self = shift;
1773
1774   local $SIG{HUP} = 'IGNORE';
1775   local $SIG{INT} = 'IGNORE';
1776   local $SIG{QUIT} = 'IGNORE';
1777   local $SIG{TERM} = 'IGNORE';
1778   local $SIG{TSTP} = 'IGNORE';
1779   local $SIG{PIPE} = 'IGNORE';
1780
1781   my $oldAutoCommit = $FS::UID::AutoCommit;
1782   local $FS::UID::AutoCommit = 0;
1783   my $dbh = dbh;
1784
1785   #a little false laziness w/due_cust_event (not too bad, really)
1786
1787   my $join = FS::part_event_condition->join_conditions_sql;
1788   my $order = FS::part_event_condition->order_conditions_sql;
1789   my $mine =
1790   '( '
1791    . join ( ' OR ' , map {
1792     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1793     my $custnum = FS::part_event->eventtables_custnum->{$_};
1794     "( part_event.eventtable = " . dbh->quote($_)
1795     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1796     . " from $_ $cust_join"
1797     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1798    } FS::part_event->eventtables)
1799    . ') ';
1800
1801   #here is the agent virtualization
1802   my $agent_virt = " (    part_event.agentnum IS NULL
1803                        OR part_event.agentnum = ". $self->agentnum. ' )';
1804
1805   #XXX this shouldn't be hardcoded, actions should declare it...
1806   my @realtime_events = qw(
1807     cust_bill_realtime_card
1808     cust_bill_realtime_check
1809     cust_bill_realtime_lec
1810     cust_bill_batch
1811   );
1812
1813   my $is_realtime_event =
1814     ' part_event.action IN ( '.
1815         join(',', map "'$_'", @realtime_events ).
1816     ' ) ';
1817
1818   my $batch_or_statustext =
1819     "( part_event.action = 'cust_bill_batch'
1820        OR ( statustext IS NOT NULL AND statustext != '' )
1821      )";
1822
1823
1824   my @cust_event = qsearch({
1825     'table'     => 'cust_event',
1826     'select'    => 'cust_event.*',
1827     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1828     'hashref'   => { 'status' => 'done' },
1829     'extra_sql' => " AND $batch_or_statustext ".
1830                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1831   });
1832
1833   my %seen_invnum = ();
1834   foreach my $cust_event (@cust_event) {
1835
1836     #max one for the customer, one for each open invoice
1837     my $cust_X = $cust_event->cust_X;
1838     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1839                           ? $cust_X->invnum
1840                           : 0
1841                         }++
1842          or $cust_event->part_event->eventtable eq 'cust_bill'
1843             && ! $cust_X->owed;
1844
1845     my $error = $cust_event->retry;
1846     if ( $error ) {
1847       $dbh->rollback if $oldAutoCommit;
1848       return "error scheduling event for retry: $error";
1849     }
1850
1851   }
1852
1853   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1854   '';
1855
1856 }
1857
1858 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1859
1860 Runs billing events; see L<FS::part_event> and the billing events web
1861 interface.
1862
1863 If there is an error, returns the error, otherwise returns false.
1864
1865 Options are passed as name-value pairs.
1866
1867 Currently available options are:
1868
1869 =over 4
1870
1871 =item time
1872
1873 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1874
1875 =item check_freq
1876
1877 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1878
1879 =item stage
1880
1881 "collect" (the default) or "pre-bill"
1882
1883 =item quiet
1884
1885 set true to surpress email card/ACH decline notices.
1886
1887 =item debug
1888
1889 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1890
1891 =back
1892 =cut
1893
1894 # =item payby
1895 #
1896 # allows for one time override of normal customer billing method
1897
1898 # =item retry
1899 #
1900 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1901
1902 sub do_cust_event {
1903   my( $self, %options ) = @_;
1904
1905   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1906
1907   my $time = $options{'time'} || time;
1908
1909   #put below somehow?
1910   local $SIG{HUP} = 'IGNORE';
1911   local $SIG{INT} = 'IGNORE';
1912   local $SIG{QUIT} = 'IGNORE';
1913   local $SIG{TERM} = 'IGNORE';
1914   local $SIG{TSTP} = 'IGNORE';
1915   local $SIG{PIPE} = 'IGNORE';
1916
1917   my $oldAutoCommit = $FS::UID::AutoCommit;
1918   local $FS::UID::AutoCommit = 0;
1919   my $dbh = dbh;
1920
1921   $self->select_for_update; #mutex
1922
1923   if ( $DEBUG ) {
1924     my $balance = $self->balance;
1925     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1926   }
1927
1928 #  if ( exists($options{'retry_card'}) ) {
1929 #    carp 'retry_card option passed to collect is deprecated; use retry';
1930 #    $options{'retry'} ||= $options{'retry_card'};
1931 #  }
1932 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1933 #    my $error = $self->retry_realtime;
1934 #    if ( $error ) {
1935 #      $dbh->rollback if $oldAutoCommit;
1936 #      return $error;
1937 #    }
1938 #  }
1939
1940   # false laziness w/pay_batch::import_results
1941
1942   my $due_cust_event = $self->due_cust_event(
1943     'debug'      => ( $options{'debug'} || 0 ),
1944     'time'       => $time,
1945     'check_freq' => $options{'check_freq'},
1946     'stage'      => ( $options{'stage'} || 'collect' ),
1947   );
1948   unless( ref($due_cust_event) ) {
1949     $dbh->rollback if $oldAutoCommit;
1950     return $due_cust_event;
1951   }
1952
1953   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1954   #never want to roll back an event just because it or a different one
1955   # returned an error
1956   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1957
1958   foreach my $cust_event ( @$due_cust_event ) {
1959
1960     #XXX lock event
1961
1962     #re-eval event conditions (a previous event could have changed things)
1963     unless ( $cust_event->test_conditions ) {
1964       #don't leave stray "new/locked" records around
1965       my $error = $cust_event->delete;
1966       return $error if $error;
1967       next;
1968     }
1969
1970     {
1971       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1972         if $options{'quiet'};
1973       warn "  running cust_event ". $cust_event->eventnum. "\n"
1974         if $DEBUG > 1;
1975
1976       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1977       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1978         #XXX wtf is this?  figure out a proper dealio with return value
1979         #from do_event
1980         return $error;
1981       }
1982     }
1983
1984   }
1985
1986   '';
1987
1988 }
1989
1990 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1991
1992 Inserts database records for and returns an ordered listref of new events due
1993 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1994 events are due, an empty listref is returned.  If there is an error, returns a
1995 scalar error message.
1996
1997 To actually run the events, call each event's test_condition method, and if
1998 still true, call the event's do_event method.
1999
2000 Options are passed as a hashref or as a list of name-value pairs.  Available
2001 options are:
2002
2003 =over 4
2004
2005 =item check_freq
2006
2007 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2008
2009 =item stage
2010
2011 "collect" (the default) or "pre-bill"
2012
2013 =item time
2014
2015 "Current time" for the events.
2016
2017 =item debug
2018
2019 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2020
2021 =item eventtable
2022
2023 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2024
2025 =item objects
2026
2027 Explicitly pass the objects to be tested (typically used with eventtable).
2028
2029 =item testonly
2030
2031 Set to true to return the objects, but not actually insert them into the
2032 database.
2033
2034 =back
2035
2036 =cut
2037
2038 sub due_cust_event {
2039   my $self = shift;
2040   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2041
2042   #???
2043   #my $DEBUG = $opt{'debug'}
2044   $opt{'debug'} ||= 0; # silence some warnings
2045   local($DEBUG) = $opt{'debug'}
2046     if $opt{'debug'} > $DEBUG;
2047   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2048
2049   warn "$me due_cust_event called with options ".
2050        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2051     if $DEBUG;
2052
2053   $opt{'time'} ||= time;
2054
2055   local $SIG{HUP} = 'IGNORE';
2056   local $SIG{INT} = 'IGNORE';
2057   local $SIG{QUIT} = 'IGNORE';
2058   local $SIG{TERM} = 'IGNORE';
2059   local $SIG{TSTP} = 'IGNORE';
2060   local $SIG{PIPE} = 'IGNORE';
2061
2062   my $oldAutoCommit = $FS::UID::AutoCommit;
2063   local $FS::UID::AutoCommit = 0;
2064   my $dbh = dbh;
2065
2066   $self->select_for_update #mutex
2067     unless $opt{testonly};
2068
2069   ###
2070   # find possible events (initial search)
2071   ###
2072
2073   my @cust_event = ();
2074
2075   my @eventtable = $opt{'eventtable'}
2076                      ? ( $opt{'eventtable'} )
2077                      : FS::part_event->eventtables_runorder;
2078
2079   my $check_freq = $opt{'check_freq'} || '1d';
2080
2081   foreach my $eventtable ( @eventtable ) {
2082
2083     my @objects;
2084     if ( $opt{'objects'} ) {
2085
2086       @objects = @{ $opt{'objects'} };
2087
2088     } elsif ( $eventtable eq 'cust_main' ) {
2089
2090       @objects = ( $self );
2091
2092     } else {
2093
2094       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2095       # linkage not needed here because FS::cust_main->$eventtable will
2096       # already supply it
2097
2098       #some false laziness w/Cron::bill bill_where
2099
2100       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
2101       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2102         'time'=>$opt{'time'},
2103       );
2104       $where = $where ? "AND $where" : '';
2105
2106       my $are_part_event =
2107       "EXISTS ( SELECT 1 FROM part_event $join
2108         WHERE check_freq = '$check_freq'
2109         AND eventtable = '$eventtable'
2110         AND ( disabled = '' OR disabled IS NULL )
2111         $where
2112         )
2113       ";
2114       #eofalse
2115
2116       @objects = $self->$eventtable(
2117         'addl_from' => $cm_join,
2118         'extra_sql' => " AND $are_part_event",
2119       );
2120     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2121
2122     my @e_cust_event = ();
2123
2124     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2125
2126     my $cross = "CROSS JOIN $eventtable $linkage";
2127     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2128       unless $eventtable eq 'cust_main';
2129
2130     foreach my $object ( @objects ) {
2131
2132       #this first search uses the condition_sql magic for optimization.
2133       #the more possible events we can eliminate in this step the better
2134
2135       my $cross_where = '';
2136       my $pkey = $object->primary_key;
2137       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2138
2139       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
2140       my $extra_sql =
2141         FS::part_event_condition->where_conditions_sql( $eventtable,
2142                                                         'time'=>$opt{'time'}
2143                                                       );
2144       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2145
2146       $extra_sql = "AND $extra_sql" if $extra_sql;
2147
2148       #here is the agent virtualization
2149       $extra_sql .= " AND (    part_event.agentnum IS NULL
2150                             OR part_event.agentnum = ". $self->agentnum. ' )';
2151
2152       $extra_sql .= " $order";
2153
2154       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2155         if $opt{'debug'} > 2;
2156       my @part_event = qsearch( {
2157         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2158         'select'    => 'part_event.*',
2159         'table'     => 'part_event',
2160         'addl_from' => "$cross $join",
2161         'hashref'   => { 'check_freq' => $check_freq,
2162                          'eventtable' => $eventtable,
2163                          'disabled'   => '',
2164                        },
2165         'extra_sql' => "AND $cross_where $extra_sql",
2166       } );
2167
2168       if ( $DEBUG > 2 ) {
2169         my $pkey = $object->primary_key;
2170         warn "      ". scalar(@part_event).
2171              " possible events found for $eventtable ". $object->$pkey(). "\n";
2172       }
2173
2174       push @e_cust_event, map {
2175         $_->new_cust_event($object, 'time' => $opt{'time'})
2176       } @part_event;
2177
2178     }
2179
2180     warn "    ". scalar(@e_cust_event).
2181          " subtotal possible cust events found for $eventtable\n"
2182       if $DEBUG > 1;
2183
2184     push @cust_event, @e_cust_event;
2185
2186   }
2187
2188   warn "  ". scalar(@cust_event).
2189        " total possible cust events found in initial search\n"
2190     if $DEBUG; # > 1;
2191
2192
2193   ##
2194   # test stage
2195   ##
2196
2197   $opt{stage} ||= 'collect';
2198   @cust_event =
2199     grep { my $stage = $_->part_event->event_stage;
2200            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2201          }
2202          @cust_event;
2203
2204   ##
2205   # test conditions
2206   ##
2207
2208   my %unsat = ();
2209
2210   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2211                      @cust_event;
2212
2213   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2214     if $DEBUG; # > 1;
2215
2216   warn "    invalid conditions not eliminated with condition_sql:\n".
2217        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2218     if keys %unsat && $DEBUG; # > 1;
2219
2220   ##
2221   # insert
2222   ##
2223
2224   unless( $opt{testonly} ) {
2225     foreach my $cust_event ( @cust_event ) {
2226
2227       my $error = $cust_event->insert();
2228       if ( $error ) {
2229         $dbh->rollback if $oldAutoCommit;
2230         return $error;
2231       }
2232
2233     }
2234   }
2235
2236   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2237
2238   ##
2239   # return
2240   ##
2241
2242   warn "  returning events: ". Dumper(@cust_event). "\n"
2243     if $DEBUG > 2;
2244
2245   \@cust_event;
2246
2247 }
2248
2249 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2250
2251 Applies unapplied payments and credits.
2252
2253 In most cases, this new method should be used in place of sequential
2254 apply_payments and apply_credits methods.
2255
2256 A hash of optional arguments may be passed.  Currently "manual" is supported.
2257 If true, a payment receipt is sent instead of a statement when
2258 'payment_receipt_email' configuration option is set.
2259
2260 If there is an error, returns the error, otherwise returns false.
2261
2262 =cut
2263
2264 sub apply_payments_and_credits {
2265   my( $self, %options ) = @_;
2266
2267   local $SIG{HUP} = 'IGNORE';
2268   local $SIG{INT} = 'IGNORE';
2269   local $SIG{QUIT} = 'IGNORE';
2270   local $SIG{TERM} = 'IGNORE';
2271   local $SIG{TSTP} = 'IGNORE';
2272   local $SIG{PIPE} = 'IGNORE';
2273
2274   my $oldAutoCommit = $FS::UID::AutoCommit;
2275   local $FS::UID::AutoCommit = 0;
2276   my $dbh = dbh;
2277
2278   $self->select_for_update; #mutex
2279
2280   foreach my $cust_bill ( $self->open_cust_bill ) {
2281     my $error = $cust_bill->apply_payments_and_credits(%options);
2282     if ( $error ) {
2283       $dbh->rollback if $oldAutoCommit;
2284       return "Error applying: $error";
2285     }
2286   }
2287
2288   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2289   ''; #no error
2290
2291 }
2292
2293 =item apply_credits OPTION => VALUE ...
2294
2295 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2296 to outstanding invoice balances in chronological order (or reverse
2297 chronological order if the I<order> option is set to B<newest>) and returns the
2298 value of any remaining unapplied credits available for refund (see
2299 L<FS::cust_refund>).
2300
2301 Dies if there is an error.
2302
2303 =cut
2304
2305 sub apply_credits {
2306   my $self = shift;
2307   my %opt = @_;
2308
2309   local $SIG{HUP} = 'IGNORE';
2310   local $SIG{INT} = 'IGNORE';
2311   local $SIG{QUIT} = 'IGNORE';
2312   local $SIG{TERM} = 'IGNORE';
2313   local $SIG{TSTP} = 'IGNORE';
2314   local $SIG{PIPE} = 'IGNORE';
2315
2316   my $oldAutoCommit = $FS::UID::AutoCommit;
2317   local $FS::UID::AutoCommit = 0;
2318   my $dbh = dbh;
2319
2320   $self->select_for_update; #mutex
2321
2322   unless ( $self->total_unapplied_credits ) {
2323     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2324     return 0;
2325   }
2326
2327   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2328       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2329
2330   my @invoices = $self->open_cust_bill;
2331   @invoices = sort { $b->_date <=> $a->_date } @invoices
2332     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2333
2334   if ( $conf->exists('pkg-balances') ) {
2335     # limit @credits to those w/ a pkgnum grepped from $self
2336     my %pkgnums = ();
2337     foreach my $i (@invoices) {
2338       foreach my $li ( $i->cust_bill_pkg ) {
2339         $pkgnums{$li->pkgnum} = 1;
2340       }
2341     }
2342     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2343   }
2344
2345   my $credit;
2346
2347   foreach my $cust_bill ( @invoices ) {
2348
2349     if ( !defined($credit) || $credit->credited == 0) {
2350       $credit = pop @credits or last;
2351     }
2352
2353     my $owed;
2354     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2355       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2356     } else {
2357       $owed = $cust_bill->owed;
2358     }
2359     unless ( $owed > 0 ) {
2360       push @credits, $credit;
2361       next;
2362     }
2363
2364     my $amount = min( $credit->credited, $owed );
2365
2366     my $cust_credit_bill = new FS::cust_credit_bill ( {
2367       'crednum' => $credit->crednum,
2368       'invnum'  => $cust_bill->invnum,
2369       'amount'  => $amount,
2370     } );
2371     $cust_credit_bill->pkgnum( $credit->pkgnum )
2372       if $conf->exists('pkg-balances') && $credit->pkgnum;
2373     my $error = $cust_credit_bill->insert;
2374     if ( $error ) {
2375       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2376       die $error;
2377     }
2378
2379     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2380
2381   }
2382
2383   my $total_unapplied_credits = $self->total_unapplied_credits;
2384
2385   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2386
2387   return $total_unapplied_credits;
2388 }
2389
2390 =item apply_payments  [ OPTION => VALUE ... ]
2391
2392 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2393 to outstanding invoice balances in chronological order.
2394
2395  #and returns the value of any remaining unapplied payments.
2396
2397 A hash of optional arguments may be passed.  Currently "manual" is supported.
2398 If true, a payment receipt is sent instead of a statement when
2399 'payment_receipt_email' configuration option is set.
2400
2401 Dies if there is an error.
2402
2403 =cut
2404
2405 sub apply_payments {
2406   my( $self, %options ) = @_;
2407
2408   local $SIG{HUP} = 'IGNORE';
2409   local $SIG{INT} = 'IGNORE';
2410   local $SIG{QUIT} = 'IGNORE';
2411   local $SIG{TERM} = 'IGNORE';
2412   local $SIG{TSTP} = 'IGNORE';
2413   local $SIG{PIPE} = 'IGNORE';
2414
2415   my $oldAutoCommit = $FS::UID::AutoCommit;
2416   local $FS::UID::AutoCommit = 0;
2417   my $dbh = dbh;
2418
2419   $self->select_for_update; #mutex
2420
2421   #return 0 unless
2422
2423   my @payments = sort { $b->_date <=> $a->_date }
2424                  grep { $_->unapplied > 0 }
2425                  $self->cust_pay;
2426
2427   my @invoices = sort { $a->_date <=> $b->_date}
2428                  grep { $_->owed > 0 }
2429                  $self->cust_bill;
2430
2431   if ( $conf->exists('pkg-balances') ) {
2432     # limit @payments to those w/ a pkgnum grepped from $self
2433     my %pkgnums = ();
2434     foreach my $i (@invoices) {
2435       foreach my $li ( $i->cust_bill_pkg ) {
2436         $pkgnums{$li->pkgnum} = 1;
2437       }
2438     }
2439     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2440   }
2441
2442   my $payment;
2443
2444   foreach my $cust_bill ( @invoices ) {
2445
2446     if ( !defined($payment) || $payment->unapplied == 0 ) {
2447       $payment = pop @payments or last;
2448     }
2449
2450     my $owed;
2451     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2452       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2453     } else {
2454       $owed = $cust_bill->owed;
2455     }
2456     unless ( $owed > 0 ) {
2457       push @payments, $payment;
2458       next;
2459     }
2460
2461     my $amount = min( $payment->unapplied, $owed );
2462
2463     my $cbp = {
2464       'paynum' => $payment->paynum,
2465       'invnum' => $cust_bill->invnum,
2466       'amount' => $amount,
2467     };
2468     $cbp->{_date} = $payment->_date
2469         if $options{'manual'} && $options{'backdate_application'};
2470     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2471     $cust_bill_pay->pkgnum( $payment->pkgnum )
2472       if $conf->exists('pkg-balances') && $payment->pkgnum;
2473     my $error = $cust_bill_pay->insert(%options);
2474     if ( $error ) {
2475       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2476       die $error;
2477     }
2478
2479     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2480
2481   }
2482
2483   my $total_unapplied_payments = $self->total_unapplied_payments;
2484
2485   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2486
2487   return $total_unapplied_payments;
2488 }
2489
2490 =back
2491
2492 =head1 FLOW
2493
2494   bill_and_collect
2495
2496     cancel_expired_pkgs
2497     suspend_adjourned_pkgs
2498     unsuspend_resumed_pkgs
2499
2500     bill
2501       (do_cust_event pre-bill)
2502       _make_lines
2503         _handle_taxes
2504           (vendor-only) _gather_taxes
2505       _omit_zero_value_bundles
2506       _handle_taxes (for fees)
2507       calculate_taxes
2508
2509     apply_payments_and_credits
2510     collect
2511       do_cust_event
2512         due_cust_event
2513
2514 =head1 BUGS
2515
2516 =head1 SEE ALSO
2517
2518 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2519
2520 =cut
2521
2522 1;