FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::cust_bill;
  11 use FS::cust_bill_pkg;
  12 use FS::cust_bill_pkg_display;
  13 use FS::cust_bill_pay;
  14 use FS::cust_credit_bill;
  15 use FS::cust_tax_adjustment;
  16 use FS::tax_rate;
  17 use FS::tax_rate_location;
  18 use FS::cust_bill_pkg_tax_location;
  19 use FS::cust_bill_pkg_tax_rate_location;
  20 use FS::part_event;
  21 use FS::part_event_condition;
  22 use FS::pkg_category;
  23
  24 # 1 is mostly method/subroutine entry and options
  25 # 2 traces progress of some operations
  26 # 3 is even more information including possibly sensitive data
  27 $DEBUG = 0;
  28 $me = '[FS::cust_main::Billing]';
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Billing - Billing mixin for cust_main
  38
  39 =head1 SYNOPSIS
  40
  41 =head1 DESCRIPTION
  42
  43 These methods are available on FS::cust_main objects.
  44
  45 =head1 METHODS
  46
  47 =over 4
  48
  49 =item bill_and_collect
  50
  51 Cancels and suspends any packages due, generates bills, applies payments and
  52 credits, and applies collection events to run cards, send bills and notices,
  53 etc.
  54
  55 By default, warns on errors and continues with the next operation (but see the
  56 "fatal" flag below).
  57
  58 Options are passed as name-value pairs.  Currently available options are:
  59
  60 =over 4
  61
  62 =item time
  63
  64 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  65
  66  use Date::Parse;
  67  ...
  68  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  69
  70 =item invoice_time
  71
  72 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  73
  74 =item check_freq
  75
  76 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  77
  78 =item resetup
  79
  80 If set true, re-charges setup fees.
  81
  82 =item fatal
  83
  84 If set any errors prevent subsequent operations from continusing.  If set
  85 specifically to "return", returns the error (or false, if there is no error).
  86 Any other true value causes errors to die.
  87
  88 =item debug
  89
  90 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  91
  92 =item job
  93
  94 Optional FS::queue entry to receive status updates.
  95
  96 =back
  97
  98 Options are passed to the B<bill> and B<collect> methods verbatim, so all
  99 options of those methods are also available.
 100
 101 =cut
 102
 103 sub bill_and_collect {
 104   my( $self, %options ) = @_;
 105
 106   my $error;
 107
 108   #$options{actual_time} not $options{time} because freeside-daily -d is for
 109   #pre-printing invoices
 110
 111   $options{'actual_time'} ||= time;
 112   my $job = $options{'job'};
 113
 114   $job->update_statustext('0,cleaning expired packages') if $job;
 115   $error = $self->cancel_expired_pkgs( $options{actual_time} );
 116   if ( $error ) {
 117     $error = "Error expiring custnum ". $self->custnum. ": $error";
 118     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 119     elsif ( $options{fatal}                                ) { die    $error; }
 120     else                                                     { warn   $error; }
 121   }
 122
 123   $error = $self->suspend_adjourned_pkgs( $options{actual_time} );
 124   if ( $error ) {
 125     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 126     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 127     elsif ( $options{fatal}                                ) { die    $error; }
 128     else                                                     { warn   $error; }
 129   }
 130
 131   $job->update_statustext('20,billing packages') if $job;
 132   $error = $self->bill( %options );
 133   if ( $error ) {
 134     $error = "Error billing custnum ". $self->custnum. ": $error";
 135     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 136     elsif ( $options{fatal}                                ) { die    $error; }
 137     else                                                     { warn   $error; }
 138   }
 139
 140   $job->update_statustext('50,applying payments and credits') if $job;
 141   $error = $self->apply_payments_and_credits;
 142   if ( $error ) {
 143     $error = "Error applying custnum ". $self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('70,running collection events') if $job;
 150   unless ( $conf->exists('cancelled_cust-noevents')
 151            && ! $self->num_ncancelled_pkgs
 152   ) {
 153     $error = $self->collect( %options );
 154     if ( $error ) {
 155       $error = "Error collecting custnum ". $self->custnum. ": $error";
 156       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 157       elsif ($options{fatal}                               ) { die    $error; }
 158       else                                                   { warn   $error; }
 159     }
 160   }
 161   $job->update_statustext('100,finished') if $job;
 162
 163   '';
 164
 165 }
 166
 167 sub cancel_expired_pkgs {
 168   my ( $self, $time, %options ) = @_;
 169
 170   my @cancel_pkgs = $self->ncancelled_pkgs( {
 171     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 172   } );
 173
 174   my @errors = ();
 175
 176   foreach my $cust_pkg ( @cancel_pkgs ) {
 177     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 178     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 179                                            'reason_otaker' => $cpr->otaker
 180                                          )
 181                                        : ()
 182                                  );
 183     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 184   }
 185
 186   scalar(@errors) ? join(' / ', @errors) : '';
 187
 188 }
 189
 190 sub suspend_adjourned_pkgs {
 191   my ( $self, $time, %options ) = @_;
 192
 193   my @susp_pkgs = $self->ncancelled_pkgs( {
 194     'extra_sql' =>
 195       " AND ( susp IS NULL OR susp = 0 )
 196         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 197               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 198             )
 199       ",
 200   } );
 201
 202   #only because there's no SQL test for is_prepaid :/
 203   @susp_pkgs =
 204     grep {     (    $_->part_pkg->is_prepaid
 205                  && $_->bill
 206                  && $_->bill < $time
 207                )
 208             || (    $_->adjourn
 209                  && $_->adjourn <= $time
 210                )
 211
 212          }
 213          @susp_pkgs;
 214
 215   my @errors = ();
 216
 217   foreach my $cust_pkg ( @susp_pkgs ) {
 218     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 219       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 220     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 221                                             'reason_otaker' => $cpr->otaker
 222                                           )
 223                                         : ()
 224                                   );
 225     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 226   }
 227
 228   scalar(@errors) ? join(' / ', @errors) : '';
 229
 230 }
 231
 232 =item bill OPTIONS
 233
 234 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 235 conjunction with the collect method by calling B<bill_and_collect>.
 236
 237 If there is an error, returns the error, otherwise returns false.
 238
 239 Options are passed as name-value pairs.  Currently available options are:
 240
 241 =over 4
 242
 243 =item resetup
 244
 245 If set true, re-charges setup fees.
 246
 247 =item recurring_only
 248
 249 If set true then only bill recurring charges, not setup, usage, one time
 250 charges, etc.
 251
 252 =item freq_override
 253
 254 If set, then override the normal frequency and look for a part_pkg_discount
 255 to take at that frequency.
 256
 257 =item time
 258
 259 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 260
 261  use Date::Parse;
 262  ...
 263  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 264
 265 =item pkg_list
 266
 267 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 268
 269  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 270
 271 =item not_pkgpart
 272
 273 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 274
 275 =item invoice_time
 276
 277 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 278
 279 =item cancel
 280
 281 This boolean value informs the us that the package is being cancelled.  This
 282 typically might mean not charging the normal recurring fee but only usage
 283 fees since the last billing. Setup charges may be charged.  Not all package
 284 plans support this feature (they tend to charge 0).
 285
 286 =item no_usage_reset
 287
 288 Prevent the resetting of usage limits during this call.
 289
 290 =item no_commit
 291
 292 Do not save the generated bill in the database.  Useful with return_bill
 293
 294 =item return_bill
 295
 296 A list reference on which the generated bill(s) will be returned.
 297
 298 =item invoice_terms
 299
 300 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 301 terms or the default terms are used.
 302
 303 =back
 304
 305 =cut
 306
 307 sub bill {
 308   my( $self, %options ) = @_;
 309
 310   return '' if $self->payby eq 'COMP';
 311
 312   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 313
 314   warn "$me bill customer ". $self->custnum. "\n"
 315     if $DEBUG;
 316
 317   my $time = $options{'time'} || time;
 318   my $invoice_time = $options{'invoice_time'} || $time;
 319
 320   $options{'not_pkgpart'} ||= {};
 321   $options{'not_pkgpart'} = { map { $_ => 1 }
 322                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 323                             }
 324     unless ref($options{'not_pkgpart'});
 325
 326   local $SIG{HUP} = 'IGNORE';
 327   local $SIG{INT} = 'IGNORE';
 328   local $SIG{QUIT} = 'IGNORE';
 329   local $SIG{TERM} = 'IGNORE';
 330   local $SIG{TSTP} = 'IGNORE';
 331   local $SIG{PIPE} = 'IGNORE';
 332
 333   my $oldAutoCommit = $FS::UID::AutoCommit;
 334   local $FS::UID::AutoCommit = 0;
 335   my $dbh = dbh;
 336
 337   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 338     if $DEBUG;
 339
 340   $self->select_for_update; #mutex
 341
 342   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 343     if $DEBUG;
 344
 345   my $error = $self->do_cust_event(
 346     'debug'      => ( $options{'debug'} || 0 ),
 347     'time'       => $invoice_time,
 348     'check_freq' => $options{'check_freq'},
 349     'stage'      => 'pre-bill',
 350   )
 351     unless $options{no_commit};
 352   if ( $error ) {
 353     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 354     return $error;
 355   }
 356
 357   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 358     if $DEBUG;
 359
 360   #keep auto-charge and non-auto-charge line items separate
 361   my @passes = ( '', 'no_auto' );
 362
 363   my %cust_bill_pkg = map { $_ => [] } @passes;
 364
 365   ###
 366   # find the packages which are due for billing, find out how much they are
 367   # & generate invoice database.
 368   ###
 369
 370   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 371   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 372
 373   my %taxlisthash = map { $_ => {} } @passes;
 374
 375   my @precommit_hooks = ();
 376
 377   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 378   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 379
 380     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 381
 382     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
 383
 384     #? to avoid use of uninitialized value errors... ?
 385     $cust_pkg->setfield('bill', '')
 386       unless defined($cust_pkg->bill);
 387
 388     #my $part_pkg = $cust_pkg->part_pkg;
 389
 390     my $real_pkgpart = $cust_pkg->pkgpart;
 391     my %hash = $cust_pkg->hash;
 392
 393     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 394     # suffer from performance issues
 395     $options{has_hidden} = 0;
 396     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 397     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 398
 399     foreach my $part_pkg ( @part_pkg ) {
 400
 401       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 402
 403       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 404
 405       my $error =
 406         $self->_make_lines( 'part_pkg'            => $part_pkg,
 407                             'cust_pkg'            => $cust_pkg,
 408                             'precommit_hooks'     => \@precommit_hooks,
 409                             'line_items'          => $cust_bill_pkg{$pass},
 410                             'setup'               => $total_setup{$pass},
 411                             'recur'               => $total_recur{$pass},
 412                             'tax_matrix'          => $taxlisthash{$pass},
 413                             'time'                => $time,
 414                             'real_pkgpart'        => $real_pkgpart,
 415                             'options'             => \%options,
 416                           );
 417       if ($error) {
 418         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 419         return $error;
 420       }
 421
 422     } #foreach my $part_pkg
 423
 424   } #foreach my $cust_pkg
 425
 426   #if the customer isn't on an automatic payby, everything can go on a single
 427   #invoice anyway?
 428   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 429     #merge everything into one list
 430   #}
 431
 432   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 433
 434     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 435
 436     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 437
 438     warn "$me billing pass $pass\n"
 439            #.Dumper(\@cust_bill_pkg)."\n"
 440       if $DEBUG > 2;
 441
 442     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 443            !$conf->exists('postal_invoice-recurring_only')
 444        )
 445     {
 446
 447       my $postal_pkg = $self->charge_postal_fee();
 448       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 449
 450         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 451         return "can't charge postal invoice fee for customer ".
 452           $self->custnum. ": $postal_pkg";
 453
 454       } elsif ( $postal_pkg ) {
 455
 456         my $real_pkgpart = $postal_pkg->pkgpart;
 457         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 458         # suffer from performance issues
 459         $options{has_hidden} = 0;
 460         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 461         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 462
 463         foreach my $part_pkg ( @part_pkg ) {
 464           my %postal_options = %options;
 465           delete $postal_options{cancel};
 466           my $error =
 467             $self->_make_lines( 'part_pkg'            => $part_pkg,
 468                                 'cust_pkg'            => $postal_pkg,
 469                                 'precommit_hooks'     => \@precommit_hooks,
 470                                 'line_items'          => \@cust_bill_pkg,
 471                                 'setup'               => $total_setup{$pass},
 472                                 'recur'               => $total_recur{$pass},
 473                                 'tax_matrix'          => $taxlisthash{$pass},
 474                                 'time'                => $time,
 475                                 'real_pkgpart'        => $real_pkgpart,
 476                                 'options'             => \%postal_options,
 477                               );
 478           if ($error) {
 479             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 480             return $error;
 481           }
 482         }
 483
 484         # it's silly to have a zero value postal_pkg, but....
 485         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 486
 487       }
 488
 489     }
 490
 491     my $listref_or_error =
 492       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 493
 494     unless ( ref( $listref_or_error ) ) {
 495       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 496       return $listref_or_error;
 497     }
 498
 499     foreach my $taxline ( @$listref_or_error ) {
 500       ${ $total_setup{$pass} } =
 501         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 502       push @cust_bill_pkg, $taxline;
 503     }
 504
 505     #add tax adjustments
 506     warn "adding tax adjustments...\n" if $DEBUG > 2;
 507     foreach my $cust_tax_adjustment (
 508       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 509                                        'billpkgnum' => '',
 510                                      }
 511              )
 512     ) {
 513
 514       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 515
 516       my $itemdesc = $cust_tax_adjustment->taxname;
 517       $itemdesc = '' if $itemdesc eq 'Tax';
 518
 519       push @cust_bill_pkg, new FS::cust_bill_pkg {
 520         'pkgnum'      => 0,
 521         'setup'       => $tax,
 522         'recur'       => 0,
 523         'sdate'       => '',
 524         'edate'       => '',
 525         'itemdesc'    => $itemdesc,
 526         'itemcomment' => $cust_tax_adjustment->comment,
 527         'cust_tax_adjustment' => $cust_tax_adjustment,
 528         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 529       };
 530
 531     }
 532
 533     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 534
 535     my @cust_bill = $self->cust_bill;
 536     my $balance = $self->balance;
 537     my $previous_balance = scalar(@cust_bill)
 538                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 539                              : 0;
 540
 541     $previous_balance += $cust_bill[$#cust_bill]->charged
 542       if scalar(@cust_bill);
 543     #my $balance_adjustments =
 544     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 545
 546     warn "creating the new invoice\n" if $DEBUG;
 547     #create the new invoice
 548     my $cust_bill = new FS::cust_bill ( {
 549       'custnum'             => $self->custnum,
 550       '_date'               => $invoice_time,
 551       'charged'             => $charged,
 552       'billing_balance'     => $balance,
 553       'previous_balance'    => $previous_balance,
 554       'invoice_terms'       => $options{'invoice_terms'},
 555       'cust_bill_pkg'       => \@cust_bill_pkg,
 556     } );
 557     $error = $cust_bill->insert unless $options{no_commit};
 558     if ( $error ) {
 559       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 560       return "can't create invoice for customer #". $self->custnum. ": $error";
 561     }
 562     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 563
 564   } #foreach my $pass ( keys %cust_bill_pkg )
 565
 566   foreach my $hook ( @precommit_hooks ) {
 567     eval {
 568       &{$hook}; #($self) ?
 569     } unless $options{no_commit};
 570     if ( $@ ) {
 571       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 572       return "$@ running precommit hook $hook\n";
 573     }
 574   }
 575
 576   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 577
 578   ''; #no error
 579 }
 580
 581 #discard bundled packages of 0 value
 582 sub _omit_zero_value_bundles {
 583
 584   my @cust_bill_pkg = ();
 585   my @cust_bill_pkg_bundle = ();
 586   my $sum = 0;
 587   my $discount_show_always = 0;
 588
 589   foreach my $cust_bill_pkg ( @_ ) {
 590     $discount_show_always = ($cust_bill_pkg->get('discounts')
 591                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 592                                 && $conf->exists('discount-show-always'));
 593     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 594       push @cust_bill_pkg, @cust_bill_pkg_bundle
 595                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 596       @cust_bill_pkg_bundle = ();
 597       $sum = 0;
 598     }
 599     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 600     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 601   }
 602   push @cust_bill_pkg, @cust_bill_pkg_bundle
 603                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 604
 605   (@cust_bill_pkg);
 606
 607 }
 608
 609 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 610
 611 This is a weird one.  Perhaps it should not even be exposed.
 612
 613 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 614 Usually used internally by bill method B<bill>.
 615
 616 If there is an error, returns the error, otherwise returns reference to a
 617 list of line items suitable for insertion.
 618
 619 =over 4
 620
 621 =item LINEITEMREF
 622
 623 An array ref of the line items being billed.
 624
 625 =item TAXHASHREF
 626
 627 A strange beast.  The keys to this hash are internal identifiers consisting
 628 of the name of the tax object type, a space, and its unique identifier ( e.g.
 629  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 630 item in the list is the tax object.  The remaining items are either line
 631 items or floating point values (currency amounts).
 632
 633 The taxes are calculated on this entity.  Calculated exemption records are
 634 transferred to the LINEITEMREF items on the assumption that they are related.
 635
 636 Read the source.
 637
 638 =item INVOICE_TIME
 639
 640 This specifies the date appearing on the associated invoice.  Some
 641 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 642
 643 =back
 644
 645 =cut
 646
 647 sub calculate_taxes {
 648   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 649
 650   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 651
 652   warn "$me calculate_taxes\n"
 653        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 654     if $DEBUG > 2;
 655
 656   my @tax_line_items = ();
 657
 658   # keys are tax names (as printed on invoices / itemdesc )
 659   # values are listrefs of taxlisthash keys (internal identifiers)
 660   my %taxname = ();
 661
 662   # keys are taxlisthash keys (internal identifiers)
 663   # values are (cumulative) amounts
 664   my %tax = ();
 665
 666   # keys are taxlisthash keys (internal identifiers)
 667   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 668   my %tax_location = ();
 669
 670   # keys are taxlisthash keys (internal identifiers)
 671   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 672   my %tax_rate_location = ();
 673
 674   foreach my $tax ( keys %$taxlisthash ) {
 675     my $tax_object = shift @{ $taxlisthash->{$tax} };
 676     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 677     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 678     my $hashref_or_error =
 679       $tax_object->taxline( $taxlisthash->{$tax},
 680                             'custnum'      => $self->custnum,
 681                             'invoice_time' => $invoice_time
 682                           );
 683     return $hashref_or_error unless ref($hashref_or_error);
 684
 685     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 686
 687     my $name   = $hashref_or_error->{'name'};
 688     my $amount = $hashref_or_error->{'amount'};
 689
 690     #warn "adding $amount as $name\n";
 691     $taxname{ $name } ||= [];
 692     push @{ $taxname{ $name } }, $tax;
 693
 694     $tax{ $tax } += $amount;
 695
 696     $tax_location{ $tax } ||= [];
 697     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 698       push @{ $tax_location{ $tax }  },
 699         {
 700           'taxnum'      => $tax_object->taxnum,
 701           'taxtype'     => ref($tax_object),
 702           'pkgnum'      => $tax_object->get('pkgnum'),
 703           'locationnum' => $tax_object->get('locationnum'),
 704           'amount'      => sprintf('%.2f', $amount ),
 705         };
 706     }
 707
 708     $tax_rate_location{ $tax } ||= [];
 709     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 710       my $taxratelocationnum =
 711         $tax_object->tax_rate_location->taxratelocationnum;
 712       push @{ $tax_rate_location{ $tax }  },
 713         {
 714           'taxnum'             => $tax_object->taxnum,
 715           'taxtype'            => ref($tax_object),
 716           'amount'             => sprintf('%.2f', $amount ),
 717           'locationtaxid'      => $tax_object->location,
 718           'taxratelocationnum' => $taxratelocationnum,
 719         };
 720     }
 721
 722   }
 723
 724   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 725   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 726   foreach my $tax ( keys %$taxlisthash ) {
 727     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 728       next unless ref($_) eq 'FS::cust_bill_pkg';
 729
 730       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 731
 732       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 733       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 734           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 735         unless $packagemap{$_->pkgnum};
 736
 737       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 738            @cust_tax_exempt_pkg;
 739     }
 740   }
 741
 742   #consolidate and create tax line items
 743   warn "consolidating and generating...\n" if $DEBUG > 2;
 744   foreach my $taxname ( keys %taxname ) {
 745     my $tax = 0;
 746     my %seen = ();
 747     my @cust_bill_pkg_tax_location = ();
 748     my @cust_bill_pkg_tax_rate_location = ();
 749     warn "adding $taxname\n" if $DEBUG > 1;
 750     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 751       next if $seen{$taxitem}++;
 752       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 753       $tax += $tax{$taxitem};
 754       push @cust_bill_pkg_tax_location,
 755         map { new FS::cust_bill_pkg_tax_location $_ }
 756             @{ $tax_location{ $taxitem } };
 757       push @cust_bill_pkg_tax_rate_location,
 758         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 759             @{ $tax_rate_location{ $taxitem } };
 760     }
 761     next unless $tax;
 762
 763     $tax = sprintf('%.2f', $tax );
 764
 765     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 766                                                    'disabled'     => '',
 767                                                  },
 768                                );
 769
 770     my @display = ();
 771     if ( $pkg_category and
 772          $conf->config('invoice_latexsummary') ||
 773          $conf->config('invoice_htmlsummary')
 774        )
 775     {
 776
 777       my %hash = (  'section' => $pkg_category->categoryname );
 778       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 779
 780     }
 781
 782     push @tax_line_items, new FS::cust_bill_pkg {
 783       'pkgnum'   => 0,
 784       'setup'    => $tax,
 785       'recur'    => 0,
 786       'sdate'    => '',
 787       'edate'    => '',
 788       'itemdesc' => $taxname,
 789       'display'  => \@display,
 790       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 791       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 792     };
 793
 794   }
 795
 796   \@tax_line_items;
 797 }
 798
 799 sub _make_lines {
 800   my ($self, %params) = @_;
 801
 802   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 803
 804   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 805   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 806   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 807   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 808   my $total_setup = $params{setup} or die "no setup accumulator specified";
 809   my $total_recur = $params{recur} or die "no recur accumulator specified";
 810   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 811   my $time = $params{'time'} or die "no time specified";
 812   my (%options) = %{$params{options}};
 813
 814   my $dbh = dbh;
 815   my $real_pkgpart = $params{real_pkgpart};
 816   my %hash = $cust_pkg->hash;
 817   my $old_cust_pkg = new FS::cust_pkg \%hash;
 818
 819   my @details = ();
 820   my @discounts = ();
 821   my $lineitems = 0;
 822
 823   $cust_pkg->pkgpart($part_pkg->pkgpart);
 824
 825   ###
 826   # bill setup
 827   ###
 828
 829   my $setup = 0;
 830   my $unitsetup = 0;
 831   if (     ! $options{recurring_only}
 832        and ! $options{cancel}
 833        and ( $options{'resetup'}
 834              || ( ! $cust_pkg->setup
 835                   && ( ! $cust_pkg->start_date
 836                        || $cust_pkg->start_date <= $time
 837                      )
 838                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 839                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 840                             ! $cust_pkg->getfield('susp')
 841                           )
 842                      )
 843                 )
 844            )
 845      )
 846   {
 847
 848     warn "    bill setup\n" if $DEBUG > 1;
 849
 850     unless ( $cust_pkg->waive_setup ) {
 851         $lineitems++;
 852
 853         $setup = eval { $cust_pkg->calc_setup( $time, \@details ) };
 854         return "$@ running calc_setup for $cust_pkg\n"
 855           if $@;
 856
 857         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 858     }
 859
 860     $cust_pkg->setfield('setup', $time)
 861       unless $cust_pkg->setup;
 862           #do need it, but it won't get written to the db
 863           #|| $cust_pkg->pkgpart != $real_pkgpart;
 864
 865     $cust_pkg->setfield('start_date', '')
 866       if $cust_pkg->start_date;
 867
 868   }
 869
 870   ###
 871   # bill recurring fee
 872   ###
 873
 874   #XXX unit stuff here too
 875   my $recur = 0;
 876   my $unitrecur = 0;
 877   my $sdate;
 878   if (     ! $cust_pkg->start_date
 879        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 880        and
 881             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $time )
 882          || ( $part_pkg->plan eq 'voip_cdr'
 883                && $part_pkg->option('bill_every_call')
 884             )
 885          || $options{cancel}
 886   ) {
 887
 888     # XXX should this be a package event?  probably.  events are called
 889     # at collection time at the moment, though...
 890     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 891       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 892       #don't want to reset usage just cause we want a line item??
 893       #&& $part_pkg->pkgpart == $real_pkgpart;
 894
 895     warn "    bill recur\n" if $DEBUG > 1;
 896     $lineitems++;
 897
 898     # XXX shared with $recur_prog
 899     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 900              || $cust_pkg->setup
 901              || $time;
 902
 903     #over two params!  lets at least switch to a hashref for the rest...
 904     my $increment_next_bill = ( $part_pkg->freq ne '0'
 905                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $time
 906                                 && !$options{cancel}
 907                               );
 908     my %param = ( 'precommit_hooks'     => $precommit_hooks,
 909                   'increment_next_bill' => $increment_next_bill,
 910                   'discounts'           => \@discounts,
 911                   'real_pkgpart'        => $real_pkgpart,
 912                   'freq_override'       => $options{freq_override} || '',
 913                   'setup_fee'           => 0,
 914                 );
 915
 916     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
 917
 918     # There may be some part_pkg for which this is wrong.  Only those
 919     # which can_discount are supported.
 920     # (the UI should prevent adding discounts to these at the moment)
 921
 922     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
 923          " for pkgpart ". $cust_pkg->pkgpart.
 924          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
 925       if $DEBUG > 2;
 926
 927     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
 928     return "$@ running $method for $cust_pkg\n"
 929       if ( $@ );
 930
 931     if ( $increment_next_bill ) {
 932
 933       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
 934       return "unparsable frequency: ". $part_pkg->freq
 935         if $next_bill == -1;
 936
 937       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
 938       # only for figuring next bill date, nothing else, so, reset $sdate again
 939       # here
 940       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 941       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
 942       $cust_pkg->last_bill($sdate);
 943
 944       $cust_pkg->setfield('bill', $next_bill );
 945
 946     }
 947
 948     if ( $param{'setup_fee'} ) {
 949       # Add an additional setup fee at the billing stage.
 950       # Used for prorate_defer_bill.
 951       $setup += $param{'setup_fee'};
 952       $unitsetup += $param{'setup_fee'};
 953       $lineitems++;
 954     }
 955
 956   }
 957
 958   warn "\$setup is undefined" unless defined($setup);
 959   warn "\$recur is undefined" unless defined($recur);
 960   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 961
 962   ###
 963   # If there's line items, create em cust_bill_pkg records
 964   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
 965   ###
 966
 967   if ( $lineitems ) {
 968
 969     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
 970       # hmm.. and if just the options are modified in some weird price plan?
 971
 972       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
 973         if $DEBUG >1;
 974
 975       my $error = $cust_pkg->replace( $old_cust_pkg,
 976                                       'depend_jobnum'=>$options{depend_jobnum},
 977                                       'options' => { $cust_pkg->options },
 978                                     )
 979         unless $options{no_commit};
 980       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
 981         if $error; #just in case
 982     }
 983
 984     $setup = sprintf( "%.2f", $setup );
 985     $recur = sprintf( "%.2f", $recur );
 986     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
 987       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
 988     }
 989     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
 990       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
 991     }
 992
 993     my $discount_show_always = ($recur == 0 && scalar(@discounts)
 994                                 && $conf->exists('discount-show-always'));
 995
 996     if ( $setup != 0 ||
 997          $recur != 0 ||
 998          (!$part_pkg->hidden && $options{has_hidden}) || #include some $0 lines
 999          $discount_show_always )
