FS/FS/cust_main.pm

   1 package FS::cust_main;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $Debug $import );
   5 use Safe;
   6 use Carp;
   7 use Time::Local;
   8 use Date::Format;
   9 #use Date::Manip;
  10 use Business::CreditCard;
  11 use FS::UID qw( getotaker dbh );
  12 use FS::Record qw( qsearchs qsearch dbdef );
  13 use FS::cust_pkg;
  14 use FS::cust_bill;
  15 use FS::cust_bill_pkg;
  16 use FS::cust_pay;
  17 use FS::cust_credit;
  18 use FS::part_referral;
  19 use FS::cust_main_county;
  20 use FS::agent;
  21 use FS::cust_main_invoice;
  22 use FS::cust_credit_bill;
  23 use FS::cust_bill_pay;
  24 use FS::prepay_credit;
  25 use FS::queue;
  26 use FS::part_pkg;
  27 use FS::part_bill_event;
  28 use FS::cust_bill_event;
  29
  30 @ISA = qw( FS::Record );
  31
  32 $Debug = 0;
  33 #$Debug = 1;
  34
  35 $import = 0;
  36
  37 #ask FS::UID to run this stuff for us later
  38 $FS::UID::callback{'FS::cust_main'} = sub {
  39   $conf = new FS::Conf;
  40   #yes, need it for stuff below (prolly should be cached)
  41 };
  42
  43 sub _cache {
  44   my $self = shift;
  45   my ( $hashref, $cache ) = @_;
  46   if ( exists $hashref->{'pkgnum'} ) {
  47 #    #@{ $self->{'_pkgnum'} } = ();
  48     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
  49     $self->{'_pkgnum'} = $subcache;
  50     #push @{ $self->{'_pkgnum'} },
  51     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
  52   }
  53 }
  54
  55 =head1 NAME
  56
  57 FS::cust_main - Object methods for cust_main records
  58
  59 =head1 SYNOPSIS
  60
  61   use FS::cust_main;
  62
  63   $record = new FS::cust_main \%hash;
  64   $record = new FS::cust_main { 'column' => 'value' };
  65
  66   $error = $record->insert;
  67
  68   $error = $new_record->replace($old_record);
  69
  70   $error = $record->delete;
  71
  72   $error = $record->check;
  73
  74   @cust_pkg = $record->all_pkgs;
  75
  76   @cust_pkg = $record->ncancelled_pkgs;
  77
  78   @cust_pkg = $record->suspended_pkgs;
  79
  80   $error = $record->bill;
  81   $error = $record->bill %options;
  82   $error = $record->bill 'time' => $time;
  83
  84   $error = $record->collect;
  85   $error = $record->collect %options;
  86   $error = $record->collect 'invoice_time'   => $time,
  87                             'batch_card'     => 'yes',
  88                             'report_badcard' => 'yes',
  89                           ;
  90
  91 =head1 DESCRIPTION
  92
  93 An FS::cust_main object represents a customer.  FS::cust_main inherits from
  94 FS::Record.  The following fields are currently supported:
  95
  96 =over 4
  97
  98 =item custnum - primary key (assigned automatically for new customers)
  99
 100 =item agentnum - agent (see L<FS::agent>)
 101
 102 =item refnum - referral (see L<FS::part_referral>)
 103
 104 =item first - name
 105
 106 =item last - name
 107
 108 =item ss - social security number (optional)
 109
 110 =item company - (optional)
 111
 112 =item address1
 113
 114 =item address2 - (optional)
 115
 116 =item city
 117
 118 =item county - (optional, see L<FS::cust_main_county>)
 119
 120 =item state - (see L<FS::cust_main_county>)
 121
 122 =item zip
 123
 124 =item country - (see L<FS::cust_main_county>)
 125
 126 =item daytime - phone (optional)
 127
 128 =item night - phone (optional)
 129
 130 =item fax - phone (optional)
 131
 132 =item ship_first - name
 133
 134 =item ship_last - name
 135
 136 =item ship_company - (optional)
 137
 138 =item ship_address1
 139
 140 =item ship_address2 - (optional)
 141
 142 =item ship_city
 143
 144 =item ship_county - (optional, see L<FS::cust_main_county>)
 145
 146 =item ship_state - (see L<FS::cust_main_county>)
 147
 148 =item ship_zip
 149
 150 =item ship_country - (see L<FS::cust_main_county>)
 151
 152 =item ship_daytime - phone (optional)
 153
 154 =item ship_night - phone (optional)
 155
 156 =item ship_fax - phone (optional)
 157
 158 =item payby - `CARD' (credit cards), `BILL' (billing), `COMP' (free), or `PREPAY' (special billing type: applies a credit - see L<FS::prepay_credit> and sets billing type to BILL)
 159
 160 =item payinfo - card number, P.O., comp issuer (4-8 lowercase alphanumerics; think username) or prepayment identifier (see L<FS::prepay_credit>)
 161
 162 =item paydate - expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 163
 164 =item payname - name on card or billing name
 165
 166 =item tax - tax exempt, empty or `Y'
 167
 168 =item otaker - order taker (assigned automatically, see L<FS::UID>)
 169
 170 =item comments - comments (optional)
 171
 172 =back
 173
 174 =head1 METHODS
 175
 176 =over 4
 177
 178 =item new HASHREF
 179
 180 Creates a new customer.  To add the customer to the database, see L<"insert">.
 181
 182 Note that this stores the hash reference, not a distinct copy of the hash it
 183 points to.  You can ask the object for a copy with the I<hash> method.
 184
 185 =cut
 186
 187 sub table { 'cust_main'; }
 188
 189 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] ]
 190
 191 Adds this customer to the database.  If there is an error, returns the error,
 192 otherwise returns false.
 193
 194 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 195 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 196 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 197 hash reference is equivalent to not supplying this parameter.  There should be
 198 a better explanation of this, but until then, here's an example:
 199
 200   use Tie::RefHash;
 201   tie %hash, 'Tie::RefHash'; #this part is important
 202   %hash = (
 203     $cust_pkg => [ $svc_acct ],
 204     ...
 205   );
 206   $cust_main->insert( \%hash );
 207
 208 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 209 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 210 expected and rollback the entire transaction; it is not necessary to call
 211 check_invoicing_list first.  The invoicing_list is set after the records in the
 212 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 213 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 214
 215   $cust_main->insert( {}, [ $email, 'POST' ] );
 216
 217 =cut
 218
 219 sub insert {
 220   my $self = shift;
 221   my @param = @_;
 222
 223   local $SIG{HUP} = 'IGNORE';
 224   local $SIG{INT} = 'IGNORE';
 225   local $SIG{QUIT} = 'IGNORE';
 226   local $SIG{TERM} = 'IGNORE';
 227   local $SIG{TSTP} = 'IGNORE';
 228   local $SIG{PIPE} = 'IGNORE';
 229
 230   my $oldAutoCommit = $FS::UID::AutoCommit;
 231   local $FS::UID::AutoCommit = 0;
 232   my $dbh = dbh;
 233
 234   my $amount = 0;
 235   my $seconds = 0;
 236   if ( $self->payby eq 'PREPAY' ) {
 237     $self->payby('BILL');
 238     my $prepay_credit = qsearchs(
 239       'prepay_credit',
 240       { 'identifier' => $self->payinfo },
 241       '',
 242       'FOR UPDATE'
 243     );
 244     warn "WARNING: can't find pre-found prepay_credit: ". $self->payinfo
 245       unless $prepay_credit;
 246     $amount = $prepay_credit->amount;
 247     $seconds = $prepay_credit->seconds;
 248     my $error = $prepay_credit->delete;
 249     if ( $error ) {
 250       $dbh->rollback if $oldAutoCommit;
 251       return "removing prepay_credit (transaction rolled back): $error";
 252     }
 253   }
 254
 255   my $error = $self->SUPER::insert;
 256   if ( $error ) {
 257     $dbh->rollback if $oldAutoCommit;
 258     return "inserting cust_main record (transaction rolled back): $error";
 259   }
 260
 261   if ( @param ) { # CUST_PKG_HASHREF
 262     my $cust_pkgs = shift @param;
 263     foreach my $cust_pkg ( keys %$cust_pkgs ) {
 264       $cust_pkg->custnum( $self->custnum );
 265       $error = $cust_pkg->insert;
 266       if ( $error ) {
 267         $dbh->rollback if $oldAutoCommit;
 268         return "inserting cust_pkg (transaction rolled back): $error";
 269       }
 270       foreach my $svc_something ( @{$cust_pkgs->{$cust_pkg}} ) {
 271         $svc_something->pkgnum( $cust_pkg->pkgnum );
 272         if ( $seconds && $svc_something->isa('FS::svc_acct') ) {
 273           $svc_something->seconds( $svc_something->seconds + $seconds );
 274           $seconds = 0;
 275         }
 276         $error = $svc_something->insert;
 277         if ( $error ) {
 278           $dbh->rollback if $oldAutoCommit;
 279           return "inserting svc_ (transaction rolled back): $error";
 280         }
 281       }
 282     }
 283   }
 284
 285   if ( $seconds ) {
 286     $dbh->rollback if $oldAutoCommit;
 287     return "No svc_acct record to apply pre-paid time";
 288   }
 289
 290   if ( @param ) { # INVOICING_LIST_ARYREF
 291     my $invoicing_list = shift @param;
 292     $error = $self->check_invoicing_list( $invoicing_list );
 293     if ( $error ) {
 294       $dbh->rollback if $oldAutoCommit;
 295       return "checking invoicing_list (transaction rolled back): $error";
 296     }
 297     $self->invoicing_list( $invoicing_list );
 298   }
 299
 300   if ( $amount ) {
 301     my $cust_credit = new FS::cust_credit {
 302       'custnum' => $self->custnum,
 303       'amount'  => $amount,
 304     };
 305     $error = $cust_credit->insert;
 306     if ( $error ) {
 307       $dbh->rollback if $oldAutoCommit;
 308       return "inserting credit (transaction rolled back): $error";
 309     }
 310   }
 311
 312   #false laziness with sub replace
 313   my $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
 314   $error = $queue->insert($self->getfield('last'), $self->company);
 315   if ( $error ) {
 316     $dbh->rollback if $oldAutoCommit;
 317     return "queueing job (transaction rolled back): $error";
 318   }
 319
 320   if ( defined $self->dbdef_table->column('ship_last') && $self->ship_last ) {
 321     $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
 322     $error = $queue->insert($self->getfield('last'), $self->company);
 323     if ( $error ) {
 324       $dbh->rollback if $oldAutoCommit;
 325       return "queueing job (transaction rolled back): $error";
 326     }
 327   }
 328   #eslaf
 329
 330   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 331   '';
 332
 333 }
 334
 335 =item delete NEW_CUSTNUM
 336
 337 This deletes the customer.  If there is an error, returns the error, otherwise
 338 returns false.
 339
 340 This will completely remove all traces of the customer record.  This is not
 341 what you want when a customer cancels service; for that, cancel all of the
 342 customer's packages (see L<FS::cust_pkg/cancel>).
 343
 344 If the customer has any uncancelled packages, you need to pass a new (valid)
 345 customer number for those packages to be transferred to.  Cancelled packages
 346 will be deleted.  Did I mention that this is NOT what you want when a customer
 347 cancels service and that you really should be looking see L<FS::cust_pkg/cancel>?
 348
 349 You can't delete a customer with invoices (see L<FS::cust_bill>),
 350 or credits (see L<FS::cust_credit>), payments (see L<FS::cust_pay>) or
 351 refunds (see L<FS::cust_refund>).
 352
 353 =cut
 354
 355 sub delete {
 356   my $self = shift;
 357
 358   local $SIG{HUP} = 'IGNORE';
 359   local $SIG{INT} = 'IGNORE';
 360   local $SIG{QUIT} = 'IGNORE';
 361   local $SIG{TERM} = 'IGNORE';
 362   local $SIG{TSTP} = 'IGNORE';
 363   local $SIG{PIPE} = 'IGNORE';
 364
 365   my $oldAutoCommit = $FS::UID::AutoCommit;
 366   local $FS::UID::AutoCommit = 0;
 367   my $dbh = dbh;
 368
 369   if ( qsearch( 'cust_bill', { 'custnum' => $self->custnum } ) ) {
 370     $dbh->rollback if $oldAutoCommit;
 371     return "Can't delete a customer with invoices";
 372   }
 373   if ( qsearch( 'cust_credit', { 'custnum' => $self->custnum } ) ) {
 374     $dbh->rollback if $oldAutoCommit;
 375     return "Can't delete a customer with credits";
 376   }
 377   if ( qsearch( 'cust_pay', { 'custnum' => $self->custnum } ) ) {
 378     $dbh->rollback if $oldAutoCommit;
 379     return "Can't delete a customer with payments";
 380   }
 381   if ( qsearch( 'cust_refund', { 'custnum' => $self->custnum } ) ) {
 382     $dbh->rollback if $oldAutoCommit;
 383     return "Can't delete a customer with refunds";
 384   }
 385
 386   my @cust_pkg = $self->ncancelled_pkgs;
 387   if ( @cust_pkg ) {
 388     my $new_custnum = shift;
 389     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
 390       $dbh->rollback if $oldAutoCommit;
 391       return "Invalid new customer number: $new_custnum";
 392     }
 393     foreach my $cust_pkg ( @cust_pkg ) {
 394       my %hash = $cust_pkg->hash;
 395       $hash{'custnum'} = $new_custnum;
 396       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
 397       my $error = $new_cust_pkg->replace($cust_pkg);
 398       if ( $error ) {
 399         $dbh->rollback if $oldAutoCommit;
 400         return $error;
 401       }
 402     }
 403   }
 404   my @cancelled_cust_pkg = $self->all_pkgs;
 405   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
 406     my $error = $cust_pkg->delete;
 407     if ( $error ) {
 408       $dbh->rollback if $oldAutoCommit;
 409       return $error;
 410     }
 411   }
 412
 413   foreach my $cust_main_invoice ( #(email invoice destinations, not invoices)
 414     qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } )
 415   ) {
 416     my $error = $cust_main_invoice->delete;
 417     if ( $error ) {
 418       $dbh->rollback if $oldAutoCommit;
 419       return $error;
 420     }
 421   }
 422
 423   my $error = $self->SUPER::delete;
 424   if ( $error ) {
 425     $dbh->rollback if $oldAutoCommit;
 426     return $error;
 427   }
 428
 429   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 430   '';
 431
 432 }
 433
 434 =item replace OLD_RECORD [ INVOICING_LIST_ARYREF ]
 435
 436 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 437 returns the error, otherwise returns false.
 438
 439 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 440 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 441 expected and rollback the entire transaction; it is not necessary to call
 442 check_invoicing_list first.  Here's an example:
 443
 444   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
 445
 446 =cut
 447
 448 sub replace {
 449   my $self = shift;
 450   my $old = shift;
 451   my @param = @_;
 452
 453   local $SIG{HUP} = 'IGNORE';
 454   local $SIG{INT} = 'IGNORE';
 455   local $SIG{QUIT} = 'IGNORE';
 456   local $SIG{TERM} = 'IGNORE';
 457   local $SIG{TSTP} = 'IGNORE';
 458   local $SIG{PIPE} = 'IGNORE';
 459
 460   my $oldAutoCommit = $FS::UID::AutoCommit;
 461   local $FS::UID::AutoCommit = 0;
 462   my $dbh = dbh;
 463
 464   my $error = $self->SUPER::replace($old);
 465
 466   if ( $error ) {
 467     $dbh->rollback if $oldAutoCommit;
 468     return $error;
 469   }
 470
 471   if ( @param ) { # INVOICING_LIST_ARYREF
 472     my $invoicing_list = shift @param;
 473     $error = $self->check_invoicing_list( $invoicing_list );
 474     if ( $error ) {
 475       $dbh->rollback if $oldAutoCommit;
 476       return $error;
 477     }
 478     $self->invoicing_list( $invoicing_list );
 479   }
 480
 481   #false laziness with sub insert
 482   my $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
 483   $error = $queue->insert($self->getfield('last'), $self->company);
 484   if ( $error ) {
 485     $dbh->rollback if $oldAutoCommit;
 486     return "queueing job (transaction rolled back): $error";
 487   }
 488
 489   if ( defined $self->dbdef_table->column('ship_last') && $self->ship_last ) {
 490     $queue = new FS::queue { 'job' => 'FS::cust_main::append_fuzzyfiles' };
 491     $error = $queue->insert($self->getfield('last'), $self->company);
 492     if ( $error ) {
 493       $dbh->rollback if $oldAutoCommit;
 494       return "queueing job (transaction rolled back): $error";
 495     }
 496   }
 497   #eslaf
 498
 499   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 500   '';
 501
 502 }
 503
 504 =item check
 505
 506 Checks all fields to make sure this is a valid customer record.  If there is
 507 an error, returns the error, otherwise returns false.  Called by the insert
 508 and repalce methods.
 509
 510 =cut
 511
 512 sub check {
 513   my $self = shift;
 514
 515   #warn "BEFORE: \n". $self->_dump;
 516
 517   my $error =
 518     $self->ut_numbern('custnum')
 519     || $self->ut_number('agentnum')
 520     || $self->ut_number('refnum')
 521     || $self->ut_name('last')
 522     || $self->ut_name('first')
 523     || $self->ut_textn('company')
 524     || $self->ut_text('address1')
 525     || $self->ut_textn('address2')
 526     || $self->ut_text('city')
 527     || $self->ut_textn('county')
 528     || $self->ut_textn('state')
 529     || $self->ut_country('country')
 530     || $self->ut_anything('comments')
 531     || $self->ut_numbern('referral_custnum')
 532   ;
 533   #barf.  need message catalogs.  i18n.  etc.
 534   $error .= "Please select a referral."
 535     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
 536   return $error if $error;
 537
 538   return "Unknown agent"
 539     unless qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
 540
 541   return "Unknown referral"
 542     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
 543
 544   return "Unknown referring custnum ". $self->referral_custnum
 545     unless ! $self->referral_custnum
 546            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
 547
 548   if ( $self->ss eq '' ) {
 549     $self->ss('');
 550   } else {
 551     my $ss = $self->ss;
 552     $ss =~ s/\D//g;
 553     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
 554       or return "Illegal social security number: ". $self->ss;
 555     $self->ss("$1-$2-$3");
 556   }
 557
 558
 559 # bad idea to disable, causes billing to fail because of no tax rates later
 560 #  unless ( $import ) {
 561     unless ( qsearchs('cust_main_county', {
 562       'country' => $self->country,
 563       'state'   => '',
 564      } ) ) {
 565       return "Unknown state/county/country: ".
 566         $self->state. "/". $self->county. "/". $self->country
 567         unless qsearchs('cust_main_county',{
 568           'state'   => $self->state,
 569           'county'  => $self->county,
 570           'country' => $self->country,
 571         } );
 572     }
 573 #  }
 574
 575   $error =
 576     $self->ut_phonen('daytime', $self->country)
 577     || $self->ut_phonen('night', $self->country)
 578     || $self->ut_phonen('fax', $self->country)
 579     || $self->ut_zip('zip', $self->country)
 580   ;
 581   return $error if $error;
 582
 583   my @addfields = qw(
 584     last first company address1 address2 city county state zip
 585     country daytime night fax
 586   );
 587
 588   if ( defined $self->dbdef_table->column('ship_last') ) {
 589     if ( scalar ( grep { $self->getfield($_) ne $self->getfield("ship_$_") }
 590                        @addfields )
 591          && scalar ( grep { $self->getfield("ship_$_") ne '' } @addfields )
 592        )
 593     {
 594       my $error =
 595         $self->ut_name('ship_last')
 596         || $self->ut_name('ship_first')
 597         || $self->ut_textn('ship_company')
 598         || $self->ut_text('ship_address1')
 599         || $self->ut_textn('ship_address2')
 600         || $self->ut_text('ship_city')
 601         || $self->ut_textn('ship_county')
 602         || $self->ut_textn('ship_state')
 603         || $self->ut_country('ship_country')
 604       ;
 605       return $error if $error;
 606
 607       #false laziness with above
 608       unless ( qsearchs('cust_main_county', {
 609         'country' => $self->ship_country,
 610         'state'   => '',
 611        } ) ) {
 612         return "Unknown ship_state/ship_county/ship_country: ".
 613           $self->ship_state. "/". $self->ship_county. "/". $self->ship_country
 614           unless qsearchs('cust_main_county',{
 615             'state'   => $self->ship_state,
 616             'county'  => $self->ship_county,
 617             'country' => $self->ship_country,
 618           } );
 619       }
 620       #eofalse
 621
 622       $error =
 623         $self->ut_phonen('ship_daytime', $self->ship_country)
 624         || $self->ut_phonen('ship_night', $self->ship_country)
 625         || $self->ut_phonen('ship_fax', $self->ship_country)
 626         || $self->ut_zip('ship_zip', $self->ship_country)
 627       ;
 628       return $error if $error;
 629
 630     } else { # ship_ info eq billing info, so don't store dup info in database
 631       $self->setfield("ship_$_", '')
 632         foreach qw( last first company address1 address2 city county state zip
 633                     country daytime night fax );
 634     }
 635   }
 636
 637   $self->payby =~ /^(CARD|BILL|COMP|PREPAY)$/
 638     or return "Illegal payby: ". $self->payby;
 639   $self->payby($1);
 640
 641   if ( $self->payby eq 'CARD' ) {
 642
 643     my $payinfo = $self->payinfo;
 644     $payinfo =~ s/\D//g;
 645     $payinfo =~ /^(\d{13,16})$/
 646       or return "Illegal credit card number: ". $self->payinfo;
 647     $payinfo = $1;
 648     $self->payinfo($payinfo);
 649     validate($payinfo)
 650       or return "Illegal credit card number: ". $self->payinfo;
 651     return "Unknown card type" if cardtype($self->payinfo) eq "Unknown";
 652
 653   } elsif ( $self->payby eq 'BILL' ) {
 654
 655     $error = $self->ut_textn('payinfo');
 656     return "Illegal P.O. number: ". $self->payinfo if $error;
 657
 658   } elsif ( $self->payby eq 'COMP' ) {
 659
 660     $error = $self->ut_textn('payinfo');
 661     return "Illegal comp account issuer: ". $self->payinfo if $error;
 662
 663   } elsif ( $self->payby eq 'PREPAY' ) {
 664
 665     my $payinfo = $self->payinfo;
 666     $payinfo =~ s/\W//g; #anything else would just confuse things
 667     $self->payinfo($payinfo);
 668     $error = $self->ut_alpha('payinfo');
 669     return "Illegal prepayment identifier: ". $self->payinfo if $error;
 670     return "Unknown prepayment identifier"
 671       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
 672
 673   }
 674
 675   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
 676     return "Expriation date required"
 677       unless $self->payby eq 'BILL' || $self->payby eq 'PREPAY';
 678     $self->paydate('');
 679   } else {
 680     $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/
 681       or return "Illegal expiration date: ". $self->paydate;
 682     if ( length($2) == 4 ) {
 683       $self->paydate("$2-$1-01");
 684     } else {
 685       $self->paydate("20$2-$1-01");
 686     }
 687   }
 688
 689   if ( $self->payname eq '' ) {
 690     $self->payname( $self->first. " ". $self->getfield('last') );
 691   } else {
 692     $self->payname =~ /^([\w \,\.\-\']+)$/
 693       or return "Illegal billing name: ". $self->payname;
 694     $self->payname($1);
 695   }
 696
 697   $self->tax =~ /^(Y?)$/ or return "Illegal tax: ". $self->tax;
 698   $self->tax($1);
 699
 700   $self->otaker(getotaker);
 701
 702   #warn "AFTER: \n". $self->_dump;
 703
 704   ''; #no error
 705 }
 706
 707 =item all_pkgs
 708
 709 Returns all packages (see L<FS::cust_pkg>) for this customer.
 710
 711 =cut
 712
 713 sub all_pkgs {
 714   my $self = shift;
 715   if ( $self->{'_pkgnum'} ) {
 716     values %{ $self->{'_pkgnum'}->cache };
 717   } else {
 718     qsearch( 'cust_pkg', { 'custnum' => $self->custnum });
 719   }
 720 }
 721
 722 =item ncancelled_pkgs
 723
 724 Returns all non-cancelled packages (see L<FS::cust_pkg>) for this customer.
 725
 726 =cut
 727
 728 sub ncancelled_pkgs {
 729   my $self = shift;
 730   if ( $self->{'_pkgnum'} ) {
 731     grep { ! $_->getfield('cancel') } values %{ $self->{'_pkgnum'}->cache };
 732   } else {
 733     @{ [ # force list context
 734       qsearch( 'cust_pkg', {
 735         'custnum' => $self->custnum,
 736         'cancel'  => '',
 737       }),
 738       qsearch( 'cust_pkg', {
 739         'custnum' => $self->custnum,
 740         'cancel'  => 0,
 741       }),
 742     ] };
 743   }
 744 }
 745
 746 =item suspended_pkgs
 747
 748 Returns all suspended packages (see L<FS::cust_pkg>) for this customer.
 749
 750 =cut
 751
 752 sub suspended_pkgs {
 753   my $self = shift;
 754   grep { $_->susp } $self->ncancelled_pkgs;
 755 }
 756
 757 =item unflagged_suspended_pkgs
 758
 759 Returns all unflagged suspended packages (see L<FS::cust_pkg>) for this
 760 customer (thouse packages without the `manual_flag' set).
 761
 762 =cut
 763
 764 sub unflagged_suspended_pkgs {
 765   my $self = shift;
 766   return $self->suspended_pkgs
 767     unless dbdef->table('cust_pkg')->column('manual_flag');
 768   grep { ! $_->manual_flag } $self->suspended_pkgs;
 769 }
 770
 771 =item unsuspended_pkgs
 772
 773 Returns all unsuspended (and uncancelled) packages (see L<FS::cust_pkg>) for
 774 this customer.
 775
 776 =cut
 777
 778 sub unsuspended_pkgs {
 779   my $self = shift;
 780   grep { ! $_->susp } $self->ncancelled_pkgs;
 781 }
 782
 783 =item unsuspend
 784
 785 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
 786 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
 787 on success or a list of errors.
 788
 789 =cut
 790
 791 sub unsuspend {
 792   my $self = shift;
 793   grep { $_->unsuspend } $self->suspended_pkgs;
 794 }
 795
 796 =item suspend
 797
 798 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
 799 Always returns a list: an empty list on success or a list of errors.
 800
 801 =cut
 802
 803 sub suspend {
 804   my $self = shift;
 805   grep { $_->suspend } $self->unsuspended_pkgs;
 806 }
 807
 808 =item cancel
 809
 810 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
 811 Always returns a list: an empty list on success or a list of errors.
 812
 813 =cut
 814
 815 sub cancel {
 816   my $self = shift;
 817   grep { $_->cancel } $self->ncancelled_pkgs;
 818 }
 819
 820 =item bill OPTIONS
 821
 822 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 823 conjunction with the collect method.
 824
 825 Options are passed as name-value pairs.
 826
 827 The only currently available option is `time', which bills the customer as if
 828 it were that time.  It is specified as a UNIX timestamp; see
 829 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
 830 functions.  For example:
 831
 832  use Date::Parse;
 833  ...
 834  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 835
 836 If there is an error, returns the error, otherwise returns false.
 837
 838 =cut
 839
 840 sub bill {
 841   my( $self, %options ) = @_;
 842   my $time = $options{'time'} || time;
 843
 844   my $error;
 845
 846   #put below somehow?
 847   local $SIG{HUP} = 'IGNORE';
 848   local $SIG{INT} = 'IGNORE';
 849   local $SIG{QUIT} = 'IGNORE';
 850   local $SIG{TERM} = 'IGNORE';
 851   local $SIG{TSTP} = 'IGNORE';
 852   local $SIG{PIPE} = 'IGNORE';
 853
 854   my $oldAutoCommit = $FS::UID::AutoCommit;
 855   local $FS::UID::AutoCommit = 0;
 856   my $dbh = dbh;
 857
 858   # find the packages which are due for billing, find out how much they are
 859   # & generate invoice database.
 860
 861   my( $total_setup, $total_recur ) = ( 0, 0 );
 862   my( $taxable_setup, $taxable_recur ) = ( 0, 0 );
 863   my @cust_bill_pkg = ();
 864
 865   foreach my $cust_pkg (
 866     qsearch('cust_pkg', { 'custnum' => $self->custnum } )
 867   ) {
 868
 869     #NO!! next if $cust_pkg->cancel;
 870     next if $cust_pkg->getfield('cancel');
 871
 872     #? to avoid use of uninitialized value errors... ?
 873     $cust_pkg->setfield('bill', '')
 874       unless defined($cust_pkg->bill);
 875
 876     my $part_pkg = qsearchs( 'part_pkg', { 'pkgpart' => $cust_pkg->pkgpart } );
 877
 878     #so we don't modify cust_pkg record unnecessarily
 879     my $cust_pkg_mod_flag = 0;
 880     my %hash = $cust_pkg->hash;
 881     my $old_cust_pkg = new FS::cust_pkg \%hash;
 882
 883     # bill setup
 884     my $setup = 0;
 885     unless ( $cust_pkg->setup ) {
 886       my $setup_prog = $part_pkg->getfield('setup');
 887       $setup_prog =~ /^(.*)$/ or do {
 888         $dbh->rollback if $oldAutoCommit;
 889         return "Illegal setup for pkgpart ". $part_pkg->pkgpart.
 890                ": $setup_prog";
 891       };
 892       $setup_prog = $1;
 893
 894         #my $cpt = new Safe;
 895         ##$cpt->permit(); #what is necessary?
 896         #$cpt->share(qw( $cust_pkg )); #can $cpt now use $cust_pkg methods?
 897         #$setup = $cpt->reval($setup_prog);
 898       $setup = eval $setup_prog;
 899       unless ( defined($setup) ) {
 900         $dbh->rollback if $oldAutoCommit;
 901         return "Error eval-ing part_pkg->setup pkgpart ". $part_pkg->pkgpart.
 902                "(expression $setup_prog): $@";
 903       }
 904       $cust_pkg->setfield('setup',$time);
 905       $cust_pkg_mod_flag=1;
 906     }
 907
 908     #bill recurring fee
 909     my $recur = 0;
 910     my $sdate;
 911     if ( $part_pkg->getfield('freq') > 0 &&
 912          ! $cust_pkg->getfield('susp') &&
 913          ( $cust_pkg->getfield('bill') || 0 ) < $time
 914     ) {
 915       my $recur_prog = $part_pkg->getfield('recur');
 916       $recur_prog =~ /^(.*)$/ or do {
 917         $dbh->rollback if $oldAutoCommit;
 918         return "Illegal recur for pkgpart ". $part_pkg->pkgpart.
 919                ": $recur_prog";
 920       };
 921       $recur_prog = $1;
 922
 923       # shared with $recur_prog
 924       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 925
 926         #my $cpt = new Safe;
 927         ##$cpt->permit(); #what is necessary?
 928         #$cpt->share(qw( $cust_pkg )); #can $cpt now use $cust_pkg methods?
 929         #$recur = $cpt->reval($recur_prog);
 930       $recur = eval $recur_prog;
 931       unless ( defined($recur) ) {
 932         $dbh->rollback if $oldAutoCommit;
 933         return "Error eval-ing part_pkg->recur pkgpart ".  $part_pkg->pkgpart.
 934                "(expression $recur_prog): $@";
 935       }
 936       #change this bit to use Date::Manip? CAREFUL with timezones (see
 937       # mailing list archive)
 938       my ($sec,$min,$hour,$mday,$mon,$year) =
 939         (localtime($sdate) )[0,1,2,3,4,5];
 940
 941       #pro-rating magic - if $recur_prog fiddles $sdate, want to use that
 942       # only for figuring next bill date, nothing else, so, reset $sdate again
 943       # here
 944       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 945
 946       $mon += $part_pkg->getfield('freq');
 947       until ( $mon < 12 ) { $mon -= 12; $year++; }
 948       $cust_pkg->setfield('bill',
 949         timelocal($sec,$min,$hour,$mday,$mon,$year));
 950       $cust_pkg_mod_flag = 1;
 951     }
 952
 953     warn "\$setup is undefined" unless defined($setup);
 954     warn "\$recur is undefined" unless defined($recur);
 955     warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 956
 957     if ( $cust_pkg_mod_flag ) {
 958       $error=$cust_pkg->replace($old_cust_pkg);
 959       if ( $error ) { #just in case
 960         $dbh->rollback if $oldAutoCommit;
 961         return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error";
 962       }
 963       $setup = sprintf( "%.2f", $setup );
 964       $recur = sprintf( "%.2f", $recur );
 965       if ( $setup < 0 ) {
 966         $dbh->rollback if $oldAutoCommit;
 967         return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
 968       }
 969       if ( $recur < 0 ) {
 970         $dbh->rollback if $oldAutoCommit;
 971         return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
 972       }
 973       if ( $setup > 0 || $recur > 0 ) {
 974         my $cust_bill_pkg = new FS::cust_bill_pkg ({
 975           'pkgnum' => $cust_pkg->pkgnum,
 976           'setup'  => $setup,
 977           'recur'  => $recur,
 978           'sdate'  => $sdate,
 979           'edate'  => $cust_pkg->bill,
 980         });
 981         push @cust_bill_pkg, $cust_bill_pkg;
 982         $total_setup += $setup;
 983         $total_recur += $recur;
 984         $taxable_setup += $setup
 985           unless $part_pkg->dbdef_table->column('setuptax')
 986                  && $part_pkg->setuptax =~ /^Y$/i;
 987         $taxable_recur += $recur
 988           unless $part_pkg->dbdef_table->column('recurtax')
 989                  && $part_pkg->recurtax =~ /^Y$/i;
 990       }
 991     }
 992
 993   }
 994
 995   my $charged = sprintf( "%.2f", $total_setup + $total_recur );
 996   my $taxable_charged = sprintf( "%.2f", $taxable_setup + $taxable_recur );
 997
 998   unless ( @cust_bill_pkg ) {
 999     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1000     return '';
1001   }
1002
1003   unless ( $self->tax =~ /Y/i
1004            || $self->payby eq 'COMP'
1005            || $taxable_charged == 0 ) {
1006     my $cust_main_county = qsearchs('cust_main_county',{
1007         'state'   => $self->state,
1008         'county'  => $self->county,
1009         'country' => $self->country,
1010     } ) or die "fatal: can't find tax rate for state/county/country ".
1011                $self->state. "/". $self->county. "/". $self->country. "\n";
1012     my $tax = sprintf( "%.2f",
1013       $taxable_charged * ( $cust_main_county->getfield('tax') / 100 )
1014     );
1015
1016     if ( $tax > 0 ) {
1017       $charged = sprintf( "%.2f", $charged+$tax );
1018
1019       my $cust_bill_pkg = new FS::cust_bill_pkg ({
1020         'pkgnum' => 0,
1021         'setup'  => $tax,
1022         'recur'  => 0,
1023         'sdate'  => '',
1024         'edate'  => '',
1025       });
1026       push @cust_bill_pkg, $cust_bill_pkg;
1027     }
1028   }
1029
1030   my $cust_bill = new FS::cust_bill ( {
1031     'custnum' => $self->custnum,
1032     '_date'   => $time,
1033     'charged' => $charged,
1034   } );
1035   $error = $cust_bill->insert;
1036   if ( $error ) {
1037     $dbh->rollback if $oldAutoCommit;
1038     return "can't create invoice for customer #". $self->custnum. ": $error";
1039   }
1040
1041   my $invnum = $cust_bill->invnum;
1042   my $cust_bill_pkg;
1043   foreach $cust_bill_pkg ( @cust_bill_pkg ) {
1044     #warn $invnum;
1045     $cust_bill_pkg->invnum($invnum);
1046     $error = $cust_bill_pkg->insert;
1047     if ( $error ) {
1048       $dbh->rollback if $oldAutoCommit;
1049       return "can't create invoice line item for customer #". $self->custnum.
1050              ": $error";
1051     }
1052   }
1053
1054   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1055   ''; #no error
1056 }
1057
1058 =item collect OPTIONS
1059
1060 (Attempt to) collect money for this customer's outstanding invoices (see
1061 L<FS::cust_bill>).  Usually used after the bill method.
1062
1063 Depending on the value of `payby', this may print an invoice (`BILL'), charge
1064 a credit card (`CARD'), or just add any necessary (pseudo-)payment (`COMP').
1065
1066 Most actions are now triggered by invoice events; see L<FS::part_bill_event>
1067 and the invoice events web interface.
1068
1069 If there is an error, returns the error, otherwise returns false.
1070
1071 Options are passed as name-value pairs.
1072
1073 Currently available options are:
1074
1075 invoice_time - Use this time when deciding when to print invoices and
1076 late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse>
1077 for conversion functions.
1078
1079 batch_card - This option is deprecated.  See the invoice events web interface
1080 to control whether cards are batched or run against a realtime gateway.
1081
1082 report_badcard - This option is deprecated.
1083
1084 force_print - This option is deprecated; see the invoice events web interface.
1085
1086 =cut
1087
1088 sub collect {
1089   my( $self, %options ) = @_;
1090   my $invoice_time = $options{'invoice_time'} || time;
1091
1092   #put below somehow?
1093   local $SIG{HUP} = 'IGNORE';
1094   local $SIG{INT} = 'IGNORE';
1095   local $SIG{QUIT} = 'IGNORE';
1096   local $SIG{TERM} = 'IGNORE';
1097   local $SIG{TSTP} = 'IGNORE';
1098   local $SIG{PIPE} = 'IGNORE';
1099
1100   my $oldAutoCommit = $FS::UID::AutoCommit;
1101   local $FS::UID::AutoCommit = 0;
1102   my $dbh = dbh;
1103
1104   my $balance = $self->balance;
1105   warn "collect: balance $balance" if $Debug;
1106   unless ( $balance > 0 ) { #redundant?????
1107     $dbh->rollback if $oldAutoCommit; #hmm
1108     return '';
1109   }
1110
1111   foreach my $cust_bill (
1112     qsearch('cust_bill', { 'custnum' => $self->custnum, } )
1113   ) {
1114
1115     #this has to be before next's
1116     my $amount = sprintf( "%.2f", $balance < $cust_bill->owed
1117                                   ? $balance
1118                                   : $cust_bill->owed
1119     );
1120     $balance = sprintf( "%.2f", $balance - $amount );
1121
1122     next unless $cust_bill->owed > 0;
1123
1124     # don't try to charge for the same invoice if it's already in a batch
1125     #next if qsearchs( 'cust_pay_batch', { 'invnum' => $cust_bill->invnum } );
1126
1127     warn "invnum ". $cust_bill->invnum. " (owed ". $cust_bill->owed. ", amount $amount, balance $balance)" if $Debug;
1128
1129     next unless $amount > 0;
1130
1131     foreach my $part_bill_event (
1132       sort {    $a->seconds   <=> $b->seconds
1133              || $a->weight    <=> $b->weight
1134              || $a->eventpart <=> $b->eventpart }
1135         grep { $_->seconds <= ( $invoice_time - $cust_bill->_date )
1136                && ! qsearchs( 'cust_bill_event', {
1137                                 'invnum'    => $cust_bill->invnum,
1138                                 'eventpart' => $_->eventpart       } )
1139              }
1140           qsearch('part_bill_event', { 'payby'    => $self->payby,
1141                                        'disabled' => '',           } )
1142     ) {
1143       #run callback
1144       my $cust_main = $self; #for callback
1145       my $error = eval $part_bill_event->eventcode;
1146
1147       if ( $error ) {
1148
1149         warn "Error running invoice event (". $part_bill_event->eventcode.
1150              "): $error";
1151
1152       } else {
1153
1154         #add cust_bill_event
1155         my $cust_bill_event = new FS::cust_bill_event {
1156           'invnum'    => $cust_bill->invnum,
1157           'eventpart' => $part_bill_event->eventpart,
1158           '_date'     => $invoice_time,
1159         };
1160         $cust_bill_event->insert;
1161         if ( $error ) {
1162           #$dbh->rollback if $oldAutoCommit;
1163           #return "error: $error";
1164
1165           # gah, even with transactions.
1166           $dbh->commit if $oldAutoCommit; #well.
1167           my $e = 'WARNING: Event run but database not updated - '.
1168                   'error inserting cust_bill_event, invnum #'. $cust_bill->invnum.
1169                   ', eventpart '. $part_bill_event->eventpart.
1170                   ": $error";
1171           warn $e;
1172           return $e;
1173         }
1174
1175       }
1176
1177     }
1178
1179   }
1180
1181   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1182   '';
1183
1184 }
1185
1186 =item total_owed
1187
1188 Returns the total owed for this customer on all invoices
1189 (see L<FS::cust_bill/owed>).
1190
1191 =cut
1192
1193 sub total_owed {
1194   my $self = shift;
1195   $self->total_owed_date(2145859200); #12/31/2037
1196 }
1197
1198 =item total_owed_date TIME
1199
1200 Returns the total owed for this customer on all invoices with date earlier than
1201 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
1202 see L<Time::Local> and L<Date::Parse> for conversion functions.
1203
1204 =cut
1205
1206 sub total_owed_date {
1207   my $self = shift;
1208   my $time = shift;
1209   my $total_bill = 0;
1210   foreach my $cust_bill (
1211     grep { $_->_date <= $time }
1212       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
1213   ) {
1214     $total_bill += $cust_bill->owed;
1215   }
1216   sprintf( "%.2f", $total_bill );
1217 }
1218
1219 =item apply_credits
1220
1221 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1222 to outstanding invoice balances in chronological order and returns the value
1223 of any remaining unapplied credits available for refund
1224 (see L<FS::cust_refund>).
1225
1226 =cut
1227
1228 sub apply_credits {
1229   my $self = shift;
1230
1231   return 0 unless $self->total_credited;
1232
1233   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1234       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1235
1236   my @invoices = sort { $a->_date <=> $b->_date} (grep { $_->owed > 0 }
1237       qsearch('cust_bill', { 'custnum' => $self->custnum } ) );
1238
1239   my $credit;
1240
1241   foreach my $cust_bill ( @invoices ) {
1242     my $amount;
1243
1244     if ( !defined($credit) || $credit->credited == 0) {
1245       $credit = pop @credits or last;
1246     }
1247
1248     if ($cust_bill->owed >= $credit->credited) {
1249       $amount=$credit->credited;
1250     }else{
1251       $amount=$cust_bill->owed;
1252     }
1253
1254     my $cust_credit_bill = new FS::cust_credit_bill ( {
1255       'crednum' => $credit->crednum,
1256       'invnum'  => $cust_bill->invnum,
1257       'amount'  => $amount,
1258     } );
1259     my $error = $cust_credit_bill->insert;
1260     die $error if $error;
1261
1262     redo if ($cust_bill->owed > 0);
1263
1264   }
1265
1266   return $self->total_credited;
1267 }
1268
1269 =item apply_payments
1270
1271 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
1272 to outstanding invoice balances in chronological order.
1273
1274  #and returns the value of any remaining unapplied payments.
1275
1276 =cut
1277
1278 sub apply_payments {
1279   my $self = shift;
1280
1281   #return 0 unless
1282
1283   my @payments = sort { $b->_date <=> $a->_date } ( grep { $_->unapplied > 0 }
1284       qsearch('cust_pay', { 'custnum' => $self->custnum } ) );
1285
1286   my @invoices = sort { $a->_date <=> $b->_date} (grep { $_->owed > 0 }
1287       qsearch('cust_bill', { 'custnum' => $self->custnum } ) );
1288
1289   my $payment;
1290
1291   foreach my $cust_bill ( @invoices ) {
1292     my $amount;
1293
1294     if ( !defined($payment) || $payment->unapplied == 0 ) {
1295       $payment = pop @payments or last;
1296     }
1297
1298     if ( $cust_bill->owed >= $payment->unapplied ) {
1299       $amount = $payment->unapplied;
1300     } else {
1301       $amount = $cust_bill->owed;
1302     }
1303
1304     my $cust_bill_pay = new FS::cust_bill_pay ( {
1305       'paynum' => $payment->paynum,
1306       'invnum' => $cust_bill->invnum,
1307       'amount' => $amount,
1308     } );
1309     my $error = $cust_bill_pay->insert;
1310     die $error if $error;
1311
1312     redo if ( $cust_bill->owed > 0);
1313
1314   }
1315
1316   return $self->total_unapplied_payments;
1317 }
1318
1319 =item total_credited
1320
1321 Returns the total outstanding credit (see L<FS::cust_credit>) for this
1322 customer.  See L<FS::cust_credit/credited>.
1323
1324 =cut
1325
1326 sub total_credited {
1327   my $self = shift;
1328   my $total_credit = 0;
1329   foreach my $cust_credit ( qsearch('cust_credit', {
1330     'custnum' => $self->custnum,
1331   } ) ) {
1332     $total_credit += $cust_credit->credited;
1333   }
1334   sprintf( "%.2f", $total_credit );
1335 }
1336
1337 =item total_unapplied_payments
1338
1339 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
1340 See L<FS::cust_pay/unapplied>.
1341
1342 =cut
1343
1344 sub total_unapplied_payments {
1345   my $self = shift;
1346   my $total_unapplied = 0;
1347   foreach my $cust_pay ( qsearch('cust_pay', {
1348     'custnum' => $self->custnum,
1349   } ) ) {
1350     $total_unapplied += $cust_pay->unapplied;
1351   }
1352   sprintf( "%.2f", $total_unapplied );
1353 }
1354
1355 =item balance
1356
1357 Returns the balance for this customer (total_owed minus total_credited
1358 minus total_unapplied_payments).
1359
1360 =cut
1361
1362 sub balance {
1363   my $self = shift;
1364   sprintf( "%.2f",
1365     $self->total_owed - $self->total_credited - $self->total_unapplied_payments
1366   );
1367 }
1368
1369 =item balance_date TIME
1370
1371 Returns the balance for this customer, only considering invoices with date
1372 earlier than TIME (total_owed_date minus total_credited minus
1373 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
1374 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
1375 functions.
1376
1377 =cut
1378
1379 sub balance_date {
1380   my $self = shift;
1381   my $time = shift;
1382   sprintf( "%.2f",
1383     $self->total_owed_date($time)
1384       - $self->total_credited
1385       - $self->total_unapplied_payments
1386   );
1387 }
1388
1389 =item invoicing_list [ ARRAYREF ]
1390
1391 If an arguement is given, sets these email addresses as invoice recipients
1392 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
1393 (except as warnings), so use check_invoicing_list first.
1394
1395 Returns a list of email addresses (with svcnum entries expanded).
1396
1397 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
1398 check it without disturbing anything by passing nothing.
1399
1400 This interface may change in the future.
1401
1402 =cut
1403
1404 sub invoicing_list {
1405   my( $self, $arrayref ) = @_;
1406   if ( $arrayref ) {
1407     my @cust_main_invoice;
1408     if ( $self->custnum ) {
1409       @cust_main_invoice =
1410         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
1411     } else {
1412       @cust_main_invoice = ();
1413     }
1414     foreach my $cust_main_invoice ( @cust_main_invoice ) {
1415       #warn $cust_main_invoice->destnum;
1416       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
1417         #warn $cust_main_invoice->destnum;
1418         my $error = $cust_main_invoice->delete;
1419         warn $error if $error;
1420       }
1421     }
1422     if ( $self->custnum ) {
1423       @cust_main_invoice =
1424         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
1425     } else {
1426       @cust_main_invoice = ();
1427     }
1428     my %seen = map { $_->address => 1 } @cust_main_invoice;
1429     foreach my $address ( @{$arrayref} ) {
1430       #unless ( grep { $address eq $_->address } @cust_main_invoice ) {
1431       next if exists $seen{$address} && $seen{$address};
1432       $seen{$address} = 1;
1433       my $cust_main_invoice = new FS::cust_main_invoice ( {
1434         'custnum' => $self->custnum,
1435         'dest'    => $address,
1436       } );
1437       my $error = $cust_main_invoice->insert;
1438       warn $error if $error;
1439     }
1440   }
1441   if ( $self->custnum ) {
1442     map { $_->address }
1443       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
1444   } else {
1445     ();
1446   }
1447 }
1448
1449 =item check_invoicing_list ARRAYREF
1450
1451 Checks these arguements as valid input for the invoicing_list method.  If there
1452 is an error, returns the error, otherwise returns false.
1453
1454 =cut
1455
1456 sub check_invoicing_list {
1457   my( $self, $arrayref ) = @_;
1458   foreach my $address ( @{$arrayref} ) {
1459     my $cust_main_invoice = new FS::cust_main_invoice ( {
1460       'custnum' => $self->custnum,
1461       'dest'    => $address,
1462     } );
1463     my $error = $self->custnum
1464                 ? $cust_main_invoice->check
1465                 : $cust_main_invoice->checkdest
1466     ;
1467     return $error if $error;
1468   }
1469   '';
1470 }
1471
1472 =item default_invoicing_list
1473
1474 Sets the invoicing list to all accounts associated with this customer.
1475
1476 =cut
1477
1478 sub default_invoicing_list {
1479   my $self = shift;
1480   my @list = ();
1481   foreach my $cust_pkg ( $self->all_pkgs ) {
1482     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
1483     my @svc_acct =
1484       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
1485         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
1486           @cust_svc;
1487     push @list, map { $_->email } @svc_acct;
1488   }
1489   $self->invoicing_list(\@list);
1490 }
1491
1492 =item invoicing_list_addpost
1493
1494 Adds postal invoicing to this customer.  If this customer is already configured
1495 to receive postal invoices, does nothing.
1496
1497 =cut
1498
1499 sub invoicing_list_addpost {
1500   my $self = shift;
1501   return if grep { $_ eq 'POST' } $self->invoicing_list;
1502   my @invoicing_list = $self->invoicing_list;
1503   push @invoicing_list, 'POST';
1504   $self->invoicing_list(\@invoicing_list);
1505 }
1506
1507 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
1508
1509 Returns an array of customers referred by this customer (referral_custnum set
1510 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
1511 customers referred by customers referred by this customer and so on, inclusive.
1512 The default behavior is DEPTH 1 (no recursion).
1513
1514 =cut
1515
1516 sub referral_cust_main {
1517   my $self = shift;
1518   my $depth = @_ ? shift : 1;
1519   my $exclude = @_ ? shift : {};
1520
1521   my @cust_main =
1522     map { $exclude->{$_->custnum}++; $_; }
1523       grep { ! $exclude->{ $_->custnum } }
1524         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
1525
1526   if ( $depth > 1 ) {
1527     push @cust_main,
1528       map { $_->referral_cust_main($depth-1, $exclude) }
1529         @cust_main;
1530   }
1531
1532   @cust_main;
1533 }
1534
1535 =item referral_cust_main_ncancelled
1536
1537 Same as referral_cust_main, except only returns customers with uncancelled
1538 packages.
1539
1540 =cut
1541
1542 sub referral_cust_main_ncancelled {
1543   my $self = shift;
1544   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
1545 }
1546
1547 =item referral_cust_pkg [ DEPTH ]
1548
1549 Like referral_cust_main, except returns a flat list of all unsuspended (and
1550 uncancelled) packages for each customer.  The number of items in this list may
1551 be useful for comission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
1552
1553 =cut
1554
1555 sub referral_cust_pkg {
1556   my $self = shift;
1557   my $depth = @_ ? shift : 1;
1558
1559   map { $_->unsuspended_pkgs }
1560     grep { $_->unsuspended_pkgs }
1561       $self->referral_cust_main($depth);
1562 }
1563
1564 =item credit AMOUNT, REASON
1565
1566 Applies a credit to this customer.  If there is an error, returns the error,
1567 otherwise returns false.
1568
1569 =cut
1570
1571 sub credit {
1572   my( $self, $amount, $reason ) = @_;
1573   my $cust_credit = new FS::cust_credit {
1574     'custnum' => $self->custnum,
1575     'amount'  => $amount,
1576     'reason'  => $reason,
1577   };
1578   $cust_credit->insert;
1579 }
1580
1581 =item charge AMOUNT PKG COMMENT
1582
1583 Creates a one-time charge for this customer.  If there is an error, returns
1584 the error, otherwise returns false.
1585
1586 =cut
1587
1588 sub charge {
1589   my ( $self, $amount, $pkg, $comment ) = @_;
1590
1591   my $part_pkg = new FS::part_pkg ( {
1592     'pkg'      => $pkg || 'One-time charge',
1593     'comment'  => $comment || '$'. sprintf("%.2f".$amount),
1594     'setup'    => $amount,
1595     'freq'     => 0,
1596     'recur'    => '0',
1597     'disabled' => 'Y',
1598   } );
1599
1600   $part_pkg->insert;
1601
1602 }
1603
1604 =back
1605
1606 =head1 SUBROUTINES
1607
1608 =over 4
1609
1610 =item check_and_rebuild_fuzzyfiles
1611
1612 =cut
1613
1614 sub check_and_rebuild_fuzzyfiles {
1615   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
1616   -e "$dir/cust_main.last" && -e "$dir/cust_main.company"
1617     or &rebuild_fuzzyfiles;
1618 }
1619
1620 =item rebuild_fuzzyfiles
1621
1622 =cut
1623
1624 sub rebuild_fuzzyfiles {
1625
1626   use Fcntl qw(:flock);
1627
1628   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
1629
1630   #last
1631
1632   open(LASTLOCK,">>$dir/cust_main.last")
1633     or die "can't open $dir/cust_main.last: $!";
1634   flock(LASTLOCK,LOCK_EX)
1635     or die "can't lock $dir/cust_main.last: $!";
1636
1637   my @all_last = map $_->getfield('last'), qsearch('cust_main', {});
1638   push @all_last,
1639                  grep $_, map $_->getfield('ship_last'), qsearch('cust_main',{})
1640     if defined dbdef->table('cust_main')->column('ship_last');
1641
1642   open (LASTCACHE,">$dir/cust_main.last.tmp")
1643     or die "can't open $dir/cust_main.last.tmp: $!";
1644   print LASTCACHE join("\n", @all_last), "\n";
1645   close LASTCACHE or die "can't close $dir/cust_main.last.tmp: $!";
1646
1647   rename "$dir/cust_main.last.tmp", "$dir/cust_main.last";
1648   close LASTLOCK;
1649
1650   #company
1651
1652   open(COMPANYLOCK,">>$dir/cust_main.company")
1653     or die "can't open $dir/cust_main.company: $!";
1654   flock(COMPANYLOCK,LOCK_EX)
1655     or die "can't lock $dir/cust_main.company: $!";
1656
1657   my @all_company = grep $_ ne '', map $_->company, qsearch('cust_main',{});
1658   push @all_company,
1659        grep $_ ne '', map $_->ship_company, qsearch('cust_main', {})
1660     if defined dbdef->table('cust_main')->column('ship_last');
1661
1662   open (COMPANYCACHE,">$dir/cust_main.company.tmp")
1663     or die "can't open $dir/cust_main.company.tmp: $!";
1664   print COMPANYCACHE join("\n", @all_company), "\n";
1665   close COMPANYCACHE or die "can't close $dir/cust_main.company.tmp: $!";
1666
1667   rename "$dir/cust_main.company.tmp", "$dir/cust_main.company";
1668   close COMPANYLOCK;
1669
1670 }
1671
1672 =item all_last
1673
1674 =cut
1675
1676 sub all_last {
1677   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
1678   open(LASTCACHE,"<$dir/cust_main.last")
1679     or die "can't open $dir/cust_main.last: $!";
1680   my @array = map { chomp; $_; } <LASTCACHE>;
1681   close LASTCACHE;
1682   \@array;
1683 }
1684
1685 =item all_company
1686
1687 =cut
1688
1689 sub all_company {
1690   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
1691   open(COMPANYCACHE,"<$dir/cust_main.company")
1692     or die "can't open $dir/cust_main.last: $!";
1693   my @array = map { chomp; $_; } <COMPANYCACHE>;
1694   close COMPANYCACHE;
1695   \@array;
1696 }
1697
1698 =item append_fuzzyfiles LASTNAME COMPANY
1699
1700 =cut
1701
1702 sub append_fuzzyfiles {
1703   my( $last, $company ) = @_;
1704
1705   &check_and_rebuild_fuzzyfiles;
1706
1707   use Fcntl qw(:flock);
1708
1709   my $dir = $FS::UID::conf_dir. "cache.". $FS::UID::datasrc;
1710
1711   if ( $last ) {
1712
1713     open(LAST,">>$dir/cust_main.last")
1714       or die "can't open $dir/cust_main.last: $!";
1715     flock(LAST,LOCK_EX)
1716       or die "can't lock $dir/cust_main.last: $!";
1717
1718     print LAST "$last\n";
1719
1720     flock(LAST,LOCK_UN)
1721       or die "can't unlock $dir/cust_main.last: $!";
1722     close LAST;
1723   }
1724
1725   if ( $company ) {
1726
1727     open(COMPANY,">>$dir/cust_main.company")
1728       or die "can't open $dir/cust_main.company: $!";
1729     flock(COMPANY,LOCK_EX)
1730       or die "can't lock $dir/cust_main.company: $!";
1731
1732     print COMPANY "$company\n";
1733
1734     flock(COMPANY,LOCK_UN)
1735       or die "can't unlock $dir/cust_main.company: $!";
1736
1737     close COMPANY;
1738   }
1739
1740   1;
1741 }
1742
1743 =back
1744
1745 =head1 BUGS
1746
1747 The delete method.
1748
1749 The delete method should possibly take an FS::cust_main object reference
1750 instead of a scalar customer number.
1751
1752 Bill and collect options should probably be passed as references instead of a
1753 list.
1754
1755 There should probably be a configuration file with a list of allowed credit
1756 card types.
1757
1758 No multiple currency support (probably a larger project than just this module).
1759
1760 =head1 SEE ALSO
1761
1762 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
1763 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
1764 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
1765
1766 =cut
1767
1768 1;
1769
1770