FS/FS/cust_main.pm

   1 package FS::cust_main;
   2
   3 require 5.006;
   4 use strict;
   5 use base qw( FS::cust_main::Packages FS::cust_main::Status
   6              FS::cust_main::NationalID
   7              FS::cust_main::Billing FS::cust_main::Billing_Realtime
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Location
  10              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  11              FS::geocode_Mixin FS::Quotable_Mixin
  12              FS::o2m_Common
  13              FS::Record
  14            );
  15 use vars qw( $DEBUG $me $conf
  16              @encrypted_fields
  17              $import
  18              $ignore_expired_card $ignore_banned_card $ignore_illegal_zip
  19              $skip_fuzzyfiles
  20              @paytypes
  21            );
  22 use Carp;
  23 use Scalar::Util qw( blessed );
  24 use Time::Local qw(timelocal);
  25 use Storable qw(thaw);
  26 use MIME::Base64;
  27 use Data::Dumper;
  28 use Tie::IxHash;
  29 use Digest::MD5 qw(md5_base64);
  30 use Date::Format;
  31 #use Date::Manip;
  32 use File::Temp; #qw( tempfile );
  33 use Business::CreditCard 0.28;
  34 use Locale::Country;
  35 use FS::UID qw( dbh driver_name );
  36 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  37 use FS::Misc qw( generate_email send_email generate_ps do_print );
  38 use FS::Msgcat qw(gettext);
  39 use FS::CurrentUser;
  40 use FS::TicketSystem;
  41 use FS::payby;
  42 use FS::cust_pkg;
  43 use FS::cust_svc;
  44 use FS::cust_bill;
  45 use FS::cust_bill_void;
  46 use FS::legacy_cust_bill;
  47 use FS::cust_pay;
  48 use FS::cust_pay_pending;
  49 use FS::cust_pay_void;
  50 use FS::cust_pay_batch;
  51 use FS::cust_credit;
  52 use FS::cust_refund;
  53 use FS::part_referral;
  54 use FS::cust_main_county;
  55 use FS::cust_location;
  56 use FS::cust_class;
  57 use FS::cust_main_exemption;
  58 use FS::cust_tax_adjustment;
  59 use FS::cust_tax_location;
  60 use FS::agent;
  61 use FS::agent_currency;
  62 use FS::cust_main_invoice;
  63 use FS::cust_tag;
  64 use FS::prepay_credit;
  65 use FS::queue;
  66 use FS::part_pkg;
  67 use FS::part_export;
  68 #use FS::cust_event;
  69 use FS::type_pkgs;
  70 use FS::payment_gateway;
  71 use FS::agent_payment_gateway;
  72 use FS::banned_pay;
  73 use FS::cust_main_note;
  74 use FS::cust_attachment;
  75 use FS::contact;
  76 use FS::Locales;
  77 use FS::upgrade_journal;
  78
  79 # 1 is mostly method/subroutine entry and options
  80 # 2 traces progress of some operations
  81 # 3 is even more information including possibly sensitive data
  82 $DEBUG = 0;
  83 $me = '[FS::cust_main]';
  84
  85 $import = 0;
  86 $ignore_expired_card = 0;
  87 $ignore_banned_card = 0;
  88
  89 $skip_fuzzyfiles = 0;
  90
  91 @encrypted_fields = ('payinfo', 'paycvv');
  92 sub nohistory_fields { ('payinfo', 'paycvv'); }
  93
  94 @paytypes = ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
  95
  96 #ask FS::UID to run this stuff for us later
  97 #$FS::UID::callback{'FS::cust_main'} = sub {
  98 install_callback FS::UID sub {
  99   $conf = new FS::Conf;
 100   #yes, need it for stuff below (prolly should be cached)
 101 };
 102
 103 sub _cache {
 104   my $self = shift;
 105   my ( $hashref, $cache ) = @_;
 106   if ( exists $hashref->{'pkgnum'} ) {
 107     #@{ $self->{'_pkgnum'} } = ();
 108     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 109     $self->{'_pkgnum'} = $subcache;
 110     #push @{ $self->{'_pkgnum'} },
 111     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 112   }
 113 }
 114
 115 =head1 NAME
 116
 117 FS::cust_main - Object methods for cust_main records
 118
 119 =head1 SYNOPSIS
 120
 121   use FS::cust_main;
 122
 123   $record = new FS::cust_main \%hash;
 124   $record = new FS::cust_main { 'column' => 'value' };
 125
 126   $error = $record->insert;
 127
 128   $error = $new_record->replace($old_record);
 129
 130   $error = $record->delete;
 131
 132   $error = $record->check;
 133
 134   @cust_pkg = $record->all_pkgs;
 135
 136   @cust_pkg = $record->ncancelled_pkgs;
 137
 138   @cust_pkg = $record->suspended_pkgs;
 139
 140   $error = $record->bill;
 141   $error = $record->bill %options;
 142   $error = $record->bill 'time' => $time;
 143
 144   $error = $record->collect;
 145   $error = $record->collect %options;
 146   $error = $record->collect 'invoice_time'   => $time,
 147                           ;
 148
 149 =head1 DESCRIPTION
 150
 151 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 152 FS::Record.  The following fields are currently supported:
 153
 154 =over 4
 155
 156 =item custnum
 157
 158 Primary key (assigned automatically for new customers)
 159
 160 =item agentnum
 161
 162 Agent (see L<FS::agent>)
 163
 164 =item refnum
 165
 166 Advertising source (see L<FS::part_referral>)
 167
 168 =item first
 169
 170 First name
 171
 172 =item last
 173
 174 Last name
 175
 176 =item ss
 177
 178 Cocial security number (optional)
 179
 180 =item company
 181
 182 (optional)
 183
 184 =item daytime
 185
 186 phone (optional)
 187
 188 =item night
 189
 190 phone (optional)
 191
 192 =item fax
 193
 194 phone (optional)
 195
 196 =item mobile
 197
 198 phone (optional)
 199
 200 =item payby
 201
 202 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 203
 204 =item payinfo
 205
 206 Payment Information (See L<FS::payinfo_Mixin> for data format)
 207
 208 =item paymask
 209
 210 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 211
 212 =item paycvv
 213
 214 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 215
 216 =item paydate
 217
 218 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 219
 220 =item paystart_month
 221
 222 Start date month (maestro/solo cards only)
 223
 224 =item paystart_year
 225
 226 Start date year (maestro/solo cards only)
 227
 228 =item payissue
 229
 230 Issue number (maestro/solo cards only)
 231
 232 =item payname
 233
 234 Name on card or billing name
 235
 236 =item payip
 237
 238 IP address from which payment information was received
 239
 240 =item tax
 241
 242 Tax exempt, empty or `Y'
 243
 244 =item usernum
 245
 246 Order taker (see L<FS::access_user>)
 247
 248 =item comments
 249
 250 Comments (optional)
 251
 252 =item referral_custnum
 253
 254 Referring customer number
 255
 256 =item spool_cdr
 257
 258 Enable individual CDR spooling, empty or `Y'
 259
 260 =item dundate
 261
 262 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 263
 264 =item squelch_cdr
 265
 266 Discourage individual CDR printing, empty or `Y'
 267
 268 =item edit_subject
 269
 270 Allow self-service editing of ticket subjects, empty or 'Y'
 271
 272 =item calling_list_exempt
 273
 274 Do not call, empty or 'Y'
 275
 276 =back
 277
 278 =head1 METHODS
 279
 280 =over 4
 281
 282 =item new HASHREF
 283
 284 Creates a new customer.  To add the customer to the database, see L<"insert">.
 285
 286 Note that this stores the hash reference, not a distinct copy of the hash it
 287 points to.  You can ask the object for a copy with the I<hash> method.
 288
 289 =cut
 290
 291 sub table { 'cust_main'; }
 292
 293 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 294
 295 Adds this customer to the database.  If there is an error, returns the error,
 296 otherwise returns false.
 297
 298 Usually the customer's location will not yet exist in the database, and
 299 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 300 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 301 (in both directions) to the new customer record.  If they're references
 302 to the same object, they will become the same location.
 303
 304 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 305 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 306 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 307 hash reference is equivalent to not supplying this parameter.  There should be
 308 a better explanation of this, but until then, here's an example:
 309
 310   use Tie::RefHash;
 311   tie %hash, 'Tie::RefHash'; #this part is important
 312   %hash = (
 313     $cust_pkg => [ $svc_acct ],
 314     ...
 315   );
 316   $cust_main->insert( \%hash );
 317
 318 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 319 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 320 expected and rollback the entire transaction; it is not necessary to call
 321 check_invoicing_list first.  The invoicing_list is set after the records in the
 322 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 323 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 324
 325   $cust_main->insert( {}, [ $email, 'POST' ] );
 326
 327 Currently available options are: I<depend_jobnum>, I<noexport>,
 328 I<tax_exemption> and I<prospectnum>.
 329
 330 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 331 on the supplied jobnum (they will not run until the specific job completes).
 332 This can be used to defer provisioning until some action completes (such
 333 as running the customer's credit card successfully).
 334
 335 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 336 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 337 the B<reexport> method.)
 338
 339 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 340 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 341 created and inserted.
 342
 343 If I<prospectnum> is set, moves contacts and locations from that prospect.
 344
 345 =cut
 346
 347 sub insert {
 348   my $self = shift;
 349   my $cust_pkgs = @_ ? shift : {};
 350   my $invoicing_list = @_ ? shift : '';
 351   my %options = @_;
 352   warn "$me insert called with options ".
 353        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 354     if $DEBUG;
 355
 356   local $SIG{HUP} = 'IGNORE';
 357   local $SIG{INT} = 'IGNORE';
 358   local $SIG{QUIT} = 'IGNORE';
 359   local $SIG{TERM} = 'IGNORE';
 360   local $SIG{TSTP} = 'IGNORE';
 361   local $SIG{PIPE} = 'IGNORE';
 362
 363   my $oldAutoCommit = $FS::UID::AutoCommit;
 364   local $FS::UID::AutoCommit = 0;
 365   my $dbh = dbh;
 366
 367   my $prepay_identifier = '';
 368   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 369   my $payby = '';
 370   if ( $self->payby eq 'PREPAY' ) {
 371
 372     $self->payby('BILL');
 373     $prepay_identifier = $self->payinfo;
 374     $self->payinfo('');
 375
 376     warn "  looking up prepaid card $prepay_identifier\n"
 377       if $DEBUG > 1;
 378
 379     my $error = $self->get_prepay( $prepay_identifier,
 380                                    'amount_ref'     => \$amount,
 381                                    'seconds_ref'    => \$seconds,
 382                                    'upbytes_ref'    => \$upbytes,
 383                                    'downbytes_ref'  => \$downbytes,
 384                                    'totalbytes_ref' => \$totalbytes,
 385                                  );
 386     if ( $error ) {
 387       $dbh->rollback if $oldAutoCommit;
 388       #return "error applying prepaid card (transaction rolled back): $error";
 389       return $error;
 390     }
 391
 392     $payby = 'PREP' if $amount;
 393
 394   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|PPAL)$/ ) {
 395
 396     $payby = $1;
 397     $self->payby('BILL');
 398     $amount = $self->paid;
 399
 400   }
 401
 402   # insert locations
 403   foreach my $l (qw(bill_location ship_location)) {
 404     my $loc = delete $self->hashref->{$l};
 405     # XXX if we're moving a prospect's locations, do that here
 406     if ( !$loc ) {
 407       return "$l not set";
 408     }
 409
 410     if ( !$loc->locationnum ) {
 411       # warn the location that we're going to insert it with no custnum
 412       $loc->set(custnum_pending => 1);
 413       warn "  inserting $l\n"
 414         if $DEBUG > 1;
 415       my $error = $loc->insert;
 416       if ( $error ) {
 417         $dbh->rollback if $oldAutoCommit;
 418         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 419         return "$error (in $label location)";
 420       }
 421     }
 422     elsif ( ($loc->custnum || 0) > 0 or $loc->prospectnum ) {
 423       # then it somehow belongs to another customer--shouldn't happen
 424       $dbh->rollback if $oldAutoCommit;
 425       return "$l belongs to customer ".$loc->custnum;
 426     }
 427     # else it already belongs to this customer
 428     # (happens when ship_location is identical to bill_location)
 429
 430     $self->set($l.'num', $loc->locationnum);
 431
 432     if ( $self->get($l.'num') eq '' ) {
 433       $dbh->rollback if $oldAutoCommit;
 434       return "$l not set";
 435     }
 436   }
 437
 438   warn "  inserting $self\n"
 439     if $DEBUG > 1;
 440
 441   $self->signupdate(time) unless $self->signupdate;
 442
 443   $self->auto_agent_custid()
 444     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 445
 446   my $error = $self->SUPER::insert;
 447   if ( $error ) {
 448     $dbh->rollback if $oldAutoCommit;
 449     #return "inserting cust_main record (transaction rolled back): $error";
 450     return $error;
 451   }
 452
 453   # now set cust_location.custnum
 454   foreach my $l (qw(bill_location ship_location)) {
 455     warn "  setting $l.custnum\n"
 456       if $DEBUG > 1;
 457     my $loc = $self->$l;
 458     unless ( $loc->custnum ) {
 459       $loc->set(custnum => $self->custnum);
 460       $error ||= $loc->replace;
 461     }
 462
 463     if ( $error ) {
 464       $dbh->rollback if $oldAutoCommit;
 465       return "error setting $l custnum: $error";
 466     }
 467   }
 468
 469   warn "  setting invoicing list\n"
 470     if $DEBUG > 1;
 471
 472   if ( $invoicing_list ) {
 473     $error = $self->check_invoicing_list( $invoicing_list );
 474     if ( $error ) {
 475       $dbh->rollback if $oldAutoCommit;
 476       #return "checking invoicing_list (transaction rolled back): $error";
 477       return $error;
 478     }
 479     $self->invoicing_list( $invoicing_list );
 480   }
 481
 482   warn "  setting customer tags\n"
 483     if $DEBUG > 1;
 484
 485   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 486     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 487                                       'custnum' => $self->custnum };
 488     my $error = $cust_tag->insert;
 489     if ( $error ) {
 490       $dbh->rollback if $oldAutoCommit;
 491       return $error;
 492     }
 493   }
 494
 495   my $prospectnum = delete $options{'prospectnum'};
 496   if ( $prospectnum ) {
 497
 498     warn "  moving contacts and locations from prospect $prospectnum\n"
 499       if $DEBUG > 1;
 500
 501     my $prospect_main =
 502       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 503     unless ( $prospect_main ) {
 504       $dbh->rollback if $oldAutoCommit;
 505       return "Unknown prospectnum $prospectnum";
 506     }
 507     $prospect_main->custnum($self->custnum);
 508     $prospect_main->disabled('Y');
 509     my $error = $prospect_main->replace;
 510     if ( $error ) {
 511       $dbh->rollback if $oldAutoCommit;
 512       return $error;
 513     }
 514
 515     my @contact = $prospect_main->contact;
 516     my @cust_location = $prospect_main->cust_location;
 517     my @qual = $prospect_main->qual;
 518
 519     foreach my $r ( @contact, @cust_location, @qual ) {
 520       $r->prospectnum('');
 521       $r->custnum($self->custnum);
 522       my $error = $r->replace;
 523       if ( $error ) {
 524         $dbh->rollback if $oldAutoCommit;
 525         return $error;
 526       }
 527     }
 528
 529   }
 530
 531   warn "  setting cust_main_exemption\n"
 532     if $DEBUG > 1;
 533
 534   my $tax_exemption = delete $options{'tax_exemption'};
 535   if ( $tax_exemption ) {
 536
 537     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 538       if ref($tax_exemption) eq 'ARRAY';
 539
 540     foreach my $taxname ( keys %$tax_exemption ) {
 541       my $cust_main_exemption = new FS::cust_main_exemption {
 542         'custnum'       => $self->custnum,
 543         'taxname'       => $taxname,
 544         'exempt_number' => $tax_exemption->{$taxname},
 545       };
 546       my $error = $cust_main_exemption->insert;
 547       if ( $error ) {
 548         $dbh->rollback if $oldAutoCommit;
 549         return "inserting cust_main_exemption (transaction rolled back): $error";
 550       }
 551     }
 552   }
 553
 554   warn "  ordering packages\n"
 555     if $DEBUG > 1;
 556
 557   $error = $self->order_pkgs( $cust_pkgs,
 558                               %options,
 559                               'seconds_ref'    => \$seconds,
 560                               'upbytes_ref'    => \$upbytes,
 561                               'downbytes_ref'  => \$downbytes,
 562                               'totalbytes_ref' => \$totalbytes,
 563                             );
 564   if ( $error ) {
 565     $dbh->rollback if $oldAutoCommit;
 566     return $error;
 567   }
 568
 569   if ( $seconds ) {
 570     $dbh->rollback if $oldAutoCommit;
 571     return "No svc_acct record to apply pre-paid time";
 572   }
 573   if ( $upbytes || $downbytes || $totalbytes ) {
 574     $dbh->rollback if $oldAutoCommit;
 575     return "No svc_acct record to apply pre-paid data";
 576   }
 577
 578   if ( $amount ) {
 579     warn "  inserting initial $payby payment of $amount\n"
 580       if $DEBUG > 1;
 581     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 582     if ( $error ) {
 583       $dbh->rollback if $oldAutoCommit;
 584       return "inserting payment (transaction rolled back): $error";
 585     }
 586   }
 587
 588   unless ( $import || $skip_fuzzyfiles ) {
 589     warn "  queueing fuzzyfiles update\n"
 590       if $DEBUG > 1;
 591     $error = $self->queue_fuzzyfiles_update;
 592     if ( $error ) {
 593       $dbh->rollback if $oldAutoCommit;
 594       return "updating fuzzy search cache: $error";
 595     }
 596   }
 597
 598   # FS::geocode_Mixin::after_insert or something?
 599   if ( $conf->config('tax_district_method') and !$import ) {
 600     # if anything non-empty, try to look it up
 601     my $queue = new FS::queue {
 602       'job'     => 'FS::geocode_Mixin::process_district_update',
 603       'custnum' => $self->custnum,
 604     };
 605     my $error = $queue->insert( ref($self), $self->custnum );
 606     if ( $error ) {
 607       $dbh->rollback if $oldAutoCommit;
 608       return "queueing tax district update: $error";
 609     }
 610   }
 611
 612   # cust_main exports!
 613   warn "  exporting\n" if $DEBUG > 1;
 614
 615   my $export_args = $options{'export_args'} || [];
 616
 617   my @part_export =
 618     map qsearch( 'part_export', {exportnum=>$_} ),
 619       $conf->config('cust_main-exports'); #, $agentnum
 620
 621   foreach my $part_export ( @part_export ) {
 622     my $error = $part_export->export_insert($self, @$export_args);
 623     if ( $error ) {
 624       $dbh->rollback if $oldAutoCommit;
 625       return "exporting to ". $part_export->exporttype.
 626              " (transaction rolled back): $error";
 627     }
 628   }
 629
 630   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 631   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 632   #      if $DEBUG;
 633   #    foreach my $jobnum ( @jobnums ) {
 634   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 635   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 636   #        if $DEBUG;
 637   #      my $error = $queue->depend_insert($depend_jobnum);
 638   #      if ( $error ) {
 639   #        $dbh->rollback if $oldAutoCommit;
 640   #        return "error queuing job dependancy: $error";
 641   #      }
 642   #    }
 643   #  }
 644   #
 645   #}
 646   #
 647   #if ( exists $options{'jobnums'} ) {
 648   #  push @{ $options{'jobnums'} }, @jobnums;
 649   #}
 650
 651   warn "  insert complete; committing transaction\n"
 652     if $DEBUG > 1;
 653
 654   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 655   '';
 656
 657 }
 658
 659 use File::CounterFile;
 660 sub auto_agent_custid {
 661   my $self = shift;
 662
 663   my $format = $conf->config('cust_main-auto_agent_custid');
 664   my $agent_custid;
 665   if ( $format eq '1YMMXXXXXXXX' ) {
 666
 667     my $counter = new File::CounterFile 'cust_main.agent_custid';
 668     $counter->lock;
 669
 670     my $ym = 100000000000 + time2str('%y%m00000000', time);
 671     if ( $ym > $counter->value ) {
 672       $counter->{'value'} = $agent_custid = $ym;
 673       $counter->{'updated'} = 1;
 674     } else {
 675       $agent_custid = $counter->inc;
 676     }
 677
 678     $counter->unlock;
 679
 680   } else {
 681     die "Unknown cust_main-auto_agent_custid format: $format";
 682   }
 683
 684   $self->agent_custid($agent_custid);
 685
 686 }
 687
 688 =item PACKAGE METHODS
 689
 690 Documentation on customer package methods has been moved to
 691 L<FS::cust_main::Packages>.
 692
 693 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 694
 695 Recharges this (existing) customer with the specified prepaid card (see
 696 L<FS::prepay_credit>), specified either by I<identifier> or as an
 697 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 698 returns false.
 699
 700 Optionally, five scalar references can be passed as well.  They will have their
 701 values filled in with the amount, number of seconds, and number of upload,
 702 download, and total bytes applied by this prepaid card.
 703
 704 =cut
 705
 706 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 707 #the only place that uses these args
 708 sub recharge_prepay {
 709   my( $self, $prepay_credit, $amountref, $secondsref,
 710       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 711
 712   local $SIG{HUP} = 'IGNORE';
 713   local $SIG{INT} = 'IGNORE';
 714   local $SIG{QUIT} = 'IGNORE';
 715   local $SIG{TERM} = 'IGNORE';
 716   local $SIG{TSTP} = 'IGNORE';
 717   local $SIG{PIPE} = 'IGNORE';
 718
 719   my $oldAutoCommit = $FS::UID::AutoCommit;
 720   local $FS::UID::AutoCommit = 0;
 721   my $dbh = dbh;
 722
 723   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 724
 725   my $error = $self->get_prepay( $prepay_credit,
 726                                  'amount_ref'     => \$amount,
 727                                  'seconds_ref'    => \$seconds,
 728                                  'upbytes_ref'    => \$upbytes,
 729                                  'downbytes_ref'  => \$downbytes,
 730                                  'totalbytes_ref' => \$totalbytes,
 731                                )
 732            || $self->increment_seconds($seconds)
 733            || $self->increment_upbytes($upbytes)
 734            || $self->increment_downbytes($downbytes)
 735            || $self->increment_totalbytes($totalbytes)
 736            || $self->insert_cust_pay_prepay( $amount,
 737                                              ref($prepay_credit)
 738                                                ? $prepay_credit->identifier
 739                                                : $prepay_credit
 740                                            );
 741
 742   if ( $error ) {
 743     $dbh->rollback if $oldAutoCommit;
 744     return $error;
 745   }
 746
 747   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 748   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 749   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 750   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 751   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 752
 753   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 754   '';
 755
 756 }
 757
 758 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 759
 760 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 761 specified either by I<identifier> or as an FS::prepay_credit object.
 762
 763 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 764 incremented by the values of the prepaid card.
 765
 766 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 767 check or set this customer's I<agentnum>.
 768
 769 If there is an error, returns the error, otherwise returns false.
 770
 771 =cut
 772
 773
 774 sub get_prepay {
 775   my( $self, $prepay_credit, %opt ) = @_;
 776
 777   local $SIG{HUP} = 'IGNORE';
 778   local $SIG{INT} = 'IGNORE';
 779   local $SIG{QUIT} = 'IGNORE';
 780   local $SIG{TERM} = 'IGNORE';
 781   local $SIG{TSTP} = 'IGNORE';
 782   local $SIG{PIPE} = 'IGNORE';
 783
 784   my $oldAutoCommit = $FS::UID::AutoCommit;
 785   local $FS::UID::AutoCommit = 0;
 786   my $dbh = dbh;
 787
 788   unless ( ref($prepay_credit) ) {
 789
 790     my $identifier = $prepay_credit;
 791
 792     $prepay_credit = qsearchs(
 793       'prepay_credit',
 794       { 'identifier' => $identifier },
 795       '',
 796       'FOR UPDATE'
 797     );
 798
 799     unless ( $prepay_credit ) {
 800       $dbh->rollback if $oldAutoCommit;
 801       return "Invalid prepaid card: ". $identifier;
 802     }
 803
 804   }
 805
 806   if ( $prepay_credit->agentnum ) {
 807     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 808       $dbh->rollback if $oldAutoCommit;
 809       return "prepaid card not valid for agent ". $self->agentnum;
 810     }
 811     $self->agentnum($prepay_credit->agentnum);
 812   }
 813
 814   my $error = $prepay_credit->delete;
 815   if ( $error ) {
 816     $dbh->rollback if $oldAutoCommit;
 817     return "removing prepay_credit (transaction rolled back): $error";
 818   }
 819
 820   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 821     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 822
 823   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 824   '';
 825
 826 }
 827
 828 =item increment_upbytes SECONDS
 829
 830 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 831 the specified number of upbytes.  If there is an error, returns the error,
 832 otherwise returns false.
 833
 834 =cut
 835
 836 sub increment_upbytes {
 837   _increment_column( shift, 'upbytes', @_);
 838 }
 839
 840 =item increment_downbytes SECONDS
 841
 842 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 843 the specified number of downbytes.  If there is an error, returns the error,
 844 otherwise returns false.
 845
 846 =cut
 847
 848 sub increment_downbytes {
 849   _increment_column( shift, 'downbytes', @_);
 850 }
 851
 852 =item increment_totalbytes SECONDS
 853
 854 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 855 the specified number of totalbytes.  If there is an error, returns the error,
 856 otherwise returns false.
 857
 858 =cut
 859
 860 sub increment_totalbytes {
 861   _increment_column( shift, 'totalbytes', @_);
 862 }
 863
 864 =item increment_seconds SECONDS
 865
 866 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 867 the specified number of seconds.  If there is an error, returns the error,
 868 otherwise returns false.
 869
 870 =cut
 871
 872 sub increment_seconds {
 873   _increment_column( shift, 'seconds', @_);
 874 }
 875
 876 =item _increment_column AMOUNT
 877
 878 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 879 the specified number of seconds or bytes.  If there is an error, returns
 880 the error, otherwise returns false.
 881
 882 =cut
 883
 884 sub _increment_column {
 885   my( $self, $column, $amount ) = @_;
 886   warn "$me increment_column called: $column, $amount\n"
 887     if $DEBUG;
 888
 889   return '' unless $amount;
 890
 891   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
 892                       $self->ncancelled_pkgs;
 893
 894   if ( ! @cust_pkg ) {
 895     return 'No packages with primary or single services found'.
 896            ' to apply pre-paid time';
 897   } elsif ( scalar(@cust_pkg) > 1 ) {
 898     #maybe have a way to specify the package/account?
 899     return 'Multiple packages found to apply pre-paid time';
 900   }
 901
 902   my $cust_pkg = $cust_pkg[0];
 903   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
 904     if $DEBUG > 1;
 905
 906   my @cust_svc =
 907     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
 908
 909   if ( ! @cust_svc ) {
 910     return 'No account found to apply pre-paid time';
 911   } elsif ( scalar(@cust_svc) > 1 ) {
 912     return 'Multiple accounts found to apply pre-paid time';
 913   }
 914
 915   my $svc_acct = $cust_svc[0]->svc_x;
 916   warn "  found service svcnum ". $svc_acct->pkgnum.
 917        ' ('. $svc_acct->email. ")\n"
 918     if $DEBUG > 1;
 919
 920   $column = "increment_$column";
 921   $svc_acct->$column($amount);
 922
 923 }
 924
 925 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
 926
 927 Inserts a prepayment in the specified amount for this customer.  An optional
 928 second argument can specify the prepayment identifier for tracking purposes.
 929 If there is an error, returns the error, otherwise returns false.
 930
 931 =cut
 932
 933 sub insert_cust_pay_prepay {
 934   shift->insert_cust_pay('PREP', @_);
 935 }
 936
 937 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
 938
 939 Inserts a cash payment in the specified amount for this customer.  An optional
 940 second argument can specify the payment identifier for tracking purposes.
 941 If there is an error, returns the error, otherwise returns false.
 942
 943 =cut
 944
 945 sub insert_cust_pay_cash {
 946   shift->insert_cust_pay('CASH', @_);
 947 }
 948
 949 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
 950
 951 Inserts a Western Union payment in the specified amount for this customer.  An
 952 optional second argument can specify the prepayment identifier for tracking
 953 purposes.  If there is an error, returns the error, otherwise returns false.
 954
 955 =cut
 956
 957 sub insert_cust_pay_west {
 958   shift->insert_cust_pay('WEST', @_);
 959 }
 960
 961 sub insert_cust_pay {
 962   my( $self, $payby, $amount ) = splice(@_, 0, 3);
 963   my $payinfo = scalar(@_) ? shift : '';
 964
 965   my $cust_pay = new FS::cust_pay {
 966     'custnum' => $self->custnum,
 967     'paid'    => sprintf('%.2f', $amount),
 968     #'_date'   => #date the prepaid card was purchased???
 969     'payby'   => $payby,
 970     'payinfo' => $payinfo,
 971   };
 972   $cust_pay->insert;
 973
 974 }
 975
 976 =item reexport
 977
 978 This method is deprecated.  See the I<depend_jobnum> option to the insert and
 979 order_pkgs methods for a better way to defer provisioning.
 980
 981 Re-schedules all exports by calling the B<reexport> method of all associated
 982 packages (see L<FS::cust_pkg>).  If there is an error, returns the error;
 983 otherwise returns false.
 984
 985 =cut
 986
 987 sub reexport {
 988   my $self = shift;
 989
 990   carp "WARNING: FS::cust_main::reexport is deprectated; ".
 991        "use the depend_jobnum option to insert or order_pkgs to delay export";
 992
 993   local $SIG{HUP} = 'IGNORE';
 994   local $SIG{INT} = 'IGNORE';
 995   local $SIG{QUIT} = 'IGNORE';
 996   local $SIG{TERM} = 'IGNORE';
 997   local $SIG{TSTP} = 'IGNORE';
 998   local $SIG{PIPE} = 'IGNORE';
 999
1000   my $oldAutoCommit = $FS::UID::AutoCommit;
1001   local $FS::UID::AutoCommit = 0;
1002   my $dbh = dbh;
1003
1004   foreach my $cust_pkg ( $self->ncancelled_pkgs ) {
1005     my $error = $cust_pkg->reexport;
1006     if ( $error ) {
1007       $dbh->rollback if $oldAutoCommit;
1008       return $error;
1009     }
1010   }
1011
1012   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1013   '';
1014
1015 }
1016
1017 =item delete [ OPTION => VALUE ... ]
1018
1019 This deletes the customer.  If there is an error, returns the error, otherwise
1020 returns false.
1021
1022 This will completely remove all traces of the customer record.  This is not
1023 what you want when a customer cancels service; for that, cancel all of the
1024 customer's packages (see L</cancel>).
1025
1026 If the customer has any uncancelled packages, you need to pass a new (valid)
1027 customer number for those packages to be transferred to, as the "new_customer"
1028 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1029 what you want when a customer cancels service and that you really should be
1030 looking at L<FS::cust_pkg/cancel>?
1031
1032 You can't delete a customer with invoices (see L<FS::cust_bill>),
1033 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1034 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1035 set the "delete_financials" option to a true value.
1036
1037 =cut
1038
1039 sub delete {
1040   my( $self, %opt ) = @_;
1041
1042   local $SIG{HUP} = 'IGNORE';
1043   local $SIG{INT} = 'IGNORE';
1044   local $SIG{QUIT} = 'IGNORE';
1045   local $SIG{TERM} = 'IGNORE';
1046   local $SIG{TSTP} = 'IGNORE';
1047   local $SIG{PIPE} = 'IGNORE';
1048
1049   my $oldAutoCommit = $FS::UID::AutoCommit;
1050   local $FS::UID::AutoCommit = 0;
1051   my $dbh = dbh;
1052
1053   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1054      $dbh->rollback if $oldAutoCommit;
1055      return "Can't delete a master agent customer";
1056   }
1057
1058   #use FS::access_user
1059   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1060      $dbh->rollback if $oldAutoCommit;
1061      return "Can't delete a master employee customer";
1062   }
1063
1064   tie my %financial_tables, 'Tie::IxHash',
1065     'cust_bill'      => 'invoices',
1066     'cust_statement' => 'statements',
1067     'cust_credit'    => 'credits',
1068     'cust_pay'       => 'payments',
1069     'cust_refund'    => 'refunds',
1070   ;
1071
1072   foreach my $table ( keys %financial_tables ) {
1073
1074     my @records = $self->$table();
1075
1076     if ( @records && ! $opt{'delete_financials'} ) {
1077       $dbh->rollback if $oldAutoCommit;
1078       return "Can't delete a customer with ". $financial_tables{$table};
1079     }
1080
1081     foreach my $record ( @records ) {
1082       my $error = $record->delete;
1083       if ( $error ) {
1084         $dbh->rollback if $oldAutoCommit;
1085         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1086       }
1087     }
1088
1089   }
1090
1091   my @cust_pkg = $self->ncancelled_pkgs;
1092   if ( @cust_pkg ) {
1093     my $new_custnum = $opt{'new_custnum'};
1094     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1095       $dbh->rollback if $oldAutoCommit;
1096       return "Invalid new customer number: $new_custnum";
1097     }
1098     foreach my $cust_pkg ( @cust_pkg ) {
1099       my %hash = $cust_pkg->hash;
1100       $hash{'custnum'} = $new_custnum;
1101       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1102       my $error = $new_cust_pkg->replace($cust_pkg,
1103                                          options => { $cust_pkg->options },
1104                                         );
1105       if ( $error ) {
1106         $dbh->rollback if $oldAutoCommit;
1107         return $error;
1108       }
1109     }
1110   }
1111   my @cancelled_cust_pkg = $self->all_pkgs;
1112   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1113     my $error = $cust_pkg->delete;
1114     if ( $error ) {
1115       $dbh->rollback if $oldAutoCommit;
1116       return $error;
1117     }
1118   }
1119
1120   #cust_tax_adjustment in financials?
1121   #cust_pay_pending?  ouch
1122   #cust_recon?
1123   foreach my $table (qw(
1124     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1125     cust_location cust_main_note cust_tax_adjustment
1126     cust_pay_void cust_pay_batch queue cust_tax_exempt
1127   )) {
1128     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1129       my $error = $record->delete;
1130       if ( $error ) {
1131         $dbh->rollback if $oldAutoCommit;
1132         return $error;
1133       }
1134     }
1135   }
1136
1137   my $sth = $dbh->prepare(
1138     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1139   ) or do {
1140     my $errstr = $dbh->errstr;
1141     $dbh->rollback if $oldAutoCommit;
1142     return $errstr;
1143   };
1144   $sth->execute($self->custnum) or do {
1145     my $errstr = $sth->errstr;
1146     $dbh->rollback if $oldAutoCommit;
1147     return $errstr;
1148   };
1149
1150   #tickets
1151
1152   my $ticket_dbh = '';
1153   if ($conf->config('ticket_system') eq 'RT_Internal') {
1154     $ticket_dbh = $dbh;
1155   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1156     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1157     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1158       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1159   }
1160
1161   if ( $ticket_dbh ) {
1162
1163     my $ticket_sth = $ticket_dbh->prepare(
1164       'DELETE FROM Links WHERE Target = ?'
1165     ) or do {
1166       my $errstr = $ticket_dbh->errstr;
1167       $dbh->rollback if $oldAutoCommit;
1168       return $errstr;
1169     };
1170     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1171       or do {
1172         my $errstr = $ticket_sth->errstr;
1173         $dbh->rollback if $oldAutoCommit;
1174         return $errstr;
1175       };
1176
1177     #check and see if the customer is the only link on the ticket, and
1178     #if so, set the ticket to deleted status in RT?
1179     #maybe someday, for now this will at least fix tickets not displaying
1180
1181   }
1182
1183   #delete the customer record
1184
1185   my $error = $self->SUPER::delete;
1186   if ( $error ) {
1187     $dbh->rollback if $oldAutoCommit;
1188     return $error;
1189   }
1190
1191   # cust_main exports!
1192
1193   #my $export_args = $options{'export_args'} || [];
1194
1195   my @part_export =
1196     map qsearch( 'part_export', {exportnum=>$_} ),
1197       $conf->config('cust_main-exports'); #, $agentnum
1198
1199   foreach my $part_export ( @part_export ) {
1200     my $error = $part_export->export_delete( $self ); #, @$export_args);
1201     if ( $error ) {
1202       $dbh->rollback if $oldAutoCommit;
1203       return "exporting to ". $part_export->exporttype.
1204              " (transaction rolled back): $error";
1205     }
1206   }
1207
1208   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1209   '';
1210
1211 }
1212
1213 =item merge NEW_CUSTNUM [ , OPTION => VALUE ... ]
1214
1215 This merges this customer into the provided new custnum, and then deletes the
1216 customer.  If there is an error, returns the error, otherwise returns false.
1217
1218 The source customer's name, company name, phone numbers, agent,
1219 referring customer, customer class, advertising source, order taker, and
1220 billing information (except balance) are discarded.
1221
1222 All packages are moved to the target customer.  Packages with package locations
1223 are preserved.  Packages without package locations are moved to a new package
1224 location with the source customer's service/shipping address.
1225
1226 All invoices, statements, payments, credits and refunds are moved to the target
1227 customer.  The source customer's balance is added to the target customer.
1228
1229 All notes, attachments, tickets and customer tags are moved to the target
1230 customer.
1231
1232 Change history is not currently moved.
1233
1234 =cut
1235
1236 sub merge {
1237   my( $self, $new_custnum, %opt ) = @_;
1238
1239   return "Can't merge a customer into self" if $self->custnum == $new_custnum;
1240
1241   my $new_cust_main = qsearchs( 'cust_main', { 'custnum' => $new_custnum } )
1242     or return "Invalid new customer number: $new_custnum";
1243
1244   return 'Access denied: "Merge customer across agents" access right required to merge into a customer of a different agent'
1245     if $self->agentnum != $new_cust_main->agentnum
1246     && ! $FS::CurrentUser::CurrentUser->access_right('Merge customer across agents');
1247
1248   local $SIG{HUP} = 'IGNORE';
1249   local $SIG{INT} = 'IGNORE';
1250   local $SIG{QUIT} = 'IGNORE';
1251   local $SIG{TERM} = 'IGNORE';
1252   local $SIG{TSTP} = 'IGNORE';
1253   local $SIG{PIPE} = 'IGNORE';
1254
1255   my $oldAutoCommit = $FS::UID::AutoCommit;
1256   local $FS::UID::AutoCommit = 0;
1257   my $dbh = dbh;
1258
1259   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1260      $dbh->rollback if $oldAutoCommit;
1261      return "Can't merge a master agent customer";
1262   }
1263
1264   #use FS::access_user
1265   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1266      $dbh->rollback if $oldAutoCommit;
1267      return "Can't merge a master employee customer";
1268   }
1269
1270   if ( qsearch('cust_pay_pending', { 'custnum' => $self->custnum,
1271                                      'status'  => { op=>'!=', value=>'done' },
1272                                    }
1273               )
1274   ) {
1275      $dbh->rollback if $oldAutoCommit;
1276      return "Can't merge a customer with pending payments";
1277   }
1278
1279   tie my %financial_tables, 'Tie::IxHash',
1280     'cust_bill'      => 'invoices',
1281     'cust_bill_void' => 'voided invoices',
1282     'cust_statement' => 'statements',
1283     'cust_credit'    => 'credits',
1284     'cust_pay'       => 'payments',
1285     'cust_pay_void'  => 'voided payments',
1286     'cust_refund'    => 'refunds',
1287   ;
1288
1289   foreach my $table ( keys %financial_tables ) {
1290
1291     my @records = $self->$table();
1292
1293     foreach my $record ( @records ) {
1294       $record->custnum($new_custnum);
1295       my $error = $record->replace;
1296       if ( $error ) {
1297         $dbh->rollback if $oldAutoCommit;
1298         return "Error merging ". $financial_tables{$table}. ": $error\n";
1299       }
1300     }
1301
1302   }
1303
1304   my $name = $self->ship_name; #?
1305
1306   my $locationnum = '';
1307   foreach my $cust_pkg ( $self->all_pkgs ) {
1308     $cust_pkg->custnum($new_custnum);
1309
1310     unless ( $cust_pkg->locationnum ) {
1311       unless ( $locationnum ) {
1312         my $cust_location = new FS::cust_location {
1313           $self->location_hash,
1314           'custnum' => $new_custnum,
1315         };
1316         my $error = $cust_location->insert;
1317         if ( $error ) {
1318           $dbh->rollback if $oldAutoCommit;
1319           return $error;
1320         }
1321         $locationnum = $cust_location->locationnum;
1322       }
1323       $cust_pkg->locationnum($locationnum);
1324     }
1325
1326     my $error = $cust_pkg->replace;
1327     if ( $error ) {
1328       $dbh->rollback if $oldAutoCommit;
1329       return $error;
1330     }
1331
1332     # add customer (ship) name to svc_phone.phone_name if blank
1333     my @cust_svc = $cust_pkg->cust_svc;
1334     foreach my $cust_svc (@cust_svc) {
1335       my($label, $value, $svcdb) = $cust_svc->label;
1336       next unless $svcdb eq 'svc_phone';
1337       my $svc_phone = $cust_svc->svc_x;
1338       next if $svc_phone->phone_name;
1339       $svc_phone->phone_name($name);
1340       my $error = $svc_phone->replace;
1341       if ( $error ) {
1342         $dbh->rollback if $oldAutoCommit;
1343         return $error;
1344       }
1345     }
1346
1347   }
1348
1349   #not considered:
1350   # cust_tax_exempt (texas tax exemptions)
1351   # cust_recon (some sort of not-well understood thing for OnPac)
1352
1353   #these are moved over
1354   foreach my $table (qw(
1355     cust_tag cust_location contact cust_attachment cust_main_note
1356     cust_tax_adjustment cust_pay_batch queue
1357   )) {
1358     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1359       $record->custnum($new_custnum);
1360       my $error = $record->replace;
1361       if ( $error ) {
1362         $dbh->rollback if $oldAutoCommit;
1363         return $error;
1364       }
1365     }
1366   }
1367
1368   #these aren't preserved
1369   foreach my $table (qw(
1370     cust_main_exemption cust_main_invoice
1371   )) {
1372     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1373       my $error = $record->delete;
1374       if ( $error ) {
1375         $dbh->rollback if $oldAutoCommit;
1376         return $error;
1377       }
1378     }
1379   }
1380
1381
1382   my $sth = $dbh->prepare(
1383     'UPDATE cust_main SET referral_custnum = ? WHERE referral_custnum = ?'
1384   ) or do {
1385     my $errstr = $dbh->errstr;
1386     $dbh->rollback if $oldAutoCommit;
1387     return $errstr;
1388   };
1389   $sth->execute($new_custnum, $self->custnum) or do {
1390     my $errstr = $sth->errstr;
1391     $dbh->rollback if $oldAutoCommit;
1392     return $errstr;
1393   };
1394
1395   #tickets
1396
1397   my $ticket_dbh = '';
1398   if ($conf->config('ticket_system') eq 'RT_Internal') {
1399     $ticket_dbh = $dbh;
1400   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1401     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1402     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1403       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1404   }
1405
1406   if ( $ticket_dbh ) {
1407
1408     my $ticket_sth = $ticket_dbh->prepare(
1409       'UPDATE Links SET Target = ? WHERE Target = ?'
1410     ) or do {
1411       my $errstr = $ticket_dbh->errstr;
1412       $dbh->rollback if $oldAutoCommit;
1413       return $errstr;
1414     };
1415     $ticket_sth->execute('freeside://freeside/cust_main/'.$new_custnum,
1416                          'freeside://freeside/cust_main/'.$self->custnum)
1417       or do {
1418         my $errstr = $ticket_sth->errstr;
1419         $dbh->rollback if $oldAutoCommit;
1420         return $errstr;
1421       };
1422
1423   }
1424
1425   #delete the customer record
1426
1427   my $error = $self->delete;
1428   if ( $error ) {
1429     $dbh->rollback if $oldAutoCommit;
1430     return $error;
1431   }
1432
1433   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1434   '';
1435
1436 }
1437
1438 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1439
1440 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1441 returns the error, otherwise returns false.
1442
1443 To change the customer's address, set the pseudo-fields C<bill_location> and
1444 C<ship_location>.  The address will still only change if at least one of the
1445 address fields differs from the existing values.
1446
1447 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
1448 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
1449 expected and rollback the entire transaction; it is not necessary to call
1450 check_invoicing_list first.  Here's an example:
1451
1452   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
1453
1454 Currently available options are: I<tax_exemption>.
1455
1456 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1457 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1458 deleted and inserted as appropriate.
1459
1460 =cut
1461
1462 sub replace {
1463   my $self = shift;
1464
1465   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1466               ? shift
1467               : $self->replace_old;
1468
1469   my @param = @_;
1470
1471   warn "$me replace called\n"
1472     if $DEBUG;
1473
1474   my $curuser = $FS::CurrentUser::CurrentUser;
1475   if (    $self->payby eq 'COMP'
1476        && $self->payby ne $old->payby
1477        && ! $curuser->access_right('Complimentary customer')
1478      )
1479   {
1480     return "You are not permitted to create complimentary accounts.";
1481   }
1482
1483   local($ignore_expired_card) = 1
1484     if $old->payby  =~ /^(CARD|DCRD)$/
1485     && $self->payby =~ /^(CARD|DCRD)$/
1486     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1487
1488   local($ignore_banned_card) = 1
1489     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1490          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1491     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1492
1493   return "Invoicing locale is required"
1494     if $old->locale
1495     && ! $self->locale
1496     && $conf->exists('cust_main-require_locale');
1497
1498   local $SIG{HUP} = 'IGNORE';
1499   local $SIG{INT} = 'IGNORE';
1500   local $SIG{QUIT} = 'IGNORE';
1501   local $SIG{TERM} = 'IGNORE';
1502   local $SIG{TSTP} = 'IGNORE';
1503   local $SIG{PIPE} = 'IGNORE';
1504
1505   my $oldAutoCommit = $FS::UID::AutoCommit;
1506   local $FS::UID::AutoCommit = 0;
1507   my $dbh = dbh;
1508
1509   for my $l (qw(bill_location ship_location)) {
1510     my $old_loc = $old->$l;
1511     my $new_loc = $self->$l;
1512
1513     # find the existing location if there is one
1514     $new_loc->set('custnum' => $self->custnum);
1515     my $error = $new_loc->find_or_insert;
1516     if ( $error ) {
1517       $dbh->rollback if $oldAutoCommit;
1518       return $error;
1519     }
1520     $self->set($l.'num', $new_loc->locationnum);
1521   } #for $l
1522
1523   # replace the customer record
1524   my $error = $self->SUPER::replace($old);
1525
1526   if ( $error ) {
1527     $dbh->rollback if $oldAutoCommit;
1528     return $error;
1529   }
1530
1531   # now move packages to the new service location
1532   $self->set('ship_location', ''); #flush cache
1533   if ( $old->ship_locationnum and # should only be null during upgrade...
1534        $old->ship_locationnum != $self->ship_locationnum ) {
1535     $error = $old->ship_location->move_to($self->ship_location);
1536     if ( $error ) {
1537       $dbh->rollback if $oldAutoCommit;
1538       return $error;
1539     }
1540   }
1541   # don't move packages based on the billing location, but
1542   # disable it if it's no longer in use
1543   if ( $old->bill_locationnum and
1544        $old->bill_locationnum != $self->bill_locationnum ) {
1545     $error = $old->bill_location->disable_if_unused;
1546     if ( $error ) {
1547       $dbh->rollback if $oldAutoCommit;
1548       return $error;
1549     }
1550   }
1551
1552   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1553     my $invoicing_list = shift @param;
1554     $error = $self->check_invoicing_list( $invoicing_list );
1555     if ( $error ) {
1556       $dbh->rollback if $oldAutoCommit;
1557       return $error;
1558     }
1559     $self->invoicing_list( $invoicing_list );
1560   }
1561
1562   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1563
1564     #this could be more efficient than deleting and re-inserting, if it matters
1565     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1566       my $error = $cust_tag->delete;
1567       if ( $error ) {
1568         $dbh->rollback if $oldAutoCommit;
1569         return $error;
1570       }
1571     }
1572     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1573       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1574                                         'custnum' => $self->custnum };
1575       my $error = $cust_tag->insert;
1576       if ( $error ) {
1577         $dbh->rollback if $oldAutoCommit;
1578         return $error;
1579       }
1580     }
1581
1582   }
1583
1584   my %options = @param;
1585
1586   my $tax_exemption = delete $options{'tax_exemption'};
1587   if ( $tax_exemption ) {
1588
1589     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1590       if ref($tax_exemption) eq 'ARRAY';
1591
1592     my %cust_main_exemption =
1593       map { $_->taxname => $_ }
1594           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1595
1596     foreach my $taxname ( keys %$tax_exemption ) {
1597
1598       if ( $cust_main_exemption{$taxname} &&
1599            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1600          )
1601       {
1602         delete $cust_main_exemption{$taxname};
1603         next;
1604       }
1605
1606       my $cust_main_exemption = new FS::cust_main_exemption {
1607         'custnum'       => $self->custnum,
1608         'taxname'       => $taxname,
1609         'exempt_number' => $tax_exemption->{$taxname},
1610       };
1611       my $error = $cust_main_exemption->insert;
1612       if ( $error ) {
1613         $dbh->rollback if $oldAutoCommit;
1614         return "inserting cust_main_exemption (transaction rolled back): $error";
1615       }
1616     }
1617
1618     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1619       my $error = $cust_main_exemption->delete;
1620       if ( $error ) {
1621         $dbh->rollback if $oldAutoCommit;
1622         return "deleting cust_main_exemption (transaction rolled back): $error";
1623       }
1624     }
1625
1626   }
1627
1628   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/
1629        && ( ( $self->get('payinfo') ne $old->get('payinfo')
1630               && $self->get('payinfo') !~ /^99\d{14}$/
1631             )
1632             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
1633           )
1634      )
1635   {
1636
1637     # card/check/lec info has changed, want to retry realtime_ invoice events
1638     my $error = $self->retry_realtime;
1639     if ( $error ) {
1640       $dbh->rollback if $oldAutoCommit;
1641       return $error;
1642     }
1643   }
1644
1645   unless ( $import || $skip_fuzzyfiles ) {
1646     $error = $self->queue_fuzzyfiles_update;
1647     if ( $error ) {
1648       $dbh->rollback if $oldAutoCommit;
1649       return "updating fuzzy search cache: $error";
1650     }
1651   }
1652
1653   # tax district update in cust_location
1654
1655   # cust_main exports!
1656
1657   my $export_args = $options{'export_args'} || [];
1658
1659   my @part_export =
1660     map qsearch( 'part_export', {exportnum=>$_} ),
1661       $conf->config('cust_main-exports'); #, $agentnum
1662
1663   foreach my $part_export ( @part_export ) {
1664     my $error = $part_export->export_replace( $self, $old, @$export_args);
1665     if ( $error ) {
1666       $dbh->rollback if $oldAutoCommit;
1667       return "exporting to ". $part_export->exporttype.
1668              " (transaction rolled back): $error";
1669     }
1670   }
1671
1672   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1673   '';
1674
1675 }
1676
1677 =item queue_fuzzyfiles_update
1678
1679 Used by insert & replace to update the fuzzy search cache
1680
1681 =cut
1682
1683 use FS::cust_main::Search;
1684 sub queue_fuzzyfiles_update {
1685   my $self = shift;
1686
1687   local $SIG{HUP} = 'IGNORE';
1688   local $SIG{INT} = 'IGNORE';
1689   local $SIG{QUIT} = 'IGNORE';
1690   local $SIG{TERM} = 'IGNORE';
1691   local $SIG{TSTP} = 'IGNORE';
1692   local $SIG{PIPE} = 'IGNORE';
1693
1694   my $oldAutoCommit = $FS::UID::AutoCommit;
1695   local $FS::UID::AutoCommit = 0;
1696   my $dbh = dbh;
1697
1698   my @locations = $self->bill_location;
1699   push @locations, $self->ship_location if $self->has_ship_address;
1700   foreach my $location (@locations) {
1701     my $queue = new FS::queue {
1702       'job' => 'FS::cust_main::Search::append_fuzzyfiles'
1703     };
1704     my @args = map $location->get($_), @FS::cust_main::Search::fuzzyfields;
1705     my $error = $queue->insert( @args );
1706     if ( $error ) {
1707       $dbh->rollback if $oldAutoCommit;
1708       return "queueing job (transaction rolled back): $error";
1709     }
1710   }
1711
1712   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1713   '';
1714
1715 }
1716
1717 =item check
1718
1719 Checks all fields to make sure this is a valid customer record.  If there is
1720 an error, returns the error, otherwise returns false.  Called by the insert
1721 and replace methods.
1722
1723 =cut
1724
1725 sub check {
1726   my $self = shift;
1727
1728   warn "$me check BEFORE: \n". $self->_dump
1729     if $DEBUG > 2;
1730
1731   my $error =
1732     $self->ut_numbern('custnum')
1733     || $self->ut_number('agentnum')
1734     || $self->ut_textn('agent_custid')
1735     || $self->ut_number('refnum')
1736     || $self->ut_foreign_key('bill_locationnum', 'cust_location','locationnum')
1737     || $self->ut_foreign_key('ship_locationnum', 'cust_location','locationnum')
1738     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1739     || $self->ut_textn('custbatch')
1740     || $self->ut_name('last')
1741     || $self->ut_name('first')
1742     || $self->ut_snumbern('signupdate')
1743     || $self->ut_snumbern('birthdate')
1744     || $self->ut_snumbern('spouse_birthdate')
1745     || $self->ut_snumbern('anniversary_date')
1746     || $self->ut_textn('company')
1747     || $self->ut_anything('comments')
1748     || $self->ut_numbern('referral_custnum')
1749     || $self->ut_textn('stateid')
1750     || $self->ut_textn('stateid_state')
1751     || $self->ut_textn('invoice_terms')
1752     || $self->ut_floatn('cdr_termination_percentage')
1753     || $self->ut_floatn('credit_limit')
1754     || $self->ut_numbern('billday')
1755     || $self->ut_numbern('prorate_day')
1756     || $self->ut_flag('edit_subject')
1757     || $self->ut_flag('calling_list_exempt')
1758     || $self->ut_flag('invoice_noemail')
1759     || $self->ut_flag('message_noemail')
1760     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1761     || $self->ut_currencyn('currency')
1762   ;
1763
1764   my $company = $self->company;
1765   $company =~ s/^\s+//;
1766   $company =~ s/\s+$//;
1767   $company =~ s/\s+/ /g;
1768   $self->company($company);
1769
1770   #barf.  need message catalogs.  i18n.  etc.
1771   $error .= "Please select an advertising source."
1772     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1773   return $error if $error;
1774
1775   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1776     or return "Unknown agent";
1777
1778   if ( $self->currency ) {
1779     my $agent_currency = qsearchs( 'agent_currency', {
1780       'agentnum' => $agent->agentnum,
1781       'currency' => $self->currency,
1782     })
1783       or return "Agent ". $agent->agent.
1784                 " not permitted to offer ".  $self->currency. " invoicing";
1785   }
1786
1787   return "Unknown refnum"
1788     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1789
1790   return "Unknown referring custnum: ". $self->referral_custnum
1791     unless ! $self->referral_custnum
1792            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1793
1794   if ( $self->ss eq '' ) {
1795     $self->ss('');
1796   } else {
1797     my $ss = $self->ss;
1798     $ss =~ s/\D//g;
1799     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1800       or return "Illegal social security number: ". $self->ss;
1801     $self->ss("$1-$2-$3");
1802   }
1803
1804   # cust_main_county verification now handled by cust_location check
1805
1806   $error =
1807        $self->ut_phonen('daytime', $self->country)
1808     || $self->ut_phonen('night',   $self->country)
1809     || $self->ut_phonen('fax',     $self->country)
1810     || $self->ut_phonen('mobile',  $self->country)
1811   ;
1812   return $error if $error;
1813
1814   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1815        && ! $import
1816        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1817      ) {
1818
1819     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1820                           ? 'Day Phone'
1821                           : FS::Msgcat::_gettext('daytime');
1822     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1823                         ? 'Night Phone'
1824                         : FS::Msgcat::_gettext('night');
1825
1826     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1827                         ? 'Mobile Phone'
1828                         : FS::Msgcat::_gettext('mobile');
1829
1830     return "$daytime_label, $night_label or $mobile_label is required"
1831
1832   }
1833
1834   #$self->payby =~ /^(CARD|DCRD|CHEK|DCHK|LECB|BILL|COMP|PREPAY|CASH|WEST|MCRD)$/
1835   #  or return "Illegal payby: ". $self->payby;
1836   #$self->payby($1);
1837   FS::payby->can_payby($self->table, $self->payby)
1838     or return "Illegal payby: ". $self->payby;
1839
1840   $error =    $self->ut_numbern('paystart_month')
1841            || $self->ut_numbern('paystart_year')
1842            || $self->ut_numbern('payissue')
1843            || $self->ut_textn('paytype')
1844   ;
1845   return $error if $error;
1846
1847   if ( $self->payip eq '' ) {
1848     $self->payip('');
1849   } else {
1850     $error = $self->ut_ip('payip');
1851     return $error if $error;
1852   }
1853
1854   # If it is encrypted and the private key is not availaible then we can't
1855   # check the credit card.
1856   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1857
1858   # Need some kind of global flag to accept invalid cards, for testing
1859   # on scrubbed data.
1860   if ( !$import && $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
1861
1862     my $payinfo = $self->payinfo;
1863     $payinfo =~ s/\D//g;
1864     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1865       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1866     $payinfo = $1;
1867     $self->payinfo($payinfo);
1868     validate($payinfo)
1869       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1870
1871     return gettext('unknown_card_type')
1872       if $self->payinfo !~ /^99\d{14}$/ #token
1873       && cardtype($self->payinfo) eq "Unknown";
1874
1875     unless ( $ignore_banned_card ) {
1876       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1877       if ( $ban ) {
1878         if ( $ban->bantype eq 'warn' ) {
1879           #or others depending on value of $ban->reason ?
1880           return '_duplicate_card'.
1881                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1882                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1883                  ' (ban# '. $ban->bannum. ')'
1884             unless $self->override_ban_warn;
1885         } else {
1886           return 'Banned credit card: banned on '.
1887                  time2str('%a %h %o at %r', $ban->_date).
1888                  ' by '. $ban->otaker.
1889                  ' (ban# '. $ban->bannum. ')';
1890         }
1891       }
1892     }
1893
1894     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1895       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1896         $self->paycvv =~ /^(\d{4})$/
1897           or return "CVV2 (CID) for American Express cards is four digits.";
1898         $self->paycvv($1);
1899       } else {
1900         $self->paycvv =~ /^(\d{3})$/
1901           or return "CVV2 (CVC2/CID) is three digits.";
1902         $self->paycvv($1);
1903       }
1904     } else {
1905       $self->paycvv('');
1906     }
1907
1908     my $cardtype = cardtype($payinfo);
1909     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1910
1911       return "Start date or issue number is required for $cardtype cards"
1912         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1913
1914       return "Start month must be between 1 and 12"
1915         if $self->paystart_month
1916            and $self->paystart_month < 1 || $self->paystart_month > 12;
1917
1918       return "Start year must be 1990 or later"
1919         if $self->paystart_year
1920            and $self->paystart_year < 1990;
1921
1922       return "Issue number must be beween 1 and 99"
1923         if $self->payissue
1924           and $self->payissue < 1 || $self->payissue > 99;
1925
1926     } else {
1927       $self->paystart_month('');
1928       $self->paystart_year('');
1929       $self->payissue('');
1930     }
1931
1932   } elsif ( $check_payinfo && $self->payby =~ /^(CHEK|DCHK)$/ ) {
1933
1934     my $payinfo = $self->payinfo;
1935     $payinfo =~ s/[^\d\@\.]//g;
1936     if ( $conf->config('echeck-country') eq 'CA' ) {
1937       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1938         or return 'invalid echeck account@branch.bank';
1939       $payinfo = "$1\@$2.$3";
1940     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1941       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1942       $payinfo = "$1\@$2";
1943     } else {
1944       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1945       $payinfo = "$1\@$2";
1946     }
1947     $self->payinfo($payinfo);
1948     $self->paycvv('');
1949
1950     unless ( $ignore_banned_card ) {
1951       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1952       if ( $ban ) {
1953         if ( $ban->bantype eq 'warn' ) {
1954           #or others depending on value of $ban->reason ?
1955           return '_duplicate_ach' unless $self->override_ban_warn;
1956         } else {
1957           return 'Banned ACH account: banned on '.
1958                  time2str('%a %h %o at %r', $ban->_date).
1959                  ' by '. $ban->otaker.
1960                  ' (ban# '. $ban->bannum. ')';
1961         }
1962       }
1963     }
1964
1965   } elsif ( $self->payby eq 'LECB' ) {
1966
1967     my $payinfo = $self->payinfo;
1968     $payinfo =~ s/\D//g;
1969     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
1970     $payinfo = $1;
1971     $self->payinfo($payinfo);
1972     $self->paycvv('');
1973
1974   } elsif ( $self->payby eq 'BILL' ) {
1975
1976     $error = $self->ut_textn('payinfo');
1977     return "Illegal P.O. number: ". $self->payinfo if $error;
1978     $self->paycvv('');
1979
1980   } elsif ( $self->payby eq 'COMP' ) {
1981
1982     my $curuser = $FS::CurrentUser::CurrentUser;
1983     if (    ! $self->custnum
1984          && ! $curuser->access_right('Complimentary customer')
1985        )
1986     {
1987       return "You are not permitted to create complimentary accounts."
1988     }
1989
1990     $error = $self->ut_textn('payinfo');
1991     return "Illegal comp account issuer: ". $self->payinfo if $error;
1992     $self->paycvv('');
1993
1994   } elsif ( $self->payby eq 'PREPAY' ) {
1995
1996     my $payinfo = $self->payinfo;
1997     $payinfo =~ s/\W//g; #anything else would just confuse things
1998     $self->payinfo($payinfo);
1999     $error = $self->ut_alpha('payinfo');
2000     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2001     return "Unknown prepayment identifier"
2002       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2003     $self->paycvv('');
2004
2005   }
2006
2007   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2008     return "Expiration date required"
2009       # shouldn't payinfo_check do this?
2010       unless $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD|PPAL)$/;
2011     $self->paydate('');
2012   } else {
2013     my( $m, $y );
2014     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2015       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2016     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2017       ( $m, $y ) = ( $2, "19$1" );
2018     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2019       ( $m, $y ) = ( $3, "20$2" );
2020     } else {
2021       return "Illegal expiration date: ". $self->paydate;
2022     }
2023     $m = sprintf('%02d',$m);
2024     $self->paydate("$y-$m-01");
2025     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2026     return gettext('expired_card')
2027       if !$import
2028       && !$ignore_expired_card
2029       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2030   }
2031
2032   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2033        ( ! $conf->exists('require_cardname')
2034          || $self->payby !~ /^(CARD|DCRD)$/  )
2035   ) {
2036     $self->payname( $self->first. " ". $self->getfield('last') );
2037   } else {
2038     $self->payname =~ /^([\w \,\.\-\'\&]+)$/
2039       or return gettext('illegal_name'). " payname: ". $self->payname;
2040     $self->payname($1);
2041   }
2042
2043   return "Please select an invoicing locale"
2044     if ! $self->locale
2045     && ! $self->custnum
2046     && $conf->exists('cust_main-require_locale');
2047
2048   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2049     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2050     $self->$flag($1);
2051   }
2052
2053   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2054
2055   warn "$me check AFTER: \n". $self->_dump
2056     if $DEBUG > 2;
2057
2058   $self->SUPER::check;
2059 }
2060
2061 =item addr_fields
2062
2063 Returns a list of fields which have ship_ duplicates.
2064
2065 =cut
2066
2067 sub addr_fields {
2068   qw( last first company
2069       address1 address2 city county state zip country
2070       latitude longitude
2071       daytime night fax mobile
2072     );
2073 }
2074
2075 =item has_ship_address
2076
2077 Returns true if this customer record has a separate shipping address.
2078
2079 =cut
2080
2081 sub has_ship_address {
2082   my $self = shift;
2083   $self->bill_locationnum != $self->ship_locationnum;
2084 }
2085
2086 =item location_hash
2087
2088 Returns a list of key/value pairs, with the following keys: address1,
2089 adddress2, city, county, state, zip, country, district, and geocode.  The
2090 shipping address is used if present.
2091
2092 =cut
2093
2094 sub location_hash {
2095   my $self = shift;
2096   $self->ship_location->location_hash;
2097 }
2098
2099 =item cust_location
2100
2101 Returns all locations (see L<FS::cust_location>) for this customer.
2102
2103 =cut
2104
2105 sub cust_location {
2106   my $self = shift;
2107   qsearch('cust_location', { 'custnum' => $self->custnum,
2108                              'prospectnum' => '' } );
2109 }
2110
2111 =item cust_contact
2112
2113 Returns all contacts (see L<FS::contact>) for this customer.
2114
2115 =cut
2116
2117 #already used :/ sub contact {
2118 sub cust_contact {
2119   my $self = shift;
2120   qsearch('contact', { 'custnum' => $self->custnum } );
2121 }
2122
2123 =item unsuspend
2124
2125 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2126 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
2127 on success or a list of errors.
2128
2129 =cut
2130
2131 sub unsuspend {
2132   my $self = shift;
2133   grep { $_->unsuspend } $self->suspended_pkgs;
2134 }
2135
2136 =item suspend
2137
2138 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2139
2140 Returns a list: an empty list on success or a list of errors.
2141
2142 =cut
2143
2144 sub suspend {
2145   my $self = shift;
2146   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2147 }
2148
2149 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2150
2151 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2152 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2153 of a list of pkgparts; the hashref has the following keys:
2154
2155 =over 4
2156
2157 =item pkgparts - listref of pkgparts
2158
2159 =item (other options are passed to the suspend method)
2160
2161 =back
2162
2163
2164 Returns a list: an empty list on success or a list of errors.
2165
2166 =cut
2167
2168 sub suspend_if_pkgpart {
2169   my $self = shift;
2170   my (@pkgparts, %opt);
2171   if (ref($_[0]) eq 'HASH'){
2172     @pkgparts = @{$_[0]{pkgparts}};
2173     %opt      = %{$_[0]};
2174   }else{
2175     @pkgparts = @_;
2176   }
2177   grep { $_->suspend(%opt) }
2178     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2179       $self->unsuspended_pkgs;
2180 }
2181
2182 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2183
2184 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2185 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2186 instead of a list of pkgparts; the hashref has the following keys:
2187
2188 =over 4
2189
2190 =item pkgparts - listref of pkgparts
2191
2192 =item (other options are passed to the suspend method)
2193
2194 =back
2195
2196 Returns a list: an empty list on success or a list of errors.
2197
2198 =cut
2199
2200 sub suspend_unless_pkgpart {
2201   my $self = shift;
2202   my (@pkgparts, %opt);
2203   if (ref($_[0]) eq 'HASH'){
2204     @pkgparts = @{$_[0]{pkgparts}};
2205     %opt      = %{$_[0]};
2206   }else{
2207     @pkgparts = @_;
2208   }
2209   grep { $_->suspend(%opt) }
2210     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2211       $self->unsuspended_pkgs;
2212 }
2213
2214 =item cancel [ OPTION => VALUE ... ]
2215
2216 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2217
2218 Available options are:
2219
2220 =over 4
2221
2222 =item quiet - can be set true to supress email cancellation notices.
2223
2224 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2225
2226 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2227
2228 =item nobill - can be set true to skip billing if it might otherwise be done.
2229
2230 =back
2231
2232 Always returns a list: an empty list on success or a list of errors.
2233
2234 =cut
2235
2236 # nb that dates are not specified as valid options to this method
2237
2238 sub cancel {
2239   my( $self, %opt ) = @_;
2240
2241   warn "$me cancel called on customer ". $self->custnum. " with options ".
2242        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2243     if $DEBUG;
2244
2245   return ( 'access denied' )
2246     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2247
2248   if ( $opt{'ban'} && $self->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/ ) {
2249
2250     #should try decryption (we might have the private key)
2251     # and if not maybe queue a job for the server that does?
2252     return ( "Can't (yet) ban encrypted credit cards" )
2253       if $self->is_encrypted($self->payinfo);
2254
2255     my $ban = new FS::banned_pay $self->_new_banned_pay_hashref;
2256     my $error = $ban->insert;
2257     return ( $error ) if $error;
2258
2259   }
2260
2261   my @pkgs = $self->ncancelled_pkgs;
2262
2263   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2264     $opt{nobill} = 1;
2265     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2266     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2267       if $error;
2268   }
2269
2270   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2271        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2272     if $DEBUG;
2273
2274   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2275 }
2276
2277 sub _banned_pay_hashref {
2278   my $self = shift;
2279
2280   my %payby2ban = (
2281     'CARD' => 'CARD',
2282     'DCRD' => 'CARD',
2283     'CHEK' => 'CHEK',
2284     'DCHK' => 'CHEK'
2285   );
2286
2287   {
2288     'payby'   => $payby2ban{$self->payby},
2289     'payinfo' => $self->payinfo,
2290     #don't ever *search* on reason! #'reason'  =>
2291   };
2292 }
2293
2294 sub _new_banned_pay_hashref {
2295   my $self = shift;
2296   my $hr = $self->_banned_pay_hashref;
2297   $hr->{payinfo} = md5_base64($hr->{payinfo});
2298   $hr;
2299 }
2300
2301 =item notes
2302
2303 Returns all notes (see L<FS::cust_main_note>) for this customer.
2304
2305 =cut
2306
2307 sub notes {
2308   my($self,$orderby_classnum) = (shift,shift);
2309   my $orderby = "_DATE DESC";
2310   $orderby = "CLASSNUM ASC, $orderby" if $orderby_classnum;
2311   qsearch( 'cust_main_note',
2312            { 'custnum' => $self->custnum },
2313            '',
2314            "ORDER BY $orderby",
2315          );
2316 }
2317
2318 =item agent
2319
2320 Returns the agent (see L<FS::agent>) for this customer.
2321
2322 =cut
2323
2324 sub agent {
2325   my $self = shift;
2326   qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
2327 }
2328
2329 =item agent_name
2330
2331 Returns the agent name (see L<FS::agent>) for this customer.
2332
2333 =cut
2334
2335 sub agent_name {
2336   my $self = shift;
2337   $self->agent->agent;
2338 }
2339
2340 =item cust_tag
2341
2342 Returns any tags associated with this customer, as FS::cust_tag objects,
2343 or an empty list if there are no tags.
2344
2345 =cut
2346
2347 sub cust_tag {
2348   my $self = shift;
2349   qsearch('cust_tag', { 'custnum' => $self->custnum } );
2350 }
2351
2352 =item part_tag
2353
2354 Returns any tags associated with this customer, as FS::part_tag objects,
2355 or an empty list if there are no tags.
2356
2357 =cut
2358
2359 sub part_tag {
2360   my $self = shift;
2361   map $_->part_tag, $self->cust_tag;
2362 }
2363
2364
2365 =item cust_class
2366
2367 Returns the customer class, as an FS::cust_class object, or the empty string
2368 if there is no customer class.
2369
2370 =cut
2371
2372 sub cust_class {
2373   my $self = shift;
2374   if ( $self->classnum ) {
2375     qsearchs('cust_class', { 'classnum' => $self->classnum } );
2376   } else {
2377     return '';
2378   }
2379 }
2380
2381 =item categoryname
2382
2383 Returns the customer category name, or the empty string if there is no customer
2384 category.
2385
2386 =cut
2387
2388 sub categoryname {
2389   my $self = shift;
2390   my $cust_class = $self->cust_class;
2391   $cust_class
2392     ? $cust_class->categoryname
2393     : '';
2394 }
2395
2396 =item classname
2397
2398 Returns the customer class name, or the empty string if there is no customer
2399 class.
2400
2401 =cut
2402
2403 sub classname {
2404   my $self = shift;
2405   my $cust_class = $self->cust_class;
2406   $cust_class
2407     ? $cust_class->classname
2408     : '';
2409 }
2410
2411 =item BILLING METHODS
2412
2413 Documentation on billing methods has been moved to
2414 L<FS::cust_main::Billing>.
2415
2416 =item REALTIME BILLING METHODS
2417
2418 Documentation on realtime billing methods has been moved to
2419 L<FS::cust_main::Billing_Realtime>.
2420
2421 =item remove_cvv
2422
2423 Removes the I<paycvv> field from the database directly.
2424
2425 If there is an error, returns the error, otherwise returns false.
2426
2427 =cut
2428
2429 sub remove_cvv {
2430   my $self = shift;
2431   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2432     or return dbh->errstr;
2433   $sth->execute($self->custnum)
2434     or return $sth->errstr;
2435   $self->paycvv('');
2436   '';
2437 }
2438
2439 =item batch_card OPTION => VALUE...
2440
2441 Adds a payment for this invoice to the pending credit card batch (see
2442 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
2443 runs the payment using a realtime gateway.
2444
2445 Options may include:
2446
2447 B<amount>: the amount to be paid; defaults to the customer's balance minus
2448 any payments in transit.
2449
2450 B<payby>: the payment method; defaults to cust_main.payby
2451
2452 B<realtime>: runs this as a realtime payment instead of adding it to a
2453 batch.  Deprecated.
2454
2455 B<invnum>: sets cust_pay_batch.invnum.
2456
2457 B<address1>, B<address2>, B<city>, B<state>, B<zip>, B<country>: sets
2458 the billing address for the payment; defaults to the customer's billing
2459 location.
2460
2461 B<payinfo>, B<paydate>, B<payname>: sets the payment account, expiration
2462 date, and name; defaults to those fields in cust_main.
2463
2464 =cut
2465
2466 sub batch_card {
2467   my ($self, %options) = @_;
2468
2469   my $amount;
2470   if (exists($options{amount})) {
2471     $amount = $options{amount};
2472   }else{
2473     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
2474   }
2475   return '' unless $amount > 0;
2476
2477   my $invnum = delete $options{invnum};
2478   my $payby = $options{payby} || $self->payby;  #still dubious
2479
2480   if ($options{'realtime'}) {
2481     return $self->realtime_bop( FS::payby->payby2bop($self->payby),
2482                                 $amount,
2483                                 %options,
2484                               );
2485   }
2486
2487   my $oldAutoCommit = $FS::UID::AutoCommit;
2488   local $FS::UID::AutoCommit = 0;
2489   my $dbh = dbh;
2490
2491   #this needs to handle mysql as well as Pg, like svc_acct.pm
2492   #(make it into a common function if folks need to do batching with mysql)
2493   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
2494     or return "Cannot lock pay_batch: " . $dbh->errstr;
2495
2496   my %pay_batch = (
2497     'status' => 'O',
2498     'payby'  => FS::payby->payby2payment($payby),
2499   );
2500   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
2501
2502   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
2503
2504   unless ( $pay_batch ) {
2505     $pay_batch = new FS::pay_batch \%pay_batch;
2506     my $error = $pay_batch->insert;
2507     if ( $error ) {
2508       $dbh->rollback if $oldAutoCommit;
2509       die "error creating new batch: $error\n";
2510     }
2511   }
2512
2513   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
2514       'batchnum' => $pay_batch->batchnum,
2515       'custnum'  => $self->custnum,
2516   } );
2517
2518   foreach (qw( address1 address2 city state zip country latitude longitude
2519                payby payinfo paydate payname ))
2520   {
2521     $options{$_} = '' unless exists($options{$_});
2522   }
2523
2524   my $loc = $self->bill_location;
2525
2526   my $cust_pay_batch = new FS::cust_pay_batch ( {
2527     'batchnum' => $pay_batch->batchnum,
2528     'invnum'   => $invnum || 0,                    # is there a better value?
2529                                                    # this field should be
2530                                                    # removed...
2531                                                    # cust_bill_pay_batch now
2532     'custnum'  => $self->custnum,
2533     'last'     => $self->getfield('last'),
2534     'first'    => $self->getfield('first'),
2535     'address1' => $options{address1} || $loc->address1,
2536     'address2' => $options{address2} || $loc->address2,
2537     'city'     => $options{city}     || $loc->city,
2538     'state'    => $options{state}    || $loc->state,
2539     'zip'      => $options{zip}      || $loc->zip,
2540     'country'  => $options{country}  || $loc->country,
2541     'payby'    => $options{payby}    || $self->payby,
2542     'payinfo'  => $options{payinfo}  || $self->payinfo,
2543     'exp'      => $options{paydate}  || $self->paydate,
2544     'payname'  => $options{payname}  || $self->payname,
2545     'amount'   => $amount,                         # consolidating
2546   } );
2547
2548   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
2549     if $old_cust_pay_batch;
2550
2551   my $error;
2552   if ($old_cust_pay_batch) {
2553     $error = $cust_pay_batch->replace($old_cust_pay_batch)
2554   } else {
2555     $error = $cust_pay_batch->insert;
2556   }
2557
2558   if ( $error ) {
2559     $dbh->rollback if $oldAutoCommit;
2560     die $error;
2561   }
2562
2563   my $unapplied =   $self->total_unapplied_credits
2564                   + $self->total_unapplied_payments
2565                   + $self->in_transit_payments;
2566   foreach my $cust_bill ($self->open_cust_bill) {
2567     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
2568     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
2569       'invnum' => $cust_bill->invnum,
2570       'paybatchnum' => $cust_pay_batch->paybatchnum,
2571       'amount' => $cust_bill->owed,
2572       '_date' => time,
2573     };
2574     if ($unapplied >= $cust_bill_pay_batch->amount){
2575       $unapplied -= $cust_bill_pay_batch->amount;
2576       next;
2577     }else{
2578       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
2579                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
2580     }
2581     $error = $cust_bill_pay_batch->insert;
2582     if ( $error ) {
2583       $dbh->rollback if $oldAutoCommit;
2584       die $error;
2585     }
2586   }
2587
2588   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2589   '';
2590 }
2591
2592 =item total_owed
2593
2594 Returns the total owed for this customer on all invoices
2595 (see L<FS::cust_bill/owed>).
2596
2597 =cut
2598
2599 sub total_owed {
2600   my $self = shift;
2601   $self->total_owed_date(2145859200); #12/31/2037
2602 }
2603
2604 =item total_owed_date TIME
2605
2606 Returns the total owed for this customer on all invoices with date earlier than
2607 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2608 see L<Time::Local> and L<Date::Parse> for conversion functions.
2609
2610 =cut
2611
2612 sub total_owed_date {
2613   my $self = shift;
2614   my $time = shift;
2615
2616   my $custnum = $self->custnum;
2617
2618   my $owed_sql = FS::cust_bill->owed_sql;
2619
2620   my $sql = "
2621     SELECT SUM($owed_sql) FROM cust_bill
2622       WHERE custnum = $custnum
2623         AND _date <= $time
2624   ";
2625
2626   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2627
2628 }
2629
2630 =item total_owed_pkgnum PKGNUM
2631
2632 Returns the total owed on all invoices for this customer's specific package
2633 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2634
2635 =cut
2636
2637 sub total_owed_pkgnum {
2638   my( $self, $pkgnum ) = @_;
2639   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2640 }
2641
2642 =item total_owed_date_pkgnum TIME PKGNUM
2643
2644 Returns the total owed for this customer's specific package when using
2645 experimental package balances on all invoices with date earlier than
2646 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2647 see L<Time::Local> and L<Date::Parse> for conversion functions.
2648
2649 =cut
2650
2651 sub total_owed_date_pkgnum {
2652   my( $self, $time, $pkgnum ) = @_;
2653
2654   my $total_bill = 0;
2655   foreach my $cust_bill (
2656     grep { $_->_date <= $time }
2657       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2658   ) {
2659     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2660   }
2661   sprintf( "%.2f", $total_bill );
2662
2663 }
2664
2665 =item total_paid
2666
2667 Returns the total amount of all payments.
2668
2669 =cut
2670
2671 sub total_paid {
2672   my $self = shift;
2673   my $total = 0;
2674   $total += $_->paid foreach $self->cust_pay;
2675   sprintf( "%.2f", $total );
2676 }
2677
2678 =item total_unapplied_credits
2679
2680 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2681 customer.  See L<FS::cust_credit/credited>.
2682
2683 =item total_credited
2684
2685 Old name for total_unapplied_credits.  Don't use.
2686
2687 =cut
2688
2689 sub total_credited {
2690   #carp "total_credited deprecated, use total_unapplied_credits";
2691   shift->total_unapplied_credits(@_);
2692 }
2693
2694 sub total_unapplied_credits {
2695   my $self = shift;
2696
2697   my $custnum = $self->custnum;
2698
2699   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2700
2701   my $sql = "
2702     SELECT SUM($unapplied_sql) FROM cust_credit
2703       WHERE custnum = $custnum
2704   ";
2705
2706   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2707
2708 }
2709
2710 =item total_unapplied_credits_pkgnum PKGNUM
2711
2712 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2713 customer.  See L<FS::cust_credit/credited>.
2714
2715 =cut
2716
2717 sub total_unapplied_credits_pkgnum {
2718   my( $self, $pkgnum ) = @_;
2719   my $total_credit = 0;
2720   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2721   sprintf( "%.2f", $total_credit );
2722 }
2723
2724
2725 =item total_unapplied_payments
2726
2727 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2728 See L<FS::cust_pay/unapplied>.
2729
2730 =cut
2731
2732 sub total_unapplied_payments {
2733   my $self = shift;
2734
2735   my $custnum = $self->custnum;
2736
2737   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2738
2739   my $sql = "
2740     SELECT SUM($unapplied_sql) FROM cust_pay
2741       WHERE custnum = $custnum
2742   ";
2743
2744   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2745
2746 }
2747
2748 =item total_unapplied_payments_pkgnum PKGNUM
2749
2750 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2751 specific package when using experimental package balances.  See
2752 L<FS::cust_pay/unapplied>.
2753
2754 =cut
2755
2756 sub total_unapplied_payments_pkgnum {
2757   my( $self, $pkgnum ) = @_;
2758   my $total_unapplied = 0;
2759   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2760   sprintf( "%.2f", $total_unapplied );
2761 }
2762
2763
2764 =item total_unapplied_refunds
2765
2766 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2767 customer.  See L<FS::cust_refund/unapplied>.
2768
2769 =cut
2770
2771 sub total_unapplied_refunds {
2772   my $self = shift;
2773   my $custnum = $self->custnum;
2774
2775   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2776
2777   my $sql = "
2778     SELECT SUM($unapplied_sql) FROM cust_refund
2779       WHERE custnum = $custnum
2780   ";
2781
2782   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2783
2784 }
2785
2786 =item balance
2787
2788 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2789 total_unapplied_credits minus total_unapplied_payments).
2790
2791 =cut
2792
2793 sub balance {
2794   my $self = shift;
2795   $self->balance_date_range;
2796 }
2797
2798 =item balance_date TIME
2799
2800 Returns the balance for this customer, only considering invoices with date
2801 earlier than TIME (total_owed_date minus total_credited minus
2802 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2803 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2804 functions.
2805
2806 =cut
2807
2808 sub balance_date {
2809   my $self = shift;
2810   $self->balance_date_range(shift);
2811 }
2812
2813 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2814
2815 Returns the balance for this customer, optionally considering invoices with
2816 date earlier than START_TIME, and not later than END_TIME
2817 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2818
2819 Times are specified as SQL fragments or numeric
2820 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2821 L<Date::Parse> for conversion functions.  The empty string can be passed
2822 to disable that time constraint completely.
2823
2824 Available options are:
2825
2826 =over 4
2827
2828 =item unapplied_date
2829
2830 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2831
2832 =back
2833
2834 =cut
2835
2836 sub balance_date_range {
2837   my $self = shift;
2838   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2839             ') FROM cust_main WHERE custnum='. $self->custnum;
2840   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2841 }
2842
2843 =item balance_pkgnum PKGNUM
2844
2845 Returns the balance for this customer's specific package when using
2846 experimental package balances (total_owed plus total_unrefunded, minus
2847 total_unapplied_credits minus total_unapplied_payments)
2848
2849 =cut
2850
2851 sub balance_pkgnum {
2852   my( $self, $pkgnum ) = @_;
2853
2854   sprintf( "%.2f",
2855       $self->total_owed_pkgnum($pkgnum)
2856 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2857 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2858     - $self->total_unapplied_credits_pkgnum($pkgnum)
2859     - $self->total_unapplied_payments_pkgnum($pkgnum)
2860   );
2861 }
2862
2863 =item in_transit_payments
2864
2865 Returns the total of requests for payments for this customer pending in
2866 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
2867
2868 =cut
2869
2870 sub in_transit_payments {
2871   my $self = shift;
2872   my $in_transit_payments = 0;
2873   foreach my $pay_batch ( qsearch('pay_batch', {
2874     'status' => 'I',
2875   } ) ) {
2876     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
2877       'batchnum' => $pay_batch->batchnum,
2878       'custnum' => $self->custnum,
2879     } ) ) {
2880       $in_transit_payments += $cust_pay_batch->amount;
2881     }
2882   }
2883   sprintf( "%.2f", $in_transit_payments );
2884 }
2885
2886 =item payment_info
2887
2888 Returns a hash of useful information for making a payment.
2889
2890 =over 4
2891
2892 =item balance
2893
2894 Current balance.
2895
2896 =item payby
2897
2898 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2899 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2900 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2901
2902 =back
2903
2904 For credit card transactions:
2905
2906 =over 4
2907
2908 =item card_type 1
2909
2910 =item payname
2911
2912 Exact name on card
2913
2914 =back
2915
2916 For electronic check transactions:
2917
2918 =over 4
2919
2920 =item stateid_state
2921
2922 =back
2923
2924 =cut
2925
2926 sub payment_info {
2927   my $self = shift;
2928
2929   my %return = ();
2930
2931   $return{balance} = $self->balance;
2932
2933   $return{payname} = $self->payname
2934                      || ( $self->first. ' '. $self->get('last') );
2935
2936   $return{$_} = $self->bill_location->$_
2937     for qw(address1 address2 city state zip);
2938
2939   $return{payby} = $self->payby;
2940   $return{stateid_state} = $self->stateid_state;
2941
2942   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2943     $return{card_type} = cardtype($self->payinfo);
2944     $return{payinfo} = $self->paymask;
2945
2946     @return{'month', 'year'} = $self->paydate_monthyear;
2947
2948   }
2949
2950   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2951     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2952     $return{payinfo1} = $payinfo1;
2953     $return{payinfo2} = $payinfo2;
2954     $return{paytype}  = $self->paytype;
2955     $return{paystate} = $self->paystate;
2956
2957   }
2958
2959   #doubleclick protection
2960   my $_date = time;
2961   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2962
2963   %return;
2964
2965 }
2966
2967 =item paydate_monthyear
2968
2969 Returns a two-element list consisting of the month and year of this customer's
2970 paydate (credit card expiration date for CARD customers)
2971
2972 =cut
2973
2974 sub paydate_monthyear {
2975   my $self = shift;
2976   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
2977     ( $2, $1 );
2978   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
2979     ( $1, $3 );
2980   } else {
2981     ('', '');
2982   }
2983 }
2984
2985 =item paydate_epoch
2986
2987 Returns the exact time in seconds corresponding to the payment method
2988 expiration date.  For CARD/DCRD customers this is the end of the month;
2989 for others (COMP is the only other payby that uses paydate) it's the start.
2990 Returns 0 if the paydate is empty or set to the far future.
2991
2992 =cut
2993
2994 sub paydate_epoch {
2995   my $self = shift;
2996   my ($month, $year) = $self->paydate_monthyear;
2997   return 0 if !$year or $year >= 2037;
2998   if ( $self->payby eq 'CARD' or $self->payby eq 'DCRD' ) {
2999     $month++;
3000     if ( $month == 13 ) {
3001       $month = 1;
3002       $year++;
3003     }
3004     return timelocal(0,0,0,1,$month-1,$year) - 1;
3005   }
3006   else {
3007     return timelocal(0,0,0,1,$month-1,$year);
3008   }
3009 }
3010
3011 =item paydate_epoch_sql
3012
3013 Class method.  Returns an SQL expression to obtain the payment expiration date
3014 as a number of seconds.
3015
3016 =cut
3017
3018 # Special expiration date behavior for non-CARD/DCRD customers has been
3019 # carefully preserved.  Do we really use that?
3020 sub paydate_epoch_sql {
3021   my $class = shift;
3022   my $table = shift || 'cust_main';
3023   my ($case1, $case2);
3024   if ( driver_name eq 'Pg' ) {
3025     $case1 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) + INTERVAL '1 month') - 1";
3026     $case2 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) )";
3027   }
3028   elsif ( lc(driver_name) eq 'mysql' ) {
3029     $case1 = "UNIX_TIMESTAMP( DATE_ADD( CAST( $table.paydate AS DATETIME ), INTERVAL 1 month ) ) - 1";
3030     $case2 = "UNIX_TIMESTAMP( CAST( $table.paydate AS DATETIME ) )";
3031   }
3032   else { return '' }
3033   return "CASE WHEN $table.payby IN('CARD','DCRD')
3034   THEN ($case1)
3035   ELSE ($case2)
3036   END"
3037 }
3038
3039 =item tax_exemption TAXNAME
3040
3041 =cut
3042
3043 sub tax_exemption {
3044   my( $self, $taxname ) = @_;
3045
3046   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3047                                      'taxname' => $taxname,
3048                                    },
3049           );
3050 }
3051
3052 =item cust_main_exemption
3053
3054 =cut
3055
3056 sub cust_main_exemption {
3057   my $self = shift;
3058   qsearch( 'cust_main_exemption', { 'custnum' => $self->custnum } );
3059 }
3060
3061 =item invoicing_list [ ARRAYREF ]
3062
3063 If an arguement is given, sets these email addresses as invoice recipients
3064 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
3065 (except as warnings), so use check_invoicing_list first.
3066
3067 Returns a list of email addresses (with svcnum entries expanded).
3068
3069 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
3070 check it without disturbing anything by passing nothing.
3071
3072 This interface may change in the future.
3073
3074 =cut
3075
3076 sub invoicing_list {
3077   my( $self, $arrayref ) = @_;
3078
3079   if ( $arrayref ) {
3080     my @cust_main_invoice;
3081     if ( $self->custnum ) {
3082       @cust_main_invoice =
3083         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3084     } else {
3085       @cust_main_invoice = ();
3086     }
3087     foreach my $cust_main_invoice ( @cust_main_invoice ) {
3088       #warn $cust_main_invoice->destnum;
3089       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
3090         #warn $cust_main_invoice->destnum;
3091         my $error = $cust_main_invoice->delete;
3092         warn $error if $error;
3093       }
3094     }
3095     if ( $self->custnum ) {
3096       @cust_main_invoice =
3097         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3098     } else {
3099       @cust_main_invoice = ();
3100     }
3101     my %seen = map { $_->address => 1 } @cust_main_invoice;
3102     foreach my $address ( @{$arrayref} ) {
3103       next if exists $seen{$address} && $seen{$address};
3104       $seen{$address} = 1;
3105       my $cust_main_invoice = new FS::cust_main_invoice ( {
3106         'custnum' => $self->custnum,
3107         'dest'    => $address,
3108       } );
3109       my $error = $cust_main_invoice->insert;
3110       warn $error if $error;
3111     }
3112   }
3113
3114   if ( $self->custnum ) {
3115     map { $_->address }
3116       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3117   } else {
3118     ();
3119   }
3120
3121 }
3122
3123 =item check_invoicing_list ARRAYREF
3124
3125 Checks these arguements as valid input for the invoicing_list method.  If there
3126 is an error, returns the error, otherwise returns false.
3127
3128 =cut
3129
3130 sub check_invoicing_list {
3131   my( $self, $arrayref ) = @_;
3132
3133   foreach my $address ( @$arrayref ) {
3134
3135     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3136       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3137     }
3138
3139     my $cust_main_invoice = new FS::cust_main_invoice ( {
3140       'custnum' => $self->custnum,
3141       'dest'    => $address,
3142     } );
3143     my $error = $self->custnum
3144                 ? $cust_main_invoice->check
3145                 : $cust_main_invoice->checkdest
3146     ;
3147     return $error if $error;
3148
3149   }
3150
3151   return "Email address required"
3152     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3153     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3154
3155   '';
3156 }
3157
3158 =item set_default_invoicing_list
3159
3160 Sets the invoicing list to all accounts associated with this customer,
3161 overwriting any previous invoicing list.
3162
3163 =cut
3164
3165 sub set_default_invoicing_list {
3166   my $self = shift;
3167   $self->invoicing_list($self->all_emails);
3168 }
3169
3170 =item all_emails
3171
3172 Returns the email addresses of all accounts provisioned for this customer.
3173
3174 =cut
3175
3176 sub all_emails {
3177   my $self = shift;
3178   my %list;
3179   foreach my $cust_pkg ( $self->all_pkgs ) {
3180     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3181     my @svc_acct =
3182       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3183         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3184           @cust_svc;
3185     $list{$_}=1 foreach map { $_->email } @svc_acct;
3186   }
3187   keys %list;
3188 }
3189
3190 =item invoicing_list_addpost
3191
3192 Adds postal invoicing to this customer.  If this customer is already configured
3193 to receive postal invoices, does nothing.
3194
3195 =cut
3196
3197 sub invoicing_list_addpost {
3198   my $self = shift;
3199   return if grep { $_ eq 'POST' } $self->invoicing_list;
3200   my @invoicing_list = $self->invoicing_list;
3201   push @invoicing_list, 'POST';
3202   $self->invoicing_list(\@invoicing_list);
3203 }
3204
3205 =item invoicing_list_emailonly
3206
3207 Returns the list of email invoice recipients (invoicing_list without non-email
3208 destinations such as POST and FAX).
3209
3210 =cut
3211
3212 sub invoicing_list_emailonly {
3213   my $self = shift;
3214   warn "$me invoicing_list_emailonly called"
3215     if $DEBUG;
3216   grep { $_ !~ /^([A-Z]+)$/ } $self->invoicing_list;
3217 }
3218
3219 =item invoicing_list_emailonly_scalar
3220
3221 Returns the list of email invoice recipients (invoicing_list without non-email
3222 destinations such as POST and FAX) as a comma-separated scalar.
3223
3224 =cut
3225
3226 sub invoicing_list_emailonly_scalar {
3227   my $self = shift;
3228   warn "$me invoicing_list_emailonly_scalar called"
3229     if $DEBUG;
3230   join(', ', $self->invoicing_list_emailonly);
3231 }
3232
3233 =item referral_custnum_cust_main
3234
3235 Returns the customer who referred this customer (or the empty string, if
3236 this customer was not referred).
3237
3238 Note the difference with referral_cust_main method: This method,
3239 referral_custnum_cust_main returns the single customer (if any) who referred
3240 this customer, while referral_cust_main returns an array of customers referred
3241 BY this customer.
3242
3243 =cut
3244
3245 sub referral_custnum_cust_main {
3246   my $self = shift;
3247   return '' unless $self->referral_custnum;
3248   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3249 }
3250
3251 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3252
3253 Returns an array of customers referred by this customer (referral_custnum set
3254 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3255 customers referred by customers referred by this customer and so on, inclusive.
3256 The default behavior is DEPTH 1 (no recursion).
3257
3258 Note the difference with referral_custnum_cust_main method: This method,
3259 referral_cust_main, returns an array of customers referred BY this customer,
3260 while referral_custnum_cust_main returns the single customer (if any) who
3261 referred this customer.
3262
3263 =cut
3264
3265 sub referral_cust_main {
3266   my $self = shift;
3267   my $depth = @_ ? shift : 1;
3268   my $exclude = @_ ? shift : {};
3269
3270   my @cust_main =
3271     map { $exclude->{$_->custnum}++; $_; }
3272       grep { ! $exclude->{ $_->custnum } }
3273         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3274
3275   if ( $depth > 1 ) {
3276     push @cust_main,
3277       map { $_->referral_cust_main($depth-1, $exclude) }
3278         @cust_main;
3279   }
3280
3281   @cust_main;
3282 }
3283
3284 =item referral_cust_main_ncancelled
3285
3286 Same as referral_cust_main, except only returns customers with uncancelled
3287 packages.
3288
3289 =cut
3290
3291 sub referral_cust_main_ncancelled {
3292   my $self = shift;
3293   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3294 }
3295
3296 =item referral_cust_pkg [ DEPTH ]
3297
3298 Like referral_cust_main, except returns a flat list of all unsuspended (and
3299 uncancelled) packages for each customer.  The number of items in this list may
3300 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3301
3302 =cut
3303
3304 sub referral_cust_pkg {
3305   my $self = shift;
3306   my $depth = @_ ? shift : 1;
3307
3308   map { $_->unsuspended_pkgs }
3309     grep { $_->unsuspended_pkgs }
3310       $self->referral_cust_main($depth);
3311 }
3312
3313 =item referring_cust_main
3314
3315 Returns the single cust_main record for the customer who referred this customer
3316 (referral_custnum), or false.
3317
3318 =cut
3319
3320 sub referring_cust_main {
3321   my $self = shift;
3322   return '' unless $self->referral_custnum;
3323   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3324 }
3325
3326 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3327
3328 Applies a credit to this customer.  If there is an error, returns the error,
3329 otherwise returns false.
3330
3331 REASON can be a text string, an FS::reason object, or a scalar reference to
3332 a reasonnum.  If a text string, it will be automatically inserted as a new
3333 reason, and a 'reason_type' option must be passed to indicate the
3334 FS::reason_type for the new reason.
3335
3336 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3337
3338 Any other options are passed to FS::cust_credit::insert.
3339
3340 =cut
3341
3342 sub credit {
3343   my( $self, $amount, $reason, %options ) = @_;
3344
3345   my $cust_credit = new FS::cust_credit {
3346     'custnum' => $self->custnum,
3347     'amount'  => $amount,
3348   };
3349
3350   if ( ref($reason) ) {
3351
3352     if ( ref($reason) eq 'SCALAR' ) {
3353       $cust_credit->reasonnum( $$reason );
3354     } else {
3355       $cust_credit->reasonnum( $reason->reasonnum );
3356     }
3357
3358   } else {
3359     $cust_credit->set('reason', $reason)
3360   }
3361
3362   for (qw( addlinfo eventnum )) {
3363     $cust_credit->$_( delete $options{$_} )
3364       if exists($options{$_});
3365   }
3366
3367   $cust_credit->insert(%options);
3368
3369 }
3370
3371 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3372
3373 Creates a one-time charge for this customer.  If there is an error, returns
3374 the error, otherwise returns false.
3375
3376 New-style, with a hashref of options:
3377
3378   my $error = $cust_main->charge(
3379                                   {
3380                                     'amount'     => 54.32,
3381                                     'quantity'   => 1,
3382                                     'start_date' => str2time('7/4/2009'),
3383                                     'pkg'        => 'Description',
3384                                     'comment'    => 'Comment',
3385                                     'additional' => [], #extra invoice detail
3386                                     'classnum'   => 1,  #pkg_class
3387
3388                                     'setuptax'   => '', # or 'Y' for tax exempt
3389
3390                                     'locationnum'=> 1234, # optional
3391
3392                                     #internal taxation
3393                                     'taxclass'   => 'Tax class',
3394
3395                                     #vendor taxation
3396                                     'taxproduct' => 2,  #part_pkg_taxproduct
3397                                     'override'   => {}, #XXX describe
3398
3399                                     #will be filled in with the new object
3400                                     'cust_pkg_ref' => \$cust_pkg,
3401
3402                                     #generate an invoice immediately
3403                                     'bill_now' => 0,
3404                                     'invoice_terms' => '', #with these terms
3405                                   }
3406                                 );
3407
3408 Old-style:
3409
3410   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3411
3412 =cut
3413
3414 sub charge {
3415   my $self = shift;
3416   my ( $amount, $quantity, $start_date, $classnum );
3417   my ( $pkg, $comment, $additional );
3418   my ( $setuptax, $taxclass );   #internal taxes
3419   my ( $taxproduct, $override ); #vendor (CCH) taxes
3420   my $no_auto = '';
3421   my $cust_pkg_ref = '';
3422   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3423   my $locationnum;
3424   if ( ref( $_[0] ) ) {
3425     $amount     = $_[0]->{amount};
3426     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3427     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3428     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3429     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3430     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3431                                            : '$'. sprintf("%.2f",$amount);
3432     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3433     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3434     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3435     $additional = $_[0]->{additional} || [];
3436     $taxproduct = $_[0]->{taxproductnum};
3437     $override   = { '' => $_[0]->{tax_override} };
3438     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3439     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3440     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3441     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3442   } else {
3443     $amount     = shift;
3444     $quantity   = 1;
3445     $start_date = '';
3446     $pkg        = @_ ? shift : 'One-time charge';
3447     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3448     $setuptax   = '';
3449     $taxclass   = @_ ? shift : '';
3450     $additional = [];
3451   }
3452
3453   local $SIG{HUP} = 'IGNORE';
3454   local $SIG{INT} = 'IGNORE';
3455   local $SIG{QUIT} = 'IGNORE';
3456   local $SIG{TERM} = 'IGNORE';
3457   local $SIG{TSTP} = 'IGNORE';
3458   local $SIG{PIPE} = 'IGNORE';
3459
3460   my $oldAutoCommit = $FS::UID::AutoCommit;
3461   local $FS::UID::AutoCommit = 0;
3462   my $dbh = dbh;
3463
3464   my $part_pkg = new FS::part_pkg ( {
3465     'pkg'           => $pkg,
3466     'comment'       => $comment,
3467     'plan'          => 'flat',
3468     'freq'          => 0,
3469     'disabled'      => 'Y',
3470     'classnum'      => ( $classnum ? $classnum : '' ),
3471     'setuptax'      => $setuptax,
3472     'taxclass'      => $taxclass,
3473     'taxproductnum' => $taxproduct,
3474   } );
3475
3476   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3477                         ( 0 .. @$additional - 1 )
3478                   ),
3479                   'additional_count' => scalar(@$additional),
3480                   'setup_fee' => $amount,
3481                 );
3482
3483   my $error = $part_pkg->insert( options       => \%options,
3484                                  tax_overrides => $override,
3485                                );
3486   if ( $error ) {
3487     $dbh->rollback if $oldAutoCommit;
3488     return $error;
3489   }
3490
3491   my $pkgpart = $part_pkg->pkgpart;
3492   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3493   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3494     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3495     $error = $type_pkgs->insert;
3496     if ( $error ) {
3497       $dbh->rollback if $oldAutoCommit;
3498       return $error;
3499     }
3500   }
3501
3502   my $cust_pkg = new FS::cust_pkg ( {
3503     'custnum'    => $self->custnum,
3504     'pkgpart'    => $pkgpart,
3505     'quantity'   => $quantity,
3506     'start_date' => $start_date,
3507     'no_auto'    => $no_auto,
3508     'locationnum'=> $locationnum,
3509   } );
3510
3511   $error = $cust_pkg->insert;
3512   if ( $error ) {
3513     $dbh->rollback if $oldAutoCommit;
3514     return $error;
3515   } elsif ( $cust_pkg_ref ) {
3516     ${$cust_pkg_ref} = $cust_pkg;
3517   }
3518
3519   if ( $bill_now ) {
3520     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3521                              'pkg_list'      => [ $cust_pkg ],
3522                            );
3523     if ( $error ) {
3524       $dbh->rollback if $oldAutoCommit;
3525       return $error;
3526     }
3527   }
3528
3529   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3530   return '';
3531
3532 }
3533
3534 #=item charge_postal_fee
3535 #
3536 #Applies a one time charge this customer.  If there is an error,
3537 #returns the error, returns the cust_pkg charge object or false
3538 #if there was no charge.
3539 #
3540 #=cut
3541 #
3542 # This should be a customer event.  For that to work requires that bill
3543 # also be a customer event.
3544
3545 sub charge_postal_fee {
3546   my $self = shift;
3547
3548   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3549   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3550
3551   my $cust_pkg = new FS::cust_pkg ( {
3552     'custnum'  => $self->custnum,
3553     'pkgpart'  => $pkgpart,
3554     'quantity' => 1,
3555   } );
3556
3557   my $error = $cust_pkg->insert;
3558   $error ? $error : $cust_pkg;
3559 }
3560
3561 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3562
3563 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3564
3565 Optionally, a list or hashref of additional arguments to the qsearch call can
3566 be passed.
3567
3568 =cut
3569
3570 sub cust_bill {
3571   my $self = shift;
3572   my $opt = ref($_[0]) ? shift : { @_ };
3573
3574   #return $self->num_cust_bill unless wantarray || keys %$opt;
3575
3576   $opt->{'table'} = 'cust_bill';
3577   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3578   $opt->{'hashref'}{'custnum'} = $self->custnum;
3579   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3580
3581   map { $_ } #behavior of sort undefined in scalar context
3582     sort { $a->_date <=> $b->_date }
3583       qsearch($opt);
3584 }
3585
3586 =item open_cust_bill
3587
3588 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3589 customer.
3590
3591 =cut
3592
3593 sub open_cust_bill {
3594   my $self = shift;
3595
3596   $self->cust_bill(
3597     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3598     #@_
3599   );
3600
3601 }
3602
3603 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3604
3605 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3606
3607 =cut
3608
3609 sub legacy_cust_bill {
3610   my $self = shift;
3611
3612   #return $self->num_legacy_cust_bill unless wantarray;
3613
3614   map { $_ } #behavior of sort undefined in scalar context
3615     sort { $a->_date <=> $b->_date }
3616       qsearch({ 'table'    => 'legacy_cust_bill',
3617                 'hashref'  => { 'custnum' => $self->custnum, },
3618                 'order_by' => 'ORDER BY _date ASC',
3619              });
3620 }
3621
3622 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3623
3624 Returns all the statements (see L<FS::cust_statement>) for this customer.
3625
3626 Optionally, a list or hashref of additional arguments to the qsearch call can
3627 be passed.
3628
3629 =cut
3630
3631 =item cust_bill_void
3632
3633 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3634
3635 =cut
3636
3637 sub cust_bill_void {
3638   my $self = shift;
3639
3640   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3641   sort { $a->_date <=> $b->_date }
3642     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3643 }
3644
3645 sub cust_statement {
3646   my $self = shift;
3647   my $opt = ref($_[0]) ? shift : { @_ };
3648
3649   #return $self->num_cust_statement unless wantarray || keys %$opt;
3650
3651   $opt->{'table'} = 'cust_statement';
3652   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3653   $opt->{'hashref'}{'custnum'} = $self->custnum;
3654   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3655
3656   map { $_ } #behavior of sort undefined in scalar context
3657     sort { $a->_date <=> $b->_date }
3658       qsearch($opt);
3659 }
3660
3661 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3662
3663 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3664
3665 Optionally, a list or hashref of additional arguments to the qsearch call can
3666 be passed following the SVCDB.
3667
3668 =cut
3669
3670 sub svc_x {
3671   my $self = shift;
3672   my $svcdb = shift;
3673   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3674     warn "$me svc_x requires a svcdb";
3675     return;
3676   }
3677   my $opt = ref($_[0]) ? shift : { @_ };
3678
3679   $opt->{'table'} = $svcdb;
3680   $opt->{'addl_from'} =
3681     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3682     ($opt->{'addl_from'} || '');
3683
3684   my $custnum = $self->custnum;
3685   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3686   my $where = "cust_pkg.custnum = $custnum";
3687
3688   my $extra_sql = $opt->{'extra_sql'} || '';
3689   if ( keys %{ $opt->{'hashref'} } ) {
3690     $extra_sql = " AND $where $extra_sql";
3691   }
3692   else {
3693     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3694       $extra_sql = "WHERE $where AND $1";
3695     }
3696     else {
3697       $extra_sql = "WHERE $where $extra_sql";
3698     }
3699   }
3700   $opt->{'extra_sql'} = $extra_sql;
3701
3702   qsearch($opt);
3703 }
3704
3705 # required for use as an eventtable;
3706 sub svc_acct {
3707   my $self = shift;
3708   $self->svc_x('svc_acct', @_);
3709 }
3710
3711 =item cust_credit
3712
3713 Returns all the credits (see L<FS::cust_credit>) for this customer.
3714
3715 =cut
3716
3717 sub cust_credit {
3718   my $self = shift;
3719   map { $_ } #return $self->num_cust_credit unless wantarray;
3720   sort { $a->_date <=> $b->_date }
3721     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3722 }
3723
3724 =item cust_credit_pkgnum
3725
3726 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3727 package when using experimental package balances.
3728
3729 =cut
3730
3731 sub cust_credit_pkgnum {
3732   my( $self, $pkgnum ) = @_;
3733   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3734   sort { $a->_date <=> $b->_date }
3735     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3736                               'pkgnum'  => $pkgnum,
3737                             }
3738     );
3739 }
3740
3741 =item cust_pay
3742
3743 Returns all the payments (see L<FS::cust_pay>) for this customer.
3744
3745 =cut
3746
3747 sub cust_pay {
3748   my $self = shift;
3749   return $self->num_cust_pay unless wantarray;
3750   sort { $a->_date <=> $b->_date }
3751     qsearch( 'cust_pay', { 'custnum' => $self->custnum } )
3752 }
3753
3754 =item num_cust_pay
3755
3756 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3757 called automatically when the cust_pay method is used in a scalar context.
3758
3759 =cut
3760
3761 sub num_cust_pay {
3762   my $self = shift;
3763   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3764   my $sth = dbh->prepare($sql) or die dbh->errstr;
3765   $sth->execute($self->custnum) or die $sth->errstr;
3766   $sth->fetchrow_arrayref->[0];
3767 }
3768
3769 =item cust_pay_pkgnum
3770
3771 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3772 package when using experimental package balances.
3773
3774 =cut
3775
3776 sub cust_pay_pkgnum {
3777   my( $self, $pkgnum ) = @_;
3778   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3779   sort { $a->_date <=> $b->_date }
3780     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3781                            'pkgnum'  => $pkgnum,
3782                          }
3783     );
3784 }
3785
3786 =item cust_pay_void
3787
3788 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3789
3790 =cut
3791
3792 sub cust_pay_void {
3793   my $self = shift;
3794   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3795   sort { $a->_date <=> $b->_date }
3796     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3797 }
3798
3799 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3800
3801 Returns all batched payments (see L<FS::cust_pay_batch>) for this customer.
3802
3803 Optionally, a list or hashref of additional arguments to the qsearch call can
3804 be passed.
3805
3806 =cut
3807
3808 sub cust_pay_batch {
3809   my $self = shift;
3810   my $opt = ref($_[0]) ? shift : { @_ };
3811
3812   #return $self->num_cust_statement unless wantarray || keys %$opt;
3813
3814   $opt->{'table'} = 'cust_pay_batch';
3815   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3816   $opt->{'hashref'}{'custnum'} = $self->custnum;
3817   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
3818
3819   map { $_ } #behavior of sort undefined in scalar context
3820     sort { $a->paybatchnum <=> $b->paybatchnum }
3821       qsearch($opt);
3822 }
3823
3824 =item cust_pay_pending
3825
3826 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3827 (without status "done").
3828
3829 =cut
3830
3831 sub cust_pay_pending {
3832   my $self = shift;
3833   return $self->num_cust_pay_pending unless wantarray;
3834   sort { $a->_date <=> $b->_date }
3835     qsearch( 'cust_pay_pending', {
3836                                    'custnum' => $self->custnum,
3837                                    'status'  => { op=>'!=', value=>'done' },
3838                                  },
3839            );
3840 }
3841
3842 =item cust_pay_pending_attempt
3843
3844 Returns all payment attempts / declined payments for this customer, as pending
3845 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3846 a corresponding payment (see L<FS::cust_pay>).
3847
3848 =cut
3849
3850 sub cust_pay_pending_attempt {
3851   my $self = shift;
3852   return $self->num_cust_pay_pending_attempt unless wantarray;
3853   sort { $a->_date <=> $b->_date }
3854     qsearch( 'cust_pay_pending', {
3855                                    'custnum' => $self->custnum,
3856                                    'status'  => 'done',
3857                                    'paynum'  => '',
3858                                  },
3859            );
3860 }
3861
3862 =item num_cust_pay_pending
3863
3864 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3865 customer (without status "done").  Also called automatically when the
3866 cust_pay_pending method is used in a scalar context.
3867
3868 =cut
3869
3870 sub num_cust_pay_pending {
3871   my $self = shift;
3872   $self->scalar_sql(
3873     " SELECT COUNT(*) FROM cust_pay_pending ".
3874       " WHERE custnum = ? AND status != 'done' ",
3875     $self->custnum
3876   );
3877 }
3878
3879 =item num_cust_pay_pending_attempt
3880
3881 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3882 customer, with status "done" but without a corresp.  Also called automatically when the
3883 cust_pay_pending method is used in a scalar context.
3884
3885 =cut
3886
3887 sub num_cust_pay_pending_attempt {
3888   my $self = shift;
3889   $self->scalar_sql(
3890     " SELECT COUNT(*) FROM cust_pay_pending ".
3891       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3892     $self->custnum
3893   );
3894 }
3895
3896 =item cust_refund
3897
3898 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3899
3900 =cut
3901
3902 sub cust_refund {
3903   my $self = shift;
3904   map { $_ } #return $self->num_cust_refund unless wantarray;
3905   sort { $a->_date <=> $b->_date }
3906     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3907 }
3908
3909 =item display_custnum
3910
3911 Returns the displayed customer number for this customer: agent_custid if
3912 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3913
3914 =cut
3915
3916 sub display_custnum {
3917   my $self = shift;
3918
3919   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3920   if ( my $special = $conf->config('cust_main-custnum-display_special') ) {
3921     if ( $special eq 'CoStAg' ) {
3922       $prefix = uc( join('',
3923         $self->country,
3924         ($self->state =~ /^(..)/),
3925         $prefix || ($self->agent->agent =~ /^(..)/)
3926       ) );
3927     }
3928     elsif ( $special eq 'CoStCl' ) {
3929       $prefix = uc( join('',
3930         $self->country,
3931         ($self->state =~ /^(..)/),
3932         ($self->classnum ? $self->cust_class->classname =~ /^(..)/ : '__')
3933       ) );
3934     }
3935     # add any others here if needed
3936   }
3937
3938   my $length = $conf->config('cust_main-custnum-display_length');
3939   if ( $conf->exists('cust_main-default_agent_custid') && $self->agent_custid ){
3940     return $self->agent_custid;
3941   } elsif ( $prefix ) {
3942     $length = 8 if !defined($length);
3943     return $prefix .
3944            sprintf('%0'.$length.'d', $self->custnum)
3945   } elsif ( $length ) {
3946     return sprintf('%0'.$length.'d', $self->custnum);
3947   } else {
3948     return $self->custnum;
3949   }
3950 }
3951
3952 =item name
3953
3954 Returns a name string for this customer, either "Company (Last, First)" or
3955 "Last, First".
3956
3957 =cut
3958
3959 sub name {
3960   my $self = shift;
3961   my $name = $self->contact;
3962   $name = $self->company. " ($name)" if $self->company;
3963   $name;
3964 }
3965
3966 =item service_contact
3967
3968 Returns the L<FS::contact> object for this customer that has the 'Service'
3969 contact class, or undef if there is no such contact.  Deprecated; don't use
3970 this in new code.
3971
3972 =cut
3973
3974 sub service_contact {
3975   my $self = shift;
3976   if ( !exists($self->{service_contact}) ) {
3977     my $classnum = $self->scalar_sql(
3978       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
3979     ) || 0; #if it's zero, qsearchs will return nothing
3980     $self->{service_contact} = qsearchs('contact', {
3981         'classnum' => $classnum, 'custnum' => $self->custnum
3982       }) || undef;
3983   }
3984   $self->{service_contact};
3985 }
3986
3987 =item ship_name
3988
3989 Returns a name string for this (service/shipping) contact, either
3990 "Company (Last, First)" or "Last, First".
3991
3992 =cut
3993
3994 sub ship_name {
3995   my $self = shift;
3996
3997   my $name = $self->ship_contact;
3998   $name = $self->company. " ($name)" if $self->company;
3999   $name;
4000 }
4001
4002 =item name_short
4003
4004 Returns a name string for this customer, either "Company" or "First Last".
4005
4006 =cut
4007
4008 sub name_short {
4009   my $self = shift;
4010   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4011 }
4012
4013 =item ship_name_short
4014
4015 Returns a name string for this (service/shipping) contact, either "Company"
4016 or "First Last".
4017
4018 =cut
4019
4020 sub ship_name_short {
4021   my $self = shift;
4022   $self->service_contact
4023     ? $self->ship_contact_firstlast
4024     : $self->name_short
4025 }
4026
4027 =item contact
4028
4029 Returns this customer's full (billing) contact name only, "Last, First"
4030
4031 =cut
4032
4033 sub contact {
4034   my $self = shift;
4035   $self->get('last'). ', '. $self->first;
4036 }
4037
4038 =item ship_contact
4039
4040 Returns this customer's full (shipping) contact name only, "Last, First"
4041
4042 =cut
4043
4044 sub ship_contact {
4045   my $self = shift;
4046   my $contact = $self->service_contact || $self;
4047   $contact->get('last') . ', ' . $contact->get('first');
4048 }
4049
4050 =item contact_firstlast
4051
4052 Returns this customers full (billing) contact name only, "First Last".
4053
4054 =cut
4055
4056 sub contact_firstlast {
4057   my $self = shift;
4058   $self->first. ' '. $self->get('last');
4059 }
4060
4061 =item ship_contact_firstlast
4062
4063 Returns this customer's full (shipping) contact name only, "First Last".
4064
4065 =cut
4066
4067 sub ship_contact_firstlast {
4068   my $self = shift;
4069   my $contact = $self->service_contact || $self;
4070   $contact->get('first') . ' '. $contact->get('last');
4071 }
4072
4073 #XXX this doesn't work in 3.x+
4074 #=item country_full
4075 #
4076 #Returns this customer's full country name
4077 #
4078 #=cut
4079 #
4080 #sub country_full {
4081 #  my $self = shift;
4082 #  code2country($self->country);
4083 #}
4084
4085 =item county_state_county [ PREFIX ]
4086
4087 Returns a string consisting of just the county, state and country.
4088
4089 =cut
4090
4091 sub county_state_country {
4092   my $self = shift;
4093   my $locationnum;
4094   if ( @_ && $_[0] && $self->has_ship_address ) {
4095     $locationnum = $self->ship_locationnum;
4096   } else {
4097     $locationnum = $self->bill_locationnum;
4098   }
4099   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4100   $cust_location->county_state_country;
4101 }
4102
4103 =item geocode DATA_VENDOR
4104
4105 Returns a value for the customer location as encoded by DATA_VENDOR.
4106 Currently this only makes sense for "CCH" as DATA_VENDOR.
4107
4108 =cut
4109
4110 =item cust_status
4111
4112 =item status
4113
4114 Returns a status string for this customer, currently:
4115
4116 =over 4
4117
4118 =item prospect - No packages have ever been ordered
4119
4120 =item ordered - Recurring packages all are new (not yet billed).
4121
4122 =item active - One or more recurring packages is active
4123
4124 =item inactive - No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled)
4125
4126 =item suspended - All non-cancelled recurring packages are suspended
4127
4128 =item cancelled - All recurring packages are cancelled
4129
4130 =back
4131
4132 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4133 cust_main-status_module configuration option.
4134
4135 =cut
4136
4137 sub status { shift->cust_status(@_); }
4138
4139 sub cust_status {
4140   my $self = shift;
4141   for my $status ( FS::cust_main->statuses() ) {
4142     my $method = $status.'_sql';
4143     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4144     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4145     $sth->execute( ($self->custnum) x $numnum )
4146       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4147     return $status if $sth->fetchrow_arrayref->[0];
4148   }
4149 }
4150
4151 =item ucfirst_cust_status
4152
4153 =item ucfirst_status
4154
4155 Returns the status with the first character capitalized.
4156
4157 =cut
4158
4159 sub ucfirst_status { shift->ucfirst_cust_status(@_); }
4160
4161 sub ucfirst_cust_status {
4162   my $self = shift;
4163   ucfirst($self->cust_status);
4164 }
4165
4166 =item statuscolor
4167
4168 Returns a hex triplet color string for this customer's status.
4169
4170 =cut
4171
4172 sub statuscolor { shift->cust_statuscolor(@_); }
4173
4174 sub cust_statuscolor {
4175   my $self = shift;
4176   __PACKAGE__->statuscolors->{$self->cust_status};
4177 }
4178
4179 =item tickets
4180
4181 Returns an array of hashes representing the customer's RT tickets.
4182
4183 =cut
4184
4185 sub tickets {
4186   my $self = shift;
4187
4188   my $num = $conf->config('cust_main-max_tickets') || 10;
4189   my @tickets = ();
4190
4191   if ( $conf->config('ticket_system') ) {
4192     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4193
4194       @tickets = @{ FS::TicketSystem->customer_tickets($self->custnum, $num) };
4195
4196     } else {
4197
4198       foreach my $priority (
4199         $conf->config('ticket_system-custom_priority_field-values'), ''
4200       ) {
4201         last if scalar(@tickets) >= $num;
4202         push @tickets,
4203           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4204                                                  $num - scalar(@tickets),
4205                                                  $priority,
4206                                                )
4207            };
4208       }
4209     }
4210   }
4211   (@tickets);
4212 }
4213
4214 # Return services representing svc_accts in customer support packages
4215 sub support_services {
4216   my $self = shift;
4217   my %packages = map { $_ => 1 } $conf->config('support_packages');
4218
4219   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4220     grep { $_->part_svc->svcdb eq 'svc_acct' }
4221     map { $_->cust_svc }
4222     grep { exists $packages{ $_->pkgpart } }
4223     $self->ncancelled_pkgs;
4224
4225 }
4226
4227 # Return a list of latitude/longitude for one of the services (if any)
4228 sub service_coordinates {
4229   my $self = shift;
4230
4231   my @svc_X =
4232     grep { $_->latitude && $_->longitude }
4233     map { $_->svc_x }
4234     map { $_->cust_svc }
4235     $self->ncancelled_pkgs;
4236
4237   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4238 }
4239
4240 =item masked FIELD
4241
4242 Returns a masked version of the named field
4243
4244 =cut
4245
4246 sub masked {
4247 my ($self,$field) = @_;
4248
4249 # Show last four
4250
4251 'x'x(length($self->getfield($field))-4).
4252   substr($self->getfield($field), (length($self->getfield($field))-4));
4253
4254 }
4255
4256 =back
4257
4258 =head1 CLASS METHODS
4259
4260 =over 4
4261
4262 =item statuses
4263
4264 Class method that returns the list of possible status strings for customers
4265 (see L<the status method|/status>).  For example:
4266
4267   @statuses = FS::cust_main->statuses();
4268
4269 =cut
4270
4271 sub statuses {
4272   my $self = shift;
4273   keys %{ $self->statuscolors };
4274 }
4275
4276 =item cust_status_sql
4277
4278 Returns an SQL fragment to determine the status of a cust_main record, as a
4279 string.
4280
4281 =cut
4282
4283 sub cust_status_sql {
4284   my $sql = 'CASE';
4285   for my $status ( FS::cust_main->statuses() ) {
4286     my $method = $status.'_sql';
4287     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4288   }
4289   $sql .= ' END';
4290   return $sql;
4291 }
4292
4293
4294 =item prospect_sql
4295
4296 Returns an SQL expression identifying prospective cust_main records (customers
4297 with no packages ever ordered)
4298
4299 =cut
4300
4301 use vars qw($select_count_pkgs);
4302 $select_count_pkgs =
4303   "SELECT COUNT(*) FROM cust_pkg
4304     WHERE cust_pkg.custnum = cust_main.custnum";
4305
4306 sub select_count_pkgs_sql {
4307   $select_count_pkgs;
4308 }
4309
4310 sub prospect_sql {
4311   " 0 = ( $select_count_pkgs ) ";
4312 }
4313
4314 =item ordered_sql
4315
4316 Returns an SQL expression identifying ordered cust_main records (customers with
4317 no active packages, but recurring packages not yet setup or one time charges
4318 not yet billed).
4319
4320 =cut
4321
4322 sub ordered_sql {
4323   FS::cust_main->none_active_sql.
4324   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4325 }
4326
4327 =item active_sql
4328
4329 Returns an SQL expression identifying active cust_main records (customers with
4330 active recurring packages).
4331
4332 =cut
4333
4334 sub active_sql {
4335   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4336 }
4337
4338 =item none_active_sql
4339
4340 Returns an SQL expression identifying cust_main records with no active
4341 recurring packages.  This includes customers of status prospect, ordered,
4342 inactive, and suspended.
4343
4344 =cut
4345
4346 sub none_active_sql {
4347   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4348 }
4349
4350 =item inactive_sql
4351
4352 Returns an SQL expression identifying inactive cust_main records (customers with
4353 no active recurring packages, but otherwise unsuspended/uncancelled).
4354
4355 =cut
4356
4357 sub inactive_sql {
4358   FS::cust_main->none_active_sql.
4359   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4360 }
4361
4362 =item susp_sql
4363 =item suspended_sql
4364
4365 Returns an SQL expression identifying suspended cust_main records.
4366
4367 =cut
4368
4369
4370 sub suspended_sql { susp_sql(@_); }
4371 sub susp_sql {
4372   FS::cust_main->none_active_sql.
4373   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4374 }
4375
4376 =item cancel_sql
4377 =item cancelled_sql
4378
4379 Returns an SQL expression identifying cancelled cust_main records.
4380
4381 =cut
4382
4383 sub cancel_sql { shift->cancelled_sql(@_); }
4384
4385 =item uncancel_sql
4386 =item uncancelled_sql
4387
4388 Returns an SQL expression identifying un-cancelled cust_main records.
4389
4390 =cut
4391
4392 sub uncancelled_sql { uncancel_sql(@_); }
4393 sub uncancel_sql { "
4394   ( 0 < ( $select_count_pkgs
4395                    AND ( cust_pkg.cancel IS NULL
4396                          OR cust_pkg.cancel = 0
4397                        )
4398         )
4399     OR 0 = ( $select_count_pkgs )
4400   )
4401 "; }
4402
4403 =item balance_sql
4404
4405 Returns an SQL fragment to retreive the balance.
4406
4407 =cut
4408
4409 sub balance_sql { "
4410     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4411         WHERE cust_bill.custnum   = cust_main.custnum     )
4412   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4413         WHERE cust_pay.custnum    = cust_main.custnum     )
4414   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4415         WHERE cust_credit.custnum = cust_main.custnum     )
4416   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4417         WHERE cust_refund.custnum = cust_main.custnum     )
4418 "; }
4419
4420 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4421
4422 Returns an SQL fragment to retreive the balance for this customer, optionally
4423 considering invoices with date earlier than START_TIME, and not
4424 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4425 total_unapplied_payments).
4426
4427 Times are specified as SQL fragments or numeric
4428 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4429 L<Date::Parse> for conversion functions.  The empty string can be passed
4430 to disable that time constraint completely.
4431
4432 Available options are:
4433
4434 =over 4
4435
4436 =item unapplied_date
4437
4438 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4439
4440 =item total
4441
4442 (unused.  obsolete?)
4443 set to true to remove all customer comparison clauses, for totals
4444
4445 =item where
4446
4447 (unused.  obsolete?)
4448 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4449
4450 =item join
4451
4452 (unused.  obsolete?)
4453 JOIN clause (typically used with the total option)
4454
4455 =item cutoff
4456
4457 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4458 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4459 range for invoices and I<unapplied> payments, credits, and refunds.
4460
4461 =back
4462
4463 =cut
4464
4465 sub balance_date_sql {
4466   my( $class, $start, $end, %opt ) = @_;
4467
4468   my $cutoff = $opt{'cutoff'};
4469
4470   my $owed         = FS::cust_bill->owed_sql($cutoff);
4471   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4472   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4473   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4474
4475   my $j = $opt{'join'} || '';
4476
4477   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4478   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4479   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4480   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4481
4482   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4483     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4484     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4485     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4486   ";
4487
4488 }
4489
4490 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4491
4492 Returns an SQL fragment to retreive the total unapplied payments for this
4493 customer, only considering payments with date earlier than START_TIME, and
4494 optionally not later than END_TIME.
4495
4496 Times are specified as SQL fragments or numeric
4497 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4498 L<Date::Parse> for conversion functions.  The empty string can be passed
4499 to disable that time constraint completely.
4500
4501 Available options are:
4502
4503 =cut
4504
4505 sub unapplied_payments_date_sql {
4506   my( $class, $start, $end, %opt ) = @_;
4507
4508   my $cutoff = $opt{'cutoff'};
4509
4510   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4511
4512   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4513                                                           'unapplied_date'=>1 );
4514
4515   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4516 }
4517
4518 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4519
4520 Helper method for balance_date_sql; name (and usage) subject to change
4521 (suggestions welcome).
4522
4523 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4524 cust_refund, cust_credit or cust_pay).
4525
4526 If TABLE is "cust_bill" or the unapplied_date option is true, only
4527 considers records with date earlier than START_TIME, and optionally not
4528 later than END_TIME .
4529
4530 =cut
4531
4532 sub _money_table_where {
4533   my( $class, $table, $start, $end, %opt ) = @_;
4534
4535   my @where = ();
4536   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4537   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4538     push @where, "$table._date <= $start" if defined($start) && length($start);
4539     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4540   }
4541   push @where, @{$opt{'where'}} if $opt{'where'};
4542   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4543
4544   $where;
4545
4546 }
4547
4548 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4549 use FS::cust_main::Search;
4550 sub search {
4551   my $class = shift;
4552   FS::cust_main::Search->search(@_);
4553 }
4554
4555 =back
4556
4557 =head1 SUBROUTINES
4558
4559 =over 4
4560
4561 =item batch_charge
4562
4563 =cut
4564
4565 sub batch_charge {
4566   my $param = shift;
4567   #warn join('-',keys %$param);
4568   my $fh = $param->{filehandle};
4569   my $agentnum = $param->{agentnum};
4570   my $format = $param->{format};
4571
4572   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
4573
4574   my @fields;
4575   if ( $format eq 'simple' ) {
4576     @fields = qw( custnum agent_custid amount pkg );
4577   } else {
4578     die "unknown format $format";
4579   }
4580
4581   eval "use Text::CSV_XS;";
4582   die $@ if $@;
4583
4584   my $csv = new Text::CSV_XS;
4585   #warn $csv;
4586   #warn $fh;
4587
4588   my $imported = 0;
4589   #my $columns;
4590
4591   local $SIG{HUP} = 'IGNORE';
4592   local $SIG{INT} = 'IGNORE';
4593   local $SIG{QUIT} = 'IGNORE';
4594   local $SIG{TERM} = 'IGNORE';
4595   local $SIG{TSTP} = 'IGNORE';
4596   local $SIG{PIPE} = 'IGNORE';
4597
4598   my $oldAutoCommit = $FS::UID::AutoCommit;
4599   local $FS::UID::AutoCommit = 0;
4600   my $dbh = dbh;
4601
4602   #while ( $columns = $csv->getline($fh) ) {
4603   my $line;
4604   while ( defined($line=<$fh>) ) {
4605
4606     $csv->parse($line) or do {
4607       $dbh->rollback if $oldAutoCommit;
4608       return "can't parse: ". $csv->error_input();
4609     };
4610
4611     my @columns = $csv->fields();
4612     #warn join('-',@columns);
4613
4614     my %row = ();
4615     foreach my $field ( @fields ) {
4616       $row{$field} = shift @columns;
4617     }
4618
4619     if ( $row{custnum} && $row{agent_custid} ) {
4620       dbh->rollback if $oldAutoCommit;
4621       return "can't specify custnum with agent_custid $row{agent_custid}";
4622     }
4623
4624     my %hash = ();
4625     if ( $row{agent_custid} && $agentnum ) {
4626       %hash = ( 'agent_custid' => $row{agent_custid},
4627                 'agentnum'     => $agentnum,
4628               );
4629     }
4630
4631     if ( $row{custnum} ) {
4632       %hash = ( 'custnum' => $row{custnum} );
4633     }
4634
4635     unless ( scalar(keys %hash) ) {
4636       $dbh->rollback if $oldAutoCommit;
4637       return "can't find customer without custnum or agent_custid and agentnum";
4638     }
4639
4640     my $cust_main = qsearchs('cust_main', { %hash } );
4641     unless ( $cust_main ) {
4642       $dbh->rollback if $oldAutoCommit;
4643       my $custnum = $row{custnum} || $row{agent_custid};
4644       return "unknown custnum $custnum";
4645     }
4646
4647     if ( $row{'amount'} > 0 ) {
4648       my $error = $cust_main->charge($row{'amount'}, $row{'pkg'});
4649       if ( $error ) {
4650         $dbh->rollback if $oldAutoCommit;
4651         return $error;
4652       }
4653       $imported++;
4654     } elsif ( $row{'amount'} < 0 ) {
4655       my $error = $cust_main->credit( sprintf( "%.2f", 0-$row{'amount'} ),
4656                                       $row{'pkg'}                         );
4657       if ( $error ) {
4658         $dbh->rollback if $oldAutoCommit;
4659         return $error;
4660       }
4661       $imported++;
4662     } else {
4663       #hmm?
4664     }
4665
4666   }
4667
4668   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4669
4670   return "Empty file!" unless $imported;
4671
4672   ''; #no error
4673
4674 }
4675
4676 =item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4677
4678 Deprecated.  Use event notification and message templates
4679 (L<FS::msg_template>) instead.
4680
4681 Sends a templated email notification to the customer (see L<Text::Template>).
4682
4683 OPTIONS is a hash and may include
4684
4685 I<from> - the email sender (default is invoice_from)
4686
4687 I<to> - comma-separated scalar or arrayref of recipients
4688    (default is invoicing_list)
4689
4690 I<subject> - The subject line of the sent email notification
4691    (default is "Notice from company_name")
4692
4693 I<extra_fields> - a hashref of name/value pairs which will be substituted
4694    into the template
4695
4696 The following variables are vavailable in the template.
4697
4698 I<$first> - the customer first name
4699 I<$last> - the customer last name
4700 I<$company> - the customer company
4701 I<$payby> - a description of the method of payment for the customer
4702             # would be nice to use FS::payby::shortname
4703 I<$payinfo> - the account information used to collect for this customer
4704 I<$expdate> - the expiration of the customer payment in seconds from epoch
4705
4706 =cut
4707
4708 sub notify {
4709   my ($self, $template, %options) = @_;
4710
4711   return unless $conf->exists($template);
4712
4713   my $from = $conf->config('invoice_from', $self->agentnum)
4714     if $conf->exists('invoice_from', $self->agentnum);
4715   $from = $options{from} if exists($options{from});
4716
4717   my $to = join(',', $self->invoicing_list_emailonly);
4718   $to = $options{to} if exists($options{to});
4719
4720   my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
4721     if $conf->exists('company_name', $self->agentnum);
4722   $subject = $options{subject} if exists($options{subject});
4723
4724   my $notify_template = new Text::Template (TYPE => 'ARRAY',
4725                                             SOURCE => [ map "$_\n",
4726                                               $conf->config($template)]
4727                                            )
4728     or die "can't create new Text::Template object: Text::Template::ERROR";
4729   $notify_template->compile()
4730     or die "can't compile template: Text::Template::ERROR";
4731
4732   $FS::notify_template::_template::company_name =
4733     $conf->config('company_name', $self->agentnum);
4734   $FS::notify_template::_template::company_address =
4735     join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
4736
4737   my $paydate = $self->paydate || '2037-12-31';
4738   $FS::notify_template::_template::first = $self->first;
4739   $FS::notify_template::_template::last = $self->last;
4740   $FS::notify_template::_template::company = $self->company;
4741   $FS::notify_template::_template::payinfo = $self->mask_payinfo;
4742   my $payby = $self->payby;
4743   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4744   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4745
4746   #credit cards expire at the end of the month/year of their exp date
4747   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4748     $FS::notify_template::_template::payby = 'credit card';
4749     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4750     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4751     $expire_time--;
4752   }elsif ($payby eq 'COMP') {
4753     $FS::notify_template::_template::payby = 'complimentary account';
4754   }else{
4755     $FS::notify_template::_template::payby = 'current method';
4756   }
4757   $FS::notify_template::_template::expdate = $expire_time;
4758
4759   for (keys %{$options{extra_fields}}){
4760     no strict "refs";
4761     ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
4762   }
4763
4764   send_email(from => $from,
4765              to => $to,
4766              subject => $subject,
4767              body => $notify_template->fill_in( PACKAGE =>
4768                                                 'FS::notify_template::_template'                                              ),
4769             );
4770
4771 }
4772
4773 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4774
4775 Generates a templated notification to the customer (see L<Text::Template>).
4776
4777 OPTIONS is a hash and may include
4778
4779 I<extra_fields> - a hashref of name/value pairs which will be substituted
4780    into the template.  These values may override values mentioned below
4781    and those from the customer record.
4782
4783 The following variables are available in the template instead of or in addition
4784 to the fields of the customer record.
4785
4786 I<$payby> - a description of the method of payment for the customer
4787             # would be nice to use FS::payby::shortname
4788 I<$payinfo> - the masked account information used to collect for this customer
4789 I<$expdate> - the expiration of the customer payment method in seconds from epoch
4790 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4791
4792 =cut
4793
4794 # a lot like cust_bill::print_latex
4795 sub generate_letter {
4796   my ($self, $template, %options) = @_;
4797
4798   return unless $conf->exists($template);
4799
4800   my $letter_template = new Text::Template
4801                         ( TYPE       => 'ARRAY',
4802                           SOURCE     => [ map "$_\n", $conf->config($template)],
4803                           DELIMITERS => [ '[@--', '--@]' ],
4804                         )
4805     or die "can't create new Text::Template object: Text::Template::ERROR";
4806
4807   $letter_template->compile()
4808     or die "can't compile template: Text::Template::ERROR";
4809
4810   my %letter_data = map { $_ => $self->$_ } $self->fields;
4811   $letter_data{payinfo} = $self->mask_payinfo;
4812
4813   #my $paydate = $self->paydate || '2037-12-31';
4814   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
4815
4816   my $payby = $self->payby;
4817   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4818   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4819
4820   #credit cards expire at the end of the month/year of their exp date
4821   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4822     $letter_data{payby} = 'credit card';
4823     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4824     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4825     $expire_time--;
4826   }elsif ($payby eq 'COMP') {
4827     $letter_data{payby} = 'complimentary account';
4828   }else{
4829     $letter_data{payby} = 'current method';
4830   }
4831   $letter_data{expdate} = $expire_time;
4832
4833   for (keys %{$options{extra_fields}}){
4834     $letter_data{$_} = $options{extra_fields}->{$_};
4835   }
4836
4837   unless(exists($letter_data{returnaddress})){
4838     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4839                                                   $self->agent_template)
4840                      );
4841     if ( length($retadd) ) {
4842       $letter_data{returnaddress} = $retadd;
4843     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4844       $letter_data{returnaddress} =
4845         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4846                           s/$/\\\\\*/;
4847                           $_;
4848                         }
4849                     ( $conf->config('company_name', $self->agentnum),
4850                       $conf->config('company_address', $self->agentnum),
4851                     )
4852         );
4853     } else {
4854       $letter_data{returnaddress} = '~';
4855     }
4856   }
4857
4858   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4859
4860   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4861
4862   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4863
4864   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4865                            DIR      => $dir,
4866                            SUFFIX   => '.eps',
4867                            UNLINK   => 0,
4868                          ) or die "can't open temp file: $!\n";
4869   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4870     or die "can't write temp file: $!\n";
4871   close $lh;
4872   $letter_data{'logo_file'} = $lh->filename;
4873
4874   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4875                            DIR      => $dir,
4876                            SUFFIX   => '.tex',
4877                            UNLINK   => 0,
4878                          ) or die "can't open temp file: $!\n";
4879
4880   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4881   close $fh;
4882   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4883   return ($1, $letter_data{'logo_file'});
4884
4885 }
4886
4887 =item print_ps TEMPLATE
4888
4889 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4890
4891 =cut
4892
4893 sub print_ps {
4894   my $self = shift;
4895   my($file, $lfile) = $self->generate_letter(@_);
4896   my $ps = FS::Misc::generate_ps($file);
4897   unlink($file.'.tex');
4898   unlink($lfile);
4899
4900   $ps;
4901 }
4902
4903 =item print TEMPLATE
4904
4905 Prints the filled in template.
4906
4907 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4908
4909 =cut
4910
4911 sub queueable_print {
4912   my %opt = @_;
4913
4914   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4915     or die "invalid customer number: " . $opt{custvnum};
4916
4917   my $error = $self->print( $opt{template} );
4918   die $error if $error;
4919 }
4920
4921 sub print {
4922   my ($self, $template) = (shift, shift);
4923   do_print(
4924     [ $self->print_ps($template) ],
4925     'agentnum' => $self->agentnum,
4926   );
4927 }
4928
4929 #these three subs should just go away once agent stuff is all config overrides
4930
4931 sub agent_template {
4932   my $self = shift;
4933   $self->_agent_plandata('agent_templatename');
4934 }
4935
4936 sub agent_invoice_from {
4937   my $self = shift;
4938   $self->_agent_plandata('agent_invoice_from');
4939 }
4940
4941 sub _agent_plandata {
4942   my( $self, $option ) = @_;
4943
4944   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4945   #agent-specific Conf
4946
4947   use FS::part_event::Condition;
4948
4949   my $agentnum = $self->agentnum;
4950
4951   my $regexp = regexp_sql();
4952
4953   my $part_event_option =
4954     qsearchs({
4955       'select'    => 'part_event_option.*',
4956       'table'     => 'part_event_option',
4957       'addl_from' => q{
4958         LEFT JOIN part_event USING ( eventpart )
4959         LEFT JOIN part_event_option AS peo_agentnum
4960           ON ( part_event.eventpart = peo_agentnum.eventpart
4961                AND peo_agentnum.optionname = 'agentnum'
4962                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
4963              )
4964         LEFT JOIN part_event_condition
4965           ON ( part_event.eventpart = part_event_condition.eventpart
4966                AND part_event_condition.conditionname = 'cust_bill_age'
4967              )
4968         LEFT JOIN part_event_condition_option
4969           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
4970                AND part_event_condition_option.optionname = 'age'
4971              )
4972       },
4973       #'hashref'   => { 'optionname' => $option },
4974       #'hashref'   => { 'part_event_option.optionname' => $option },
4975       'extra_sql' =>
4976         " WHERE part_event_option.optionname = ". dbh->quote($option).
4977         " AND action = 'cust_bill_send_agent' ".
4978         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
4979         " AND peo_agentnum.optionname = 'agentnum' ".
4980         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
4981         " ORDER BY
4982            CASE WHEN part_event_condition_option.optionname IS NULL
4983            THEN -1
4984            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
4985         " END
4986           , part_event.weight".
4987         " LIMIT 1"
4988     });
4989
4990   unless ( $part_event_option ) {
4991     return $self->agent->invoice_template || ''
4992       if $option eq 'agent_templatename';
4993     return '';
4994   }
4995
4996   $part_event_option->optionvalue;
4997
4998 }
4999
5000 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5001
5002 Subroutine (not a method), designed to be called from the queue.
5003
5004 Takes a list of options and values.
5005
5006 Pulls up the customer record via the custnum option and calls bill_and_collect.
5007
5008 =cut
5009
5010 sub queued_bill {
5011   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5012
5013   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5014   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5015
5016   $cust_main->bill_and_collect( %args );
5017 }
5018
5019 sub process_bill_and_collect {
5020   my $job = shift;
5021   my $param = thaw(decode_base64(shift));
5022   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5023       or die "custnum '$param->{custnum}' not found!\n";
5024   $param->{'job'}   = $job;
5025   $param->{'fatal'} = 1; # runs from job queue, will be caught
5026   $param->{'retry'} = 1;
5027
5028   $cust_main->bill_and_collect( %$param );
5029 }
5030
5031 #starting to take quite a while for big dbs
5032 #   (JRNL: journaled so it only happens once per database)
5033 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5034 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5035 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5036 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5037 # JRNL leading/trailing spaces in first, last, company
5038 # - otaker upgrade?  journal and call it good?  (double check to make sure
5039 #    we're not still setting otaker here)
5040 #
5041 #only going to get worse with new location stuff...
5042
5043 sub _upgrade_data { #class method
5044   my ($class, %opts) = @_;
5045
5046   my @statements = (
5047     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
5048   );
5049
5050   #this seems to be the only expensive one.. why does it take so long?
5051   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5052     push @statements,
5053       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5054     FS::upgrade_journal->set_done('cust_main__signupdate');
5055   }
5056
5057   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
5058
5059     # fix yyyy-m-dd formatted paydates
5060     if ( driver_name =~ /^mysql/i ) {
5061       push @statements,
5062       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5063     } else { # the SQL standard
5064       push @statements,
5065       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5066     }
5067     FS::upgrade_journal->set_done('cust_main__paydate');
5068   }
5069
5070   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5071
5072     push @statements, #fix the weird BILL with a cc# in payinfo problem
5073       #DCRD to be safe
5074       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5075
5076     FS::upgrade_journal->set_done('cust_main__payinfo');
5077
5078   }
5079
5080   my $t = time;
5081   foreach my $sql ( @statements ) {
5082     my $sth = dbh->prepare($sql) or die dbh->errstr;
5083     $sth->execute or die $sth->errstr;
5084     #warn ( (time - $t). " seconds\n" );
5085     #$t = time;
5086   }
5087
5088   local($ignore_expired_card) = 1;
5089   local($ignore_banned_card) = 1;
5090   local($skip_fuzzyfiles) = 1;
5091   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5092
5093   FS::cust_main::Location->_upgrade_data(%opts);
5094
5095   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5096
5097     foreach my $cust_main ( qsearch({
5098       'table'     => 'cust_main',
5099       'hashref'   => {},
5100       'extra_sql' => 'WHERE '.
5101                        join(' OR ',
5102                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5103                            qw( first last company )
5104                        ),
5105     }) ) {
5106       my $error = $cust_main->replace;
5107       die $error if $error;
5108     }
5109
5110     FS::upgrade_journal->set_done('cust_main__trimspaces');
5111
5112   }
5113
5114   $class->_upgrade_otaker(%opts);
5115
5116 }
5117
5118 =back
5119
5120 =head1 BUGS
5121
5122 The delete method.
5123
5124 The delete method should possibly take an FS::cust_main object reference
5125 instead of a scalar customer number.
5126
5127 Bill and collect options should probably be passed as references instead of a
5128 list.
5129
5130 There should probably be a configuration file with a list of allowed credit
5131 card types.
5132
5133 No multiple currency support (probably a larger project than just this module).
5134
5135 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5136
5137 Birthdates rely on negative epoch values.
5138
5139 The payby for card/check batches is broken.  With mixed batching, bad
5140 things will happen.
5141
5142 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5143
5144 =head1 SEE ALSO
5145
5146 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5147 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5148 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5149
5150 =cut
5151
5152 1;
5153