FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Discount
   8              FS::cust_main::Billing_ThirdParty
   9              FS::cust_main::Location
  10              FS::cust_main::Credit_Limit
  11              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  12              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  13              FS::o2m_Common
  14              FS::Record
  15            );
  16
  17 require 5.006;
  18 use strict;
  19 use vars qw( $DEBUG $me $conf
  20              @encrypted_fields
  21              $import
  22              $ignore_expired_card $ignore_banned_card $ignore_illegal_zip
  23              $ignore_invalid_card
  24              $skip_fuzzyfiles
  25              @paytypes
  26            );
  27 use Carp;
  28 use Scalar::Util qw( blessed );
  29 use Time::Local qw(timelocal);
  30 use Storable qw(thaw);
  31 use MIME::Base64;
  32 use Data::Dumper;
  33 use Tie::IxHash;
  34 use Digest::MD5 qw(md5_base64);
  35 use Date::Format;
  36 #use Date::Manip;
  37 use File::Temp; #qw( tempfile );
  38 use Business::CreditCard 0.28;
  39 use Locale::Country;
  40 use FS::UID qw( dbh driver_name );
  41 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  42 use FS::Cursor;
  43 use FS::Misc qw( generate_email send_email generate_ps do_print );
  44 use FS::Msgcat qw(gettext);
  45 use FS::CurrentUser;
  46 use FS::TicketSystem;
  47 use FS::payby;
  48 use FS::cust_pkg;
  49 use FS::cust_svc;
  50 use FS::cust_bill;
  51 use FS::cust_bill_void;
  52 use FS::legacy_cust_bill;
  53 use FS::cust_pay;
  54 use FS::cust_pay_pending;
  55 use FS::cust_pay_void;
  56 use FS::cust_pay_batch;
  57 use FS::cust_credit;
  58 use FS::cust_refund;
  59 use FS::part_referral;
  60 use FS::cust_main_county;
  61 use FS::cust_location;
  62 use FS::cust_class;
  63 use FS::cust_main_exemption;
  64 use FS::cust_tax_adjustment;
  65 use FS::cust_tax_location;
  66 use FS::agent_currency;
  67 use FS::cust_main_invoice;
  68 use FS::cust_tag;
  69 use FS::prepay_credit;
  70 use FS::queue;
  71 use FS::part_pkg;
  72 use FS::part_export;
  73 #use FS::cust_event;
  74 use FS::type_pkgs;
  75 use FS::payment_gateway;
  76 use FS::agent_payment_gateway;
  77 use FS::banned_pay;
  78 use FS::cust_main_note;
  79 use FS::cust_attachment;
  80 use FS::contact;
  81 use FS::Locales;
  82 use FS::upgrade_journal;
  83 use FS::sales;
  84 use FS::cust_payby;
  85
  86 # 1 is mostly method/subroutine entry and options
  87 # 2 traces progress of some operations
  88 # 3 is even more information including possibly sensitive data
  89 $DEBUG = 0;
  90 $me = '[FS::cust_main]';
  91
  92 $import = 0;
  93 $ignore_expired_card = 0;
  94 $ignore_banned_card = 0;
  95 $ignore_invalid_card = 0;
  96
  97 $skip_fuzzyfiles = 0;
  98
  99 @encrypted_fields = ('payinfo', 'paycvv');
 100 sub nohistory_fields { ('payinfo', 'paycvv'); }
 101
 102 @paytypes = ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
 103
 104 #ask FS::UID to run this stuff for us later
 105 #$FS::UID::callback{'FS::cust_main'} = sub {
 106 install_callback FS::UID sub {
 107   $conf = new FS::Conf;
 108   #yes, need it for stuff below (prolly should be cached)
 109   $ignore_invalid_card = $conf->exists('allow_invalid_cards');
 110 };
 111
 112 sub _cache {
 113   my $self = shift;
 114   my ( $hashref, $cache ) = @_;
 115   if ( exists $hashref->{'pkgnum'} ) {
 116     #@{ $self->{'_pkgnum'} } = ();
 117     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 118     $self->{'_pkgnum'} = $subcache;
 119     #push @{ $self->{'_pkgnum'} },
 120     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 121   }
 122 }
 123
 124 =head1 NAME
 125
 126 FS::cust_main - Object methods for cust_main records
 127
 128 =head1 SYNOPSIS
 129
 130   use FS::cust_main;
 131
 132   $record = new FS::cust_main \%hash;
 133   $record = new FS::cust_main { 'column' => 'value' };
 134
 135   $error = $record->insert;
 136
 137   $error = $new_record->replace($old_record);
 138
 139   $error = $record->delete;
 140
 141   $error = $record->check;
 142
 143   @cust_pkg = $record->all_pkgs;
 144
 145   @cust_pkg = $record->ncancelled_pkgs;
 146
 147   @cust_pkg = $record->suspended_pkgs;
 148
 149   $error = $record->bill;
 150   $error = $record->bill %options;
 151   $error = $record->bill 'time' => $time;
 152
 153   $error = $record->collect;
 154   $error = $record->collect %options;
 155   $error = $record->collect 'invoice_time'   => $time,
 156                           ;
 157
 158 =head1 DESCRIPTION
 159
 160 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 161 FS::Record.  The following fields are currently supported:
 162
 163 =over 4
 164
 165 =item custnum
 166
 167 Primary key (assigned automatically for new customers)
 168
 169 =item agentnum
 170
 171 Agent (see L<FS::agent>)
 172
 173 =item refnum
 174
 175 Advertising source (see L<FS::part_referral>)
 176
 177 =item first
 178
 179 First name
 180
 181 =item last
 182
 183 Last name
 184
 185 =item ss
 186
 187 Cocial security number (optional)
 188
 189 =item company
 190
 191 (optional)
 192
 193 =item daytime
 194
 195 phone (optional)
 196
 197 =item night
 198
 199 phone (optional)
 200
 201 =item fax
 202
 203 phone (optional)
 204
 205 =item mobile
 206
 207 phone (optional)
 208
 209 =item payby
 210
 211 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 212
 213 =item payinfo
 214
 215 Payment Information (See L<FS::payinfo_Mixin> for data format)
 216
 217 =item paymask
 218
 219 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 220
 221 =item paycvv
 222
 223 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 224
 225 =item paydate
 226
 227 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 228
 229 =item paystart_month
 230
 231 Start date month (maestro/solo cards only)
 232
 233 =item paystart_year
 234
 235 Start date year (maestro/solo cards only)
 236
 237 =item payissue
 238
 239 Issue number (maestro/solo cards only)
 240
 241 =item payname
 242
 243 Name on card or billing name
 244
 245 =item payip
 246
 247 IP address from which payment information was received
 248
 249 =item tax
 250
 251 Tax exempt, empty or `Y'
 252
 253 =item usernum
 254
 255 Order taker (see L<FS::access_user>)
 256
 257 =item comments
 258
 259 Comments (optional)
 260
 261 =item referral_custnum
 262
 263 Referring customer number
 264
 265 =item spool_cdr
 266
 267 Enable individual CDR spooling, empty or `Y'
 268
 269 =item dundate
 270
 271 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 272
 273 =item squelch_cdr
 274
 275 Discourage individual CDR printing, empty or `Y'
 276
 277 =item edit_subject
 278
 279 Allow self-service editing of ticket subjects, empty or 'Y'
 280
 281 =item calling_list_exempt
 282
 283 Do not call, empty or 'Y'
 284
 285 =back
 286
 287 =head1 METHODS
 288
 289 =over 4
 290
 291 =item new HASHREF
 292
 293 Creates a new customer.  To add the customer to the database, see L<"insert">.
 294
 295 Note that this stores the hash reference, not a distinct copy of the hash it
 296 points to.  You can ask the object for a copy with the I<hash> method.
 297
 298 =cut
 299
 300 sub table { 'cust_main'; }
 301
 302 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 303
 304 Adds this customer to the database.  If there is an error, returns the error,
 305 otherwise returns false.
 306
 307 Usually the customer's location will not yet exist in the database, and
 308 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 309 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 310 (in both directions) to the new customer record.  If they're references
 311 to the same object, they will become the same location.
 312
 313 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 314 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 315 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 316 hash reference is equivalent to not supplying this parameter.  There should be
 317 a better explanation of this, but until then, here's an example:
 318
 319   use Tie::RefHash;
 320   tie %hash, 'Tie::RefHash'; #this part is important
 321   %hash = (
 322     $cust_pkg => [ $svc_acct ],
 323     ...
 324   );
 325   $cust_main->insert( \%hash );
 326
 327 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 328 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 329 expected and rollback the entire transaction; it is not necessary to call
 330 check_invoicing_list first.  The invoicing_list is set after the records in the
 331 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 332 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 333
 334   $cust_main->insert( {}, [ $email, 'POST' ] );
 335
 336 Currently available options are: I<depend_jobnum>, I<noexport>,
 337 I<tax_exemption> and I<prospectnum>.
 338
 339 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 340 on the supplied jobnum (they will not run until the specific job completes).
 341 This can be used to defer provisioning until some action completes (such
 342 as running the customer's credit card successfully).
 343
 344 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 345 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 346 the B<reexport> method.)
 347
 348 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 349 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 350 created and inserted.
 351
 352 If I<prospectnum> is set, moves contacts and locations from that prospect.
 353
 354 If I<contact> is set to an arrayref of FS::contact objects, inserts those
 355 new contacts with this new customer.
 356
 357 =cut
 358
 359 sub insert {
 360   my $self = shift;
 361   my $cust_pkgs = @_ ? shift : {};
 362   my $invoicing_list = @_ ? shift : '';
 363   my %options = @_;
 364   warn "$me insert called with options ".
 365        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 366     if $DEBUG;
 367
 368   local $SIG{HUP} = 'IGNORE';
 369   local $SIG{INT} = 'IGNORE';
 370   local $SIG{QUIT} = 'IGNORE';
 371   local $SIG{TERM} = 'IGNORE';
 372   local $SIG{TSTP} = 'IGNORE';
 373   local $SIG{PIPE} = 'IGNORE';
 374
 375   my $oldAutoCommit = $FS::UID::AutoCommit;
 376   local $FS::UID::AutoCommit = 0;
 377   my $dbh = dbh;
 378
 379   my $prepay_identifier = '';
 380   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 381   my $payby = '';
 382   if ( $self->payby eq 'PREPAY' ) {
 383
 384     $self->payby('BILL');
 385     $prepay_identifier = $self->payinfo;
 386     $self->payinfo('');
 387
 388     warn "  looking up prepaid card $prepay_identifier\n"
 389       if $DEBUG > 1;
 390
 391     my $error = $self->get_prepay( $prepay_identifier,
 392                                    'amount_ref'     => \$amount,
 393                                    'seconds_ref'    => \$seconds,
 394                                    'upbytes_ref'    => \$upbytes,
 395                                    'downbytes_ref'  => \$downbytes,
 396                                    'totalbytes_ref' => \$totalbytes,
 397                                  );
 398     if ( $error ) {
 399       $dbh->rollback if $oldAutoCommit;
 400       #return "error applying prepaid card (transaction rolled back): $error";
 401       return $error;
 402     }
 403
 404     $payby = 'PREP' if $amount;
 405
 406   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|PPAL)$/ ) {
 407
 408     $payby = $1;
 409     $self->payby('BILL');
 410     $amount = $self->paid;
 411
 412   }
 413
 414   # insert locations
 415   foreach my $l (qw(bill_location ship_location)) {
 416     my $loc = delete $self->hashref->{$l};
 417     # XXX if we're moving a prospect's locations, do that here
 418     if ( !$loc ) {
 419       #return "$l not set";
 420       #location-less customer records are now permitted
 421       next;
 422     }
 423
 424     if ( !$loc->locationnum ) {
 425       # warn the location that we're going to insert it with no custnum
 426       $loc->set(custnum_pending => 1);
 427       warn "  inserting $l\n"
 428         if $DEBUG > 1;
 429       my $error = $loc->insert;
 430       if ( $error ) {
 431         $dbh->rollback if $oldAutoCommit;
 432         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 433         return "$error (in $label location)";
 434       }
 435     }
 436     elsif ( ($loc->custnum || 0) > 0 or $loc->prospectnum ) {
 437       # then it somehow belongs to another customer--shouldn't happen
 438       $dbh->rollback if $oldAutoCommit;
 439       return "$l belongs to customer ".$loc->custnum;
 440     }
 441     # else it already belongs to this customer
 442     # (happens when ship_location is identical to bill_location)
 443
 444     $self->set($l.'num', $loc->locationnum);
 445
 446     if ( $self->get($l.'num') eq '' ) {
 447       $dbh->rollback if $oldAutoCommit;
 448       return "$l not set";
 449     }
 450   }
 451
 452   warn "  inserting $self\n"
 453     if $DEBUG > 1;
 454
 455   $self->signupdate(time) unless $self->signupdate;
 456
 457   $self->auto_agent_custid()
 458     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 459
 460   my $error = $self->SUPER::insert;
 461   if ( $error ) {
 462     $dbh->rollback if $oldAutoCommit;
 463     #return "inserting cust_main record (transaction rolled back): $error";
 464     return $error;
 465   }
 466
 467   # now set cust_location.custnum
 468   foreach my $l (qw(bill_location ship_location)) {
 469     warn "  setting $l.custnum\n"
 470       if $DEBUG > 1;
 471     my $loc = $self->$l or next;
 472     unless ( $loc->custnum ) {
 473       $loc->set(custnum => $self->custnum);
 474       $error ||= $loc->replace;
 475     }
 476
 477     if ( $error ) {
 478       $dbh->rollback if $oldAutoCommit;
 479       return "error setting $l custnum: $error";
 480     }
 481   }
 482
 483   warn "  setting invoicing list\n"
 484     if $DEBUG > 1;
 485
 486   if ( $invoicing_list ) {
 487     $error = $self->check_invoicing_list( $invoicing_list );
 488     if ( $error ) {
 489       $dbh->rollback if $oldAutoCommit;
 490       #return "checking invoicing_list (transaction rolled back): $error";
 491       return $error;
 492     }
 493     $self->invoicing_list( $invoicing_list );
 494   }
 495
 496   warn "  setting customer tags\n"
 497     if $DEBUG > 1;
 498
 499   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 500     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 501                                       'custnum' => $self->custnum };
 502     my $error = $cust_tag->insert;
 503     if ( $error ) {
 504       $dbh->rollback if $oldAutoCommit;
 505       return $error;
 506     }
 507   }
 508
 509   my $prospectnum = delete $options{'prospectnum'};
 510   if ( $prospectnum ) {
 511
 512     warn "  moving contacts and locations from prospect $prospectnum\n"
 513       if $DEBUG > 1;
 514
 515     my $prospect_main =
 516       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 517     unless ( $prospect_main ) {
 518       $dbh->rollback if $oldAutoCommit;
 519       return "Unknown prospectnum $prospectnum";
 520     }
 521     $prospect_main->custnum($self->custnum);
 522     $prospect_main->disabled('Y');
 523     my $error = $prospect_main->replace;
 524     if ( $error ) {
 525       $dbh->rollback if $oldAutoCommit;
 526       return $error;
 527     }
 528
 529     my @contact = $prospect_main->contact;
 530     my @cust_location = $prospect_main->cust_location;
 531     my @qual = $prospect_main->qual;
 532
 533     foreach my $r ( @contact, @cust_location, @qual ) {
 534       $r->prospectnum('');
 535       $r->custnum($self->custnum);
 536       my $error = $r->replace;
 537       if ( $error ) {
 538         $dbh->rollback if $oldAutoCommit;
 539         return $error;
 540       }
 541     }
 542
 543   }
 544
 545   my $contact = delete $options{'contact'};
 546   if ( $contact ) {
 547
 548     foreach my $c ( @$contact ) {
 549       $c->custnum($self->custnum);
 550       my $error = $c->insert;
 551       if ( $error ) {
 552         $dbh->rollback if $oldAutoCommit;
 553         return $error;
 554       }
 555
 556     }
 557
 558   }
 559
 560   warn "  setting cust_main_exemption\n"
 561     if $DEBUG > 1;
 562
 563   my $tax_exemption = delete $options{'tax_exemption'};
 564   if ( $tax_exemption ) {
 565
 566     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 567       if ref($tax_exemption) eq 'ARRAY';
 568
 569     foreach my $taxname ( keys %$tax_exemption ) {
 570       my $cust_main_exemption = new FS::cust_main_exemption {
 571         'custnum'       => $self->custnum,
 572         'taxname'       => $taxname,
 573         'exempt_number' => $tax_exemption->{$taxname},
 574       };
 575       my $error = $cust_main_exemption->insert;
 576       if ( $error ) {
 577         $dbh->rollback if $oldAutoCommit;
 578         return "inserting cust_main_exemption (transaction rolled back): $error";
 579       }
 580     }
 581   }
 582
 583   warn "  ordering packages\n"
 584     if $DEBUG > 1;
 585
 586   $error = $self->order_pkgs( $cust_pkgs,
 587                               %options,
 588                               'seconds_ref'    => \$seconds,
 589                               'upbytes_ref'    => \$upbytes,
 590                               'downbytes_ref'  => \$downbytes,
 591                               'totalbytes_ref' => \$totalbytes,
 592                             );
 593   if ( $error ) {
 594     $dbh->rollback if $oldAutoCommit;
 595     return $error;
 596   }
 597
 598   if ( $seconds ) {
 599     $dbh->rollback if $oldAutoCommit;
 600     return "No svc_acct record to apply pre-paid time";
 601   }
 602   if ( $upbytes || $downbytes || $totalbytes ) {
 603     $dbh->rollback if $oldAutoCommit;
 604     return "No svc_acct record to apply pre-paid data";
 605   }
 606
 607   if ( $amount ) {
 608     warn "  inserting initial $payby payment of $amount\n"
 609       if $DEBUG > 1;
 610     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 611     if ( $error ) {
 612       $dbh->rollback if $oldAutoCommit;
 613       return "inserting payment (transaction rolled back): $error";
 614     }
 615   }
 616
 617   unless ( $import || $skip_fuzzyfiles ) {
 618     warn "  queueing fuzzyfiles update\n"
 619       if $DEBUG > 1;
 620     $error = $self->queue_fuzzyfiles_update;
 621     if ( $error ) {
 622       $dbh->rollback if $oldAutoCommit;
 623       return "updating fuzzy search cache: $error";
 624     }
 625   }
 626
 627   # FS::geocode_Mixin::after_insert or something?
 628   if ( $conf->config('tax_district_method') and !$import ) {
 629     # if anything non-empty, try to look it up
 630     my $queue = new FS::queue {
 631       'job'     => 'FS::geocode_Mixin::process_district_update',
 632       'custnum' => $self->custnum,
 633     };
 634     my $error = $queue->insert( ref($self), $self->custnum );
 635     if ( $error ) {
 636       $dbh->rollback if $oldAutoCommit;
 637       return "queueing tax district update: $error";
 638     }
 639   }
 640
 641   # cust_main exports!
 642   warn "  exporting\n" if $DEBUG > 1;
 643
 644   my $export_args = $options{'export_args'} || [];
 645
 646   my @part_export =
 647     map qsearch( 'part_export', {exportnum=>$_} ),
 648       $conf->config('cust_main-exports'); #, $agentnum
 649
 650   foreach my $part_export ( @part_export ) {
 651     my $error = $part_export->export_insert($self, @$export_args);
 652     if ( $error ) {
 653       $dbh->rollback if $oldAutoCommit;
 654       return "exporting to ". $part_export->exporttype.
 655              " (transaction rolled back): $error";
 656     }
 657   }
 658
 659   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 660   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 661   #      if $DEBUG;
 662   #    foreach my $jobnum ( @jobnums ) {
 663   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 664   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 665   #        if $DEBUG;
 666   #      my $error = $queue->depend_insert($depend_jobnum);
 667   #      if ( $error ) {
 668   #        $dbh->rollback if $oldAutoCommit;
 669   #        return "error queuing job dependancy: $error";
 670   #      }
 671   #    }
 672   #  }
 673   #
 674   #}
 675   #
 676   #if ( exists $options{'jobnums'} ) {
 677   #  push @{ $options{'jobnums'} }, @jobnums;
 678   #}
 679
 680   warn "  insert complete; committing transaction\n"
 681     if $DEBUG > 1;
 682
 683   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 684   '';
 685
 686 }
 687
 688 use File::CounterFile;
 689 sub auto_agent_custid {
 690   my $self = shift;
 691
 692   my $format = $conf->config('cust_main-auto_agent_custid');
 693   my $agent_custid;
 694   if ( $format eq '1YMMXXXXXXXX' ) {
 695
 696     my $counter = new File::CounterFile 'cust_main.agent_custid';
 697     $counter->lock;
 698
 699     my $ym = 100000000000 + time2str('%y%m00000000', time);
 700     if ( $ym > $counter->value ) {
 701       $counter->{'value'} = $agent_custid = $ym;
 702       $counter->{'updated'} = 1;
 703     } else {
 704       $agent_custid = $counter->inc;
 705     }
 706
 707     $counter->unlock;
 708
 709   } else {
 710     die "Unknown cust_main-auto_agent_custid format: $format";
 711   }
 712
 713   $self->agent_custid($agent_custid);
 714
 715 }
 716
 717 =item PACKAGE METHODS
 718
 719 Documentation on customer package methods has been moved to
 720 L<FS::cust_main::Packages>.
 721
 722 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 723
 724 Recharges this (existing) customer with the specified prepaid card (see
 725 L<FS::prepay_credit>), specified either by I<identifier> or as an
 726 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 727 returns false.
 728
 729 Optionally, five scalar references can be passed as well.  They will have their
 730 values filled in with the amount, number of seconds, and number of upload,
 731 download, and total bytes applied by this prepaid card.
 732
 733 =cut
 734
 735 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 736 #the only place that uses these args
 737 sub recharge_prepay {
 738   my( $self, $prepay_credit, $amountref, $secondsref,
 739       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 740
 741   local $SIG{HUP} = 'IGNORE';
 742   local $SIG{INT} = 'IGNORE';
 743   local $SIG{QUIT} = 'IGNORE';
 744   local $SIG{TERM} = 'IGNORE';
 745   local $SIG{TSTP} = 'IGNORE';
 746   local $SIG{PIPE} = 'IGNORE';
 747
 748   my $oldAutoCommit = $FS::UID::AutoCommit;
 749   local $FS::UID::AutoCommit = 0;
 750   my $dbh = dbh;
 751
 752   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 753
 754   my $error = $self->get_prepay( $prepay_credit,
 755                                  'amount_ref'     => \$amount,
 756                                  'seconds_ref'    => \$seconds,
 757                                  'upbytes_ref'    => \$upbytes,
 758                                  'downbytes_ref'  => \$downbytes,
 759                                  'totalbytes_ref' => \$totalbytes,
 760                                )
 761            || $self->increment_seconds($seconds)
 762            || $self->increment_upbytes($upbytes)
 763            || $self->increment_downbytes($downbytes)
 764            || $self->increment_totalbytes($totalbytes)
 765            || $self->insert_cust_pay_prepay( $amount,
 766                                              ref($prepay_credit)
 767                                                ? $prepay_credit->identifier
 768                                                : $prepay_credit
 769                                            );
 770
 771   if ( $error ) {
 772     $dbh->rollback if $oldAutoCommit;
 773     return $error;
 774   }
 775
 776   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 777   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 778   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 779   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 780   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 781
 782   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 783   '';
 784
 785 }
 786
 787 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 788
 789 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 790 specified either by I<identifier> or as an FS::prepay_credit object.
 791
 792 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 793 incremented by the values of the prepaid card.
 794
 795 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 796 check or set this customer's I<agentnum>.
 797
 798 If there is an error, returns the error, otherwise returns false.
 799
 800 =cut
 801
 802
 803 sub get_prepay {
 804   my( $self, $prepay_credit, %opt ) = @_;
 805
 806   local $SIG{HUP} = 'IGNORE';
 807   local $SIG{INT} = 'IGNORE';
 808   local $SIG{QUIT} = 'IGNORE';
 809   local $SIG{TERM} = 'IGNORE';
 810   local $SIG{TSTP} = 'IGNORE';
 811   local $SIG{PIPE} = 'IGNORE';
 812
 813   my $oldAutoCommit = $FS::UID::AutoCommit;
 814   local $FS::UID::AutoCommit = 0;
 815   my $dbh = dbh;
 816
 817   unless ( ref($prepay_credit) ) {
 818
 819     my $identifier = $prepay_credit;
 820
 821     $prepay_credit = qsearchs(
 822       'prepay_credit',
 823       { 'identifier' => $identifier },
 824       '',
 825       'FOR UPDATE'
 826     );
 827
 828     unless ( $prepay_credit ) {
 829       $dbh->rollback if $oldAutoCommit;
 830       return "Invalid prepaid card: ". $identifier;
 831     }
 832
 833   }
 834
 835   if ( $prepay_credit->agentnum ) {
 836     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 837       $dbh->rollback if $oldAutoCommit;
 838       return "prepaid card not valid for agent ". $self->agentnum;
 839     }
 840     $self->agentnum($prepay_credit->agentnum);
 841   }
 842
 843   my $error = $prepay_credit->delete;
 844   if ( $error ) {
 845     $dbh->rollback if $oldAutoCommit;
 846     return "removing prepay_credit (transaction rolled back): $error";
 847   }
 848
 849   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 850     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 851
 852   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 853   '';
 854
 855 }
 856
 857 =item increment_upbytes SECONDS
 858
 859 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 860 the specified number of upbytes.  If there is an error, returns the error,
 861 otherwise returns false.
 862
 863 =cut
 864
 865 sub increment_upbytes {
 866   _increment_column( shift, 'upbytes', @_);
 867 }
 868
 869 =item increment_downbytes SECONDS
 870
 871 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 872 the specified number of downbytes.  If there is an error, returns the error,
 873 otherwise returns false.
 874
 875 =cut
 876
 877 sub increment_downbytes {
 878   _increment_column( shift, 'downbytes', @_);
 879 }
 880
 881 =item increment_totalbytes SECONDS
 882
 883 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 884 the specified number of totalbytes.  If there is an error, returns the error,
 885 otherwise returns false.
 886
 887 =cut
 888
 889 sub increment_totalbytes {
 890   _increment_column( shift, 'totalbytes', @_);
 891 }
 892
 893 =item increment_seconds SECONDS
 894
 895 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 896 the specified number of seconds.  If there is an error, returns the error,
 897 otherwise returns false.
 898
 899 =cut
 900
 901 sub increment_seconds {
 902   _increment_column( shift, 'seconds', @_);
 903 }
 904
 905 =item _increment_column AMOUNT
 906
 907 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 908 the specified number of seconds or bytes.  If there is an error, returns
 909 the error, otherwise returns false.
 910
 911 =cut
 912
 913 sub _increment_column {
 914   my( $self, $column, $amount ) = @_;
 915   warn "$me increment_column called: $column, $amount\n"
 916     if $DEBUG;
 917
 918   return '' unless $amount;
 919
 920   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
 921                       $self->ncancelled_pkgs;
 922
 923   if ( ! @cust_pkg ) {
 924     return 'No packages with primary or single services found'.
 925            ' to apply pre-paid time';
 926   } elsif ( scalar(@cust_pkg) > 1 ) {
 927     #maybe have a way to specify the package/account?
 928     return 'Multiple packages found to apply pre-paid time';
 929   }
 930
 931   my $cust_pkg = $cust_pkg[0];
 932   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
 933     if $DEBUG > 1;
 934
 935   my @cust_svc =
 936     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
 937
 938   if ( ! @cust_svc ) {
 939     return 'No account found to apply pre-paid time';
 940   } elsif ( scalar(@cust_svc) > 1 ) {
 941     return 'Multiple accounts found to apply pre-paid time';
 942   }
 943
 944   my $svc_acct = $cust_svc[0]->svc_x;
 945   warn "  found service svcnum ". $svc_acct->pkgnum.
 946        ' ('. $svc_acct->email. ")\n"
 947     if $DEBUG > 1;
 948
 949   $column = "increment_$column";
 950   $svc_acct->$column($amount);
 951
 952 }
 953
 954 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
 955
 956 Inserts a prepayment in the specified amount for this customer.  An optional
 957 second argument can specify the prepayment identifier for tracking purposes.
 958 If there is an error, returns the error, otherwise returns false.
 959
 960 =cut
 961
 962 sub insert_cust_pay_prepay {
 963   shift->insert_cust_pay('PREP', @_);
 964 }
 965
 966 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
 967
 968 Inserts a cash payment in the specified amount for this customer.  An optional
 969 second argument can specify the payment identifier for tracking purposes.
 970 If there is an error, returns the error, otherwise returns false.
 971
 972 =cut
 973
 974 sub insert_cust_pay_cash {
 975   shift->insert_cust_pay('CASH', @_);
 976 }
 977
 978 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
 979
 980 Inserts a Western Union payment in the specified amount for this customer.  An
 981 optional second argument can specify the prepayment identifier for tracking
 982 purposes.  If there is an error, returns the error, otherwise returns false.
 983
 984 =cut
 985
 986 sub insert_cust_pay_west {
 987   shift->insert_cust_pay('WEST', @_);
 988 }
 989
 990 sub insert_cust_pay {
 991   my( $self, $payby, $amount ) = splice(@_, 0, 3);
 992   my $payinfo = scalar(@_) ? shift : '';
 993
 994   my $cust_pay = new FS::cust_pay {
 995     'custnum' => $self->custnum,
 996     'paid'    => sprintf('%.2f', $amount),
 997     #'_date'   => #date the prepaid card was purchased???
 998     'payby'   => $payby,
 999     'payinfo' => $payinfo,
1000   };
1001   $cust_pay->insert;
1002
1003 }
1004
1005 =item delete [ OPTION => VALUE ... ]
1006
1007 This deletes the customer.  If there is an error, returns the error, otherwise
1008 returns false.
1009
1010 This will completely remove all traces of the customer record.  This is not
1011 what you want when a customer cancels service; for that, cancel all of the
1012 customer's packages (see L</cancel>).
1013
1014 If the customer has any uncancelled packages, you need to pass a new (valid)
1015 customer number for those packages to be transferred to, as the "new_customer"
1016 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1017 what you want when a customer cancels service and that you really should be
1018 looking at L<FS::cust_pkg/cancel>?
1019
1020 You can't delete a customer with invoices (see L<FS::cust_bill>),
1021 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1022 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1023 set the "delete_financials" option to a true value.
1024
1025 =cut
1026
1027 sub delete {
1028   my( $self, %opt ) = @_;
1029
1030   local $SIG{HUP} = 'IGNORE';
1031   local $SIG{INT} = 'IGNORE';
1032   local $SIG{QUIT} = 'IGNORE';
1033   local $SIG{TERM} = 'IGNORE';
1034   local $SIG{TSTP} = 'IGNORE';
1035   local $SIG{PIPE} = 'IGNORE';
1036
1037   my $oldAutoCommit = $FS::UID::AutoCommit;
1038   local $FS::UID::AutoCommit = 0;
1039   my $dbh = dbh;
1040
1041   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1042      $dbh->rollback if $oldAutoCommit;
1043      return "Can't delete a master agent customer";
1044   }
1045
1046   #use FS::access_user
1047   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1048      $dbh->rollback if $oldAutoCommit;
1049      return "Can't delete a master employee customer";
1050   }
1051
1052   tie my %financial_tables, 'Tie::IxHash',
1053     'cust_bill'      => 'invoices',
1054     'cust_statement' => 'statements',
1055     'cust_credit'    => 'credits',
1056     'cust_pay'       => 'payments',
1057     'cust_refund'    => 'refunds',
1058   ;
1059
1060   foreach my $table ( keys %financial_tables ) {
1061
1062     my @records = $self->$table();
1063
1064     if ( @records && ! $opt{'delete_financials'} ) {
1065       $dbh->rollback if $oldAutoCommit;
1066       return "Can't delete a customer with ". $financial_tables{$table};
1067     }
1068
1069     foreach my $record ( @records ) {
1070       my $error = $record->delete;
1071       if ( $error ) {
1072         $dbh->rollback if $oldAutoCommit;
1073         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1074       }
1075     }
1076
1077   }
1078
1079   my @cust_pkg = $self->ncancelled_pkgs;
1080   if ( @cust_pkg ) {
1081     my $new_custnum = $opt{'new_custnum'};
1082     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1083       $dbh->rollback if $oldAutoCommit;
1084       return "Invalid new customer number: $new_custnum";
1085     }
1086     foreach my $cust_pkg ( @cust_pkg ) {
1087       my %hash = $cust_pkg->hash;
1088       $hash{'custnum'} = $new_custnum;
1089       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1090       my $error = $new_cust_pkg->replace($cust_pkg,
1091                                          options => { $cust_pkg->options },
1092                                         );
1093       if ( $error ) {
1094         $dbh->rollback if $oldAutoCommit;
1095         return $error;
1096       }
1097     }
1098   }
1099   my @cancelled_cust_pkg = $self->all_pkgs;
1100   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1101     my $error = $cust_pkg->delete;
1102     if ( $error ) {
1103       $dbh->rollback if $oldAutoCommit;
1104       return $error;
1105     }
1106   }
1107
1108   #cust_tax_adjustment in financials?
1109   #cust_pay_pending?  ouch
1110   #cust_recon?
1111   foreach my $table (qw(
1112     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1113     cust_location cust_main_note cust_tax_adjustment
1114     cust_pay_void cust_pay_batch queue cust_tax_exempt
1115   )) {
1116     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1117       my $error = $record->delete;
1118       if ( $error ) {
1119         $dbh->rollback if $oldAutoCommit;
1120         return $error;
1121       }
1122     }
1123   }
1124
1125   my $sth = $dbh->prepare(
1126     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1127   ) or do {
1128     my $errstr = $dbh->errstr;
1129     $dbh->rollback if $oldAutoCommit;
1130     return $errstr;
1131   };
1132   $sth->execute($self->custnum) or do {
1133     my $errstr = $sth->errstr;
1134     $dbh->rollback if $oldAutoCommit;
1135     return $errstr;
1136   };
1137
1138   #tickets
1139
1140   my $ticket_dbh = '';
1141   if ($conf->config('ticket_system') eq 'RT_Internal') {
1142     $ticket_dbh = $dbh;
1143   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1144     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1145     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1146       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1147   }
1148
1149   if ( $ticket_dbh ) {
1150
1151     my $ticket_sth = $ticket_dbh->prepare(
1152       'DELETE FROM Links WHERE Target = ?'
1153     ) or do {
1154       my $errstr = $ticket_dbh->errstr;
1155       $dbh->rollback if $oldAutoCommit;
1156       return $errstr;
1157     };
1158     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1159       or do {
1160         my $errstr = $ticket_sth->errstr;
1161         $dbh->rollback if $oldAutoCommit;
1162         return $errstr;
1163       };
1164
1165     #check and see if the customer is the only link on the ticket, and
1166     #if so, set the ticket to deleted status in RT?
1167     #maybe someday, for now this will at least fix tickets not displaying
1168
1169   }
1170
1171   #delete the customer record
1172
1173   my $error = $self->SUPER::delete;
1174   if ( $error ) {
1175     $dbh->rollback if $oldAutoCommit;
1176     return $error;
1177   }
1178
1179   # cust_main exports!
1180
1181   #my $export_args = $options{'export_args'} || [];
1182
1183   my @part_export =
1184     map qsearch( 'part_export', {exportnum=>$_} ),
1185       $conf->config('cust_main-exports'); #, $agentnum
1186
1187   foreach my $part_export ( @part_export ) {
1188     my $error = $part_export->export_delete( $self ); #, @$export_args);
1189     if ( $error ) {
1190       $dbh->rollback if $oldAutoCommit;
1191       return "exporting to ". $part_export->exporttype.
1192              " (transaction rolled back): $error";
1193     }
1194   }
1195
1196   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1197   '';
1198
1199 }
1200
1201 =item merge NEW_CUSTNUM [ , OPTION => VALUE ... ]
1202
1203 This merges this customer into the provided new custnum, and then deletes the
1204 customer.  If there is an error, returns the error, otherwise returns false.
1205
1206 The source customer's name, company name, phone numbers, agent,
1207 referring customer, customer class, advertising source, order taker, and
1208 billing information (except balance) are discarded.
1209
1210 All packages are moved to the target customer.  Packages with package locations
1211 are preserved.  Packages without package locations are moved to a new package
1212 location with the source customer's service/shipping address.
1213
1214 All invoices, statements, payments, credits and refunds are moved to the target
1215 customer.  The source customer's balance is added to the target customer.
1216
1217 All notes, attachments, tickets and customer tags are moved to the target
1218 customer.
1219
1220 Change history is not currently moved.
1221
1222 =cut
1223
1224 sub merge {
1225   my( $self, $new_custnum, %opt ) = @_;
1226
1227   return "Can't merge a customer into self" if $self->custnum == $new_custnum;
1228
1229   my $new_cust_main = qsearchs( 'cust_main', { 'custnum' => $new_custnum } )
1230     or return "Invalid new customer number: $new_custnum";
1231
1232   return 'Access denied: "Merge customer across agents" access right required to merge into a customer of a different agent'
1233     if $self->agentnum != $new_cust_main->agentnum
1234     && ! $FS::CurrentUser::CurrentUser->access_right('Merge customer across agents');
1235
1236   local $SIG{HUP} = 'IGNORE';
1237   local $SIG{INT} = 'IGNORE';
1238   local $SIG{QUIT} = 'IGNORE';
1239   local $SIG{TERM} = 'IGNORE';
1240   local $SIG{TSTP} = 'IGNORE';
1241   local $SIG{PIPE} = 'IGNORE';
1242
1243   my $oldAutoCommit = $FS::UID::AutoCommit;
1244   local $FS::UID::AutoCommit = 0;
1245   my $dbh = dbh;
1246
1247   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1248      $dbh->rollback if $oldAutoCommit;
1249      return "Can't merge a master agent customer";
1250   }
1251
1252   #use FS::access_user
1253   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1254      $dbh->rollback if $oldAutoCommit;
1255      return "Can't merge a master employee customer";
1256   }
1257
1258   if ( qsearch('cust_pay_pending', { 'custnum' => $self->custnum,
1259                                      'status'  => { op=>'!=', value=>'done' },
1260                                    }
1261               )
1262   ) {
1263      $dbh->rollback if $oldAutoCommit;
1264      return "Can't merge a customer with pending payments";
1265   }
1266
1267   tie my %financial_tables, 'Tie::IxHash',
1268     'cust_bill'         => 'invoices',
1269     'cust_bill_void'    => 'voided invoices',
1270     'cust_statement'    => 'statements',
1271     'cust_credit'       => 'credits',
1272     'cust_credit_void'  => 'voided credits',
1273     'cust_pay'          => 'payments',
1274     'cust_pay_void'     => 'voided payments',
1275     'cust_refund'       => 'refunds',
1276   ;
1277
1278   foreach my $table ( keys %financial_tables ) {
1279
1280     my @records = $self->$table();
1281
1282     foreach my $record ( @records ) {
1283       $record->custnum($new_custnum);
1284       my $error = $record->replace;
1285       if ( $error ) {
1286         $dbh->rollback if $oldAutoCommit;
1287         return "Error merging ". $financial_tables{$table}. ": $error\n";
1288       }
1289     }
1290
1291   }
1292
1293   my $name = $self->ship_name; #?
1294
1295   my $locationnum = '';
1296   foreach my $cust_pkg ( $self->all_pkgs ) {
1297     $cust_pkg->custnum($new_custnum);
1298
1299     unless ( $cust_pkg->locationnum ) {
1300       unless ( $locationnum ) {
1301         my $cust_location = new FS::cust_location {
1302           $self->location_hash,
1303           'custnum' => $new_custnum,
1304         };
1305         my $error = $cust_location->insert;
1306         if ( $error ) {
1307           $dbh->rollback if $oldAutoCommit;
1308           return $error;
1309         }
1310         $locationnum = $cust_location->locationnum;
1311       }
1312       $cust_pkg->locationnum($locationnum);
1313     }
1314
1315     my $error = $cust_pkg->replace;
1316     if ( $error ) {
1317       $dbh->rollback if $oldAutoCommit;
1318       return $error;
1319     }
1320
1321     # add customer (ship) name to svc_phone.phone_name if blank
1322     my @cust_svc = $cust_pkg->cust_svc;
1323     foreach my $cust_svc (@cust_svc) {
1324       my($label, $value, $svcdb) = $cust_svc->label;
1325       next unless $svcdb eq 'svc_phone';
1326       my $svc_phone = $cust_svc->svc_x;
1327       next if $svc_phone->phone_name;
1328       $svc_phone->phone_name($name);
1329       my $error = $svc_phone->replace;
1330       if ( $error ) {
1331         $dbh->rollback if $oldAutoCommit;
1332         return $error;
1333       }
1334     }
1335
1336   }
1337
1338   #not considered:
1339   # cust_tax_exempt (texas tax exemptions)
1340   # cust_recon (some sort of not-well understood thing for OnPac)
1341
1342   #these are moved over
1343   foreach my $table (qw(
1344     cust_tag cust_location contact cust_attachment cust_main_note
1345     cust_tax_adjustment cust_pay_batch queue
1346   )) {
1347     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1348       $record->custnum($new_custnum);
1349       my $error = $record->replace;
1350       if ( $error ) {
1351         $dbh->rollback if $oldAutoCommit;
1352         return $error;
1353       }
1354     }
1355   }
1356
1357   #these aren't preserved
1358   foreach my $table (qw(
1359     cust_main_exemption cust_main_invoice
1360   )) {
1361     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1362       my $error = $record->delete;
1363       if ( $error ) {
1364         $dbh->rollback if $oldAutoCommit;
1365         return $error;
1366       }
1367     }
1368   }
1369
1370
1371   my $sth = $dbh->prepare(
1372     'UPDATE cust_main SET referral_custnum = ? WHERE referral_custnum = ?'
1373   ) or do {
1374     my $errstr = $dbh->errstr;
1375     $dbh->rollback if $oldAutoCommit;
1376     return $errstr;
1377   };
1378   $sth->execute($new_custnum, $self->custnum) or do {
1379     my $errstr = $sth->errstr;
1380     $dbh->rollback if $oldAutoCommit;
1381     return $errstr;
1382   };
1383
1384   #tickets
1385
1386   my $ticket_dbh = '';
1387   if ($conf->config('ticket_system') eq 'RT_Internal') {
1388     $ticket_dbh = $dbh;
1389   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1390     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1391     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1392       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1393   }
1394
1395   if ( $ticket_dbh ) {
1396
1397     my $ticket_sth = $ticket_dbh->prepare(
1398       'UPDATE Links SET Target = ? WHERE Target = ?'
1399     ) or do {
1400       my $errstr = $ticket_dbh->errstr;
1401       $dbh->rollback if $oldAutoCommit;
1402       return $errstr;
1403     };
1404     $ticket_sth->execute('freeside://freeside/cust_main/'.$new_custnum,
1405                          'freeside://freeside/cust_main/'.$self->custnum)
1406       or do {
1407         my $errstr = $ticket_sth->errstr;
1408         $dbh->rollback if $oldAutoCommit;
1409         return $errstr;
1410       };
1411
1412   }
1413
1414   #delete the customer record
1415
1416   my $error = $self->delete;
1417   if ( $error ) {
1418     $dbh->rollback if $oldAutoCommit;
1419     return $error;
1420   }
1421
1422   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1423   '';
1424
1425 }
1426
1427 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1428
1429 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1430 returns the error, otherwise returns false.
1431
1432 To change the customer's address, set the pseudo-fields C<bill_location> and
1433 C<ship_location>.  The address will still only change if at least one of the
1434 address fields differs from the existing values.
1435
1436 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
1437 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
1438 expected and rollback the entire transaction; it is not necessary to call
1439 check_invoicing_list first.  Here's an example:
1440
1441   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
1442
1443 Currently available options are: I<tax_exemption>.
1444
1445 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1446 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1447 deleted and inserted as appropriate.
1448
1449 =cut
1450
1451 sub replace {
1452   my $self = shift;
1453
1454   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1455               ? shift
1456               : $self->replace_old;
1457
1458   my @param = @_;
1459
1460   warn "$me replace called\n"
1461     if $DEBUG;
1462
1463   my $curuser = $FS::CurrentUser::CurrentUser;
1464   if (    $self->payby eq 'COMP'
1465        && $self->payby ne $old->payby
1466        && ! $curuser->access_right('Complimentary customer')
1467      )
1468   {
1469     return "You are not permitted to create complimentary accounts.";
1470   }
1471
1472   local($ignore_expired_card) = 1
1473     if $old->payby  =~ /^(CARD|DCRD)$/
1474     && $self->payby =~ /^(CARD|DCRD)$/
1475     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1476
1477   local($ignore_banned_card) = 1
1478     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1479          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1480     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1481
1482   return "Invoicing locale is required"
1483     if $old->locale
1484     && ! $self->locale
1485     && $conf->exists('cust_main-require_locale');
1486
1487   local $SIG{HUP} = 'IGNORE';
1488   local $SIG{INT} = 'IGNORE';
1489   local $SIG{QUIT} = 'IGNORE';
1490   local $SIG{TERM} = 'IGNORE';
1491   local $SIG{TSTP} = 'IGNORE';
1492   local $SIG{PIPE} = 'IGNORE';
1493
1494   my $oldAutoCommit = $FS::UID::AutoCommit;
1495   local $FS::UID::AutoCommit = 0;
1496   my $dbh = dbh;
1497
1498   for my $l (qw(bill_location ship_location)) {
1499     my $old_loc = $old->$l;
1500     my $new_loc = $self->$l;
1501
1502     # find the existing location if there is one
1503     $new_loc->set('custnum' => $self->custnum);
1504     my $error = $new_loc->find_or_insert;
1505     if ( $error ) {
1506       $dbh->rollback if $oldAutoCommit;
1507       return $error;
1508     }
1509     $self->set($l.'num', $new_loc->locationnum);
1510   } #for $l
1511
1512   # replace the customer record
1513   my $error = $self->SUPER::replace($old);
1514
1515   if ( $error ) {
1516     $dbh->rollback if $oldAutoCommit;
1517     return $error;
1518   }
1519
1520   # now move packages to the new service location
1521   $self->set('ship_location', ''); #flush cache
1522   if ( $old->ship_locationnum and # should only be null during upgrade...
1523        $old->ship_locationnum != $self->ship_locationnum ) {
1524     $error = $old->ship_location->move_to($self->ship_location);
1525     if ( $error ) {
1526       $dbh->rollback if $oldAutoCommit;
1527       return $error;
1528     }
1529   }
1530   # don't move packages based on the billing location, but
1531   # disable it if it's no longer in use
1532   if ( $old->bill_locationnum and
1533        $old->bill_locationnum != $self->bill_locationnum ) {
1534     $error = $old->bill_location->disable_if_unused;
1535     if ( $error ) {
1536       $dbh->rollback if $oldAutoCommit;
1537       return $error;
1538     }
1539   }
1540
1541   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1542     my $invoicing_list = shift @param;
1543     $error = $self->check_invoicing_list( $invoicing_list );
1544     if ( $error ) {
1545       $dbh->rollback if $oldAutoCommit;
1546       return $error;
1547     }
1548     $self->invoicing_list( $invoicing_list );
1549   }
1550
1551   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1552
1553     #this could be more efficient than deleting and re-inserting, if it matters
1554     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1555       my $error = $cust_tag->delete;
1556       if ( $error ) {
1557         $dbh->rollback if $oldAutoCommit;
1558         return $error;
1559       }
1560     }
1561     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1562       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1563                                         'custnum' => $self->custnum };
1564       my $error = $cust_tag->insert;
1565       if ( $error ) {
1566         $dbh->rollback if $oldAutoCommit;
1567         return $error;
1568       }
1569     }
1570
1571   }
1572
1573   my %options = @param;
1574
1575   my $tax_exemption = delete $options{'tax_exemption'};
1576   if ( $tax_exemption ) {
1577
1578     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1579       if ref($tax_exemption) eq 'ARRAY';
1580
1581     my %cust_main_exemption =
1582       map { $_->taxname => $_ }
1583           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1584
1585     foreach my $taxname ( keys %$tax_exemption ) {
1586
1587       if ( $cust_main_exemption{$taxname} &&
1588            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1589          )
1590       {
1591         delete $cust_main_exemption{$taxname};
1592         next;
1593       }
1594
1595       my $cust_main_exemption = new FS::cust_main_exemption {
1596         'custnum'       => $self->custnum,
1597         'taxname'       => $taxname,
1598         'exempt_number' => $tax_exemption->{$taxname},
1599       };
1600       my $error = $cust_main_exemption->insert;
1601       if ( $error ) {
1602         $dbh->rollback if $oldAutoCommit;
1603         return "inserting cust_main_exemption (transaction rolled back): $error";
1604       }
1605     }
1606
1607     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1608       my $error = $cust_main_exemption->delete;
1609       if ( $error ) {
1610         $dbh->rollback if $oldAutoCommit;
1611         return "deleting cust_main_exemption (transaction rolled back): $error";
1612       }
1613     }
1614
1615   }
1616
1617   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/
1618        && ( ( $self->get('payinfo') ne $old->get('payinfo')
1619               && $self->get('payinfo') !~ /^99\d{14}$/
1620             )
1621             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
1622           )
1623      )
1624   {
1625
1626     # card/check/lec info has changed, want to retry realtime_ invoice events
1627     my $error = $self->retry_realtime;
1628     if ( $error ) {
1629       $dbh->rollback if $oldAutoCommit;
1630       return $error;
1631     }
1632   }
1633
1634   unless ( $import || $skip_fuzzyfiles ) {
1635     $error = $self->queue_fuzzyfiles_update;
1636     if ( $error ) {
1637       $dbh->rollback if $oldAutoCommit;
1638       return "updating fuzzy search cache: $error";
1639     }
1640   }
1641
1642   # tax district update in cust_location
1643
1644   # cust_main exports!
1645
1646   my $export_args = $options{'export_args'} || [];
1647
1648   my @part_export =
1649     map qsearch( 'part_export', {exportnum=>$_} ),
1650       $conf->config('cust_main-exports'); #, $agentnum
1651
1652   foreach my $part_export ( @part_export ) {
1653     my $error = $part_export->export_replace( $self, $old, @$export_args);
1654     if ( $error ) {
1655       $dbh->rollback if $oldAutoCommit;
1656       return "exporting to ". $part_export->exporttype.
1657              " (transaction rolled back): $error";
1658     }
1659   }
1660
1661   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1662   '';
1663
1664 }
1665
1666 =item queue_fuzzyfiles_update
1667
1668 Used by insert & replace to update the fuzzy search cache
1669
1670 =cut
1671
1672 use FS::cust_main::Search;
1673 sub queue_fuzzyfiles_update {
1674   my $self = shift;
1675
1676   local $SIG{HUP} = 'IGNORE';
1677   local $SIG{INT} = 'IGNORE';
1678   local $SIG{QUIT} = 'IGNORE';
1679   local $SIG{TERM} = 'IGNORE';
1680   local $SIG{TSTP} = 'IGNORE';
1681   local $SIG{PIPE} = 'IGNORE';
1682
1683   my $oldAutoCommit = $FS::UID::AutoCommit;
1684   local $FS::UID::AutoCommit = 0;
1685   my $dbh = dbh;
1686
1687   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1688     my $queue = new FS::queue {
1689       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1690     };
1691     my @args = "cust_main.$field", $self->get($field);
1692     my $error = $queue->insert( @args );
1693     if ( $error ) {
1694       $dbh->rollback if $oldAutoCommit;
1695       return "queueing job (transaction rolled back): $error";
1696     }
1697   }
1698
1699   my @locations = ();
1700   push @locations, $self->bill_location if $self->bill_locationnum;
1701   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1702   foreach my $location (@locations) {
1703     my $queue = new FS::queue {
1704       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1705     };
1706     my @args = 'cust_location.address1', $location->address1;
1707     my $error = $queue->insert( @args );
1708     if ( $error ) {
1709       $dbh->rollback if $oldAutoCommit;
1710       return "queueing job (transaction rolled back): $error";
1711     }
1712   }
1713
1714   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1715   '';
1716
1717 }
1718
1719 =item check
1720
1721 Checks all fields to make sure this is a valid customer record.  If there is
1722 an error, returns the error, otherwise returns false.  Called by the insert
1723 and replace methods.
1724
1725 =cut
1726
1727 sub check {
1728   my $self = shift;
1729
1730   warn "$me check BEFORE: \n". $self->_dump
1731     if $DEBUG > 2;
1732
1733   my $error =
1734     $self->ut_numbern('custnum')
1735     || $self->ut_number('agentnum')
1736     || $self->ut_textn('agent_custid')
1737     || $self->ut_number('refnum')
1738     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1739     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1740     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1741     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1742     || $self->ut_textn('custbatch')
1743     || $self->ut_name('last')
1744     || $self->ut_name('first')
1745     || $self->ut_snumbern('signupdate')
1746     || $self->ut_snumbern('birthdate')
1747     || $self->ut_namen('spouse_last')
1748     || $self->ut_namen('spouse_first')
1749     || $self->ut_snumbern('spouse_birthdate')
1750     || $self->ut_snumbern('anniversary_date')
1751     || $self->ut_textn('company')
1752     || $self->ut_textn('ship_company')
1753     || $self->ut_anything('comments')
1754     || $self->ut_numbern('referral_custnum')
1755     || $self->ut_textn('stateid')
1756     || $self->ut_textn('stateid_state')
1757     || $self->ut_textn('invoice_terms')
1758     || $self->ut_floatn('cdr_termination_percentage')
1759     || $self->ut_floatn('credit_limit')
1760     || $self->ut_numbern('billday')
1761     || $self->ut_numbern('prorate_day')
1762     || $self->ut_flag('edit_subject')
1763     || $self->ut_flag('calling_list_exempt')
1764     || $self->ut_flag('invoice_noemail')
1765     || $self->ut_flag('message_noemail')
1766     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1767     || $self->ut_currencyn('currency')
1768   ;
1769
1770   foreach (qw(company ship_company)) {
1771     my $company = $self->get($_);
1772     $company =~ s/^\s+//;
1773     $company =~ s/\s+$//;
1774     $company =~ s/\s+/ /g;
1775     $self->set($_, $company);
1776   }
1777
1778   #barf.  need message catalogs.  i18n.  etc.
1779   $error .= "Please select an advertising source."
1780     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1781   return $error if $error;
1782
1783   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1784     or return "Unknown agent";
1785
1786   if ( $self->currency ) {
1787     my $agent_currency = qsearchs( 'agent_currency', {
1788       'agentnum' => $agent->agentnum,
1789       'currency' => $self->currency,
1790     })
1791       or return "Agent ". $agent->agent.
1792                 " not permitted to offer ".  $self->currency. " invoicing";
1793   }
1794
1795   return "Unknown refnum"
1796     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1797
1798   return "Unknown referring custnum: ". $self->referral_custnum
1799     unless ! $self->referral_custnum
1800            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1801
1802   if ( $self->ss eq '' ) {
1803     $self->ss('');
1804   } else {
1805     my $ss = $self->ss;
1806     $ss =~ s/\D//g;
1807     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1808       or return "Illegal social security number: ". $self->ss;
1809     $self->ss("$1-$2-$3");
1810   }
1811
1812   # cust_main_county verification now handled by cust_location check
1813
1814   $error =
1815        $self->ut_phonen('daytime', $self->country)
1816     || $self->ut_phonen('night',   $self->country)
1817     || $self->ut_phonen('fax',     $self->country)
1818     || $self->ut_phonen('mobile',  $self->country)
1819   ;
1820   return $error if $error;
1821
1822   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1823        && ! $import
1824        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1825      ) {
1826
1827     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1828                           ? 'Day Phone'
1829                           : FS::Msgcat::_gettext('daytime');
1830     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1831                         ? 'Night Phone'
1832                         : FS::Msgcat::_gettext('night');
1833
1834     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1835                         ? 'Mobile Phone'
1836                         : FS::Msgcat::_gettext('mobile');
1837
1838     return "$daytime_label, $night_label or $mobile_label is required"
1839
1840   }
1841
1842   ### start of stuff moved to cust_payby
1843   # then mostly kept here to support upgrades (can remove in 5.x)
1844   #  but modified to allow everything to be empty
1845
1846   if ( $self->payby ) {
1847     FS::payby->can_payby($self->table, $self->payby)
1848       or return "Illegal payby: ". $self->payby;
1849   } else {
1850     $self->payby('');
1851   }
1852
1853   $error =    $self->ut_numbern('paystart_month')
1854            || $self->ut_numbern('paystart_year')
1855            || $self->ut_numbern('payissue')
1856            || $self->ut_textn('paytype')
1857   ;
1858   return $error if $error;
1859
1860   if ( $self->payip eq '' ) {
1861     $self->payip('');
1862   } else {
1863     $error = $self->ut_ip('payip');
1864     return $error if $error;
1865   }
1866
1867   # If it is encrypted and the private key is not availaible then we can't
1868   # check the credit card.
1869   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1870
1871   # Need some kind of global flag to accept invalid cards, for testing
1872   # on scrubbed data.
1873   if ( !$import && !$ignore_invalid_card && $check_payinfo &&
1874     $self->payby =~ /^(CARD|DCRD)$/ ) {
1875
1876     my $payinfo = $self->payinfo;
1877     $payinfo =~ s/\D//g;
1878     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1879       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1880     $payinfo = $1;
1881     $self->payinfo($payinfo);
1882     validate($payinfo)
1883       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1884
1885     return gettext('unknown_card_type')
1886       if $self->payinfo !~ /^99\d{14}$/ #token
1887       && cardtype($self->payinfo) eq "Unknown";
1888
1889     unless ( $ignore_banned_card ) {
1890       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1891       if ( $ban ) {
1892         if ( $ban->bantype eq 'warn' ) {
1893           #or others depending on value of $ban->reason ?
1894           return '_duplicate_card'.
1895                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1896                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1897                  ' (ban# '. $ban->bannum. ')'
1898             unless $self->override_ban_warn;
1899         } else {
1900           return 'Banned credit card: banned on '.
1901                  time2str('%a %h %o at %r', $ban->_date).
1902                  ' by '. $ban->otaker.
1903                  ' (ban# '. $ban->bannum. ')';
1904         }
1905       }
1906     }
1907
1908     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1909       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1910         $self->paycvv =~ /^(\d{4})$/
1911           or return "CVV2 (CID) for American Express cards is four digits.";
1912         $self->paycvv($1);
1913       } else {
1914         $self->paycvv =~ /^(\d{3})$/
1915           or return "CVV2 (CVC2/CID) is three digits.";
1916         $self->paycvv($1);
1917       }
1918     } else {
1919       $self->paycvv('');
1920     }
1921
1922     my $cardtype = cardtype($payinfo);
1923     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1924
1925       return "Start date or issue number is required for $cardtype cards"
1926         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1927
1928       return "Start month must be between 1 and 12"
1929         if $self->paystart_month
1930            and $self->paystart_month < 1 || $self->paystart_month > 12;
1931
1932       return "Start year must be 1990 or later"
1933         if $self->paystart_year
1934            and $self->paystart_year < 1990;
1935
1936       return "Issue number must be beween 1 and 99"
1937         if $self->payissue
1938           and $self->payissue < 1 || $self->payissue > 99;
1939
1940     } else {
1941       $self->paystart_month('');
1942       $self->paystart_year('');
1943       $self->payissue('');
1944     }
1945
1946   } elsif ( !$ignore_invalid_card && $check_payinfo &&
1947     $self->payby =~ /^(CHEK|DCHK)$/ ) {
1948
1949     my $payinfo = $self->payinfo;
1950     $payinfo =~ s/[^\d\@\.]//g;
1951     if ( $conf->config('echeck-country') eq 'CA' ) {
1952       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1953         or return 'invalid echeck account@branch.bank';
1954       $payinfo = "$1\@$2.$3";
1955     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1956       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1957       $payinfo = "$1\@$2";
1958     } else {
1959       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1960       $payinfo = "$1\@$2";
1961     }
1962     $self->payinfo($payinfo);
1963     $self->paycvv('');
1964
1965     unless ( $ignore_banned_card ) {
1966       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1967       if ( $ban ) {
1968         if ( $ban->bantype eq 'warn' ) {
1969           #or others depending on value of $ban->reason ?
1970           return '_duplicate_ach' unless $self->override_ban_warn;
1971         } else {
1972           return 'Banned ACH account: banned on '.
1973                  time2str('%a %h %o at %r', $ban->_date).
1974                  ' by '. $ban->otaker.
1975                  ' (ban# '. $ban->bannum. ')';
1976         }
1977       }
1978     }
1979
1980   } elsif ( $self->payby eq 'LECB' ) {
1981
1982     my $payinfo = $self->payinfo;
1983     $payinfo =~ s/\D//g;
1984     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
1985     $payinfo = $1;
1986     $self->payinfo($payinfo);
1987     $self->paycvv('');
1988
1989   } elsif ( $self->payby eq 'BILL' ) {
1990
1991     $error = $self->ut_textn('payinfo');
1992     return "Illegal P.O. number: ". $self->payinfo if $error;
1993     $self->paycvv('');
1994
1995   } elsif ( $self->payby eq 'COMP' ) {
1996
1997     my $curuser = $FS::CurrentUser::CurrentUser;
1998     if (    ! $self->custnum
1999          && ! $curuser->access_right('Complimentary customer')
2000        )
2001     {
2002       return "You are not permitted to create complimentary accounts."
2003     }
2004
2005     $error = $self->ut_textn('payinfo');
2006     return "Illegal comp account issuer: ". $self->payinfo if $error;
2007     $self->paycvv('');
2008
2009   } elsif ( $self->payby eq 'PREPAY' ) {
2010
2011     my $payinfo = $self->payinfo;
2012     $payinfo =~ s/\W//g; #anything else would just confuse things
2013     $self->payinfo($payinfo);
2014     $error = $self->ut_alpha('payinfo');
2015     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2016     return "Unknown prepayment identifier"
2017       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2018     $self->paycvv('');
2019
2020   }
2021
2022   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2023     return "Expiration date required"
2024       # shouldn't payinfo_check do this?
2025       unless ! $self->payby
2026             || $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD|PPAL)$/;
2027     $self->paydate('');
2028   } else {
2029     my( $m, $y );
2030     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2031       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2032     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2033       ( $m, $y ) = ( $2, "19$1" );
2034     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2035       ( $m, $y ) = ( $3, "20$2" );
2036     } else {
2037       return "Illegal expiration date: ". $self->paydate;
2038     }
2039     $m = sprintf('%02d',$m);
2040     $self->paydate("$y-$m-01");
2041     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2042     return gettext('expired_card')
2043       if !$import
2044       && !$ignore_expired_card
2045       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2046   }
2047
2048   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2049        ( ! $conf->exists('require_cardname')
2050          || $self->payby !~ /^(CARD|DCRD)$/  )
2051   ) {
2052     $self->payname( $self->first. " ". $self->getfield('last') );
2053   } else {
2054
2055     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2056       $self->payname =~ /^([\w \,\.\-\']*)$/
2057         or return gettext('illegal_name'). " payname: ". $self->payname;
2058       $self->payname($1);
2059     } else {
2060       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
2061         or return gettext('illegal_name'). " payname: ". $self->payname;
2062       $self->payname($1);
2063     }
2064
2065   }
2066
2067   ### end of stuff moved to cust_payby
2068
2069   return "Please select an invoicing locale"
2070     if ! $self->locale
2071     && ! $self->custnum
2072     && $conf->exists('cust_main-require_locale');
2073
2074   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2075     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2076     $self->$flag($1);
2077   }
2078
2079   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2080
2081   warn "$me check AFTER: \n". $self->_dump
2082     if $DEBUG > 2;
2083
2084   $self->SUPER::check;
2085 }
2086
2087 =item addr_fields
2088
2089 Returns a list of fields which have ship_ duplicates.
2090
2091 =cut
2092
2093 sub addr_fields {
2094   qw( last first company
2095       address1 address2 city county state zip country
2096       latitude longitude
2097       daytime night fax mobile
2098     );
2099 }
2100
2101 =item has_ship_address
2102
2103 Returns true if this customer record has a separate shipping address.
2104
2105 =cut
2106
2107 sub has_ship_address {
2108   my $self = shift;
2109   $self->bill_locationnum != $self->ship_locationnum;
2110 }
2111
2112 =item location_hash
2113
2114 Returns a list of key/value pairs, with the following keys: address1,
2115 adddress2, city, county, state, zip, country, district, and geocode.  The
2116 shipping address is used if present.
2117
2118 =cut
2119
2120 sub location_hash {
2121   my $self = shift;
2122   $self->ship_location->location_hash;
2123 }
2124
2125 =item cust_location
2126
2127 Returns all locations (see L<FS::cust_location>) for this customer.
2128
2129 =cut
2130
2131 sub cust_location {
2132   my $self = shift;
2133   qsearch('cust_location', { 'custnum'     => $self->custnum,
2134                              'prospectnum' => '' } );
2135 }
2136
2137 =item cust_contact
2138
2139 Returns all contacts (see L<FS::contact>) for this customer.
2140
2141 =cut
2142
2143 #already used :/ sub contact {
2144 sub cust_contact {
2145   my $self = shift;
2146   qsearch('contact', { 'custnum' => $self->custnum } );
2147 }
2148
2149 =item cust_payby
2150
2151 Returns all payment methods (see L<FS::cust_payby>) for this customer.
2152
2153 =cut
2154
2155 sub cust_payby {
2156   my $self = shift;
2157   qsearch({
2158     'table'    => 'cust_payby',
2159     'hashref'  => { 'custnum' => $self->custnum },
2160     'order_by' => 'ORDER BY weight ASC',
2161   });
2162 }
2163
2164 =item unsuspend
2165
2166 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2167 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
2168 on success or a list of errors.
2169
2170 =cut
2171
2172 sub unsuspend {
2173   my $self = shift;
2174   grep { $_->unsuspend } $self->suspended_pkgs;
2175 }
2176
2177 =item suspend
2178
2179 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2180
2181 Returns a list: an empty list on success or a list of errors.
2182
2183 =cut
2184
2185 sub suspend {
2186   my $self = shift;
2187   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2188 }
2189
2190 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2191
2192 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2193 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2194 of a list of pkgparts; the hashref has the following keys:
2195
2196 =over 4
2197
2198 =item pkgparts - listref of pkgparts
2199
2200 =item (other options are passed to the suspend method)
2201
2202 =back
2203
2204
2205 Returns a list: an empty list on success or a list of errors.
2206
2207 =cut
2208
2209 sub suspend_if_pkgpart {
2210   my $self = shift;
2211   my (@pkgparts, %opt);
2212   if (ref($_[0]) eq 'HASH'){
2213     @pkgparts = @{$_[0]{pkgparts}};
2214     %opt      = %{$_[0]};
2215   }else{
2216     @pkgparts = @_;
2217   }
2218   grep { $_->suspend(%opt) }
2219     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2220       $self->unsuspended_pkgs;
2221 }
2222
2223 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2224
2225 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2226 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2227 instead of a list of pkgparts; the hashref has the following keys:
2228
2229 =over 4
2230
2231 =item pkgparts - listref of pkgparts
2232
2233 =item (other options are passed to the suspend method)
2234
2235 =back
2236
2237 Returns a list: an empty list on success or a list of errors.
2238
2239 =cut
2240
2241 sub suspend_unless_pkgpart {
2242   my $self = shift;
2243   my (@pkgparts, %opt);
2244   if (ref($_[0]) eq 'HASH'){
2245     @pkgparts = @{$_[0]{pkgparts}};
2246     %opt      = %{$_[0]};
2247   }else{
2248     @pkgparts = @_;
2249   }
2250   grep { $_->suspend(%opt) }
2251     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2252       $self->unsuspended_pkgs;
2253 }
2254
2255 =item cancel [ OPTION => VALUE ... ]
2256
2257 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2258
2259 Available options are:
2260
2261 =over 4
2262
2263 =item quiet - can be set true to supress email cancellation notices.
2264
2265 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2266
2267 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2268
2269 =item nobill - can be set true to skip billing if it might otherwise be done.
2270
2271 =back
2272
2273 Always returns a list: an empty list on success or a list of errors.
2274
2275 =cut
2276
2277 # nb that dates are not specified as valid options to this method
2278
2279 sub cancel {
2280   my( $self, %opt ) = @_;
2281
2282   warn "$me cancel called on customer ". $self->custnum. " with options ".
2283        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2284     if $DEBUG;
2285
2286   return ( 'access denied' )
2287     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2288
2289   if ( $opt{'ban'} && $self->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/ ) {
2290
2291     #should try decryption (we might have the private key)
2292     # and if not maybe queue a job for the server that does?
2293     return ( "Can't (yet) ban encrypted credit cards" )
2294       if $self->is_encrypted($self->payinfo);
2295
2296     my $ban = new FS::banned_pay $self->_new_banned_pay_hashref;
2297     my $error = $ban->insert;
2298     return ( $error ) if $error;
2299
2300   }
2301
2302   my @pkgs = $self->ncancelled_pkgs;
2303
2304   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2305     $opt{nobill} = 1;
2306     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2307     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2308       if $error;
2309   }
2310
2311   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2312        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2313     if $DEBUG;
2314
2315   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2316 }
2317
2318 sub _banned_pay_hashref {
2319   my $self = shift;
2320
2321   my %payby2ban = (
2322     'CARD' => 'CARD',
2323     'DCRD' => 'CARD',
2324     'CHEK' => 'CHEK',
2325     'DCHK' => 'CHEK'
2326   );
2327
2328   {
2329     'payby'   => $payby2ban{$self->payby},
2330     'payinfo' => $self->payinfo,
2331     #don't ever *search* on reason! #'reason'  =>
2332   };
2333 }
2334
2335 sub _new_banned_pay_hashref {
2336   my $self = shift;
2337   my $hr = $self->_banned_pay_hashref;
2338   $hr->{payinfo} = md5_base64($hr->{payinfo});
2339   $hr;
2340 }
2341
2342 =item notes
2343
2344 Returns all notes (see L<FS::cust_main_note>) for this customer.
2345
2346 =cut
2347
2348 sub notes {
2349   my($self,$orderby_classnum) = (shift,shift);
2350   my $orderby = "_DATE DESC";
2351   $orderby = "CLASSNUM ASC, $orderby" if $orderby_classnum;
2352   qsearch( 'cust_main_note',
2353            { 'custnum' => $self->custnum },
2354            '',
2355            "ORDER BY $orderby",
2356          );
2357 }
2358
2359 =item agent
2360
2361 Returns the agent (see L<FS::agent>) for this customer.
2362
2363 =item agent_name
2364
2365 Returns the agent name (see L<FS::agent>) for this customer.
2366
2367 =cut
2368
2369 sub agent_name {
2370   my $self = shift;
2371   $self->agent->agent;
2372 }
2373
2374 =item cust_tag
2375
2376 Returns any tags associated with this customer, as FS::cust_tag objects,
2377 or an empty list if there are no tags.
2378
2379 =item part_tag
2380
2381 Returns any tags associated with this customer, as FS::part_tag objects,
2382 or an empty list if there are no tags.
2383
2384 =cut
2385
2386 sub part_tag {
2387   my $self = shift;
2388   map $_->part_tag, $self->cust_tag;
2389 }
2390
2391
2392 =item cust_class
2393
2394 Returns the customer class, as an FS::cust_class object, or the empty string
2395 if there is no customer class.
2396
2397 =item categoryname
2398
2399 Returns the customer category name, or the empty string if there is no customer
2400 category.
2401
2402 =cut
2403
2404 sub categoryname {
2405   my $self = shift;
2406   my $cust_class = $self->cust_class;
2407   $cust_class
2408     ? $cust_class->categoryname
2409     : '';
2410 }
2411
2412 =item classname
2413
2414 Returns the customer class name, or the empty string if there is no customer
2415 class.
2416
2417 =cut
2418
2419 sub classname {
2420   my $self = shift;
2421   my $cust_class = $self->cust_class;
2422   $cust_class
2423     ? $cust_class->classname
2424     : '';
2425 }
2426
2427 =item BILLING METHODS
2428
2429 Documentation on billing methods has been moved to
2430 L<FS::cust_main::Billing>.
2431
2432 =item REALTIME BILLING METHODS
2433
2434 Documentation on realtime billing methods has been moved to
2435 L<FS::cust_main::Billing_Realtime>.
2436
2437 =item remove_cvv
2438
2439 Removes the I<paycvv> field from the database directly.
2440
2441 If there is an error, returns the error, otherwise returns false.
2442
2443 =cut
2444
2445 sub remove_cvv {
2446   my $self = shift;
2447   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2448     or return dbh->errstr;
2449   $sth->execute($self->custnum)
2450     or return $sth->errstr;
2451   $self->paycvv('');
2452   '';
2453 }
2454
2455 =item batch_card OPTION => VALUE...
2456
2457 Adds a payment for this invoice to the pending credit card batch (see
2458 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
2459 runs the payment using a realtime gateway.
2460
2461 Options may include:
2462
2463 B<amount>: the amount to be paid; defaults to the customer's balance minus
2464 any payments in transit.
2465
2466 B<payby>: the payment method; defaults to cust_main.payby
2467
2468 B<realtime>: runs this as a realtime payment instead of adding it to a
2469 batch.  Deprecated.
2470
2471 B<invnum>: sets cust_pay_batch.invnum.
2472
2473 B<address1>, B<address2>, B<city>, B<state>, B<zip>, B<country>: sets
2474 the billing address for the payment; defaults to the customer's billing
2475 location.
2476
2477 B<payinfo>, B<paydate>, B<payname>: sets the payment account, expiration
2478 date, and name; defaults to those fields in cust_main.
2479
2480 =cut
2481
2482 sub batch_card {
2483   my ($self, %options) = @_;
2484
2485   my $amount;
2486   if (exists($options{amount})) {
2487     $amount = $options{amount};
2488   }else{
2489     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
2490   }
2491   return '' unless $amount > 0;
2492
2493   my $invnum = delete $options{invnum};
2494   my $payby = $options{payby} || $self->payby;  #still dubious
2495
2496   if ($options{'realtime'}) {
2497     return $self->realtime_bop( FS::payby->payby2bop($self->payby),
2498                                 $amount,
2499                                 %options,
2500                               );
2501   }
2502
2503   my $oldAutoCommit = $FS::UID::AutoCommit;
2504   local $FS::UID::AutoCommit = 0;
2505   my $dbh = dbh;
2506
2507   #this needs to handle mysql as well as Pg, like svc_acct.pm
2508   #(make it into a common function if folks need to do batching with mysql)
2509   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
2510     or return "Cannot lock pay_batch: " . $dbh->errstr;
2511
2512   my %pay_batch = (
2513     'status' => 'O',
2514     'payby'  => FS::payby->payby2payment($payby),
2515   );
2516   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
2517
2518   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
2519
2520   unless ( $pay_batch ) {
2521     $pay_batch = new FS::pay_batch \%pay_batch;
2522     my $error = $pay_batch->insert;
2523     if ( $error ) {
2524       $dbh->rollback if $oldAutoCommit;
2525       die "error creating new batch: $error\n";
2526     }
2527   }
2528
2529   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
2530       'batchnum' => $pay_batch->batchnum,
2531       'custnum'  => $self->custnum,
2532   } );
2533
2534   foreach (qw( address1 address2 city state zip country latitude longitude
2535                payby payinfo paydate payname ))
2536   {
2537     $options{$_} = '' unless exists($options{$_});
2538   }
2539
2540   my $loc = $self->bill_location;
2541
2542   my $cust_pay_batch = new FS::cust_pay_batch ( {
2543     'batchnum' => $pay_batch->batchnum,
2544     'invnum'   => $invnum || 0,                    # is there a better value?
2545                                                    # this field should be
2546                                                    # removed...
2547                                                    # cust_bill_pay_batch now
2548     'custnum'  => $self->custnum,
2549     'last'     => $self->getfield('last'),
2550     'first'    => $self->getfield('first'),
2551     'address1' => $options{address1} || $loc->address1,
2552     'address2' => $options{address2} || $loc->address2,
2553     'city'     => $options{city}     || $loc->city,
2554     'state'    => $options{state}    || $loc->state,
2555     'zip'      => $options{zip}      || $loc->zip,
2556     'country'  => $options{country}  || $loc->country,
2557     'payby'    => $options{payby}    || $self->payby,
2558     'payinfo'  => $options{payinfo}  || $self->payinfo,
2559     'exp'      => $options{paydate}  || $self->paydate,
2560     'payname'  => $options{payname}  || $self->payname,
2561     'amount'   => $amount,                         # consolidating
2562   } );
2563
2564   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
2565     if $old_cust_pay_batch;
2566
2567   my $error;
2568   if ($old_cust_pay_batch) {
2569     $error = $cust_pay_batch->replace($old_cust_pay_batch)
2570   } else {
2571     $error = $cust_pay_batch->insert;
2572   }
2573
2574   if ( $error ) {
2575     $dbh->rollback if $oldAutoCommit;
2576     die $error;
2577   }
2578
2579   my $unapplied =   $self->total_unapplied_credits
2580                   + $self->total_unapplied_payments
2581                   + $self->in_transit_payments;
2582   foreach my $cust_bill ($self->open_cust_bill) {
2583     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
2584     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
2585       'invnum' => $cust_bill->invnum,
2586       'paybatchnum' => $cust_pay_batch->paybatchnum,
2587       'amount' => $cust_bill->owed,
2588       '_date' => time,
2589     };
2590     if ($unapplied >= $cust_bill_pay_batch->amount){
2591       $unapplied -= $cust_bill_pay_batch->amount;
2592       next;
2593     }else{
2594       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
2595                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
2596     }
2597     $error = $cust_bill_pay_batch->insert;
2598     if ( $error ) {
2599       $dbh->rollback if $oldAutoCommit;
2600       die $error;
2601     }
2602   }
2603
2604   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2605   '';
2606 }
2607
2608 =item total_owed
2609
2610 Returns the total owed for this customer on all invoices
2611 (see L<FS::cust_bill/owed>).
2612
2613 =cut
2614
2615 sub total_owed {
2616   my $self = shift;
2617   $self->total_owed_date(2145859200); #12/31/2037
2618 }
2619
2620 =item total_owed_date TIME
2621
2622 Returns the total owed for this customer on all invoices with date earlier than
2623 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2624 see L<Time::Local> and L<Date::Parse> for conversion functions.
2625
2626 =cut
2627
2628 sub total_owed_date {
2629   my $self = shift;
2630   my $time = shift;
2631
2632   my $custnum = $self->custnum;
2633
2634   my $owed_sql = FS::cust_bill->owed_sql;
2635
2636   my $sql = "
2637     SELECT SUM($owed_sql) FROM cust_bill
2638       WHERE custnum = $custnum
2639         AND _date <= $time
2640   ";
2641
2642   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2643
2644 }
2645
2646 =item total_owed_pkgnum PKGNUM
2647
2648 Returns the total owed on all invoices for this customer's specific package
2649 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2650
2651 =cut
2652
2653 sub total_owed_pkgnum {
2654   my( $self, $pkgnum ) = @_;
2655   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2656 }
2657
2658 =item total_owed_date_pkgnum TIME PKGNUM
2659
2660 Returns the total owed for this customer's specific package when using
2661 experimental package balances on all invoices with date earlier than
2662 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2663 see L<Time::Local> and L<Date::Parse> for conversion functions.
2664
2665 =cut
2666
2667 sub total_owed_date_pkgnum {
2668   my( $self, $time, $pkgnum ) = @_;
2669
2670   my $total_bill = 0;
2671   foreach my $cust_bill (
2672     grep { $_->_date <= $time }
2673       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2674   ) {
2675     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2676   }
2677   sprintf( "%.2f", $total_bill );
2678
2679 }
2680
2681 =item total_paid
2682
2683 Returns the total amount of all payments.
2684
2685 =cut
2686
2687 sub total_paid {
2688   my $self = shift;
2689   my $total = 0;
2690   $total += $_->paid foreach $self->cust_pay;
2691   sprintf( "%.2f", $total );
2692 }
2693
2694 =item total_unapplied_credits
2695
2696 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2697 customer.  See L<FS::cust_credit/credited>.
2698
2699 =item total_credited
2700
2701 Old name for total_unapplied_credits.  Don't use.
2702
2703 =cut
2704
2705 sub total_credited {
2706   #carp "total_credited deprecated, use total_unapplied_credits";
2707   shift->total_unapplied_credits(@_);
2708 }
2709
2710 sub total_unapplied_credits {
2711   my $self = shift;
2712
2713   my $custnum = $self->custnum;
2714
2715   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2716
2717   my $sql = "
2718     SELECT SUM($unapplied_sql) FROM cust_credit
2719       WHERE custnum = $custnum
2720   ";
2721
2722   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2723
2724 }
2725
2726 =item total_unapplied_credits_pkgnum PKGNUM
2727
2728 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2729 customer.  See L<FS::cust_credit/credited>.
2730
2731 =cut
2732
2733 sub total_unapplied_credits_pkgnum {
2734   my( $self, $pkgnum ) = @_;
2735   my $total_credit = 0;
2736   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2737   sprintf( "%.2f", $total_credit );
2738 }
2739
2740
2741 =item total_unapplied_payments
2742
2743 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2744 See L<FS::cust_pay/unapplied>.
2745
2746 =cut
2747
2748 sub total_unapplied_payments {
2749   my $self = shift;
2750
2751   my $custnum = $self->custnum;
2752
2753   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2754
2755   my $sql = "
2756     SELECT SUM($unapplied_sql) FROM cust_pay
2757       WHERE custnum = $custnum
2758   ";
2759
2760   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2761
2762 }
2763
2764 =item total_unapplied_payments_pkgnum PKGNUM
2765
2766 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2767 specific package when using experimental package balances.  See
2768 L<FS::cust_pay/unapplied>.
2769
2770 =cut
2771
2772 sub total_unapplied_payments_pkgnum {
2773   my( $self, $pkgnum ) = @_;
2774   my $total_unapplied = 0;
2775   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2776   sprintf( "%.2f", $total_unapplied );
2777 }
2778
2779
2780 =item total_unapplied_refunds
2781
2782 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2783 customer.  See L<FS::cust_refund/unapplied>.
2784
2785 =cut
2786
2787 sub total_unapplied_refunds {
2788   my $self = shift;
2789   my $custnum = $self->custnum;
2790
2791   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2792
2793   my $sql = "
2794     SELECT SUM($unapplied_sql) FROM cust_refund
2795       WHERE custnum = $custnum
2796   ";
2797
2798   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2799
2800 }
2801
2802 =item balance
2803
2804 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2805 total_unapplied_credits minus total_unapplied_payments).
2806
2807 =cut
2808
2809 sub balance {
2810   my $self = shift;
2811   $self->balance_date_range;
2812 }
2813
2814 =item balance_date TIME
2815
2816 Returns the balance for this customer, only considering invoices with date
2817 earlier than TIME (total_owed_date minus total_credited minus
2818 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2819 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2820 functions.
2821
2822 =cut
2823
2824 sub balance_date {
2825   my $self = shift;
2826   $self->balance_date_range(shift);
2827 }
2828
2829 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2830
2831 Returns the balance for this customer, optionally considering invoices with
2832 date earlier than START_TIME, and not later than END_TIME
2833 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2834
2835 Times are specified as SQL fragments or numeric
2836 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2837 L<Date::Parse> for conversion functions.  The empty string can be passed
2838 to disable that time constraint completely.
2839
2840 Available options are:
2841
2842 =over 4
2843
2844 =item unapplied_date
2845
2846 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2847
2848 =back
2849
2850 =cut
2851
2852 sub balance_date_range {
2853   my $self = shift;
2854   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2855             ') FROM cust_main WHERE custnum='. $self->custnum;
2856   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2857 }
2858
2859 =item balance_pkgnum PKGNUM
2860
2861 Returns the balance for this customer's specific package when using
2862 experimental package balances (total_owed plus total_unrefunded, minus
2863 total_unapplied_credits minus total_unapplied_payments)
2864
2865 =cut
2866
2867 sub balance_pkgnum {
2868   my( $self, $pkgnum ) = @_;
2869
2870   sprintf( "%.2f",
2871       $self->total_owed_pkgnum($pkgnum)
2872 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2873 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2874     - $self->total_unapplied_credits_pkgnum($pkgnum)
2875     - $self->total_unapplied_payments_pkgnum($pkgnum)
2876   );
2877 }
2878
2879 =item in_transit_payments
2880
2881 Returns the total of requests for payments for this customer pending in
2882 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
2883
2884 =cut
2885
2886 sub in_transit_payments {
2887   my $self = shift;
2888   my $in_transit_payments = 0;
2889   foreach my $pay_batch ( qsearch('pay_batch', {
2890     'status' => 'I',
2891   } ) ) {
2892     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
2893       'batchnum' => $pay_batch->batchnum,
2894       'custnum' => $self->custnum,
2895     } ) ) {
2896       $in_transit_payments += $cust_pay_batch->amount;
2897     }
2898   }
2899   sprintf( "%.2f", $in_transit_payments );
2900 }
2901
2902 =item payment_info
2903
2904 Returns a hash of useful information for making a payment.
2905
2906 =over 4
2907
2908 =item balance
2909
2910 Current balance.
2911
2912 =item payby
2913
2914 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2915 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2916 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2917
2918 =back
2919
2920 For credit card transactions:
2921
2922 =over 4
2923
2924 =item card_type 1
2925
2926 =item payname
2927
2928 Exact name on card
2929
2930 =back
2931
2932 For electronic check transactions:
2933
2934 =over 4
2935
2936 =item stateid_state
2937
2938 =back
2939
2940 =cut
2941
2942 sub payment_info {
2943   my $self = shift;
2944
2945   my %return = ();
2946
2947   $return{balance} = $self->balance;
2948
2949   $return{payname} = $self->payname
2950                      || ( $self->first. ' '. $self->get('last') );
2951
2952   $return{$_} = $self->bill_location->$_
2953     for qw(address1 address2 city state zip);
2954
2955   $return{payby} = $self->payby;
2956   $return{stateid_state} = $self->stateid_state;
2957
2958   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2959     $return{card_type} = cardtype($self->payinfo);
2960     $return{payinfo} = $self->paymask;
2961
2962     @return{'month', 'year'} = $self->paydate_monthyear;
2963
2964   }
2965
2966   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2967     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2968     $return{payinfo1} = $payinfo1;
2969     $return{payinfo2} = $payinfo2;
2970     $return{paytype}  = $self->paytype;
2971     $return{paystate} = $self->paystate;
2972
2973   }
2974
2975   #doubleclick protection
2976   my $_date = time;
2977   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2978
2979   %return;
2980
2981 }
2982
2983 =item paydate_monthyear
2984
2985 Returns a two-element list consisting of the month and year of this customer's
2986 paydate (credit card expiration date for CARD customers)
2987
2988 =cut
2989
2990 sub paydate_monthyear {
2991   my $self = shift;
2992   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
2993     ( $2, $1 );
2994   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
2995     ( $1, $3 );
2996   } else {
2997     ('', '');
2998   }
2999 }
3000
3001 =item paydate_epoch
3002
3003 Returns the exact time in seconds corresponding to the payment method
3004 expiration date.  For CARD/DCRD customers this is the end of the month;
3005 for others (COMP is the only other payby that uses paydate) it's the start.
3006 Returns 0 if the paydate is empty or set to the far future.
3007
3008 =cut
3009
3010 sub paydate_epoch {
3011   my $self = shift;
3012   my ($month, $year) = $self->paydate_monthyear;
3013   return 0 if !$year or $year >= 2037;
3014   if ( $self->payby eq 'CARD' or $self->payby eq 'DCRD' ) {
3015     $month++;
3016     if ( $month == 13 ) {
3017       $month = 1;
3018       $year++;
3019     }
3020     return timelocal(0,0,0,1,$month-1,$year) - 1;
3021   }
3022   else {
3023     return timelocal(0,0,0,1,$month-1,$year);
3024   }
3025 }
3026
3027 =item paydate_epoch_sql
3028
3029 Class method.  Returns an SQL expression to obtain the payment expiration date
3030 as a number of seconds.
3031
3032 =cut
3033
3034 # Special expiration date behavior for non-CARD/DCRD customers has been
3035 # carefully preserved.  Do we really use that?
3036 sub paydate_epoch_sql {
3037   my $class = shift;
3038   my $table = shift || 'cust_main';
3039   my ($case1, $case2);
3040   if ( driver_name eq 'Pg' ) {
3041     $case1 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) + INTERVAL '1 month') - 1";
3042     $case2 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) )";
3043   }
3044   elsif ( lc(driver_name) eq 'mysql' ) {
3045     $case1 = "UNIX_TIMESTAMP( DATE_ADD( CAST( $table.paydate AS DATETIME ), INTERVAL 1 month ) ) - 1";
3046     $case2 = "UNIX_TIMESTAMP( CAST( $table.paydate AS DATETIME ) )";
3047   }
3048   else { return '' }
3049   return "CASE WHEN $table.payby IN('CARD','DCRD')
3050   THEN ($case1)
3051   ELSE ($case2)
3052   END"
3053 }
3054
3055 =item tax_exemption TAXNAME
3056
3057 =cut
3058
3059 sub tax_exemption {
3060   my( $self, $taxname ) = @_;
3061
3062   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3063                                      'taxname' => $taxname,
3064                                    },
3065           );
3066 }
3067
3068 =item cust_main_exemption
3069
3070 =item invoicing_list [ ARRAYREF ]
3071
3072 If an arguement is given, sets these email addresses as invoice recipients
3073 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
3074 (except as warnings), so use check_invoicing_list first.
3075
3076 Returns a list of email addresses (with svcnum entries expanded).
3077
3078 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
3079 check it without disturbing anything by passing nothing.
3080
3081 This interface may change in the future.
3082
3083 =cut
3084
3085 sub invoicing_list {
3086   my( $self, $arrayref ) = @_;
3087
3088   if ( $arrayref ) {
3089     my @cust_main_invoice;
3090     if ( $self->custnum ) {
3091       @cust_main_invoice =
3092         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3093     } else {
3094       @cust_main_invoice = ();
3095     }
3096     foreach my $cust_main_invoice ( @cust_main_invoice ) {
3097       #warn $cust_main_invoice->destnum;
3098       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
3099         #warn $cust_main_invoice->destnum;
3100         my $error = $cust_main_invoice->delete;
3101         warn $error if $error;
3102       }
3103     }
3104     if ( $self->custnum ) {
3105       @cust_main_invoice =
3106         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3107     } else {
3108       @cust_main_invoice = ();
3109     }
3110     my %seen = map { $_->address => 1 } @cust_main_invoice;
3111     foreach my $address ( @{$arrayref} ) {
3112       next if exists $seen{$address} && $seen{$address};
3113       $seen{$address} = 1;
3114       my $cust_main_invoice = new FS::cust_main_invoice ( {
3115         'custnum' => $self->custnum,
3116         'dest'    => $address,
3117       } );
3118       my $error = $cust_main_invoice->insert;
3119       warn $error if $error;
3120     }
3121   }
3122
3123   if ( $self->custnum ) {
3124     map { $_->address }
3125       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3126   } else {
3127     ();
3128   }
3129
3130 }
3131
3132 =item check_invoicing_list ARRAYREF
3133
3134 Checks these arguements as valid input for the invoicing_list method.  If there
3135 is an error, returns the error, otherwise returns false.
3136
3137 =cut
3138
3139 sub check_invoicing_list {
3140   my( $self, $arrayref ) = @_;
3141
3142   foreach my $address ( @$arrayref ) {
3143
3144     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3145       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3146     }
3147
3148     my $cust_main_invoice = new FS::cust_main_invoice ( {
3149       'custnum' => $self->custnum,
3150       'dest'    => $address,
3151     } );
3152     my $error = $self->custnum
3153                 ? $cust_main_invoice->check
3154                 : $cust_main_invoice->checkdest
3155     ;
3156     return $error if $error;
3157
3158   }
3159
3160   return "Email address required"
3161     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3162     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3163
3164   '';
3165 }
3166
3167 =item set_default_invoicing_list
3168
3169 Sets the invoicing list to all accounts associated with this customer,
3170 overwriting any previous invoicing list.
3171
3172 =cut
3173
3174 sub set_default_invoicing_list {
3175   my $self = shift;
3176   $self->invoicing_list($self->all_emails);
3177 }
3178
3179 =item all_emails
3180
3181 Returns the email addresses of all accounts provisioned for this customer.
3182
3183 =cut
3184
3185 sub all_emails {
3186   my $self = shift;
3187   my %list;
3188   foreach my $cust_pkg ( $self->all_pkgs ) {
3189     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3190     my @svc_acct =
3191       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3192         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3193           @cust_svc;
3194     $list{$_}=1 foreach map { $_->email } @svc_acct;
3195   }
3196   keys %list;
3197 }
3198
3199 =item invoicing_list_addpost
3200
3201 Adds postal invoicing to this customer.  If this customer is already configured
3202 to receive postal invoices, does nothing.
3203
3204 =cut
3205
3206 sub invoicing_list_addpost {
3207   my $self = shift;
3208   return if grep { $_ eq 'POST' } $self->invoicing_list;
3209   my @invoicing_list = $self->invoicing_list;
3210   push @invoicing_list, 'POST';
3211   $self->invoicing_list(\@invoicing_list);
3212 }
3213
3214 =item invoicing_list_emailonly
3215
3216 Returns the list of email invoice recipients (invoicing_list without non-email
3217 destinations such as POST and FAX).
3218
3219 =cut
3220
3221 sub invoicing_list_emailonly {
3222   my $self = shift;
3223   warn "$me invoicing_list_emailonly called"
3224     if $DEBUG;
3225   grep { $_ !~ /^([A-Z]+)$/ } $self->invoicing_list;
3226 }
3227
3228 =item invoicing_list_emailonly_scalar
3229
3230 Returns the list of email invoice recipients (invoicing_list without non-email
3231 destinations such as POST and FAX) as a comma-separated scalar.
3232
3233 =cut
3234
3235 sub invoicing_list_emailonly_scalar {
3236   my $self = shift;
3237   warn "$me invoicing_list_emailonly_scalar called"
3238     if $DEBUG;
3239   join(', ', $self->invoicing_list_emailonly);
3240 }
3241
3242 =item referral_custnum_cust_main
3243
3244 Returns the customer who referred this customer (or the empty string, if
3245 this customer was not referred).
3246
3247 Note the difference with referral_cust_main method: This method,
3248 referral_custnum_cust_main returns the single customer (if any) who referred
3249 this customer, while referral_cust_main returns an array of customers referred
3250 BY this customer.
3251
3252 =cut
3253
3254 sub referral_custnum_cust_main {
3255   my $self = shift;
3256   return '' unless $self->referral_custnum;
3257   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3258 }
3259
3260 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3261
3262 Returns an array of customers referred by this customer (referral_custnum set
3263 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3264 customers referred by customers referred by this customer and so on, inclusive.
3265 The default behavior is DEPTH 1 (no recursion).
3266
3267 Note the difference with referral_custnum_cust_main method: This method,
3268 referral_cust_main, returns an array of customers referred BY this customer,
3269 while referral_custnum_cust_main returns the single customer (if any) who
3270 referred this customer.
3271
3272 =cut
3273
3274 sub referral_cust_main {
3275   my $self = shift;
3276   my $depth = @_ ? shift : 1;
3277   my $exclude = @_ ? shift : {};
3278
3279   my @cust_main =
3280     map { $exclude->{$_->custnum}++; $_; }
3281       grep { ! $exclude->{ $_->custnum } }
3282         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3283
3284   if ( $depth > 1 ) {
3285     push @cust_main,
3286       map { $_->referral_cust_main($depth-1, $exclude) }
3287         @cust_main;
3288   }
3289
3290   @cust_main;
3291 }
3292
3293 =item referral_cust_main_ncancelled
3294
3295 Same as referral_cust_main, except only returns customers with uncancelled
3296 packages.
3297
3298 =cut
3299
3300 sub referral_cust_main_ncancelled {
3301   my $self = shift;
3302   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3303 }
3304
3305 =item referral_cust_pkg [ DEPTH ]
3306
3307 Like referral_cust_main, except returns a flat list of all unsuspended (and
3308 uncancelled) packages for each customer.  The number of items in this list may
3309 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3310
3311 =cut
3312
3313 sub referral_cust_pkg {
3314   my $self = shift;
3315   my $depth = @_ ? shift : 1;
3316
3317   map { $_->unsuspended_pkgs }
3318     grep { $_->unsuspended_pkgs }
3319       $self->referral_cust_main($depth);
3320 }
3321
3322 =item referring_cust_main
3323
3324 Returns the single cust_main record for the customer who referred this customer
3325 (referral_custnum), or false.
3326
3327 =cut
3328
3329 sub referring_cust_main {
3330   my $self = shift;
3331   return '' unless $self->referral_custnum;
3332   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3333 }
3334
3335 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3336
3337 Applies a credit to this customer.  If there is an error, returns the error,
3338 otherwise returns false.
3339
3340 REASON can be a text string, an FS::reason object, or a scalar reference to
3341 a reasonnum.  If a text string, it will be automatically inserted as a new
3342 reason, and a 'reason_type' option must be passed to indicate the
3343 FS::reason_type for the new reason.
3344
3345 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3346 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3347 I<commission_pkgnum>.
3348
3349 Any other options are passed to FS::cust_credit::insert.
3350
3351 =cut
3352
3353 sub credit {
3354   my( $self, $amount, $reason, %options ) = @_;
3355
3356   my $cust_credit = new FS::cust_credit {
3357     'custnum' => $self->custnum,
3358     'amount'  => $amount,
3359   };
3360
3361   if ( ref($reason) ) {
3362
3363     if ( ref($reason) eq 'SCALAR' ) {
3364       $cust_credit->reasonnum( $$reason );
3365     } else {
3366       $cust_credit->reasonnum( $reason->reasonnum );
3367     }
3368
3369   } else {
3370     $cust_credit->set('reason', $reason)
3371   }
3372
3373   $cust_credit->$_( delete $options{$_} )
3374     foreach grep exists($options{$_}),
3375               qw( addlinfo eventnum ),
3376               map "commission_$_", qw( agentnum salesnum pkgnum );
3377
3378   $cust_credit->insert(%options);
3379
3380 }
3381
3382 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3383
3384 Creates a one-time charge for this customer.  If there is an error, returns
3385 the error, otherwise returns false.
3386
3387 New-style, with a hashref of options:
3388
3389   my $error = $cust_main->charge(
3390                                   {
3391                                     'amount'     => 54.32,
3392                                     'quantity'   => 1,
3393                                     'start_date' => str2time('7/4/2009'),
3394                                     'pkg'        => 'Description',
3395                                     'comment'    => 'Comment',
3396                                     'additional' => [], #extra invoice detail
3397                                     'classnum'   => 1,  #pkg_class
3398
3399                                     'setuptax'   => '', # or 'Y' for tax exempt
3400
3401                                     'locationnum'=> 1234, # optional
3402
3403                                     #internal taxation
3404                                     'taxclass'   => 'Tax class',
3405
3406                                     #vendor taxation
3407                                     'taxproduct' => 2,  #part_pkg_taxproduct
3408                                     'override'   => {}, #XXX describe
3409
3410                                     #will be filled in with the new object
3411                                     'cust_pkg_ref' => \$cust_pkg,
3412
3413                                     #generate an invoice immediately
3414                                     'bill_now' => 0,
3415                                     'invoice_terms' => '', #with these terms
3416                                   }
3417                                 );
3418
3419 Old-style:
3420
3421   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3422
3423 =cut
3424
3425 sub charge {
3426   my $self = shift;
3427   my ( $amount, $quantity, $start_date, $classnum );
3428   my ( $pkg, $comment, $additional );
3429   my ( $setuptax, $taxclass );   #internal taxes
3430   my ( $taxproduct, $override ); #vendor (CCH) taxes
3431   my $no_auto = '';
3432   my $cust_pkg_ref = '';
3433   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3434   my $locationnum;
3435   if ( ref( $_[0] ) ) {
3436     $amount     = $_[0]->{amount};
3437     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3438     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3439     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3440     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3441     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3442                                            : '$'. sprintf("%.2f",$amount);
3443     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3444     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3445     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3446     $additional = $_[0]->{additional} || [];
3447     $taxproduct = $_[0]->{taxproductnum};
3448     $override   = { '' => $_[0]->{tax_override} };
3449     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3450     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3451     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3452     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3453   } else {
3454     $amount     = shift;
3455     $quantity   = 1;
3456     $start_date = '';
3457     $pkg        = @_ ? shift : 'One-time charge';
3458     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3459     $setuptax   = '';
3460     $taxclass   = @_ ? shift : '';
3461     $additional = [];
3462   }
3463
3464   local $SIG{HUP} = 'IGNORE';
3465   local $SIG{INT} = 'IGNORE';
3466   local $SIG{QUIT} = 'IGNORE';
3467   local $SIG{TERM} = 'IGNORE';
3468   local $SIG{TSTP} = 'IGNORE';
3469   local $SIG{PIPE} = 'IGNORE';
3470
3471   my $oldAutoCommit = $FS::UID::AutoCommit;
3472   local $FS::UID::AutoCommit = 0;
3473   my $dbh = dbh;
3474
3475   my $part_pkg = new FS::part_pkg ( {
3476     'pkg'           => $pkg,
3477     'comment'       => $comment,
3478     'plan'          => 'flat',
3479     'freq'          => 0,
3480     'disabled'      => 'Y',
3481     'classnum'      => ( $classnum ? $classnum : '' ),
3482     'setuptax'      => $setuptax,
3483     'taxclass'      => $taxclass,
3484     'taxproductnum' => $taxproduct,
3485   } );
3486
3487   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3488                         ( 0 .. @$additional - 1 )
3489                   ),
3490                   'additional_count' => scalar(@$additional),
3491                   'setup_fee' => $amount,
3492                 );
3493
3494   my $error = $part_pkg->insert( options       => \%options,
3495                                  tax_overrides => $override,
3496                                );
3497   if ( $error ) {
3498     $dbh->rollback if $oldAutoCommit;
3499     return $error;
3500   }
3501
3502   my $pkgpart = $part_pkg->pkgpart;
3503   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3504   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3505     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3506     $error = $type_pkgs->insert;
3507     if ( $error ) {
3508       $dbh->rollback if $oldAutoCommit;
3509       return $error;
3510     }
3511   }
3512
3513   my $cust_pkg = new FS::cust_pkg ( {
3514     'custnum'    => $self->custnum,
3515     'pkgpart'    => $pkgpart,
3516     'quantity'   => $quantity,
3517     'start_date' => $start_date,
3518     'no_auto'    => $no_auto,
3519     'locationnum'=> $locationnum,
3520   } );
3521
3522   $error = $cust_pkg->insert;
3523   if ( $error ) {
3524     $dbh->rollback if $oldAutoCommit;
3525     return $error;
3526   } elsif ( $cust_pkg_ref ) {
3527     ${$cust_pkg_ref} = $cust_pkg;
3528   }
3529
3530   if ( $bill_now ) {
3531     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3532                              'pkg_list'      => [ $cust_pkg ],
3533                            );
3534     if ( $error ) {
3535       $dbh->rollback if $oldAutoCommit;
3536       return $error;
3537     }
3538   }
3539
3540   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3541   return '';
3542
3543 }
3544
3545 #=item charge_postal_fee
3546 #
3547 #Applies a one time charge this customer.  If there is an error,
3548 #returns the error, returns the cust_pkg charge object or false
3549 #if there was no charge.
3550 #
3551 #=cut
3552 #
3553 # This should be a customer event.  For that to work requires that bill
3554 # also be a customer event.
3555
3556 sub charge_postal_fee {
3557   my $self = shift;
3558
3559   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3560   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3561
3562   my $cust_pkg = new FS::cust_pkg ( {
3563     'custnum'  => $self->custnum,
3564     'pkgpart'  => $pkgpart,
3565     'quantity' => 1,
3566   } );
3567
3568   my $error = $cust_pkg->insert;
3569   $error ? $error : $cust_pkg;
3570 }
3571
3572 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3573
3574 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3575
3576 Optionally, a list or hashref of additional arguments to the qsearch call can
3577 be passed.
3578
3579 =cut
3580
3581 sub cust_bill {
3582   my $self = shift;
3583   my $opt = ref($_[0]) ? shift : { @_ };
3584
3585   #return $self->num_cust_bill unless wantarray || keys %$opt;
3586
3587   $opt->{'table'} = 'cust_bill';
3588   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3589   $opt->{'hashref'}{'custnum'} = $self->custnum;
3590   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3591
3592   map { $_ } #behavior of sort undefined in scalar context
3593     sort { $a->_date <=> $b->_date }
3594       qsearch($opt);
3595 }
3596
3597 =item open_cust_bill
3598
3599 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3600 customer.
3601
3602 =cut
3603
3604 sub open_cust_bill {
3605   my $self = shift;
3606
3607   $self->cust_bill(
3608     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3609     #@_
3610   );
3611
3612 }
3613
3614 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3615
3616 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3617
3618 =cut
3619
3620 sub legacy_cust_bill {
3621   my $self = shift;
3622
3623   #return $self->num_legacy_cust_bill unless wantarray;
3624
3625   map { $_ } #behavior of sort undefined in scalar context
3626     sort { $a->_date <=> $b->_date }
3627       qsearch({ 'table'    => 'legacy_cust_bill',
3628                 'hashref'  => { 'custnum' => $self->custnum, },
3629                 'order_by' => 'ORDER BY _date ASC',
3630              });
3631 }
3632
3633 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3634
3635 Returns all the statements (see L<FS::cust_statement>) for this customer.
3636
3637 Optionally, a list or hashref of additional arguments to the qsearch call can
3638 be passed.
3639
3640 =cut
3641
3642 =item cust_bill_void
3643
3644 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3645
3646 =cut
3647
3648 sub cust_bill_void {
3649   my $self = shift;
3650
3651   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3652   sort { $a->_date <=> $b->_date }
3653     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3654 }
3655
3656 sub cust_statement {
3657   my $self = shift;
3658   my $opt = ref($_[0]) ? shift : { @_ };
3659
3660   #return $self->num_cust_statement unless wantarray || keys %$opt;
3661
3662   $opt->{'table'} = 'cust_statement';
3663   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3664   $opt->{'hashref'}{'custnum'} = $self->custnum;
3665   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3666
3667   map { $_ } #behavior of sort undefined in scalar context
3668     sort { $a->_date <=> $b->_date }
3669       qsearch($opt);
3670 }
3671
3672 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3673
3674 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3675
3676 Optionally, a list or hashref of additional arguments to the qsearch call can
3677 be passed following the SVCDB.
3678
3679 =cut
3680
3681 sub svc_x {
3682   my $self = shift;
3683   my $svcdb = shift;
3684   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3685     warn "$me svc_x requires a svcdb";
3686     return;
3687   }
3688   my $opt = ref($_[0]) ? shift : { @_ };
3689
3690   $opt->{'table'} = $svcdb;
3691   $opt->{'addl_from'} =
3692     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3693     ($opt->{'addl_from'} || '');
3694
3695   my $custnum = $self->custnum;
3696   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3697   my $where = "cust_pkg.custnum = $custnum";
3698
3699   my $extra_sql = $opt->{'extra_sql'} || '';
3700   if ( keys %{ $opt->{'hashref'} } ) {
3701     $extra_sql = " AND $where $extra_sql";
3702   }
3703   else {
3704     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3705       $extra_sql = "WHERE $where AND $1";
3706     }
3707     else {
3708       $extra_sql = "WHERE $where $extra_sql";
3709     }
3710   }
3711   $opt->{'extra_sql'} = $extra_sql;
3712
3713   qsearch($opt);
3714 }
3715
3716 # required for use as an eventtable;
3717 sub svc_acct {
3718   my $self = shift;
3719   $self->svc_x('svc_acct', @_);
3720 }
3721
3722 =item cust_credit
3723
3724 Returns all the credits (see L<FS::cust_credit>) for this customer.
3725
3726 =cut
3727
3728 sub cust_credit {
3729   my $self = shift;
3730   map { $_ } #return $self->num_cust_credit unless wantarray;
3731   sort { $a->_date <=> $b->_date }
3732     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3733 }
3734
3735 =item cust_credit_pkgnum
3736
3737 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3738 package when using experimental package balances.
3739
3740 =cut
3741
3742 sub cust_credit_pkgnum {
3743   my( $self, $pkgnum ) = @_;
3744   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3745   sort { $a->_date <=> $b->_date }
3746     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3747                               'pkgnum'  => $pkgnum,
3748                             }
3749     );
3750 }
3751
3752 =item cust_credit_void
3753
3754 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3755
3756 =cut
3757
3758 sub cust_credit_void {
3759   my $self = shift;
3760   map { $_ }
3761   sort { $a->_date <=> $b->_date }
3762     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3763 }
3764
3765 =item cust_pay
3766
3767 Returns all the payments (see L<FS::cust_pay>) for this customer.
3768
3769 =cut
3770
3771 sub cust_pay {
3772   my $self = shift;
3773   return $self->num_cust_pay unless wantarray;
3774   sort { $a->_date <=> $b->_date }
3775     qsearch( 'cust_pay', { 'custnum' => $self->custnum } )
3776 }
3777
3778 =item num_cust_pay
3779
3780 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3781 called automatically when the cust_pay method is used in a scalar context.
3782
3783 =cut
3784
3785 sub num_cust_pay {
3786   my $self = shift;
3787   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3788   my $sth = dbh->prepare($sql) or die dbh->errstr;
3789   $sth->execute($self->custnum) or die $sth->errstr;
3790   $sth->fetchrow_arrayref->[0];
3791 }
3792
3793 =item cust_pay_pkgnum
3794
3795 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3796 package when using experimental package balances.
3797
3798 =cut
3799
3800 sub cust_pay_pkgnum {
3801   my( $self, $pkgnum ) = @_;
3802   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3803   sort { $a->_date <=> $b->_date }
3804     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3805                            'pkgnum'  => $pkgnum,
3806                          }
3807     );
3808 }
3809
3810 =item cust_pay_void
3811
3812 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3813
3814 =cut
3815
3816 sub cust_pay_void {
3817   my $self = shift;
3818   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3819   sort { $a->_date <=> $b->_date }
3820     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3821 }
3822
3823 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3824
3825 Returns all batched payments (see L<FS::cust_pay_batch>) for this customer.
3826
3827 Optionally, a list or hashref of additional arguments to the qsearch call can
3828 be passed.
3829
3830 =cut
3831
3832 sub cust_pay_batch {
3833   my $self = shift;
3834   my $opt = ref($_[0]) ? shift : { @_ };
3835
3836   #return $self->num_cust_statement unless wantarray || keys %$opt;
3837
3838   $opt->{'table'} = 'cust_pay_batch';
3839   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3840   $opt->{'hashref'}{'custnum'} = $self->custnum;
3841   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
3842
3843   map { $_ } #behavior of sort undefined in scalar context
3844     sort { $a->paybatchnum <=> $b->paybatchnum }
3845       qsearch($opt);
3846 }
3847
3848 =item cust_pay_pending
3849
3850 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3851 (without status "done").
3852
3853 =cut
3854
3855 sub cust_pay_pending {
3856   my $self = shift;
3857   return $self->num_cust_pay_pending unless wantarray;
3858   sort { $a->_date <=> $b->_date }
3859     qsearch( 'cust_pay_pending', {
3860                                    'custnum' => $self->custnum,
3861                                    'status'  => { op=>'!=', value=>'done' },
3862                                  },
3863            );
3864 }
3865
3866 =item cust_pay_pending_attempt
3867
3868 Returns all payment attempts / declined payments for this customer, as pending
3869 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3870 a corresponding payment (see L<FS::cust_pay>).
3871
3872 =cut
3873
3874 sub cust_pay_pending_attempt {
3875   my $self = shift;
3876   return $self->num_cust_pay_pending_attempt unless wantarray;
3877   sort { $a->_date <=> $b->_date }
3878     qsearch( 'cust_pay_pending', {
3879                                    'custnum' => $self->custnum,
3880                                    'status'  => 'done',
3881                                    'paynum'  => '',
3882                                  },
3883            );
3884 }
3885
3886 =item num_cust_pay_pending
3887
3888 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3889 customer (without status "done").  Also called automatically when the
3890 cust_pay_pending method is used in a scalar context.
3891
3892 =cut
3893
3894 sub num_cust_pay_pending {
3895   my $self = shift;
3896   $self->scalar_sql(
3897     " SELECT COUNT(*) FROM cust_pay_pending ".
3898       " WHERE custnum = ? AND status != 'done' ",
3899     $self->custnum
3900   );
3901 }
3902
3903 =item num_cust_pay_pending_attempt
3904
3905 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3906 customer, with status "done" but without a corresp.  Also called automatically when the
3907 cust_pay_pending method is used in a scalar context.
3908
3909 =cut
3910
3911 sub num_cust_pay_pending_attempt {
3912   my $self = shift;
3913   $self->scalar_sql(
3914     " SELECT COUNT(*) FROM cust_pay_pending ".
3915       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3916     $self->custnum
3917   );
3918 }
3919
3920 =item cust_refund
3921
3922 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3923
3924 =cut
3925
3926 sub cust_refund {
3927   my $self = shift;
3928   map { $_ } #return $self->num_cust_refund unless wantarray;
3929   sort { $a->_date <=> $b->_date }
3930     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3931 }
3932
3933 =item display_custnum
3934
3935 Returns the displayed customer number for this customer: agent_custid if
3936 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3937
3938 =cut
3939
3940 sub display_custnum {
3941   my $self = shift;
3942
3943   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3944   if ( my $special = $conf->config('cust_main-custnum-display_special') ) {
3945     if ( $special eq 'CoStAg' ) {
3946       $prefix = uc( join('',
3947         $self->country,
3948         ($self->state =~ /^(..)/),
3949         $prefix || ($self->agent->agent =~ /^(..)/)
3950       ) );
3951     }
3952     elsif ( $special eq 'CoStCl' ) {
3953       $prefix = uc( join('',
3954         $self->country,
3955         ($self->state =~ /^(..)/),
3956         ($self->classnum ? $self->cust_class->classname =~ /^(..)/ : '__')
3957       ) );
3958     }
3959     # add any others here if needed
3960   }
3961
3962   my $length = $conf->config('cust_main-custnum-display_length');
3963   if ( $conf->exists('cust_main-default_agent_custid') && $self->agent_custid ){
3964     return $self->agent_custid;
3965   } elsif ( $prefix ) {
3966     $length = 8 if !defined($length);
3967     return $prefix .
3968            sprintf('%0'.$length.'d', $self->custnum)
3969   } elsif ( $length ) {
3970     return sprintf('%0'.$length.'d', $self->custnum);
3971   } else {
3972     return $self->custnum;
3973   }
3974 }
3975
3976 =item name
3977
3978 Returns a name string for this customer, either "Company (Last, First)" or
3979 "Last, First".
3980
3981 =cut
3982
3983 sub name {
3984   my $self = shift;
3985   my $name = $self->contact;
3986   $name = $self->company. " ($name)" if $self->company;
3987   $name;
3988 }
3989
3990 =item service_contact
3991
3992 Returns the L<FS::contact> object for this customer that has the 'Service'
3993 contact class, or undef if there is no such contact.  Deprecated; don't use
3994 this in new code.
3995
3996 =cut
3997
3998 sub service_contact {
3999   my $self = shift;
4000   if ( !exists($self->{service_contact}) ) {
4001     my $classnum = $self->scalar_sql(
4002       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
4003     ) || 0; #if it's zero, qsearchs will return nothing
4004     $self->{service_contact} = qsearchs('contact', {
4005         'classnum' => $classnum, 'custnum' => $self->custnum
4006       }) || undef;
4007   }
4008   $self->{service_contact};
4009 }
4010
4011 =item ship_name
4012
4013 Returns a name string for this (service/shipping) contact, either
4014 "Company (Last, First)" or "Last, First".
4015
4016 =cut
4017
4018 sub ship_name {
4019   my $self = shift;
4020
4021   my $name = $self->ship_contact;
4022   $name = $self->company. " ($name)" if $self->company;
4023   $name;
4024 }
4025
4026 =item name_short
4027
4028 Returns a name string for this customer, either "Company" or "First Last".
4029
4030 =cut
4031
4032 sub name_short {
4033   my $self = shift;
4034   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4035 }
4036
4037 =item ship_name_short
4038
4039 Returns a name string for this (service/shipping) contact, either "Company"
4040 or "First Last".
4041
4042 =cut
4043
4044 sub ship_name_short {
4045   my $self = shift;
4046   $self->service_contact
4047     ? $self->ship_contact_firstlast
4048     : $self->name_short
4049 }
4050
4051 =item contact
4052
4053 Returns this customer's full (billing) contact name only, "Last, First"
4054
4055 =cut
4056
4057 sub contact {
4058   my $self = shift;
4059   $self->get('last'). ', '. $self->first;
4060 }
4061
4062 =item ship_contact
4063
4064 Returns this customer's full (shipping) contact name only, "Last, First"
4065
4066 =cut
4067
4068 sub ship_contact {
4069   my $self = shift;
4070   my $contact = $self->service_contact || $self;
4071   $contact->get('last') . ', ' . $contact->get('first');
4072 }
4073
4074 =item contact_firstlast
4075
4076 Returns this customers full (billing) contact name only, "First Last".
4077
4078 =cut
4079
4080 sub contact_firstlast {
4081   my $self = shift;
4082   $self->first. ' '. $self->get('last');
4083 }
4084
4085 =item ship_contact_firstlast
4086
4087 Returns this customer's full (shipping) contact name only, "First Last".
4088
4089 =cut
4090
4091 sub ship_contact_firstlast {
4092   my $self = shift;
4093   my $contact = $self->service_contact || $self;
4094   $contact->get('first') . ' '. $contact->get('last');
4095 }
4096
4097 #XXX this doesn't work in 3.x+
4098 #=item country_full
4099 #
4100 #Returns this customer's full country name
4101 #
4102 #=cut
4103 #
4104 #sub country_full {
4105 #  my $self = shift;
4106 #  code2country($self->country);
4107 #}
4108
4109 sub bill_country_full {
4110   my $self = shift;
4111   code2country($self->bill_location->country);
4112 }
4113
4114 sub ship_country_full {
4115   my $self = shift;
4116   code2country($self->ship_location->country);
4117 }
4118
4119 =item county_state_county [ PREFIX ]
4120
4121 Returns a string consisting of just the county, state and country.
4122
4123 =cut
4124
4125 sub county_state_country {
4126   my $self = shift;
4127   my $locationnum;
4128   if ( @_ && $_[0] && $self->has_ship_address ) {
4129     $locationnum = $self->ship_locationnum;
4130   } else {
4131     $locationnum = $self->bill_locationnum;
4132   }
4133   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4134   $cust_location->county_state_country;
4135 }
4136
4137 =item geocode DATA_VENDOR
4138
4139 Returns a value for the customer location as encoded by DATA_VENDOR.
4140 Currently this only makes sense for "CCH" as DATA_VENDOR.
4141
4142 =cut
4143
4144 =item cust_status
4145
4146 =item status
4147
4148 Returns a status string for this customer, currently:
4149
4150 =over 4
4151
4152 =item prospect - No packages have ever been ordered
4153
4154 =item ordered - Recurring packages all are new (not yet billed).
4155
4156 =item active - One or more recurring packages is active
4157
4158 =item inactive - No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled)
4159
4160 =item suspended - All non-cancelled recurring packages are suspended
4161
4162 =item cancelled - All recurring packages are cancelled
4163
4164 =back
4165
4166 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4167 cust_main-status_module configuration option.
4168
4169 =cut
4170
4171 sub status { shift->cust_status(@_); }
4172
4173 sub cust_status {
4174   my $self = shift;
4175   for my $status ( FS::cust_main->statuses() ) {
4176     my $method = $status.'_sql';
4177     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4178     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4179     $sth->execute( ($self->custnum) x $numnum )
4180       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4181     return $status if $sth->fetchrow_arrayref->[0];
4182   }
4183 }
4184
4185 =item ucfirst_cust_status
4186
4187 =item ucfirst_status
4188
4189 Returns the status with the first character capitalized.
4190
4191 =cut
4192
4193 sub ucfirst_status { shift->ucfirst_cust_status(@_); }
4194
4195 sub ucfirst_cust_status {
4196   my $self = shift;
4197   ucfirst($self->cust_status);
4198 }
4199
4200 =item statuscolor
4201
4202 Returns a hex triplet color string for this customer's status.
4203
4204 =cut
4205
4206 sub statuscolor { shift->cust_statuscolor(@_); }
4207
4208 sub cust_statuscolor {
4209   my $self = shift;
4210   __PACKAGE__->statuscolors->{$self->cust_status};
4211 }
4212
4213 =item tickets [ STATUS ]
4214
4215 Returns an array of hashes representing the customer's RT tickets.
4216
4217 An optional status (or arrayref or hashref of statuses) may be specified.
4218
4219 =cut
4220
4221 sub tickets {
4222   my $self = shift;
4223   my $status = ( @_ && $_[0] ) ? shift : '';
4224
4225   my $num = $conf->config('cust_main-max_tickets') || 10;
4226   my @tickets = ();
4227
4228   if ( $conf->config('ticket_system') ) {
4229     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4230
4231       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
4232                                                         $num,
4233                                                         undef,
4234                                                         $status,
4235                                                       )
4236                   };
4237
4238     } else {
4239
4240       foreach my $priority (
4241         $conf->config('ticket_system-custom_priority_field-values'), ''
4242       ) {
4243         last if scalar(@tickets) >= $num;
4244         push @tickets,
4245           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4246                                                  $num - scalar(@tickets),
4247                                                  $priority,
4248                                                  $status,
4249                                                )
4250            };
4251       }
4252     }
4253   }
4254   (@tickets);
4255 }
4256
4257 # Return services representing svc_accts in customer support packages
4258 sub support_services {
4259   my $self = shift;
4260   my %packages = map { $_ => 1 } $conf->config('support_packages');
4261
4262   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4263     grep { $_->part_svc->svcdb eq 'svc_acct' }
4264     map { $_->cust_svc }
4265     grep { exists $packages{ $_->pkgpart } }
4266     $self->ncancelled_pkgs;
4267
4268 }
4269
4270 # Return a list of latitude/longitude for one of the services (if any)
4271 sub service_coordinates {
4272   my $self = shift;
4273
4274   my @svc_X =
4275     grep { $_->latitude && $_->longitude }
4276     map { $_->svc_x }
4277     map { $_->cust_svc }
4278     $self->ncancelled_pkgs;
4279
4280   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4281 }
4282
4283 =item masked FIELD
4284
4285 Returns a masked version of the named field
4286
4287 =cut
4288
4289 sub masked {
4290 my ($self,$field) = @_;
4291
4292 # Show last four
4293
4294 'x'x(length($self->getfield($field))-4).
4295   substr($self->getfield($field), (length($self->getfield($field))-4));
4296
4297 }
4298
4299 =back
4300
4301 =head1 CLASS METHODS
4302
4303 =over 4
4304
4305 =item statuses
4306
4307 Class method that returns the list of possible status strings for customers
4308 (see L<the status method|/status>).  For example:
4309
4310   @statuses = FS::cust_main->statuses();
4311
4312 =cut
4313
4314 sub statuses {
4315   my $self = shift;
4316   keys %{ $self->statuscolors };
4317 }
4318
4319 =item cust_status_sql
4320
4321 Returns an SQL fragment to determine the status of a cust_main record, as a
4322 string.
4323
4324 =cut
4325
4326 sub cust_status_sql {
4327   my $sql = 'CASE';
4328   for my $status ( FS::cust_main->statuses() ) {
4329     my $method = $status.'_sql';
4330     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4331   }
4332   $sql .= ' END';
4333   return $sql;
4334 }
4335
4336
4337 =item prospect_sql
4338
4339 Returns an SQL expression identifying prospective cust_main records (customers
4340 with no packages ever ordered)
4341
4342 =cut
4343
4344 use vars qw($select_count_pkgs);
4345 $select_count_pkgs =
4346   "SELECT COUNT(*) FROM cust_pkg
4347     WHERE cust_pkg.custnum = cust_main.custnum";
4348
4349 sub select_count_pkgs_sql {
4350   $select_count_pkgs;
4351 }
4352
4353 sub prospect_sql {
4354   " 0 = ( $select_count_pkgs ) ";
4355 }
4356
4357 =item ordered_sql
4358
4359 Returns an SQL expression identifying ordered cust_main records (customers with
4360 no active packages, but recurring packages not yet setup or one time charges
4361 not yet billed).
4362
4363 =cut
4364
4365 sub ordered_sql {
4366   FS::cust_main->none_active_sql.
4367   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4368 }
4369
4370 =item active_sql
4371
4372 Returns an SQL expression identifying active cust_main records (customers with
4373 active recurring packages).
4374
4375 =cut
4376
4377 sub active_sql {
4378   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4379 }
4380
4381 =item none_active_sql
4382
4383 Returns an SQL expression identifying cust_main records with no active
4384 recurring packages.  This includes customers of status prospect, ordered,
4385 inactive, and suspended.
4386
4387 =cut
4388
4389 sub none_active_sql {
4390   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4391 }
4392
4393 =item inactive_sql
4394
4395 Returns an SQL expression identifying inactive cust_main records (customers with
4396 no active recurring packages, but otherwise unsuspended/uncancelled).
4397
4398 =cut
4399
4400 sub inactive_sql {
4401   FS::cust_main->none_active_sql.
4402   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4403 }
4404
4405 =item susp_sql
4406 =item suspended_sql
4407
4408 Returns an SQL expression identifying suspended cust_main records.
4409
4410 =cut
4411
4412
4413 sub suspended_sql { susp_sql(@_); }
4414 sub susp_sql {
4415   FS::cust_main->none_active_sql.
4416   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4417 }
4418
4419 =item cancel_sql
4420 =item cancelled_sql
4421
4422 Returns an SQL expression identifying cancelled cust_main records.
4423
4424 =cut
4425
4426 sub cancel_sql { shift->cancelled_sql(@_); }
4427
4428 =item uncancel_sql
4429 =item uncancelled_sql
4430
4431 Returns an SQL expression identifying un-cancelled cust_main records.
4432
4433 =cut
4434
4435 sub uncancelled_sql { uncancel_sql(@_); }
4436 sub uncancel_sql { "
4437   ( 0 < ( $select_count_pkgs
4438                    AND ( cust_pkg.cancel IS NULL
4439                          OR cust_pkg.cancel = 0
4440                        )
4441         )
4442     OR 0 = ( $select_count_pkgs )
4443   )
4444 "; }
4445
4446 =item balance_sql
4447
4448 Returns an SQL fragment to retreive the balance.
4449
4450 =cut
4451
4452 sub balance_sql { "
4453     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4454         WHERE cust_bill.custnum   = cust_main.custnum     )
4455   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4456         WHERE cust_pay.custnum    = cust_main.custnum     )
4457   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4458         WHERE cust_credit.custnum = cust_main.custnum     )
4459   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4460         WHERE cust_refund.custnum = cust_main.custnum     )
4461 "; }
4462
4463 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4464
4465 Returns an SQL fragment to retreive the balance for this customer, optionally
4466 considering invoices with date earlier than START_TIME, and not
4467 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4468 total_unapplied_payments).
4469
4470 Times are specified as SQL fragments or numeric
4471 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4472 L<Date::Parse> for conversion functions.  The empty string can be passed
4473 to disable that time constraint completely.
4474
4475 Available options are:
4476
4477 =over 4
4478
4479 =item unapplied_date
4480
4481 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4482
4483 =item total
4484
4485 (unused.  obsolete?)
4486 set to true to remove all customer comparison clauses, for totals
4487
4488 =item where
4489
4490 (unused.  obsolete?)
4491 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4492
4493 =item join
4494
4495 (unused.  obsolete?)
4496 JOIN clause (typically used with the total option)
4497
4498 =item cutoff
4499
4500 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4501 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4502 range for invoices and I<unapplied> payments, credits, and refunds.
4503
4504 =back
4505
4506 =cut
4507
4508 sub balance_date_sql {
4509   my( $class, $start, $end, %opt ) = @_;
4510
4511   my $cutoff = $opt{'cutoff'};
4512
4513   my $owed         = FS::cust_bill->owed_sql($cutoff);
4514   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4515   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4516   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4517
4518   my $j = $opt{'join'} || '';
4519
4520   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4521   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4522   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4523   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4524
4525   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4526     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4527     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4528     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4529   ";
4530
4531 }
4532
4533 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4534
4535 Returns an SQL fragment to retreive the total unapplied payments for this
4536 customer, only considering payments with date earlier than START_TIME, and
4537 optionally not later than END_TIME.
4538
4539 Times are specified as SQL fragments or numeric
4540 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4541 L<Date::Parse> for conversion functions.  The empty string can be passed
4542 to disable that time constraint completely.
4543
4544 Available options are:
4545
4546 =cut
4547
4548 sub unapplied_payments_date_sql {
4549   my( $class, $start, $end, %opt ) = @_;
4550
4551   my $cutoff = $opt{'cutoff'};
4552
4553   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4554
4555   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4556                                                           'unapplied_date'=>1 );
4557
4558   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4559 }
4560
4561 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4562
4563 Helper method for balance_date_sql; name (and usage) subject to change
4564 (suggestions welcome).
4565
4566 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4567 cust_refund, cust_credit or cust_pay).
4568
4569 If TABLE is "cust_bill" or the unapplied_date option is true, only
4570 considers records with date earlier than START_TIME, and optionally not
4571 later than END_TIME .
4572
4573 =cut
4574
4575 sub _money_table_where {
4576   my( $class, $table, $start, $end, %opt ) = @_;
4577
4578   my @where = ();
4579   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4580   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4581     push @where, "$table._date <= $start" if defined($start) && length($start);
4582     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4583   }
4584   push @where, @{$opt{'where'}} if $opt{'where'};
4585   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4586
4587   $where;
4588
4589 }
4590
4591 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4592 use FS::cust_main::Search;
4593 sub search {
4594   my $class = shift;
4595   FS::cust_main::Search->search(@_);
4596 }
4597
4598 =back
4599
4600 =head1 SUBROUTINES
4601
4602 =over 4
4603
4604 =item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4605
4606 Deprecated.  Use event notification and message templates
4607 (L<FS::msg_template>) instead.
4608
4609 Sends a templated email notification to the customer (see L<Text::Template>).
4610
4611 OPTIONS is a hash and may include
4612
4613 I<from> - the email sender (default is invoice_from)
4614
4615 I<to> - comma-separated scalar or arrayref of recipients
4616    (default is invoicing_list)
4617
4618 I<subject> - The subject line of the sent email notification
4619    (default is "Notice from company_name")
4620
4621 I<extra_fields> - a hashref of name/value pairs which will be substituted
4622    into the template
4623
4624 The following variables are vavailable in the template.
4625
4626 I<$first> - the customer first name
4627 I<$last> - the customer last name
4628 I<$company> - the customer company
4629 I<$payby> - a description of the method of payment for the customer
4630             # would be nice to use FS::payby::shortname
4631 I<$payinfo> - the account information used to collect for this customer
4632 I<$expdate> - the expiration of the customer payment in seconds from epoch
4633
4634 =cut
4635
4636 sub notify {
4637   my ($self, $template, %options) = @_;
4638
4639   return unless $conf->exists($template);
4640
4641   my $from = $conf->config('invoice_from', $self->agentnum)
4642     if $conf->exists('invoice_from', $self->agentnum);
4643   $from = $options{from} if exists($options{from});
4644
4645   my $to = join(',', $self->invoicing_list_emailonly);
4646   $to = $options{to} if exists($options{to});
4647
4648   my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
4649     if $conf->exists('company_name', $self->agentnum);
4650   $subject = $options{subject} if exists($options{subject});
4651
4652   my $notify_template = new Text::Template (TYPE => 'ARRAY',
4653                                             SOURCE => [ map "$_\n",
4654                                               $conf->config($template)]
4655                                            )
4656     or die "can't create new Text::Template object: Text::Template::ERROR";
4657   $notify_template->compile()
4658     or die "can't compile template: Text::Template::ERROR";
4659
4660   $FS::notify_template::_template::company_name =
4661     $conf->config('company_name', $self->agentnum);
4662   $FS::notify_template::_template::company_address =
4663     join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
4664
4665   my $paydate = $self->paydate || '2037-12-31';
4666   $FS::notify_template::_template::first = $self->first;
4667   $FS::notify_template::_template::last = $self->last;
4668   $FS::notify_template::_template::company = $self->company;
4669   $FS::notify_template::_template::payinfo = $self->mask_payinfo;
4670   my $payby = $self->payby;
4671   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4672   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4673
4674   #credit cards expire at the end of the month/year of their exp date
4675   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4676     $FS::notify_template::_template::payby = 'credit card';
4677     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4678     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4679     $expire_time--;
4680   }elsif ($payby eq 'COMP') {
4681     $FS::notify_template::_template::payby = 'complimentary account';
4682   }else{
4683     $FS::notify_template::_template::payby = 'current method';
4684   }
4685   $FS::notify_template::_template::expdate = $expire_time;
4686
4687   for (keys %{$options{extra_fields}}){
4688     no strict "refs";
4689     ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
4690   }
4691
4692   send_email(from => $from,
4693              to => $to,
4694              subject => $subject,
4695              body => $notify_template->fill_in( PACKAGE =>
4696                                                 'FS::notify_template::_template'                                              ),
4697             );
4698
4699 }
4700
4701 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4702
4703 Generates a templated notification to the customer (see L<Text::Template>).
4704
4705 OPTIONS is a hash and may include
4706
4707 I<extra_fields> - a hashref of name/value pairs which will be substituted
4708    into the template.  These values may override values mentioned below
4709    and those from the customer record.
4710
4711 The following variables are available in the template instead of or in addition
4712 to the fields of the customer record.
4713
4714 I<$payby> - a description of the method of payment for the customer
4715             # would be nice to use FS::payby::shortname
4716 I<$payinfo> - the masked account information used to collect for this customer
4717 I<$expdate> - the expiration of the customer payment method in seconds from epoch
4718 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4719
4720 =cut
4721
4722 # a lot like cust_bill::print_latex
4723 sub generate_letter {
4724   my ($self, $template, %options) = @_;
4725
4726   return unless $conf->exists($template);
4727
4728   my $letter_template = new Text::Template
4729                         ( TYPE       => 'ARRAY',
4730                           SOURCE     => [ map "$_\n", $conf->config($template)],
4731                           DELIMITERS => [ '[@--', '--@]' ],
4732                         )
4733     or die "can't create new Text::Template object: Text::Template::ERROR";
4734
4735   $letter_template->compile()
4736     or die "can't compile template: Text::Template::ERROR";
4737
4738   my %letter_data = map { $_ => $self->$_ } $self->fields;
4739   $letter_data{payinfo} = $self->mask_payinfo;
4740
4741   #my $paydate = $self->paydate || '2037-12-31';
4742   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
4743
4744   my $payby = $self->payby;
4745   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4746   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4747
4748   #credit cards expire at the end of the month/year of their exp date
4749   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4750     $letter_data{payby} = 'credit card';
4751     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4752     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4753     $expire_time--;
4754   }elsif ($payby eq 'COMP') {
4755     $letter_data{payby} = 'complimentary account';
4756   }else{
4757     $letter_data{payby} = 'current method';
4758   }
4759   $letter_data{expdate} = $expire_time;
4760
4761   for (keys %{$options{extra_fields}}){
4762     $letter_data{$_} = $options{extra_fields}->{$_};
4763   }
4764
4765   unless(exists($letter_data{returnaddress})){
4766     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4767                                                   $self->agent_template)
4768                      );
4769     if ( length($retadd) ) {
4770       $letter_data{returnaddress} = $retadd;
4771     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4772       $letter_data{returnaddress} =
4773         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4774                           s/$/\\\\\*/;
4775                           $_;
4776                         }
4777                     ( $conf->config('company_name', $self->agentnum),
4778                       $conf->config('company_address', $self->agentnum),
4779                     )
4780         );
4781     } else {
4782       $letter_data{returnaddress} = '~';
4783     }
4784   }
4785
4786   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4787
4788   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4789
4790   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4791
4792   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4793                            DIR      => $dir,
4794                            SUFFIX   => '.eps',
4795                            UNLINK   => 0,
4796                          ) or die "can't open temp file: $!\n";
4797   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4798     or die "can't write temp file: $!\n";
4799   close $lh;
4800   $letter_data{'logo_file'} = $lh->filename;
4801
4802   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4803                            DIR      => $dir,
4804                            SUFFIX   => '.tex',
4805                            UNLINK   => 0,
4806                          ) or die "can't open temp file: $!\n";
4807
4808   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4809   close $fh;
4810   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4811   return ($1, $letter_data{'logo_file'});
4812
4813 }
4814
4815 =item print_ps TEMPLATE
4816
4817 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4818
4819 =cut
4820
4821 sub print_ps {
4822   my $self = shift;
4823   my($file, $lfile) = $self->generate_letter(@_);
4824   my $ps = FS::Misc::generate_ps($file);
4825   unlink($file.'.tex');
4826   unlink($lfile);
4827
4828   $ps;
4829 }
4830
4831 =item print TEMPLATE
4832
4833 Prints the filled in template.
4834
4835 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4836
4837 =cut
4838
4839 sub queueable_print {
4840   my %opt = @_;
4841
4842   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4843     or die "invalid customer number: " . $opt{custnum};
4844
4845   my $error = $self->print( { 'template' => $opt{template} } );
4846   die $error if $error;
4847 }
4848
4849 sub print {
4850   my ($self, $template) = (shift, shift);
4851   do_print(
4852     [ $self->print_ps($template) ],
4853     'agentnum' => $self->agentnum,
4854   );
4855 }
4856
4857 #these three subs should just go away once agent stuff is all config overrides
4858
4859 sub agent_template {
4860   my $self = shift;
4861   $self->_agent_plandata('agent_templatename');
4862 }
4863
4864 sub agent_invoice_from {
4865   my $self = shift;
4866   $self->_agent_plandata('agent_invoice_from');
4867 }
4868
4869 sub _agent_plandata {
4870   my( $self, $option ) = @_;
4871
4872   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4873   #agent-specific Conf
4874
4875   use FS::part_event::Condition;
4876
4877   my $agentnum = $self->agentnum;
4878
4879   my $regexp = regexp_sql();
4880
4881   my $part_event_option =
4882     qsearchs({
4883       'select'    => 'part_event_option.*',
4884       'table'     => 'part_event_option',
4885       'addl_from' => q{
4886         LEFT JOIN part_event USING ( eventpart )
4887         LEFT JOIN part_event_option AS peo_agentnum
4888           ON ( part_event.eventpart = peo_agentnum.eventpart
4889                AND peo_agentnum.optionname = 'agentnum'
4890                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
4891              )
4892         LEFT JOIN part_event_condition
4893           ON ( part_event.eventpart = part_event_condition.eventpart
4894                AND part_event_condition.conditionname = 'cust_bill_age'
4895              )
4896         LEFT JOIN part_event_condition_option
4897           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
4898                AND part_event_condition_option.optionname = 'age'
4899              )
4900       },
4901       #'hashref'   => { 'optionname' => $option },
4902       #'hashref'   => { 'part_event_option.optionname' => $option },
4903       'extra_sql' =>
4904         " WHERE part_event_option.optionname = ". dbh->quote($option).
4905         " AND action = 'cust_bill_send_agent' ".
4906         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
4907         " AND peo_agentnum.optionname = 'agentnum' ".
4908         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
4909         " ORDER BY
4910            CASE WHEN part_event_condition_option.optionname IS NULL
4911            THEN -1
4912            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
4913         " END
4914           , part_event.weight".
4915         " LIMIT 1"
4916     });
4917
4918   unless ( $part_event_option ) {
4919     return $self->agent->invoice_template || ''
4920       if $option eq 'agent_templatename';
4921     return '';
4922   }
4923
4924   $part_event_option->optionvalue;
4925
4926 }
4927
4928 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
4929
4930 Subroutine (not a method), designed to be called from the queue.
4931
4932 Takes a list of options and values.
4933
4934 Pulls up the customer record via the custnum option and calls bill_and_collect.
4935
4936 =cut
4937
4938 sub queued_bill {
4939   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
4940
4941   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
4942   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
4943
4944   #without this errors don't get rolled back
4945   $args{'fatal'} = 1; # runs from job queue, will be caught
4946
4947   $cust_main->bill_and_collect( %args );
4948 }
4949
4950 sub process_bill_and_collect {
4951   my $job = shift;
4952   my $param = thaw(decode_base64(shift));
4953   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
4954       or die "custnum '$param->{custnum}' not found!\n";
4955   $param->{'job'}   = $job;
4956   $param->{'fatal'} = 1; # runs from job queue, will be caught
4957   $param->{'retry'} = 1;
4958
4959   $cust_main->bill_and_collect( %$param );
4960 }
4961
4962 #starting to take quite a while for big dbs
4963 #   (JRNL: journaled so it only happens once per database)
4964 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
4965 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
4966 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
4967 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
4968 # JRNL leading/trailing spaces in first, last, company
4969 # JRNL migrate to cust_payby
4970 # - otaker upgrade?  journal and call it good?  (double check to make sure
4971 #    we're not still setting otaker here)
4972 #
4973 #only going to get worse with new location stuff...
4974
4975 sub _upgrade_data { #class method
4976   my ($class, %opts) = @_;
4977
4978   my @statements = (
4979     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
4980   );
4981
4982   #this seems to be the only expensive one.. why does it take so long?
4983   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
4984     push @statements,
4985       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
4986     FS::upgrade_journal->set_done('cust_main__signupdate');
4987   }
4988
4989   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
4990
4991     # fix yyyy-m-dd formatted paydates
4992     if ( driver_name =~ /^mysql/i ) {
4993       push @statements,
4994       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
4995     } else { # the SQL standard
4996       push @statements,
4997       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
4998     }
4999     FS::upgrade_journal->set_done('cust_main__paydate');
5000   }
5001
5002   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5003
5004     push @statements, #fix the weird BILL with a cc# in payinfo problem
5005       #DCRD to be safe
5006       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5007
5008     FS::upgrade_journal->set_done('cust_main__payinfo');
5009
5010   }
5011
5012   my $t = time;
5013   foreach my $sql ( @statements ) {
5014     my $sth = dbh->prepare($sql) or die dbh->errstr;
5015     $sth->execute or die $sth->errstr;
5016     #warn ( (time - $t). " seconds\n" );
5017     #$t = time;
5018   }
5019
5020   local($ignore_expired_card) = 1;
5021   local($ignore_banned_card) = 1;
5022   local($skip_fuzzyfiles) = 1;
5023   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5024
5025   FS::cust_main::Location->_upgrade_data(%opts);
5026
5027   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5028
5029     foreach my $cust_main ( qsearch({
5030       'table'     => 'cust_main',
5031       'hashref'   => {},
5032       'extra_sql' => 'WHERE '.
5033                        join(' OR ',
5034                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5035                            qw( first last company )
5036                        ),
5037     }) ) {
5038       my $error = $cust_main->replace;
5039       die $error if $error;
5040     }
5041
5042     FS::upgrade_journal->set_done('cust_main__trimspaces');
5043
5044   }
5045
5046   unless ( FS::upgrade_journal->is_done('cust_main__cust_payby') ) {
5047
5048     #we don't want to decrypt them, just stuff them as-is into cust_payby
5049     local(@encrypted_fields) = ();
5050
5051     local($FS::cust_payby::ignore_expired_card) = 1;
5052     local($FS::cust_payby::ignore_banned_card) = 1;
5053
5054     my @payfields = qw( payby payinfo paycvv paymask
5055                         paydate paystart_month paystart_year payissue
5056                         payname paystate paytype payip
5057                       );
5058
5059     my $search = new FS::Cursor {
5060       'table'     => 'cust_main',
5061       'extra_sql' => " WHERE ( payby IS NOT NULL AND payby != '' ) ",
5062     };
5063
5064     while (my $cust_main = $search->fetch) {
5065
5066       my $cust_payby = new FS::cust_payby {
5067         'custnum' => $cust_main->custnum,
5068         'weight'  => 1,
5069         map { $_ => $cust_main->$_(); } @payfields
5070       };
5071
5072       my $error = $cust_payby->insert;
5073       die $error if $error;
5074
5075       $cust_main->setfield($_, '') foreach @payfields;
5076       $error = $cust_main->replace;
5077       die $error if $error;
5078
5079     };
5080
5081     FS::upgrade_journal->set_done('cust_main__cust_payby');
5082   }
5083
5084   $class->_upgrade_otaker(%opts);
5085
5086 }
5087
5088 =back
5089
5090 =head1 BUGS
5091
5092 The delete method.
5093
5094 The delete method should possibly take an FS::cust_main object reference
5095 instead of a scalar customer number.
5096
5097 Bill and collect options should probably be passed as references instead of a
5098 list.
5099
5100 There should probably be a configuration file with a list of allowed credit
5101 card types.
5102
5103 No multiple currency support (probably a larger project than just this module).
5104
5105 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5106
5107 Birthdates rely on negative epoch values.
5108
5109 The payby for card/check batches is broken.  With mixed batching, bad
5110 things will happen.
5111
5112 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5113
5114 =head1 SEE ALSO
5115
5116 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5117 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5118 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5119
5120 =cut
5121
5122 1;
5123