FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Discount
   8              FS::cust_main::Billing_ThirdParty
   9              FS::cust_main::Location
  10              FS::cust_main::Credit_Limit
  11              FS::cust_main::API
  12              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  13              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  14              FS::o2m_Common
  15              FS::Record
  16            );
  17
  18 require 5.006;
  19 use strict;
  20 use vars qw( $DEBUG $me $conf
  21              @encrypted_fields
  22              $import
  23              $ignore_expired_card $ignore_banned_card $ignore_illegal_zip
  24              $ignore_invalid_card
  25              $skip_fuzzyfiles
  26              @paytypes
  27            );
  28 use Carp;
  29 use Scalar::Util qw( blessed );
  30 use Time::Local qw(timelocal);
  31 use Storable qw(thaw);
  32 use MIME::Base64;
  33 use Data::Dumper;
  34 use Tie::IxHash;
  35 use Digest::MD5 qw(md5_base64);
  36 use Date::Format;
  37 #use Date::Manip;
  38 use File::Temp; #qw( tempfile );
  39 use Business::CreditCard 0.28;
  40 use Locale::Country;
  41 use FS::UID qw( dbh driver_name );
  42 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  43 use FS::Cursor;
  44 use FS::Misc qw( generate_email send_email generate_ps do_print );
  45 use FS::Msgcat qw(gettext);
  46 use FS::CurrentUser;
  47 use FS::TicketSystem;
  48 use FS::payby;
  49 use FS::cust_pkg;
  50 use FS::cust_svc;
  51 use FS::cust_bill;
  52 use FS::cust_bill_void;
  53 use FS::legacy_cust_bill;
  54 use FS::cust_pay;
  55 use FS::cust_pay_pending;
  56 use FS::cust_pay_void;
  57 use FS::cust_pay_batch;
  58 use FS::cust_credit;
  59 use FS::cust_refund;
  60 use FS::part_referral;
  61 use FS::cust_main_county;
  62 use FS::cust_location;
  63 use FS::cust_class;
  64 use FS::cust_main_exemption;
  65 use FS::cust_tax_adjustment;
  66 use FS::cust_tax_location;
  67 use FS::agent_currency;
  68 use FS::cust_main_invoice;
  69 use FS::cust_tag;
  70 use FS::prepay_credit;
  71 use FS::queue;
  72 use FS::part_pkg;
  73 use FS::part_export;
  74 #use FS::cust_event;
  75 use FS::type_pkgs;
  76 use FS::payment_gateway;
  77 use FS::agent_payment_gateway;
  78 use FS::banned_pay;
  79 use FS::cust_main_note;
  80 use FS::cust_attachment;
  81 use FS::contact;
  82 use FS::Locales;
  83 use FS::upgrade_journal;
  84 use FS::sales;
  85 use FS::cust_payby;
  86
  87 # 1 is mostly method/subroutine entry and options
  88 # 2 traces progress of some operations
  89 # 3 is even more information including possibly sensitive data
  90 $DEBUG = 0;
  91 $me = '[FS::cust_main]';
  92
  93 $import = 0;
  94 $ignore_expired_card = 0;
  95 $ignore_banned_card = 0;
  96 $ignore_invalid_card = 0;
  97
  98 $skip_fuzzyfiles = 0;
  99
 100 @encrypted_fields = ('payinfo', 'paycvv');
 101 sub nohistory_fields { ('payinfo', 'paycvv'); }
 102
 103 @paytypes = ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
 104
 105 #ask FS::UID to run this stuff for us later
 106 #$FS::UID::callback{'FS::cust_main'} = sub {
 107 install_callback FS::UID sub {
 108   $conf = new FS::Conf;
 109   #yes, need it for stuff below (prolly should be cached)
 110   $ignore_invalid_card = $conf->exists('allow_invalid_cards');
 111 };
 112
 113 sub _cache {
 114   my $self = shift;
 115   my ( $hashref, $cache ) = @_;
 116   if ( exists $hashref->{'pkgnum'} ) {
 117     #@{ $self->{'_pkgnum'} } = ();
 118     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 119     $self->{'_pkgnum'} = $subcache;
 120     #push @{ $self->{'_pkgnum'} },
 121     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 122   }
 123 }
 124
 125 =head1 NAME
 126
 127 FS::cust_main - Object methods for cust_main records
 128
 129 =head1 SYNOPSIS
 130
 131   use FS::cust_main;
 132
 133   $record = new FS::cust_main \%hash;
 134   $record = new FS::cust_main { 'column' => 'value' };
 135
 136   $error = $record->insert;
 137
 138   $error = $new_record->replace($old_record);
 139
 140   $error = $record->delete;
 141
 142   $error = $record->check;
 143
 144   @cust_pkg = $record->all_pkgs;
 145
 146   @cust_pkg = $record->ncancelled_pkgs;
 147
 148   @cust_pkg = $record->suspended_pkgs;
 149
 150   $error = $record->bill;
 151   $error = $record->bill %options;
 152   $error = $record->bill 'time' => $time;
 153
 154   $error = $record->collect;
 155   $error = $record->collect %options;
 156   $error = $record->collect 'invoice_time'   => $time,
 157                           ;
 158
 159 =head1 DESCRIPTION
 160
 161 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 162 FS::Record.  The following fields are currently supported:
 163
 164 =over 4
 165
 166 =item custnum
 167
 168 Primary key (assigned automatically for new customers)
 169
 170 =item agentnum
 171
 172 Agent (see L<FS::agent>)
 173
 174 =item refnum
 175
 176 Advertising source (see L<FS::part_referral>)
 177
 178 =item first
 179
 180 First name
 181
 182 =item last
 183
 184 Last name
 185
 186 =item ss
 187
 188 Cocial security number (optional)
 189
 190 =item company
 191
 192 (optional)
 193
 194 =item daytime
 195
 196 phone (optional)
 197
 198 =item night
 199
 200 phone (optional)
 201
 202 =item fax
 203
 204 phone (optional)
 205
 206 =item mobile
 207
 208 phone (optional)
 209
 210 =item payby
 211
 212 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 213
 214 =item payinfo
 215
 216 Payment Information (See L<FS::payinfo_Mixin> for data format)
 217
 218 =item paymask
 219
 220 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 221
 222 =item paycvv
 223
 224 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 225
 226 =item paydate
 227
 228 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 229
 230 =item paystart_month
 231
 232 Start date month (maestro/solo cards only)
 233
 234 =item paystart_year
 235
 236 Start date year (maestro/solo cards only)
 237
 238 =item payissue
 239
 240 Issue number (maestro/solo cards only)
 241
 242 =item payname
 243
 244 Name on card or billing name
 245
 246 =item payip
 247
 248 IP address from which payment information was received
 249
 250 =item tax
 251
 252 Tax exempt, empty or `Y'
 253
 254 =item usernum
 255
 256 Order taker (see L<FS::access_user>)
 257
 258 =item comments
 259
 260 Comments (optional)
 261
 262 =item referral_custnum
 263
 264 Referring customer number
 265
 266 =item spool_cdr
 267
 268 Enable individual CDR spooling, empty or `Y'
 269
 270 =item dundate
 271
 272 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 273
 274 =item squelch_cdr
 275
 276 Discourage individual CDR printing, empty or `Y'
 277
 278 =item edit_subject
 279
 280 Allow self-service editing of ticket subjects, empty or 'Y'
 281
 282 =item calling_list_exempt
 283
 284 Do not call, empty or 'Y'
 285
 286 =back
 287
 288 =head1 METHODS
 289
 290 =over 4
 291
 292 =item new HASHREF
 293
 294 Creates a new customer.  To add the customer to the database, see L<"insert">.
 295
 296 Note that this stores the hash reference, not a distinct copy of the hash it
 297 points to.  You can ask the object for a copy with the I<hash> method.
 298
 299 =cut
 300
 301 sub table { 'cust_main'; }
 302
 303 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 304
 305 Adds this customer to the database.  If there is an error, returns the error,
 306 otherwise returns false.
 307
 308 Usually the customer's location will not yet exist in the database, and
 309 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 310 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 311 (in both directions) to the new customer record.  If they're references
 312 to the same object, they will become the same location.
 313
 314 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 315 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 316 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 317 hash reference is equivalent to not supplying this parameter.  There should be
 318 a better explanation of this, but until then, here's an example:
 319
 320   use Tie::RefHash;
 321   tie %hash, 'Tie::RefHash'; #this part is important
 322   %hash = (
 323     $cust_pkg => [ $svc_acct ],
 324     ...
 325   );
 326   $cust_main->insert( \%hash );
 327
 328 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 329 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 330 expected and rollback the entire transaction; it is not necessary to call
 331 check_invoicing_list first.  The invoicing_list is set after the records in the
 332 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 333 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 334
 335   $cust_main->insert( {}, [ $email, 'POST' ] );
 336
 337 Currently available options are: I<depend_jobnum>, I<noexport>,
 338 I<tax_exemption> and I<prospectnum>.
 339
 340 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 341 on the supplied jobnum (they will not run until the specific job completes).
 342 This can be used to defer provisioning until some action completes (such
 343 as running the customer's credit card successfully).
 344
 345 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 346 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 347 the B<reexport> method.)
 348
 349 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 350 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 351 created and inserted.
 352
 353 If I<prospectnum> is set, moves contacts and locations from that prospect.
 354
 355 If I<contact> is set to an arrayref of FS::contact objects, inserts those
 356 new contacts with this new customer.
 357
 358 =cut
 359
 360 sub insert {
 361   my $self = shift;
 362   my $cust_pkgs = @_ ? shift : {};
 363   my $invoicing_list = @_ ? shift : '';
 364   my %options = @_;
 365   warn "$me insert called with options ".
 366        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 367     if $DEBUG;
 368
 369   local $SIG{HUP} = 'IGNORE';
 370   local $SIG{INT} = 'IGNORE';
 371   local $SIG{QUIT} = 'IGNORE';
 372   local $SIG{TERM} = 'IGNORE';
 373   local $SIG{TSTP} = 'IGNORE';
 374   local $SIG{PIPE} = 'IGNORE';
 375
 376   my $oldAutoCommit = $FS::UID::AutoCommit;
 377   local $FS::UID::AutoCommit = 0;
 378   my $dbh = dbh;
 379
 380   my $prepay_identifier = '';
 381   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 382   my $payby = '';
 383   if ( $self->payby eq 'PREPAY' ) {
 384
 385     $self->payby('BILL');
 386     $prepay_identifier = $self->payinfo;
 387     $self->payinfo('');
 388
 389     warn "  looking up prepaid card $prepay_identifier\n"
 390       if $DEBUG > 1;
 391
 392     my $error = $self->get_prepay( $prepay_identifier,
 393                                    'amount_ref'     => \$amount,
 394                                    'seconds_ref'    => \$seconds,
 395                                    'upbytes_ref'    => \$upbytes,
 396                                    'downbytes_ref'  => \$downbytes,
 397                                    'totalbytes_ref' => \$totalbytes,
 398                                  );
 399     if ( $error ) {
 400       $dbh->rollback if $oldAutoCommit;
 401       #return "error applying prepaid card (transaction rolled back): $error";
 402       return $error;
 403     }
 404
 405     $payby = 'PREP' if $amount;
 406
 407   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|PPAL)$/ ) {
 408
 409     $payby = $1;
 410     $self->payby('BILL');
 411     $amount = $self->paid;
 412
 413   }
 414
 415   # insert locations
 416   foreach my $l (qw(bill_location ship_location)) {
 417     my $loc = delete $self->hashref->{$l};
 418     # XXX if we're moving a prospect's locations, do that here
 419     if ( !$loc ) {
 420       #return "$l not set";
 421       #location-less customer records are now permitted
 422       next;
 423     }
 424
 425     if ( !$loc->locationnum ) {
 426       # warn the location that we're going to insert it with no custnum
 427       $loc->set(custnum_pending => 1);
 428       warn "  inserting $l\n"
 429         if $DEBUG > 1;
 430       my $error = $loc->insert;
 431       if ( $error ) {
 432         $dbh->rollback if $oldAutoCommit;
 433         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 434         return "$error (in $label location)";
 435       }
 436     }
 437     elsif ( ($loc->custnum || 0) > 0 or $loc->prospectnum ) {
 438       # then it somehow belongs to another customer--shouldn't happen
 439       $dbh->rollback if $oldAutoCommit;
 440       return "$l belongs to customer ".$loc->custnum;
 441     }
 442     # else it already belongs to this customer
 443     # (happens when ship_location is identical to bill_location)
 444
 445     $self->set($l.'num', $loc->locationnum);
 446
 447     if ( $self->get($l.'num') eq '' ) {
 448       $dbh->rollback if $oldAutoCommit;
 449       return "$l not set";
 450     }
 451   }
 452
 453   warn "  inserting $self\n"
 454     if $DEBUG > 1;
 455
 456   $self->signupdate(time) unless $self->signupdate;
 457
 458   $self->auto_agent_custid()
 459     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 460
 461   my $error = $self->SUPER::insert;
 462   if ( $error ) {
 463     $dbh->rollback if $oldAutoCommit;
 464     #return "inserting cust_main record (transaction rolled back): $error";
 465     return $error;
 466   }
 467
 468   # now set cust_location.custnum
 469   foreach my $l (qw(bill_location ship_location)) {
 470     warn "  setting $l.custnum\n"
 471       if $DEBUG > 1;
 472     my $loc = $self->$l or next;
 473     unless ( $loc->custnum ) {
 474       $loc->set(custnum => $self->custnum);
 475       $error ||= $loc->replace;
 476     }
 477
 478     if ( $error ) {
 479       $dbh->rollback if $oldAutoCommit;
 480       return "error setting $l custnum: $error";
 481     }
 482   }
 483
 484   warn "  setting invoicing list\n"
 485     if $DEBUG > 1;
 486
 487   if ( $invoicing_list ) {
 488     $error = $self->check_invoicing_list( $invoicing_list );
 489     if ( $error ) {
 490       $dbh->rollback if $oldAutoCommit;
 491       #return "checking invoicing_list (transaction rolled back): $error";
 492       return $error;
 493     }
 494     $self->invoicing_list( $invoicing_list );
 495   }
 496
 497   warn "  setting customer tags\n"
 498     if $DEBUG > 1;
 499
 500   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 501     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 502                                       'custnum' => $self->custnum };
 503     my $error = $cust_tag->insert;
 504     if ( $error ) {
 505       $dbh->rollback if $oldAutoCommit;
 506       return $error;
 507     }
 508   }
 509
 510   my $prospectnum = delete $options{'prospectnum'};
 511   if ( $prospectnum ) {
 512
 513     warn "  moving contacts and locations from prospect $prospectnum\n"
 514       if $DEBUG > 1;
 515
 516     my $prospect_main =
 517       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 518     unless ( $prospect_main ) {
 519       $dbh->rollback if $oldAutoCommit;
 520       return "Unknown prospectnum $prospectnum";
 521     }
 522     $prospect_main->custnum($self->custnum);
 523     $prospect_main->disabled('Y');
 524     my $error = $prospect_main->replace;
 525     if ( $error ) {
 526       $dbh->rollback if $oldAutoCommit;
 527       return $error;
 528     }
 529
 530     my @contact = $prospect_main->contact;
 531     my @cust_location = $prospect_main->cust_location;
 532     my @qual = $prospect_main->qual;
 533
 534     foreach my $r ( @contact, @cust_location, @qual ) {
 535       $r->prospectnum('');
 536       $r->custnum($self->custnum);
 537       my $error = $r->replace;
 538       if ( $error ) {
 539         $dbh->rollback if $oldAutoCommit;
 540         return $error;
 541       }
 542     }
 543
 544   }
 545
 546   my $contact = delete $options{'contact'};
 547   if ( $contact ) {
 548
 549     foreach my $c ( @$contact ) {
 550       $c->custnum($self->custnum);
 551       my $error = $c->insert;
 552       if ( $error ) {
 553         $dbh->rollback if $oldAutoCommit;
 554         return $error;
 555       }
 556
 557     }
 558
 559   }
 560
 561   warn "  setting cust_main_exemption\n"
 562     if $DEBUG > 1;
 563
 564   my $tax_exemption = delete $options{'tax_exemption'};
 565   if ( $tax_exemption ) {
 566
 567     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 568       if ref($tax_exemption) eq 'ARRAY';
 569
 570     foreach my $taxname ( keys %$tax_exemption ) {
 571       my $cust_main_exemption = new FS::cust_main_exemption {
 572         'custnum'       => $self->custnum,
 573         'taxname'       => $taxname,
 574         'exempt_number' => $tax_exemption->{$taxname},
 575       };
 576       my $error = $cust_main_exemption->insert;
 577       if ( $error ) {
 578         $dbh->rollback if $oldAutoCommit;
 579         return "inserting cust_main_exemption (transaction rolled back): $error";
 580       }
 581     }
 582   }
 583
 584   warn "  ordering packages\n"
 585     if $DEBUG > 1;
 586
 587   $error = $self->order_pkgs( $cust_pkgs,
 588                               %options,
 589                               'seconds_ref'    => \$seconds,
 590                               'upbytes_ref'    => \$upbytes,
 591                               'downbytes_ref'  => \$downbytes,
 592                               'totalbytes_ref' => \$totalbytes,
 593                             );
 594   if ( $error ) {
 595     $dbh->rollback if $oldAutoCommit;
 596     return $error;
 597   }
 598
 599   if ( $seconds ) {
 600     $dbh->rollback if $oldAutoCommit;
 601     return "No svc_acct record to apply pre-paid time";
 602   }
 603   if ( $upbytes || $downbytes || $totalbytes ) {
 604     $dbh->rollback if $oldAutoCommit;
 605     return "No svc_acct record to apply pre-paid data";
 606   }
 607
 608   if ( $amount ) {
 609     warn "  inserting initial $payby payment of $amount\n"
 610       if $DEBUG > 1;
 611     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 612     if ( $error ) {
 613       $dbh->rollback if $oldAutoCommit;
 614       return "inserting payment (transaction rolled back): $error";
 615     }
 616   }
 617
 618   unless ( $import || $skip_fuzzyfiles ) {
 619     warn "  queueing fuzzyfiles update\n"
 620       if $DEBUG > 1;
 621     $error = $self->queue_fuzzyfiles_update;
 622     if ( $error ) {
 623       $dbh->rollback if $oldAutoCommit;
 624       return "updating fuzzy search cache: $error";
 625     }
 626   }
 627
 628   # FS::geocode_Mixin::after_insert or something?
 629   if ( $conf->config('tax_district_method') and !$import ) {
 630     # if anything non-empty, try to look it up
 631     my $queue = new FS::queue {
 632       'job'     => 'FS::geocode_Mixin::process_district_update',
 633       'custnum' => $self->custnum,
 634     };
 635     my $error = $queue->insert( ref($self), $self->custnum );
 636     if ( $error ) {
 637       $dbh->rollback if $oldAutoCommit;
 638       return "queueing tax district update: $error";
 639     }
 640   }
 641
 642   # cust_main exports!
 643   warn "  exporting\n" if $DEBUG > 1;
 644
 645   my $export_args = $options{'export_args'} || [];
 646
 647   my @part_export =
 648     map qsearch( 'part_export', {exportnum=>$_} ),
 649       $conf->config('cust_main-exports'); #, $agentnum
 650
 651   foreach my $part_export ( @part_export ) {
 652     my $error = $part_export->export_insert($self, @$export_args);
 653     if ( $error ) {
 654       $dbh->rollback if $oldAutoCommit;
 655       return "exporting to ". $part_export->exporttype.
 656              " (transaction rolled back): $error";
 657     }
 658   }
 659
 660   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 661   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 662   #      if $DEBUG;
 663   #    foreach my $jobnum ( @jobnums ) {
 664   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 665   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 666   #        if $DEBUG;
 667   #      my $error = $queue->depend_insert($depend_jobnum);
 668   #      if ( $error ) {
 669   #        $dbh->rollback if $oldAutoCommit;
 670   #        return "error queuing job dependancy: $error";
 671   #      }
 672   #    }
 673   #  }
 674   #
 675   #}
 676   #
 677   #if ( exists $options{'jobnums'} ) {
 678   #  push @{ $options{'jobnums'} }, @jobnums;
 679   #}
 680
 681   warn "  insert complete; committing transaction\n"
 682     if $DEBUG > 1;
 683
 684   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 685   '';
 686
 687 }
 688
 689 use File::CounterFile;
 690 sub auto_agent_custid {
 691   my $self = shift;
 692
 693   my $format = $conf->config('cust_main-auto_agent_custid');
 694   my $agent_custid;
 695   if ( $format eq '1YMMXXXXXXXX' ) {
 696
 697     my $counter = new File::CounterFile 'cust_main.agent_custid';
 698     $counter->lock;
 699
 700     my $ym = 100000000000 + time2str('%y%m00000000', time);
 701     if ( $ym > $counter->value ) {
 702       $counter->{'value'} = $agent_custid = $ym;
 703       $counter->{'updated'} = 1;
 704     } else {
 705       $agent_custid = $counter->inc;
 706     }
 707
 708     $counter->unlock;
 709
 710   } else {
 711     die "Unknown cust_main-auto_agent_custid format: $format";
 712   }
 713
 714   $self->agent_custid($agent_custid);
 715
 716 }
 717
 718 =item PACKAGE METHODS
 719
 720 Documentation on customer package methods has been moved to
 721 L<FS::cust_main::Packages>.
 722
 723 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 724
 725 Recharges this (existing) customer with the specified prepaid card (see
 726 L<FS::prepay_credit>), specified either by I<identifier> or as an
 727 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 728 returns false.
 729
 730 Optionally, five scalar references can be passed as well.  They will have their
 731 values filled in with the amount, number of seconds, and number of upload,
 732 download, and total bytes applied by this prepaid card.
 733
 734 =cut
 735
 736 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 737 #the only place that uses these args
 738 sub recharge_prepay {
 739   my( $self, $prepay_credit, $amountref, $secondsref,
 740       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 741
 742   local $SIG{HUP} = 'IGNORE';
 743   local $SIG{INT} = 'IGNORE';
 744   local $SIG{QUIT} = 'IGNORE';
 745   local $SIG{TERM} = 'IGNORE';
 746   local $SIG{TSTP} = 'IGNORE';
 747   local $SIG{PIPE} = 'IGNORE';
 748
 749   my $oldAutoCommit = $FS::UID::AutoCommit;
 750   local $FS::UID::AutoCommit = 0;
 751   my $dbh = dbh;
 752
 753   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 754
 755   my $error = $self->get_prepay( $prepay_credit,
 756                                  'amount_ref'     => \$amount,
 757                                  'seconds_ref'    => \$seconds,
 758                                  'upbytes_ref'    => \$upbytes,
 759                                  'downbytes_ref'  => \$downbytes,
 760                                  'totalbytes_ref' => \$totalbytes,
 761                                )
 762            || $self->increment_seconds($seconds)
 763            || $self->increment_upbytes($upbytes)
 764            || $self->increment_downbytes($downbytes)
 765            || $self->increment_totalbytes($totalbytes)
 766            || $self->insert_cust_pay_prepay( $amount,
 767                                              ref($prepay_credit)
 768                                                ? $prepay_credit->identifier
 769                                                : $prepay_credit
 770                                            );
 771
 772   if ( $error ) {
 773     $dbh->rollback if $oldAutoCommit;
 774     return $error;
 775   }
 776
 777   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 778   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 779   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 780   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 781   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 782
 783   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 784   '';
 785
 786 }
 787
 788 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 789
 790 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 791 specified either by I<identifier> or as an FS::prepay_credit object.
 792
 793 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 794 incremented by the values of the prepaid card.
 795
 796 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 797 check or set this customer's I<agentnum>.
 798
 799 If there is an error, returns the error, otherwise returns false.
 800
 801 =cut
 802
 803
 804 sub get_prepay {
 805   my( $self, $prepay_credit, %opt ) = @_;
 806
 807   local $SIG{HUP} = 'IGNORE';
 808   local $SIG{INT} = 'IGNORE';
 809   local $SIG{QUIT} = 'IGNORE';
 810   local $SIG{TERM} = 'IGNORE';
 811   local $SIG{TSTP} = 'IGNORE';
 812   local $SIG{PIPE} = 'IGNORE';
 813
 814   my $oldAutoCommit = $FS::UID::AutoCommit;
 815   local $FS::UID::AutoCommit = 0;
 816   my $dbh = dbh;
 817
 818   unless ( ref($prepay_credit) ) {
 819
 820     my $identifier = $prepay_credit;
 821
 822     $prepay_credit = qsearchs(
 823       'prepay_credit',
 824       { 'identifier' => $identifier },
 825       '',
 826       'FOR UPDATE'
 827     );
 828
 829     unless ( $prepay_credit ) {
 830       $dbh->rollback if $oldAutoCommit;
 831       return "Invalid prepaid card: ". $identifier;
 832     }
 833
 834   }
 835
 836   if ( $prepay_credit->agentnum ) {
 837     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 838       $dbh->rollback if $oldAutoCommit;
 839       return "prepaid card not valid for agent ". $self->agentnum;
 840     }
 841     $self->agentnum($prepay_credit->agentnum);
 842   }
 843
 844   my $error = $prepay_credit->delete;
 845   if ( $error ) {
 846     $dbh->rollback if $oldAutoCommit;
 847     return "removing prepay_credit (transaction rolled back): $error";
 848   }
 849
 850   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 851     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 852
 853   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 854   '';
 855
 856 }
 857
 858 =item increment_upbytes SECONDS
 859
 860 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 861 the specified number of upbytes.  If there is an error, returns the error,
 862 otherwise returns false.
 863
 864 =cut
 865
 866 sub increment_upbytes {
 867   _increment_column( shift, 'upbytes', @_);
 868 }
 869
 870 =item increment_downbytes SECONDS
 871
 872 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 873 the specified number of downbytes.  If there is an error, returns the error,
 874 otherwise returns false.
 875
 876 =cut
 877
 878 sub increment_downbytes {
 879   _increment_column( shift, 'downbytes', @_);
 880 }
 881
 882 =item increment_totalbytes SECONDS
 883
 884 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 885 the specified number of totalbytes.  If there is an error, returns the error,
 886 otherwise returns false.
 887
 888 =cut
 889
 890 sub increment_totalbytes {
 891   _increment_column( shift, 'totalbytes', @_);
 892 }
 893
 894 =item increment_seconds SECONDS
 895
 896 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 897 the specified number of seconds.  If there is an error, returns the error,
 898 otherwise returns false.
 899
 900 =cut
 901
 902 sub increment_seconds {
 903   _increment_column( shift, 'seconds', @_);
 904 }
 905
 906 =item _increment_column AMOUNT
 907
 908 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 909 the specified number of seconds or bytes.  If there is an error, returns
 910 the error, otherwise returns false.
 911
 912 =cut
 913
 914 sub _increment_column {
 915   my( $self, $column, $amount ) = @_;
 916   warn "$me increment_column called: $column, $amount\n"
 917     if $DEBUG;
 918
 919   return '' unless $amount;
 920
 921   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
 922                       $self->ncancelled_pkgs;
 923
 924   if ( ! @cust_pkg ) {
 925     return 'No packages with primary or single services found'.
 926            ' to apply pre-paid time';
 927   } elsif ( scalar(@cust_pkg) > 1 ) {
 928     #maybe have a way to specify the package/account?
 929     return 'Multiple packages found to apply pre-paid time';
 930   }
 931
 932   my $cust_pkg = $cust_pkg[0];
 933   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
 934     if $DEBUG > 1;
 935
 936   my @cust_svc =
 937     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
 938
 939   if ( ! @cust_svc ) {
 940     return 'No account found to apply pre-paid time';
 941   } elsif ( scalar(@cust_svc) > 1 ) {
 942     return 'Multiple accounts found to apply pre-paid time';
 943   }
 944
 945   my $svc_acct = $cust_svc[0]->svc_x;
 946   warn "  found service svcnum ". $svc_acct->pkgnum.
 947        ' ('. $svc_acct->email. ")\n"
 948     if $DEBUG > 1;
 949
 950   $column = "increment_$column";
 951   $svc_acct->$column($amount);
 952
 953 }
 954
 955 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
 956
 957 Inserts a prepayment in the specified amount for this customer.  An optional
 958 second argument can specify the prepayment identifier for tracking purposes.
 959 If there is an error, returns the error, otherwise returns false.
 960
 961 =cut
 962
 963 sub insert_cust_pay_prepay {
 964   shift->insert_cust_pay('PREP', @_);
 965 }
 966
 967 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
 968
 969 Inserts a cash payment in the specified amount for this customer.  An optional
 970 second argument can specify the payment identifier for tracking purposes.
 971 If there is an error, returns the error, otherwise returns false.
 972
 973 =cut
 974
 975 sub insert_cust_pay_cash {
 976   shift->insert_cust_pay('CASH', @_);
 977 }
 978
 979 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
 980
 981 Inserts a Western Union payment in the specified amount for this customer.  An
 982 optional second argument can specify the prepayment identifier for tracking
 983 purposes.  If there is an error, returns the error, otherwise returns false.
 984
 985 =cut
 986
 987 sub insert_cust_pay_west {
 988   shift->insert_cust_pay('WEST', @_);
 989 }
 990
 991 sub insert_cust_pay {
 992   my( $self, $payby, $amount ) = splice(@_, 0, 3);
 993   my $payinfo = scalar(@_) ? shift : '';
 994
 995   my $cust_pay = new FS::cust_pay {
 996     'custnum' => $self->custnum,
 997     'paid'    => sprintf('%.2f', $amount),
 998     #'_date'   => #date the prepaid card was purchased???
 999     'payby'   => $payby,
1000     'payinfo' => $payinfo,
1001   };
1002   $cust_pay->insert;
1003
1004 }
1005
1006 =item delete [ OPTION => VALUE ... ]
1007
1008 This deletes the customer.  If there is an error, returns the error, otherwise
1009 returns false.
1010
1011 This will completely remove all traces of the customer record.  This is not
1012 what you want when a customer cancels service; for that, cancel all of the
1013 customer's packages (see L</cancel>).
1014
1015 If the customer has any uncancelled packages, you need to pass a new (valid)
1016 customer number for those packages to be transferred to, as the "new_customer"
1017 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1018 what you want when a customer cancels service and that you really should be
1019 looking at L<FS::cust_pkg/cancel>?
1020
1021 You can't delete a customer with invoices (see L<FS::cust_bill>),
1022 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1023 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1024 set the "delete_financials" option to a true value.
1025
1026 =cut
1027
1028 sub delete {
1029   my( $self, %opt ) = @_;
1030
1031   local $SIG{HUP} = 'IGNORE';
1032   local $SIG{INT} = 'IGNORE';
1033   local $SIG{QUIT} = 'IGNORE';
1034   local $SIG{TERM} = 'IGNORE';
1035   local $SIG{TSTP} = 'IGNORE';
1036   local $SIG{PIPE} = 'IGNORE';
1037
1038   my $oldAutoCommit = $FS::UID::AutoCommit;
1039   local $FS::UID::AutoCommit = 0;
1040   my $dbh = dbh;
1041
1042   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1043      $dbh->rollback if $oldAutoCommit;
1044      return "Can't delete a master agent customer";
1045   }
1046
1047   #use FS::access_user
1048   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1049      $dbh->rollback if $oldAutoCommit;
1050      return "Can't delete a master employee customer";
1051   }
1052
1053   tie my %financial_tables, 'Tie::IxHash',
1054     'cust_bill'      => 'invoices',
1055     'cust_statement' => 'statements',
1056     'cust_credit'    => 'credits',
1057     'cust_pay'       => 'payments',
1058     'cust_refund'    => 'refunds',
1059   ;
1060
1061   foreach my $table ( keys %financial_tables ) {
1062
1063     my @records = $self->$table();
1064
1065     if ( @records && ! $opt{'delete_financials'} ) {
1066       $dbh->rollback if $oldAutoCommit;
1067       return "Can't delete a customer with ". $financial_tables{$table};
1068     }
1069
1070     foreach my $record ( @records ) {
1071       my $error = $record->delete;
1072       if ( $error ) {
1073         $dbh->rollback if $oldAutoCommit;
1074         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1075       }
1076     }
1077
1078   }
1079
1080   my @cust_pkg = $self->ncancelled_pkgs;
1081   if ( @cust_pkg ) {
1082     my $new_custnum = $opt{'new_custnum'};
1083     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1084       $dbh->rollback if $oldAutoCommit;
1085       return "Invalid new customer number: $new_custnum";
1086     }
1087     foreach my $cust_pkg ( @cust_pkg ) {
1088       my %hash = $cust_pkg->hash;
1089       $hash{'custnum'} = $new_custnum;
1090       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1091       my $error = $new_cust_pkg->replace($cust_pkg,
1092                                          options => { $cust_pkg->options },
1093                                         );
1094       if ( $error ) {
1095         $dbh->rollback if $oldAutoCommit;
1096         return $error;
1097       }
1098     }
1099   }
1100   my @cancelled_cust_pkg = $self->all_pkgs;
1101   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1102     my $error = $cust_pkg->delete;
1103     if ( $error ) {
1104       $dbh->rollback if $oldAutoCommit;
1105       return $error;
1106     }
1107   }
1108
1109   #cust_tax_adjustment in financials?
1110   #cust_pay_pending?  ouch
1111   #cust_recon?
1112   foreach my $table (qw(
1113     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1114     cust_location cust_main_note cust_tax_adjustment
1115     cust_pay_void cust_pay_batch queue cust_tax_exempt
1116   )) {
1117     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1118       my $error = $record->delete;
1119       if ( $error ) {
1120         $dbh->rollback if $oldAutoCommit;
1121         return $error;
1122       }
1123     }
1124   }
1125
1126   my $sth = $dbh->prepare(
1127     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1128   ) or do {
1129     my $errstr = $dbh->errstr;
1130     $dbh->rollback if $oldAutoCommit;
1131     return $errstr;
1132   };
1133   $sth->execute($self->custnum) or do {
1134     my $errstr = $sth->errstr;
1135     $dbh->rollback if $oldAutoCommit;
1136     return $errstr;
1137   };
1138
1139   #tickets
1140
1141   my $ticket_dbh = '';
1142   if ($conf->config('ticket_system') eq 'RT_Internal') {
1143     $ticket_dbh = $dbh;
1144   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1145     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1146     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1147       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1148   }
1149
1150   if ( $ticket_dbh ) {
1151
1152     my $ticket_sth = $ticket_dbh->prepare(
1153       'DELETE FROM Links WHERE Target = ?'
1154     ) or do {
1155       my $errstr = $ticket_dbh->errstr;
1156       $dbh->rollback if $oldAutoCommit;
1157       return $errstr;
1158     };
1159     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1160       or do {
1161         my $errstr = $ticket_sth->errstr;
1162         $dbh->rollback if $oldAutoCommit;
1163         return $errstr;
1164       };
1165
1166     #check and see if the customer is the only link on the ticket, and
1167     #if so, set the ticket to deleted status in RT?
1168     #maybe someday, for now this will at least fix tickets not displaying
1169
1170   }
1171
1172   #delete the customer record
1173
1174   my $error = $self->SUPER::delete;
1175   if ( $error ) {
1176     $dbh->rollback if $oldAutoCommit;
1177     return $error;
1178   }
1179
1180   # cust_main exports!
1181
1182   #my $export_args = $options{'export_args'} || [];
1183
1184   my @part_export =
1185     map qsearch( 'part_export', {exportnum=>$_} ),
1186       $conf->config('cust_main-exports'); #, $agentnum
1187
1188   foreach my $part_export ( @part_export ) {
1189     my $error = $part_export->export_delete( $self ); #, @$export_args);
1190     if ( $error ) {
1191       $dbh->rollback if $oldAutoCommit;
1192       return "exporting to ". $part_export->exporttype.
1193              " (transaction rolled back): $error";
1194     }
1195   }
1196
1197   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1198   '';
1199
1200 }
1201
1202 =item merge NEW_CUSTNUM [ , OPTION => VALUE ... ]
1203
1204 This merges this customer into the provided new custnum, and then deletes the
1205 customer.  If there is an error, returns the error, otherwise returns false.
1206
1207 The source customer's name, company name, phone numbers, agent,
1208 referring customer, customer class, advertising source, order taker, and
1209 billing information (except balance) are discarded.
1210
1211 All packages are moved to the target customer.  Packages with package locations
1212 are preserved.  Packages without package locations are moved to a new package
1213 location with the source customer's service/shipping address.
1214
1215 All invoices, statements, payments, credits and refunds are moved to the target
1216 customer.  The source customer's balance is added to the target customer.
1217
1218 All notes, attachments, tickets and customer tags are moved to the target
1219 customer.
1220
1221 Change history is not currently moved.
1222
1223 =cut
1224
1225 sub merge {
1226   my( $self, $new_custnum, %opt ) = @_;
1227
1228   return "Can't merge a customer into self" if $self->custnum == $new_custnum;
1229
1230   my $new_cust_main = qsearchs( 'cust_main', { 'custnum' => $new_custnum } )
1231     or return "Invalid new customer number: $new_custnum";
1232
1233   return 'Access denied: "Merge customer across agents" access right required to merge into a customer of a different agent'
1234     if $self->agentnum != $new_cust_main->agentnum
1235     && ! $FS::CurrentUser::CurrentUser->access_right('Merge customer across agents');
1236
1237   local $SIG{HUP} = 'IGNORE';
1238   local $SIG{INT} = 'IGNORE';
1239   local $SIG{QUIT} = 'IGNORE';
1240   local $SIG{TERM} = 'IGNORE';
1241   local $SIG{TSTP} = 'IGNORE';
1242   local $SIG{PIPE} = 'IGNORE';
1243
1244   my $oldAutoCommit = $FS::UID::AutoCommit;
1245   local $FS::UID::AutoCommit = 0;
1246   my $dbh = dbh;
1247
1248   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1249      $dbh->rollback if $oldAutoCommit;
1250      return "Can't merge a master agent customer";
1251   }
1252
1253   #use FS::access_user
1254   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1255      $dbh->rollback if $oldAutoCommit;
1256      return "Can't merge a master employee customer";
1257   }
1258
1259   if ( qsearch('cust_pay_pending', { 'custnum' => $self->custnum,
1260                                      'status'  => { op=>'!=', value=>'done' },
1261                                    }
1262               )
1263   ) {
1264      $dbh->rollback if $oldAutoCommit;
1265      return "Can't merge a customer with pending payments";
1266   }
1267
1268   tie my %financial_tables, 'Tie::IxHash',
1269     'cust_bill'         => 'invoices',
1270     'cust_bill_void'    => 'voided invoices',
1271     'cust_statement'    => 'statements',
1272     'cust_credit'       => 'credits',
1273     'cust_credit_void'  => 'voided credits',
1274     'cust_pay'          => 'payments',
1275     'cust_pay_void'     => 'voided payments',
1276     'cust_refund'       => 'refunds',
1277   ;
1278
1279   foreach my $table ( keys %financial_tables ) {
1280
1281     my @records = $self->$table();
1282
1283     foreach my $record ( @records ) {
1284       $record->custnum($new_custnum);
1285       my $error = $record->replace;
1286       if ( $error ) {
1287         $dbh->rollback if $oldAutoCommit;
1288         return "Error merging ". $financial_tables{$table}. ": $error\n";
1289       }
1290     }
1291
1292   }
1293
1294   my $name = $self->ship_name; #?
1295
1296   my $locationnum = '';
1297   foreach my $cust_pkg ( $self->all_pkgs ) {
1298     $cust_pkg->custnum($new_custnum);
1299
1300     unless ( $cust_pkg->locationnum ) {
1301       unless ( $locationnum ) {
1302         my $cust_location = new FS::cust_location {
1303           $self->location_hash,
1304           'custnum' => $new_custnum,
1305         };
1306         my $error = $cust_location->insert;
1307         if ( $error ) {
1308           $dbh->rollback if $oldAutoCommit;
1309           return $error;
1310         }
1311         $locationnum = $cust_location->locationnum;
1312       }
1313       $cust_pkg->locationnum($locationnum);
1314     }
1315
1316     my $error = $cust_pkg->replace;
1317     if ( $error ) {
1318       $dbh->rollback if $oldAutoCommit;
1319       return $error;
1320     }
1321
1322     # add customer (ship) name to svc_phone.phone_name if blank
1323     my @cust_svc = $cust_pkg->cust_svc;
1324     foreach my $cust_svc (@cust_svc) {
1325       my($label, $value, $svcdb) = $cust_svc->label;
1326       next unless $svcdb eq 'svc_phone';
1327       my $svc_phone = $cust_svc->svc_x;
1328       next if $svc_phone->phone_name;
1329       $svc_phone->phone_name($name);
1330       my $error = $svc_phone->replace;
1331       if ( $error ) {
1332         $dbh->rollback if $oldAutoCommit;
1333         return $error;
1334       }
1335     }
1336
1337   }
1338
1339   #not considered:
1340   # cust_tax_exempt (texas tax exemptions)
1341   # cust_recon (some sort of not-well understood thing for OnPac)
1342
1343   #these are moved over
1344   foreach my $table (qw(
1345     cust_tag cust_location contact cust_attachment cust_main_note
1346     cust_tax_adjustment cust_pay_batch queue
1347   )) {
1348     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1349       $record->custnum($new_custnum);
1350       my $error = $record->replace;
1351       if ( $error ) {
1352         $dbh->rollback if $oldAutoCommit;
1353         return $error;
1354       }
1355     }
1356   }
1357
1358   #these aren't preserved
1359   foreach my $table (qw(
1360     cust_main_exemption cust_main_invoice
1361   )) {
1362     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1363       my $error = $record->delete;
1364       if ( $error ) {
1365         $dbh->rollback if $oldAutoCommit;
1366         return $error;
1367       }
1368     }
1369   }
1370
1371
1372   my $sth = $dbh->prepare(
1373     'UPDATE cust_main SET referral_custnum = ? WHERE referral_custnum = ?'
1374   ) or do {
1375     my $errstr = $dbh->errstr;
1376     $dbh->rollback if $oldAutoCommit;
1377     return $errstr;
1378   };
1379   $sth->execute($new_custnum, $self->custnum) or do {
1380     my $errstr = $sth->errstr;
1381     $dbh->rollback if $oldAutoCommit;
1382     return $errstr;
1383   };
1384
1385   #tickets
1386
1387   my $ticket_dbh = '';
1388   if ($conf->config('ticket_system') eq 'RT_Internal') {
1389     $ticket_dbh = $dbh;
1390   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1391     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1392     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1393       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1394   }
1395
1396   if ( $ticket_dbh ) {
1397
1398     my $ticket_sth = $ticket_dbh->prepare(
1399       'UPDATE Links SET Target = ? WHERE Target = ?'
1400     ) or do {
1401       my $errstr = $ticket_dbh->errstr;
1402       $dbh->rollback if $oldAutoCommit;
1403       return $errstr;
1404     };
1405     $ticket_sth->execute('freeside://freeside/cust_main/'.$new_custnum,
1406                          'freeside://freeside/cust_main/'.$self->custnum)
1407       or do {
1408         my $errstr = $ticket_sth->errstr;
1409         $dbh->rollback if $oldAutoCommit;
1410         return $errstr;
1411       };
1412
1413   }
1414
1415   #delete the customer record
1416
1417   my $error = $self->delete;
1418   if ( $error ) {
1419     $dbh->rollback if $oldAutoCommit;
1420     return $error;
1421   }
1422
1423   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1424   '';
1425
1426 }
1427
1428 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1429
1430 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1431 returns the error, otherwise returns false.
1432
1433 To change the customer's address, set the pseudo-fields C<bill_location> and
1434 C<ship_location>.  The address will still only change if at least one of the
1435 address fields differs from the existing values.
1436
1437 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
1438 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
1439 expected and rollback the entire transaction; it is not necessary to call
1440 check_invoicing_list first.  Here's an example:
1441
1442   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
1443
1444 Currently available options are: I<tax_exemption>.
1445
1446 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1447 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1448 deleted and inserted as appropriate.
1449
1450 =cut
1451
1452 sub replace {
1453   my $self = shift;
1454
1455   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1456               ? shift
1457               : $self->replace_old;
1458
1459   my @param = @_;
1460
1461   warn "$me replace called\n"
1462     if $DEBUG;
1463
1464   my $curuser = $FS::CurrentUser::CurrentUser;
1465   if (    $self->payby eq 'COMP'
1466        && $self->payby ne $old->payby
1467        && ! $curuser->access_right('Complimentary customer')
1468      )
1469   {
1470     return "You are not permitted to create complimentary accounts.";
1471   }
1472
1473   local($ignore_expired_card) = 1
1474     if $old->payby  =~ /^(CARD|DCRD)$/
1475     && $self->payby =~ /^(CARD|DCRD)$/
1476     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1477
1478   local($ignore_banned_card) = 1
1479     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1480          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1481     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1482
1483   return "Invoicing locale is required"
1484     if $old->locale
1485     && ! $self->locale
1486     && $conf->exists('cust_main-require_locale');
1487
1488   local $SIG{HUP} = 'IGNORE';
1489   local $SIG{INT} = 'IGNORE';
1490   local $SIG{QUIT} = 'IGNORE';
1491   local $SIG{TERM} = 'IGNORE';
1492   local $SIG{TSTP} = 'IGNORE';
1493   local $SIG{PIPE} = 'IGNORE';
1494
1495   my $oldAutoCommit = $FS::UID::AutoCommit;
1496   local $FS::UID::AutoCommit = 0;
1497   my $dbh = dbh;
1498
1499   for my $l (qw(bill_location ship_location)) {
1500     my $old_loc = $old->$l;
1501     my $new_loc = $self->$l;
1502
1503     # find the existing location if there is one
1504     $new_loc->set('custnum' => $self->custnum);
1505     my $error = $new_loc->find_or_insert;
1506     if ( $error ) {
1507       $dbh->rollback if $oldAutoCommit;
1508       return $error;
1509     }
1510     $self->set($l.'num', $new_loc->locationnum);
1511   } #for $l
1512
1513   # replace the customer record
1514   my $error = $self->SUPER::replace($old);
1515
1516   if ( $error ) {
1517     $dbh->rollback if $oldAutoCommit;
1518     return $error;
1519   }
1520
1521   # now move packages to the new service location
1522   $self->set('ship_location', ''); #flush cache
1523   if ( $old->ship_locationnum and # should only be null during upgrade...
1524        $old->ship_locationnum != $self->ship_locationnum ) {
1525     $error = $old->ship_location->move_to($self->ship_location);
1526     if ( $error ) {
1527       $dbh->rollback if $oldAutoCommit;
1528       return $error;
1529     }
1530   }
1531   # don't move packages based on the billing location, but
1532   # disable it if it's no longer in use
1533   if ( $old->bill_locationnum and
1534        $old->bill_locationnum != $self->bill_locationnum ) {
1535     $error = $old->bill_location->disable_if_unused;
1536     if ( $error ) {
1537       $dbh->rollback if $oldAutoCommit;
1538       return $error;
1539     }
1540   }
1541
1542   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1543     my $invoicing_list = shift @param;
1544     $error = $self->check_invoicing_list( $invoicing_list );
1545     if ( $error ) {
1546       $dbh->rollback if $oldAutoCommit;
1547       return $error;
1548     }
1549     $self->invoicing_list( $invoicing_list );
1550   }
1551
1552   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1553
1554     #this could be more efficient than deleting and re-inserting, if it matters
1555     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1556       my $error = $cust_tag->delete;
1557       if ( $error ) {
1558         $dbh->rollback if $oldAutoCommit;
1559         return $error;
1560       }
1561     }
1562     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1563       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1564                                         'custnum' => $self->custnum };
1565       my $error = $cust_tag->insert;
1566       if ( $error ) {
1567         $dbh->rollback if $oldAutoCommit;
1568         return $error;
1569       }
1570     }
1571
1572   }
1573
1574   my %options = @param;
1575
1576   my $tax_exemption = delete $options{'tax_exemption'};
1577   if ( $tax_exemption ) {
1578
1579     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1580       if ref($tax_exemption) eq 'ARRAY';
1581
1582     my %cust_main_exemption =
1583       map { $_->taxname => $_ }
1584           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1585
1586     foreach my $taxname ( keys %$tax_exemption ) {
1587
1588       if ( $cust_main_exemption{$taxname} &&
1589            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1590          )
1591       {
1592         delete $cust_main_exemption{$taxname};
1593         next;
1594       }
1595
1596       my $cust_main_exemption = new FS::cust_main_exemption {
1597         'custnum'       => $self->custnum,
1598         'taxname'       => $taxname,
1599         'exempt_number' => $tax_exemption->{$taxname},
1600       };
1601       my $error = $cust_main_exemption->insert;
1602       if ( $error ) {
1603         $dbh->rollback if $oldAutoCommit;
1604         return "inserting cust_main_exemption (transaction rolled back): $error";
1605       }
1606     }
1607
1608     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1609       my $error = $cust_main_exemption->delete;
1610       if ( $error ) {
1611         $dbh->rollback if $oldAutoCommit;
1612         return "deleting cust_main_exemption (transaction rolled back): $error";
1613       }
1614     }
1615
1616   }
1617
1618   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/
1619        && ( ( $self->get('payinfo') ne $old->get('payinfo')
1620               && $self->get('payinfo') !~ /^99\d{14}$/
1621             )
1622             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
1623           )
1624      )
1625   {
1626
1627     # card/check/lec info has changed, want to retry realtime_ invoice events
1628     my $error = $self->retry_realtime;
1629     if ( $error ) {
1630       $dbh->rollback if $oldAutoCommit;
1631       return $error;
1632     }
1633   }
1634
1635   unless ( $import || $skip_fuzzyfiles ) {
1636     $error = $self->queue_fuzzyfiles_update;
1637     if ( $error ) {
1638       $dbh->rollback if $oldAutoCommit;
1639       return "updating fuzzy search cache: $error";
1640     }
1641   }
1642
1643   # tax district update in cust_location
1644
1645   # cust_main exports!
1646
1647   my $export_args = $options{'export_args'} || [];
1648
1649   my @part_export =
1650     map qsearch( 'part_export', {exportnum=>$_} ),
1651       $conf->config('cust_main-exports'); #, $agentnum
1652
1653   foreach my $part_export ( @part_export ) {
1654     my $error = $part_export->export_replace( $self, $old, @$export_args);
1655     if ( $error ) {
1656       $dbh->rollback if $oldAutoCommit;
1657       return "exporting to ". $part_export->exporttype.
1658              " (transaction rolled back): $error";
1659     }
1660   }
1661
1662   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1663   '';
1664
1665 }
1666
1667 =item queue_fuzzyfiles_update
1668
1669 Used by insert & replace to update the fuzzy search cache
1670
1671 =cut
1672
1673 use FS::cust_main::Search;
1674 sub queue_fuzzyfiles_update {
1675   my $self = shift;
1676
1677   local $SIG{HUP} = 'IGNORE';
1678   local $SIG{INT} = 'IGNORE';
1679   local $SIG{QUIT} = 'IGNORE';
1680   local $SIG{TERM} = 'IGNORE';
1681   local $SIG{TSTP} = 'IGNORE';
1682   local $SIG{PIPE} = 'IGNORE';
1683
1684   my $oldAutoCommit = $FS::UID::AutoCommit;
1685   local $FS::UID::AutoCommit = 0;
1686   my $dbh = dbh;
1687
1688   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1689     my $queue = new FS::queue {
1690       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1691     };
1692     my @args = "cust_main.$field", $self->get($field);
1693     my $error = $queue->insert( @args );
1694     if ( $error ) {
1695       $dbh->rollback if $oldAutoCommit;
1696       return "queueing job (transaction rolled back): $error";
1697     }
1698   }
1699
1700   my @locations = ();
1701   push @locations, $self->bill_location if $self->bill_locationnum;
1702   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1703   foreach my $location (@locations) {
1704     my $queue = new FS::queue {
1705       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1706     };
1707     my @args = 'cust_location.address1', $location->address1;
1708     my $error = $queue->insert( @args );
1709     if ( $error ) {
1710       $dbh->rollback if $oldAutoCommit;
1711       return "queueing job (transaction rolled back): $error";
1712     }
1713   }
1714
1715   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1716   '';
1717
1718 }
1719
1720 =item check
1721
1722 Checks all fields to make sure this is a valid customer record.  If there is
1723 an error, returns the error, otherwise returns false.  Called by the insert
1724 and replace methods.
1725
1726 =cut
1727
1728 sub check {
1729   my $self = shift;
1730
1731   warn "$me check BEFORE: \n". $self->_dump
1732     if $DEBUG > 2;
1733
1734   my $error =
1735     $self->ut_numbern('custnum')
1736     || $self->ut_number('agentnum')
1737     || $self->ut_textn('agent_custid')
1738     || $self->ut_number('refnum')
1739     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1740     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1741     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1742     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1743     || $self->ut_textn('custbatch')
1744     || $self->ut_name('last')
1745     || $self->ut_name('first')
1746     || $self->ut_snumbern('signupdate')
1747     || $self->ut_snumbern('birthdate')
1748     || $self->ut_namen('spouse_last')
1749     || $self->ut_namen('spouse_first')
1750     || $self->ut_snumbern('spouse_birthdate')
1751     || $self->ut_snumbern('anniversary_date')
1752     || $self->ut_textn('company')
1753     || $self->ut_textn('ship_company')
1754     || $self->ut_anything('comments')
1755     || $self->ut_numbern('referral_custnum')
1756     || $self->ut_textn('stateid')
1757     || $self->ut_textn('stateid_state')
1758     || $self->ut_textn('invoice_terms')
1759     || $self->ut_floatn('cdr_termination_percentage')
1760     || $self->ut_floatn('credit_limit')
1761     || $self->ut_numbern('billday')
1762     || $self->ut_numbern('prorate_day')
1763     || $self->ut_flag('edit_subject')
1764     || $self->ut_flag('calling_list_exempt')
1765     || $self->ut_flag('invoice_noemail')
1766     || $self->ut_flag('message_noemail')
1767     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1768     || $self->ut_currencyn('currency')
1769   ;
1770
1771   foreach (qw(company ship_company)) {
1772     my $company = $self->get($_);
1773     $company =~ s/^\s+//;
1774     $company =~ s/\s+$//;
1775     $company =~ s/\s+/ /g;
1776     $self->set($_, $company);
1777   }
1778
1779   #barf.  need message catalogs.  i18n.  etc.
1780   $error .= "Please select an advertising source."
1781     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1782   return $error if $error;
1783
1784   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1785     or return "Unknown agent";
1786
1787   if ( $self->currency ) {
1788     my $agent_currency = qsearchs( 'agent_currency', {
1789       'agentnum' => $agent->agentnum,
1790       'currency' => $self->currency,
1791     })
1792       or return "Agent ". $agent->agent.
1793                 " not permitted to offer ".  $self->currency. " invoicing";
1794   }
1795
1796   return "Unknown refnum"
1797     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1798
1799   return "Unknown referring custnum: ". $self->referral_custnum
1800     unless ! $self->referral_custnum
1801            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1802
1803   if ( $self->ss eq '' ) {
1804     $self->ss('');
1805   } else {
1806     my $ss = $self->ss;
1807     $ss =~ s/\D//g;
1808     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1809       or return "Illegal social security number: ". $self->ss;
1810     $self->ss("$1-$2-$3");
1811   }
1812
1813   # cust_main_county verification now handled by cust_location check
1814
1815   $error =
1816        $self->ut_phonen('daytime', $self->country)
1817     || $self->ut_phonen('night',   $self->country)
1818     || $self->ut_phonen('fax',     $self->country)
1819     || $self->ut_phonen('mobile',  $self->country)
1820   ;
1821   return $error if $error;
1822
1823   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1824        && ! $import
1825        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1826      ) {
1827
1828     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1829                           ? 'Day Phone'
1830                           : FS::Msgcat::_gettext('daytime');
1831     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1832                         ? 'Night Phone'
1833                         : FS::Msgcat::_gettext('night');
1834
1835     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1836                         ? 'Mobile Phone'
1837                         : FS::Msgcat::_gettext('mobile');
1838
1839     return "$daytime_label, $night_label or $mobile_label is required"
1840
1841   }
1842
1843   ### start of stuff moved to cust_payby
1844   # then mostly kept here to support upgrades (can remove in 5.x)
1845   #  but modified to allow everything to be empty
1846
1847   if ( $self->payby ) {
1848     FS::payby->can_payby($self->table, $self->payby)
1849       or return "Illegal payby: ". $self->payby;
1850   } else {
1851     $self->payby('');
1852   }
1853
1854   $error =    $self->ut_numbern('paystart_month')
1855            || $self->ut_numbern('paystart_year')
1856            || $self->ut_numbern('payissue')
1857            || $self->ut_textn('paytype')
1858   ;
1859   return $error if $error;
1860
1861   if ( $self->payip eq '' ) {
1862     $self->payip('');
1863   } else {
1864     $error = $self->ut_ip('payip');
1865     return $error if $error;
1866   }
1867
1868   # If it is encrypted and the private key is not availaible then we can't
1869   # check the credit card.
1870   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1871
1872   # Need some kind of global flag to accept invalid cards, for testing
1873   # on scrubbed data.
1874   if ( !$import && !$ignore_invalid_card && $check_payinfo &&
1875     $self->payby =~ /^(CARD|DCRD)$/ ) {
1876
1877     my $payinfo = $self->payinfo;
1878     $payinfo =~ s/\D//g;
1879     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1880       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1881     $payinfo = $1;
1882     $self->payinfo($payinfo);
1883     validate($payinfo)
1884       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1885
1886     return gettext('unknown_card_type')
1887       if $self->payinfo !~ /^99\d{14}$/ #token
1888       && cardtype($self->payinfo) eq "Unknown";
1889
1890     unless ( $ignore_banned_card ) {
1891       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1892       if ( $ban ) {
1893         if ( $ban->bantype eq 'warn' ) {
1894           #or others depending on value of $ban->reason ?
1895           return '_duplicate_card'.
1896                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1897                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1898                  ' (ban# '. $ban->bannum. ')'
1899             unless $self->override_ban_warn;
1900         } else {
1901           return 'Banned credit card: banned on '.
1902                  time2str('%a %h %o at %r', $ban->_date).
1903                  ' by '. $ban->otaker.
1904                  ' (ban# '. $ban->bannum. ')';
1905         }
1906       }
1907     }
1908
1909     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1910       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1911         $self->paycvv =~ /^(\d{4})$/
1912           or return "CVV2 (CID) for American Express cards is four digits.";
1913         $self->paycvv($1);
1914       } else {
1915         $self->paycvv =~ /^(\d{3})$/
1916           or return "CVV2 (CVC2/CID) is three digits.";
1917         $self->paycvv($1);
1918       }
1919     } else {
1920       $self->paycvv('');
1921     }
1922
1923     my $cardtype = cardtype($payinfo);
1924     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1925
1926       return "Start date or issue number is required for $cardtype cards"
1927         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1928
1929       return "Start month must be between 1 and 12"
1930         if $self->paystart_month
1931            and $self->paystart_month < 1 || $self->paystart_month > 12;
1932
1933       return "Start year must be 1990 or later"
1934         if $self->paystart_year
1935            and $self->paystart_year < 1990;
1936
1937       return "Issue number must be beween 1 and 99"
1938         if $self->payissue
1939           and $self->payissue < 1 || $self->payissue > 99;
1940
1941     } else {
1942       $self->paystart_month('');
1943       $self->paystart_year('');
1944       $self->payissue('');
1945     }
1946
1947   } elsif ( !$ignore_invalid_card && $check_payinfo &&
1948     $self->payby =~ /^(CHEK|DCHK)$/ ) {
1949
1950     my $payinfo = $self->payinfo;
1951     $payinfo =~ s/[^\d\@\.]//g;
1952     if ( $conf->config('echeck-country') eq 'CA' ) {
1953       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1954         or return 'invalid echeck account@branch.bank';
1955       $payinfo = "$1\@$2.$3";
1956     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1957       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1958       $payinfo = "$1\@$2";
1959     } else {
1960       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1961       $payinfo = "$1\@$2";
1962     }
1963     $self->payinfo($payinfo);
1964     $self->paycvv('');
1965
1966     unless ( $ignore_banned_card ) {
1967       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1968       if ( $ban ) {
1969         if ( $ban->bantype eq 'warn' ) {
1970           #or others depending on value of $ban->reason ?
1971           return '_duplicate_ach' unless $self->override_ban_warn;
1972         } else {
1973           return 'Banned ACH account: banned on '.
1974                  time2str('%a %h %o at %r', $ban->_date).
1975                  ' by '. $ban->otaker.
1976                  ' (ban# '. $ban->bannum. ')';
1977         }
1978       }
1979     }
1980
1981   } elsif ( $self->payby eq 'LECB' ) {
1982
1983     my $payinfo = $self->payinfo;
1984     $payinfo =~ s/\D//g;
1985     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
1986     $payinfo = $1;
1987     $self->payinfo($payinfo);
1988     $self->paycvv('');
1989
1990   } elsif ( $self->payby eq 'BILL' ) {
1991
1992     $error = $self->ut_textn('payinfo');
1993     return "Illegal P.O. number: ". $self->payinfo if $error;
1994     $self->paycvv('');
1995
1996   } elsif ( $self->payby eq 'COMP' ) {
1997
1998     my $curuser = $FS::CurrentUser::CurrentUser;
1999     if (    ! $self->custnum
2000          && ! $curuser->access_right('Complimentary customer')
2001        )
2002     {
2003       return "You are not permitted to create complimentary accounts."
2004     }
2005
2006     $error = $self->ut_textn('payinfo');
2007     return "Illegal comp account issuer: ". $self->payinfo if $error;
2008     $self->paycvv('');
2009
2010   } elsif ( $self->payby eq 'PREPAY' ) {
2011
2012     my $payinfo = $self->payinfo;
2013     $payinfo =~ s/\W//g; #anything else would just confuse things
2014     $self->payinfo($payinfo);
2015     $error = $self->ut_alpha('payinfo');
2016     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2017     return "Unknown prepayment identifier"
2018       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2019     $self->paycvv('');
2020
2021   }
2022
2023   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2024     return "Expiration date required"
2025       # shouldn't payinfo_check do this?
2026       unless ! $self->payby
2027             || $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD|PPAL)$/;
2028     $self->paydate('');
2029   } else {
2030     my( $m, $y );
2031     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2032       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2033     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2034       ( $m, $y ) = ( $2, "19$1" );
2035     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2036       ( $m, $y ) = ( $3, "20$2" );
2037     } else {
2038       return "Illegal expiration date: ". $self->paydate;
2039     }
2040     $m = sprintf('%02d',$m);
2041     $self->paydate("$y-$m-01");
2042     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2043     return gettext('expired_card')
2044       if !$import
2045       && !$ignore_expired_card
2046       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2047   }
2048
2049   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2050        ( ! $conf->exists('require_cardname')
2051          || $self->payby !~ /^(CARD|DCRD)$/  )
2052   ) {
2053     $self->payname( $self->first. " ". $self->getfield('last') );
2054   } else {
2055
2056     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2057       $self->payname =~ /^([\w \,\.\-\']*)$/
2058         or return gettext('illegal_name'). " payname: ". $self->payname;
2059       $self->payname($1);
2060     } else {
2061       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
2062         or return gettext('illegal_name'). " payname: ". $self->payname;
2063       $self->payname($1);
2064     }
2065
2066   }
2067
2068   ### end of stuff moved to cust_payby
2069
2070   return "Please select an invoicing locale"
2071     if ! $self->locale
2072     && ! $self->custnum
2073     && $conf->exists('cust_main-require_locale');
2074
2075   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2076     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2077     $self->$flag($1);
2078   }
2079
2080   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2081
2082   warn "$me check AFTER: \n". $self->_dump
2083     if $DEBUG > 2;
2084
2085   $self->SUPER::check;
2086 }
2087
2088 =item addr_fields
2089
2090 Returns a list of fields which have ship_ duplicates.
2091
2092 =cut
2093
2094 sub addr_fields {
2095   qw( last first company
2096       address1 address2 city county state zip country
2097       latitude longitude
2098       daytime night fax mobile
2099     );
2100 }
2101
2102 =item has_ship_address
2103
2104 Returns true if this customer record has a separate shipping address.
2105
2106 =cut
2107
2108 sub has_ship_address {
2109   my $self = shift;
2110   $self->bill_locationnum != $self->ship_locationnum;
2111 }
2112
2113 =item location_hash
2114
2115 Returns a list of key/value pairs, with the following keys: address1,
2116 adddress2, city, county, state, zip, country, district, and geocode.  The
2117 shipping address is used if present.
2118
2119 =cut
2120
2121 sub location_hash {
2122   my $self = shift;
2123   $self->ship_location->location_hash;
2124 }
2125
2126 =item cust_location
2127
2128 Returns all locations (see L<FS::cust_location>) for this customer.
2129
2130 =cut
2131
2132 sub cust_location {
2133   my $self = shift;
2134   qsearch('cust_location', { 'custnum'     => $self->custnum,
2135                              'prospectnum' => '' } );
2136 }
2137
2138 =item cust_contact
2139
2140 Returns all contacts (see L<FS::contact>) for this customer.
2141
2142 =cut
2143
2144 #already used :/ sub contact {
2145 sub cust_contact {
2146   my $self = shift;
2147   qsearch('contact', { 'custnum' => $self->custnum } );
2148 }
2149
2150 =item cust_payby
2151
2152 Returns all payment methods (see L<FS::cust_payby>) for this customer.
2153
2154 =cut
2155
2156 sub cust_payby {
2157   my $self = shift;
2158   qsearch({
2159     'table'    => 'cust_payby',
2160     'hashref'  => { 'custnum' => $self->custnum },
2161     'order_by' => 'ORDER BY weight ASC',
2162   });
2163 }
2164
2165 =item unsuspend
2166
2167 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2168 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
2169 on success or a list of errors.
2170
2171 =cut
2172
2173 sub unsuspend {
2174   my $self = shift;
2175   grep { $_->unsuspend } $self->suspended_pkgs;
2176 }
2177
2178 =item suspend
2179
2180 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2181
2182 Returns a list: an empty list on success or a list of errors.
2183
2184 =cut
2185
2186 sub suspend {
2187   my $self = shift;
2188   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2189 }
2190
2191 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2192
2193 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2194 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2195 of a list of pkgparts; the hashref has the following keys:
2196
2197 =over 4
2198
2199 =item pkgparts - listref of pkgparts
2200
2201 =item (other options are passed to the suspend method)
2202
2203 =back
2204
2205
2206 Returns a list: an empty list on success or a list of errors.
2207
2208 =cut
2209
2210 sub suspend_if_pkgpart {
2211   my $self = shift;
2212   my (@pkgparts, %opt);
2213   if (ref($_[0]) eq 'HASH'){
2214     @pkgparts = @{$_[0]{pkgparts}};
2215     %opt      = %{$_[0]};
2216   }else{
2217     @pkgparts = @_;
2218   }
2219   grep { $_->suspend(%opt) }
2220     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2221       $self->unsuspended_pkgs;
2222 }
2223
2224 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2225
2226 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2227 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2228 instead of a list of pkgparts; the hashref has the following keys:
2229
2230 =over 4
2231
2232 =item pkgparts - listref of pkgparts
2233
2234 =item (other options are passed to the suspend method)
2235
2236 =back
2237
2238 Returns a list: an empty list on success or a list of errors.
2239
2240 =cut
2241
2242 sub suspend_unless_pkgpart {
2243   my $self = shift;
2244   my (@pkgparts, %opt);
2245   if (ref($_[0]) eq 'HASH'){
2246     @pkgparts = @{$_[0]{pkgparts}};
2247     %opt      = %{$_[0]};
2248   }else{
2249     @pkgparts = @_;
2250   }
2251   grep { $_->suspend(%opt) }
2252     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2253       $self->unsuspended_pkgs;
2254 }
2255
2256 =item cancel [ OPTION => VALUE ... ]
2257
2258 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2259
2260 Available options are:
2261
2262 =over 4
2263
2264 =item quiet - can be set true to supress email cancellation notices.
2265
2266 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2267
2268 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2269
2270 =item nobill - can be set true to skip billing if it might otherwise be done.
2271
2272 =back
2273
2274 Always returns a list: an empty list on success or a list of errors.
2275
2276 =cut
2277
2278 # nb that dates are not specified as valid options to this method
2279
2280 sub cancel {
2281   my( $self, %opt ) = @_;
2282
2283   warn "$me cancel called on customer ". $self->custnum. " with options ".
2284        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2285     if $DEBUG;
2286
2287   return ( 'access denied' )
2288     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2289
2290   if ( $opt{'ban'} && $self->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/ ) {
2291
2292     #should try decryption (we might have the private key)
2293     # and if not maybe queue a job for the server that does?
2294     return ( "Can't (yet) ban encrypted credit cards" )
2295       if $self->is_encrypted($self->payinfo);
2296
2297     my $ban = new FS::banned_pay $self->_new_banned_pay_hashref;
2298     my $error = $ban->insert;
2299     return ( $error ) if $error;
2300
2301   }
2302
2303   my @pkgs = $self->ncancelled_pkgs;
2304
2305   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2306     $opt{nobill} = 1;
2307     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2308     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2309       if $error;
2310   }
2311
2312   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2313        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2314     if $DEBUG;
2315
2316   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2317 }
2318
2319 sub _banned_pay_hashref {
2320   my $self = shift;
2321
2322   my %payby2ban = (
2323     'CARD' => 'CARD',
2324     'DCRD' => 'CARD',
2325     'CHEK' => 'CHEK',
2326     'DCHK' => 'CHEK'
2327   );
2328
2329   {
2330     'payby'   => $payby2ban{$self->payby},
2331     'payinfo' => $self->payinfo,
2332     #don't ever *search* on reason! #'reason'  =>
2333   };
2334 }
2335
2336 sub _new_banned_pay_hashref {
2337   my $self = shift;
2338   my $hr = $self->_banned_pay_hashref;
2339   $hr->{payinfo} = md5_base64($hr->{payinfo});
2340   $hr;
2341 }
2342
2343 =item notes
2344
2345 Returns all notes (see L<FS::cust_main_note>) for this customer.
2346
2347 =cut
2348
2349 sub notes {
2350   my($self,$orderby_classnum) = (shift,shift);
2351   my $orderby = "_DATE DESC";
2352   $orderby = "CLASSNUM ASC, $orderby" if $orderby_classnum;
2353   qsearch( 'cust_main_note',
2354            { 'custnum' => $self->custnum },
2355            '',
2356            "ORDER BY $orderby",
2357          );
2358 }
2359
2360 =item agent
2361
2362 Returns the agent (see L<FS::agent>) for this customer.
2363
2364 =item agent_name
2365
2366 Returns the agent name (see L<FS::agent>) for this customer.
2367
2368 =cut
2369
2370 sub agent_name {
2371   my $self = shift;
2372   $self->agent->agent;
2373 }
2374
2375 =item cust_tag
2376
2377 Returns any tags associated with this customer, as FS::cust_tag objects,
2378 or an empty list if there are no tags.
2379
2380 =item part_tag
2381
2382 Returns any tags associated with this customer, as FS::part_tag objects,
2383 or an empty list if there are no tags.
2384
2385 =cut
2386
2387 sub part_tag {
2388   my $self = shift;
2389   map $_->part_tag, $self->cust_tag;
2390 }
2391
2392
2393 =item cust_class
2394
2395 Returns the customer class, as an FS::cust_class object, or the empty string
2396 if there is no customer class.
2397
2398 =item categoryname
2399
2400 Returns the customer category name, or the empty string if there is no customer
2401 category.
2402
2403 =cut
2404
2405 sub categoryname {
2406   my $self = shift;
2407   my $cust_class = $self->cust_class;
2408   $cust_class
2409     ? $cust_class->categoryname
2410     : '';
2411 }
2412
2413 =item classname
2414
2415 Returns the customer class name, or the empty string if there is no customer
2416 class.
2417
2418 =cut
2419
2420 sub classname {
2421   my $self = shift;
2422   my $cust_class = $self->cust_class;
2423   $cust_class
2424     ? $cust_class->classname
2425     : '';
2426 }
2427
2428 =item BILLING METHODS
2429
2430 Documentation on billing methods has been moved to
2431 L<FS::cust_main::Billing>.
2432
2433 =item REALTIME BILLING METHODS
2434
2435 Documentation on realtime billing methods has been moved to
2436 L<FS::cust_main::Billing_Realtime>.
2437
2438 =item remove_cvv
2439
2440 Removes the I<paycvv> field from the database directly.
2441
2442 If there is an error, returns the error, otherwise returns false.
2443
2444 =cut
2445
2446 sub remove_cvv {
2447   my $self = shift;
2448   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2449     or return dbh->errstr;
2450   $sth->execute($self->custnum)
2451     or return $sth->errstr;
2452   $self->paycvv('');
2453   '';
2454 }
2455
2456 =item batch_card OPTION => VALUE...
2457
2458 Adds a payment for this invoice to the pending credit card batch (see
2459 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
2460 runs the payment using a realtime gateway.
2461
2462 Options may include:
2463
2464 B<amount>: the amount to be paid; defaults to the customer's balance minus
2465 any payments in transit.
2466
2467 B<payby>: the payment method; defaults to cust_main.payby
2468
2469 B<realtime>: runs this as a realtime payment instead of adding it to a
2470 batch.  Deprecated.
2471
2472 B<invnum>: sets cust_pay_batch.invnum.
2473
2474 B<address1>, B<address2>, B<city>, B<state>, B<zip>, B<country>: sets
2475 the billing address for the payment; defaults to the customer's billing
2476 location.
2477
2478 B<payinfo>, B<paydate>, B<payname>: sets the payment account, expiration
2479 date, and name; defaults to those fields in cust_main.
2480
2481 =cut
2482
2483 sub batch_card {
2484   my ($self, %options) = @_;
2485
2486   my $amount;
2487   if (exists($options{amount})) {
2488     $amount = $options{amount};
2489   }else{
2490     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
2491   }
2492   return '' unless $amount > 0;
2493
2494   my $invnum = delete $options{invnum};
2495   my $payby = $options{payby} || $self->payby;  #still dubious
2496
2497   if ($options{'realtime'}) {
2498     return $self->realtime_bop( FS::payby->payby2bop($self->payby),
2499                                 $amount,
2500                                 %options,
2501                               );
2502   }
2503
2504   my $oldAutoCommit = $FS::UID::AutoCommit;
2505   local $FS::UID::AutoCommit = 0;
2506   my $dbh = dbh;
2507
2508   #this needs to handle mysql as well as Pg, like svc_acct.pm
2509   #(make it into a common function if folks need to do batching with mysql)
2510   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
2511     or return "Cannot lock pay_batch: " . $dbh->errstr;
2512
2513   my %pay_batch = (
2514     'status' => 'O',
2515     'payby'  => FS::payby->payby2payment($payby),
2516   );
2517   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
2518
2519   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
2520
2521   unless ( $pay_batch ) {
2522     $pay_batch = new FS::pay_batch \%pay_batch;
2523     my $error = $pay_batch->insert;
2524     if ( $error ) {
2525       $dbh->rollback if $oldAutoCommit;
2526       die "error creating new batch: $error\n";
2527     }
2528   }
2529
2530   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
2531       'batchnum' => $pay_batch->batchnum,
2532       'custnum'  => $self->custnum,
2533   } );
2534
2535   foreach (qw( address1 address2 city state zip country latitude longitude
2536                payby payinfo paydate payname ))
2537   {
2538     $options{$_} = '' unless exists($options{$_});
2539   }
2540
2541   my $loc = $self->bill_location;
2542
2543   my $cust_pay_batch = new FS::cust_pay_batch ( {
2544     'batchnum' => $pay_batch->batchnum,
2545     'invnum'   => $invnum || 0,                    # is there a better value?
2546                                                    # this field should be
2547                                                    # removed...
2548                                                    # cust_bill_pay_batch now
2549     'custnum'  => $self->custnum,
2550     'last'     => $self->getfield('last'),
2551     'first'    => $self->getfield('first'),
2552     'address1' => $options{address1} || $loc->address1,
2553     'address2' => $options{address2} || $loc->address2,
2554     'city'     => $options{city}     || $loc->city,
2555     'state'    => $options{state}    || $loc->state,
2556     'zip'      => $options{zip}      || $loc->zip,
2557     'country'  => $options{country}  || $loc->country,
2558     'payby'    => $options{payby}    || $self->payby,
2559     'payinfo'  => $options{payinfo}  || $self->payinfo,
2560     'exp'      => $options{paydate}  || $self->paydate,
2561     'payname'  => $options{payname}  || $self->payname,
2562     'amount'   => $amount,                         # consolidating
2563   } );
2564
2565   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
2566     if $old_cust_pay_batch;
2567
2568   my $error;
2569   if ($old_cust_pay_batch) {
2570     $error = $cust_pay_batch->replace($old_cust_pay_batch)
2571   } else {
2572     $error = $cust_pay_batch->insert;
2573   }
2574
2575   if ( $error ) {
2576     $dbh->rollback if $oldAutoCommit;
2577     die $error;
2578   }
2579
2580   my $unapplied =   $self->total_unapplied_credits
2581                   + $self->total_unapplied_payments
2582                   + $self->in_transit_payments;
2583   foreach my $cust_bill ($self->open_cust_bill) {
2584     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
2585     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
2586       'invnum' => $cust_bill->invnum,
2587       'paybatchnum' => $cust_pay_batch->paybatchnum,
2588       'amount' => $cust_bill->owed,
2589       '_date' => time,
2590     };
2591     if ($unapplied >= $cust_bill_pay_batch->amount){
2592       $unapplied -= $cust_bill_pay_batch->amount;
2593       next;
2594     }else{
2595       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
2596                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
2597     }
2598     $error = $cust_bill_pay_batch->insert;
2599     if ( $error ) {
2600       $dbh->rollback if $oldAutoCommit;
2601       die $error;
2602     }
2603   }
2604
2605   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2606   '';
2607 }
2608
2609 =item total_owed
2610
2611 Returns the total owed for this customer on all invoices
2612 (see L<FS::cust_bill/owed>).
2613
2614 =cut
2615
2616 sub total_owed {
2617   my $self = shift;
2618   $self->total_owed_date(2145859200); #12/31/2037
2619 }
2620
2621 =item total_owed_date TIME
2622
2623 Returns the total owed for this customer on all invoices with date earlier than
2624 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2625 see L<Time::Local> and L<Date::Parse> for conversion functions.
2626
2627 =cut
2628
2629 sub total_owed_date {
2630   my $self = shift;
2631   my $time = shift;
2632
2633   my $custnum = $self->custnum;
2634
2635   my $owed_sql = FS::cust_bill->owed_sql;
2636
2637   my $sql = "
2638     SELECT SUM($owed_sql) FROM cust_bill
2639       WHERE custnum = $custnum
2640         AND _date <= $time
2641   ";
2642
2643   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2644
2645 }
2646
2647 =item total_owed_pkgnum PKGNUM
2648
2649 Returns the total owed on all invoices for this customer's specific package
2650 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2651
2652 =cut
2653
2654 sub total_owed_pkgnum {
2655   my( $self, $pkgnum ) = @_;
2656   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2657 }
2658
2659 =item total_owed_date_pkgnum TIME PKGNUM
2660
2661 Returns the total owed for this customer's specific package when using
2662 experimental package balances on all invoices with date earlier than
2663 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2664 see L<Time::Local> and L<Date::Parse> for conversion functions.
2665
2666 =cut
2667
2668 sub total_owed_date_pkgnum {
2669   my( $self, $time, $pkgnum ) = @_;
2670
2671   my $total_bill = 0;
2672   foreach my $cust_bill (
2673     grep { $_->_date <= $time }
2674       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2675   ) {
2676     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2677   }
2678   sprintf( "%.2f", $total_bill );
2679
2680 }
2681
2682 =item total_paid
2683
2684 Returns the total amount of all payments.
2685
2686 =cut
2687
2688 sub total_paid {
2689   my $self = shift;
2690   my $total = 0;
2691   $total += $_->paid foreach $self->cust_pay;
2692   sprintf( "%.2f", $total );
2693 }
2694
2695 =item total_unapplied_credits
2696
2697 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2698 customer.  See L<FS::cust_credit/credited>.
2699
2700 =item total_credited
2701
2702 Old name for total_unapplied_credits.  Don't use.
2703
2704 =cut
2705
2706 sub total_credited {
2707   #carp "total_credited deprecated, use total_unapplied_credits";
2708   shift->total_unapplied_credits(@_);
2709 }
2710
2711 sub total_unapplied_credits {
2712   my $self = shift;
2713
2714   my $custnum = $self->custnum;
2715
2716   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2717
2718   my $sql = "
2719     SELECT SUM($unapplied_sql) FROM cust_credit
2720       WHERE custnum = $custnum
2721   ";
2722
2723   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2724
2725 }
2726
2727 =item total_unapplied_credits_pkgnum PKGNUM
2728
2729 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2730 customer.  See L<FS::cust_credit/credited>.
2731
2732 =cut
2733
2734 sub total_unapplied_credits_pkgnum {
2735   my( $self, $pkgnum ) = @_;
2736   my $total_credit = 0;
2737   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2738   sprintf( "%.2f", $total_credit );
2739 }
2740
2741
2742 =item total_unapplied_payments
2743
2744 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2745 See L<FS::cust_pay/unapplied>.
2746
2747 =cut
2748
2749 sub total_unapplied_payments {
2750   my $self = shift;
2751
2752   my $custnum = $self->custnum;
2753
2754   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2755
2756   my $sql = "
2757     SELECT SUM($unapplied_sql) FROM cust_pay
2758       WHERE custnum = $custnum
2759   ";
2760
2761   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2762
2763 }
2764
2765 =item total_unapplied_payments_pkgnum PKGNUM
2766
2767 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2768 specific package when using experimental package balances.  See
2769 L<FS::cust_pay/unapplied>.
2770
2771 =cut
2772
2773 sub total_unapplied_payments_pkgnum {
2774   my( $self, $pkgnum ) = @_;
2775   my $total_unapplied = 0;
2776   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2777   sprintf( "%.2f", $total_unapplied );
2778 }
2779
2780
2781 =item total_unapplied_refunds
2782
2783 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2784 customer.  See L<FS::cust_refund/unapplied>.
2785
2786 =cut
2787
2788 sub total_unapplied_refunds {
2789   my $self = shift;
2790   my $custnum = $self->custnum;
2791
2792   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2793
2794   my $sql = "
2795     SELECT SUM($unapplied_sql) FROM cust_refund
2796       WHERE custnum = $custnum
2797   ";
2798
2799   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2800
2801 }
2802
2803 =item balance
2804
2805 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2806 total_unapplied_credits minus total_unapplied_payments).
2807
2808 =cut
2809
2810 sub balance {
2811   my $self = shift;
2812   $self->balance_date_range;
2813 }
2814
2815 =item balance_date TIME
2816
2817 Returns the balance for this customer, only considering invoices with date
2818 earlier than TIME (total_owed_date minus total_credited minus
2819 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2820 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2821 functions.
2822
2823 =cut
2824
2825 sub balance_date {
2826   my $self = shift;
2827   $self->balance_date_range(shift);
2828 }
2829
2830 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2831
2832 Returns the balance for this customer, optionally considering invoices with
2833 date earlier than START_TIME, and not later than END_TIME
2834 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2835
2836 Times are specified as SQL fragments or numeric
2837 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2838 L<Date::Parse> for conversion functions.  The empty string can be passed
2839 to disable that time constraint completely.
2840
2841 Accepts the same options as L<balance_date_sql>:
2842
2843 =over 4
2844
2845 =item unapplied_date
2846
2847 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2848
2849 =item cutoff
2850
2851 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2852 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2853 range for invoices and I<unapplied> payments, credits, and refunds.
2854
2855 =back
2856
2857 =cut
2858
2859 sub balance_date_range {
2860   my $self = shift;
2861   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2862             ') FROM cust_main WHERE custnum='. $self->custnum;
2863   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2864 }
2865
2866 =item balance_pkgnum PKGNUM
2867
2868 Returns the balance for this customer's specific package when using
2869 experimental package balances (total_owed plus total_unrefunded, minus
2870 total_unapplied_credits minus total_unapplied_payments)
2871
2872 =cut
2873
2874 sub balance_pkgnum {
2875   my( $self, $pkgnum ) = @_;
2876
2877   sprintf( "%.2f",
2878       $self->total_owed_pkgnum($pkgnum)
2879 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2880 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2881     - $self->total_unapplied_credits_pkgnum($pkgnum)
2882     - $self->total_unapplied_payments_pkgnum($pkgnum)
2883   );
2884 }
2885
2886 =item in_transit_payments
2887
2888 Returns the total of requests for payments for this customer pending in
2889 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
2890
2891 =cut
2892
2893 sub in_transit_payments {
2894   my $self = shift;
2895   my $in_transit_payments = 0;
2896   foreach my $pay_batch ( qsearch('pay_batch', {
2897     'status' => 'I',
2898   } ) ) {
2899     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
2900       'batchnum' => $pay_batch->batchnum,
2901       'custnum' => $self->custnum,
2902     } ) ) {
2903       $in_transit_payments += $cust_pay_batch->amount;
2904     }
2905   }
2906   sprintf( "%.2f", $in_transit_payments );
2907 }
2908
2909 =item payment_info
2910
2911 Returns a hash of useful information for making a payment.
2912
2913 =over 4
2914
2915 =item balance
2916
2917 Current balance.
2918
2919 =item payby
2920
2921 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2922 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2923 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2924
2925 =back
2926
2927 For credit card transactions:
2928
2929 =over 4
2930
2931 =item card_type 1
2932
2933 =item payname
2934
2935 Exact name on card
2936
2937 =back
2938
2939 For electronic check transactions:
2940
2941 =over 4
2942
2943 =item stateid_state
2944
2945 =back
2946
2947 =cut
2948
2949 sub payment_info {
2950   my $self = shift;
2951
2952   my %return = ();
2953
2954   $return{balance} = $self->balance;
2955
2956   $return{payname} = $self->payname
2957                      || ( $self->first. ' '. $self->get('last') );
2958
2959   $return{$_} = $self->bill_location->$_
2960     for qw(address1 address2 city state zip);
2961
2962   $return{payby} = $self->payby;
2963   $return{stateid_state} = $self->stateid_state;
2964
2965   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2966     $return{card_type} = cardtype($self->payinfo);
2967     $return{payinfo} = $self->paymask;
2968
2969     @return{'month', 'year'} = $self->paydate_monthyear;
2970
2971   }
2972
2973   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2974     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2975     $return{payinfo1} = $payinfo1;
2976     $return{payinfo2} = $payinfo2;
2977     $return{paytype}  = $self->paytype;
2978     $return{paystate} = $self->paystate;
2979
2980   }
2981
2982   #doubleclick protection
2983   my $_date = time;
2984   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2985
2986   %return;
2987
2988 }
2989
2990 =item paydate_monthyear
2991
2992 Returns a two-element list consisting of the month and year of this customer's
2993 paydate (credit card expiration date for CARD customers)
2994
2995 =cut
2996
2997 sub paydate_monthyear {
2998   my $self = shift;
2999   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
3000     ( $2, $1 );
3001   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
3002     ( $1, $3 );
3003   } else {
3004     ('', '');
3005   }
3006 }
3007
3008 =item paydate_epoch
3009
3010 Returns the exact time in seconds corresponding to the payment method
3011 expiration date.  For CARD/DCRD customers this is the end of the month;
3012 for others (COMP is the only other payby that uses paydate) it's the start.
3013 Returns 0 if the paydate is empty or set to the far future.
3014
3015 =cut
3016
3017 sub paydate_epoch {
3018   my $self = shift;
3019   my ($month, $year) = $self->paydate_monthyear;
3020   return 0 if !$year or $year >= 2037;
3021   if ( $self->payby eq 'CARD' or $self->payby eq 'DCRD' ) {
3022     $month++;
3023     if ( $month == 13 ) {
3024       $month = 1;
3025       $year++;
3026     }
3027     return timelocal(0,0,0,1,$month-1,$year) - 1;
3028   }
3029   else {
3030     return timelocal(0,0,0,1,$month-1,$year);
3031   }
3032 }
3033
3034 =item paydate_epoch_sql
3035
3036 Class method.  Returns an SQL expression to obtain the payment expiration date
3037 as a number of seconds.
3038
3039 =cut
3040
3041 # Special expiration date behavior for non-CARD/DCRD customers has been
3042 # carefully preserved.  Do we really use that?
3043 sub paydate_epoch_sql {
3044   my $class = shift;
3045   my $table = shift || 'cust_main';
3046   my ($case1, $case2);
3047   if ( driver_name eq 'Pg' ) {
3048     $case1 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) + INTERVAL '1 month') - 1";
3049     $case2 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) )";
3050   }
3051   elsif ( lc(driver_name) eq 'mysql' ) {
3052     $case1 = "UNIX_TIMESTAMP( DATE_ADD( CAST( $table.paydate AS DATETIME ), INTERVAL 1 month ) ) - 1";
3053     $case2 = "UNIX_TIMESTAMP( CAST( $table.paydate AS DATETIME ) )";
3054   }
3055   else { return '' }
3056   return "CASE WHEN $table.payby IN('CARD','DCRD')
3057   THEN ($case1)
3058   ELSE ($case2)
3059   END"
3060 }
3061
3062 =item tax_exemption TAXNAME
3063
3064 =cut
3065
3066 sub tax_exemption {
3067   my( $self, $taxname ) = @_;
3068
3069   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3070                                      'taxname' => $taxname,
3071                                    },
3072           );
3073 }
3074
3075 =item cust_main_exemption
3076
3077 =item invoicing_list [ ARRAYREF ]
3078
3079 If an arguement is given, sets these email addresses as invoice recipients
3080 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
3081 (except as warnings), so use check_invoicing_list first.
3082
3083 Returns a list of email addresses (with svcnum entries expanded).
3084
3085 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
3086 check it without disturbing anything by passing nothing.
3087
3088 This interface may change in the future.
3089
3090 =cut
3091
3092 sub invoicing_list {
3093   my( $self, $arrayref ) = @_;
3094
3095   if ( $arrayref ) {
3096     my @cust_main_invoice;
3097     if ( $self->custnum ) {
3098       @cust_main_invoice =
3099         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3100     } else {
3101       @cust_main_invoice = ();
3102     }
3103     foreach my $cust_main_invoice ( @cust_main_invoice ) {
3104       #warn $cust_main_invoice->destnum;
3105       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
3106         #warn $cust_main_invoice->destnum;
3107         my $error = $cust_main_invoice->delete;
3108         warn $error if $error;
3109       }
3110     }
3111     if ( $self->custnum ) {
3112       @cust_main_invoice =
3113         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3114     } else {
3115       @cust_main_invoice = ();
3116     }
3117     my %seen = map { $_->address => 1 } @cust_main_invoice;
3118     foreach my $address ( @{$arrayref} ) {
3119       next if exists $seen{$address} && $seen{$address};
3120       $seen{$address} = 1;
3121       my $cust_main_invoice = new FS::cust_main_invoice ( {
3122         'custnum' => $self->custnum,
3123         'dest'    => $address,
3124       } );
3125       my $error = $cust_main_invoice->insert;
3126       warn $error if $error;
3127     }
3128   }
3129
3130   if ( $self->custnum ) {
3131     map { $_->address }
3132       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3133   } else {
3134     ();
3135   }
3136
3137 }
3138
3139 =item check_invoicing_list ARRAYREF
3140
3141 Checks these arguements as valid input for the invoicing_list method.  If there
3142 is an error, returns the error, otherwise returns false.
3143
3144 =cut
3145
3146 sub check_invoicing_list {
3147   my( $self, $arrayref ) = @_;
3148
3149   foreach my $address ( @$arrayref ) {
3150
3151     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3152       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3153     }
3154
3155     my $cust_main_invoice = new FS::cust_main_invoice ( {
3156       'custnum' => $self->custnum,
3157       'dest'    => $address,
3158     } );
3159     my $error = $self->custnum
3160                 ? $cust_main_invoice->check
3161                 : $cust_main_invoice->checkdest
3162     ;
3163     return $error if $error;
3164
3165   }
3166
3167   return "Email address required"
3168     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3169     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3170
3171   '';
3172 }
3173
3174 =item set_default_invoicing_list
3175
3176 Sets the invoicing list to all accounts associated with this customer,
3177 overwriting any previous invoicing list.
3178
3179 =cut
3180
3181 sub set_default_invoicing_list {
3182   my $self = shift;
3183   $self->invoicing_list($self->all_emails);
3184 }
3185
3186 =item all_emails
3187
3188 Returns the email addresses of all accounts provisioned for this customer.
3189
3190 =cut
3191
3192 sub all_emails {
3193   my $self = shift;
3194   my %list;
3195   foreach my $cust_pkg ( $self->all_pkgs ) {
3196     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3197     my @svc_acct =
3198       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3199         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3200           @cust_svc;
3201     $list{$_}=1 foreach map { $_->email } @svc_acct;
3202   }
3203   keys %list;
3204 }
3205
3206 =item invoicing_list_addpost
3207
3208 Adds postal invoicing to this customer.  If this customer is already configured
3209 to receive postal invoices, does nothing.
3210
3211 =cut
3212
3213 sub invoicing_list_addpost {
3214   my $self = shift;
3215   return if grep { $_ eq 'POST' } $self->invoicing_list;
3216   my @invoicing_list = $self->invoicing_list;
3217   push @invoicing_list, 'POST';
3218   $self->invoicing_list(\@invoicing_list);
3219 }
3220
3221 =item invoicing_list_emailonly
3222
3223 Returns the list of email invoice recipients (invoicing_list without non-email
3224 destinations such as POST and FAX).
3225
3226 =cut
3227
3228 sub invoicing_list_emailonly {
3229   my $self = shift;
3230   warn "$me invoicing_list_emailonly called"
3231     if $DEBUG;
3232   grep { $_ !~ /^([A-Z]+)$/ } $self->invoicing_list;
3233 }
3234
3235 =item invoicing_list_emailonly_scalar
3236
3237 Returns the list of email invoice recipients (invoicing_list without non-email
3238 destinations such as POST and FAX) as a comma-separated scalar.
3239
3240 =cut
3241
3242 sub invoicing_list_emailonly_scalar {
3243   my $self = shift;
3244   warn "$me invoicing_list_emailonly_scalar called"
3245     if $DEBUG;
3246   join(', ', $self->invoicing_list_emailonly);
3247 }
3248
3249 =item referral_custnum_cust_main
3250
3251 Returns the customer who referred this customer (or the empty string, if
3252 this customer was not referred).
3253
3254 Note the difference with referral_cust_main method: This method,
3255 referral_custnum_cust_main returns the single customer (if any) who referred
3256 this customer, while referral_cust_main returns an array of customers referred
3257 BY this customer.
3258
3259 =cut
3260
3261 sub referral_custnum_cust_main {
3262   my $self = shift;
3263   return '' unless $self->referral_custnum;
3264   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3265 }
3266
3267 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3268
3269 Returns an array of customers referred by this customer (referral_custnum set
3270 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3271 customers referred by customers referred by this customer and so on, inclusive.
3272 The default behavior is DEPTH 1 (no recursion).
3273
3274 Note the difference with referral_custnum_cust_main method: This method,
3275 referral_cust_main, returns an array of customers referred BY this customer,
3276 while referral_custnum_cust_main returns the single customer (if any) who
3277 referred this customer.
3278
3279 =cut
3280
3281 sub referral_cust_main {
3282   my $self = shift;
3283   my $depth = @_ ? shift : 1;
3284   my $exclude = @_ ? shift : {};
3285
3286   my @cust_main =
3287     map { $exclude->{$_->custnum}++; $_; }
3288       grep { ! $exclude->{ $_->custnum } }
3289         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3290
3291   if ( $depth > 1 ) {
3292     push @cust_main,
3293       map { $_->referral_cust_main($depth-1, $exclude) }
3294         @cust_main;
3295   }
3296
3297   @cust_main;
3298 }
3299
3300 =item referral_cust_main_ncancelled
3301
3302 Same as referral_cust_main, except only returns customers with uncancelled
3303 packages.
3304
3305 =cut
3306
3307 sub referral_cust_main_ncancelled {
3308   my $self = shift;
3309   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3310 }
3311
3312 =item referral_cust_pkg [ DEPTH ]
3313
3314 Like referral_cust_main, except returns a flat list of all unsuspended (and
3315 uncancelled) packages for each customer.  The number of items in this list may
3316 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3317
3318 =cut
3319
3320 sub referral_cust_pkg {
3321   my $self = shift;
3322   my $depth = @_ ? shift : 1;
3323
3324   map { $_->unsuspended_pkgs }
3325     grep { $_->unsuspended_pkgs }
3326       $self->referral_cust_main($depth);
3327 }
3328
3329 =item referring_cust_main
3330
3331 Returns the single cust_main record for the customer who referred this customer
3332 (referral_custnum), or false.
3333
3334 =cut
3335
3336 sub referring_cust_main {
3337   my $self = shift;
3338   return '' unless $self->referral_custnum;
3339   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3340 }
3341
3342 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3343
3344 Applies a credit to this customer.  If there is an error, returns the error,
3345 otherwise returns false.
3346
3347 REASON can be a text string, an FS::reason object, or a scalar reference to
3348 a reasonnum.  If a text string, it will be automatically inserted as a new
3349 reason, and a 'reason_type' option must be passed to indicate the
3350 FS::reason_type for the new reason.
3351
3352 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3353 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3354 I<commission_pkgnum>.
3355
3356 Any other options are passed to FS::cust_credit::insert.
3357
3358 =cut
3359
3360 sub credit {
3361   my( $self, $amount, $reason, %options ) = @_;
3362
3363   my $cust_credit = new FS::cust_credit {
3364     'custnum' => $self->custnum,
3365     'amount'  => $amount,
3366   };
3367
3368   if ( ref($reason) ) {
3369
3370     if ( ref($reason) eq 'SCALAR' ) {
3371       $cust_credit->reasonnum( $$reason );
3372     } else {
3373       $cust_credit->reasonnum( $reason->reasonnum );
3374     }
3375
3376   } else {
3377     $cust_credit->set('reason', $reason)
3378   }
3379
3380   $cust_credit->$_( delete $options{$_} )
3381     foreach grep exists($options{$_}),
3382               qw( addlinfo eventnum ),
3383               map "commission_$_", qw( agentnum salesnum pkgnum );
3384
3385   $cust_credit->insert(%options);
3386
3387 }
3388
3389 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3390
3391 Creates a one-time charge for this customer.  If there is an error, returns
3392 the error, otherwise returns false.
3393
3394 New-style, with a hashref of options:
3395
3396   my $error = $cust_main->charge(
3397                                   {
3398                                     'amount'     => 54.32,
3399                                     'quantity'   => 1,
3400                                     'start_date' => str2time('7/4/2009'),
3401                                     'pkg'        => 'Description',
3402                                     'comment'    => 'Comment',
3403                                     'additional' => [], #extra invoice detail
3404                                     'classnum'   => 1,  #pkg_class
3405
3406                                     'setuptax'   => '', # or 'Y' for tax exempt
3407
3408                                     'locationnum'=> 1234, # optional
3409
3410                                     #internal taxation
3411                                     'taxclass'   => 'Tax class',
3412
3413                                     #vendor taxation
3414                                     'taxproduct' => 2,  #part_pkg_taxproduct
3415                                     'override'   => {}, #XXX describe
3416
3417                                     #will be filled in with the new object
3418                                     'cust_pkg_ref' => \$cust_pkg,
3419
3420                                     #generate an invoice immediately
3421                                     'bill_now' => 0,
3422                                     'invoice_terms' => '', #with these terms
3423                                   }
3424                                 );
3425
3426 Old-style:
3427
3428   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3429
3430 =cut
3431
3432 sub charge {
3433   my $self = shift;
3434   my ( $amount, $quantity, $start_date, $classnum );
3435   my ( $pkg, $comment, $additional );
3436   my ( $setuptax, $taxclass );   #internal taxes
3437   my ( $taxproduct, $override ); #vendor (CCH) taxes
3438   my $no_auto = '';
3439   my $cust_pkg_ref = '';
3440   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3441   my $locationnum;
3442   if ( ref( $_[0] ) ) {
3443     $amount     = $_[0]->{amount};
3444     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3445     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3446     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3447     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3448     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3449                                            : '$'. sprintf("%.2f",$amount);
3450     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3451     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3452     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3453     $additional = $_[0]->{additional} || [];
3454     $taxproduct = $_[0]->{taxproductnum};
3455     $override   = { '' => $_[0]->{tax_override} };
3456     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3457     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3458     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3459     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3460   } else {
3461     $amount     = shift;
3462     $quantity   = 1;
3463     $start_date = '';
3464     $pkg        = @_ ? shift : 'One-time charge';
3465     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3466     $setuptax   = '';
3467     $taxclass   = @_ ? shift : '';
3468     $additional = [];
3469   }
3470
3471   local $SIG{HUP} = 'IGNORE';
3472   local $SIG{INT} = 'IGNORE';
3473   local $SIG{QUIT} = 'IGNORE';
3474   local $SIG{TERM} = 'IGNORE';
3475   local $SIG{TSTP} = 'IGNORE';
3476   local $SIG{PIPE} = 'IGNORE';
3477
3478   my $oldAutoCommit = $FS::UID::AutoCommit;
3479   local $FS::UID::AutoCommit = 0;
3480   my $dbh = dbh;
3481
3482   my $part_pkg = new FS::part_pkg ( {
3483     'pkg'           => $pkg,
3484     'comment'       => $comment,
3485     'plan'          => 'flat',
3486     'freq'          => 0,
3487     'disabled'      => 'Y',
3488     'classnum'      => ( $classnum ? $classnum : '' ),
3489     'setuptax'      => $setuptax,
3490     'taxclass'      => $taxclass,
3491     'taxproductnum' => $taxproduct,
3492   } );
3493
3494   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3495                         ( 0 .. @$additional - 1 )
3496                   ),
3497                   'additional_count' => scalar(@$additional),
3498                   'setup_fee' => $amount,
3499                 );
3500
3501   my $error = $part_pkg->insert( options       => \%options,
3502                                  tax_overrides => $override,
3503                                );
3504   if ( $error ) {
3505     $dbh->rollback if $oldAutoCommit;
3506     return $error;
3507   }
3508
3509   my $pkgpart = $part_pkg->pkgpart;
3510   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3511   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3512     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3513     $error = $type_pkgs->insert;
3514     if ( $error ) {
3515       $dbh->rollback if $oldAutoCommit;
3516       return $error;
3517     }
3518   }
3519
3520   my $cust_pkg = new FS::cust_pkg ( {
3521     'custnum'    => $self->custnum,
3522     'pkgpart'    => $pkgpart,
3523     'quantity'   => $quantity,
3524     'start_date' => $start_date,
3525     'no_auto'    => $no_auto,
3526     'locationnum'=> $locationnum,
3527   } );
3528
3529   $error = $cust_pkg->insert;
3530   if ( $error ) {
3531     $dbh->rollback if $oldAutoCommit;
3532     return $error;
3533   } elsif ( $cust_pkg_ref ) {
3534     ${$cust_pkg_ref} = $cust_pkg;
3535   }
3536
3537   if ( $bill_now ) {
3538     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3539                              'pkg_list'      => [ $cust_pkg ],
3540                            );
3541     if ( $error ) {
3542       $dbh->rollback if $oldAutoCommit;
3543       return $error;
3544     }
3545   }
3546
3547   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3548   return '';
3549
3550 }
3551
3552 #=item charge_postal_fee
3553 #
3554 #Applies a one time charge this customer.  If there is an error,
3555 #returns the error, returns the cust_pkg charge object or false
3556 #if there was no charge.
3557 #
3558 #=cut
3559 #
3560 # This should be a customer event.  For that to work requires that bill
3561 # also be a customer event.
3562
3563 sub charge_postal_fee {
3564   my $self = shift;
3565
3566   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3567   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3568
3569   my $cust_pkg = new FS::cust_pkg ( {
3570     'custnum'  => $self->custnum,
3571     'pkgpart'  => $pkgpart,
3572     'quantity' => 1,
3573   } );
3574
3575   my $error = $cust_pkg->insert;
3576   $error ? $error : $cust_pkg;
3577 }
3578
3579 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3580
3581 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3582
3583 Optionally, a list or hashref of additional arguments to the qsearch call can
3584 be passed.
3585
3586 =cut
3587
3588 sub cust_bill {
3589   my $self = shift;
3590   my $opt = ref($_[0]) ? shift : { @_ };
3591
3592   #return $self->num_cust_bill unless wantarray || keys %$opt;
3593
3594   $opt->{'table'} = 'cust_bill';
3595   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3596   $opt->{'hashref'}{'custnum'} = $self->custnum;
3597   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3598
3599   map { $_ } #behavior of sort undefined in scalar context
3600     sort { $a->_date <=> $b->_date }
3601       qsearch($opt);
3602 }
3603
3604 =item open_cust_bill
3605
3606 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3607 customer.
3608
3609 =cut
3610
3611 sub open_cust_bill {
3612   my $self = shift;
3613
3614   $self->cust_bill(
3615     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3616     #@_
3617   );
3618
3619 }
3620
3621 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3622
3623 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3624
3625 =cut
3626
3627 sub legacy_cust_bill {
3628   my $self = shift;
3629
3630   #return $self->num_legacy_cust_bill unless wantarray;
3631
3632   map { $_ } #behavior of sort undefined in scalar context
3633     sort { $a->_date <=> $b->_date }
3634       qsearch({ 'table'    => 'legacy_cust_bill',
3635                 'hashref'  => { 'custnum' => $self->custnum, },
3636                 'order_by' => 'ORDER BY _date ASC',
3637              });
3638 }
3639
3640 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3641
3642 Returns all the statements (see L<FS::cust_statement>) for this customer.
3643
3644 Optionally, a list or hashref of additional arguments to the qsearch call can
3645 be passed.
3646
3647 =cut
3648
3649 =item cust_bill_void
3650
3651 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3652
3653 =cut
3654
3655 sub cust_bill_void {
3656   my $self = shift;
3657
3658   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3659   sort { $a->_date <=> $b->_date }
3660     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3661 }
3662
3663 sub cust_statement {
3664   my $self = shift;
3665   my $opt = ref($_[0]) ? shift : { @_ };
3666
3667   #return $self->num_cust_statement unless wantarray || keys %$opt;
3668
3669   $opt->{'table'} = 'cust_statement';
3670   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3671   $opt->{'hashref'}{'custnum'} = $self->custnum;
3672   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3673
3674   map { $_ } #behavior of sort undefined in scalar context
3675     sort { $a->_date <=> $b->_date }
3676       qsearch($opt);
3677 }
3678
3679 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3680
3681 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3682
3683 Optionally, a list or hashref of additional arguments to the qsearch call can
3684 be passed following the SVCDB.
3685
3686 =cut
3687
3688 sub svc_x {
3689   my $self = shift;
3690   my $svcdb = shift;
3691   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3692     warn "$me svc_x requires a svcdb";
3693     return;
3694   }
3695   my $opt = ref($_[0]) ? shift : { @_ };
3696
3697   $opt->{'table'} = $svcdb;
3698   $opt->{'addl_from'} =
3699     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3700     ($opt->{'addl_from'} || '');
3701
3702   my $custnum = $self->custnum;
3703   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3704   my $where = "cust_pkg.custnum = $custnum";
3705
3706   my $extra_sql = $opt->{'extra_sql'} || '';
3707   if ( keys %{ $opt->{'hashref'} } ) {
3708     $extra_sql = " AND $where $extra_sql";
3709   }
3710   else {
3711     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3712       $extra_sql = "WHERE $where AND $1";
3713     }
3714     else {
3715       $extra_sql = "WHERE $where $extra_sql";
3716     }
3717   }
3718   $opt->{'extra_sql'} = $extra_sql;
3719
3720   qsearch($opt);
3721 }
3722
3723 # required for use as an eventtable;
3724 sub svc_acct {
3725   my $self = shift;
3726   $self->svc_x('svc_acct', @_);
3727 }
3728
3729 =item cust_credit
3730
3731 Returns all the credits (see L<FS::cust_credit>) for this customer.
3732
3733 =cut
3734
3735 sub cust_credit {
3736   my $self = shift;
3737   map { $_ } #return $self->num_cust_credit unless wantarray;
3738   sort { $a->_date <=> $b->_date }
3739     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3740 }
3741
3742 =item cust_credit_pkgnum
3743
3744 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3745 package when using experimental package balances.
3746
3747 =cut
3748
3749 sub cust_credit_pkgnum {
3750   my( $self, $pkgnum ) = @_;
3751   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3752   sort { $a->_date <=> $b->_date }
3753     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3754                               'pkgnum'  => $pkgnum,
3755                             }
3756     );
3757 }
3758
3759 =item cust_credit_void
3760
3761 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3762
3763 =cut
3764
3765 sub cust_credit_void {
3766   my $self = shift;
3767   map { $_ }
3768   sort { $a->_date <=> $b->_date }
3769     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3770 }
3771
3772 =item cust_pay
3773
3774 Returns all the payments (see L<FS::cust_pay>) for this customer.
3775
3776 =cut
3777
3778 sub cust_pay {
3779   my $self = shift;
3780   my $opt = ref($_[0]) ? shift : { @_ };
3781
3782   return $self->num_cust_pay unless wantarray || keys %$opt;
3783
3784   $opt->{'table'} = 'cust_pay';
3785   $opt->{'hashref'}{'custnum'} = $self->custnum;
3786
3787   map { $_ } #behavior of sort undefined in scalar context
3788     sort { $a->_date <=> $b->_date }
3789       qsearch($opt);
3790
3791 }
3792
3793 =item num_cust_pay
3794
3795 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3796 called automatically when the cust_pay method is used in a scalar context.
3797
3798 =cut
3799
3800 sub num_cust_pay {
3801   my $self = shift;
3802   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3803   my $sth = dbh->prepare($sql) or die dbh->errstr;
3804   $sth->execute($self->custnum) or die $sth->errstr;
3805   $sth->fetchrow_arrayref->[0];
3806 }
3807
3808 =item unapplied_cust_pay
3809
3810 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3811
3812 =cut
3813
3814 sub unapplied_cust_pay {
3815   my $self = shift;
3816
3817   $self->cust_pay(
3818     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3819     #@_
3820   );
3821
3822 }
3823
3824 =item cust_pay_pkgnum
3825
3826 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3827 package when using experimental package balances.
3828
3829 =cut
3830
3831 sub cust_pay_pkgnum {
3832   my( $self, $pkgnum ) = @_;
3833   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3834   sort { $a->_date <=> $b->_date }
3835     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3836                            'pkgnum'  => $pkgnum,
3837                          }
3838     );
3839 }
3840
3841 =item cust_pay_void
3842
3843 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3844
3845 =cut
3846
3847 sub cust_pay_void {
3848   my $self = shift;
3849   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3850   sort { $a->_date <=> $b->_date }
3851     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3852 }
3853
3854 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3855
3856 Returns all batched payments (see L<FS::cust_pay_batch>) for this customer.
3857
3858 Optionally, a list or hashref of additional arguments to the qsearch call can
3859 be passed.
3860
3861 =cut
3862
3863 sub cust_pay_batch {
3864   my $self = shift;
3865   my $opt = ref($_[0]) ? shift : { @_ };
3866
3867   #return $self->num_cust_statement unless wantarray || keys %$opt;
3868
3869   $opt->{'table'} = 'cust_pay_batch';
3870   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3871   $opt->{'hashref'}{'custnum'} = $self->custnum;
3872   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
3873
3874   map { $_ } #behavior of sort undefined in scalar context
3875     sort { $a->paybatchnum <=> $b->paybatchnum }
3876       qsearch($opt);
3877 }
3878
3879 =item cust_pay_pending
3880
3881 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3882 (without status "done").
3883
3884 =cut
3885
3886 sub cust_pay_pending {
3887   my $self = shift;
3888   return $self->num_cust_pay_pending unless wantarray;
3889   sort { $a->_date <=> $b->_date }
3890     qsearch( 'cust_pay_pending', {
3891                                    'custnum' => $self->custnum,
3892                                    'status'  => { op=>'!=', value=>'done' },
3893                                  },
3894            );
3895 }
3896
3897 =item cust_pay_pending_attempt
3898
3899 Returns all payment attempts / declined payments for this customer, as pending
3900 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3901 a corresponding payment (see L<FS::cust_pay>).
3902
3903 =cut
3904
3905 sub cust_pay_pending_attempt {
3906   my $self = shift;
3907   return $self->num_cust_pay_pending_attempt unless wantarray;
3908   sort { $a->_date <=> $b->_date }
3909     qsearch( 'cust_pay_pending', {
3910                                    'custnum' => $self->custnum,
3911                                    'status'  => 'done',
3912                                    'paynum'  => '',
3913                                  },
3914            );
3915 }
3916
3917 =item num_cust_pay_pending
3918
3919 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3920 customer (without status "done").  Also called automatically when the
3921 cust_pay_pending method is used in a scalar context.
3922
3923 =cut
3924
3925 sub num_cust_pay_pending {
3926   my $self = shift;
3927   $self->scalar_sql(
3928     " SELECT COUNT(*) FROM cust_pay_pending ".
3929       " WHERE custnum = ? AND status != 'done' ",
3930     $self->custnum
3931   );
3932 }
3933
3934 =item num_cust_pay_pending_attempt
3935
3936 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3937 customer, with status "done" but without a corresp.  Also called automatically when the
3938 cust_pay_pending method is used in a scalar context.
3939
3940 =cut
3941
3942 sub num_cust_pay_pending_attempt {
3943   my $self = shift;
3944   $self->scalar_sql(
3945     " SELECT COUNT(*) FROM cust_pay_pending ".
3946       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3947     $self->custnum
3948   );
3949 }
3950
3951 =item cust_refund
3952
3953 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3954
3955 =cut
3956
3957 sub cust_refund {
3958   my $self = shift;
3959   map { $_ } #return $self->num_cust_refund unless wantarray;
3960   sort { $a->_date <=> $b->_date }
3961     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3962 }
3963
3964 =item display_custnum
3965
3966 Returns the displayed customer number for this customer: agent_custid if
3967 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3968
3969 =cut
3970
3971 sub display_custnum {
3972   my $self = shift;
3973
3974   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3975   if ( my $special = $conf->config('cust_main-custnum-display_special') ) {
3976     if ( $special eq 'CoStAg' ) {
3977       $prefix = uc( join('',
3978         $self->country,
3979         ($self->state =~ /^(..)/),
3980         $prefix || ($self->agent->agent =~ /^(..)/)
3981       ) );
3982     }
3983     elsif ( $special eq 'CoStCl' ) {
3984       $prefix = uc( join('',
3985         $self->country,
3986         ($self->state =~ /^(..)/),
3987         ($self->classnum ? $self->cust_class->classname =~ /^(..)/ : '__')
3988       ) );
3989     }
3990     # add any others here if needed
3991   }
3992
3993   my $length = $conf->config('cust_main-custnum-display_length');
3994   if ( $conf->exists('cust_main-default_agent_custid') && $self->agent_custid ){
3995     return $self->agent_custid;
3996   } elsif ( $prefix ) {
3997     $length = 8 if !defined($length);
3998     return $prefix .
3999            sprintf('%0'.$length.'d', $self->custnum)
4000   } elsif ( $length ) {
4001     return sprintf('%0'.$length.'d', $self->custnum);
4002   } else {
4003     return $self->custnum;
4004   }
4005 }
4006
4007 =item name
4008
4009 Returns a name string for this customer, either "Company (Last, First)" or
4010 "Last, First".
4011
4012 =cut
4013
4014 sub name {
4015   my $self = shift;
4016   my $name = $self->contact;
4017   $name = $self->company. " ($name)" if $self->company;
4018   $name;
4019 }
4020
4021 =item service_contact
4022
4023 Returns the L<FS::contact> object for this customer that has the 'Service'
4024 contact class, or undef if there is no such contact.  Deprecated; don't use
4025 this in new code.
4026
4027 =cut
4028
4029 sub service_contact {
4030   my $self = shift;
4031   if ( !exists($self->{service_contact}) ) {
4032     my $classnum = $self->scalar_sql(
4033       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
4034     ) || 0; #if it's zero, qsearchs will return nothing
4035     $self->{service_contact} = qsearchs('contact', {
4036         'classnum' => $classnum, 'custnum' => $self->custnum
4037       }) || undef;
4038   }
4039   $self->{service_contact};
4040 }
4041
4042 =item ship_name
4043
4044 Returns a name string for this (service/shipping) contact, either
4045 "Company (Last, First)" or "Last, First".
4046
4047 =cut
4048
4049 sub ship_name {
4050   my $self = shift;
4051
4052   my $name = $self->ship_contact;
4053   $name = $self->company. " ($name)" if $self->company;
4054   $name;
4055 }
4056
4057 =item name_short
4058
4059 Returns a name string for this customer, either "Company" or "First Last".
4060
4061 =cut
4062
4063 sub name_short {
4064   my $self = shift;
4065   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4066 }
4067
4068 =item ship_name_short
4069
4070 Returns a name string for this (service/shipping) contact, either "Company"
4071 or "First Last".
4072
4073 =cut
4074
4075 sub ship_name_short {
4076   my $self = shift;
4077   $self->service_contact
4078     ? $self->ship_contact_firstlast
4079     : $self->name_short
4080 }
4081
4082 =item contact
4083
4084 Returns this customer's full (billing) contact name only, "Last, First"
4085
4086 =cut
4087
4088 sub contact {
4089   my $self = shift;
4090   $self->get('last'). ', '. $self->first;
4091 }
4092
4093 =item ship_contact
4094
4095 Returns this customer's full (shipping) contact name only, "Last, First"
4096
4097 =cut
4098
4099 sub ship_contact {
4100   my $self = shift;
4101   my $contact = $self->service_contact || $self;
4102   $contact->get('last') . ', ' . $contact->get('first');
4103 }
4104
4105 =item contact_firstlast
4106
4107 Returns this customers full (billing) contact name only, "First Last".
4108
4109 =cut
4110
4111 sub contact_firstlast {
4112   my $self = shift;
4113   $self->first. ' '. $self->get('last');
4114 }
4115
4116 =item ship_contact_firstlast
4117
4118 Returns this customer's full (shipping) contact name only, "First Last".
4119
4120 =cut
4121
4122 sub ship_contact_firstlast {
4123   my $self = shift;
4124   my $contact = $self->service_contact || $self;
4125   $contact->get('first') . ' '. $contact->get('last');
4126 }
4127
4128 #XXX this doesn't work in 3.x+
4129 #=item country_full
4130 #
4131 #Returns this customer's full country name
4132 #
4133 #=cut
4134 #
4135 #sub country_full {
4136 #  my $self = shift;
4137 #  code2country($self->country);
4138 #}
4139
4140 sub bill_country_full {
4141   my $self = shift;
4142   code2country($self->bill_location->country);
4143 }
4144
4145 sub ship_country_full {
4146   my $self = shift;
4147   code2country($self->ship_location->country);
4148 }
4149
4150 =item county_state_county [ PREFIX ]
4151
4152 Returns a string consisting of just the county, state and country.
4153
4154 =cut
4155
4156 sub county_state_country {
4157   my $self = shift;
4158   my $locationnum;
4159   if ( @_ && $_[0] && $self->has_ship_address ) {
4160     $locationnum = $self->ship_locationnum;
4161   } else {
4162     $locationnum = $self->bill_locationnum;
4163   }
4164   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4165   $cust_location->county_state_country;
4166 }
4167
4168 =item geocode DATA_VENDOR
4169
4170 Returns a value for the customer location as encoded by DATA_VENDOR.
4171 Currently this only makes sense for "CCH" as DATA_VENDOR.
4172
4173 =cut
4174
4175 =item cust_status
4176
4177 =item status
4178
4179 Returns a status string for this customer, currently:
4180
4181 =over 4
4182
4183 =item prospect - No packages have ever been ordered
4184
4185 =item ordered - Recurring packages all are new (not yet billed).
4186
4187 =item active - One or more recurring packages is active
4188
4189 =item inactive - No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled)
4190
4191 =item suspended - All non-cancelled recurring packages are suspended
4192
4193 =item cancelled - All recurring packages are cancelled
4194
4195 =back
4196
4197 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4198 cust_main-status_module configuration option.
4199
4200 =cut
4201
4202 sub status { shift->cust_status(@_); }
4203
4204 sub cust_status {
4205   my $self = shift;
4206   for my $status ( FS::cust_main->statuses() ) {
4207     my $method = $status.'_sql';
4208     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4209     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4210     $sth->execute( ($self->custnum) x $numnum )
4211       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4212     return $status if $sth->fetchrow_arrayref->[0];
4213   }
4214 }
4215
4216 =item ucfirst_cust_status
4217
4218 =item ucfirst_status
4219
4220 Returns the status with the first character capitalized.
4221
4222 =cut
4223
4224 sub ucfirst_status { shift->ucfirst_cust_status(@_); }
4225
4226 sub ucfirst_cust_status {
4227   my $self = shift;
4228   ucfirst($self->cust_status);
4229 }
4230
4231 =item statuscolor
4232
4233 Returns a hex triplet color string for this customer's status.
4234
4235 =cut
4236
4237 sub statuscolor { shift->cust_statuscolor(@_); }
4238
4239 sub cust_statuscolor {
4240   my $self = shift;
4241   __PACKAGE__->statuscolors->{$self->cust_status};
4242 }
4243
4244 =item tickets [ STATUS ]
4245
4246 Returns an array of hashes representing the customer's RT tickets.
4247
4248 An optional status (or arrayref or hashref of statuses) may be specified.
4249
4250 =cut
4251
4252 sub tickets {
4253   my $self = shift;
4254   my $status = ( @_ && $_[0] ) ? shift : '';
4255
4256   my $num = $conf->config('cust_main-max_tickets') || 10;
4257   my @tickets = ();
4258
4259   if ( $conf->config('ticket_system') ) {
4260     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4261
4262       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
4263                                                         $num,
4264                                                         undef,
4265                                                         $status,
4266                                                       )
4267                   };
4268
4269     } else {
4270
4271       foreach my $priority (
4272         $conf->config('ticket_system-custom_priority_field-values'), ''
4273       ) {
4274         last if scalar(@tickets) >= $num;
4275         push @tickets,
4276           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4277                                                  $num - scalar(@tickets),
4278                                                  $priority,
4279                                                  $status,
4280                                                )
4281            };
4282       }
4283     }
4284   }
4285   (@tickets);
4286 }
4287
4288 # Return services representing svc_accts in customer support packages
4289 sub support_services {
4290   my $self = shift;
4291   my %packages = map { $_ => 1 } $conf->config('support_packages');
4292
4293   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4294     grep { $_->part_svc->svcdb eq 'svc_acct' }
4295     map { $_->cust_svc }
4296     grep { exists $packages{ $_->pkgpart } }
4297     $self->ncancelled_pkgs;
4298
4299 }
4300
4301 # Return a list of latitude/longitude for one of the services (if any)
4302 sub service_coordinates {
4303   my $self = shift;
4304
4305   my @svc_X =
4306     grep { $_->latitude && $_->longitude }
4307     map { $_->svc_x }
4308     map { $_->cust_svc }
4309     $self->ncancelled_pkgs;
4310
4311   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4312 }
4313
4314 =item masked FIELD
4315
4316 Returns a masked version of the named field
4317
4318 =cut
4319
4320 sub masked {
4321 my ($self,$field) = @_;
4322
4323 # Show last four
4324
4325 'x'x(length($self->getfield($field))-4).
4326   substr($self->getfield($field), (length($self->getfield($field))-4));
4327
4328 }
4329
4330 =back
4331
4332 =head1 CLASS METHODS
4333
4334 =over 4
4335
4336 =item statuses
4337
4338 Class method that returns the list of possible status strings for customers
4339 (see L<the status method|/status>).  For example:
4340
4341   @statuses = FS::cust_main->statuses();
4342
4343 =cut
4344
4345 sub statuses {
4346   my $self = shift;
4347   keys %{ $self->statuscolors };
4348 }
4349
4350 =item cust_status_sql
4351
4352 Returns an SQL fragment to determine the status of a cust_main record, as a
4353 string.
4354
4355 =cut
4356
4357 sub cust_status_sql {
4358   my $sql = 'CASE';
4359   for my $status ( FS::cust_main->statuses() ) {
4360     my $method = $status.'_sql';
4361     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4362   }
4363   $sql .= ' END';
4364   return $sql;
4365 }
4366
4367
4368 =item prospect_sql
4369
4370 Returns an SQL expression identifying prospective cust_main records (customers
4371 with no packages ever ordered)
4372
4373 =cut
4374
4375 use vars qw($select_count_pkgs);
4376 $select_count_pkgs =
4377   "SELECT COUNT(*) FROM cust_pkg
4378     WHERE cust_pkg.custnum = cust_main.custnum";
4379
4380 sub select_count_pkgs_sql {
4381   $select_count_pkgs;
4382 }
4383
4384 sub prospect_sql {
4385   " 0 = ( $select_count_pkgs ) ";
4386 }
4387
4388 =item ordered_sql
4389
4390 Returns an SQL expression identifying ordered cust_main records (customers with
4391 no active packages, but recurring packages not yet setup or one time charges
4392 not yet billed).
4393
4394 =cut
4395
4396 sub ordered_sql {
4397   FS::cust_main->none_active_sql.
4398   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4399 }
4400
4401 =item active_sql
4402
4403 Returns an SQL expression identifying active cust_main records (customers with
4404 active recurring packages).
4405
4406 =cut
4407
4408 sub active_sql {
4409   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4410 }
4411
4412 =item none_active_sql
4413
4414 Returns an SQL expression identifying cust_main records with no active
4415 recurring packages.  This includes customers of status prospect, ordered,
4416 inactive, and suspended.
4417
4418 =cut
4419
4420 sub none_active_sql {
4421   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4422 }
4423
4424 =item inactive_sql
4425
4426 Returns an SQL expression identifying inactive cust_main records (customers with
4427 no active recurring packages, but otherwise unsuspended/uncancelled).
4428
4429 =cut
4430
4431 sub inactive_sql {
4432   FS::cust_main->none_active_sql.
4433   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4434 }
4435
4436 =item susp_sql
4437 =item suspended_sql
4438
4439 Returns an SQL expression identifying suspended cust_main records.
4440
4441 =cut
4442
4443
4444 sub suspended_sql { susp_sql(@_); }
4445 sub susp_sql {
4446   FS::cust_main->none_active_sql.
4447   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4448 }
4449
4450 =item cancel_sql
4451 =item cancelled_sql
4452
4453 Returns an SQL expression identifying cancelled cust_main records.
4454
4455 =cut
4456
4457 sub cancel_sql { shift->cancelled_sql(@_); }
4458
4459 =item uncancel_sql
4460 =item uncancelled_sql
4461
4462 Returns an SQL expression identifying un-cancelled cust_main records.
4463
4464 =cut
4465
4466 sub uncancelled_sql { uncancel_sql(@_); }
4467 sub uncancel_sql { "
4468   ( 0 < ( $select_count_pkgs
4469                    AND ( cust_pkg.cancel IS NULL
4470                          OR cust_pkg.cancel = 0
4471                        )
4472         )
4473     OR 0 = ( $select_count_pkgs )
4474   )
4475 "; }
4476
4477 =item balance_sql
4478
4479 Returns an SQL fragment to retreive the balance.
4480
4481 =cut
4482
4483 sub balance_sql { "
4484     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4485         WHERE cust_bill.custnum   = cust_main.custnum     )
4486   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4487         WHERE cust_pay.custnum    = cust_main.custnum     )
4488   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4489         WHERE cust_credit.custnum = cust_main.custnum     )
4490   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4491         WHERE cust_refund.custnum = cust_main.custnum     )
4492 "; }
4493
4494 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4495
4496 Returns an SQL fragment to retreive the balance for this customer, optionally
4497 considering invoices with date earlier than START_TIME, and not
4498 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4499 total_unapplied_payments).
4500
4501 Times are specified as SQL fragments or numeric
4502 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4503 L<Date::Parse> for conversion functions.  The empty string can be passed
4504 to disable that time constraint completely.
4505
4506 Available options are:
4507
4508 =over 4
4509
4510 =item unapplied_date
4511
4512 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4513
4514 =item total
4515
4516 (unused.  obsolete?)
4517 set to true to remove all customer comparison clauses, for totals
4518
4519 =item where
4520
4521 (unused.  obsolete?)
4522 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4523
4524 =item join
4525
4526 (unused.  obsolete?)
4527 JOIN clause (typically used with the total option)
4528
4529 =item cutoff
4530
4531 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4532 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4533 range for invoices and I<unapplied> payments, credits, and refunds.
4534
4535 =back
4536
4537 =cut
4538
4539 sub balance_date_sql {
4540   my( $class, $start, $end, %opt ) = @_;
4541
4542   my $cutoff = $opt{'cutoff'};
4543
4544   my $owed         = FS::cust_bill->owed_sql($cutoff);
4545   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4546   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4547   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4548
4549   my $j = $opt{'join'} || '';
4550
4551   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4552   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4553   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4554   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4555
4556   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4557     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4558     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4559     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4560   ";
4561
4562 }
4563
4564 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4565
4566 Returns an SQL fragment to retreive the total unapplied payments for this
4567 customer, only considering payments with date earlier than START_TIME, and
4568 optionally not later than END_TIME.
4569
4570 Times are specified as SQL fragments or numeric
4571 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4572 L<Date::Parse> for conversion functions.  The empty string can be passed
4573 to disable that time constraint completely.
4574
4575 Available options are:
4576
4577 =cut
4578
4579 sub unapplied_payments_date_sql {
4580   my( $class, $start, $end, %opt ) = @_;
4581
4582   my $cutoff = $opt{'cutoff'};
4583
4584   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4585
4586   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4587                                                           'unapplied_date'=>1 );
4588
4589   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4590 }
4591
4592 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4593
4594 Helper method for balance_date_sql; name (and usage) subject to change
4595 (suggestions welcome).
4596
4597 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4598 cust_refund, cust_credit or cust_pay).
4599
4600 If TABLE is "cust_bill" or the unapplied_date option is true, only
4601 considers records with date earlier than START_TIME, and optionally not
4602 later than END_TIME .
4603
4604 =cut
4605
4606 sub _money_table_where {
4607   my( $class, $table, $start, $end, %opt ) = @_;
4608
4609   my @where = ();
4610   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4611   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4612     push @where, "$table._date <= $start" if defined($start) && length($start);
4613     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4614   }
4615   push @where, @{$opt{'where'}} if $opt{'where'};
4616   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4617
4618   $where;
4619
4620 }
4621
4622 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4623 use FS::cust_main::Search;
4624 sub search {
4625   my $class = shift;
4626   FS::cust_main::Search->search(@_);
4627 }
4628
4629 =back
4630
4631 =head1 SUBROUTINES
4632
4633 =over 4
4634
4635 =item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4636
4637 Deprecated.  Use event notification and message templates
4638 (L<FS::msg_template>) instead.
4639
4640 Sends a templated email notification to the customer (see L<Text::Template>).
4641
4642 OPTIONS is a hash and may include
4643
4644 I<from> - the email sender (default is invoice_from)
4645
4646 I<to> - comma-separated scalar or arrayref of recipients
4647    (default is invoicing_list)
4648
4649 I<subject> - The subject line of the sent email notification
4650    (default is "Notice from company_name")
4651
4652 I<extra_fields> - a hashref of name/value pairs which will be substituted
4653    into the template
4654
4655 The following variables are vavailable in the template.
4656
4657 I<$first> - the customer first name
4658 I<$last> - the customer last name
4659 I<$company> - the customer company
4660 I<$payby> - a description of the method of payment for the customer
4661             # would be nice to use FS::payby::shortname
4662 I<$payinfo> - the account information used to collect for this customer
4663 I<$expdate> - the expiration of the customer payment in seconds from epoch
4664
4665 =cut
4666
4667 sub notify {
4668   my ($self, $template, %options) = @_;
4669
4670   return unless $conf->exists($template);
4671
4672   my $from = $conf->config('invoice_from', $self->agentnum)
4673     if $conf->exists('invoice_from', $self->agentnum);
4674   $from = $options{from} if exists($options{from});
4675
4676   my $to = join(',', $self->invoicing_list_emailonly);
4677   $to = $options{to} if exists($options{to});
4678
4679   my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
4680     if $conf->exists('company_name', $self->agentnum);
4681   $subject = $options{subject} if exists($options{subject});
4682
4683   my $notify_template = new Text::Template (TYPE => 'ARRAY',
4684                                             SOURCE => [ map "$_\n",
4685                                               $conf->config($template)]
4686                                            )
4687     or die "can't create new Text::Template object: Text::Template::ERROR";
4688   $notify_template->compile()
4689     or die "can't compile template: Text::Template::ERROR";
4690
4691   $FS::notify_template::_template::company_name =
4692     $conf->config('company_name', $self->agentnum);
4693   $FS::notify_template::_template::company_address =
4694     join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
4695
4696   my $paydate = $self->paydate || '2037-12-31';
4697   $FS::notify_template::_template::first = $self->first;
4698   $FS::notify_template::_template::last = $self->last;
4699   $FS::notify_template::_template::company = $self->company;
4700   $FS::notify_template::_template::payinfo = $self->mask_payinfo;
4701   my $payby = $self->payby;
4702   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4703   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4704
4705   #credit cards expire at the end of the month/year of their exp date
4706   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4707     $FS::notify_template::_template::payby = 'credit card';
4708     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4709     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4710     $expire_time--;
4711   }elsif ($payby eq 'COMP') {
4712     $FS::notify_template::_template::payby = 'complimentary account';
4713   }else{
4714     $FS::notify_template::_template::payby = 'current method';
4715   }
4716   $FS::notify_template::_template::expdate = $expire_time;
4717
4718   for (keys %{$options{extra_fields}}){
4719     no strict "refs";
4720     ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
4721   }
4722
4723   send_email(from => $from,
4724              to => $to,
4725              subject => $subject,
4726              body => $notify_template->fill_in( PACKAGE =>
4727                                                 'FS::notify_template::_template'                                              ),
4728             );
4729
4730 }
4731
4732 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4733
4734 Generates a templated notification to the customer (see L<Text::Template>).
4735
4736 OPTIONS is a hash and may include
4737
4738 I<extra_fields> - a hashref of name/value pairs which will be substituted
4739    into the template.  These values may override values mentioned below
4740    and those from the customer record.
4741
4742 The following variables are available in the template instead of or in addition
4743 to the fields of the customer record.
4744
4745 I<$payby> - a description of the method of payment for the customer
4746             # would be nice to use FS::payby::shortname
4747 I<$payinfo> - the masked account information used to collect for this customer
4748 I<$expdate> - the expiration of the customer payment method in seconds from epoch
4749 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4750
4751 =cut
4752
4753 # a lot like cust_bill::print_latex
4754 sub generate_letter {
4755   my ($self, $template, %options) = @_;
4756
4757   return unless $conf->exists($template);
4758
4759   my $letter_template = new Text::Template
4760                         ( TYPE       => 'ARRAY',
4761                           SOURCE     => [ map "$_\n", $conf->config($template)],
4762                           DELIMITERS => [ '[@--', '--@]' ],
4763                         )
4764     or die "can't create new Text::Template object: Text::Template::ERROR";
4765
4766   $letter_template->compile()
4767     or die "can't compile template: Text::Template::ERROR";
4768
4769   my %letter_data = map { $_ => $self->$_ } $self->fields;
4770   $letter_data{payinfo} = $self->mask_payinfo;
4771
4772   #my $paydate = $self->paydate || '2037-12-31';
4773   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
4774
4775   my $payby = $self->payby;
4776   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4777   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4778
4779   #credit cards expire at the end of the month/year of their exp date
4780   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4781     $letter_data{payby} = 'credit card';
4782     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4783     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4784     $expire_time--;
4785   }elsif ($payby eq 'COMP') {
4786     $letter_data{payby} = 'complimentary account';
4787   }else{
4788     $letter_data{payby} = 'current method';
4789   }
4790   $letter_data{expdate} = $expire_time;
4791
4792   for (keys %{$options{extra_fields}}){
4793     $letter_data{$_} = $options{extra_fields}->{$_};
4794   }
4795
4796   unless(exists($letter_data{returnaddress})){
4797     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4798                                                   $self->agent_template)
4799                      );
4800     if ( length($retadd) ) {
4801       $letter_data{returnaddress} = $retadd;
4802     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4803       $letter_data{returnaddress} =
4804         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4805                           s/$/\\\\\*/;
4806                           $_;
4807                         }
4808                     ( $conf->config('company_name', $self->agentnum),
4809                       $conf->config('company_address', $self->agentnum),
4810                     )
4811         );
4812     } else {
4813       $letter_data{returnaddress} = '~';
4814     }
4815   }
4816
4817   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4818
4819   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4820
4821   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4822
4823   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4824                            DIR      => $dir,
4825                            SUFFIX   => '.eps',
4826                            UNLINK   => 0,
4827                          ) or die "can't open temp file: $!\n";
4828   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4829     or die "can't write temp file: $!\n";
4830   close $lh;
4831   $letter_data{'logo_file'} = $lh->filename;
4832
4833   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4834                            DIR      => $dir,
4835                            SUFFIX   => '.tex',
4836                            UNLINK   => 0,
4837                          ) or die "can't open temp file: $!\n";
4838
4839   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4840   close $fh;
4841   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4842   return ($1, $letter_data{'logo_file'});
4843
4844 }
4845
4846 =item print_ps TEMPLATE
4847
4848 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4849
4850 =cut
4851
4852 sub print_ps {
4853   my $self = shift;
4854   my($file, $lfile) = $self->generate_letter(@_);
4855   my $ps = FS::Misc::generate_ps($file);
4856   unlink($file.'.tex');
4857   unlink($lfile);
4858
4859   $ps;
4860 }
4861
4862 =item print TEMPLATE
4863
4864 Prints the filled in template.
4865
4866 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4867
4868 =cut
4869
4870 sub queueable_print {
4871   my %opt = @_;
4872
4873   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4874     or die "invalid customer number: " . $opt{custnum};
4875
4876   my $error = $self->print( { 'template' => $opt{template} } );
4877   die $error if $error;
4878 }
4879
4880 sub print {
4881   my ($self, $template) = (shift, shift);
4882   do_print(
4883     [ $self->print_ps($template) ],
4884     'agentnum' => $self->agentnum,
4885   );
4886 }
4887
4888 #these three subs should just go away once agent stuff is all config overrides
4889
4890 sub agent_template {
4891   my $self = shift;
4892   $self->_agent_plandata('agent_templatename');
4893 }
4894
4895 sub agent_invoice_from {
4896   my $self = shift;
4897   $self->_agent_plandata('agent_invoice_from');
4898 }
4899
4900 sub _agent_plandata {
4901   my( $self, $option ) = @_;
4902
4903   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4904   #agent-specific Conf
4905
4906   use FS::part_event::Condition;
4907
4908   my $agentnum = $self->agentnum;
4909
4910   my $regexp = regexp_sql();
4911
4912   my $part_event_option =
4913     qsearchs({
4914       'select'    => 'part_event_option.*',
4915       'table'     => 'part_event_option',
4916       'addl_from' => q{
4917         LEFT JOIN part_event USING ( eventpart )
4918         LEFT JOIN part_event_option AS peo_agentnum
4919           ON ( part_event.eventpart = peo_agentnum.eventpart
4920                AND peo_agentnum.optionname = 'agentnum'
4921                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
4922              )
4923         LEFT JOIN part_event_condition
4924           ON ( part_event.eventpart = part_event_condition.eventpart
4925                AND part_event_condition.conditionname = 'cust_bill_age'
4926              )
4927         LEFT JOIN part_event_condition_option
4928           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
4929                AND part_event_condition_option.optionname = 'age'
4930              )
4931       },
4932       #'hashref'   => { 'optionname' => $option },
4933       #'hashref'   => { 'part_event_option.optionname' => $option },
4934       'extra_sql' =>
4935         " WHERE part_event_option.optionname = ". dbh->quote($option).
4936         " AND action = 'cust_bill_send_agent' ".
4937         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
4938         " AND peo_agentnum.optionname = 'agentnum' ".
4939         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
4940         " ORDER BY
4941            CASE WHEN part_event_condition_option.optionname IS NULL
4942            THEN -1
4943            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
4944         " END
4945           , part_event.weight".
4946         " LIMIT 1"
4947     });
4948
4949   unless ( $part_event_option ) {
4950     return $self->agent->invoice_template || ''
4951       if $option eq 'agent_templatename';
4952     return '';
4953   }
4954
4955   $part_event_option->optionvalue;
4956
4957 }
4958
4959 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
4960
4961 Subroutine (not a method), designed to be called from the queue.
4962
4963 Takes a list of options and values.
4964
4965 Pulls up the customer record via the custnum option and calls bill_and_collect.
4966
4967 =cut
4968
4969 sub queued_bill {
4970   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
4971
4972   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
4973   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
4974
4975   #without this errors don't get rolled back
4976   $args{'fatal'} = 1; # runs from job queue, will be caught
4977
4978   $cust_main->bill_and_collect( %args );
4979 }
4980
4981 sub process_bill_and_collect {
4982   my $job = shift;
4983   my $param = thaw(decode_base64(shift));
4984   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
4985       or die "custnum '$param->{custnum}' not found!\n";
4986   $param->{'job'}   = $job;
4987   $param->{'fatal'} = 1; # runs from job queue, will be caught
4988   $param->{'retry'} = 1;
4989
4990   $cust_main->bill_and_collect( %$param );
4991 }
4992
4993 #starting to take quite a while for big dbs
4994 #   (JRNL: journaled so it only happens once per database)
4995 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
4996 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
4997 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
4998 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
4999 # JRNL leading/trailing spaces in first, last, company
5000 # JRNL migrate to cust_payby
5001 # - otaker upgrade?  journal and call it good?  (double check to make sure
5002 #    we're not still setting otaker here)
5003 #
5004 #only going to get worse with new location stuff...
5005
5006 sub _upgrade_data { #class method
5007   my ($class, %opts) = @_;
5008
5009   my @statements = (
5010     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
5011   );
5012
5013   #this seems to be the only expensive one.. why does it take so long?
5014   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5015     push @statements,
5016       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5017     FS::upgrade_journal->set_done('cust_main__signupdate');
5018   }
5019
5020   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
5021
5022     # fix yyyy-m-dd formatted paydates
5023     if ( driver_name =~ /^mysql/i ) {
5024       push @statements,
5025       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5026     } else { # the SQL standard
5027       push @statements,
5028       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5029     }
5030     FS::upgrade_journal->set_done('cust_main__paydate');
5031   }
5032
5033   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5034
5035     push @statements, #fix the weird BILL with a cc# in payinfo problem
5036       #DCRD to be safe
5037       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5038
5039     FS::upgrade_journal->set_done('cust_main__payinfo');
5040
5041   }
5042
5043   my $t = time;
5044   foreach my $sql ( @statements ) {
5045     my $sth = dbh->prepare($sql) or die dbh->errstr;
5046     $sth->execute or die $sth->errstr;
5047     #warn ( (time - $t). " seconds\n" );
5048     #$t = time;
5049   }
5050
5051   local($ignore_expired_card) = 1;
5052   local($ignore_banned_card) = 1;
5053   local($skip_fuzzyfiles) = 1;
5054   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5055
5056   FS::cust_main::Location->_upgrade_data(%opts);
5057
5058   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5059
5060     foreach my $cust_main ( qsearch({
5061       'table'     => 'cust_main',
5062       'hashref'   => {},
5063       'extra_sql' => 'WHERE '.
5064                        join(' OR ',
5065                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5066                            qw( first last company )
5067                        ),
5068     }) ) {
5069       my $error = $cust_main->replace;
5070       die $error if $error;
5071     }
5072
5073     FS::upgrade_journal->set_done('cust_main__trimspaces');
5074
5075   }
5076
5077   unless ( FS::upgrade_journal->is_done('cust_main__cust_payby') ) {
5078
5079     #we don't want to decrypt them, just stuff them as-is into cust_payby
5080     local(@encrypted_fields) = ();
5081
5082     local($FS::cust_payby::ignore_expired_card) = 1;
5083     local($FS::cust_payby::ignore_banned_card) = 1;
5084
5085     my @payfields = qw( payby payinfo paycvv paymask
5086                         paydate paystart_month paystart_year payissue
5087                         payname paystate paytype payip
5088                       );
5089
5090     my $search = new FS::Cursor {
5091       'table'     => 'cust_main',
5092       'extra_sql' => " WHERE ( payby IS NOT NULL AND payby != '' ) ",
5093     };
5094
5095     while (my $cust_main = $search->fetch) {
5096
5097       my $cust_payby = new FS::cust_payby {
5098         'custnum' => $cust_main->custnum,
5099         'weight'  => 1,
5100         map { $_ => $cust_main->$_(); } @payfields
5101       };
5102
5103       my $error = $cust_payby->insert;
5104       die $error if $error;
5105
5106       $cust_main->setfield($_, '') foreach @payfields;
5107       $error = $cust_main->replace;
5108       die $error if $error;
5109
5110     };
5111
5112     FS::upgrade_journal->set_done('cust_main__cust_payby');
5113   }
5114
5115   $class->_upgrade_otaker(%opts);
5116
5117 }
5118
5119 =back
5120
5121 =head1 BUGS
5122
5123 The delete method.
5124
5125 The delete method should possibly take an FS::cust_main object reference
5126 instead of a scalar customer number.
5127
5128 Bill and collect options should probably be passed as references instead of a
5129 list.
5130
5131 There should probably be a configuration file with a list of allowed credit
5132 card types.
5133
5134 No multiple currency support (probably a larger project than just this module).
5135
5136 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5137
5138 Birthdates rely on negative epoch values.
5139
5140 The payby for card/check batches is broken.  With mixed batching, bad
5141 things will happen.
5142
5143 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5144
5145 =head1 SEE ALSO
5146
5147 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5148 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5149 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5150
5151 =cut
5152
5153 1;
5154