1000     {
1001
1002       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1003         if $DEBUG > 1;
1004
1005       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1006       if ( $DEBUG > 1 ) {
1007         warn "      adding customer package invoice detail: $_\n"
1008           foreach @cust_pkg_detail;
1009       }
1010       push @details, @cust_pkg_detail;
1011
1012       my $cust_bill_pkg = new FS::cust_bill_pkg {
1013         'pkgnum'    => $cust_pkg->pkgnum,
1014         'setup'     => $setup,
1015         'unitsetup' => $unitsetup,
1016         'recur'     => $recur,
1017         'unitrecur' => $unitrecur,
1018         'quantity'  => $cust_pkg->quantity,
1019         'details'   => \@details,
1020         'discounts' => \@discounts,
1021         'hidden'    => $part_pkg->hidden,
1022         'freq'      => $part_pkg->freq,
1023       };
1024
1025       if ( $part_pkg->recur_temporality eq 'preceding' ) {
1026         $cust_bill_pkg->sdate( $hash{last_bill} );
1027         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1028         $cust_bill_pkg->edate( $time ) if $options{cancel};
1029       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1030         $cust_bill_pkg->sdate( $sdate );
1031         $cust_bill_pkg->edate( $cust_pkg->bill );
1032         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1033       }
1034
1035       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1036         unless $part_pkg->pkgpart == $real_pkgpart;
1037
1038       $$total_setup += $setup;
1039       $$total_recur += $recur;
1040
1041       ###
1042       # handle taxes
1043       ###
1044
1045       unless ( $discount_show_always ) {
1046           my $error =
1047             $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1048           return $error if $error;
1049       }
1050
1051       push @$cust_bill_pkgs, $cust_bill_pkg;
1052
1053     } #if $setup != 0 || $recur != 0
1054
1055   } #if $line_items
1056
1057   '';
1058
1059 }
1060
1061 sub _handle_taxes {
1062   my $self = shift;
1063   my $part_pkg = shift;
1064   my $taxlisthash = shift;
1065   my $cust_bill_pkg = shift;
1066   my $cust_pkg = shift;
1067   my $invoice_time = shift;
1068   my $real_pkgpart = shift;
1069   my $options = shift;
1070
1071   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1072
1073   my %cust_bill_pkg = ();
1074   my %taxes = ();
1075
1076   my @classes;
1077   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1078   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1079   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1080   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1081
1082   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1083
1084     if ( $conf->exists('enable_taxproducts')
1085          && ( scalar($part_pkg->part_pkg_taxoverride)
1086               || $part_pkg->has_taxproduct
1087             )
1088        )
1089     {
1090
1091       foreach my $class (@classes) {
1092         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1093         return $err_or_ref unless ref($err_or_ref);
1094         $taxes{$class} = $err_or_ref;
1095       }
1096
1097       unless (exists $taxes{''}) {
1098         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1099         return $err_or_ref unless ref($err_or_ref);
1100         $taxes{''} = $err_or_ref;
1101       }
1102
1103     } else {
1104
1105       my @loc_keys = qw( city county state country );
1106       my %taxhash;
1107       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1108         my $cust_location = $cust_pkg->cust_location;
1109         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1110       } else {
1111         my $prefix =
1112           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1113           ? 'ship_'
1114           : '';
1115         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1116       }
1117
1118       $taxhash{'taxclass'} = $part_pkg->taxclass;
1119
1120       my @taxes = ();
1121       my %taxhash_elim = %taxhash;
1122       my @elim = qw( city county state );
1123       do {
1124
1125         #first try a match with taxclass
1126         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1127
1128         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1129           #then try a match without taxclass
1130           my %no_taxclass = %taxhash_elim;
1131           $no_taxclass{ 'taxclass' } = '';
1132           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1133         }
1134
1135         $taxhash_elim{ shift(@elim) } = '';
1136
1137       } while ( !scalar(@taxes) && scalar(@elim) );
1138
1139       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1140                     @taxes
1141         if $self->cust_main_exemption; #just to be safe
1142
1143       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1144         foreach (@taxes) {
1145           $_->set('pkgnum',      $cust_pkg->pkgnum );
1146           $_->set('locationnum', $cust_pkg->locationnum );
1147         }
1148       }
1149
1150       $taxes{''} = [ @taxes ];
1151       $taxes{'setup'} = [ @taxes ];
1152       $taxes{'recur'} = [ @taxes ];
1153       $taxes{$_} = [ @taxes ] foreach (@classes);
1154
1155       # # maybe eliminate this entirely, along with all the 0% records
1156       # unless ( @taxes ) {
1157       #   return
1158       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1159       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1160       # }
1161
1162     } #if $conf->exists('enable_taxproducts') ...
1163
1164   }
1165
1166   my @display = ();
1167   my $separate = $conf->exists('separate_usage');
1168   my $temp_pkg = new FS::cust_pkg { pkgpart => $real_pkgpart };
1169   my $usage_mandate = $temp_pkg->part_pkg->option('usage_mandate', 'Hush!');
1170   my $section = $temp_pkg->part_pkg->categoryname;
1171   if ( $separate || $section || $usage_mandate ) {
1172
1173     my %hash = ( 'section' => $section );
1174
1175     $section = $temp_pkg->part_pkg->option('usage_section', 'Hush!');
1176     my $summary = $temp_pkg->part_pkg->option('summarize_usage', 'Hush!');
1177     if ( $separate ) {
1178       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1179       push @display, new FS::cust_bill_pkg_display { type => 'R', %hash };
1180     } else {
1181       push @display, new FS::cust_bill_pkg_display
1182                        { type => '',
1183                          %hash,
1184                          ( ( $usage_mandate ) ? ( 'summary' => 'Y' ) : () ),
1185                        };
1186     }
1187
1188     if ($separate && $section && $summary) {
1189       push @display, new FS::cust_bill_pkg_display { type    => 'U',
1190                                                      summary => 'Y',
1191                                                      %hash,
1192                                                    };
1193     }
1194     if ($usage_mandate || $section && $summary) {
1195       $hash{post_total} = 'Y';
1196     }
1197
1198     if ($separate || $usage_mandate) {
1199       $hash{section} = $section if ($separate || $usage_mandate);
1200       push @display, new FS::cust_bill_pkg_display { type => 'U', %hash };
1201     }
1202
1203   }
1204   $cust_bill_pkg->set('display', \@display);
1205
1206   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1207   foreach my $key (keys %tax_cust_bill_pkg) {
1208     my @taxes = @{ $taxes{$key} || [] };
1209     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1210
1211     my %localtaxlisthash = ();
1212     foreach my $tax ( @taxes ) {
1213
1214       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1215 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1216 #                  ' locationnum'. $cust_pkg->locationnum
1217 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1218
1219       $taxlisthash->{ $taxname } ||= [ $tax ];
1220       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1221
1222       $localtaxlisthash{ $taxname } ||= [ $tax ];
1223       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1224
1225     }
1226
1227     warn "finding taxed taxes...\n" if $DEBUG > 2;
1228     foreach my $tax ( keys %localtaxlisthash ) {
1229       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1230       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1231         if $DEBUG > 2;
1232       next unless $tax_object->can('tax_on_tax');
1233
1234       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1235         my $totname = ref( $tot ). ' '. $tot->taxnum;
1236
1237         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1238           if $DEBUG > 2;
1239         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1240                                                              # existing taxes
1241         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1242         my $hashref_or_error =
1243           $tax_object->taxline( $localtaxlisthash{$tax},
1244                                 'custnum'      => $self->custnum,
1245                                 'invoice_time' => $invoice_time,
1246                               );
1247         return $hashref_or_error
1248           unless ref($hashref_or_error);
1249
1250         $taxlisthash->{ $totname } ||= [ $tot ];
1251         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1252
1253       }
1254     }
1255
1256   }
1257
1258   '';
1259 }
1260
1261 sub _gather_taxes {
1262   my $self = shift;
1263   my $part_pkg = shift;
1264   my $class = shift;
1265   my $cust_pkg = shift;
1266
1267   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1268
1269   my $geocode;
1270   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1271     $geocode = $cust_pkg->cust_location->geocode('cch');
1272   } else {
1273     $geocode = $self->geocode('cch');
1274   }
1275
1276   my @taxes = ();
1277
1278   my @taxclassnums = map { $_->taxclassnum }
1279                      $part_pkg->part_pkg_taxoverride($class);
1280
1281   unless (@taxclassnums) {
1282     @taxclassnums = map { $_->taxclassnum }
1283                     grep { $_->taxable eq 'Y' }
1284                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1285   }
1286   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1287     if $DEBUG;
1288
1289   my $extra_sql =
1290     "AND (".
1291     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1292
1293   @taxes = qsearch({ 'table' => 'tax_rate',
1294                      'hashref' => { 'geocode' => $geocode, },
1295                      'extra_sql' => $extra_sql,
1296                   })
1297     if scalar(@taxclassnums);
1298
1299   warn "Found taxes ".
1300        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1301    if $DEBUG;
1302
1303   [ @taxes ];
1304
1305 }
1306
1307 =item collect [ HASHREF | OPTION => VALUE ... ]
1308
1309 (Attempt to) collect money for this customer's outstanding invoices (see
1310 L<FS::cust_bill>).  Usually used after the bill method.
1311
1312 Actions are now triggered by billing events; see L<FS::part_event> and the
1313 billing events web interface.  Old-style invoice events (see
1314 L<FS::part_bill_event>) have been deprecated.
1315
1316 If there is an error, returns the error, otherwise returns false.
1317
1318 Options are passed as name-value pairs.
1319
1320 Currently available options are:
1321
1322 =over 4
1323
1324 =item invoice_time
1325
1326 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1327
1328 =item retry
1329
1330 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1331
1332 =item check_freq
1333
1334 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1335
1336 =item quiet
1337
1338 set true to surpress email card/ACH decline notices.
1339
1340 =item debug
1341
1342 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1343
1344 =back
1345
1346 # =item payby
1347 #
1348 # allows for one time override of normal customer billing method
1349
1350 =cut
1351
1352 sub collect {
1353   my( $self, %options ) = @_;
1354
1355   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1356
1357   my $invoice_time = $options{'invoice_time'} || time;
1358
1359   #put below somehow?
1360   local $SIG{HUP} = 'IGNORE';
1361   local $SIG{INT} = 'IGNORE';
1362   local $SIG{QUIT} = 'IGNORE';
1363   local $SIG{TERM} = 'IGNORE';
1364   local $SIG{TSTP} = 'IGNORE';
1365   local $SIG{PIPE} = 'IGNORE';
1366
1367   my $oldAutoCommit = $FS::UID::AutoCommit;
1368   local $FS::UID::AutoCommit = 0;
1369   my $dbh = dbh;
1370
1371   $self->select_for_update; #mutex
1372
1373   if ( $DEBUG ) {
1374     my $balance = $self->balance;
1375     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1376   }
1377
1378   if ( exists($options{'retry_card'}) ) {
1379     carp 'retry_card option passed to collect is deprecated; use retry';
1380     $options{'retry'} ||= $options{'retry_card'};
1381   }
1382   if ( exists($options{'retry'}) && $options{'retry'} ) {
1383     my $error = $self->retry_realtime;
1384     if ( $error ) {
1385       $dbh->rollback if $oldAutoCommit;
1386       return $error;
1387     }
1388   }
1389
1390   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1391
1392   #never want to roll back an event just because it returned an error
1393   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1394
1395   $self->do_cust_event(
1396     'debug'      => ( $options{'debug'} || 0 ),
1397     'time'       => $invoice_time,
1398     'check_freq' => $options{'check_freq'},
1399     'stage'      => 'collect',
1400   );
1401
1402 }
1403
1404 =item retry_realtime
1405
1406 Schedules realtime / batch  credit card / electronic check / LEC billing
1407 events for for retry.  Useful if card information has changed or manual
1408 retry is desired.  The 'collect' method must be called to actually retry
1409 the transaction.
1410
1411 Implementation details: For either this customer, or for each of this
1412 customer's open invoices, changes the status of the first "done" (with
1413 statustext error) realtime processing event to "failed".
1414
1415 =cut
1416
1417 sub retry_realtime {
1418   my $self = shift;
1419
1420   local $SIG{HUP} = 'IGNORE';
1421   local $SIG{INT} = 'IGNORE';
1422   local $SIG{QUIT} = 'IGNORE';
1423   local $SIG{TERM} = 'IGNORE';
1424   local $SIG{TSTP} = 'IGNORE';
1425   local $SIG{PIPE} = 'IGNORE';
1426
1427   my $oldAutoCommit = $FS::UID::AutoCommit;
1428   local $FS::UID::AutoCommit = 0;
1429   my $dbh = dbh;
1430
1431   #a little false laziness w/due_cust_event (not too bad, really)
1432
1433   my $join = FS::part_event_condition->join_conditions_sql;
1434   my $order = FS::part_event_condition->order_conditions_sql;
1435   my $mine =
1436   '( '
1437    . join ( ' OR ' , map {
1438     "( part_event.eventtable = " . dbh->quote($_)
1439     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1440    } FS::part_event->eventtables)
1441    . ') ';
1442
1443   #here is the agent virtualization
1444   my $agent_virt = " (    part_event.agentnum IS NULL
1445                        OR part_event.agentnum = ". $self->agentnum. ' )';
1446
1447   #XXX this shouldn't be hardcoded, actions should declare it...
1448   my @realtime_events = qw(
1449     cust_bill_realtime_card
1450     cust_bill_realtime_check
1451     cust_bill_realtime_lec
1452     cust_bill_batch
1453   );
1454
1455   my $is_realtime_event = ' ( '. join(' OR ', map "part_event.action = '$_'",
1456                                                   @realtime_events
1457                                      ).
1458                           ' ) ';
1459
1460   my @cust_event = qsearchs({
1461     'table'     => 'cust_event',
1462     'select'    => 'cust_event.*',
1463     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1464     'hashref'   => { 'status' => 'done' },
1465     'extra_sql' => " AND statustext IS NOT NULL AND statustext != '' ".
1466                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1467   });
1468
1469   my %seen_invnum = ();
1470   foreach my $cust_event (@cust_event) {
1471
1472     #max one for the customer, one for each open invoice
1473     my $cust_X = $cust_event->cust_X;
1474     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1475                           ? $cust_X->invnum
1476                           : 0
1477                         }++
1478          or $cust_event->part_event->eventtable eq 'cust_bill'
1479             && ! $cust_X->owed;
1480
1481     my $error = $cust_event->retry;
1482     if ( $error ) {
1483       $dbh->rollback if $oldAutoCommit;
1484       return "error scheduling event for retry: $error";
1485     }
1486
1487   }
1488
1489   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1490   '';
1491
1492 }
1493
1494 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1495
1496 Runs billing events; see L<FS::part_event> and the billing events web
1497 interface.
1498
1499 If there is an error, returns the error, otherwise returns false.
1500
1501 Options are passed as name-value pairs.
1502
1503 Currently available options are:
1504
1505 =over 4
1506
1507 =item time
1508
1509 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1510
1511 =item check_freq
1512
1513 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1514
1515 =item stage
1516
1517 "collect" (the default) or "pre-bill"
1518
1519 =item quiet
1520
1521 set true to surpress email card/ACH decline notices.
1522
1523 =item debug
1524
1525 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1526
1527 =back
1528 =cut
1529
1530 # =item payby
1531 #
1532 # allows for one time override of normal customer billing method
1533
1534 # =item retry
1535 #
1536 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1537
1538 sub do_cust_event {
1539   my( $self, %options ) = @_;
1540
1541   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1542
1543   my $time = $options{'time'} || time;
1544
1545   #put below somehow?
1546   local $SIG{HUP} = 'IGNORE';
1547   local $SIG{INT} = 'IGNORE';
1548   local $SIG{QUIT} = 'IGNORE';
1549   local $SIG{TERM} = 'IGNORE';
1550   local $SIG{TSTP} = 'IGNORE';
1551   local $SIG{PIPE} = 'IGNORE';
1552
1553   my $oldAutoCommit = $FS::UID::AutoCommit;
1554   local $FS::UID::AutoCommit = 0;
1555   my $dbh = dbh;
1556
1557   $self->select_for_update; #mutex
1558
1559   if ( $DEBUG ) {
1560     my $balance = $self->balance;
1561     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1562   }
1563
1564 #  if ( exists($options{'retry_card'}) ) {
1565 #    carp 'retry_card option passed to collect is deprecated; use retry';
1566 #    $options{'retry'} ||= $options{'retry_card'};
1567 #  }
1568 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1569 #    my $error = $self->retry_realtime;
1570 #    if ( $error ) {
1571 #      $dbh->rollback if $oldAutoCommit;
1572 #      return $error;
1573 #    }
1574 #  }
1575
1576   # false laziness w/pay_batch::import_results
1577
1578   my $due_cust_event = $self->due_cust_event(
1579     'debug'      => ( $options{'debug'} || 0 ),
1580     'time'       => $time,
1581     'check_freq' => $options{'check_freq'},
1582     'stage'      => ( $options{'stage'} || 'collect' ),
1583   );
1584   unless( ref($due_cust_event) ) {
1585     $dbh->rollback if $oldAutoCommit;
1586     return $due_cust_event;
1587   }
1588
1589   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1590   #never want to roll back an event just because it or a different one
1591   # returned an error
1592   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1593
1594   foreach my $cust_event ( @$due_cust_event ) {
1595
1596     #XXX lock event
1597
1598     #re-eval event conditions (a previous event could have changed things)
1599     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1600       #don't leave stray "new/locked" records around
1601       my $error = $cust_event->delete;
1602       return $error if $error;
1603       next;
1604     }
1605
1606     {
1607       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1608         if $options{'quiet'};
1609       warn "  running cust_event ". $cust_event->eventnum. "\n"
1610         if $DEBUG > 1;
1611
1612       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1613       if ( my $error = $cust_event->do_event() ) {
1614         #XXX wtf is this?  figure out a proper dealio with return value
1615         #from do_event
1616         return $error;
1617       }
1618     }
1619
1620   }
1621
1622   '';
1623
1624 }
1625
1626 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1627
1628 Inserts database records for and returns an ordered listref of new events due
1629 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1630 events are due, an empty listref is returned.  If there is an error, returns a
1631 scalar error message.
1632
1633 To actually run the events, call each event's test_condition method, and if
1634 still true, call the event's do_event method.
1635
1636 Options are passed as a hashref or as a list of name-value pairs.  Available
1637 options are:
1638
1639 =over 4
1640
1641 =item check_freq
1642
1643 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1644
1645 =item stage
1646
1647 "collect" (the default) or "pre-bill"
1648
1649 =item time
1650
1651 "Current time" for the events.
1652
1653 =item debug
1654
1655 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1656
1657 =item eventtable
1658
1659 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1660
1661 =item objects
1662
1663 Explicitly pass the objects to be tested (typically used with eventtable).
1664
1665 =item testonly
1666
1667 Set to true to return the objects, but not actually insert them into the
1668 database.
1669
1670 =back
1671
1672 =cut
1673
1674 sub due_cust_event {
1675   my $self = shift;
1676   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1677
1678   #???
1679   #my $DEBUG = $opt{'debug'}
1680   local($DEBUG) = $opt{'debug'}
1681     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1682   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1683
1684   warn "$me due_cust_event called with options ".
1685        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1686     if $DEBUG;
1687
1688   $opt{'time'} ||= time;
1689
1690   local $SIG{HUP} = 'IGNORE';
1691   local $SIG{INT} = 'IGNORE';
1692   local $SIG{QUIT} = 'IGNORE';
1693   local $SIG{TERM} = 'IGNORE';
1694   local $SIG{TSTP} = 'IGNORE';
1695   local $SIG{PIPE} = 'IGNORE';
1696
1697   my $oldAutoCommit = $FS::UID::AutoCommit;
1698   local $FS::UID::AutoCommit = 0;
1699   my $dbh = dbh;
1700
1701   $self->select_for_update #mutex
1702     unless $opt{testonly};
1703
1704   ###
1705   # find possible events (initial search)
1706   ###
1707
1708   my @cust_event = ();
1709
1710   my @eventtable = $opt{'eventtable'}
1711                      ? ( $opt{'eventtable'} )
1712                      : FS::part_event->eventtables_runorder;
1713
1714   my $check_freq = $opt{'check_freq'} || '1d';
1715
1716   foreach my $eventtable ( @eventtable ) {
1717
1718     my @objects;
1719     if ( $opt{'objects'} ) {
1720
1721       @objects = @{ $opt{'objects'} };
1722
1723     } else {
1724
1725       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1726       if ( $eventtable eq 'cust_main' ) {
1727         @objects = ( $self );
1728       } else {
1729
1730         my $cm_join =
1731           "LEFT JOIN cust_main USING ( custnum )";
1732
1733         #some false laziness w/Cron::bill bill_where
1734
1735         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1736         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1737                                                            'time'=>$opt{'time'},
1738                                                                   );
1739         $where = $where ? "AND $where" : '';
1740
1741         my $are_part_event =
1742           "EXISTS ( SELECT 1 FROM part_event $join
1743                       WHERE check_freq = '$check_freq'
1744                         AND eventtable = '$eventtable'
1745                         AND ( disabled = '' OR disabled IS NULL )
1746                         $where
1747                   )
1748           ";
1749         #eofalse
1750
1751         @objects = $self->$eventtable(
1752                      'addl_from' => $cm_join,
1753                      'extra_sql' => " AND $are_part_event",
1754                    );
1755       }
1756
1757     }
1758
1759     my @e_cust_event = ();
1760
1761     my $cross = "CROSS JOIN $eventtable";
1762     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1763       unless $eventtable eq 'cust_main';
1764
1765     foreach my $object ( @objects ) {
1766
1767       #this first search uses the condition_sql magic for optimization.
1768       #the more possible events we can eliminate in this step the better
1769
1770       my $cross_where = '';
1771       my $pkey = $object->primary_key;
1772       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1773
1774       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1775       my $extra_sql =
1776         FS::part_event_condition->where_conditions_sql( $eventtable,
1777                                                         'time'=>$opt{'time'}
1778                                                       );
1779       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1780
1781       $extra_sql = "AND $extra_sql" if $extra_sql;
1782
1783       #here is the agent virtualization
1784       $extra_sql .= " AND (    part_event.agentnum IS NULL
1785                             OR part_event.agentnum = ". $self->agentnum. ' )';
1786
1787       $extra_sql .= " $order";
1788
1789       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1790         if $opt{'debug'} > 2;
1791       my @part_event = qsearch( {
1792         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1793         'select'    => 'part_event.*',
1794         'table'     => 'part_event',
1795         'addl_from' => "$cross $join",
1796         'hashref'   => { 'check_freq' => $check_freq,
1797                          'eventtable' => $eventtable,
1798                          'disabled'   => '',
1799                        },
1800         'extra_sql' => "AND $cross_where $extra_sql",
1801       } );
1802
1803       if ( $DEBUG > 2 ) {
1804         my $pkey = $object->primary_key;
1805         warn "      ". scalar(@part_event).
1806              " possible events found for $eventtable ". $object->$pkey(). "\n";
1807       }
1808
1809       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1810
1811     }
1812
1813     warn "    ". scalar(@e_cust_event).
1814          " subtotal possible cust events found for $eventtable\n"
1815       if $DEBUG > 1;
1816
1817     push @cust_event, @e_cust_event;
1818
1819   }
1820
1821   warn "  ". scalar(@cust_event).
1822        " total possible cust events found in initial search\n"
1823     if $DEBUG; # > 1;
1824
1825
1826   ##
1827   # test stage
1828   ##
1829
1830   $opt{stage} ||= 'collect';
1831   @cust_event =
1832     grep { my $stage = $_->part_event->event_stage;
1833            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1834          }
1835          @cust_event;
1836
1837   ##
1838   # test conditions
1839   ##
1840
1841   my %unsat = ();
1842
1843   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1844                                           'stats_hashref' => \%unsat ),
1845                      @cust_event;
1846
1847   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1848     if $DEBUG; # > 1;
1849
1850   warn "    invalid conditions not eliminated with condition_sql:\n".
1851        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1852     if keys %unsat && $DEBUG; # > 1;
1853
1854   ##
1855   # insert
1856   ##
1857
1858   unless( $opt{testonly} ) {
1859     foreach my $cust_event ( @cust_event ) {
1860
1861       my $error = $cust_event->insert();
1862       if ( $error ) {
1863         $dbh->rollback if $oldAutoCommit;
1864         return $error;
1865       }
1866
1867     }
1868   }
1869
1870   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1871
1872   ##
1873   # return
1874   ##
1875
1876   warn "  returning events: ". Dumper(@cust_event). "\n"
1877     if $DEBUG > 2;
1878
1879   \@cust_event;
1880
1881 }
1882
1883 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1884
1885 Applies unapplied payments and credits.
1886
1887 In most cases, this new method should be used in place of sequential
1888 apply_payments and apply_credits methods.
1889
1890 A hash of optional arguments may be passed.  Currently "manual" is supported.
1891 If true, a payment receipt is sent instead of a statement when
1892 'payment_receipt_email' configuration option is set.
1893
1894 If there is an error, returns the error, otherwise returns false.
1895
1896 =cut
1897
1898 sub apply_payments_and_credits {
1899   my( $self, %options ) = @_;
1900
1901   local $SIG{HUP} = 'IGNORE';
1902   local $SIG{INT} = 'IGNORE';
1903   local $SIG{QUIT} = 'IGNORE';
1904   local $SIG{TERM} = 'IGNORE';
1905   local $SIG{TSTP} = 'IGNORE';
1906   local $SIG{PIPE} = 'IGNORE';
1907
1908   my $oldAutoCommit = $FS::UID::AutoCommit;
1909   local $FS::UID::AutoCommit = 0;
1910   my $dbh = dbh;
1911
1912   $self->select_for_update; #mutex
1913
1914   foreach my $cust_bill ( $self->open_cust_bill ) {
1915     my $error = $cust_bill->apply_payments_and_credits(%options);
1916     if ( $error ) {
1917       $dbh->rollback if $oldAutoCommit;
1918       return "Error applying: $error";
1919     }
1920   }
1921
1922   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1923   ''; #no error
1924
1925 }
1926
1927 =item apply_credits OPTION => VALUE ...
1928
1929 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1930 to outstanding invoice balances in chronological order (or reverse
1931 chronological order if the I<order> option is set to B<newest>) and returns the
1932 value of any remaining unapplied credits available for refund (see
1933 L<FS::cust_refund>).
1934
1935 Dies if there is an error.
1936
1937 =cut
1938
1939 sub apply_credits {
1940   my $self = shift;
1941   my %opt = @_;
1942
1943   local $SIG{HUP} = 'IGNORE';
1944   local $SIG{INT} = 'IGNORE';
1945   local $SIG{QUIT} = 'IGNORE';
1946   local $SIG{TERM} = 'IGNORE';
1947   local $SIG{TSTP} = 'IGNORE';
1948   local $SIG{PIPE} = 'IGNORE';
1949
1950   my $oldAutoCommit = $FS::UID::AutoCommit;
1951   local $FS::UID::AutoCommit = 0;
1952   my $dbh = dbh;
1953
1954   $self->select_for_update; #mutex
1955
1956   unless ( $self->total_unapplied_credits ) {
1957     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1958     return 0;
1959   }
1960
1961   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1962       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1963
1964   my @invoices = $self->open_cust_bill;
1965   @invoices = sort { $b->_date <=> $a->_date } @invoices
1966     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
1967
1968   if ( $conf->exists('pkg-balances') ) {
1969     # limit @credits to those w/ a pkgnum grepped from $self
1970     my %pkgnums = ();
1971     foreach my $i (@invoices) {
1972       foreach my $li ( $i->cust_bill_pkg ) {
1973         $pkgnums{$li->pkgnum} = 1;
1974       }
1975     }
1976     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
1977   }
1978
1979   my $credit;
1980
1981   foreach my $cust_bill ( @invoices ) {
1982
1983     if ( !defined($credit) || $credit->credited == 0) {
1984       $credit = pop @credits or last;
1985     }
1986
1987     my $owed;
1988     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
1989       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
1990     } else {
1991       $owed = $cust_bill->owed;
1992     }
1993     unless ( $owed > 0 ) {
1994       push @credits, $credit;
1995       next;
1996     }
1997
1998     my $amount = min( $credit->credited, $owed );
1999
2000     my $cust_credit_bill = new FS::cust_credit_bill ( {
2001       'crednum' => $credit->crednum,
2002       'invnum'  => $cust_bill->invnum,
2003       'amount'  => $amount,
2004     } );
2005     $cust_credit_bill->pkgnum( $credit->pkgnum )
2006       if $conf->exists('pkg-balances') && $credit->pkgnum;
2007     my $error = $cust_credit_bill->insert;
2008     if ( $error ) {
2009       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2010       die $error;
2011     }
2012
2013     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2014
2015   }
2016
2017   my $total_unapplied_credits = $self->total_unapplied_credits;
2018
2019   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2020
2021   return $total_unapplied_credits;
2022 }
2023
2024 =item apply_payments  [ OPTION => VALUE ... ]
2025
2026 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2027 to outstanding invoice balances in chronological order.
2028
2029  #and returns the value of any remaining unapplied payments.
2030
2031 A hash of optional arguments may be passed.  Currently "manual" is supported.
2032 If true, a payment receipt is sent instead of a statement when
2033 'payment_receipt_email' configuration option is set.
2034
2035 Dies if there is an error.
2036
2037 =cut
2038
2039 sub apply_payments {
2040   my( $self, %options ) = @_;
2041
2042   local $SIG{HUP} = 'IGNORE';
2043   local $SIG{INT} = 'IGNORE';
2044   local $SIG{QUIT} = 'IGNORE';
2045   local $SIG{TERM} = 'IGNORE';
2046   local $SIG{TSTP} = 'IGNORE';
2047   local $SIG{PIPE} = 'IGNORE';
2048
2049   my $oldAutoCommit = $FS::UID::AutoCommit;
2050   local $FS::UID::AutoCommit = 0;
2051   my $dbh = dbh;
2052
2053   $self->select_for_update; #mutex
2054
2055   #return 0 unless
2056
2057   my @payments = sort { $b->_date <=> $a->_date }
2058                  grep { $_->unapplied > 0 }
2059                  $self->cust_pay;
2060
2061   my @invoices = sort { $a->_date <=> $b->_date}
2062                  grep { $_->owed > 0 }
2063                  $self->cust_bill;
2064
2065   if ( $conf->exists('pkg-balances') ) {
2066     # limit @payments to those w/ a pkgnum grepped from $self
2067     my %pkgnums = ();
2068     foreach my $i (@invoices) {
2069       foreach my $li ( $i->cust_bill_pkg ) {
2070         $pkgnums{$li->pkgnum} = 1;
2071       }
2072     }
2073     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2074   }
2075
2076   my $payment;
2077
2078   foreach my $cust_bill ( @invoices ) {
2079
2080     if ( !defined($payment) || $payment->unapplied == 0 ) {
2081       $payment = pop @payments or last;
2082     }
2083
2084     my $owed;
2085     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2086       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2087     } else {
2088       $owed = $cust_bill->owed;
2089     }
2090     unless ( $owed > 0 ) {
2091       push @payments, $payment;
2092       next;
2093     }
2094
2095     my $amount = min( $payment->unapplied, $owed );
2096
2097     my $cust_bill_pay = new FS::cust_bill_pay ( {
2098       'paynum' => $payment->paynum,
2099       'invnum' => $cust_bill->invnum,
2100       'amount' => $amount,
2101     } );
2102     $cust_bill_pay->pkgnum( $payment->pkgnum )
2103       if $conf->exists('pkg-balances') && $payment->pkgnum;
2104     my $error = $cust_bill_pay->insert(%options);
2105     if ( $error ) {
2106       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2107       die $error;
2108     }
2109
2110     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2111
2112   }
2113
2114   my $total_unapplied_payments = $self->total_unapplied_payments;
2115
2116   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2117
2118   return $total_unapplied_payments;
2119 }
2120
2121 =back
2122
2123 =head1 FLOW
2124
2125   bill_and_collect
2126
2127     cancel_expired_pkgs
2128     suspend_adjourned_pkgs
2129
2130     bill
2131       (do_cust_event pre-bill)
2132       _make_lines
2133         _handle_taxes
2134           (vendor-only) _gather_taxes
2135       _omit_zero_value_bundles
2136       calculate_taxes
2137
2138     apply_payments_and_credits
2139     collect
2140       do_cust_event
2141         due_cust_event
2142
2143 =head1 BUGS
2144
2145 =head1 SEE ALSO
2146
2147 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2148
2149 =cut
2150
2151 1;