FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Batch
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Billing_ThirdParty
  10              FS::cust_main::Location
  11              FS::cust_main::Credit_Limit
  12              FS::cust_main::Merge
  13              FS::cust_main::API
  14              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  15              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  16              FS::o2m_Common
  17              FS::Record
  18            );
  19
  20 require 5.006;
  21 use strict;
  22 use Carp;
  23 use Scalar::Util qw( blessed );
  24 use Time::Local qw(timelocal);
  25 use Data::Dumper;
  26 use Tie::IxHash;
  27 use Date::Format;
  28 #use Date::Manip;
  29 use File::Temp; #qw( tempfile );
  30 use Business::CreditCard 0.28;
  31 use List::Util qw(min);
  32 use FS::UID qw( dbh driver_name );
  33 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  34 use FS::Cursor;
  35 use FS::Misc qw( generate_ps do_print money_pretty card_types );
  36 use FS::Msgcat qw(gettext);
  37 use FS::CurrentUser;
  38 use FS::TicketSystem;
  39 use FS::payby;
  40 use FS::cust_pkg;
  41 use FS::cust_svc;
  42 use FS::cust_bill;
  43 use FS::cust_bill_void;
  44 use FS::legacy_cust_bill;
  45 use FS::cust_pay;
  46 use FS::cust_pay_pending;
  47 use FS::cust_pay_void;
  48 use FS::cust_pay_batch;
  49 use FS::cust_credit;
  50 use FS::cust_refund;
  51 use FS::part_referral;
  52 use FS::cust_main_county;
  53 use FS::cust_location;
  54 use FS::cust_class;
  55 use FS::tax_status;
  56 use FS::cust_main_exemption;
  57 use FS::cust_tax_adjustment;
  58 use FS::cust_tax_location;
  59 use FS::agent_currency;
  60 use FS::cust_main_invoice;
  61 use FS::cust_tag;
  62 use FS::prepay_credit;
  63 use FS::queue;
  64 use FS::part_pkg;
  65 use FS::part_export;
  66 #use FS::cust_event;
  67 use FS::type_pkgs;
  68 use FS::payment_gateway;
  69 use FS::agent_payment_gateway;
  70 use FS::banned_pay;
  71 use FS::cust_main_note;
  72 use FS::cust_attachment;
  73 use FS::cust_contact;
  74 use FS::Locales;
  75 use FS::upgrade_journal;
  76 use FS::sales;
  77 use FS::cust_payby;
  78 use FS::contact;
  79
  80 # 1 is mostly method/subroutine entry and options
  81 # 2 traces progress of some operations
  82 # 3 is even more information including possibly sensitive data
  83 our $DEBUG = 0;
  84 our $me = '[FS::cust_main]';
  85
  86 our $import = 0;
  87 our $ignore_expired_card = 0;
  88 our $ignore_banned_card = 0;
  89 our $ignore_invalid_card = 0;
  90
  91 our $skip_fuzzyfiles = 0;
  92
  93 our $ucfirst_nowarn = 0;
  94
  95 #this info is in cust_payby as of 4.x
  96 #this and the fields themselves can be removed in 5.x
  97 our @encrypted_fields = ('payinfo', 'paycvv');
  98 sub nohistory_fields { ('payinfo', 'paycvv'); }
  99
 100 our $conf;
 101 our $default_agent_custid;
 102 our $custnum_display_length;
 103 #ask FS::UID to run this stuff for us later
 104 #$FS::UID::callback{'FS::cust_main'} = sub {
 105 install_callback FS::UID sub {
 106   $conf = new FS::Conf;
 107   $ignore_invalid_card    = $conf->exists('allow_invalid_cards');
 108   $default_agent_custid   = $conf->exists('cust_main-default_agent_custid');
 109   $custnum_display_length = $conf->config('cust_main-custnum-display_length');
 110 };
 111
 112 sub _cache {
 113   my $self = shift;
 114   my ( $hashref, $cache ) = @_;
 115   if ( exists $hashref->{'pkgnum'} ) {
 116     #@{ $self->{'_pkgnum'} } = ();
 117     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 118     $self->{'_pkgnum'} = $subcache;
 119     #push @{ $self->{'_pkgnum'} },
 120     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 121   }
 122 }
 123
 124 =head1 NAME
 125
 126 FS::cust_main - Object methods for cust_main records
 127
 128 =head1 SYNOPSIS
 129
 130   use FS::cust_main;
 131
 132   $record = new FS::cust_main \%hash;
 133   $record = new FS::cust_main { 'column' => 'value' };
 134
 135   $error = $record->insert;
 136
 137   $error = $new_record->replace($old_record);
 138
 139   $error = $record->delete;
 140
 141   $error = $record->check;
 142
 143   @cust_pkg = $record->all_pkgs;
 144
 145   @cust_pkg = $record->ncancelled_pkgs;
 146
 147   @cust_pkg = $record->suspended_pkgs;
 148
 149   $error = $record->bill;
 150   $error = $record->bill %options;
 151   $error = $record->bill 'time' => $time;
 152
 153   $error = $record->collect;
 154   $error = $record->collect %options;
 155   $error = $record->collect 'invoice_time'   => $time,
 156                           ;
 157
 158 =head1 DESCRIPTION
 159
 160 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 161 FS::Record.  The following fields are currently supported:
 162
 163 =over 4
 164
 165 =item custnum
 166
 167 Primary key (assigned automatically for new customers)
 168
 169 =item agentnum
 170
 171 Agent (see L<FS::agent>)
 172
 173 =item refnum
 174
 175 Advertising source (see L<FS::part_referral>)
 176
 177 =item first
 178
 179 First name
 180
 181 =item last
 182
 183 Last name
 184
 185 =item ss
 186
 187 Cocial security number (optional)
 188
 189 =item company
 190
 191 (optional)
 192
 193 =item daytime
 194
 195 phone (optional)
 196
 197 =item night
 198
 199 phone (optional)
 200
 201 =item fax
 202
 203 phone (optional)
 204
 205 =item mobile
 206
 207 phone (optional)
 208
 209 =item payby
 210
 211 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 212
 213 =item payinfo
 214
 215 Payment Information (See L<FS::payinfo_Mixin> for data format)
 216
 217 =item paymask
 218
 219 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 220
 221 =item paycvv
 222
 223 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 224
 225 =item paydate
 226
 227 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 228
 229 =item paystart_month
 230
 231 Start date month (maestro/solo cards only)
 232
 233 =item paystart_year
 234
 235 Start date year (maestro/solo cards only)
 236
 237 =item payissue
 238
 239 Issue number (maestro/solo cards only)
 240
 241 =item payname
 242
 243 Name on card or billing name
 244
 245 =item payip
 246
 247 IP address from which payment information was received
 248
 249 =item tax
 250
 251 Tax exempt, empty or `Y'
 252
 253 =item usernum
 254
 255 Order taker (see L<FS::access_user>)
 256
 257 =item comments
 258
 259 Comments (optional)
 260
 261 =item referral_custnum
 262
 263 Referring customer number
 264
 265 =item spool_cdr
 266
 267 Enable individual CDR spooling, empty or `Y'
 268
 269 =item dundate
 270
 271 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 272
 273 =item squelch_cdr
 274
 275 Discourage individual CDR printing, empty or `Y'
 276
 277 =item edit_subject
 278
 279 Allow self-service editing of ticket subjects, empty or 'Y'
 280
 281 =item calling_list_exempt
 282
 283 Do not call, empty or 'Y'
 284
 285 =item invoice_ship_address
 286
 287 Display ship_address ("Service address") on invoices for this customer, empty or 'Y'
 288
 289 =back
 290
 291 =head1 METHODS
 292
 293 =over 4
 294
 295 =item new HASHREF
 296
 297 Creates a new customer.  To add the customer to the database, see L<"insert">.
 298
 299 Note that this stores the hash reference, not a distinct copy of the hash it
 300 points to.  You can ask the object for a copy with the I<hash> method.
 301
 302 =cut
 303
 304 sub table { 'cust_main'; }
 305
 306 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 307
 308 Adds this customer to the database.  If there is an error, returns the error,
 309 otherwise returns false.
 310
 311 Usually the customer's location will not yet exist in the database, and
 312 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 313 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 314 (in both directions) to the new customer record.  If they're references
 315 to the same object, they will become the same location.
 316
 317 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 318 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 319 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 320 hash reference is equivalent to not supplying this parameter.  There should be
 321 a better explanation of this, but until then, here's an example:
 322
 323   use Tie::RefHash;
 324   tie %hash, 'Tie::RefHash'; #this part is important
 325   %hash = (
 326     $cust_pkg => [ $svc_acct ],
 327     ...
 328   );
 329   $cust_main->insert( \%hash );
 330
 331 INVOICING_LIST_ARYREF: No longer supported.
 332
 333 Currently available options are: I<depend_jobnum>, I<noexport>,
 334 I<tax_exemption>, I<prospectnum>, I<contact> and I<contact_params>.
 335
 336 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 337 on the supplied jobnum (they will not run until the specific job completes).
 338 This can be used to defer provisioning until some action completes (such
 339 as running the customer's credit card successfully).
 340
 341 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 342 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 343 the B<reexport> method.)
 344
 345 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 346 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 347 created and inserted.
 348
 349 If I<prospectnum> is set, moves contacts and locations from that prospect.
 350
 351 If I<contact> is set to an arrayref of FS::contact objects, those will be
 352 inserted.
 353
 354 If I<contact_params> is set to a hashref of CGI parameters (and I<contact> is
 355 unset), inserts those new contacts with this new customer.  Handles CGI
 356 paramaters for an "m2" multiple entry field as passed by edit/cust_main.cgi
 357
 358 If I<cust_payby_params> is set to a hashref o fCGI parameters, inserts those
 359 new stored payment records with this new customer.  Handles CGI parameters
 360 for an "m2" multiple entry field as passed by edit/cust_main.cgi
 361
 362 =cut
 363
 364 sub insert {
 365   my $self = shift;
 366   my $cust_pkgs = @_ ? shift : {};
 367   my $invoicing_list;
 368   if ( $_[0] and ref($_[0]) eq 'ARRAY' ) {
 369     warn "cust_main::insert using deprecated invoicing list argument";
 370     $invoicing_list = shift;
 371   }
 372   my %options = @_;
 373   warn "$me insert called with options ".
 374        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 375     if $DEBUG;
 376
 377   local $SIG{HUP} = 'IGNORE';
 378   local $SIG{INT} = 'IGNORE';
 379   local $SIG{QUIT} = 'IGNORE';
 380   local $SIG{TERM} = 'IGNORE';
 381   local $SIG{TSTP} = 'IGNORE';
 382   local $SIG{PIPE} = 'IGNORE';
 383
 384   my $oldAutoCommit = $FS::UID::AutoCommit;
 385   local $FS::UID::AutoCommit = 0;
 386   my $dbh = dbh;
 387
 388   my $prepay_identifier = '';
 389   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 390   my $payby = '';
 391   if ( $self->payby eq 'PREPAY' ) {
 392
 393     $self->payby(''); #'BILL');
 394     $prepay_identifier = $self->payinfo;
 395     $self->payinfo('');
 396
 397     warn "  looking up prepaid card $prepay_identifier\n"
 398       if $DEBUG > 1;
 399
 400     my $error = $self->get_prepay( $prepay_identifier,
 401                                    'amount_ref'     => \$amount,
 402                                    'seconds_ref'    => \$seconds,
 403                                    'upbytes_ref'    => \$upbytes,
 404                                    'downbytes_ref'  => \$downbytes,
 405                                    'totalbytes_ref' => \$totalbytes,
 406                                  );
 407     if ( $error ) {
 408       $dbh->rollback if $oldAutoCommit;
 409       #return "error applying prepaid card (transaction rolled back): $error";
 410       return $error;
 411     }
 412
 413     $payby = 'PREP' if $amount;
 414
 415   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|MCHK|PPAL)$/ ) {
 416
 417     $payby = $1;
 418     $self->payby(''); #'BILL');
 419     $amount = $self->paid;
 420
 421   }
 422
 423   # insert locations
 424   foreach my $l (qw(bill_location ship_location)) {
 425
 426     my $loc = delete $self->hashref->{$l} or next;
 427
 428     if ( !$loc->locationnum ) {
 429       # warn the location that we're going to insert it with no custnum
 430       $loc->set(custnum_pending => 1);
 431       warn "  inserting $l\n"
 432         if $DEBUG > 1;
 433       my $error = $loc->insert;
 434       if ( $error ) {
 435         $dbh->rollback if $oldAutoCommit;
 436         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 437         return "$error (in $label location)";
 438       }
 439
 440     } elsif ( $loc->prospectnum ) {
 441
 442       $loc->prospectnum('');
 443       $loc->set(custnum_pending => 1);
 444       my $error = $loc->replace;
 445       if ( $error ) {
 446         $dbh->rollback if $oldAutoCommit;
 447         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 448         return "$error (moving $label location)";
 449       }
 450
 451     } elsif ( ($loc->custnum || 0) > 0 ) {
 452       # then it somehow belongs to another customer--shouldn't happen
 453       $dbh->rollback if $oldAutoCommit;
 454       return "$l belongs to customer ".$loc->custnum;
 455     }
 456     # else it already belongs to this customer
 457     # (happens when ship_location is identical to bill_location)
 458
 459     $self->set($l.'num', $loc->locationnum);
 460
 461     if ( $self->get($l.'num') eq '' ) {
 462       $dbh->rollback if $oldAutoCommit;
 463       return "$l not set";
 464     }
 465   }
 466
 467   warn "  inserting $self\n"
 468     if $DEBUG > 1;
 469
 470   $self->signupdate(time) unless $self->signupdate;
 471
 472   $self->auto_agent_custid()
 473     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 474
 475   my $error =  $self->check_payinfo_cardtype
 476             || $self->SUPER::insert;
 477   if ( $error ) {
 478     $dbh->rollback if $oldAutoCommit;
 479     #return "inserting cust_main record (transaction rolled back): $error";
 480     return $error;
 481   }
 482
 483   # now set cust_location.custnum
 484   foreach my $l (qw(bill_location ship_location)) {
 485     warn "  setting $l.custnum\n"
 486       if $DEBUG > 1;
 487     my $loc = $self->$l or next;
 488     unless ( $loc->custnum ) {
 489       $loc->set(custnum => $self->custnum);
 490       $error ||= $loc->replace;
 491     }
 492
 493     if ( $error ) {
 494       $dbh->rollback if $oldAutoCommit;
 495       return "error setting $l custnum: $error";
 496     }
 497   }
 498
 499   warn "  setting customer tags\n"
 500     if $DEBUG > 1;
 501
 502   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 503     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 504                                       'custnum' => $self->custnum };
 505     my $error = $cust_tag->insert;
 506     if ( $error ) {
 507       $dbh->rollback if $oldAutoCommit;
 508       return $error;
 509     }
 510   }
 511
 512   my $prospectnum = delete $options{'prospectnum'};
 513   if ( $prospectnum ) {
 514
 515     warn "  moving contacts and locations from prospect $prospectnum\n"
 516       if $DEBUG > 1;
 517
 518     my $prospect_main =
 519       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 520     unless ( $prospect_main ) {
 521       $dbh->rollback if $oldAutoCommit;
 522       return "Unknown prospectnum $prospectnum";
 523     }
 524     $prospect_main->custnum($self->custnum);
 525     $prospect_main->disabled('Y');
 526     my $error = $prospect_main->replace;
 527     if ( $error ) {
 528       $dbh->rollback if $oldAutoCommit;
 529       return $error;
 530     }
 531
 532     foreach my $prospect_contact ( $prospect_main->prospect_contact ) {
 533       my $cust_contact = new FS::cust_contact {
 534         'custnum' => $self->custnum,
 535         'invoice_dest' => 'Y', # invoice_dest currently not set for prospect contacts
 536         map { $_ => $prospect_contact->$_() } qw( contactnum classnum comment )
 537       };
 538       my $error =  $cust_contact->insert
 539                 || $prospect_contact->delete;
 540       if ( $error ) {
 541         $dbh->rollback if $oldAutoCommit;
 542         return $error;
 543       }
 544     }
 545
 546     my @cust_location = $prospect_main->cust_location;
 547     my @qual = $prospect_main->qual;
 548
 549     foreach my $r ( @cust_location, @qual ) {
 550       $r->prospectnum('');
 551       $r->custnum($self->custnum);
 552       my $error = $r->replace;
 553       if ( $error ) {
 554         $dbh->rollback if $oldAutoCommit;
 555         return $error;
 556       }
 557     }
 558     # since we set invoice_dest on all migrated prospect contacts (for now),
 559     # don't process invoicing_list.
 560     delete $options{'invoicing_list'};
 561     $invoicing_list = undef;
 562   }
 563
 564   warn "  setting contacts\n"
 565     if $DEBUG > 1;
 566
 567   $invoicing_list ||= $options{'invoicing_list'};
 568   if ( $invoicing_list ) {
 569
 570     $invoicing_list = [ $invoicing_list ] if !ref($invoicing_list);
 571
 572     my $email = '';
 573     foreach my $dest (@$invoicing_list ) {
 574       if ($dest eq 'POST') {
 575         $self->set('postal_invoice', 'Y');
 576       } else {
 577
 578         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
 579         if ( $contact_email ) {
 580           my $cust_contact = FS::cust_contact->new({
 581               contactnum    => $contact_email->contactnum,
 582               custnum       => $self->custnum,
 583           });
 584           $cust_contact->set('invoice_dest', 'Y');
 585           my $error = $cust_contact->insert;
 586           if ( $error ) {
 587             $dbh->rollback if $oldAutoCommit;
 588             return "$error (linking to email address $dest)";
 589           }
 590
 591         } else {
 592           # this email address is not yet linked to any contact
 593           $email .= ',' if length($email);
 594           $email .= $dest;
 595         }
 596       }
 597     }
 598
 599     my $contact = FS::contact->new({
 600       'custnum'       => $self->get('custnum'),
 601       'last'          => $self->get('last'),
 602       'first'         => $self->get('first'),
 603       'emailaddress'  => $email,
 604       'invoice_dest'  => 'Y', # yes, you can set this via the contact
 605     });
 606     my $error = $contact->insert;
 607     if ( $error ) {
 608       $dbh->rollback if $oldAutoCommit;
 609       return $error;
 610     }
 611
 612   }
 613
 614   if ( my $contact = delete $options{'contact'} ) {
 615
 616     foreach my $c ( @$contact ) {
 617       $c->custnum($self->custnum);
 618       my $error = $c->insert;
 619       if ( $error ) {
 620         $dbh->rollback if $oldAutoCommit;
 621         return $error;
 622       }
 623
 624     }
 625
 626   } elsif ( my $contact_params = delete $options{'contact_params'} ) {
 627
 628     my $error = $self->process_o2m( 'table'  => 'contact',
 629                                     'fields' => FS::contact->cgi_contact_fields,
 630                                     'params' => $contact_params,
 631                                   );
 632     if ( $error ) {
 633       $dbh->rollback if $oldAutoCommit;
 634       return $error;
 635     }
 636   }
 637
 638   warn "  setting cust_payby\n"
 639     if $DEBUG > 1;
 640
 641   if ( $options{cust_payby} ) {
 642
 643     foreach my $cust_payby ( @{ $options{cust_payby} } ) {
 644       $cust_payby->custnum($self->custnum);
 645       my $error = $cust_payby->insert;
 646       if ( $error ) {
 647         $dbh->rollback if $oldAutoCommit;
 648         return $error;
 649       }
 650     }
 651
 652   } elsif ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
 653
 654     my $error = $self->process_o2m(
 655       'table'         => 'cust_payby',
 656       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
 657       'params'        => $cust_payby_params,
 658       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
 659     );
 660     if ( $error ) {
 661       $dbh->rollback if $oldAutoCommit;
 662       return $error;
 663     }
 664
 665   }
 666
 667   warn "  setting cust_main_exemption\n"
 668     if $DEBUG > 1;
 669
 670   my $tax_exemption = delete $options{'tax_exemption'};
 671   if ( $tax_exemption ) {
 672
 673     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 674       if ref($tax_exemption) eq 'ARRAY';
 675
 676     foreach my $taxname ( keys %$tax_exemption ) {
 677       my $cust_main_exemption = new FS::cust_main_exemption {
 678         'custnum'       => $self->custnum,
 679         'taxname'       => $taxname,
 680         'exempt_number' => $tax_exemption->{$taxname},
 681       };
 682       my $error = $cust_main_exemption->insert;
 683       if ( $error ) {
 684         $dbh->rollback if $oldAutoCommit;
 685         return "inserting cust_main_exemption (transaction rolled back): $error";
 686       }
 687     }
 688   }
 689
 690   warn "  ordering packages\n"
 691     if $DEBUG > 1;
 692
 693   $error = $self->order_pkgs( $cust_pkgs,
 694                               %options,
 695                               'seconds_ref'    => \$seconds,
 696                               'upbytes_ref'    => \$upbytes,
 697                               'downbytes_ref'  => \$downbytes,
 698                               'totalbytes_ref' => \$totalbytes,
 699                             );
 700   if ( $error ) {
 701     $dbh->rollback if $oldAutoCommit;
 702     return $error;
 703   }
 704
 705   if ( $seconds ) {
 706     $dbh->rollback if $oldAutoCommit;
 707     return "No svc_acct record to apply pre-paid time";
 708   }
 709   if ( $upbytes || $downbytes || $totalbytes ) {
 710     $dbh->rollback if $oldAutoCommit;
 711     return "No svc_acct record to apply pre-paid data";
 712   }
 713
 714   if ( $amount ) {
 715     warn "  inserting initial $payby payment of $amount\n"
 716       if $DEBUG > 1;
 717     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 718     if ( $error ) {
 719       $dbh->rollback if $oldAutoCommit;
 720       return "inserting payment (transaction rolled back): $error";
 721     }
 722   }
 723
 724   unless ( $import || $skip_fuzzyfiles ) {
 725     warn "  queueing fuzzyfiles update\n"
 726       if $DEBUG > 1;
 727     $error = $self->queue_fuzzyfiles_update;
 728     if ( $error ) {
 729       $dbh->rollback if $oldAutoCommit;
 730       return "updating fuzzy search cache: $error";
 731     }
 732   }
 733
 734   # FS::geocode_Mixin::after_insert or something?
 735   if ( $conf->config('tax_district_method') and !$import ) {
 736     # if anything non-empty, try to look it up
 737     my $queue = new FS::queue {
 738       'job'     => 'FS::geocode_Mixin::process_district_update',
 739       'custnum' => $self->custnum,
 740     };
 741     my $error = $queue->insert( ref($self), $self->custnum );
 742     if ( $error ) {
 743       $dbh->rollback if $oldAutoCommit;
 744       return "queueing tax district update: $error";
 745     }
 746   }
 747
 748   # cust_main exports!
 749   warn "  exporting\n" if $DEBUG > 1;
 750
 751   my $export_args = $options{'export_args'} || [];
 752
 753   my @part_export =
 754     map qsearch( 'part_export', {exportnum=>$_} ),
 755       $conf->config('cust_main-exports'); #, $agentnum
 756
 757   foreach my $part_export ( @part_export ) {
 758     my $error = $part_export->export_insert($self, @$export_args);
 759     if ( $error ) {
 760       $dbh->rollback if $oldAutoCommit;
 761       return "exporting to ". $part_export->exporttype.
 762              " (transaction rolled back): $error";
 763     }
 764   }
 765
 766   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 767   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 768   #      if $DEBUG;
 769   #    foreach my $jobnum ( @jobnums ) {
 770   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 771   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 772   #        if $DEBUG;
 773   #      my $error = $queue->depend_insert($depend_jobnum);
 774   #      if ( $error ) {
 775   #        $dbh->rollback if $oldAutoCommit;
 776   #        return "error queuing job dependancy: $error";
 777   #      }
 778   #    }
 779   #  }
 780   #
 781   #}
 782   #
 783   #if ( exists $options{'jobnums'} ) {
 784   #  push @{ $options{'jobnums'} }, @jobnums;
 785   #}
 786
 787   warn "  insert complete; committing transaction\n"
 788     if $DEBUG > 1;
 789
 790   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 791   '';
 792
 793 }
 794
 795 use File::CounterFile;
 796 sub auto_agent_custid {
 797   my $self = shift;
 798
 799   my $format = $conf->config('cust_main-auto_agent_custid');
 800   my $agent_custid;
 801   if ( $format eq '1YMMXXXXXXXX' ) {
 802
 803     my $counter = new File::CounterFile 'cust_main.agent_custid';
 804     $counter->lock;
 805
 806     my $ym = 100000000000 + time2str('%y%m00000000', time);
 807     if ( $ym > $counter->value ) {
 808       $counter->{'value'} = $agent_custid = $ym;
 809       $counter->{'updated'} = 1;
 810     } else {
 811       $agent_custid = $counter->inc;
 812     }
 813
 814     $counter->unlock;
 815
 816   } else {
 817     die "Unknown cust_main-auto_agent_custid format: $format";
 818   }
 819
 820   $self->agent_custid($agent_custid);
 821
 822 }
 823
 824 =item PACKAGE METHODS
 825
 826 Documentation on customer package methods has been moved to
 827 L<FS::cust_main::Packages>.
 828
 829 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 830
 831 Recharges this (existing) customer with the specified prepaid card (see
 832 L<FS::prepay_credit>), specified either by I<identifier> or as an
 833 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 834 returns false.
 835
 836 Optionally, five scalar references can be passed as well.  They will have their
 837 values filled in with the amount, number of seconds, and number of upload,
 838 download, and total bytes applied by this prepaid card.
 839
 840 =cut
 841
 842 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 843 #the only place that uses these args
 844 sub recharge_prepay {
 845   my( $self, $prepay_credit, $amountref, $secondsref,
 846       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 847
 848   local $SIG{HUP} = 'IGNORE';
 849   local $SIG{INT} = 'IGNORE';
 850   local $SIG{QUIT} = 'IGNORE';
 851   local $SIG{TERM} = 'IGNORE';
 852   local $SIG{TSTP} = 'IGNORE';
 853   local $SIG{PIPE} = 'IGNORE';
 854
 855   my $oldAutoCommit = $FS::UID::AutoCommit;
 856   local $FS::UID::AutoCommit = 0;
 857   my $dbh = dbh;
 858
 859   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 860
 861   my $error = $self->get_prepay( $prepay_credit,
 862                                  'amount_ref'     => \$amount,
 863                                  'seconds_ref'    => \$seconds,
 864                                  'upbytes_ref'    => \$upbytes,
 865                                  'downbytes_ref'  => \$downbytes,
 866                                  'totalbytes_ref' => \$totalbytes,
 867                                )
 868            || $self->increment_seconds($seconds)
 869            || $self->increment_upbytes($upbytes)
 870            || $self->increment_downbytes($downbytes)
 871            || $self->increment_totalbytes($totalbytes)
 872            || $self->insert_cust_pay_prepay( $amount,
 873                                              ref($prepay_credit)
 874                                                ? $prepay_credit->identifier
 875                                                : $prepay_credit
 876                                            );
 877
 878   if ( $error ) {
 879     $dbh->rollback if $oldAutoCommit;
 880     return $error;
 881   }
 882
 883   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 884   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 885   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 886   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 887   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 888
 889   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 890   '';
 891
 892 }
 893
 894 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 895
 896 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 897 specified either by I<identifier> or as an FS::prepay_credit object.
 898
 899 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 900 incremented by the values of the prepaid card.
 901
 902 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 903 check or set this customer's I<agentnum>.
 904
 905 If there is an error, returns the error, otherwise returns false.
 906
 907 =cut
 908
 909
 910 sub get_prepay {
 911   my( $self, $prepay_credit, %opt ) = @_;
 912
 913   local $SIG{HUP} = 'IGNORE';
 914   local $SIG{INT} = 'IGNORE';
 915   local $SIG{QUIT} = 'IGNORE';
 916   local $SIG{TERM} = 'IGNORE';
 917   local $SIG{TSTP} = 'IGNORE';
 918   local $SIG{PIPE} = 'IGNORE';
 919
 920   my $oldAutoCommit = $FS::UID::AutoCommit;
 921   local $FS::UID::AutoCommit = 0;
 922   my $dbh = dbh;
 923
 924   unless ( ref($prepay_credit) ) {
 925
 926     my $identifier = $prepay_credit;
 927
 928     $prepay_credit = qsearchs(
 929       'prepay_credit',
 930       { 'identifier' => $identifier },
 931       '',
 932       'FOR UPDATE'
 933     );
 934
 935     unless ( $prepay_credit ) {
 936       $dbh->rollback if $oldAutoCommit;
 937       return "Invalid prepaid card: ". $identifier;
 938     }
 939
 940   }
 941
 942   if ( $prepay_credit->agentnum ) {
 943     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 944       $dbh->rollback if $oldAutoCommit;
 945       return "prepaid card not valid for agent ". $self->agentnum;
 946     }
 947     $self->agentnum($prepay_credit->agentnum);
 948   }
 949
 950   my $error = $prepay_credit->delete;
 951   if ( $error ) {
 952     $dbh->rollback if $oldAutoCommit;
 953     return "removing prepay_credit (transaction rolled back): $error";
 954   }
 955
 956   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 957     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 958
 959   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 960   '';
 961
 962 }
 963
 964 =item increment_upbytes SECONDS
 965
 966 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 967 the specified number of upbytes.  If there is an error, returns the error,
 968 otherwise returns false.
 969
 970 =cut
 971
 972 sub increment_upbytes {
 973   _increment_column( shift, 'upbytes', @_);
 974 }
 975
 976 =item increment_downbytes SECONDS
 977
 978 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 979 the specified number of downbytes.  If there is an error, returns the error,
 980 otherwise returns false.
 981
 982 =cut
 983
 984 sub increment_downbytes {
 985   _increment_column( shift, 'downbytes', @_);
 986 }
 987
 988 =item increment_totalbytes SECONDS
 989
 990 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 991 the specified number of totalbytes.  If there is an error, returns the error,
 992 otherwise returns false.
 993
 994 =cut
 995
 996 sub increment_totalbytes {
 997   _increment_column( shift, 'totalbytes', @_);
 998 }
 999
1000 =item increment_seconds SECONDS
1001
1002 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1003 the specified number of seconds.  If there is an error, returns the error,
1004 otherwise returns false.
1005
1006 =cut
1007
1008 sub increment_seconds {
1009   _increment_column( shift, 'seconds', @_);
1010 }
1011
1012 =item _increment_column AMOUNT
1013
1014 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1015 the specified number of seconds or bytes.  If there is an error, returns
1016 the error, otherwise returns false.
1017
1018 =cut
1019
1020 sub _increment_column {
1021   my( $self, $column, $amount ) = @_;
1022   warn "$me increment_column called: $column, $amount\n"
1023     if $DEBUG;
1024
1025   return '' unless $amount;
1026
1027   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
1028                       $self->ncancelled_pkgs;
1029
1030   if ( ! @cust_pkg ) {
1031     return 'No packages with primary or single services found'.
1032            ' to apply pre-paid time';
1033   } elsif ( scalar(@cust_pkg) > 1 ) {
1034     #maybe have a way to specify the package/account?
1035     return 'Multiple packages found to apply pre-paid time';
1036   }
1037
1038   my $cust_pkg = $cust_pkg[0];
1039   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
1040     if $DEBUG > 1;
1041
1042   my @cust_svc =
1043     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
1044
1045   if ( ! @cust_svc ) {
1046     return 'No account found to apply pre-paid time';
1047   } elsif ( scalar(@cust_svc) > 1 ) {
1048     return 'Multiple accounts found to apply pre-paid time';
1049   }
1050
1051   my $svc_acct = $cust_svc[0]->svc_x;
1052   warn "  found service svcnum ". $svc_acct->pkgnum.
1053        ' ('. $svc_acct->email. ")\n"
1054     if $DEBUG > 1;
1055
1056   $column = "increment_$column";
1057   $svc_acct->$column($amount);
1058
1059 }
1060
1061 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
1062
1063 Inserts a prepayment in the specified amount for this customer.  An optional
1064 second argument can specify the prepayment identifier for tracking purposes.
1065 If there is an error, returns the error, otherwise returns false.
1066
1067 =cut
1068
1069 sub insert_cust_pay_prepay {
1070   shift->insert_cust_pay('PREP', @_);
1071 }
1072
1073 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
1074
1075 Inserts a cash payment in the specified amount for this customer.  An optional
1076 second argument can specify the payment identifier for tracking purposes.
1077 If there is an error, returns the error, otherwise returns false.
1078
1079 =cut
1080
1081 sub insert_cust_pay_cash {
1082   shift->insert_cust_pay('CASH', @_);
1083 }
1084
1085 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
1086
1087 Inserts a Western Union payment in the specified amount for this customer.  An
1088 optional second argument can specify the prepayment identifier for tracking
1089 purposes.  If there is an error, returns the error, otherwise returns false.
1090
1091 =cut
1092
1093 sub insert_cust_pay_west {
1094   shift->insert_cust_pay('WEST', @_);
1095 }
1096
1097 sub insert_cust_pay {
1098   my( $self, $payby, $amount ) = splice(@_, 0, 3);
1099   my $payinfo = scalar(@_) ? shift : '';
1100
1101   my $cust_pay = new FS::cust_pay {
1102     'custnum' => $self->custnum,
1103     'paid'    => sprintf('%.2f', $amount),
1104     #'_date'   => #date the prepaid card was purchased???
1105     'payby'   => $payby,
1106     'payinfo' => $payinfo,
1107   };
1108   $cust_pay->insert;
1109
1110 }
1111
1112 =item delete [ OPTION => VALUE ... ]
1113
1114 This deletes the customer.  If there is an error, returns the error, otherwise
1115 returns false.
1116
1117 This will completely remove all traces of the customer record.  This is not
1118 what you want when a customer cancels service; for that, cancel all of the
1119 customer's packages (see L</cancel>).
1120
1121 If the customer has any uncancelled packages, you need to pass a new (valid)
1122 customer number for those packages to be transferred to, as the "new_customer"
1123 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1124 what you want when a customer cancels service and that you really should be
1125 looking at L<FS::cust_pkg/cancel>?
1126
1127 You can't delete a customer with invoices (see L<FS::cust_bill>),
1128 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1129 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1130 set the "delete_financials" option to a true value.
1131
1132 =cut
1133
1134 sub delete {
1135   my( $self, %opt ) = @_;
1136
1137   local $SIG{HUP} = 'IGNORE';
1138   local $SIG{INT} = 'IGNORE';
1139   local $SIG{QUIT} = 'IGNORE';
1140   local $SIG{TERM} = 'IGNORE';
1141   local $SIG{TSTP} = 'IGNORE';
1142   local $SIG{PIPE} = 'IGNORE';
1143
1144   my $oldAutoCommit = $FS::UID::AutoCommit;
1145   local $FS::UID::AutoCommit = 0;
1146   my $dbh = dbh;
1147
1148   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1149      $dbh->rollback if $oldAutoCommit;
1150      return "Can't delete a master agent customer";
1151   }
1152
1153   #use FS::access_user
1154   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1155      $dbh->rollback if $oldAutoCommit;
1156      return "Can't delete a master employee customer";
1157   }
1158
1159   tie my %financial_tables, 'Tie::IxHash',
1160     'cust_bill'      => 'invoices',
1161     'cust_statement' => 'statements',
1162     'cust_credit'    => 'credits',
1163     'cust_pay'       => 'payments',
1164     'cust_refund'    => 'refunds',
1165   ;
1166
1167   foreach my $table ( keys %financial_tables ) {
1168
1169     my @records = $self->$table();
1170
1171     if ( @records && ! $opt{'delete_financials'} ) {
1172       $dbh->rollback if $oldAutoCommit;
1173       return "Can't delete a customer with ". $financial_tables{$table};
1174     }
1175
1176     foreach my $record ( @records ) {
1177       my $error = $record->delete;
1178       if ( $error ) {
1179         $dbh->rollback if $oldAutoCommit;
1180         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1181       }
1182     }
1183
1184   }
1185
1186   my @cust_pkg = $self->ncancelled_pkgs;
1187   if ( @cust_pkg ) {
1188     my $new_custnum = $opt{'new_custnum'};
1189     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1190       $dbh->rollback if $oldAutoCommit;
1191       return "Invalid new customer number: $new_custnum";
1192     }
1193     foreach my $cust_pkg ( @cust_pkg ) {
1194       my %hash = $cust_pkg->hash;
1195       $hash{'custnum'} = $new_custnum;
1196       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1197       my $error = $new_cust_pkg->replace($cust_pkg,
1198                                          options => { $cust_pkg->options },
1199                                         );
1200       if ( $error ) {
1201         $dbh->rollback if $oldAutoCommit;
1202         return $error;
1203       }
1204     }
1205   }
1206   my @cancelled_cust_pkg = $self->all_pkgs;
1207   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1208     my $error = $cust_pkg->delete;
1209     if ( $error ) {
1210       $dbh->rollback if $oldAutoCommit;
1211       return $error;
1212     }
1213   }
1214
1215   #cust_tax_adjustment in financials?
1216   #cust_pay_pending?  ouch
1217   foreach my $table (qw(
1218     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1219     cust_payby cust_location cust_main_note cust_tax_adjustment
1220     cust_pay_void cust_pay_batch queue cust_tax_exempt
1221   )) {
1222     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1223       my $error = $record->delete;
1224       if ( $error ) {
1225         $dbh->rollback if $oldAutoCommit;
1226         return $error;
1227       }
1228     }
1229   }
1230
1231   my $sth = $dbh->prepare(
1232     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1233   ) or do {
1234     my $errstr = $dbh->errstr;
1235     $dbh->rollback if $oldAutoCommit;
1236     return $errstr;
1237   };
1238   $sth->execute($self->custnum) or do {
1239     my $errstr = $sth->errstr;
1240     $dbh->rollback if $oldAutoCommit;
1241     return $errstr;
1242   };
1243
1244   #tickets
1245
1246   my $ticket_dbh = '';
1247   if ($conf->config('ticket_system') eq 'RT_Internal') {
1248     $ticket_dbh = $dbh;
1249   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1250     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1251     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1252       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1253   }
1254
1255   if ( $ticket_dbh ) {
1256
1257     my $ticket_sth = $ticket_dbh->prepare(
1258       'DELETE FROM Links WHERE Target = ?'
1259     ) or do {
1260       my $errstr = $ticket_dbh->errstr;
1261       $dbh->rollback if $oldAutoCommit;
1262       return $errstr;
1263     };
1264     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1265       or do {
1266         my $errstr = $ticket_sth->errstr;
1267         $dbh->rollback if $oldAutoCommit;
1268         return $errstr;
1269       };
1270
1271     #check and see if the customer is the only link on the ticket, and
1272     #if so, set the ticket to deleted status in RT?
1273     #maybe someday, for now this will at least fix tickets not displaying
1274
1275   }
1276
1277   #delete the customer record
1278
1279   my $error = $self->SUPER::delete;
1280   if ( $error ) {
1281     $dbh->rollback if $oldAutoCommit;
1282     return $error;
1283   }
1284
1285   # cust_main exports!
1286
1287   #my $export_args = $options{'export_args'} || [];
1288
1289   my @part_export =
1290     map qsearch( 'part_export', {exportnum=>$_} ),
1291       $conf->config('cust_main-exports'); #, $agentnum
1292
1293   foreach my $part_export ( @part_export ) {
1294     my $error = $part_export->export_delete( $self ); #, @$export_args);
1295     if ( $error ) {
1296       $dbh->rollback if $oldAutoCommit;
1297       return "exporting to ". $part_export->exporttype.
1298              " (transaction rolled back): $error";
1299     }
1300   }
1301
1302   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1303   '';
1304
1305 }
1306
1307 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1308
1309 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1310 returns the error, otherwise returns false.
1311
1312 To change the customer's address, set the pseudo-fields C<bill_location> and
1313 C<ship_location>.  The address will still only change if at least one of the
1314 address fields differs from the existing values.
1315
1316 INVOICING_LIST_ARYREF: If you pass an arrayref to this method, it will be
1317 set as the contact email address for a default contact with the same name as
1318 the customer.
1319
1320 Currently available options are: I<tax_exemption>, I<cust_payby_params>,
1321 I<contact_params>, I<invoicing_list>.
1322
1323 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1324 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1325 deleted and inserted as appropriate.
1326
1327 I<cust_payby_params> and I<contact_params> can be hashrefs of named parameter
1328 groups (describing the customer's payment methods and contacts, respectively)
1329 in the style supported by L<FS::o2m_Common/process_o2m>. See L<FS::cust_payby>
1330 and L<FS::contact> for the fields these can contain.
1331
1332 I<invoicing_list> is a synonym for the INVOICING_LIST_ARYREF parameter, and
1333 should be used instead if possible.
1334
1335 =cut
1336
1337 sub replace {
1338   my $self = shift;
1339
1340   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1341               ? shift
1342               : $self->replace_old;
1343
1344   my @param = @_;
1345
1346   warn "$me replace called\n"
1347     if $DEBUG;
1348
1349   my $curuser = $FS::CurrentUser::CurrentUser;
1350   return "You are not permitted to create complimentary accounts."
1351     if $self->complimentary eq 'Y'
1352     && $self->complimentary ne $old->complimentary
1353     && ! $curuser->access_right('Complimentary customer');
1354
1355   local($ignore_expired_card) = 1
1356     if $old->payby  =~ /^(CARD|DCRD)$/
1357     && $self->payby =~ /^(CARD|DCRD)$/
1358     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1359
1360   local($ignore_banned_card) = 1
1361     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1362          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1363     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1364
1365   if (    $self->payby =~ /^(CARD|DCRD)$/
1366        && $old->payinfo ne $self->payinfo
1367        && $old->paymask ne $self->paymask )
1368   {
1369     my $error = $self->check_payinfo_cardtype;
1370     return $error if $error;
1371   }
1372
1373   return "Invoicing locale is required"
1374     if $old->locale
1375     && ! $self->locale
1376     && $conf->exists('cust_main-require_locale');
1377
1378   local $SIG{HUP} = 'IGNORE';
1379   local $SIG{INT} = 'IGNORE';
1380   local $SIG{QUIT} = 'IGNORE';
1381   local $SIG{TERM} = 'IGNORE';
1382   local $SIG{TSTP} = 'IGNORE';
1383   local $SIG{PIPE} = 'IGNORE';
1384
1385   my $oldAutoCommit = $FS::UID::AutoCommit;
1386   local $FS::UID::AutoCommit = 0;
1387   my $dbh = dbh;
1388
1389   for my $l (qw(bill_location ship_location)) {
1390     #my $old_loc = $old->$l;
1391     my $new_loc = $self->$l or next;
1392
1393     # find the existing location if there is one
1394     $new_loc->set('custnum' => $self->custnum);
1395     my $error = $new_loc->find_or_insert;
1396     if ( $error ) {
1397       $dbh->rollback if $oldAutoCommit;
1398       return $error;
1399     }
1400     $self->set($l.'num', $new_loc->locationnum);
1401   } #for $l
1402
1403   my $invoicing_list;
1404   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1405     warn "cust_main::replace: using deprecated invoicing list argument";
1406     $invoicing_list = shift @param;
1407   }
1408
1409   my %options = @param;
1410
1411   $invoicing_list ||= $options{invoicing_list};
1412
1413   my @contacts = map { $_->contact } $self->cust_contact;
1414   # find a contact that matches the customer's name
1415   my ($implicit_contact) = grep { $_->first eq $old->get('first')
1416                               and $_->last  eq $old->get('last') }
1417                             @contacts;
1418   $implicit_contact ||= FS::contact->new({
1419       'custnum'       => $self->custnum,
1420       'locationnum'   => $self->get('bill_locationnum'),
1421   });
1422
1423   # for any of these that are already contact emails, link to the existing
1424   # contact
1425   if ( $invoicing_list ) {
1426     my $email = '';
1427
1428     # kind of like process_m2m on these, except:
1429     # - the other side is two tables in a join
1430     # - and we might have to create new contact_emails
1431     # - and possibly a new contact
1432     #
1433     # Find existing invoice emails that aren't on the implicit contact.
1434     # Any of these that are not on the new invoicing list will be removed.
1435     my %old_email_cust_contact;
1436     foreach my $cust_contact ($self->cust_contact) {
1437       next if !$cust_contact->invoice_dest;
1438       next if $cust_contact->contactnum == ($implicit_contact->contactnum || 0);
1439
1440       foreach my $contact_email ($cust_contact->contact->contact_email) {
1441         $old_email_cust_contact{ $contact_email->emailaddress } = $cust_contact;
1442       }
1443     }
1444
1445     foreach my $dest (@$invoicing_list) {
1446
1447       if ($dest eq 'POST') {
1448
1449         $self->set('postal_invoice', 'Y');
1450
1451       } elsif ( exists($old_email_cust_contact{$dest}) ) {
1452
1453         delete $old_email_cust_contact{$dest}; # don't need to remove it, then
1454
1455       } else {
1456
1457         # See if it belongs to some other contact; if so, link it.
1458         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
1459         if ( $contact_email
1460              and $contact_email->contactnum != ($implicit_contact->contactnum || 0) ) {
1461           my $cust_contact = qsearchs('cust_contact', {
1462               contactnum  => $contact_email->contactnum,
1463               custnum     => $self->custnum,
1464           }) || FS::cust_contact->new({
1465               contactnum    => $contact_email->contactnum,
1466               custnum       => $self->custnum,
1467           });
1468           $cust_contact->set('invoice_dest', 'Y');
1469           my $error = $cust_contact->custcontactnum ?
1470                         $cust_contact->replace : $cust_contact->insert;
1471           if ( $error ) {
1472             $dbh->rollback if $oldAutoCommit;
1473             return "$error (linking to email address $dest)";
1474           }
1475
1476         } else {
1477           # This email address is not yet linked to any contact, so it will
1478           # be added to the implicit contact.
1479           $email .= ',' if length($email);
1480           $email .= $dest;
1481         }
1482       }
1483     }
1484
1485     foreach my $remove_dest (keys %old_email_cust_contact) {
1486       my $cust_contact = $old_email_cust_contact{$remove_dest};
1487       # These were not in the list of requested destinations, so take them off.
1488       $cust_contact->set('invoice_dest', '');
1489       my $error = $cust_contact->replace;
1490       if ( $error ) {
1491         $dbh->rollback if $oldAutoCommit;
1492         return "$error (unlinking email address $remove_dest)";
1493       }
1494     }
1495
1496     # make sure it keeps up with the changed customer name, if any
1497     $implicit_contact->set('last', $self->get('last'));
1498     $implicit_contact->set('first', $self->get('first'));
1499     $implicit_contact->set('emailaddress', $email);
1500     $implicit_contact->set('invoice_dest', 'Y');
1501     $implicit_contact->set('custnum', $self->custnum);
1502
1503     my $error;
1504     if ( $implicit_contact->contactnum ) {
1505       $error = $implicit_contact->replace;
1506     } elsif ( length($email) ) { # don't create a new contact if not needed
1507       $error = $implicit_contact->insert;
1508     }
1509
1510     if ( $error ) {
1511       $dbh->rollback if $oldAutoCommit;
1512       return "$error (adding email address $email)";
1513     }
1514
1515   }
1516
1517   # replace the customer record
1518   my $error = $self->SUPER::replace($old);
1519
1520   if ( $error ) {
1521     $dbh->rollback if $oldAutoCommit;
1522     return $error;
1523   }
1524
1525   # now move packages to the new service location
1526   $self->set('ship_location', ''); #flush cache
1527   if ( $old->ship_locationnum and # should only be null during upgrade...
1528        $old->ship_locationnum != $self->ship_locationnum ) {
1529     $error = $old->ship_location->move_to($self->ship_location);
1530     if ( $error ) {
1531       $dbh->rollback if $oldAutoCommit;
1532       return $error;
1533     }
1534   }
1535   # don't move packages based on the billing location, but
1536   # disable it if it's no longer in use
1537   if ( $old->bill_locationnum and
1538        $old->bill_locationnum != $self->bill_locationnum ) {
1539     $error = $old->bill_location->disable_if_unused;
1540     if ( $error ) {
1541       $dbh->rollback if $oldAutoCommit;
1542       return $error;
1543     }
1544   }
1545
1546   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1547
1548     #this could be more efficient than deleting and re-inserting, if it matters
1549     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1550       my $error = $cust_tag->delete;
1551       if ( $error ) {
1552         $dbh->rollback if $oldAutoCommit;
1553         return $error;
1554       }
1555     }
1556     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1557       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1558                                         'custnum' => $self->custnum };
1559       my $error = $cust_tag->insert;
1560       if ( $error ) {
1561         $dbh->rollback if $oldAutoCommit;
1562         return $error;
1563       }
1564     }
1565
1566   }
1567
1568   my $tax_exemption = delete $options{'tax_exemption'};
1569   if ( $tax_exemption ) {
1570
1571     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1572       if ref($tax_exemption) eq 'ARRAY';
1573
1574     my %cust_main_exemption =
1575       map { $_->taxname => $_ }
1576           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1577
1578     foreach my $taxname ( keys %$tax_exemption ) {
1579
1580       if ( $cust_main_exemption{$taxname} &&
1581            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1582          )
1583       {
1584         delete $cust_main_exemption{$taxname};
1585         next;
1586       }
1587
1588       my $cust_main_exemption = new FS::cust_main_exemption {
1589         'custnum'       => $self->custnum,
1590         'taxname'       => $taxname,
1591         'exempt_number' => $tax_exemption->{$taxname},
1592       };
1593       my $error = $cust_main_exemption->insert;
1594       if ( $error ) {
1595         $dbh->rollback if $oldAutoCommit;
1596         return "inserting cust_main_exemption (transaction rolled back): $error";
1597       }
1598     }
1599
1600     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1601       my $error = $cust_main_exemption->delete;
1602       if ( $error ) {
1603         $dbh->rollback if $oldAutoCommit;
1604         return "deleting cust_main_exemption (transaction rolled back): $error";
1605       }
1606     }
1607
1608   }
1609
1610   if ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
1611
1612     my $error = $self->process_o2m(
1613       'table'         => 'cust_payby',
1614       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
1615       'params'        => $cust_payby_params,
1616       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
1617     );
1618     if ( $error ) {
1619       $dbh->rollback if $oldAutoCommit;
1620       return $error;
1621     }
1622
1623   }
1624
1625   if ( my $contact_params = delete $options{'contact_params'} ) {
1626
1627     # this can potentially replace contacts that were created by the
1628     # invoicing list argument, but the UI shouldn't allow both of them
1629     # to be specified
1630
1631     my $error = $self->process_o2m(
1632       'table'         => 'contact',
1633       'fields'        => FS::contact->cgi_contact_fields,
1634       'params'        => $contact_params,
1635     );
1636     if ( $error ) {
1637       $dbh->rollback if $oldAutoCommit;
1638       return $error;
1639     }
1640
1641   }
1642
1643   unless ( $import || $skip_fuzzyfiles ) {
1644     $error = $self->queue_fuzzyfiles_update;
1645     if ( $error ) {
1646       $dbh->rollback if $oldAutoCommit;
1647       return "updating fuzzy search cache: $error";
1648     }
1649   }
1650
1651   # tax district update in cust_location
1652
1653   # cust_main exports!
1654
1655   my $export_args = $options{'export_args'} || [];
1656
1657   my @part_export =
1658     map qsearch( 'part_export', {exportnum=>$_} ),
1659       $conf->config('cust_main-exports'); #, $agentnum
1660
1661   foreach my $part_export ( @part_export ) {
1662     my $error = $part_export->export_replace( $self, $old, @$export_args);
1663     if ( $error ) {
1664       $dbh->rollback if $oldAutoCommit;
1665       return "exporting to ". $part_export->exporttype.
1666              " (transaction rolled back): $error";
1667     }
1668   }
1669
1670   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1671   '';
1672
1673 }
1674
1675 =item queue_fuzzyfiles_update
1676
1677 Used by insert & replace to update the fuzzy search cache
1678
1679 =cut
1680
1681 use FS::cust_main::Search;
1682 sub queue_fuzzyfiles_update {
1683   my $self = shift;
1684
1685   local $SIG{HUP} = 'IGNORE';
1686   local $SIG{INT} = 'IGNORE';
1687   local $SIG{QUIT} = 'IGNORE';
1688   local $SIG{TERM} = 'IGNORE';
1689   local $SIG{TSTP} = 'IGNORE';
1690   local $SIG{PIPE} = 'IGNORE';
1691
1692   my $oldAutoCommit = $FS::UID::AutoCommit;
1693   local $FS::UID::AutoCommit = 0;
1694   my $dbh = dbh;
1695
1696   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1697     my $queue = new FS::queue {
1698       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1699     };
1700     my @args = "cust_main.$field", $self->get($field);
1701     my $error = $queue->insert( @args );
1702     if ( $error ) {
1703       $dbh->rollback if $oldAutoCommit;
1704       return "queueing job (transaction rolled back): $error";
1705     }
1706   }
1707
1708   my @locations = ();
1709   push @locations, $self->bill_location if $self->bill_locationnum;
1710   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1711   foreach my $location (@locations) {
1712     my $queue = new FS::queue {
1713       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1714     };
1715     my @args = 'cust_location.address1', $location->address1;
1716     my $error = $queue->insert( @args );
1717     if ( $error ) {
1718       $dbh->rollback if $oldAutoCommit;
1719       return "queueing job (transaction rolled back): $error";
1720     }
1721   }
1722
1723   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1724   '';
1725
1726 }
1727
1728 =item check
1729
1730 Checks all fields to make sure this is a valid customer record.  If there is
1731 an error, returns the error, otherwise returns false.  Called by the insert
1732 and replace methods.
1733
1734 =cut
1735
1736 sub check {
1737   my $self = shift;
1738
1739   warn "$me check BEFORE: \n". $self->_dump
1740     if $DEBUG > 2;
1741
1742   my $error =
1743     $self->ut_numbern('custnum')
1744     || $self->ut_number('agentnum')
1745     || $self->ut_textn('agent_custid')
1746     || $self->ut_number('refnum')
1747     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1748     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1749     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1750     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1751     || $self->ut_foreign_keyn('taxstatusnum', 'tax_status', 'taxstatusnum')
1752     || $self->ut_textn('custbatch')
1753     || $self->ut_name('last')
1754     || $self->ut_name('first')
1755     || $self->ut_snumbern('signupdate')
1756     || $self->ut_snumbern('birthdate')
1757     || $self->ut_namen('spouse_last')
1758     || $self->ut_namen('spouse_first')
1759     || $self->ut_snumbern('spouse_birthdate')
1760     || $self->ut_snumbern('anniversary_date')
1761     || $self->ut_textn('company')
1762     || $self->ut_textn('ship_company')
1763     || $self->ut_anything('comments')
1764     || $self->ut_numbern('referral_custnum')
1765     || $self->ut_textn('stateid')
1766     || $self->ut_textn('stateid_state')
1767     || $self->ut_textn('invoice_terms')
1768     || $self->ut_floatn('cdr_termination_percentage')
1769     || $self->ut_floatn('credit_limit')
1770     || $self->ut_numbern('billday')
1771     || $self->ut_numbern('prorate_day')
1772     || $self->ut_flag('edit_subject')
1773     || $self->ut_flag('calling_list_exempt')
1774     || $self->ut_flag('invoice_noemail')
1775     || $self->ut_flag('message_noemail')
1776     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1777     || $self->ut_currencyn('currency')
1778     || $self->ut_textn('po_number')
1779     || $self->ut_enum('complimentary', [ '', 'Y' ])
1780     || $self->ut_flag('invoice_ship_address')
1781     || $self->ut_flag('invoice_dest')
1782   ;
1783
1784   foreach (qw(company ship_company)) {
1785     my $company = $self->get($_);
1786     $company =~ s/^\s+//;
1787     $company =~ s/\s+$//;
1788     $company =~ s/\s+/ /g;
1789     $self->set($_, $company);
1790   }
1791
1792   #barf.  need message catalogs.  i18n.  etc.
1793   $error .= "Please select an advertising source."
1794     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1795   return $error if $error;
1796
1797   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1798     or return "Unknown agent";
1799
1800   if ( $self->currency ) {
1801     my $agent_currency = qsearchs( 'agent_currency', {
1802       'agentnum' => $agent->agentnum,
1803       'currency' => $self->currency,
1804     })
1805       or return "Agent ". $agent->agent.
1806                 " not permitted to offer ".  $self->currency. " invoicing";
1807   }
1808
1809   return "Unknown refnum"
1810     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1811
1812   return "Unknown referring custnum: ". $self->referral_custnum
1813     unless ! $self->referral_custnum
1814            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1815
1816   if ( $self->ss eq '' ) {
1817     $self->ss('');
1818   } else {
1819     my $ss = $self->ss;
1820     $ss =~ s/\D//g;
1821     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1822       or return "Illegal social security number: ". $self->ss;
1823     $self->ss("$1-$2-$3");
1824   }
1825
1826   #turn off invoice_ship_address if ship & bill are the same
1827   if ($self->bill_locationnum eq $self->ship_locationnum) {
1828     $self->invoice_ship_address('');
1829   }
1830
1831   # cust_main_county verification now handled by cust_location check
1832
1833   $error =
1834        $self->ut_phonen('daytime', $self->country)
1835     || $self->ut_phonen('night',   $self->country)
1836     || $self->ut_phonen('fax',     $self->country)
1837     || $self->ut_phonen('mobile',  $self->country)
1838   ;
1839   return $error if $error;
1840
1841   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1842        && ! $import
1843        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1844      ) {
1845
1846     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1847                           ? 'Day Phone'
1848                           : FS::Msgcat::_gettext('daytime');
1849     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1850                         ? 'Night Phone'
1851                         : FS::Msgcat::_gettext('night');
1852
1853     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1854                         ? 'Mobile Phone'
1855                         : FS::Msgcat::_gettext('mobile');
1856
1857     return "$daytime_label, $night_label or $mobile_label is required"
1858
1859   }
1860
1861   ### start of stuff moved to cust_payby
1862   # then mostly kept here to support upgrades (can remove in 5.x)
1863   #  but modified to allow everything to be empty
1864
1865   if ( $self->payby ) {
1866     FS::payby->can_payby($self->table, $self->payby)
1867       or return "Illegal payby: ". $self->payby;
1868   } else {
1869     $self->payby('');
1870   }
1871
1872   $error =    $self->ut_numbern('paystart_month')
1873            || $self->ut_numbern('paystart_year')
1874            || $self->ut_numbern('payissue')
1875            || $self->ut_textn('paytype')
1876   ;
1877   return $error if $error;
1878
1879   if ( $self->payip eq '' ) {
1880     $self->payip('');
1881   } else {
1882     $error = $self->ut_ip('payip');
1883     return $error if $error;
1884   }
1885
1886   # If it is encrypted and the private key is not availaible then we can't
1887   # check the credit card.
1888   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1889
1890   # Need some kind of global flag to accept invalid cards, for testing
1891   # on scrubbed data.
1892   if ( !$import && !$ignore_invalid_card && $check_payinfo &&
1893     $self->payby =~ /^(CARD|DCRD)$/ ) {
1894
1895     my $payinfo = $self->payinfo;
1896     $payinfo =~ s/\D//g;
1897     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1898       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1899     $payinfo = $1;
1900     $self->payinfo($payinfo);
1901     validate($payinfo)
1902       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1903
1904     return gettext('unknown_card_type')
1905       if $self->payinfo !~ /^99\d{14}$/ #token
1906       && cardtype($self->payinfo) eq "Unknown";
1907
1908     unless ( $ignore_banned_card ) {
1909       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1910       if ( $ban ) {
1911         if ( $ban->bantype eq 'warn' ) {
1912           #or others depending on value of $ban->reason ?
1913           return '_duplicate_card'.
1914                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1915                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1916                  ' (ban# '. $ban->bannum. ')'
1917             unless $self->override_ban_warn;
1918         } else {
1919           return 'Banned credit card: banned on '.
1920                  time2str('%a %h %o at %r', $ban->_date).
1921                  ' by '. $ban->otaker.
1922                  ' (ban# '. $ban->bannum. ')';
1923         }
1924       }
1925     }
1926
1927     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1928       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1929         $self->paycvv =~ /^(\d{4})$/
1930           or return "CVV2 (CID) for American Express cards is four digits.";
1931         $self->paycvv($1);
1932       } else {
1933         $self->paycvv =~ /^(\d{3})$/
1934           or return "CVV2 (CVC2/CID) is three digits.";
1935         $self->paycvv($1);
1936       }
1937     } else {
1938       $self->paycvv('');
1939     }
1940
1941     my $cardtype = cardtype($payinfo);
1942     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1943
1944       return "Start date or issue number is required for $cardtype cards"
1945         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1946
1947       return "Start month must be between 1 and 12"
1948         if $self->paystart_month
1949            and $self->paystart_month < 1 || $self->paystart_month > 12;
1950
1951       return "Start year must be 1990 or later"
1952         if $self->paystart_year
1953            and $self->paystart_year < 1990;
1954
1955       return "Issue number must be beween 1 and 99"
1956         if $self->payissue
1957           and $self->payissue < 1 || $self->payissue > 99;
1958
1959     } else {
1960       $self->paystart_month('');
1961       $self->paystart_year('');
1962       $self->payissue('');
1963     }
1964
1965   } elsif ( !$ignore_invalid_card && $check_payinfo &&
1966     $self->payby =~ /^(CHEK|DCHK)$/ ) {
1967
1968     my $payinfo = $self->payinfo;
1969     $payinfo =~ s/[^\d\@\.]//g;
1970     if ( $conf->config('echeck-country') eq 'CA' ) {
1971       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1972         or return 'invalid echeck account@branch.bank';
1973       $payinfo = "$1\@$2.$3";
1974     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1975       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1976       $payinfo = "$1\@$2";
1977     } else {
1978       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1979       $payinfo = "$1\@$2";
1980     }
1981     $self->payinfo($payinfo);
1982     $self->paycvv('');
1983
1984     unless ( $ignore_banned_card ) {
1985       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1986       if ( $ban ) {
1987         if ( $ban->bantype eq 'warn' ) {
1988           #or others depending on value of $ban->reason ?
1989           return '_duplicate_ach' unless $self->override_ban_warn;
1990         } else {
1991           return 'Banned ACH account: banned on '.
1992                  time2str('%a %h %o at %r', $ban->_date).
1993                  ' by '. $ban->otaker.
1994                  ' (ban# '. $ban->bannum. ')';
1995         }
1996       }
1997     }
1998
1999   } elsif ( $self->payby eq 'LECB' ) {
2000
2001     my $payinfo = $self->payinfo;
2002     $payinfo =~ s/\D//g;
2003     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
2004     $payinfo = $1;
2005     $self->payinfo($payinfo);
2006     $self->paycvv('');
2007
2008   } elsif ( $self->payby eq 'BILL' ) {
2009
2010     $error = $self->ut_textn('payinfo');
2011     return "Illegal P.O. number: ". $self->payinfo if $error;
2012     $self->paycvv('');
2013
2014   } elsif ( $self->payby eq 'COMP' ) {
2015
2016     my $curuser = $FS::CurrentUser::CurrentUser;
2017     if (    ! $self->custnum
2018          && ! $curuser->access_right('Complimentary customer')
2019        )
2020     {
2021       return "You are not permitted to create complimentary accounts."
2022     }
2023
2024     $error = $self->ut_textn('payinfo');
2025     return "Illegal comp account issuer: ". $self->payinfo if $error;
2026     $self->paycvv('');
2027
2028   } elsif ( $self->payby eq 'PREPAY' ) {
2029
2030     my $payinfo = $self->payinfo;
2031     $payinfo =~ s/\W//g; #anything else would just confuse things
2032     $self->payinfo($payinfo);
2033     $error = $self->ut_alpha('payinfo');
2034     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2035     return "Unknown prepayment identifier"
2036       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2037     $self->paycvv('');
2038
2039   }
2040
2041   return "You are not permitted to create complimentary accounts."
2042     if ! $self->custnum
2043     && $self->complimentary eq 'Y'
2044     && ! $FS::CurrentUser::CurrentUser->access_right('Complimentary customer');
2045
2046   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2047     return "Expiration date required"
2048       # shouldn't payinfo_check do this?
2049       unless ! $self->payby
2050             || $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD|PPAL)$/;
2051     $self->paydate('');
2052   } else {
2053     my( $m, $y );
2054     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2055       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2056     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2057       ( $m, $y ) = ( $2, "19$1" );
2058     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2059       ( $m, $y ) = ( $3, "20$2" );
2060     } else {
2061       return "Illegal expiration date: ". $self->paydate;
2062     }
2063     $m = sprintf('%02d',$m);
2064     $self->paydate("$y-$m-01");
2065     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2066     return gettext('expired_card')
2067       if !$import
2068       && !$ignore_expired_card
2069       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2070   }
2071
2072   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2073        ( ! $conf->exists('require_cardname')
2074          || $self->payby !~ /^(CARD|DCRD)$/  )
2075   ) {
2076     $self->payname( $self->first. " ". $self->getfield('last') );
2077   } else {
2078
2079     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2080       $self->payname =~ /^([\w \,\.\-\']*)$/
2081         or return gettext('illegal_name'). " payname: ". $self->payname;
2082       $self->payname($1);
2083     } else {
2084       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
2085         or return gettext('illegal_name'). " payname: ". $self->payname;
2086       $self->payname($1);
2087     }
2088
2089   }
2090
2091   ### end of stuff moved to cust_payby
2092
2093   return "Please select an invoicing locale"
2094     if ! $self->locale
2095     && ! $self->custnum
2096     && $conf->exists('cust_main-require_locale');
2097
2098   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2099     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2100     $self->$flag($1);
2101   }
2102
2103   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2104
2105   warn "$me check AFTER: \n". $self->_dump
2106     if $DEBUG > 2;
2107
2108   $self->SUPER::check;
2109 }
2110
2111 sub check_payinfo_cardtype {
2112   my $self = shift;
2113
2114   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
2115
2116   my $payinfo = $self->payinfo;
2117   $payinfo =~ s/\D//g;
2118
2119   return '' if $payinfo =~ /^99\d{14}$/; #token
2120
2121   my %bop_card_types = map { $_=>1 } values %{ card_types() };
2122   my $cardtype = cardtype($payinfo);
2123
2124   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
2125
2126   '';
2127
2128 }
2129
2130 =item replace_check
2131
2132 Additional checks for replace only.
2133
2134 =cut
2135
2136 sub replace_check {
2137   my ($new,$old) = @_;
2138   #preserve old value if global config is set
2139   if ($old && $conf->exists('invoice-ship_address')) {
2140     $new->invoice_ship_address($old->invoice_ship_address);
2141   }
2142   return '';
2143 }
2144
2145 =item addr_fields
2146
2147 Returns a list of fields which have ship_ duplicates.
2148
2149 =cut
2150
2151 sub addr_fields {
2152   qw( last first company
2153       locationname
2154       address1 address2 city county state zip country
2155       latitude longitude
2156       daytime night fax mobile
2157     );
2158 }
2159
2160 =item has_ship_address
2161
2162 Returns true if this customer record has a separate shipping address.
2163
2164 =cut
2165
2166 sub has_ship_address {
2167   my $self = shift;
2168   $self->bill_locationnum != $self->ship_locationnum;
2169 }
2170
2171 =item location_hash
2172
2173 Returns a list of key/value pairs, with the following keys: address1,
2174 adddress2, city, county, state, zip, country, district, and geocode.  The
2175 shipping address is used if present.
2176
2177 =cut
2178
2179 sub location_hash {
2180   my $self = shift;
2181   $self->ship_location->location_hash;
2182 }
2183
2184 =item cust_location
2185
2186 Returns all locations (see L<FS::cust_location>) for this customer.
2187
2188 =cut
2189
2190 sub cust_location {
2191   my $self = shift;
2192   qsearch({
2193     'table'   => 'cust_location',
2194     'hashref' => { 'custnum'     => $self->custnum,
2195                    'prospectnum' => '',
2196                  },
2197     'order_by' => 'ORDER BY country, LOWER(state), LOWER(city), LOWER(county), LOWER(address1), LOWER(address2)',
2198   });
2199 }
2200
2201 =item cust_contact
2202
2203 Returns all contact associations (see L<FS::cust_contact>) for this customer.
2204
2205 =cut
2206
2207 sub cust_contact {
2208   my $self = shift;
2209   qsearch('cust_contact', { 'custnum' => $self->custnum } );
2210 }
2211
2212 =item cust_payby PAYBY
2213
2214 Returns all payment methods (see L<FS::cust_payby>) for this customer.
2215
2216 If one or more PAYBY are specified, returns only payment methods for specified PAYBY.
2217 Does not validate PAYBY.
2218
2219 =cut
2220
2221 sub cust_payby {
2222   my $self = shift;
2223   my @payby = @_;
2224   my $search = {
2225     'table'    => 'cust_payby',
2226     'hashref'  => { 'custnum' => $self->custnum },
2227     'order_by' => "ORDER BY payby IN ('CARD','CHEK') DESC, weight ASC",
2228   };
2229   $search->{'extra_sql'} = ' AND payby IN ( '.
2230                                join(',', map dbh->quote($_), @payby).
2231                              ' ) '
2232     if @payby;
2233
2234   qsearch($search);
2235 }
2236
2237 =item has_cust_payby_auto
2238
2239 Returns true if customer has an automatic payment method ('CARD' or 'CHEK')
2240
2241 =cut
2242
2243 sub has_cust_payby_auto {
2244   my $self = shift;
2245   scalar( qsearch({
2246     'table'     => 'cust_payby',
2247     'hashref'   => { 'custnum' => $self->custnum, },
2248     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
2249     'order_by'  => 'LIMIT 1',
2250   }) );
2251
2252 }
2253
2254 =item unsuspend
2255
2256 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2257 and L<FS::cust_pkg>) for this customer, except those on hold.
2258
2259 Returns a list: an empty list on success or a list of errors.
2260
2261 =cut
2262
2263 sub unsuspend {
2264   my $self = shift;
2265   grep { ($_->get('setup')) && $_->unsuspend } $self->suspended_pkgs;
2266 }
2267
2268 =item release_hold
2269
2270 Unsuspends all suspended packages in the on-hold state (those without setup
2271 dates) for this customer.
2272
2273 =cut
2274
2275 sub release_hold {
2276   my $self = shift;
2277   grep { (!$_->setup) && $_->unsuspend } $self->suspended_pkgs;
2278 }
2279
2280 =item suspend
2281
2282 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2283
2284 Returns a list: an empty list on success or a list of errors.
2285
2286 =cut
2287
2288 sub suspend {
2289   my $self = shift;
2290   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2291 }
2292
2293 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2294
2295 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2296 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2297 of a list of pkgparts; the hashref has the following keys:
2298
2299 =over 4
2300
2301 =item pkgparts - listref of pkgparts
2302
2303 =item (other options are passed to the suspend method)
2304
2305 =back
2306
2307
2308 Returns a list: an empty list on success or a list of errors.
2309
2310 =cut
2311
2312 sub suspend_if_pkgpart {
2313   my $self = shift;
2314   my (@pkgparts, %opt);
2315   if (ref($_[0]) eq 'HASH'){
2316     @pkgparts = @{$_[0]{pkgparts}};
2317     %opt      = %{$_[0]};
2318   }else{
2319     @pkgparts = @_;
2320   }
2321   grep { $_->suspend(%opt) }
2322     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2323       $self->unsuspended_pkgs;
2324 }
2325
2326 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2327
2328 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2329 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2330 instead of a list of pkgparts; the hashref has the following keys:
2331
2332 =over 4
2333
2334 =item pkgparts - listref of pkgparts
2335
2336 =item (other options are passed to the suspend method)
2337
2338 =back
2339
2340 Returns a list: an empty list on success or a list of errors.
2341
2342 =cut
2343
2344 sub suspend_unless_pkgpart {
2345   my $self = shift;
2346   my (@pkgparts, %opt);
2347   if (ref($_[0]) eq 'HASH'){
2348     @pkgparts = @{$_[0]{pkgparts}};
2349     %opt      = %{$_[0]};
2350   }else{
2351     @pkgparts = @_;
2352   }
2353   grep { $_->suspend(%opt) }
2354     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2355       $self->unsuspended_pkgs;
2356 }
2357
2358 =item cancel [ OPTION => VALUE ... ]
2359
2360 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2361
2362 Available options are:
2363
2364 =over 4
2365
2366 =item quiet - can be set true to supress email cancellation notices.
2367
2368 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2369
2370 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2371
2372 =item nobill - can be set true to skip billing if it might otherwise be done.
2373
2374 =back
2375
2376 Always returns a list: an empty list on success or a list of errors.
2377
2378 =cut
2379
2380 # nb that dates are not specified as valid options to this method
2381
2382 sub cancel {
2383   my( $self, %opt ) = @_;
2384
2385   my $oldAutoCommit = $FS::UID::AutoCommit;
2386   local $FS::UID::AutoCommit = 0;
2387
2388   warn "$me cancel called on customer ". $self->custnum. " with options ".
2389        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2390     if $DEBUG;
2391
2392   return ( 'access denied' )
2393     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2394
2395   if ( $opt{'ban'} ) {
2396
2397     foreach my $cust_payby ( $self->cust_payby ) {
2398
2399       #well, if they didn't get decrypted on search, then we don't have to
2400       # try again... queue a job for the server that does have decryption
2401       # capability if we're in a paranoid multi-server implementation?
2402       return ( "Can't (yet) ban encrypted credit cards" )
2403         if $cust_payby->is_encrypted($cust_payby->payinfo);
2404
2405       my $ban = new FS::banned_pay $cust_payby->_new_banned_pay_hashref;
2406       my $error = $ban->insert;
2407       if ($error) {
2408         dbh->rollback if $oldAutoCommit;
2409         return ( $error );
2410       }
2411
2412     }
2413
2414   }
2415
2416   my @pkgs = $self->ncancelled_pkgs;
2417
2418   # bill all packages first, so we don't lose usage, service counts for
2419   # bulk billing, etc.
2420   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2421     $opt{nobill} = 1;
2422     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2423     if ($error) {
2424       # we should return an error and exit in this case, yes?
2425       warn "Error billing during cancel, custnum ". $self->custnum. ": $error";
2426       dbh->rollback if $oldAutoCommit;
2427       return ( "Error billing during cancellation: $error" );
2428     }
2429   }
2430
2431   my @errors;
2432   # now cancel all services, the same way we would for individual packages
2433   my @cust_svc = map { $_->cust_svc } @pkgs;
2434   my @sorted_cust_svc =
2435     map  { $_->[0] }
2436     sort { $a->[1] <=> $b->[1] }
2437     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
2438     @cust_svc
2439   ;
2440   warn "$me removing ".scalar(@sorted_cust_svc)." service(s) for customer ".
2441     $self->custnum."\n"
2442     if $DEBUG;
2443   foreach my $cust_svc (@sorted_cust_svc) {
2444     my $part_svc = $cust_svc->part_svc;
2445     next if ( defined($part_svc) and $part_svc->preserve );
2446     my $error = $cust_svc->cancel; # immediate cancel, no date option
2447     push @errors, $error if $error;
2448   }
2449   if (@errors) {
2450     # then we won't get to the point of canceling packages
2451     dbh->rollback if $oldAutoCommit;
2452     return @errors;
2453   }
2454
2455   warn "$me cancelling ". scalar(@pkgs) ." package(s) for customer ".
2456     $self->custnum. "\n"
2457     if $DEBUG;
2458
2459   @errors = grep { $_ } map { $_->cancel(%opt) } @pkgs;
2460   if (@errors) {
2461     dbh->rollback if $oldAutoCommit;
2462     return @errors;
2463   }
2464
2465   return;
2466 }
2467
2468 sub _banned_pay_hashref {
2469   my $self = shift;
2470
2471   my %payby2ban = (
2472     'CARD' => 'CARD',
2473     'DCRD' => 'CARD',
2474     'CHEK' => 'CHEK',
2475     'DCHK' => 'CHEK'
2476   );
2477
2478   {
2479     'payby'   => $payby2ban{$self->payby},
2480     'payinfo' => $self->payinfo,
2481     #don't ever *search* on reason! #'reason'  =>
2482   };
2483 }
2484
2485 =item notes
2486
2487 Returns all notes (see L<FS::cust_main_note>) for this customer.
2488
2489 =cut
2490
2491 sub notes {
2492   my($self,$orderby_classnum) = (shift,shift);
2493   my $orderby = "sticky DESC, _date DESC";
2494   $orderby = "classnum ASC, $orderby" if $orderby_classnum;
2495   qsearch( 'cust_main_note',
2496            { 'custnum' => $self->custnum },
2497            '',
2498            "ORDER BY $orderby",
2499          );
2500 }
2501
2502 =item agent
2503
2504 Returns the agent (see L<FS::agent>) for this customer.
2505
2506 =item agent_name
2507
2508 Returns the agent name (see L<FS::agent>) for this customer.
2509
2510 =cut
2511
2512 sub agent_name {
2513   my $self = shift;
2514   $self->agent->agent;
2515 }
2516
2517 =item cust_tag
2518
2519 Returns any tags associated with this customer, as FS::cust_tag objects,
2520 or an empty list if there are no tags.
2521
2522 =item part_tag
2523
2524 Returns any tags associated with this customer, as FS::part_tag objects,
2525 or an empty list if there are no tags.
2526
2527 =cut
2528
2529 sub part_tag {
2530   my $self = shift;
2531   map $_->part_tag, $self->cust_tag;
2532 }
2533
2534
2535 =item cust_class
2536
2537 Returns the customer class, as an FS::cust_class object, or the empty string
2538 if there is no customer class.
2539
2540 =item categoryname
2541
2542 Returns the customer category name, or the empty string if there is no customer
2543 category.
2544
2545 =cut
2546
2547 sub categoryname {
2548   my $self = shift;
2549   my $cust_class = $self->cust_class;
2550   $cust_class
2551     ? $cust_class->categoryname
2552     : '';
2553 }
2554
2555 =item classname
2556
2557 Returns the customer class name, or the empty string if there is no customer
2558 class.
2559
2560 =cut
2561
2562 sub classname {
2563   my $self = shift;
2564   my $cust_class = $self->cust_class;
2565   $cust_class
2566     ? $cust_class->classname
2567     : '';
2568 }
2569
2570 =item tax_status
2571
2572 Returns the external tax status, as an FS::tax_status object, or the empty
2573 string if there is no tax status.
2574
2575 =cut
2576
2577 sub tax_status {
2578   my $self = shift;
2579   if ( $self->taxstatusnum ) {
2580     qsearchs('tax_status', { 'taxstatusnum' => $self->taxstatusnum } );
2581   } else {
2582     return '';
2583   }
2584 }
2585
2586 =item taxstatus
2587
2588 Returns the tax status code if there is one.
2589
2590 =cut
2591
2592 sub taxstatus {
2593   my $self = shift;
2594   my $tax_status = $self->tax_status;
2595   $tax_status
2596     ? $tax_status->taxstatus
2597     : '';
2598 }
2599
2600 =item BILLING METHODS
2601
2602 Documentation on billing methods has been moved to
2603 L<FS::cust_main::Billing>.
2604
2605 =item REALTIME BILLING METHODS
2606
2607 Documentation on realtime billing methods has been moved to
2608 L<FS::cust_main::Billing_Realtime>.
2609
2610 =item remove_cvv
2611
2612 Removes the I<paycvv> field from the database directly.
2613
2614 If there is an error, returns the error, otherwise returns false.
2615
2616 DEPRECATED.  Use L</remove_cvv_from_cust_payby> instead.
2617
2618 =cut
2619
2620 sub remove_cvv {
2621   my $self = shift;
2622   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2623     or return dbh->errstr;
2624   $sth->execute($self->custnum)
2625     or return $sth->errstr;
2626   $self->paycvv('');
2627   '';
2628 }
2629
2630 =item total_owed
2631
2632 Returns the total owed for this customer on all invoices
2633 (see L<FS::cust_bill/owed>).
2634
2635 =cut
2636
2637 sub total_owed {
2638   my $self = shift;
2639   $self->total_owed_date(2145859200); #12/31/2037
2640 }
2641
2642 =item total_owed_date TIME
2643
2644 Returns the total owed for this customer on all invoices with date earlier than
2645 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2646 see L<Time::Local> and L<Date::Parse> for conversion functions.
2647
2648 =cut
2649
2650 sub total_owed_date {
2651   my $self = shift;
2652   my $time = shift;
2653
2654   my $custnum = $self->custnum;
2655
2656   my $owed_sql = FS::cust_bill->owed_sql;
2657
2658   my $sql = "
2659     SELECT SUM($owed_sql) FROM cust_bill
2660       WHERE custnum = $custnum
2661         AND _date <= $time
2662   ";
2663
2664   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2665
2666 }
2667
2668 =item total_owed_pkgnum PKGNUM
2669
2670 Returns the total owed on all invoices for this customer's specific package
2671 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2672
2673 =cut
2674
2675 sub total_owed_pkgnum {
2676   my( $self, $pkgnum ) = @_;
2677   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2678 }
2679
2680 =item total_owed_date_pkgnum TIME PKGNUM
2681
2682 Returns the total owed for this customer's specific package when using
2683 experimental package balances on all invoices with date earlier than
2684 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2685 see L<Time::Local> and L<Date::Parse> for conversion functions.
2686
2687 =cut
2688
2689 sub total_owed_date_pkgnum {
2690   my( $self, $time, $pkgnum ) = @_;
2691
2692   my $total_bill = 0;
2693   foreach my $cust_bill (
2694     grep { $_->_date <= $time }
2695       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2696   ) {
2697     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2698   }
2699   sprintf( "%.2f", $total_bill );
2700
2701 }
2702
2703 =item total_paid
2704
2705 Returns the total amount of all payments.
2706
2707 =cut
2708
2709 sub total_paid {
2710   my $self = shift;
2711   my $total = 0;
2712   $total += $_->paid foreach $self->cust_pay;
2713   sprintf( "%.2f", $total );
2714 }
2715
2716 =item total_unapplied_credits
2717
2718 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2719 customer.  See L<FS::cust_credit/credited>.
2720
2721 =item total_credited
2722
2723 Old name for total_unapplied_credits.  Don't use.
2724
2725 =cut
2726
2727 sub total_credited {
2728   #carp "total_credited deprecated, use total_unapplied_credits";
2729   shift->total_unapplied_credits(@_);
2730 }
2731
2732 sub total_unapplied_credits {
2733   my $self = shift;
2734
2735   my $custnum = $self->custnum;
2736
2737   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2738
2739   my $sql = "
2740     SELECT SUM($unapplied_sql) FROM cust_credit
2741       WHERE custnum = $custnum
2742   ";
2743
2744   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2745
2746 }
2747
2748 =item total_unapplied_credits_pkgnum PKGNUM
2749
2750 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2751 customer.  See L<FS::cust_credit/credited>.
2752
2753 =cut
2754
2755 sub total_unapplied_credits_pkgnum {
2756   my( $self, $pkgnum ) = @_;
2757   my $total_credit = 0;
2758   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2759   sprintf( "%.2f", $total_credit );
2760 }
2761
2762
2763 =item total_unapplied_payments
2764
2765 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2766 See L<FS::cust_pay/unapplied>.
2767
2768 =cut
2769
2770 sub total_unapplied_payments {
2771   my $self = shift;
2772
2773   my $custnum = $self->custnum;
2774
2775   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2776
2777   my $sql = "
2778     SELECT SUM($unapplied_sql) FROM cust_pay
2779       WHERE custnum = $custnum
2780   ";
2781
2782   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2783
2784 }
2785
2786 =item total_unapplied_payments_pkgnum PKGNUM
2787
2788 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2789 specific package when using experimental package balances.  See
2790 L<FS::cust_pay/unapplied>.
2791
2792 =cut
2793
2794 sub total_unapplied_payments_pkgnum {
2795   my( $self, $pkgnum ) = @_;
2796   my $total_unapplied = 0;
2797   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2798   sprintf( "%.2f", $total_unapplied );
2799 }
2800
2801
2802 =item total_unapplied_refunds
2803
2804 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2805 customer.  See L<FS::cust_refund/unapplied>.
2806
2807 =cut
2808
2809 sub total_unapplied_refunds {
2810   my $self = shift;
2811   my $custnum = $self->custnum;
2812
2813   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2814
2815   my $sql = "
2816     SELECT SUM($unapplied_sql) FROM cust_refund
2817       WHERE custnum = $custnum
2818   ";
2819
2820   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2821
2822 }
2823
2824 =item balance
2825
2826 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2827 total_unapplied_credits minus total_unapplied_payments).
2828
2829 =cut
2830
2831 sub balance {
2832   my $self = shift;
2833   $self->balance_date_range;
2834 }
2835
2836 =item balance_date TIME
2837
2838 Returns the balance for this customer, only considering invoices with date
2839 earlier than TIME (total_owed_date minus total_credited minus
2840 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2841 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2842 functions.
2843
2844 =cut
2845
2846 sub balance_date {
2847   my $self = shift;
2848   $self->balance_date_range(shift);
2849 }
2850
2851 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2852
2853 Returns the balance for this customer, optionally considering invoices with
2854 date earlier than START_TIME, and not later than END_TIME
2855 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2856
2857 Times are specified as SQL fragments or numeric
2858 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2859 L<Date::Parse> for conversion functions.  The empty string can be passed
2860 to disable that time constraint completely.
2861
2862 Accepts the same options as L<balance_date_sql>:
2863
2864 =over 4
2865
2866 =item unapplied_date
2867
2868 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2869
2870 =item cutoff
2871
2872 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2873 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2874 range for invoices and I<unapplied> payments, credits, and refunds.
2875
2876 =back
2877
2878 =cut
2879
2880 sub balance_date_range {
2881   my $self = shift;
2882   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2883             ') FROM cust_main WHERE custnum='. $self->custnum;
2884   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2885 }
2886
2887 =item balance_pkgnum PKGNUM
2888
2889 Returns the balance for this customer's specific package when using
2890 experimental package balances (total_owed plus total_unrefunded, minus
2891 total_unapplied_credits minus total_unapplied_payments)
2892
2893 =cut
2894
2895 sub balance_pkgnum {
2896   my( $self, $pkgnum ) = @_;
2897
2898   sprintf( "%.2f",
2899       $self->total_owed_pkgnum($pkgnum)
2900 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2901 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2902     - $self->total_unapplied_credits_pkgnum($pkgnum)
2903     - $self->total_unapplied_payments_pkgnum($pkgnum)
2904   );
2905 }
2906
2907 =item payment_info
2908
2909 Returns a hash of useful information for making a payment.
2910
2911 =over 4
2912
2913 =item balance
2914
2915 Current balance.
2916
2917 =item payby
2918
2919 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2920 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2921 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2922
2923 =back
2924
2925 For credit card transactions:
2926
2927 =over 4
2928
2929 =item card_type 1
2930
2931 =item payname
2932
2933 Exact name on card
2934
2935 =back
2936
2937 For electronic check transactions:
2938
2939 =over 4
2940
2941 =item stateid_state
2942
2943 =back
2944
2945 =cut
2946
2947 sub payment_info {
2948   my $self = shift;
2949
2950   my %return = ();
2951
2952   $return{balance} = $self->balance;
2953
2954   $return{payname} = $self->payname
2955                      || ( $self->first. ' '. $self->get('last') );
2956
2957   $return{$_} = $self->bill_location->$_
2958     for qw(address1 address2 city state zip);
2959
2960   $return{payby} = $self->payby;
2961   $return{stateid_state} = $self->stateid_state;
2962
2963   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2964     $return{card_type} = cardtype($self->payinfo);
2965     $return{payinfo} = $self->paymask;
2966
2967     @return{'month', 'year'} = $self->paydate_monthyear;
2968
2969   }
2970
2971   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2972     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2973     $return{payinfo1} = $payinfo1;
2974     $return{payinfo2} = $payinfo2;
2975     $return{paytype}  = $self->paytype;
2976     $return{paystate} = $self->paystate;
2977
2978   }
2979
2980   #doubleclick protection
2981   my $_date = time;
2982   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2983
2984   %return;
2985
2986 }
2987
2988 =item paydate_epoch
2989
2990 Returns the next payment expiration date for this customer. If they have no
2991 payment methods that will expire, returns 0.
2992
2993 =cut
2994
2995 sub paydate_epoch {
2996   my $self = shift;
2997   # filter out the ones that individually return 0, but then return 0 if
2998   # there are no results
2999   my @epochs = grep { $_ > 0 } map { $_->paydate_epoch } $self->cust_payby;
3000   min( @epochs ) || 0;
3001 }
3002
3003 =item paydate_epoch_sql
3004
3005 Returns an SQL expression to get the next payment expiration date for a
3006 customer. Returns 2143260000 (2037-12-01) if there are no payment expiration
3007 dates, so that it's safe to test for "will it expire before date X" for any
3008 date up to then.
3009
3010 =cut
3011
3012 sub paydate_epoch_sql {
3013   my $class = shift;
3014   my $paydate = FS::cust_payby->paydate_epoch_sql;
3015   "(SELECT COALESCE(MIN($paydate), 2143260000) FROM cust_payby WHERE cust_payby.custnum = cust_main.custnum)";
3016 }
3017
3018 sub tax_exemption {
3019   my( $self, $taxname ) = @_;
3020
3021   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3022                                      'taxname' => $taxname,
3023                                    },
3024           );
3025 }
3026
3027 =item cust_main_exemption
3028
3029 =item invoicing_list
3030
3031 Returns a list of email addresses (with svcnum entries expanded), and the word
3032 'POST' if the customer receives postal invoices.
3033
3034 =cut
3035
3036 sub invoicing_list {
3037   my( $self, $arrayref ) = @_;
3038
3039   if ( $arrayref ) {
3040     warn "FS::cust_main::invoicing_list(ARRAY) is no longer supported.";
3041   }
3042
3043   my @emails = $self->invoicing_list_emailonly;
3044   push @emails, 'POST' if $self->get('postal_invoice');
3045
3046   @emails;
3047 }
3048
3049 =item check_invoicing_list ARRAYREF
3050
3051 Checks these arguements as valid input for the invoicing_list method.  If there
3052 is an error, returns the error, otherwise returns false.
3053
3054 =cut
3055
3056 sub check_invoicing_list {
3057   my( $self, $arrayref ) = @_;
3058
3059   foreach my $address ( @$arrayref ) {
3060
3061     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3062       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3063     }
3064
3065     my $cust_main_invoice = new FS::cust_main_invoice ( {
3066       'custnum' => $self->custnum,
3067       'dest'    => $address,
3068     } );
3069     my $error = $self->custnum
3070                 ? $cust_main_invoice->check
3071                 : $cust_main_invoice->checkdest
3072     ;
3073     return $error if $error;
3074
3075   }
3076
3077   return "Email address required"
3078     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3079     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3080
3081   '';
3082 }
3083
3084 =item all_emails
3085
3086 Returns the email addresses of all accounts provisioned for this customer.
3087
3088 =cut
3089
3090 sub all_emails {
3091   my $self = shift;
3092   my %list;
3093   foreach my $cust_pkg ( $self->all_pkgs ) {
3094     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3095     my @svc_acct =
3096       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3097         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3098           @cust_svc;
3099     $list{$_}=1 foreach map { $_->email } @svc_acct;
3100   }
3101   keys %list;
3102 }
3103
3104 =item invoicing_list_addpost
3105
3106 Adds postal invoicing to this customer.  If this customer is already configured
3107 to receive postal invoices, does nothing.
3108
3109 =cut
3110
3111 sub invoicing_list_addpost {
3112   my $self = shift;
3113   if ( $self->get('postal_invoice') eq '' ) {
3114     $self->set('postal_invoice', 'Y');
3115     my $error = $self->replace;
3116     warn $error if $error; # should fail harder, but this is traditional
3117   }
3118 }
3119
3120 =item invoicing_list_emailonly
3121
3122 Returns the list of email invoice recipients (invoicing_list without non-email
3123 destinations such as POST and FAX).
3124
3125 =cut
3126
3127 sub invoicing_list_emailonly {
3128   my $self = shift;
3129   warn "$me invoicing_list_emailonly called"
3130     if $DEBUG;
3131   return () if !$self->custnum; # not yet inserted
3132   return map { $_->emailaddress }
3133     qsearch({
3134         table     => 'cust_contact',
3135         select    => 'emailaddress',
3136         addl_from => ' JOIN contact USING (contactnum) '.
3137                      ' JOIN contact_email USING (contactnum)',
3138         hashref   => { 'custnum' => $self->custnum, },
3139         extra_sql => q( AND cust_contact.invoice_dest = 'Y'),
3140     });
3141 }
3142
3143 =item invoicing_list_emailonly_scalar
3144
3145 Returns the list of email invoice recipients (invoicing_list without non-email
3146 destinations such as POST and FAX) as a comma-separated scalar.
3147
3148 =cut
3149
3150 sub invoicing_list_emailonly_scalar {
3151   my $self = shift;
3152   warn "$me invoicing_list_emailonly_scalar called"
3153     if $DEBUG;
3154   join(', ', $self->invoicing_list_emailonly);
3155 }
3156
3157 =item contact_list [ CLASSNUM, ... ]
3158
3159 Returns a list of contacts (L<FS::contact> objects) for the customer. If
3160 a list of contact classnums is given, returns only contacts in those
3161 classes. If the pseudo-classnum 'invoice' is given, returns contacts that
3162 are marked as invoice destinations. If '0' is given, also returns contacts
3163 with no class.
3164
3165 If no arguments are given, returns all contacts for the customer.
3166
3167 =cut
3168
3169 sub contact_list {
3170   my $self = shift;
3171   my $search = {
3172     table       => 'contact',
3173     select      => 'contact.*, cust_contact.invoice_dest',
3174     addl_from   => ' JOIN cust_contact USING (contactnum)',
3175     extra_sql   => ' WHERE cust_contact.custnum = '.$self->custnum,
3176   };
3177
3178   my @orwhere;
3179   my @classnums;
3180   foreach (@_) {
3181     if ( $_ eq 'invoice' ) {
3182       push @orwhere, 'cust_contact.invoice_dest = \'Y\'';
3183     } elsif ( $_ eq '0' ) {
3184       push @orwhere, 'cust_contact.classnum is null';
3185     } elsif ( /^\d+$/ ) {
3186       push @classnums, $_;
3187     } else {
3188       die "bad classnum argument '$_'";
3189     }
3190   }
3191
3192   if (@classnums) {
3193     push @orwhere, 'cust_contact.classnum IN ('.join(',', @classnums).')';
3194   }
3195   if (@orwhere) {
3196     $search->{extra_sql} .= ' AND (' .
3197                             join(' OR ', map "( $_ )", @orwhere) .
3198                             ')';
3199   }
3200
3201   qsearch($search);
3202 }
3203
3204 =item contact_list_email [ CLASSNUM, ... ]
3205
3206 Same as L</contact_list>, but returns email destinations instead of contact
3207 objects.
3208
3209 =cut
3210
3211 sub contact_list_email {
3212   my $self = shift;
3213   my @contacts = $self->contact_list(@_);
3214   my @emails;
3215   foreach my $contact (@contacts) {
3216     foreach my $contact_email ($contact->contact_email) {
3217       push @emails,
3218         $contact->firstlast . ' <' . $contact_email->emailaddress . '>';
3219     }
3220   }
3221   @emails;
3222 }
3223
3224 =item referral_custnum_cust_main
3225
3226 Returns the customer who referred this customer (or the empty string, if
3227 this customer was not referred).
3228
3229 Note the difference with referral_cust_main method: This method,
3230 referral_custnum_cust_main returns the single customer (if any) who referred
3231 this customer, while referral_cust_main returns an array of customers referred
3232 BY this customer.
3233
3234 =cut
3235
3236 sub referral_custnum_cust_main {
3237   my $self = shift;
3238   return '' unless $self->referral_custnum;
3239   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3240 }
3241
3242 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3243
3244 Returns an array of customers referred by this customer (referral_custnum set
3245 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3246 customers referred by customers referred by this customer and so on, inclusive.
3247 The default behavior is DEPTH 1 (no recursion).
3248
3249 Note the difference with referral_custnum_cust_main method: This method,
3250 referral_cust_main, returns an array of customers referred BY this customer,
3251 while referral_custnum_cust_main returns the single customer (if any) who
3252 referred this customer.
3253
3254 =cut
3255
3256 sub referral_cust_main {
3257   my $self = shift;
3258   my $depth = @_ ? shift : 1;
3259   my $exclude = @_ ? shift : {};
3260
3261   my @cust_main =
3262     map { $exclude->{$_->custnum}++; $_; }
3263       grep { ! $exclude->{ $_->custnum } }
3264         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3265
3266   if ( $depth > 1 ) {
3267     push @cust_main,
3268       map { $_->referral_cust_main($depth-1, $exclude) }
3269         @cust_main;
3270   }
3271
3272   @cust_main;
3273 }
3274
3275 =item referral_cust_main_ncancelled
3276
3277 Same as referral_cust_main, except only returns customers with uncancelled
3278 packages.
3279
3280 =cut
3281
3282 sub referral_cust_main_ncancelled {
3283   my $self = shift;
3284   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3285 }
3286
3287 =item referral_cust_pkg [ DEPTH ]
3288
3289 Like referral_cust_main, except returns a flat list of all unsuspended (and
3290 uncancelled) packages for each customer.  The number of items in this list may
3291 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3292
3293 =cut
3294
3295 sub referral_cust_pkg {
3296   my $self = shift;
3297   my $depth = @_ ? shift : 1;
3298
3299   map { $_->unsuspended_pkgs }
3300     grep { $_->unsuspended_pkgs }
3301       $self->referral_cust_main($depth);
3302 }
3303
3304 =item referring_cust_main
3305
3306 Returns the single cust_main record for the customer who referred this customer
3307 (referral_custnum), or false.
3308
3309 =cut
3310
3311 sub referring_cust_main {
3312   my $self = shift;
3313   return '' unless $self->referral_custnum;
3314   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3315 }
3316
3317 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3318
3319 Applies a credit to this customer.  If there is an error, returns the error,
3320 otherwise returns false.
3321
3322 REASON can be a text string, an FS::reason object, or a scalar reference to
3323 a reasonnum.  If a text string, it will be automatically inserted as a new
3324 reason, and a 'reason_type' option must be passed to indicate the
3325 FS::reason_type for the new reason.
3326
3327 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3328 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3329 I<commission_pkgnum>.
3330
3331 Any other options are passed to FS::cust_credit::insert.
3332
3333 =cut
3334
3335 sub credit {
3336   my( $self, $amount, $reason, %options ) = @_;
3337
3338   my $cust_credit = new FS::cust_credit {
3339     'custnum' => $self->custnum,
3340     'amount'  => $amount,
3341   };
3342
3343   if ( ref($reason) ) {
3344
3345     if ( ref($reason) eq 'SCALAR' ) {
3346       $cust_credit->reasonnum( $$reason );
3347     } else {
3348       $cust_credit->reasonnum( $reason->reasonnum );
3349     }
3350
3351   } else {
3352     $cust_credit->set('reason', $reason)
3353   }
3354
3355   $cust_credit->$_( delete $options{$_} )
3356     foreach grep exists($options{$_}),
3357               qw( addlinfo eventnum ),
3358               map "commission_$_", qw( agentnum salesnum pkgnum );
3359
3360   $cust_credit->insert(%options);
3361
3362 }
3363
3364 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3365
3366 Creates a one-time charge for this customer.  If there is an error, returns
3367 the error, otherwise returns false.
3368
3369 New-style, with a hashref of options:
3370
3371   my $error = $cust_main->charge(
3372                                   {
3373                                     'amount'     => 54.32,
3374                                     'quantity'   => 1,
3375                                     'start_date' => str2time('7/4/2009'),
3376                                     'pkg'        => 'Description',
3377                                     'comment'    => 'Comment',
3378                                     'additional' => [], #extra invoice detail
3379                                     'classnum'   => 1,  #pkg_class
3380
3381                                     'setuptax'   => '', # or 'Y' for tax exempt
3382
3383                                     'locationnum'=> 1234, # optional
3384
3385                                     #internal taxation
3386                                     'taxclass'   => 'Tax class',
3387
3388                                     #vendor taxation
3389                                     'taxproduct' => 2,  #part_pkg_taxproduct
3390                                     'override'   => {}, #XXX describe
3391
3392                                     #will be filled in with the new object
3393                                     'cust_pkg_ref' => \$cust_pkg,
3394
3395                                     #generate an invoice immediately
3396                                     'bill_now' => 0,
3397                                     'invoice_terms' => '', #with these terms
3398                                   }
3399                                 );
3400
3401 Old-style:
3402
3403   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3404
3405 =cut
3406
3407 #super false laziness w/quotation::charge
3408 sub charge {
3409   my $self = shift;
3410   my ( $amount, $setup_cost, $quantity, $start_date, $classnum );
3411   my ( $pkg, $comment, $additional );
3412   my ( $setuptax, $taxclass );   #internal taxes
3413   my ( $taxproduct, $override ); #vendor (CCH) taxes
3414   my $no_auto = '';
3415   my $separate_bill = '';
3416   my $cust_pkg_ref = '';
3417   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3418   my $locationnum;
3419   if ( ref( $_[0] ) ) {
3420     $amount     = $_[0]->{amount};
3421     $setup_cost = $_[0]->{setup_cost};
3422     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3423     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3424     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3425     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3426     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3427                                            : '$'. sprintf("%.2f",$amount);
3428     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3429     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3430     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3431     $additional = $_[0]->{additional} || [];
3432     $taxproduct = $_[0]->{taxproductnum};
3433     $override   = { '' => $_[0]->{tax_override} };
3434     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3435     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3436     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3437     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3438     $separate_bill = $_[0]->{separate_bill} || '';
3439   } else { # yuck
3440     $amount     = shift;
3441     $setup_cost = '';
3442     $quantity   = 1;
3443     $start_date = '';
3444     $pkg        = @_ ? shift : 'One-time charge';
3445     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3446     $setuptax   = '';
3447     $taxclass   = @_ ? shift : '';
3448     $additional = [];
3449   }
3450
3451   local $SIG{HUP} = 'IGNORE';
3452   local $SIG{INT} = 'IGNORE';
3453   local $SIG{QUIT} = 'IGNORE';
3454   local $SIG{TERM} = 'IGNORE';
3455   local $SIG{TSTP} = 'IGNORE';
3456   local $SIG{PIPE} = 'IGNORE';
3457
3458   my $oldAutoCommit = $FS::UID::AutoCommit;
3459   local $FS::UID::AutoCommit = 0;
3460   my $dbh = dbh;
3461
3462   my $part_pkg = new FS::part_pkg ( {
3463     'pkg'           => $pkg,
3464     'comment'       => $comment,
3465     'plan'          => 'flat',
3466     'freq'          => 0,
3467     'disabled'      => 'Y',
3468     'classnum'      => ( $classnum ? $classnum : '' ),
3469     'setuptax'      => $setuptax,
3470     'taxclass'      => $taxclass,
3471     'taxproductnum' => $taxproduct,
3472     'setup_cost'    => $setup_cost,
3473   } );
3474
3475   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3476                         ( 0 .. @$additional - 1 )
3477                   ),
3478                   'additional_count' => scalar(@$additional),
3479                   'setup_fee' => $amount,
3480                 );
3481
3482   my $error = $part_pkg->insert( options       => \%options,
3483                                  tax_overrides => $override,
3484                                );
3485   if ( $error ) {
3486     $dbh->rollback if $oldAutoCommit;
3487     return $error;
3488   }
3489
3490   my $pkgpart = $part_pkg->pkgpart;
3491   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3492   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3493     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3494     $error = $type_pkgs->insert;
3495     if ( $error ) {
3496       $dbh->rollback if $oldAutoCommit;
3497       return $error;
3498     }
3499   }
3500
3501   my $cust_pkg = new FS::cust_pkg ( {
3502     'custnum'    => $self->custnum,
3503     'pkgpart'    => $pkgpart,
3504     'quantity'   => $quantity,
3505     'start_date' => $start_date,
3506     'no_auto'    => $no_auto,
3507     'separate_bill' => $separate_bill,
3508     'locationnum'=> $locationnum,
3509   } );
3510
3511   $error = $cust_pkg->insert;
3512   if ( $error ) {
3513     $dbh->rollback if $oldAutoCommit;
3514     return $error;
3515   } elsif ( $cust_pkg_ref ) {
3516     ${$cust_pkg_ref} = $cust_pkg;
3517   }
3518
3519   if ( $bill_now ) {
3520     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3521                              'pkg_list'      => [ $cust_pkg ],
3522                            );
3523     if ( $error ) {
3524       $dbh->rollback if $oldAutoCommit;
3525       return $error;
3526     }
3527   }
3528
3529   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3530   return '';
3531
3532 }
3533
3534 #=item charge_postal_fee
3535 #
3536 #Applies a one time charge this customer.  If there is an error,
3537 #returns the error, returns the cust_pkg charge object or false
3538 #if there was no charge.
3539 #
3540 #=cut
3541 #
3542 # This should be a customer event.  For that to work requires that bill
3543 # also be a customer event.
3544
3545 sub charge_postal_fee {
3546   my $self = shift;
3547
3548   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3549   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3550
3551   my $cust_pkg = new FS::cust_pkg ( {
3552     'custnum'  => $self->custnum,
3553     'pkgpart'  => $pkgpart,
3554     'quantity' => 1,
3555   } );
3556
3557   my $error = $cust_pkg->insert;
3558   $error ? $error : $cust_pkg;
3559 }
3560
3561 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3562
3563 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3564
3565 Optionally, a list or hashref of additional arguments to the qsearch call can
3566 be passed.
3567
3568 =cut
3569
3570 sub cust_bill {
3571   my $self = shift;
3572   my $opt = ref($_[0]) ? shift : { @_ };
3573
3574   #return $self->num_cust_bill unless wantarray || keys %$opt;
3575
3576   $opt->{'table'} = 'cust_bill';
3577   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3578   $opt->{'hashref'}{'custnum'} = $self->custnum;
3579   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3580
3581   map { $_ } #behavior of sort undefined in scalar context
3582     sort { $a->_date <=> $b->_date }
3583       qsearch($opt);
3584 }
3585
3586 =item open_cust_bill
3587
3588 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3589 customer.
3590
3591 =cut
3592
3593 sub open_cust_bill {
3594   my $self = shift;
3595
3596   $self->cust_bill(
3597     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3598     #@_
3599   );
3600
3601 }
3602
3603 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3604
3605 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3606
3607 =cut
3608
3609 sub legacy_cust_bill {
3610   my $self = shift;
3611
3612   #return $self->num_legacy_cust_bill unless wantarray;
3613
3614   map { $_ } #behavior of sort undefined in scalar context
3615     sort { $a->_date <=> $b->_date }
3616       qsearch({ 'table'    => 'legacy_cust_bill',
3617                 'hashref'  => { 'custnum' => $self->custnum, },
3618                 'order_by' => 'ORDER BY _date ASC',
3619              });
3620 }
3621
3622 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3623
3624 Returns all the statements (see L<FS::cust_statement>) for this customer.
3625
3626 Optionally, a list or hashref of additional arguments to the qsearch call can
3627 be passed.
3628
3629 =cut
3630
3631 =item cust_bill_void
3632
3633 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3634
3635 =cut
3636
3637 sub cust_bill_void {
3638   my $self = shift;
3639
3640   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3641   sort { $a->_date <=> $b->_date }
3642     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3643 }
3644
3645 sub cust_statement {
3646   my $self = shift;
3647   my $opt = ref($_[0]) ? shift : { @_ };
3648
3649   #return $self->num_cust_statement unless wantarray || keys %$opt;
3650
3651   $opt->{'table'} = 'cust_statement';
3652   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3653   $opt->{'hashref'}{'custnum'} = $self->custnum;
3654   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3655
3656   map { $_ } #behavior of sort undefined in scalar context
3657     sort { $a->_date <=> $b->_date }
3658       qsearch($opt);
3659 }
3660
3661 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3662
3663 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3664
3665 Optionally, a list or hashref of additional arguments to the qsearch call can
3666 be passed following the SVCDB.
3667
3668 =cut
3669
3670 sub svc_x {
3671   my $self = shift;
3672   my $svcdb = shift;
3673   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3674     warn "$me svc_x requires a svcdb";
3675     return;
3676   }
3677   my $opt = ref($_[0]) ? shift : { @_ };
3678
3679   $opt->{'table'} = $svcdb;
3680   $opt->{'addl_from'} =
3681     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3682     ($opt->{'addl_from'} || '');
3683
3684   my $custnum = $self->custnum;
3685   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3686   my $where = "cust_pkg.custnum = $custnum";
3687
3688   my $extra_sql = $opt->{'extra_sql'} || '';
3689   if ( keys %{ $opt->{'hashref'} } ) {
3690     $extra_sql = " AND $where $extra_sql";
3691   }
3692   else {
3693     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3694       $extra_sql = "WHERE $where AND $1";
3695     }
3696     else {
3697       $extra_sql = "WHERE $where $extra_sql";
3698     }
3699   }
3700   $opt->{'extra_sql'} = $extra_sql;
3701
3702   qsearch($opt);
3703 }
3704
3705 # required for use as an eventtable;
3706 sub svc_acct {
3707   my $self = shift;
3708   $self->svc_x('svc_acct', @_);
3709 }
3710
3711 =item cust_credit
3712
3713 Returns all the credits (see L<FS::cust_credit>) for this customer.
3714
3715 =cut
3716
3717 sub cust_credit {
3718   my $self = shift;
3719
3720   #return $self->num_cust_credit unless wantarray;
3721
3722   map { $_ } #behavior of sort undefined in scalar context
3723     sort { $a->_date <=> $b->_date }
3724       qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3725 }
3726
3727 =item cust_credit_pkgnum
3728
3729 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3730 package when using experimental package balances.
3731
3732 =cut
3733
3734 sub cust_credit_pkgnum {
3735   my( $self, $pkgnum ) = @_;
3736   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3737   sort { $a->_date <=> $b->_date }
3738     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3739                               'pkgnum'  => $pkgnum,
3740                             }
3741     );
3742 }
3743
3744 =item cust_credit_void
3745
3746 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3747
3748 =cut
3749
3750 sub cust_credit_void {
3751   my $self = shift;
3752   map { $_ }
3753   sort { $a->_date <=> $b->_date }
3754     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3755 }
3756
3757 =item cust_pay
3758
3759 Returns all the payments (see L<FS::cust_pay>) for this customer.
3760
3761 =cut
3762
3763 sub cust_pay {
3764   my $self = shift;
3765   my $opt = ref($_[0]) ? shift : { @_ };
3766
3767   return $self->num_cust_pay unless wantarray || keys %$opt;
3768
3769   $opt->{'table'} = 'cust_pay';
3770   $opt->{'hashref'}{'custnum'} = $self->custnum;
3771
3772   map { $_ } #behavior of sort undefined in scalar context
3773     sort { $a->_date <=> $b->_date }
3774       qsearch($opt);
3775
3776 }
3777
3778 =item num_cust_pay
3779
3780 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3781 called automatically when the cust_pay method is used in a scalar context.
3782
3783 =cut
3784
3785 sub num_cust_pay {
3786   my $self = shift;
3787   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3788   my $sth = dbh->prepare($sql) or die dbh->errstr;
3789   $sth->execute($self->custnum) or die $sth->errstr;
3790   $sth->fetchrow_arrayref->[0];
3791 }
3792
3793 =item unapplied_cust_pay
3794
3795 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3796
3797 =cut
3798
3799 sub unapplied_cust_pay {
3800   my $self = shift;
3801
3802   $self->cust_pay(
3803     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3804     #@_
3805   );
3806
3807 }
3808
3809 =item cust_pay_pkgnum
3810
3811 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3812 package when using experimental package balances.
3813
3814 =cut
3815
3816 sub cust_pay_pkgnum {
3817   my( $self, $pkgnum ) = @_;
3818   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3819   sort { $a->_date <=> $b->_date }
3820     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3821                            'pkgnum'  => $pkgnum,
3822                          }
3823     );
3824 }
3825
3826 =item cust_pay_void
3827
3828 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3829
3830 =cut
3831
3832 sub cust_pay_void {
3833   my $self = shift;
3834   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3835   sort { $a->_date <=> $b->_date }
3836     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3837 }
3838
3839 =item cust_pay_pending
3840
3841 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3842 (without status "done").
3843
3844 =cut
3845
3846 sub cust_pay_pending {
3847   my $self = shift;
3848   return $self->num_cust_pay_pending unless wantarray;
3849   sort { $a->_date <=> $b->_date }
3850     qsearch( 'cust_pay_pending', {
3851                                    'custnum' => $self->custnum,
3852                                    'status'  => { op=>'!=', value=>'done' },
3853                                  },
3854            );
3855 }
3856
3857 =item cust_pay_pending_attempt
3858
3859 Returns all payment attempts / declined payments for this customer, as pending
3860 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3861 a corresponding payment (see L<FS::cust_pay>).
3862
3863 =cut
3864
3865 sub cust_pay_pending_attempt {
3866   my $self = shift;
3867   return $self->num_cust_pay_pending_attempt unless wantarray;
3868   sort { $a->_date <=> $b->_date }
3869     qsearch( 'cust_pay_pending', {
3870                                    'custnum' => $self->custnum,
3871                                    'status'  => 'done',
3872                                    'paynum'  => '',
3873                                  },
3874            );
3875 }
3876
3877 =item num_cust_pay_pending
3878
3879 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3880 customer (without status "done").  Also called automatically when the
3881 cust_pay_pending method is used in a scalar context.
3882
3883 =cut
3884
3885 sub num_cust_pay_pending {
3886   my $self = shift;
3887   $self->scalar_sql(
3888     " SELECT COUNT(*) FROM cust_pay_pending ".
3889       " WHERE custnum = ? AND status != 'done' ",
3890     $self->custnum
3891   );
3892 }
3893
3894 =item num_cust_pay_pending_attempt
3895
3896 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3897 customer, with status "done" but without a corresp.  Also called automatically when the
3898 cust_pay_pending method is used in a scalar context.
3899
3900 =cut
3901
3902 sub num_cust_pay_pending_attempt {
3903   my $self = shift;
3904   $self->scalar_sql(
3905     " SELECT COUNT(*) FROM cust_pay_pending ".
3906       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3907     $self->custnum
3908   );
3909 }
3910
3911 =item cust_refund
3912
3913 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3914
3915 =cut
3916
3917 sub cust_refund {
3918   my $self = shift;
3919   map { $_ } #return $self->num_cust_refund unless wantarray;
3920   sort { $a->_date <=> $b->_date }
3921     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3922 }
3923
3924 =item display_custnum
3925
3926 Returns the displayed customer number for this customer: agent_custid if
3927 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3928
3929 =cut
3930
3931 sub display_custnum {
3932   my $self = shift;
3933
3934   return $self->agent_custid
3935     if $default_agent_custid && $self->agent_custid;
3936
3937   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3938
3939   if ( $prefix ) {
3940     return $prefix .
3941            sprintf('%0'.($custnum_display_length||8).'d', $self->custnum)
3942   } elsif ( $custnum_display_length ) {
3943     return sprintf('%0'.$custnum_display_length.'d', $self->custnum);
3944   } else {
3945     return $self->custnum;
3946   }
3947 }
3948
3949 =item name
3950
3951 Returns a name string for this customer, either "Company (Last, First)" or
3952 "Last, First".
3953
3954 =cut
3955
3956 sub name {
3957   my $self = shift;
3958   my $name = $self->contact;
3959   $name = $self->company. " ($name)" if $self->company;
3960   $name;
3961 }
3962
3963 =item service_contact
3964
3965 Returns the L<FS::contact> object for this customer that has the 'Service'
3966 contact class, or undef if there is no such contact.  Deprecated; don't use
3967 this in new code.
3968
3969 =cut
3970
3971 sub service_contact {
3972   my $self = shift;
3973   if ( !exists($self->{service_contact}) ) {
3974     my $classnum = $self->scalar_sql(
3975       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
3976     ) || 0; #if it's zero, qsearchs will return nothing
3977     my $cust_contact = qsearchs('cust_contact', {
3978         'classnum' => $classnum,
3979         'custnum'  => $self->custnum,
3980     });
3981     $self->{service_contact} = $cust_contact->contact if $cust_contact;
3982   }
3983   $self->{service_contact};
3984 }
3985
3986 =item ship_name
3987
3988 Returns a name string for this (service/shipping) contact, either
3989 "Company (Last, First)" or "Last, First".
3990
3991 =cut
3992
3993 sub ship_name {
3994   my $self = shift;
3995
3996   my $name = $self->ship_contact;
3997   $name = $self->company. " ($name)" if $self->company;
3998   $name;
3999 }
4000
4001 =item name_short
4002
4003 Returns a name string for this customer, either "Company" or "First Last".
4004
4005 =cut
4006
4007 sub name_short {
4008   my $self = shift;
4009   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4010 }
4011
4012 =item ship_name_short
4013
4014 Returns a name string for this (service/shipping) contact, either "Company"
4015 or "First Last".
4016
4017 =cut
4018
4019 sub ship_name_short {
4020   my $self = shift;
4021   $self->service_contact
4022     ? $self->ship_contact_firstlast
4023     : $self->name_short
4024 }
4025
4026 =item contact
4027
4028 Returns this customer's full (billing) contact name only, "Last, First"
4029
4030 =cut
4031
4032 sub contact {
4033   my $self = shift;
4034   $self->get('last'). ', '. $self->first;
4035 }
4036
4037 =item ship_contact
4038
4039 Returns this customer's full (shipping) contact name only, "Last, First"
4040
4041 =cut
4042
4043 sub ship_contact {
4044   my $self = shift;
4045   my $contact = $self->service_contact || $self;
4046   $contact->get('last') . ', ' . $contact->get('first');
4047 }
4048
4049 =item contact_firstlast
4050
4051 Returns this customers full (billing) contact name only, "First Last".
4052
4053 =cut
4054
4055 sub contact_firstlast {
4056   my $self = shift;
4057   $self->first. ' '. $self->get('last');
4058 }
4059
4060 =item ship_contact_firstlast
4061
4062 Returns this customer's full (shipping) contact name only, "First Last".
4063
4064 =cut
4065
4066 sub ship_contact_firstlast {
4067   my $self = shift;
4068   my $contact = $self->service_contact || $self;
4069   $contact->get('first') . ' '. $contact->get('last');
4070 }
4071
4072 sub bill_country_full {
4073   my $self = shift;
4074   $self->bill_location->country_full;
4075 }
4076
4077 sub ship_country_full {
4078   my $self = shift;
4079   $self->ship_location->country_full;
4080 }
4081
4082 =item county_state_county [ PREFIX ]
4083
4084 Returns a string consisting of just the county, state and country.
4085
4086 =cut
4087
4088 sub county_state_country {
4089   my $self = shift;
4090   my $locationnum;
4091   if ( @_ && $_[0] && $self->has_ship_address ) {
4092     $locationnum = $self->ship_locationnum;
4093   } else {
4094     $locationnum = $self->bill_locationnum;
4095   }
4096   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4097   $cust_location->county_state_country;
4098 }
4099
4100 =item geocode DATA_VENDOR
4101
4102 Returns a value for the customer location as encoded by DATA_VENDOR.
4103 Currently this only makes sense for "CCH" as DATA_VENDOR.
4104
4105 =cut
4106
4107 =item cust_status
4108
4109 =item status
4110
4111 Returns a status string for this customer, currently:
4112
4113 =over 4
4114
4115 =item prospect
4116
4117 No packages have ever been ordered.  Displayed as "No packages".
4118
4119 =item ordered
4120
4121 Recurring packages all are new (not yet billed).
4122
4123 =item active
4124
4125 One or more recurring packages is active.
4126
4127 =item inactive
4128
4129 No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled).
4130
4131 =item suspended
4132
4133 All non-cancelled recurring packages are suspended.
4134
4135 =item cancelled
4136
4137 All recurring packages are cancelled.
4138
4139 =back
4140
4141 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4142 cust_main-status_module configuration option.
4143
4144 =cut
4145
4146 sub status { shift->cust_status(@_); }
4147
4148 sub cust_status {
4149   my $self = shift;
4150   return $self->hashref->{cust_status} if $self->hashref->{cust_status};
4151   for my $status ( FS::cust_main->statuses() ) {
4152     my $method = $status.'_sql';
4153     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4154     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4155     $sth->execute( ($self->custnum) x $numnum )
4156       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4157     if ( $sth->fetchrow_arrayref->[0] ) {
4158       $self->hashref->{cust_status} = $status;
4159       return $status;
4160     }
4161   }
4162 }
4163
4164 =item is_status_delay_cancel
4165
4166 Returns true if customer status is 'suspended'
4167 and all suspended cust_pkg return true for
4168 cust_pkg->is_status_delay_cancel.
4169
4170 This is not a real status, this only meant for hacking display
4171 values, because otherwise treating the customer as suspended is
4172 really the whole point of the delay_cancel option.
4173
4174 =cut
4175
4176 sub is_status_delay_cancel {
4177   my ($self) = @_;
4178   return 0 unless $self->status eq 'suspended';
4179   foreach my $cust_pkg ($self->ncancelled_pkgs) {
4180     return 0 unless $cust_pkg->is_status_delay_cancel;
4181   }
4182   return 1;
4183 }
4184
4185 =item ucfirst_cust_status
4186
4187 =item ucfirst_status
4188
4189 Deprecated, use the cust_status_label method instead.
4190
4191 Returns the status with the first character capitalized.
4192
4193 =cut
4194
4195 sub ucfirst_status {
4196   carp "ucfirst_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4197   local($ucfirst_nowarn) = 1;
4198   shift->ucfirst_cust_status(@_);
4199 }
4200
4201 sub ucfirst_cust_status {
4202   carp "ucfirst_cust_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
4203   my $self = shift;
4204   ucfirst($self->cust_status);
4205 }
4206
4207 =item cust_status_label
4208
4209 =item status_label
4210
4211 Returns the display label for this status.
4212
4213 =cut
4214
4215 sub status_label { shift->cust_status_label(@_); }
4216
4217 sub cust_status_label {
4218   my $self = shift;
4219   __PACKAGE__->statuslabels->{$self->cust_status};
4220 }
4221
4222 =item statuscolor
4223
4224 Returns a hex triplet color string for this customer's status.
4225
4226 =cut
4227
4228 sub statuscolor { shift->cust_statuscolor(@_); }
4229
4230 sub cust_statuscolor {
4231   my $self = shift;
4232   __PACKAGE__->statuscolors->{$self->cust_status};
4233 }
4234
4235 =item tickets [ STATUS ]
4236
4237 Returns an array of hashes representing the customer's RT tickets.
4238
4239 An optional status (or arrayref or hashref of statuses) may be specified.
4240
4241 =cut
4242
4243 sub tickets {
4244   my $self = shift;
4245   my $status = ( @_ && $_[0] ) ? shift : '';
4246
4247   my $num = $conf->config('cust_main-max_tickets') || 10;
4248   my @tickets = ();
4249
4250   if ( $conf->config('ticket_system') ) {
4251     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4252
4253       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
4254                                                         $num,
4255                                                         undef,
4256                                                         $status,
4257                                                       )
4258                   };
4259
4260     } else {
4261
4262       foreach my $priority (
4263         $conf->config('ticket_system-custom_priority_field-values'), ''
4264       ) {
4265         last if scalar(@tickets) >= $num;
4266         push @tickets,
4267           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4268                                                  $num - scalar(@tickets),
4269                                                  $priority,
4270                                                  $status,
4271                                                )
4272            };
4273       }
4274     }
4275   }
4276   (@tickets);
4277 }
4278
4279 =item appointments [ STATUS ]
4280
4281 Returns an array of hashes representing the customer's RT tickets which
4282 are appointments.
4283
4284 =cut
4285
4286 sub appointments {
4287   my $self = shift;
4288   my $status = ( @_ && $_[0] ) ? shift : '';
4289
4290   return () unless $conf->config('ticket_system');
4291
4292   my $queueid = $conf->config('ticket_system-appointment-queueid');
4293
4294   @{ FS::TicketSystem->customer_tickets( $self->custnum,
4295                                          99,
4296                                          undef,
4297                                          $status,
4298                                          $queueid,
4299                                        )
4300   };
4301 }
4302
4303 # Return services representing svc_accts in customer support packages
4304 sub support_services {
4305   my $self = shift;
4306   my %packages = map { $_ => 1 } $conf->config('support_packages');
4307
4308   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4309     grep { $_->part_svc->svcdb eq 'svc_acct' }
4310     map { $_->cust_svc }
4311     grep { exists $packages{ $_->pkgpart } }
4312     $self->ncancelled_pkgs;
4313
4314 }
4315
4316 # Return a list of latitude/longitude for one of the services (if any)
4317 sub service_coordinates {
4318   my $self = shift;
4319
4320   my @svc_X =
4321     grep { $_->latitude && $_->longitude }
4322     map { $_->svc_x }
4323     map { $_->cust_svc }
4324     $self->ncancelled_pkgs;
4325
4326   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4327 }
4328
4329 =item masked FIELD
4330
4331 Returns a masked version of the named field
4332
4333 =cut
4334
4335 sub masked {
4336 my ($self,$field) = @_;
4337
4338 # Show last four
4339
4340 'x'x(length($self->getfield($field))-4).
4341   substr($self->getfield($field), (length($self->getfield($field))-4));
4342
4343 }
4344
4345 =item payment_history
4346
4347 Returns an array of hashrefs standardizing information from cust_bill, cust_pay,
4348 cust_credit and cust_refund objects.  Each hashref has the following fields:
4349
4350 I<type> - one of 'Line item', 'Invoice', 'Payment', 'Credit', 'Refund' or 'Previous'
4351
4352 I<date> - value of _date field, unix timestamp
4353
4354 I<date_pretty> - user-friendly date
4355
4356 I<description> - user-friendly description of item
4357
4358 I<amount> - impact of item on user's balance
4359 (positive for Invoice/Refund/Line item, negative for Payment/Credit.)
4360 Not to be confused with the native 'amount' field in cust_credit, see below.
4361
4362 I<amount_pretty> - includes money char
4363
4364 I<balance> - customer balance, chronologically as of this item
4365
4366 I<balance_pretty> - includes money char
4367
4368 I<charged> - amount charged for cust_bill (Invoice or Line item) records, undef for other types
4369
4370 I<paid> - amount paid for cust_pay records, undef for other types
4371
4372 I<credit> - amount credited for cust_credit records, undef for other types.
4373 Literally the 'amount' field from cust_credit, renamed here to avoid confusion.
4374
4375 I<refund> - amount refunded for cust_refund records, undef for other types
4376
4377 The four table-specific keys always have positive values, whether they reflect charges or payments.
4378
4379 The following options may be passed to this method:
4380
4381 I<line_items> - if true, returns charges ('Line item') rather than invoices
4382
4383 I<start_date> - unix timestamp, only include records on or after.
4384 If specified, an item of type 'Previous' will also be included.
4385 It does not have table-specific fields.
4386
4387 I<end_date> - unix timestamp, only include records before
4388
4389 I<reverse_sort> - order from newest to oldest (default is oldest to newest)
4390
4391 I<conf> - optional already-loaded FS::Conf object.
4392
4393 =cut
4394
4395 # Caution: this gets used by FS::ClientAPI::MyAccount::billing_history,
4396 # and also for sending customer statements, which should both be kept customer-friendly.
4397 # If you add anything that shouldn't be passed on through the API or exposed
4398 # to customers, add a new option to include it, don't include it by default
4399 sub payment_history {
4400   my $self = shift;
4401   my $opt = ref($_[0]) ? $_[0] : { @_ };
4402
4403   my $conf = $$opt{'conf'} || new FS::Conf;
4404   my $money_char = $conf->config("money_char") || '$',
4405
4406   #first load entire history,
4407   #need previous to calculate previous balance
4408   #loading after end_date shouldn't hurt too much?
4409   my @history = ();
4410   if ( $$opt{'line_items'} ) {
4411
4412     foreach my $cust_bill ( $self->cust_bill ) {
4413
4414       push @history, {
4415         'type'        => 'Line item',
4416         'description' => $_->desc( $self->locale ).
4417                            ( $_->sdate && $_->edate
4418                                ? ' '. time2str('%d-%b-%Y', $_->sdate).
4419                                  ' To '. time2str('%d-%b-%Y', $_->edate)
4420                                : ''
4421                            ),
4422         'amount'      => sprintf('%.2f', $_->setup + $_->recur ),
4423         'charged'     => sprintf('%.2f', $_->setup + $_->recur ),
4424         'date'        => $cust_bill->_date,
4425         'date_pretty' => $self->time2str_local('short', $cust_bill->_date ),
4426       }
4427         foreach $cust_bill->cust_bill_pkg;
4428
4429     }
4430
4431   } else {
4432
4433     push @history, {
4434                      'type'        => 'Invoice',
4435                      'description' => 'Invoice #'. $_->display_invnum,
4436                      'amount'      => sprintf('%.2f', $_->charged ),
4437                      'charged'     => sprintf('%.2f', $_->charged ),
4438                      'date'        => $_->_date,
4439                      'date_pretty' => $self->time2str_local('short', $_->_date ),
4440                    }
4441       foreach $self->cust_bill;
4442
4443   }
4444
4445   push @history, {
4446                    'type'        => 'Payment',
4447                    'description' => 'Payment', #XXX type
4448                    'amount'      => sprintf('%.2f', 0 - $_->paid ),
4449                    'paid'        => sprintf('%.2f', $_->paid ),
4450                    'date'        => $_->_date,
4451                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4452                  }
4453     foreach $self->cust_pay;
4454
4455   push @history, {
4456                    'type'        => 'Credit',
4457                    'description' => 'Credit', #more info?
4458                    'amount'      => sprintf('%.2f', 0 -$_->amount ),
4459                    'credit'      => sprintf('%.2f', $_->amount ),
4460                    'date'        => $_->_date,
4461                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4462                  }
4463     foreach $self->cust_credit;
4464
4465   push @history, {
4466                    'type'        => 'Refund',
4467                    'description' => 'Refund', #more info?  type, like payment?
4468                    'amount'      => $_->refund,
4469                    'refund'      => $_->refund,
4470                    'date'        => $_->_date,
4471                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4472                  }
4473     foreach $self->cust_refund;
4474
4475   #put it all in chronological order
4476   @history = sort { $a->{'date'} <=> $b->{'date'} } @history;
4477
4478   #calculate balance, filter items outside date range
4479   my $previous = 0;
4480   my $balance = 0;
4481   my @out = ();
4482   foreach my $item (@history) {
4483     last if $$opt{'end_date'} && ($$item{'date'} >= $$opt{'end_date'});
4484     $balance += $$item{'amount'};
4485     if ($$opt{'start_date'} && ($$item{'date'} < $$opt{'start_date'})) {
4486       $previous += $$item{'amount'};
4487       next;
4488     }
4489     $$item{'balance'} = sprintf("%.2f",$balance);
4490     foreach my $key ( qw(amount balance) ) {
4491       $$item{$key.'_pretty'} = money_pretty($$item{$key});
4492     }
4493     push(@out,$item);
4494   }
4495
4496   # start with previous balance, if there was one
4497   if ($previous) {
4498     my $item = {
4499       'type'        => 'Previous',
4500       'description' => 'Previous balance',
4501       'amount'      => sprintf("%.2f",$previous),
4502       'balance'     => sprintf("%.2f",$previous),
4503       'date'        => $$opt{'start_date'},
4504       'date_pretty' => $self->time2str_local('short', $$opt{'start_date'} ),
4505     };
4506     #false laziness with above
4507     foreach my $key ( qw(amount balance) ) {
4508       $$item{$key.'_pretty'} = $$item{$key};
4509       $$item{$key.'_pretty'} =~ s/^(-?)/$1$money_char/;
4510     }
4511     unshift(@out,$item);
4512   }
4513
4514   @out = reverse @history if $$opt{'reverse_sort'};
4515
4516   return @out;
4517 }
4518
4519 =item save_cust_payby
4520
4521 Saves a new cust_payby for this customer, replacing an existing entry only
4522 in select circumstances.  Does not validate input.
4523
4524 If auto is specified, marks this as the customer's primary method, or the
4525 specified weight.  Existing payment methods have their weight incremented as
4526 appropriate.
4527
4528 If bill_location is specified with auto, also sets location in cust_main.
4529
4530 Will not insert complete duplicates of existing records, or records in which the
4531 only difference from an existing record is to turn off automatic payment (will
4532 return without error.)  Will replace existing records in which the only difference
4533 is to add a value to a previously empty preserved field and/or turn on automatic payment.
4534 Fields marked as preserved are optional, and existing values will not be overwritten with
4535 blanks when replacing.
4536
4537 Accepts the following named parameters:
4538
4539 =over 4
4540
4541 =item payment_payby
4542
4543 either CARD or CHEK
4544
4545 =item auto
4546
4547 save as an automatic payment type (CARD/CHEK if true, DCRD/DCHK if false)
4548
4549 =item weight
4550
4551 optional, set higher than 1 for secondary, etc.
4552
4553 =item payinfo
4554
4555 required
4556
4557 =item paymask
4558
4559 optional, but should be specified for anything that might be tokenized, will be preserved when replacing
4560
4561 =item payname
4562
4563 required
4564
4565 =item payip
4566
4567 optional, will be preserved when replacing
4568
4569 =item paydate
4570
4571 CARD only, required
4572
4573 =item bill_location
4574
4575 CARD only, required, FS::cust_location object
4576
4577 =item paystart_month
4578
4579 CARD only, optional, will be preserved when replacing
4580
4581 =item paystart_year
4582
4583 CARD only, optional, will be preserved when replacing
4584
4585 =item payissue
4586
4587 CARD only, optional, will be preserved when replacing
4588
4589 =item paycvv
4590
4591 CARD only, only used if conf cvv-save is set appropriately
4592
4593 =item paytype
4594
4595 CHEK only
4596
4597 =item paystate
4598
4599 CHEK only
4600
4601 =back
4602
4603 =cut
4604
4605 #The code for this option is in place, but it's not currently used
4606 #
4607 # =item replace
4608 #
4609 # existing cust_payby object to be replaced (must match custnum)
4610
4611 # stateid/stateid_state/ss are not currently supported in cust_payby,
4612 # might not even work properly in 4.x, but will need to work here if ever added
4613
4614 sub save_cust_payby {
4615   my $self = shift;
4616   my %opt = @_;
4617
4618   my $old = $opt{'replace'};
4619   my $new = new FS::cust_payby { $old ? $old->hash : () };
4620   return "Customer number does not match" if $new->custnum and $new->custnum != $self->custnum;
4621   $new->set( 'custnum' => $self->custnum );
4622
4623   my $payby = $opt{'payment_payby'};
4624   return "Bad payby" unless grep(/^$payby$/,('CARD','CHEK'));
4625
4626   # don't allow turning off auto when replacing
4627   $opt{'auto'} ||= 1 if $old and $old->payby !~ /^D/;
4628
4629   my @check_existing; # payby relevant to this payment_payby
4630
4631   # set payby based on auto
4632   if ( $payby eq 'CARD' ) {
4633     $new->set( 'payby' => ( $opt{'auto'} ? 'CARD' : 'DCRD' ) );
4634     @check_existing = qw( CARD DCRD );
4635   } elsif ( $payby eq 'CHEK' ) {
4636     $new->set( 'payby' => ( $opt{'auto'} ? 'CHEK' : 'DCHK' ) );
4637     @check_existing = qw( CHEK DCHK );
4638   }
4639
4640   $new->set( 'weight' => $opt{'auto'} ? $opt{'weight'} : '' );
4641
4642   # basic fields
4643   $new->payinfo($opt{'payinfo'}); # sets default paymask, but not if it's already tokenized
4644   $new->paymask($opt{'paymask'}) if $opt{'paymask'}; # in case it's been tokenized, override with loaded paymask
4645   $new->set( 'payname' => $opt{'payname'} );
4646   $new->set( 'payip' => $opt{'payip'} ); # will be preserved below
4647
4648   my $conf = new FS::Conf;
4649
4650   # compare to FS::cust_main::realtime_bop - check both to make sure working correctly
4651   if ( $payby eq 'CARD' &&
4652        ( (grep { $_ eq cardtype($opt{'payinfo'}) } $conf->config('cvv-save'))
4653          || $conf->exists('business-onlinepayment-verification')
4654        )
4655   ) {
4656     $new->set( 'paycvv' => $opt{'paycvv'} );
4657   } else {
4658     $new->set( 'paycvv' => '');
4659   }
4660
4661   local $SIG{HUP} = 'IGNORE';
4662   local $SIG{INT} = 'IGNORE';
4663   local $SIG{QUIT} = 'IGNORE';
4664   local $SIG{TERM} = 'IGNORE';
4665   local $SIG{TSTP} = 'IGNORE';
4666   local $SIG{PIPE} = 'IGNORE';
4667
4668   my $oldAutoCommit = $FS::UID::AutoCommit;
4669   local $FS::UID::AutoCommit = 0;
4670   my $dbh = dbh;
4671
4672   # set fields specific to payment_payby
4673   if ( $payby eq 'CARD' ) {
4674     if ($opt{'bill_location'}) {
4675       $opt{'bill_location'}->set('custnum' => $self->custnum);
4676       my $error = $opt{'bill_location'}->find_or_insert;
4677       if ( $error ) {
4678         $dbh->rollback if $oldAutoCommit;
4679         return $error;
4680       }
4681       $new->set( 'locationnum' => $opt{'bill_location'}->locationnum );
4682     }
4683     foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
4684       $new->set( $field => $opt{$field} );
4685     }
4686   } else {
4687     foreach my $field ( qw(paytype paystate) ) {
4688       $new->set( $field => $opt{$field} );
4689     }
4690   }
4691
4692   # other cust_payby to compare this to
4693   my @existing = $self->cust_payby(@check_existing);
4694
4695   # fields that can overwrite blanks with values, but not values with blanks
4696   my @preserve = qw( paymask locationnum paystart_month paystart_year payissue payip );
4697
4698   my $skip_cust_payby = 0; # true if we don't need to save or reweight cust_payby
4699   unless ($old) {
4700     # generally, we don't want to overwrite existing cust_payby with this,
4701     # but we can replace if we're only marking it auto or adding a preserved field
4702     # and we can avoid saving a total duplicate or merely turning off auto
4703 PAYBYLOOP:
4704     foreach my $cust_payby (@existing) {
4705       # check fields that absolutely should not change
4706       foreach my $field ($new->fields) {
4707         next if grep(/^$field$/, qw( custpaybynum payby weight ) );
4708         next if grep(/^$field$/, @preserve );
4709         next PAYBYLOOP unless $new->get($field) eq $cust_payby->get($field);
4710       }
4711       # now check fields that can replace if one value is blank
4712       my $replace = 0;
4713       foreach my $field (@preserve) {
4714         if (
4715           ( $new->get($field) and !$cust_payby->get($field) ) or
4716           ( $cust_payby->get($field) and !$new->get($field) )
4717         ) {
4718           # prevention of overwriting values with blanks happens farther below
4719           $replace = 1;
4720         } elsif ( $new->get($field) ne $cust_payby->get($field) ) {
4721           next PAYBYLOOP;
4722         }
4723       }
4724       unless ( $replace ) {
4725         # nearly identical, now check weight
4726         if ($new->get('weight') eq $cust_payby->get('weight') or !$new->get('weight')) {
4727           # ignore identical cust_payby, and ignore attempts to turn off auto
4728           # no need to save or re-weight cust_payby (but still need to update/commit $self)
4729           $skip_cust_payby = 1;
4730           last PAYBYLOOP;
4731         }
4732         # otherwise, only change is to mark this as primary
4733       }
4734       # if we got this far, we're definitely replacing
4735       $old = $cust_payby;
4736       last PAYBYLOOP;
4737     } #PAYBYLOOP
4738   }
4739
4740   if ($old) {
4741     $new->set( 'custpaybynum' => $old->custpaybynum );
4742     # don't turn off automatic payment (but allow it to be turned on)
4743     if ($new->payby =~ /^D/ and $new->payby ne $old->payby) {
4744       $opt{'auto'} = 1;
4745       $new->set( 'payby' => $old->payby );
4746       $new->set( 'weight' => 1 );
4747     }
4748     # make sure we're not overwriting values with blanks
4749     foreach my $field (@preserve) {
4750       if ( $old->get($field) and !$new->get($field) ) {
4751         $new->set( $field => $old->get($field) );
4752       }
4753     }
4754   }
4755
4756   # only overwrite cust_main bill_location if auto
4757   if ($opt{'auto'} && $opt{'bill_location'}) {
4758     $self->set('bill_location' => $opt{'bill_location'});
4759     my $error = $self->replace;
4760     if ( $error ) {
4761       $dbh->rollback if $oldAutoCommit;
4762       return $error;
4763     }
4764   }
4765
4766   # done with everything except reweighting and saving cust_payby
4767   # still need to commit changes to cust_main and cust_location
4768   if ($skip_cust_payby) {
4769     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4770     return '';
4771   }
4772
4773   # re-weight existing primary cust_pay for this payby
4774   if ($opt{'auto'}) {
4775     foreach my $cust_payby (@existing) {
4776       # relies on cust_payby return order
4777       last unless $cust_payby->payby !~ /^D/;
4778       last if $cust_payby->weight > 1;
4779       next if $new->custpaybynum eq $cust_payby->custpaybynum;
4780       next if $cust_payby->weight < ($opt{'weight'} || 1);
4781       $cust_payby->weight( $cust_payby->weight + 1 );
4782       my $error = $cust_payby->replace;
4783       if ( $error ) {
4784         $dbh->rollback if $oldAutoCommit;
4785         return "Error reweighting cust_payby: $error";
4786       }
4787     }
4788   }
4789
4790   # finally, save cust_payby
4791   my $error = $old ? $new->replace($old) : $new->insert;
4792   if ( $error ) {
4793     $dbh->rollback if $oldAutoCommit;
4794     return $error;
4795   }
4796
4797   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4798   '';
4799
4800 }
4801
4802 =item remove_cvv_from_cust_payby PAYINFO
4803
4804 Removes paycvv from associated cust_payby with matching PAYINFO.
4805
4806 =cut
4807
4808 sub remove_cvv_from_cust_payby {
4809   my ($self,$payinfo) = @_;
4810
4811   my $oldAutoCommit = $FS::UID::AutoCommit;
4812   local $FS::UID::AutoCommit = 0;
4813   my $dbh = dbh;
4814
4815   foreach my $cust_payby ( qsearch('cust_payby',{ custnum => $self->custnum }) ) {
4816     next unless $cust_payby->payinfo eq $payinfo; # can't qsearch on payinfo
4817     $cust_payby->paycvv('');
4818     my $error = $cust_payby->replace;
4819     if ($error) {
4820       $dbh->rollback if $oldAutoCommit;
4821       return $error;
4822     }
4823   }
4824
4825   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4826   '';
4827 }
4828
4829 =back
4830
4831 =head1 CLASS METHODS
4832
4833 =over 4
4834
4835 =item statuses
4836
4837 Class method that returns the list of possible status strings for customers
4838 (see L<the status method|/status>).  For example:
4839
4840   @statuses = FS::cust_main->statuses();
4841
4842 =cut
4843
4844 sub statuses {
4845   my $self = shift;
4846   keys %{ $self->statuscolors };
4847 }
4848
4849 =item cust_status_sql
4850
4851 Returns an SQL fragment to determine the status of a cust_main record, as a
4852 string.
4853
4854 =cut
4855
4856 sub cust_status_sql {
4857   my $sql = 'CASE';
4858   for my $status ( FS::cust_main->statuses() ) {
4859     my $method = $status.'_sql';
4860     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4861   }
4862   $sql .= ' END';
4863   return $sql;
4864 }
4865
4866
4867 =item prospect_sql
4868
4869 Returns an SQL expression identifying prospective cust_main records (customers
4870 with no packages ever ordered)
4871
4872 =cut
4873
4874 use vars qw($select_count_pkgs);
4875 $select_count_pkgs =
4876   "SELECT COUNT(*) FROM cust_pkg
4877     WHERE cust_pkg.custnum = cust_main.custnum";
4878
4879 sub select_count_pkgs_sql {
4880   $select_count_pkgs;
4881 }
4882
4883 sub prospect_sql {
4884   " 0 = ( $select_count_pkgs ) ";
4885 }
4886
4887 =item ordered_sql
4888
4889 Returns an SQL expression identifying ordered cust_main records (customers with
4890 no active packages, but recurring packages not yet setup or one time charges
4891 not yet billed).
4892
4893 =cut
4894
4895 sub ordered_sql {
4896   FS::cust_main->none_active_sql.
4897   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4898 }
4899
4900 =item active_sql
4901
4902 Returns an SQL expression identifying active cust_main records (customers with
4903 active recurring packages).
4904
4905 =cut
4906
4907 sub active_sql {
4908   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4909 }
4910
4911 =item none_active_sql
4912
4913 Returns an SQL expression identifying cust_main records with no active
4914 recurring packages.  This includes customers of status prospect, ordered,
4915 inactive, and suspended.
4916
4917 =cut
4918
4919 sub none_active_sql {
4920   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4921 }
4922
4923 =item inactive_sql
4924
4925 Returns an SQL expression identifying inactive cust_main records (customers with
4926 no active recurring packages, but otherwise unsuspended/uncancelled).
4927
4928 =cut
4929
4930 sub inactive_sql {
4931   FS::cust_main->none_active_sql.
4932   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4933 }
4934
4935 =item susp_sql
4936 =item suspended_sql
4937
4938 Returns an SQL expression identifying suspended cust_main records.
4939
4940 =cut
4941
4942
4943 sub suspended_sql { susp_sql(@_); }
4944 sub susp_sql {
4945   FS::cust_main->none_active_sql.
4946   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4947 }
4948
4949 =item cancel_sql
4950 =item cancelled_sql
4951
4952 Returns an SQL expression identifying cancelled cust_main records.
4953
4954 =cut
4955
4956 sub cancel_sql { shift->cancelled_sql(@_); }
4957
4958 =item uncancel_sql
4959 =item uncancelled_sql
4960
4961 Returns an SQL expression identifying un-cancelled cust_main records.
4962
4963 =cut
4964
4965 sub uncancelled_sql { uncancel_sql(@_); }
4966 sub uncancel_sql { "
4967   ( 0 < ( $select_count_pkgs
4968                    AND ( cust_pkg.cancel IS NULL
4969                          OR cust_pkg.cancel = 0
4970                        )
4971         )
4972     OR 0 = ( $select_count_pkgs )
4973   )
4974 "; }
4975
4976 =item balance_sql
4977
4978 Returns an SQL fragment to retreive the balance.
4979
4980 =cut
4981
4982 sub balance_sql { "
4983     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4984         WHERE cust_bill.custnum   = cust_main.custnum     )
4985   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4986         WHERE cust_pay.custnum    = cust_main.custnum     )
4987   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4988         WHERE cust_credit.custnum = cust_main.custnum     )
4989   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4990         WHERE cust_refund.custnum = cust_main.custnum     )
4991 "; }
4992
4993 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4994
4995 Returns an SQL fragment to retreive the balance for this customer, optionally
4996 considering invoices with date earlier than START_TIME, and not
4997 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4998 total_unapplied_payments).
4999
5000 Times are specified as SQL fragments or numeric
5001 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5002 L<Date::Parse> for conversion functions.  The empty string can be passed
5003 to disable that time constraint completely.
5004
5005 Available options are:
5006
5007 =over 4
5008
5009 =item unapplied_date
5010
5011 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
5012
5013 =item total
5014
5015 (unused.  obsolete?)
5016 set to true to remove all customer comparison clauses, for totals
5017
5018 =item where
5019
5020 (unused.  obsolete?)
5021 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
5022
5023 =item join
5024
5025 (unused.  obsolete?)
5026 JOIN clause (typically used with the total option)
5027
5028 =item cutoff
5029
5030 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
5031 time will be ignored.  Note that START_TIME and END_TIME only limit the date
5032 range for invoices and I<unapplied> payments, credits, and refunds.
5033
5034 =back
5035
5036 =cut
5037
5038 sub balance_date_sql {
5039   my( $class, $start, $end, %opt ) = @_;
5040
5041   my $cutoff = $opt{'cutoff'};
5042
5043   my $owed         = FS::cust_bill->owed_sql($cutoff);
5044   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
5045   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
5046   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5047
5048   my $j = $opt{'join'} || '';
5049
5050   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
5051   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
5052   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
5053   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
5054
5055   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
5056     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
5057     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
5058     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
5059   ";
5060
5061 }
5062
5063 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
5064
5065 Returns an SQL fragment to retreive the total unapplied payments for this
5066 customer, only considering payments with date earlier than START_TIME, and
5067 optionally not later than END_TIME.
5068
5069 Times are specified as SQL fragments or numeric
5070 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
5071 L<Date::Parse> for conversion functions.  The empty string can be passed
5072 to disable that time constraint completely.
5073
5074 Available options are:
5075
5076 =cut
5077
5078 sub unapplied_payments_date_sql {
5079   my( $class, $start, $end, %opt ) = @_;
5080
5081   my $cutoff = $opt{'cutoff'};
5082
5083   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
5084
5085   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
5086                                                           'unapplied_date'=>1 );
5087
5088   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
5089 }
5090
5091 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
5092
5093 Helper method for balance_date_sql; name (and usage) subject to change
5094 (suggestions welcome).
5095
5096 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
5097 cust_refund, cust_credit or cust_pay).
5098
5099 If TABLE is "cust_bill" or the unapplied_date option is true, only
5100 considers records with date earlier than START_TIME, and optionally not
5101 later than END_TIME .
5102
5103 =cut
5104
5105 sub _money_table_where {
5106   my( $class, $table, $start, $end, %opt ) = @_;
5107
5108   my @where = ();
5109   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
5110   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
5111     push @where, "$table._date <= $start" if defined($start) && length($start);
5112     push @where, "$table._date >  $end"   if defined($end)   && length($end);
5113   }
5114   push @where, @{$opt{'where'}} if $opt{'where'};
5115   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
5116
5117   $where;
5118
5119 }
5120
5121 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
5122 use FS::cust_main::Search;
5123 sub search {
5124   my $class = shift;
5125   FS::cust_main::Search->search(@_);
5126 }
5127
5128 =back
5129
5130 =head1 SUBROUTINES
5131
5132 =over 4
5133
5134 #=item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5135
5136 #Deprecated.  Use event notification and message templates
5137 #(L<FS::msg_template>) instead.
5138
5139 #Sends a templated email notification to the customer (see L<Text::Template>).
5140
5141 #OPTIONS is a hash and may include
5142
5143 #I<from> - the email sender (default is invoice_from)
5144
5145 #I<to> - comma-separated scalar or arrayref of recipients
5146 #   (default is invoicing_list)
5147
5148 #I<subject> - The subject line of the sent email notification
5149 #   (default is "Notice from company_name")
5150
5151 #I<extra_fields> - a hashref of name/value pairs which will be substituted
5152 #   into the template
5153
5154 #The following variables are vavailable in the template.
5155
5156 #I<$first> - the customer first name
5157 #I<$last> - the customer last name
5158 #I<$company> - the customer company
5159 #I<$payby> - a description of the method of payment for the customer
5160 #            # would be nice to use FS::payby::shortname
5161 #I<$payinfo> - the account information used to collect for this customer
5162 #I<$expdate> - the expiration of the customer payment in seconds from epoch
5163
5164 #=cut
5165
5166 #sub notify {
5167 #  my ($self, $template, %options) = @_;
5168
5169 #  return unless $conf->exists($template);
5170
5171 #  my $from = $conf->invoice_from_full($self->agentnum)
5172 #    if $conf->exists('invoice_from', $self->agentnum);
5173 #  $from = $options{from} if exists($options{from});
5174
5175 #  my $to = join(',', $self->invoicing_list_emailonly);
5176 #  $to = $options{to} if exists($options{to});
5177 #
5178 #  my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
5179 #    if $conf->exists('company_name', $self->agentnum);
5180 #  $subject = $options{subject} if exists($options{subject});
5181
5182 #  my $notify_template = new Text::Template (TYPE => 'ARRAY',
5183 #                                            SOURCE => [ map "$_\n",
5184 #                                              $conf->config($template)]
5185 #                                           )
5186 #    or die "can't create new Text::Template object: Text::Template::ERROR";
5187 #  $notify_template->compile()
5188 #    or die "can't compile template: Text::Template::ERROR";
5189
5190 #  $FS::notify_template::_template::company_name =
5191 #    $conf->config('company_name', $self->agentnum);
5192 #  $FS::notify_template::_template::company_address =
5193 #    join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
5194
5195 #  my $paydate = $self->paydate || '2037-12-31';
5196 #  $FS::notify_template::_template::first = $self->first;
5197 #  $FS::notify_template::_template::last = $self->last;
5198 #  $FS::notify_template::_template::company = $self->company;
5199 #  $FS::notify_template::_template::payinfo = $self->mask_payinfo;
5200 #  my $payby = $self->payby;
5201 #  my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
5202 #  my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
5203
5204 #  #credit cards expire at the end of the month/year of their exp date
5205 #  if ($payby eq 'CARD' || $payby eq 'DCRD') {
5206 #    $FS::notify_template::_template::payby = 'credit card';
5207 #    ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
5208 #    $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
5209 #    $expire_time--;
5210 #  }elsif ($payby eq 'COMP') {
5211 #    $FS::notify_template::_template::payby = 'complimentary account';
5212 #  }else{
5213 #    $FS::notify_template::_template::payby = 'current method';
5214 #  }
5215 #  $FS::notify_template::_template::expdate = $expire_time;
5216
5217 #  for (keys %{$options{extra_fields}}){
5218 #    no strict "refs";
5219 #    ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
5220 #  }
5221
5222 #  send_email(from => $from,
5223 #             to => $to,
5224 #             subject => $subject,
5225 #             body => $notify_template->fill_in( PACKAGE =>
5226 #                                                'FS::notify_template::_template'                                              ),
5227 #            );
5228
5229 #}
5230
5231 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
5232
5233 Generates a templated notification to the customer (see L<Text::Template>).
5234
5235 OPTIONS is a hash and may include
5236
5237 I<extra_fields> - a hashref of name/value pairs which will be substituted
5238    into the template.  These values may override values mentioned below
5239    and those from the customer record.
5240
5241 I<template_text> - if present, ignores TEMPLATE_NAME and uses the provided text
5242
5243 The following variables are available in the template instead of or in addition
5244 to the fields of the customer record.
5245
5246 I<$payby> - a description of the method of payment for the customer
5247             # would be nice to use FS::payby::shortname
5248 I<$payinfo> - the masked account information used to collect for this customer
5249 I<$expdate> - the expiration of the customer payment method in seconds from epoch
5250 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
5251
5252 =cut
5253
5254 # a lot like cust_bill::print_latex
5255 sub generate_letter {
5256   my ($self, $template, %options) = @_;
5257
5258   warn "Template $template does not exist" && return
5259     unless $conf->exists($template) || $options{'template_text'};
5260
5261   my $template_source = $options{'template_text'}
5262                         ? [ $options{'template_text'} ]
5263                         : [ map "$_\n", $conf->config($template) ];
5264
5265   my $letter_template = new Text::Template
5266                         ( TYPE       => 'ARRAY',
5267                           SOURCE     => $template_source,
5268                           DELIMITERS => [ '[@--', '--@]' ],
5269                         )
5270     or die "can't create new Text::Template object: Text::Template::ERROR";
5271
5272   $letter_template->compile()
5273     or die "can't compile template: Text::Template::ERROR";
5274
5275   my %letter_data = map { $_ => $self->$_ } $self->fields;
5276   $letter_data{payinfo} = $self->mask_payinfo;
5277
5278   #my $paydate = $self->paydate || '2037-12-31';
5279   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
5280
5281   my $payby = $self->payby;
5282   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
5283   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
5284
5285   #credit cards expire at the end of the month/year of their exp date
5286   if ($payby eq 'CARD' || $payby eq 'DCRD') {
5287     $letter_data{payby} = 'credit card';
5288     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
5289     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
5290     $expire_time--;
5291   }elsif ($payby eq 'COMP') {
5292     $letter_data{payby} = 'complimentary account';
5293   }else{
5294     $letter_data{payby} = 'current method';
5295   }
5296   $letter_data{expdate} = $expire_time;
5297
5298   for (keys %{$options{extra_fields}}){
5299     $letter_data{$_} = $options{extra_fields}->{$_};
5300   }
5301
5302   unless(exists($letter_data{returnaddress})){
5303     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
5304                                                   $self->agent_template)
5305                      );
5306     if ( length($retadd) ) {
5307       $letter_data{returnaddress} = $retadd;
5308     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
5309       $letter_data{returnaddress} =
5310         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
5311                           s/$/\\\\\*/;
5312                           $_;
5313                         }
5314                     ( $conf->config('company_name', $self->agentnum),
5315                       $conf->config('company_address', $self->agentnum),
5316                     )
5317         );
5318     } else {
5319       $letter_data{returnaddress} = '~';
5320     }
5321   }
5322
5323   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
5324
5325   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
5326
5327   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
5328
5329   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5330                            DIR      => $dir,
5331                            SUFFIX   => '.eps',
5332                            UNLINK   => 0,
5333                          ) or die "can't open temp file: $!\n";
5334   print $lh $conf->config_binary('logo.eps', $self->agentnum)
5335     or die "can't write temp file: $!\n";
5336   close $lh;
5337   $letter_data{'logo_file'} = $lh->filename;
5338
5339   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
5340                            DIR      => $dir,
5341                            SUFFIX   => '.tex',
5342                            UNLINK   => 0,
5343                          ) or die "can't open temp file: $!\n";
5344
5345   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
5346   close $fh;
5347   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
5348   return ($1, $letter_data{'logo_file'});
5349
5350 }
5351
5352 =item print_ps TEMPLATE
5353
5354 Returns an postscript letter filled in from TEMPLATE, as a scalar.
5355
5356 =cut
5357
5358 sub print_ps {
5359   my $self = shift;
5360   my($file, $lfile) = $self->generate_letter(@_);
5361   my $ps = FS::Misc::generate_ps($file);
5362   unlink($file.'.tex');
5363   unlink($lfile);
5364
5365   $ps;
5366 }
5367
5368 =item print TEMPLATE
5369
5370 Prints the filled in template.
5371
5372 TEMPLATE is the name of a L<Text::Template> to fill in and print.
5373
5374 =cut
5375
5376 sub queueable_print {
5377   my %opt = @_;
5378
5379   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
5380     or die "invalid customer number: " . $opt{custnum};
5381
5382 #do not backport this change to 3.x
5383 #  my $error = $self->print( { 'template' => $opt{template} } );
5384   my $error = $self->print( $opt{'template'} );
5385   die $error if $error;
5386 }
5387
5388 sub print {
5389   my ($self, $template) = (shift, shift);
5390   do_print(
5391     [ $self->print_ps($template) ],
5392     'agentnum' => $self->agentnum,
5393   );
5394 }
5395
5396 #these three subs should just go away once agent stuff is all config overrides
5397
5398 sub agent_template {
5399   my $self = shift;
5400   $self->_agent_plandata('agent_templatename');
5401 }
5402
5403 sub agent_invoice_from {
5404   my $self = shift;
5405   $self->_agent_plandata('agent_invoice_from');
5406 }
5407
5408 sub _agent_plandata {
5409   my( $self, $option ) = @_;
5410
5411   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
5412   #agent-specific Conf
5413
5414   use FS::part_event::Condition;
5415
5416   my $agentnum = $self->agentnum;
5417
5418   my $regexp = regexp_sql();
5419
5420   my $part_event_option =
5421     qsearchs({
5422       'select'    => 'part_event_option.*',
5423       'table'     => 'part_event_option',
5424       'addl_from' => q{
5425         LEFT JOIN part_event USING ( eventpart )
5426         LEFT JOIN part_event_option AS peo_agentnum
5427           ON ( part_event.eventpart = peo_agentnum.eventpart
5428                AND peo_agentnum.optionname = 'agentnum'
5429                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
5430              )
5431         LEFT JOIN part_event_condition
5432           ON ( part_event.eventpart = part_event_condition.eventpart
5433                AND part_event_condition.conditionname = 'cust_bill_age'
5434              )
5435         LEFT JOIN part_event_condition_option
5436           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
5437                AND part_event_condition_option.optionname = 'age'
5438              )
5439       },
5440       #'hashref'   => { 'optionname' => $option },
5441       #'hashref'   => { 'part_event_option.optionname' => $option },
5442       'extra_sql' =>
5443         " WHERE part_event_option.optionname = ". dbh->quote($option).
5444         " AND action = 'cust_bill_send_agent' ".
5445         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
5446         " AND peo_agentnum.optionname = 'agentnum' ".
5447         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
5448         " ORDER BY
5449            CASE WHEN part_event_condition_option.optionname IS NULL
5450            THEN -1
5451            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
5452         " END
5453           , part_event.weight".
5454         " LIMIT 1"
5455     });
5456
5457   unless ( $part_event_option ) {
5458     return $self->agent->invoice_template || ''
5459       if $option eq 'agent_templatename';
5460     return '';
5461   }
5462
5463   $part_event_option->optionvalue;
5464
5465 }
5466
5467 sub process_o2m_qsearch {
5468   my $self = shift;
5469   my $table = shift;
5470   return qsearch($table, @_) unless $table eq 'contact';
5471
5472   my $hashref = shift;
5473   my %hash = %$hashref;
5474   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5475     or die 'guru meditation #4343';
5476
5477   qsearch({ 'table'     => 'contact',
5478             'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5479             'hashref'   => \%hash,
5480             'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5481                            " cust_contact.custnum = $custnum "
5482          });
5483 }
5484
5485 sub process_o2m_qsearchs {
5486   my $self = shift;
5487   my $table = shift;
5488   return qsearchs($table, @_) unless $table eq 'contact';
5489
5490   my $hashref = shift;
5491   my %hash = %$hashref;
5492   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5493     or die 'guru meditation #2121';
5494
5495   qsearchs({ 'table'     => 'contact',
5496              'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5497              'hashref'   => \%hash,
5498              'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5499                             " cust_contact.custnum = $custnum "
5500           });
5501 }
5502
5503 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5504
5505 Subroutine (not a method), designed to be called from the queue.
5506
5507 Takes a list of options and values.
5508
5509 Pulls up the customer record via the custnum option and calls bill_and_collect.
5510
5511 =cut
5512
5513 sub queued_bill {
5514   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5515
5516   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5517   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5518
5519   #without this errors don't get rolled back
5520   $args{'fatal'} = 1; # runs from job queue, will be caught
5521
5522   $cust_main->bill_and_collect( %args );
5523 }
5524
5525 =item queued_collect 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5526
5527 Like queued_bill, but instead of C<bill_and_collect>, just runs the
5528 C<collect> part.  This is used in batch tax calculation, where invoice
5529 generation and collection events have to be completely separated.
5530
5531 =cut
5532
5533 sub queued_collect {
5534   my (%args) = @_;
5535   my $cust_main = FS::cust_main->by_key($args{'custnum'});
5536
5537   $cust_main->collect(%args);
5538 }
5539
5540 sub process_bill_and_collect {
5541   my $job = shift;
5542   my $param = shift;
5543   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5544       or die "custnum '$param->{custnum}' not found!\n";
5545   $param->{'job'}   = $job;
5546   $param->{'fatal'} = 1; # runs from job queue, will be caught
5547   $param->{'retry'} = 1;
5548
5549   $cust_main->bill_and_collect( %$param );
5550 }
5551
5552 #starting to take quite a while for big dbs
5553 #   (JRNL: journaled so it only happens once per database)
5554 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5555 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5556 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5557 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5558 # JRNL leading/trailing spaces in first, last, company
5559 # JRNL migrate to cust_payby
5560 # - otaker upgrade?  journal and call it good?  (double check to make sure
5561 #    we're not still setting otaker here)
5562 #
5563 #only going to get worse with new location stuff...
5564
5565 sub _upgrade_data { #class method
5566   my ($class, %opts) = @_;
5567
5568   my @statements = (
5569     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
5570   );
5571
5572   #this seems to be the only expensive one.. why does it take so long?
5573   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5574     push @statements,
5575       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5576     FS::upgrade_journal->set_done('cust_main__signupdate');
5577   }
5578
5579   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
5580
5581     # fix yyyy-m-dd formatted paydates
5582     if ( driver_name =~ /^mysql/i ) {
5583       push @statements,
5584       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5585     } else { # the SQL standard
5586       push @statements,
5587       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5588     }
5589     FS::upgrade_journal->set_done('cust_main__paydate');
5590   }
5591
5592   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5593
5594     push @statements, #fix the weird BILL with a cc# in payinfo problem
5595       #DCRD to be safe
5596       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5597
5598     FS::upgrade_journal->set_done('cust_main__payinfo');
5599
5600   }
5601
5602   my $t = time;
5603   foreach my $sql ( @statements ) {
5604     my $sth = dbh->prepare($sql) or die dbh->errstr;
5605     $sth->execute or die $sth->errstr;
5606     #warn ( (time - $t). " seconds\n" );
5607     #$t = time;
5608   }
5609
5610   local($ignore_expired_card) = 1;
5611   local($ignore_banned_card) = 1;
5612   local($skip_fuzzyfiles) = 1;
5613   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5614
5615   unless ( FS::upgrade_journal->is_done('cust_main__cust_payby') ) {
5616
5617     #we don't want to decrypt them, just stuff them as-is into cust_payby
5618     local(@encrypted_fields) = ();
5619
5620     local($FS::cust_payby::ignore_expired_card) = 1;
5621     local($FS::cust_payby::ignore_banned_card)  = 1;
5622     local($FS::cust_payby::ignore_cardtype)     = 1;
5623
5624     my @payfields = qw( payby payinfo paycvv paymask
5625                         paydate paystart_month paystart_year payissue
5626                         payname paystate paytype payip
5627                       );
5628
5629     my $search = new FS::Cursor {
5630       'table'     => 'cust_main',
5631       'extra_sql' => " WHERE ( payby IS NOT NULL AND payby != '' ) ",
5632     };
5633
5634     while (my $cust_main = $search->fetch) {
5635
5636       unless ( $cust_main->payby =~ /^(BILL|COMP)$/ ) {
5637
5638         my $cust_payby = new FS::cust_payby {
5639           'custnum' => $cust_main->custnum,
5640           'weight'  => 1,
5641           map { $_ => $cust_main->$_(); } @payfields
5642         };
5643
5644         my $error = $cust_payby->insert;
5645         die $error if $error;
5646
5647       }
5648
5649       # at the time we do this, also migrate paytype into cust_pay_batch
5650       # so that batches that are open before the migration can still be
5651       # processed
5652       my @cust_pay_batch = qsearch('cust_pay_batch', {
5653           'custnum' => $cust_main->custnum,
5654           'payby'   => 'CHEK',
5655           'paytype' => '',
5656       });
5657       foreach my $cust_pay_batch (@cust_pay_batch) {
5658         $cust_pay_batch->set('paytype', $cust_main->get('paytype'));
5659         my $error = $cust_pay_batch->replace;
5660         die "$error (setting cust_pay_batch.paytype)" if $error;
5661       }
5662
5663       $cust_main->complimentary('Y') if $cust_main->payby eq 'COMP';
5664
5665       $cust_main->invoice_attn( $cust_main->payname )
5666         if $cust_main->payby eq 'BILL' && $cust_main->payname;
5667       $cust_main->po_number( $cust_main->payinfo )
5668         if $cust_main->payby eq 'BILL' && $cust_main->payinfo;
5669
5670       $cust_main->setfield($_, '') foreach @payfields;
5671       my $error = $cust_main->replace;
5672       die "Error upgradging payment information for custnum ".
5673           $cust_main->custnum. ": $error"
5674         if $error;
5675
5676     };
5677
5678     FS::upgrade_journal->set_done('cust_main__cust_payby');
5679   }
5680
5681   FS::cust_main::Location->_upgrade_data(%opts);
5682
5683   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5684
5685     foreach my $cust_main ( qsearch({
5686       'table'     => 'cust_main',
5687       'hashref'   => {},
5688       'extra_sql' => 'WHERE '.
5689                        join(' OR ',
5690                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5691                            qw( first last company )
5692                        ),
5693     }) ) {
5694       my $error = $cust_main->replace;
5695       die $error if $error;
5696     }
5697
5698     FS::upgrade_journal->set_done('cust_main__trimspaces');
5699
5700   }
5701
5702   $class->_upgrade_otaker(%opts);
5703
5704 }
5705
5706 =back
5707
5708 =head1 BUGS
5709
5710 The delete method.
5711
5712 The delete method should possibly take an FS::cust_main object reference
5713 instead of a scalar customer number.
5714
5715 Bill and collect options should probably be passed as references instead of a
5716 list.
5717
5718 There should probably be a configuration file with a list of allowed credit
5719 card types.
5720
5721 No multiple currency support (probably a larger project than just this module).
5722
5723 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5724
5725 Birthdates rely on negative epoch values.
5726
5727 The payby for card/check batches is broken.  With mixed batching, bad
5728 things will happen.
5729
5730 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5731
5732 =head1 SEE ALSO
5733
5734 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5735 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5736 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5737
5738 =cut
5739
5740 1;
5741